config/spl-build.m4

   1 dnl #
   2 dnl # Default SPL kernel configuration
   3 dnl #
   4 AC_DEFUN([SPL_AC_CONFIG_KERNEL], [
   5         SPL_AC_KERNEL
   6
   7         dnl # Kernel build make options
   8         dnl # KERNELMAKE_PARAMS="V=1"   # Enable verbose module build
   9         KERNELMAKE_PARAMS="V=1"
  10
  11         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  12         dnl # compiler options are added by the kernel build system.
  13         abs_srcdir=`readlink -f ${srcdir}`
  14         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wstrict-prototypes -Werror"
  15         KERNELCPPFLAGS="$KERNELCPPFLAGS -I${abs_srcdir} -I${abs_srcdir}/include"
  16
  17         if test "${LINUX_OBJ}" != "${LINUX}"; then
  18                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  19         fi
  20
  21         AC_SUBST(KERNELMAKE_PARAMS)
  22         AC_SUBST(KERNELCPPFLAGS)
  23
  24         SPL_AC_DEBUG
  25         SPL_AC_DEBUG_KMEM
  26         SPL_AC_DEBUG_KMEM_TRACKING
  27         SPL_AC_ATOMIC_SPINLOCK
  28         SPL_AC_TYPE_UINTPTR_T
  29         SPL_AC_TYPE_ATOMIC64_T
  30         SPL_AC_TYPE_ATOMIC64_CMPXCHG
  31         SPL_AC_TYPE_ATOMIC64_XCHG
  32         SPL_AC_3ARGS_INIT_WORK
  33         SPL_AC_2ARGS_REGISTER_SYSCTL
  34         SPL_AC_SET_SHRINKER
  35         SPL_AC_PATH_IN_NAMEIDATA
  36         SPL_AC_TASK_CURR
  37         SPL_AC_CTL_UNNUMBERED
  38         SPL_AC_FLS64
  39         SPL_AC_DEVICE_CREATE
  40         SPL_AC_5ARGS_DEVICE_CREATE
  41         SPL_AC_CLASS_DEVICE_CREATE
  42         SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT
  43         SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE
  44         SPL_AC_TIMESPEC_SUB
  45         SPL_AC_INIT_UTSNAME
  46         SPL_AC_FDTABLE_HEADER
  47         SPL_AC_FILES_FDTABLE
  48         SPL_AC_UACCESS_HEADER
  49         SPL_AC_KMALLOC_NODE
  50         SPL_AC_MONOTONIC_CLOCK
  51         SPL_AC_INODE_I_MUTEX
  52         SPL_AC_MUTEX_OWNER
  53         SPL_AC_MUTEX_LOCK_NESTED
  54         SPL_AC_DIV64_64
  55         SPL_AC_DIV64_U64
  56         SPL_AC_3ARGS_ON_EACH_CPU
  57         SPL_AC_KALLSYMS_LOOKUP_NAME
  58         SPL_AC_GET_VMALLOC_INFO
  59         SPL_AC_PGDAT_HELPERS
  60         SPL_AC_FIRST_ONLINE_PGDAT
  61         SPL_AC_NEXT_ONLINE_PGDAT
  62         SPL_AC_NEXT_ZONE
  63         SPL_AC_PGDAT_LIST
  64         SPL_AC_GLOBAL_PAGE_STATE
  65         SPL_AC_ZONE_STAT_ITEM_FREE
  66         SPL_AC_ZONE_STAT_ITEM_INACTIVE
  67         SPL_AC_ZONE_STAT_ITEM_ACTIVE
  68         SPL_AC_GET_ZONE_COUNTS
  69         SPL_AC_SET_FS_PWD
  70         SPL_AC_2ARGS_SET_FS_PWD
  71         SPL_AC_2ARGS_VFS_UNLINK
  72         SPL_AC_4ARGS_VFS_RENAME
  73         SPL_AC_CRED_STRUCT
  74         SPL_AC_GROUPS_SEARCH
  75         SPL_AC_PUT_TASK_STRUCT
  76 ])
  77
  78 AC_DEFUN([SPL_AC_MODULE_SYMVERS], [
  79         modpost=$LINUX/scripts/Makefile.modpost
  80         AC_MSG_CHECKING([kernel file name for module symbols])
  81         if test -f "$modpost"; then
  82                 if grep -q Modules.symvers $modpost; then
  83                         LINUX_SYMBOLS=Modules.symvers
  84                 else
  85                         LINUX_SYMBOLS=Module.symvers
  86                 fi
  87         else
  88                 LINUX_SYMBOLS=NONE
  89         fi
  90         AC_MSG_RESULT($LINUX_SYMBOLS)
  91         AC_SUBST(LINUX_SYMBOLS)
  92 ])
  93
  94 AC_DEFUN([SPL_AC_KERNEL], [
  95         AC_ARG_WITH([linux],
  96                 AS_HELP_STRING([--with-linux=PATH],
  97                 [Path to kernel source]),
  98                 [kernelsrc="$withval"])
  99
 100         AC_ARG_WITH([linux-obj],
 101                 AS_HELP_STRING([--with-linux-obj=PATH],
 102                 [Path to kernel build objects]),
 103                 [kernelbuild="$withval"])
 104
 105         AC_MSG_CHECKING([kernel source directory])
 106         if test -z "$kernelsrc"; then
 107                 sourcelink=`ls -1d /usr/src/kernels/* /usr/src/linux-* \
 108                             2>/dev/null | grep -v obj | tail -1`
 109
 110                 if test -e ${sourcelink}; then
 111                         kernelsrc=`readlink -f ${sourcelink}`
 112                 else
 113                         AC_MSG_RESULT([Not found])
 114                         AC_MSG_ERROR([
 115                         *** Please specify the location of the kernel source
 116                         *** with the '--with-linux=PATH' option])
 117                 fi
 118         else
 119                 if test "$kernelsrc" = "NONE"; then
 120                         kernsrcver=NONE
 121                 fi
 122         fi
 123
 124         AC_MSG_RESULT([$kernelsrc])
 125         AC_MSG_CHECKING([kernel build directory])
 126         if test -z "$kernelbuild"; then
 127                 if test -d ${kernelsrc}-obj/`arch`/`arch`; then
 128                         kernelbuild=${kernelsrc}-obj/`arch`/`arch`
 129                 elif test -d ${kernelsrc}-obj/`arch`/default; then
 130                         kernelbuild=${kernelsrc}-obj/`arch`/default
 131                 elif test -d `dirname ${kernelsrc}`/build-`arch`; then
 132                         kernelbuild=`dirname ${kernelsrc}`/build-`arch`
 133                 else
 134                         kernelbuild=${kernelsrc}
 135                 fi
 136         fi
 137         AC_MSG_RESULT([$kernelbuild])
 138
 139         AC_MSG_CHECKING([kernel source version])
 140         if test -r $kernelbuild/include/linux/version.h &&
 141                 fgrep -q UTS_RELEASE $kernelbuild/include/linux/version.h; then
 142
 143                 kernsrcver=`(echo "#include <linux/version.h>";
 144                              echo "kernsrcver=UTS_RELEASE") |
 145                              cpp -I $kernelbuild/include |
 146                              grep "^kernsrcver=" | cut -d \" -f 2`
 147
 148         elif test -r $kernelbuild/include/linux/utsrelease.h &&
 149                 fgrep -q UTS_RELEASE $kernelbuild/include/linux/utsrelease.h; then
 150
 151                 kernsrcver=`(echo "#include <linux/utsrelease.h>";
 152                              echo "kernsrcver=UTS_RELEASE") |
 153                              cpp -I $kernelbuild/include |
 154                              grep "^kernsrcver=" | cut -d \" -f 2`
 155         fi
 156
 157         if test -z "$kernsrcver"; then
 158                 AC_MSG_RESULT([Not found])
 159                 AC_MSG_ERROR([
 160                 *** Cannot determine the version of the linux kernel source.
 161                 *** Please prepare the kernel before running this script])
 162         fi
 163
 164         AC_MSG_RESULT([$kernsrcver])
 165
 166         LINUX=${kernelsrc}
 167         LINUX_OBJ=${kernelbuild}
 168         LINUX_VERSION=${kernsrcver}
 169
 170         AC_SUBST(LINUX)
 171         AC_SUBST(LINUX_OBJ)
 172         AC_SUBST(LINUX_VERSION)
 173
 174         SPL_AC_MODULE_SYMVERS
 175 ])
 176
 177 dnl #
 178 dnl # Default SPL user configuration
 179 dnl #
 180 AC_DEFUN([SPL_AC_CONFIG_USER], [])
 181
 182 AC_DEFUN([SPL_AC_LICENSE], [
 183         AC_MSG_CHECKING([spl license])
 184         LICENSE=GPL
 185         AC_MSG_RESULT([$LICENSE])
 186         KERNELCPPFLAGS="${KERNELCPPFLAGS} -DHAVE_GPL_ONLY_SYMBOLS"
 187         AC_SUBST(LICENSE)
 188 ])
 189
 190 AC_DEFUN([SPL_AC_CONFIG], [
 191         SPL_CONFIG=all
 192         AC_ARG_WITH([config],
 193                 AS_HELP_STRING([--with-config=CONFIG],
 194                 [Config file 'kernel|user|all|srpm']),
 195                 [SPL_CONFIG="$withval"])
 196
 197         AC_MSG_CHECKING([spl config])
 198         AC_MSG_RESULT([$SPL_CONFIG]);
 199         AC_SUBST(SPL_CONFIG)
 200
 201         case "$SPL_CONFIG" in
 202                 kernel) SPL_AC_CONFIG_KERNEL ;;
 203                 user)   SPL_AC_CONFIG_USER   ;;
 204                 all)    SPL_AC_CONFIG_KERNEL
 205                         SPL_AC_CONFIG_USER   ;;
 206                 srpm)                        ;;
 207                 *)
 208                 AC_MSG_RESULT([Error!])
 209                 AC_MSG_ERROR([Bad value "$SPL_CONFIG" for --with-config,
 210                               user kernel|user|all|srpm]) ;;
 211         esac
 212
 213         AM_CONDITIONAL([CONFIG_USER],
 214                        [test "$SPL_CONFIG" = user] ||
 215                        [test "$SPL_CONFIG" = all])
 216         AM_CONDITIONAL([CONFIG_KERNEL],
 217                        [test "$SPL_CONFIG" = kernel] ||
 218                        [test "$SPL_CONFIG" = all])
 219 ])
 220
 221 dnl #
 222 dnl # Enable if the SPL should be compiled with internal debugging enabled.
 223 dnl # By default this support is disabled.
 224 dnl #
 225 AC_DEFUN([SPL_AC_DEBUG], [
 226         AC_ARG_ENABLE([debug],
 227                 [AS_HELP_STRING([--enable-debug],
 228                 [Enable generic debug support @<:@default=no@:>@])],
 229                 [],
 230                 [enable_debug=no])
 231
 232         AS_IF([test "x$enable_debug" = xyes],
 233                 [KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG"],
 234                 [KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG"])
 235
 236         AC_MSG_CHECKING([whether debugging is enabled])
 237         AC_MSG_RESULT([$enable_debug])
 238 ])
 239
 240 dnl #
 241 dnl # Enabled by default it provides a minimal level of memory tracking.
 242 dnl # A total count of bytes allocated is kept for each alloc and free.
 243 dnl # Then at module unload time a report to the console will be printed
 244 dnl # if memory was leaked.  Additionally, /proc/spl/kmem/slab will exist
 245 dnl # and provide an easy way to inspect the kmem based slab.
 246 dnl #
 247 AC_DEFUN([SPL_AC_DEBUG_KMEM], [
 248         AC_ARG_ENABLE([debug-kmem],
 249                 [AS_HELP_STRING([--enable-debug-kmem],
 250                 [Enable basic kmem accounting @<:@default=yes@:>@])],
 251                 [],
 252                 [enable_debug_kmem=yes])
 253
 254         AS_IF([test "x$enable_debug_kmem" = xyes],
 255                 [AC_DEFINE([DEBUG_KMEM], [1],
 256                 [Define to 1 to enable basic kmem accounting])
 257                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM"])
 258
 259         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 260         AC_MSG_RESULT([$enable_debug_kmem])
 261 ])
 262
 263 dnl #
 264 dnl # Disabled by default it provides detailed memory tracking.  This
 265 dnl # feature also requires --enable-debug-kmem to be set.  When enabled
 266 dnl # not only will total bytes be tracked but also the location of every
 267 dnl # alloc and free.  When the SPL module is unloaded a list of all leaked
 268 dnl # addresses and where they were allocated will be dumped to the console.
 269 dnl # Enabling this feature has a significant impact on performance but it
 270 dnl # makes finding memory leaks pretty straight forward.
 271 dnl #
 272 AC_DEFUN([SPL_AC_DEBUG_KMEM_TRACKING], [
 273         AC_ARG_ENABLE([debug-kmem-tracking],
 274                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 275                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 276                 [],
 277                 [enable_debug_kmem_tracking=no])
 278
 279         AS_IF([test "x$enable_debug_kmem_tracking" = xyes],
 280                 [AC_DEFINE([DEBUG_KMEM_TRACKING], [1],
 281                 [Define to 1 to enable detailed kmem tracking])
 282                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM_TRACKING"])
 283
 284         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 285         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 286 ])
 287
 288 dnl #
 289 dnl # Use the atomic implemenation based on global spinlocks.  This
 290 dnl # should never be needed, however it has been left in place as
 291 dnl # a fallback option in case problems are observed with directly
 292 dnl # mapping to the native Linux atomic operations.
 293 dnl #
 294 AC_DEFUN([SPL_AC_ATOMIC_SPINLOCK], [
 295         AC_ARG_ENABLE([atomic-spinlocks],
 296                 [AS_HELP_STRING([--enable-atomic-spinlocks],
 297                 [Atomic types use spinlocks @<:@default=no@:>@])],
 298                 [],
 299                 [enable_atomic_spinlocks=no])
 300
 301         AS_IF([test "x$enable_atomic_spinlocks" = xyes],
 302                 [AC_DEFINE([ATOMIC_SPINLOCK], [1],
 303                 [Atomic types use spinlocks])])
 304
 305         AC_MSG_CHECKING([whether atomic types use spinlocks])
 306         AC_MSG_RESULT([$enable_atomic_spinlocks])
 307 ])
 308
 309 dnl #
 310 dnl # SPL_LINUX_CONFTEST
 311 dnl #
 312 AC_DEFUN([SPL_LINUX_CONFTEST], [
 313 cat >conftest.c <<_ACEOF
 314 $1
 315 _ACEOF
 316 ])
 317
 318 dnl #
 319 dnl # SPL_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 320 dnl #
 321 m4_define([SPL_LANG_PROGRAM], [
 322 $1
 323 int
 324 main (void)
 325 {
 326 dnl Do *not* indent the following line: there may be CPP directives.
 327 dnl Don't move the `;' right after for the same reason.
 328 $2
 329   ;
 330   return 0;
 331 }
 332 ])
 333
 334 dnl #
 335 dnl # SPL_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 336 dnl #
 337 AC_DEFUN([SPL_LINUX_COMPILE_IFELSE], [
 338         m4_ifvaln([$1], [SPL_LINUX_CONFTEST([$1])])
 339         rm -Rf build && mkdir -p build
 340         echo "obj-m := conftest.o" >build/Makefile
 341         AS_IF(
 342                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])],
 343                 [$4],
 344                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 345         )
 346         rm -Rf build
 347 ])
 348
 349 dnl #
 350 dnl # SPL_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 351 dnl #
 352 AC_DEFUN([SPL_LINUX_TRY_COMPILE],
 353         [SPL_LINUX_COMPILE_IFELSE(
 354         [AC_LANG_SOURCE([SPL_LANG_PROGRAM([[$1]], [[$2]])])],
 355         [modules],
 356         [test -s build/conftest.o],
 357         [$3], [$4])
 358 ])
 359
 360 dnl #
 361 dnl # SPL_LINUX_CONFIG
 362 dnl #
 363 AC_DEFUN([SPL_LINUX_CONFIG],
 364         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 365         SPL_LINUX_TRY_COMPILE([
 366                 #ifndef AUTOCONF_INCLUDED
 367                 #include <linux/config.h>
 368                 #endif
 369         ],[
 370                 #ifndef CONFIG_$1
 371                 #error CONFIG_$1 not #defined
 372                 #endif
 373         ],[
 374                 AC_MSG_RESULT([yes])
 375                 $2
 376         ],[
 377                 AC_MSG_RESULT([no])
 378                 $3
 379         ])
 380 ])
 381
 382 dnl #
 383 dnl # SPL_CHECK_SYMBOL_EXPORT
 384 dnl # check symbol exported or not
 385 dnl #
 386 AC_DEFUN([SPL_CHECK_SYMBOL_EXPORT],
 387         [AC_MSG_CHECKING([whether symbol $1 is exported])
 388         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 389                 $LINUX_OBJ/Module*.symvers 2>/dev/null
 390         rc=$?
 391         if test $rc -ne 0; then
 392                 export=0
 393                 for file in $2; do
 394                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 395                                 "$LINUX_OBJ/$file" 2>/dev/null
 396                         rc=$?
 397                         if test $rc -eq 0; then
 398                                 export=1
 399                                 break;
 400                         fi
 401                 done
 402                 if test $export -eq 0; then
 403                         AC_MSG_RESULT([no])
 404                         $4
 405                 else
 406                         AC_MSG_RESULT([yes])
 407                         $3
 408                 fi
 409         else
 410                 AC_MSG_RESULT([yes])
 411                 $3
 412         fi
 413 ])
 414
 415 dnl #
 416 dnl # SPL_CHECK_HEADER
 417 dnl # check whether header exists and define HAVE_$2_HEADER
 418 dnl #
 419 AC_DEFUN([SPL_CHECK_HEADER],
 420         [AC_MSG_CHECKING([whether header $1 exists])
 421         SPL_LINUX_TRY_COMPILE([
 422                 #include <$1>
 423         ],[
 424                 return 0;
 425         ],[
 426                 AC_DEFINE(HAVE_$2_HEADER, 1, [$1 exists])
 427                 AC_MSG_RESULT(yes)
 428                 $3
 429         ],[
 430                 AC_MSG_RESULT(no)
 431                 $4
 432         ])
 433 ])
 434
 435 dnl #
 436 dnl # 2.6.24 API change,
 437 dnl # check if uintptr_t typedef is defined
 438 dnl #
 439 AC_DEFUN([SPL_AC_TYPE_UINTPTR_T],
 440         [AC_MSG_CHECKING([whether kernel defines uintptr_t])
 441         SPL_LINUX_TRY_COMPILE([
 442                 #include <linux/types.h>
 443         ],[
 444                 uintptr_t *ptr;
 445         ],[
 446                 AC_MSG_RESULT([yes])
 447                 AC_DEFINE(HAVE_UINTPTR_T, 1,
 448                           [kernel defines uintptr_t])
 449         ],[
 450                 AC_MSG_RESULT([no])
 451         ])
 452 ])
 453
 454 dnl #
 455 dnl # 2.6.x API change,
 456 dnl # check if atomic64_t typedef is defined
 457 dnl #
 458 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_T],
 459         [AC_MSG_CHECKING([whether kernel defines atomic64_t])
 460         SPL_LINUX_TRY_COMPILE([
 461                 #include <asm/atomic.h>
 462         ],[
 463                 atomic64_t *ptr;
 464         ],[
 465                 AC_MSG_RESULT([yes])
 466                 AC_DEFINE(HAVE_ATOMIC64_T, 1,
 467                           [kernel defines atomic64_t])
 468         ],[
 469                 AC_MSG_RESULT([no])
 470         ])
 471 ])
 472
 473 dnl #
 474 dnl # 2.6.24 API change,
 475 dnl # check if atomic64_cmpxchg is defined
 476 dnl #
 477 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_CMPXCHG],
 478         [AC_MSG_CHECKING([whether kernel defines atomic64_cmpxchg])
 479         SPL_LINUX_TRY_COMPILE([
 480                 #include <asm/atomic.h>
 481         ],[
 482                 atomic64_cmpxchg((atomic64_t *)NULL, 0, 0);
 483         ],[
 484                 AC_MSG_RESULT([yes])
 485                 AC_DEFINE(HAVE_ATOMIC64_CMPXCHG, 1,
 486                           [kernel defines atomic64_cmpxchg])
 487         ],[
 488                 AC_MSG_RESULT([no])
 489         ])
 490 ])
 491
 492 dnl #
 493 dnl # 2.6.24 API change,
 494 dnl # check if atomic64_xchg is defined
 495 dnl #
 496 AC_DEFUN([SPL_AC_TYPE_ATOMIC64_XCHG],
 497         [AC_MSG_CHECKING([whether kernel defines atomic64_xchg])
 498         SPL_LINUX_TRY_COMPILE([
 499                 #include <asm/atomic.h>
 500         ],[
 501                 atomic64_xchg((atomic64_t *)NULL, 0);
 502         ],[
 503                 AC_MSG_RESULT([yes])
 504                 AC_DEFINE(HAVE_ATOMIC64_XCHG, 1,
 505                           [kernel defines atomic64_xchg])
 506         ],[
 507                 AC_MSG_RESULT([no])
 508         ])
 509 ])
 510
 511 dnl #
 512 dnl # 2.6.20 API change,
 513 dnl # INIT_WORK use 2 args and not store data inside
 514 dnl #
 515 AC_DEFUN([SPL_AC_3ARGS_INIT_WORK],
 516         [AC_MSG_CHECKING([whether INIT_WORK wants 3 args])
 517         SPL_LINUX_TRY_COMPILE([
 518                 #include <linux/workqueue.h>
 519         ],[
 520                 struct work_struct work;
 521                 INIT_WORK(&work, NULL, NULL);
 522         ],[
 523                 AC_MSG_RESULT(yes)
 524                 AC_DEFINE(HAVE_3ARGS_INIT_WORK, 1,
 525                           [INIT_WORK wants 3 args])
 526         ],[
 527                 AC_MSG_RESULT(no)
 528         ])
 529 ])
 530
 531 dnl #
 532 dnl # 2.6.21 API change,
 533 dnl # 'register_sysctl_table' use only one argument instead of two
 534 dnl #
 535 AC_DEFUN([SPL_AC_2ARGS_REGISTER_SYSCTL],
 536         [AC_MSG_CHECKING([whether register_sysctl_table() wants 2 args])
 537         SPL_LINUX_TRY_COMPILE([
 538                 #include <linux/sysctl.h>
 539         ],[
 540                 return register_sysctl_table(NULL,0);
 541         ],[
 542                 AC_MSG_RESULT(yes)
 543                 AC_DEFINE(HAVE_2ARGS_REGISTER_SYSCTL, 1,
 544                           [register_sysctl_table() wants 2 args])
 545         ],[
 546                 AC_MSG_RESULT(no)
 547         ])
 548 ])
 549
 550 dnl #
 551 dnl # 2.6.23 API change
 552 dnl # Old set_shrinker API replaced with register_shrinker
 553 dnl #
 554 AC_DEFUN([SPL_AC_SET_SHRINKER], [
 555         AC_MSG_CHECKING([whether set_shrinker() available])
 556         SPL_LINUX_TRY_COMPILE([
 557                 #include <linux/mm.h>
 558         ],[
 559                 return set_shrinker(DEFAULT_SEEKS, NULL);
 560         ],[
 561                 AC_MSG_RESULT([yes])
 562                 AC_DEFINE(HAVE_SET_SHRINKER, 1,
 563                           [set_shrinker() available])
 564         ],[
 565                 AC_MSG_RESULT([no])
 566         ])
 567 ])
 568
 569 dnl #
 570 dnl # 2.6.25 API change,
 571 dnl # struct path entry added to struct nameidata
 572 dnl #
 573 AC_DEFUN([SPL_AC_PATH_IN_NAMEIDATA],
 574         [AC_MSG_CHECKING([whether struct path used in struct nameidata])
 575         SPL_LINUX_TRY_COMPILE([
 576                 #include <linux/namei.h>
 577         ],[
 578                 struct nameidata nd;
 579
 580                 nd.path.mnt = NULL;
 581                 nd.path.dentry = NULL;
 582         ],[
 583                 AC_MSG_RESULT(yes)
 584                 AC_DEFINE(HAVE_PATH_IN_NAMEIDATA, 1,
 585                           [struct path used in struct nameidata])
 586         ],[
 587                 AC_MSG_RESULT(no)
 588         ])
 589 ])
 590
 591 dnl #
 592 dnl # Custom SPL patch may export this system it is not required
 593 dnl #
 594 AC_DEFUN([SPL_AC_TASK_CURR], [
 595         SPL_CHECK_SYMBOL_EXPORT([task_curr], [kernel/sched.c],
 596                 [AC_DEFINE(HAVE_TASK_CURR, 1, [task_curr() exported])],
 597                 [])
 598 ])
 599
 600 dnl #
 601 dnl # 2.6.19 API change,
 602 dnl # Use CTL_UNNUMBERED when binary sysctl is not required
 603 dnl #
 604 AC_DEFUN([SPL_AC_CTL_UNNUMBERED],
 605         [AC_MSG_CHECKING([whether unnumbered sysctl support exists])
 606         SPL_LINUX_TRY_COMPILE([
 607                 #include <linux/sysctl.h>
 608         ],[
 609                 #ifndef CTL_UNNUMBERED
 610                 #error CTL_UNNUMBERED undefined
 611                 #endif
 612         ],[
 613                 AC_MSG_RESULT(yes)
 614                 AC_DEFINE(HAVE_CTL_UNNUMBERED, 1,
 615                           [unnumbered sysctl support exists])
 616         ],[
 617                 AC_MSG_RESULT(no)
 618         ])
 619 ])
 620
 621 dnl #
 622 dnl # 2.6.16 API change.
 623 dnl # Check if 'fls64()' is available
 624 dnl #
 625 AC_DEFUN([SPL_AC_FLS64],
 626         [AC_MSG_CHECKING([whether fls64() is available])
 627         SPL_LINUX_TRY_COMPILE([
 628                 #include <linux/bitops.h>
 629         ],[
 630                 return fls64(0);
 631         ],[
 632                 AC_MSG_RESULT(yes)
 633                 AC_DEFINE(HAVE_FLS64, 1, [fls64() is available])
 634         ],[
 635                 AC_MSG_RESULT(no)
 636         ])
 637 ])
 638
 639 dnl #
 640 dnl # 2.6.18 API change, check whether device_create() is available.
 641 dnl # Device_create() was introduced in 2.6.18 and depricated
 642 dnl # class_device_create() which was fully removed in 2.6.26.
 643 dnl #
 644 AC_DEFUN([SPL_AC_DEVICE_CREATE], [
 645         SPL_CHECK_SYMBOL_EXPORT(
 646                 [device_create],
 647                 [drivers/base/core.c],
 648                 [AC_DEFINE(HAVE_DEVICE_CREATE, 1,
 649                 [device_create() is available])],
 650                 [])
 651 ])
 652
 653 dnl #
 654 dnl # 2.6.27 API change,
 655 dnl # device_create() uses 5 args, new 'drvdata' argument.
 656 dnl #
 657 AC_DEFUN([SPL_AC_5ARGS_DEVICE_CREATE], [
 658         AC_MSG_CHECKING([whether device_create() wants 5 args])
 659         tmp_flags="$EXTRA_KCFLAGS"
 660         EXTRA_KCFLAGS="-Werror"
 661         SPL_LINUX_TRY_COMPILE([
 662                 #include <linux/device.h>
 663         ],[
 664                 device_create(NULL, NULL, 0, NULL, "%d", 1);
 665         ],[
 666                 AC_MSG_RESULT(yes)
 667                 AC_DEFINE(HAVE_5ARGS_DEVICE_CREATE, 1,
 668                           [device_create wants 5 args])
 669         ],[
 670                 AC_MSG_RESULT(no)
 671         ])
 672         EXTRA_KCFLAGS="$tmp_flags"
 673 ])
 674
 675 dnl #
 676 dnl # 2.6.13 API change, check whether class_device_create() is available.
 677 dnl # Class_device_create() was introduced in 2.6.13 and depricated
 678 dnl # class_simple_device_add() which was fully removed in 2.6.13.
 679 dnl #
 680 AC_DEFUN([SPL_AC_CLASS_DEVICE_CREATE], [
 681         SPL_CHECK_SYMBOL_EXPORT(
 682                 [class_device_create],
 683                 [drivers/base/class.c],
 684                 [AC_DEFINE(HAVE_CLASS_DEVICE_CREATE, 1,
 685                 [class_device_create() is available])],
 686                 [])
 687 ])
 688
 689 dnl #
 690 dnl # 2.6.26 API change, set_normalized_timespec() is exported.
 691 dnl #
 692 AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_EXPORT], [
 693         SPL_CHECK_SYMBOL_EXPORT(
 694                 [set_normalized_timespec],
 695                 [kernel/time.c],
 696                 [AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_EXPORT, 1,
 697                 [set_normalized_timespec() is available as export])],
 698                 [])
 699 ])
 700
 701 dnl #
 702 dnl # 2.6.16 API change, set_normalize_timespec() moved to time.c
 703 dnl # previously it was available in time.h as an inline.
 704 dnl #
 705 AC_DEFUN([SPL_AC_SET_NORMALIZED_TIMESPEC_INLINE], [
 706         AC_MSG_CHECKING([whether set_normalized_timespec() is an inline])
 707         SPL_LINUX_TRY_COMPILE([
 708                 #include <linux/time.h>
 709                 void set_normalized_timespec(struct timespec *ts,
 710                                              time_t sec, long nsec) { }
 711         ],
 712         [],
 713         [
 714                 AC_MSG_RESULT(no)
 715         ],[
 716                 AC_MSG_RESULT(yes)
 717                 AC_DEFINE(HAVE_SET_NORMALIZED_TIMESPEC_INLINE, 1,
 718                           [set_normalized_timespec() is available as inline])
 719         ])
 720 ])
 721
 722 dnl #
 723 dnl # 2.6.18 API change,
 724 dnl # timespec_sub() inline function available in linux/time.h
 725 dnl #
 726 AC_DEFUN([SPL_AC_TIMESPEC_SUB], [
 727         AC_MSG_CHECKING([whether timespec_sub() is available])
 728         SPL_LINUX_TRY_COMPILE([
 729                 #include <linux/time.h>
 730         ],[
 731                 struct timespec a, b, c = { 0 };
 732                 c = timespec_sub(a, b);
 733         ],[
 734                 AC_MSG_RESULT(yes)
 735                 AC_DEFINE(HAVE_TIMESPEC_SUB, 1, [timespec_sub() is available])
 736         ],[
 737                 AC_MSG_RESULT(no)
 738         ])
 739 ])
 740
 741 dnl #
 742 dnl # 2.6.19 API change,
 743 dnl # check if init_utsname() is available in linux/utsname.h
 744 dnl #
 745 AC_DEFUN([SPL_AC_INIT_UTSNAME], [
 746         AC_MSG_CHECKING([whether init_utsname() is available])
 747         SPL_LINUX_TRY_COMPILE([
 748                 #include <linux/utsname.h>
 749         ],[
 750                 struct new_utsname *a = init_utsname();
 751         ],[
 752                 AC_MSG_RESULT(yes)
 753                 AC_DEFINE(HAVE_INIT_UTSNAME, 1, [init_utsname() is available])
 754         ],[
 755                 AC_MSG_RESULT(no)
 756         ])
 757 ])
 758
 759 dnl #
 760 dnl # 2.6.26 API change,
 761 dnl # definition of struct fdtable relocated to linux/fdtable.h
 762 dnl #
 763 AC_DEFUN([SPL_AC_FDTABLE_HEADER], [
 764         SPL_CHECK_HEADER([linux/fdtable.h], [FDTABLE], [], [])
 765 ])
 766
 767 dnl #
 768 dnl # 2.6.14 API change,
 769 dnl # check whether 'files_fdtable()' exists
 770 dnl #
 771 AC_DEFUN([SPL_AC_FILES_FDTABLE], [
 772         AC_MSG_CHECKING([whether files_fdtable() is available])
 773         SPL_LINUX_TRY_COMPILE([
 774                 #include <linux/sched.h>
 775                 #include <linux/file.h>
 776                 #ifdef HAVE_FDTABLE_HEADER
 777                 #include <linux/fdtable.h>
 778                 #endif
 779         ],[
 780                 struct files_struct *files = current->files;
 781                 struct fdtable *fdt = files_fdtable(files);
 782         ],[
 783                 AC_MSG_RESULT(yes)
 784                 AC_DEFINE(HAVE_FILES_FDTABLE, 1, [files_fdtable() is available])
 785         ],[
 786                 AC_MSG_RESULT(no)
 787         ])
 788 ])
 789
 790 dnl #
 791 dnl # 2.6.18 API change,
 792 dnl # added linux/uaccess.h
 793 dnl #
 794 AC_DEFUN([SPL_AC_UACCESS_HEADER], [
 795         SPL_CHECK_HEADER([linux/uaccess.h], [UACCESS], [], [])
 796 ])
 797
 798 dnl #
 799 dnl # 2.6.12 API change,
 800 dnl # check whether 'kmalloc_node()' is available.
 801 dnl #
 802 AC_DEFUN([SPL_AC_KMALLOC_NODE], [
 803         AC_MSG_CHECKING([whether kmalloc_node() is available])
 804         SPL_LINUX_TRY_COMPILE([
 805                 #include <linux/slab.h>
 806         ],[
 807                 void *a = kmalloc_node(1, GFP_KERNEL, 0);
 808         ],[
 809                 AC_MSG_RESULT(yes)
 810                 AC_DEFINE(HAVE_KMALLOC_NODE, 1, [kmalloc_node() is available])
 811         ],[
 812                 AC_MSG_RESULT(no)
 813         ])
 814 ])
 815
 816 dnl #
 817 dnl # 2.6.9 API change,
 818 dnl # check whether 'monotonic_clock()' is available it may
 819 dnl # be available for some archs but not others.
 820 dnl #
 821 AC_DEFUN([SPL_AC_MONOTONIC_CLOCK], [
 822         SPL_CHECK_SYMBOL_EXPORT(
 823                 [monotonic_clock],
 824                 [],
 825                 [AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1,
 826                 [monotonic_clock() is available])],
 827                 [])
 828 ])
 829
 830 dnl #
 831 dnl # 2.6.16 API change,
 832 dnl # check whether 'struct inode' has i_mutex
 833 dnl #
 834 AC_DEFUN([SPL_AC_INODE_I_MUTEX], [
 835         AC_MSG_CHECKING([whether struct inode has i_mutex])
 836         SPL_LINUX_TRY_COMPILE([
 837                 #include <linux/fs.h>
 838                 #include <linux/mutex.h>
 839         ],[
 840                 struct inode i;
 841                 mutex_init(&i.i_mutex);
 842         ],[
 843                 AC_MSG_RESULT(yes)
 844                 AC_DEFINE(HAVE_INODE_I_MUTEX, 1, [struct inode has i_mutex])
 845         ],[
 846                 AC_MSG_RESULT(no)
 847         ])
 848 ])
 849
 850 dnl #
 851 dnl # 2.6.29 API change,
 852 dnl # Adaptive mutexs introduced.
 853 dnl #
 854 AC_DEFUN([SPL_AC_MUTEX_OWNER], [
 855         AC_MSG_CHECKING([whether struct mutex has owner])
 856         SPL_LINUX_TRY_COMPILE([
 857                 #include <linux/mutex.h>
 858         ],[
 859                 struct mutex mtx;
 860                 mtx.owner = NULL;
 861         ],[
 862                 AC_MSG_RESULT(yes)
 863                 AC_DEFINE(HAVE_MUTEX_OWNER, 1, [struct mutex has owner])
 864         ],[
 865                 AC_MSG_RESULT(no)
 866         ])
 867 ])
 868
 869 dnl #
 870 dnl # 2.6.18 API change,
 871 dnl # First introduced 'mutex_lock_nested()' in include/linux/mutex.h,
 872 dnl # as part of the mutex validator.  Fallback to using 'mutex_lock()'
 873 dnl # if the mutex validator is disabled or otherwise unavailable.
 874 dnl #
 875 AC_DEFUN([SPL_AC_MUTEX_LOCK_NESTED], [
 876         AC_MSG_CHECKING([whether mutex_lock_nested() is available])
 877         SPL_LINUX_TRY_COMPILE([
 878                 #include <linux/mutex.h>
 879         ],[
 880                 struct mutex mutex;
 881                 mutex_init(&mutex);
 882                 mutex_lock_nested(&mutex, 0);
 883         ],[
 884                 AC_MSG_RESULT(yes)
 885                 AC_DEFINE(HAVE_MUTEX_LOCK_NESTED, 1,
 886                 [mutex_lock_nested() is available])
 887         ],[
 888                 AC_MSG_RESULT(no)
 889         ])
 890 ])
 891
 892 dnl #
 893 dnl # 2.6.22 API change,
 894 dnl # First introduced 'div64_64()' in lib/div64.c
 895 dnl
 896 AC_DEFUN([SPL_AC_DIV64_64], [
 897         SPL_CHECK_SYMBOL_EXPORT(
 898                 [div64_64],
 899                 [],
 900                 [AC_DEFINE(HAVE_DIV64_64, 1,
 901                 [div64_64() is available])],
 902                 [])
 903 ])
 904
 905 dnl #
 906 dnl # 2.6.26 API change,
 907 dnl # Renamed 'div64_64()' to 'div64_u64' in lib/div64.c
 908 dnl #
 909 AC_DEFUN([SPL_AC_DIV64_U64], [
 910         SPL_CHECK_SYMBOL_EXPORT(
 911                 [div64_u64],
 912                 [],
 913                 [AC_DEFINE(HAVE_DIV64_U64, 1,
 914                 [div64_u64() is available])],
 915                 [])
 916 ])
 917
 918 dnl #
 919 dnl # 2.6.27 API change,
 920 dnl # on_each_cpu() uses 3 args, no 'retry' argument
 921 dnl #
 922 AC_DEFUN([SPL_AC_3ARGS_ON_EACH_CPU], [
 923         AC_MSG_CHECKING([whether on_each_cpu() wants 3 args])
 924         SPL_LINUX_TRY_COMPILE([
 925                 #include <linux/smp.h>
 926         ],[
 927                 on_each_cpu(NULL, NULL, 0);
 928         ],[
 929                 AC_MSG_RESULT(yes)
 930                 AC_DEFINE(HAVE_3ARGS_ON_EACH_CPU, 1,
 931                           [on_each_cpu wants 3 args])
 932         ],[
 933                 AC_MSG_RESULT(no)
 934         ])
 935 ])
 936
 937 dnl #
 938 dnl # 2.6.18 API change,
 939 dnl # kallsyms_lookup_name no longer exported
 940 dnl #
 941 AC_DEFUN([SPL_AC_KALLSYMS_LOOKUP_NAME], [
 942         SPL_CHECK_SYMBOL_EXPORT(
 943                 [kallsyms_lookup_name],
 944                 [],
 945                 [AC_DEFINE(HAVE_KALLSYMS_LOOKUP_NAME, 1,
 946                 [kallsyms_lookup_name() is available])],
 947                 [])
 948 ])
 949
 950 dnl #
 951 dnl # Proposed API change,
 952 dnl # This symbol is not available in stock kernels.  You may build a
 953 dnl # custom kernel with the *-spl-export-symbols.patch which will export
 954 dnl # these symbols for use.  If your already rolling a custom kernel for
 955 dnl # your environment this is recommended.
 956 dnl #
 957 AC_DEFUN([SPL_AC_GET_VMALLOC_INFO], [
 958         SPL_CHECK_SYMBOL_EXPORT(
 959                 [get_vmalloc_info],
 960                 [],
 961                 [AC_DEFINE(HAVE_GET_VMALLOC_INFO, 1,
 962                 [get_vmalloc_info() is available])],
 963                 [])
 964 ])
 965
 966 dnl #
 967 dnl # 2.6.17 API change
 968 dnl # The helper functions first_online_pgdat(), next_online_pgdat(), and
 969 dnl # next_zone() are introduced to simplify for_each_zone().  These symbols
 970 dnl # were exported in 2.6.17 for use by modules which was consistent with
 971 dnl # the previous implementation of for_each_zone().  From 2.6.18 - 2.6.19
 972 dnl # the symbols were exported as 'unused', and by 2.6.20 they exports
 973 dnl # were dropped entirely leaving modules no way to directly iterate over
 974 dnl # the zone list.  Because we need access to the zone helpers we check
 975 dnl # if the kernel contains the old or new implementation.  Then we check
 976 dnl # to see if the symbols we need for each version are available.  If they
 977 dnl # are not, dynamically aquire the addresses with kallsyms_lookup_name().
 978 dnl #
 979 AC_DEFUN([SPL_AC_PGDAT_HELPERS], [
 980         AC_MSG_CHECKING([whether symbol *_pgdat exist])
 981         grep -q -E 'first_online_pgdat' $LINUX/include/linux/mmzone.h 2>/dev/null
 982         rc=$?
 983         if test $rc -eq 0; then
 984                 AC_MSG_RESULT([yes])
 985                 AC_DEFINE(HAVE_PGDAT_HELPERS, 1, [pgdat helpers are available])
 986         else
 987                 AC_MSG_RESULT([no])
 988         fi
 989 ])
 990
 991 dnl #
 992 dnl # Proposed API change,
 993 dnl # This symbol is not available in stock kernels.  You may build a
 994 dnl # custom kernel with the *-spl-export-symbols.patch which will export
 995 dnl # these symbols for use.  If your already rolling a custom kernel for
 996 dnl # your environment this is recommended.
 997 dnl #
 998 AC_DEFUN([SPL_AC_FIRST_ONLINE_PGDAT], [
 999         SPL_CHECK_SYMBOL_EXPORT(
1000                 [first_online_pgdat],
1001                 [],
1002                 [AC_DEFINE(HAVE_FIRST_ONLINE_PGDAT, 1,
1003                 [first_online_pgdat() is available])],
1004                 [])
1005 ])
1006
1007 dnl #
1008 dnl # Proposed API change,
1009 dnl # This symbol is not available in stock kernels.  You may build a
1010 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1011 dnl # these symbols for use.  If your already rolling a custom kernel for
1012 dnl # your environment this is recommended.
1013 dnl #
1014 AC_DEFUN([SPL_AC_NEXT_ONLINE_PGDAT], [
1015         SPL_CHECK_SYMBOL_EXPORT(
1016                 [next_online_pgdat],
1017                 [],
1018                 [AC_DEFINE(HAVE_NEXT_ONLINE_PGDAT, 1,
1019                 [next_online_pgdat() is available])],
1020                 [])
1021 ])
1022
1023 dnl #
1024 dnl # Proposed API change,
1025 dnl # This symbol is not available in stock kernels.  You may build a
1026 dnl # custom kernel with the *-spl-export-symbols.patch which will export
1027 dnl # these symbols for use.  If your already rolling a custom kernel for
1028 dnl # your environment this is recommended.
1029 dnl #
1030 AC_DEFUN([SPL_AC_NEXT_ZONE], [
1031         SPL_CHECK_SYMBOL_EXPORT(
1032                 [next_zone],
1033                 [],
1034                 [AC_DEFINE(HAVE_NEXT_ZONE, 1,
1035                 [next_zone() is available])],
1036                 [])
1037 ])
1038
1039 dnl #
1040 dnl # 2.6.17 API change,
1041 dnl # See SPL_AC_PGDAT_HELPERS for details.
1042 dnl #
1043 AC_DEFUN([SPL_AC_PGDAT_LIST], [
1044         SPL_CHECK_SYMBOL_EXPORT(
1045                 [pgdat_list],
1046                 [],
1047                 [AC_DEFINE(HAVE_PGDAT_LIST, 1,
1048                 [pgdat_list is available])],
1049                 [])
1050 ])
1051
1052 dnl #
1053 dnl # 2.6.18 API change,
1054 dnl # First introduced global_page_state() support as an inline.
1055 dnl #
1056 AC_DEFUN([SPL_AC_GLOBAL_PAGE_STATE], [
1057         AC_MSG_CHECKING([whether global_page_state() is available])
1058         SPL_LINUX_TRY_COMPILE([
1059                 #include <linux/mm.h>
1060         ],[
1061                 unsigned long state;
1062                 state = global_page_state(0);
1063         ],[
1064                 AC_MSG_RESULT(yes)
1065                 AC_DEFINE(HAVE_GLOBAL_PAGE_STATE, 1,
1066                           [global_page_state() is available])
1067         ],[
1068                 AC_MSG_RESULT(no)
1069         ])
1070 ])
1071
1072 dnl #
1073 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1074 dnl # Public global zone stats now include a free page count.  However
1075 dnl # the enumerated names of the counters have changed since this API
1076 dnl # was introduced.  We need to deduce the corrent name to use.  This
1077 dnl # replaces the priviate get_zone_counts() interface.
1078 dnl #
1079 dnl # NR_FREE_PAGES was available from 2.6.21 to current kernels, which
1080 dnl # is 2.6.30 as of when this was written.
1081 dnl #
1082 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_FREE], [
1083         AC_MSG_CHECKING([whether page state NR_FREE_PAGES is available])
1084         SPL_LINUX_TRY_COMPILE([
1085                 #include <linux/mm.h>
1086         ],[
1087                 enum zone_stat_item zsi;
1088                 zsi = NR_FREE_PAGES;
1089         ],[
1090                 AC_MSG_RESULT(yes)
1091                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_FREE_PAGES, 1,
1092                           [Page state NR_FREE_PAGES is available])
1093         ],[
1094                 AC_MSG_RESULT(no)
1095         ])
1096 ])
1097
1098 dnl #
1099 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1100 dnl # Public global zone stats now include an inactive page count.  However
1101 dnl # the enumerated names of the counters have changed since this API
1102 dnl # was introduced.  We need to deduce the corrent name to use.  This
1103 dnl # replaces the priviate get_zone_counts() interface.
1104 dnl #
1105 dnl # NR_INACTIVE was available from 2.6.21 to 2.6.27 and included both
1106 dnl # anonymous and file inactive pages.  As of 2.6.28 it was split in
1107 dnl # to NR_INACTIVE_ANON and NR_INACTIVE_FILE.
1108 dnl #
1109 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_INACTIVE], [
1110         AC_MSG_CHECKING([whether page state NR_INACTIVE is available])
1111         SPL_LINUX_TRY_COMPILE([
1112                 #include <linux/mm.h>
1113         ],[
1114                 enum zone_stat_item zsi;
1115                 zsi = NR_INACTIVE;
1116         ],[
1117                 AC_MSG_RESULT(yes)
1118                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE, 1,
1119                           [Page state NR_INACTIVE is available])
1120         ],[
1121                 AC_MSG_RESULT(no)
1122         ])
1123
1124         AC_MSG_CHECKING([whether page state NR_INACTIVE_ANON is available])
1125         SPL_LINUX_TRY_COMPILE([
1126                 #include <linux/mm.h>
1127         ],[
1128                 enum zone_stat_item zsi;
1129                 zsi = NR_INACTIVE_ANON;
1130         ],[
1131                 AC_MSG_RESULT(yes)
1132                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_ANON, 1,
1133                           [Page state NR_INACTIVE_ANON is available])
1134         ],[
1135                 AC_MSG_RESULT(no)
1136         ])
1137
1138         AC_MSG_CHECKING([whether page state NR_INACTIVE_FILE is available])
1139         SPL_LINUX_TRY_COMPILE([
1140                 #include <linux/mm.h>
1141         ],[
1142                 enum zone_stat_item zsi;
1143                 zsi = NR_INACTIVE_FILE;
1144         ],[
1145                 AC_MSG_RESULT(yes)
1146                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_FILE, 1,
1147                           [Page state NR_INACTIVE_FILE is available])
1148         ],[
1149                 AC_MSG_RESULT(no)
1150         ])
1151 ])
1152
1153 dnl #
1154 dnl # 2.6.21 API change (plus subsequent naming convention changes),
1155 dnl # Public global zone stats now include an active page count.  However
1156 dnl # the enumerated names of the counters have changed since this API
1157 dnl # was introduced.  We need to deduce the corrent name to use.  This
1158 dnl # replaces the priviate get_zone_counts() interface.
1159 dnl #
1160 dnl # NR_ACTIVE was available from 2.6.21 to 2.6.27 and included both
1161 dnl # anonymous and file active pages.  As of 2.6.28 it was split in
1162 dnl # to NR_ACTIVE_ANON and NR_ACTIVE_FILE.
1163 dnl #
1164 AC_DEFUN([SPL_AC_ZONE_STAT_ITEM_ACTIVE], [
1165         AC_MSG_CHECKING([whether page state NR_ACTIVE is available])
1166         SPL_LINUX_TRY_COMPILE([
1167                 #include <linux/mm.h>
1168         ],[
1169                 enum zone_stat_item zsi;
1170                 zsi = NR_ACTIVE;
1171         ],[
1172                 AC_MSG_RESULT(yes)
1173                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE, 1,
1174                           [Page state NR_ACTIVE is available])
1175         ],[
1176                 AC_MSG_RESULT(no)
1177         ])
1178
1179         AC_MSG_CHECKING([whether page state NR_ACTIVE_ANON is available])
1180         SPL_LINUX_TRY_COMPILE([
1181                 #include <linux/mm.h>
1182         ],[
1183                 enum zone_stat_item zsi;
1184                 zsi = NR_ACTIVE_ANON;
1185         ],[
1186                 AC_MSG_RESULT(yes)
1187                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_ANON, 1,
1188                           [Page state NR_ACTIVE_ANON is available])
1189         ],[
1190                 AC_MSG_RESULT(no)
1191         ])
1192
1193         AC_MSG_CHECKING([whether page state NR_ACTIVE_FILE is available])
1194         SPL_LINUX_TRY_COMPILE([
1195                 #include <linux/mm.h>
1196         ],[
1197                 enum zone_stat_item zsi;
1198                 zsi = NR_ACTIVE_FILE;
1199         ],[
1200                 AC_MSG_RESULT(yes)
1201                 AC_DEFINE(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_FILE, 1,
1202                           [Page state NR_ACTIVE_FILE is available])
1203         ],[
1204                 AC_MSG_RESULT(no)
1205         ])
1206 ])
1207
1208 dnl #
1209 dnl # Proposed API change for legacy kernels.
1210 dnl # This symbol is not available in older kernels.  For kernels post
1211 dnl # 2.6.21 the global_page_state() API is used to get free/inactive/active
1212 dnl # page state information.  This symbol is only used in legacy kernels
1213 dnl # any only as a last resort.
1214 dnl
1215 AC_DEFUN([SPL_AC_GET_ZONE_COUNTS], [
1216         AC_MSG_CHECKING([whether symbol get_zone_counts is needed])
1217         SPL_LINUX_TRY_COMPILE([
1218         ],[
1219                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_FREE_PAGES)
1220                 #error "global_page_state needs NR_FREE_PAGES"
1221                 #endif
1222
1223                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE) && \
1224                     !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_ANON) && \
1225                     !defined(HAVE_ZONE_STAT_ITEM_NR_ACTIVE_FILE)
1226                 #error "global_page_state needs NR_ACTIVE*"
1227                 #endif
1228
1229                 #if !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE) && \
1230                     !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_ANON) && \
1231                     !defined(HAVE_ZONE_STAT_ITEM_NR_INACTIVE_FILE)
1232                 #error "global_page_state needs NR_INACTIVE*"
1233                 #endif
1234         ],[
1235                 AC_MSG_RESULT(no)
1236         ],[
1237                 AC_MSG_RESULT(yes)
1238                 AC_DEFINE(NEED_GET_ZONE_COUNTS, 1,
1239                           [get_zone_counts() is needed])
1240
1241                 SPL_CHECK_SYMBOL_EXPORT(
1242                         [get_zone_counts],
1243                         [],
1244                         [AC_DEFINE(HAVE_GET_ZONE_COUNTS, 1,
1245                         [get_zone_counts() is available])],
1246                         [])
1247         ])
1248 ])
1249
1250 dnl #
1251 dnl # Symbol available in RHEL kernels not in stock kernels.
1252 dnl #
1253 AC_DEFUN([SPL_AC_SET_FS_PWD], [
1254         SPL_CHECK_SYMBOL_EXPORT(
1255                 [set_fs_pwd],
1256                 [],
1257                 [AC_DEFINE(HAVE_SET_FS_PWD, 1,
1258                 [set_fs_pwd() is available])],
1259                 [])
1260 ])
1261
1262 dnl #
1263 dnl # 2.6.25 API change,
1264 dnl # Simplied API by replacing mnt+dentry args with a single path arg.
1265 dnl #
1266 AC_DEFUN([SPL_AC_2ARGS_SET_FS_PWD],
1267         [AC_MSG_CHECKING([whether set_fs_pwd() wants 2 args])
1268         SPL_LINUX_TRY_COMPILE([
1269                 #include <linux/sched.h>
1270                 #include <linux/fs_struct.h>
1271         ],[
1272                 set_fs_pwd(NULL, NULL);
1273         ],[
1274                 AC_MSG_RESULT(yes)
1275                 AC_DEFINE(HAVE_2ARGS_SET_FS_PWD, 1,
1276                           [set_fs_pwd() wants 2 args])
1277         ],[
1278                 AC_MSG_RESULT(no)
1279         ])
1280 ])
1281
1282 dnl #
1283 dnl # SLES API change, never adopted in mainline,
1284 dnl # Third 'struct vfsmount *' argument removed.
1285 dnl #
1286 AC_DEFUN([SPL_AC_2ARGS_VFS_UNLINK],
1287         [AC_MSG_CHECKING([whether vfs_unlink() wants 2 args])
1288         SPL_LINUX_TRY_COMPILE([
1289                 #include <linux/fs.h>
1290         ],[
1291                 vfs_unlink(NULL, NULL);
1292         ],[
1293                 AC_MSG_RESULT(yes)
1294                 AC_DEFINE(HAVE_2ARGS_VFS_UNLINK, 1,
1295                           [vfs_unlink() wants 2 args])
1296         ],[
1297                 AC_MSG_RESULT(no)
1298         ])
1299 ])
1300
1301 dnl #
1302 dnl # SLES API change, never adopted in mainline,
1303 dnl # Third and sixth 'struct vfsmount *' argument removed.
1304 dnl #
1305 AC_DEFUN([SPL_AC_4ARGS_VFS_RENAME],
1306         [AC_MSG_CHECKING([whether vfs_rename() wants 4 args])
1307         SPL_LINUX_TRY_COMPILE([
1308                 #include <linux/fs.h>
1309         ],[
1310                 vfs_rename(NULL, NULL, NULL, NULL);
1311         ],[
1312                 AC_MSG_RESULT(yes)
1313                 AC_DEFINE(HAVE_4ARGS_VFS_RENAME, 1,
1314                           [vfs_rename() wants 4 args])
1315         ],[
1316                 AC_MSG_RESULT(no)
1317         ])
1318 ])
1319
1320 dnl #
1321 dnl # 2.6.29 API change,
1322 dnl # check whether 'struct cred' exists
1323 dnl #
1324 AC_DEFUN([SPL_AC_CRED_STRUCT], [
1325         AC_MSG_CHECKING([whether struct cred exists])
1326         SPL_LINUX_TRY_COMPILE([
1327                 #include <linux/cred.h>
1328         ],[
1329                 struct cred *cr;
1330                 cr  = NULL;
1331         ],[
1332                 AC_MSG_RESULT(yes)
1333                 AC_DEFINE(HAVE_CRED_STRUCT, 1, [struct cred exists])
1334         ],[
1335                 AC_MSG_RESULT(no)
1336         ])
1337 ])
1338
1339 dnl #
1340 dnl # Custom SPL patch may export this symbol.
1341 dnl #
1342 AC_DEFUN([SPL_AC_GROUPS_SEARCH], [
1343         SPL_CHECK_SYMBOL_EXPORT(
1344                 [groups_search],
1345                 [],
1346                 [AC_DEFINE(HAVE_GROUPS_SEARCH, 1,
1347                 [groups_search() is available])],
1348                 [])
1349 ])
1350
1351 dnl #
1352 dnl # 2.6.x API change,
1353 dnl # __put_task_struct() was exported in RHEL5 but unavailable elsewhere.
1354 dnl #
1355 AC_DEFUN([SPL_AC_PUT_TASK_STRUCT], [
1356         SPL_CHECK_SYMBOL_EXPORT(
1357                 [__put_task_struct],
1358                 [],
1359                 [AC_DEFINE(HAVE_PUT_TASK_STRUCT, 1,
1360                 [__put_task_struct() is available])],
1361                 [])
1362 ])