config/spl-build.m4

   1 ###############################################################################
   2 # Copyright (C) 2007-2010 Lawrence Livermore National Security, LLC.
   3 # Copyright (C) 2007 The Regents of the University of California.
   4 # Written by Brian Behlendorf <behlendorf1@llnl.gov>.
   5 ###############################################################################
   6 # SPL_AC_CONFIG_KERNEL: Default SPL kernel configuration.
   7 ###############################################################################
   8
   9 AC_DEFUN([SPL_AC_CONFIG_KERNEL], [
  10         SPL_AC_KERNEL
  11
  12         if test "${LINUX_OBJ}" != "${LINUX}"; then
  13                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  14         fi
  15         AC_SUBST(KERNELMAKE_PARAMS)
  16
  17         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wstrict-prototypes"
  18         AC_SUBST(KERNELCPPFLAGS)
  19
  20         SPL_AC_DEBUG
  21         SPL_AC_DEBUG_KMEM
  22         SPL_AC_DEBUG_KMEM_TRACKING
  23         SPL_AC_TEST_MODULE
  24         SPL_AC_ATOMIC_SPINLOCK
  25         SPL_AC_SHRINKER_CALLBACK
  26         SPL_AC_CTL_NAME
  27         SPL_AC_CONFIG_TRIM_UNUSED_KSYMS
  28         SPL_AC_PDE_DATA
  29         SPL_AC_SET_FS_PWD_WITH_CONST
  30         SPL_AC_2ARGS_VFS_UNLINK
  31         SPL_AC_4ARGS_VFS_RENAME
  32         SPL_AC_2ARGS_VFS_FSYNC
  33         SPL_AC_INODE_TRUNCATE_RANGE
  34         SPL_AC_FS_STRUCT_SPINLOCK
  35         SPL_AC_KUIDGID_T
  36         SPL_AC_PUT_TASK_STRUCT
  37         SPL_AC_KERNEL_FALLOCATE
  38         SPL_AC_CONFIG_ZLIB_INFLATE
  39         SPL_AC_CONFIG_ZLIB_DEFLATE
  40         SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  41         SPL_AC_SHRINK_CONTROL_STRUCT
  42         SPL_AC_RWSEM_SPINLOCK_IS_RAW
  43         SPL_AC_RWSEM_ACTIVITY
  44         SPL_AC_RWSEM_ATOMIC_LONG_COUNT
  45         SPL_AC_SCHED_RT_HEADER
  46         SPL_AC_2ARGS_VFS_GETATTR
  47         SPL_AC_USLEEP_RANGE
  48         SPL_AC_KMEM_CACHE_ALLOCFLAGS
  49         SPL_AC_WAIT_ON_BIT
  50         SPL_AC_MUTEX_OWNER
  51         SPL_AC_INODE_LOCK
  52         SPL_AC_GROUP_INFO_GID
  53 ])
  54
  55 AC_DEFUN([SPL_AC_MODULE_SYMVERS], [
  56         modpost=$LINUX/scripts/Makefile.modpost
  57         AC_MSG_CHECKING([kernel file name for module symbols])
  58         if test "x$enable_linux_builtin" != xyes -a -f "$modpost"; then
  59                 if grep -q Modules.symvers $modpost; then
  60                         LINUX_SYMBOLS=Modules.symvers
  61                 else
  62                         LINUX_SYMBOLS=Module.symvers
  63                 fi
  64
  65                 if ! test -f "$LINUX_OBJ/$LINUX_SYMBOLS"; then
  66                         AC_MSG_ERROR([
  67         *** Please make sure the kernel devel package for your distribution
  68         *** is installed.  If you are building with a custom kernel, make sure the
  69         *** kernel is configured, built, and the '--with-linux=PATH' configure
  70         *** option refers to the location of the kernel source.])
  71                 fi
  72         else
  73                 LINUX_SYMBOLS=NONE
  74         fi
  75         AC_MSG_RESULT($LINUX_SYMBOLS)
  76         AC_SUBST(LINUX_SYMBOLS)
  77 ])
  78
  79 AC_DEFUN([SPL_AC_KERNEL], [
  80         AC_ARG_WITH([linux],
  81                 AS_HELP_STRING([--with-linux=PATH],
  82                 [Path to kernel source]),
  83                 [kernelsrc="$withval"])
  84
  85         AC_ARG_WITH([linux-obj],
  86                 AS_HELP_STRING([--with-linux-obj=PATH],
  87                 [Path to kernel build objects]),
  88                 [kernelbuild="$withval"])
  89
  90         AC_MSG_CHECKING([kernel source directory])
  91         if test -z "$kernelsrc"; then
  92                 if test -e "/lib/modules/$(uname -r)/source"; then
  93                         headersdir="/lib/modules/$(uname -r)/source"
  94                         sourcelink=$(readlink -f "$headersdir")
  95                 elif test -e "/lib/modules/$(uname -r)/build"; then
  96                         headersdir="/lib/modules/$(uname -r)/build"
  97                         sourcelink=$(readlink -f "$headersdir")
  98                 else
  99                         sourcelink=$(ls -1d /usr/src/kernels/* \
 100                                      /usr/src/linux-* \
 101                                      2>/dev/null | grep -v obj | tail -1)
 102                 fi
 103
 104                 if test -n "$sourcelink" && test -e ${sourcelink}; then
 105                         kernelsrc=`readlink -f ${sourcelink}`
 106                 else
 107                         kernelsrc="[Not found]"
 108                 fi
 109         else
 110                 if test "$kernelsrc" = "NONE"; then
 111                         kernsrcver=NONE
 112                 fi
 113         fi
 114
 115         AC_MSG_RESULT([$kernelsrc])
 116         if test ! -d "$kernelsrc"; then
 117                 AC_MSG_ERROR([
 118         *** Please make sure the kernel devel package for your distribution
 119         *** is installed and then try again.  If that fails, you can specify the
 120         *** location of the kernel source with the '--with-linux=PATH' option.])
 121         fi
 122
 123         AC_MSG_CHECKING([kernel build directory])
 124         if test -z "$kernelbuild"; then
 125                 if test -e "/lib/modules/$(uname -r)/build"; then
 126                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 127                 elif test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}; then
 128                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 129                 elif test -d ${kernelsrc}-obj/${target_cpu}/default; then
 130                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 131                 elif test -d `dirname ${kernelsrc}`/build-${target_cpu}; then
 132                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 133                 else
 134                         kernelbuild=${kernelsrc}
 135                 fi
 136         fi
 137         AC_MSG_RESULT([$kernelbuild])
 138
 139         AC_MSG_CHECKING([kernel source version])
 140         utsrelease1=$kernelbuild/include/linux/version.h
 141         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 142         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 143         if test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1; then
 144                 utsrelease=linux/version.h
 145         elif test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2; then
 146                 utsrelease=linux/utsrelease.h
 147         elif test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3; then
 148                 utsrelease=generated/utsrelease.h
 149         fi
 150
 151         if test "$utsrelease"; then
 152                 kernsrcver=`(echo "#include <$utsrelease>";
 153                              echo "kernsrcver=UTS_RELEASE") |
 154                              cpp -I $kernelbuild/include |
 155                              grep "^kernsrcver=" | cut -d \" -f 2`
 156
 157                 if test -z "$kernsrcver"; then
 158                         AC_MSG_RESULT([Not found])
 159                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 160                 fi
 161         else
 162                 AC_MSG_RESULT([Not found])
 163                 if test "x$enable_linux_builtin" != xyes; then
 164                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 165                 else
 166                         AC_MSG_ERROR([
 167         *** Cannot find UTS_RELEASE definition.
 168         *** Please run 'make prepare' inside the kernel source tree.])
 169                 fi
 170         fi
 171
 172         AC_MSG_RESULT([$kernsrcver])
 173
 174         LINUX=${kernelsrc}
 175         LINUX_OBJ=${kernelbuild}
 176         LINUX_VERSION=${kernsrcver}
 177
 178         AC_SUBST(LINUX)
 179         AC_SUBST(LINUX_OBJ)
 180         AC_SUBST(LINUX_VERSION)
 181
 182         SPL_AC_MODULE_SYMVERS
 183 ])
 184
 185 dnl #
 186 dnl # Default SPL user configuration
 187 dnl #
 188 AC_DEFUN([SPL_AC_CONFIG_USER], [])
 189
 190 dnl #
 191 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 192 dnl # are missing, it is non-fatal, but you will not be able to build
 193 dnl # RPM packages and will be warned if you try too.
 194 dnl #
 195 dnl # By default, the generic spec file will be used because it requires
 196 dnl # minimal dependencies.  Distribution specific spec files can be
 197 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 198 dnl # the --with-spec=<distribution> configure option.
 199 dnl #
 200 AC_DEFUN([SPL_AC_RPM], [
 201         RPM=rpm
 202         RPMBUILD=rpmbuild
 203
 204         AC_MSG_CHECKING([whether $RPM is available])
 205         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 206                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 207                 HAVE_RPM=yes
 208                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 209         ],[
 210                 HAVE_RPM=no
 211                 AC_MSG_RESULT([$HAVE_RPM])
 212         ])
 213
 214         AC_MSG_CHECKING([whether $RPMBUILD is available])
 215         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 216                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 217                 HAVE_RPMBUILD=yes
 218                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 219         ],[
 220                 HAVE_RPMBUILD=no
 221                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 222         ])
 223
 224         RPM_DEFINE_COMMON='--define "$(DEBUG_SPL) 1" --define "$(DEBUG_KMEM) 1" --define "$(DEBUG_KMEM_TRACKING) 1"'
 225         RPM_DEFINE_UTIL=
 226         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)"'
 227         RPM_DEFINE_DKMS=
 228
 229         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 230         SRPM_DEFINE_UTIL=
 231         SRPM_DEFINE_KMOD=
 232         SRPM_DEFINE_DKMS=
 233
 234         RPM_SPEC_DIR="rpm/generic"
 235         AC_ARG_WITH([spec],
 236                 AS_HELP_STRING([--with-spec=SPEC],
 237                 [Spec files 'generic|redhat']),
 238                 [RPM_SPEC_DIR="rpm/$withval"])
 239
 240         AC_MSG_CHECKING([whether spec files are available])
 241         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 242
 243         AC_SUBST(HAVE_RPM)
 244         AC_SUBST(RPM)
 245         AC_SUBST(RPM_VERSION)
 246
 247         AC_SUBST(HAVE_RPMBUILD)
 248         AC_SUBST(RPMBUILD)
 249         AC_SUBST(RPMBUILD_VERSION)
 250
 251         AC_SUBST(RPM_SPEC_DIR)
 252         AC_SUBST(RPM_DEFINE_UTIL)
 253         AC_SUBST(RPM_DEFINE_KMOD)
 254         AC_SUBST(RPM_DEFINE_DKMS)
 255         AC_SUBST(RPM_DEFINE_COMMON)
 256         AC_SUBST(SRPM_DEFINE_UTIL)
 257         AC_SUBST(SRPM_DEFINE_KMOD)
 258         AC_SUBST(SRPM_DEFINE_DKMS)
 259         AC_SUBST(SRPM_DEFINE_COMMON)
 260 ])
 261
 262 dnl #
 263 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 264 dnl # tools are missing it is non-fatal but you will not be able to build
 265 dnl # DEB packages and will be warned if you try too.
 266 dnl #
 267 AC_DEFUN([SPL_AC_DPKG], [
 268         DPKG=dpkg
 269         DPKGBUILD=dpkg-buildpackage
 270
 271         AC_MSG_CHECKING([whether $DPKG is available])
 272         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 273                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 274                 HAVE_DPKG=yes
 275                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 276         ],[
 277                 HAVE_DPKG=no
 278                 AC_MSG_RESULT([$HAVE_DPKG])
 279         ])
 280
 281         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 282         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 283                 DPKGBUILD_VERSION=$(echo $tmp | \
 284                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 285                 HAVE_DPKGBUILD=yes
 286                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 287         ],[
 288                 HAVE_DPKGBUILD=no
 289                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 290         ])
 291
 292         AC_SUBST(HAVE_DPKG)
 293         AC_SUBST(DPKG)
 294         AC_SUBST(DPKG_VERSION)
 295
 296         AC_SUBST(HAVE_DPKGBUILD)
 297         AC_SUBST(DPKGBUILD)
 298         AC_SUBST(DPKGBUILD_VERSION)
 299 ])
 300
 301 dnl #
 302 dnl # Until native packaging for various different packing systems
 303 dnl # can be added the least we can do is attempt to use alien to
 304 dnl # convert the RPM packages to the needed package type.  This is
 305 dnl # a hack but so far it has worked reasonable well.
 306 dnl #
 307 AC_DEFUN([SPL_AC_ALIEN], [
 308         ALIEN=alien
 309
 310         AC_MSG_CHECKING([whether $ALIEN is available])
 311         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 312                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 313                 HAVE_ALIEN=yes
 314                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 315         ],[
 316                 HAVE_ALIEN=no
 317                 AC_MSG_RESULT([$HAVE_ALIEN])
 318         ])
 319
 320         AC_SUBST(HAVE_ALIEN)
 321         AC_SUBST(ALIEN)
 322         AC_SUBST(ALIEN_VERSION)
 323 ])
 324
 325 dnl #
 326 dnl # Using the VENDOR tag from config.guess set the default
 327 dnl # package type for 'make pkg': (rpm | deb | tgz)
 328 dnl #
 329 AC_DEFUN([SPL_AC_DEFAULT_PACKAGE], [
 330         AC_MSG_CHECKING([linux distribution])
 331         if test -f /etc/toss-release ; then
 332                 VENDOR=toss ;
 333         elif test -f /etc/fedora-release ; then
 334                 VENDOR=fedora ;
 335         elif test -f /etc/redhat-release ; then
 336                 VENDOR=redhat ;
 337         elif test -f /etc/gentoo-release ; then
 338                 VENDOR=gentoo ;
 339         elif test -f /etc/arch-release ; then
 340                 VENDOR=arch ;
 341         elif test -f /etc/SuSE-release ; then
 342                 VENDOR=sles ;
 343         elif test -f /etc/slackware-version ; then
 344                 VENDOR=slackware ;
 345         elif test -f /etc/lunar.release ; then
 346                 VENDOR=lunar ;
 347         elif test -f /etc/lsb-release ; then
 348                 VENDOR=ubuntu ;
 349         elif test -f /etc/debian_version ; then
 350                 VENDOR=debian ;
 351         else
 352                 VENDOR= ;
 353         fi
 354         AC_MSG_RESULT([$VENDOR])
 355         AC_SUBST(VENDOR)
 356
 357         AC_MSG_CHECKING([default package type])
 358         case "$VENDOR" in
 359                 toss)       DEFAULT_PACKAGE=rpm  ;;
 360                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 361                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 362                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 363                 arch)       DEFAULT_PACKAGE=tgz  ;;
 364                 sles)       DEFAULT_PACKAGE=rpm  ;;
 365                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 366                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 367                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 368                 debian)     DEFAULT_PACKAGE=deb  ;;
 369                 *)          DEFAULT_PACKAGE=rpm  ;;
 370         esac
 371
 372         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 373         AC_SUBST(DEFAULT_PACKAGE)
 374 ])
 375
 376 dnl #
 377 dnl # Default SPL user configuration
 378 dnl #
 379 AC_DEFUN([SPL_AC_PACKAGE], [
 380         SPL_AC_DEFAULT_PACKAGE
 381         SPL_AC_RPM
 382         SPL_AC_DPKG
 383         SPL_AC_ALIEN
 384 ])
 385
 386 AC_DEFUN([SPL_AC_LICENSE], [
 387         AC_MSG_CHECKING([spl author])
 388         AC_MSG_RESULT([$SPL_META_AUTHOR])
 389
 390         AC_MSG_CHECKING([spl license])
 391         AC_MSG_RESULT([$SPL_META_LICENSE])
 392 ])
 393
 394 AC_DEFUN([SPL_AC_CONFIG], [
 395         SPL_CONFIG=all
 396         AC_ARG_WITH([config],
 397                 AS_HELP_STRING([--with-config=CONFIG],
 398                 [Config file 'kernel|user|all|srpm']),
 399                 [SPL_CONFIG="$withval"])
 400         AC_ARG_ENABLE([linux-builtin],
 401                 [AC_HELP_STRING([--enable-linux-builtin],
 402                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 403                 [],
 404                 [enable_linux_builtin=no])
 405
 406         AC_MSG_CHECKING([spl config])
 407         AC_MSG_RESULT([$SPL_CONFIG]);
 408         AC_SUBST(SPL_CONFIG)
 409
 410         case "$SPL_CONFIG" in
 411                 kernel) SPL_AC_CONFIG_KERNEL ;;
 412                 user)   SPL_AC_CONFIG_USER   ;;
 413                 all)    SPL_AC_CONFIG_KERNEL
 414                         SPL_AC_CONFIG_USER   ;;
 415                 srpm)                        ;;
 416                 *)
 417                 AC_MSG_RESULT([Error!])
 418                 AC_MSG_ERROR([Bad value "$SPL_CONFIG" for --with-config,
 419                              user kernel|user|all|srpm]) ;;
 420         esac
 421
 422         AM_CONDITIONAL([CONFIG_USER],
 423                        [test "$SPL_CONFIG" = user -o "$SPL_CONFIG" = all])
 424         AM_CONDITIONAL([CONFIG_KERNEL],
 425                        [test "$SPL_CONFIG" = kernel -o "$SPL_CONFIG" = all] &&
 426                        [test "x$enable_linux_builtin" != xyes ])
 427 ])
 428
 429 dnl #
 430 dnl # Enable if the SPL should be compiled with internal debugging enabled.
 431 dnl # By default this support is disabled.
 432 dnl #
 433 AC_DEFUN([SPL_AC_DEBUG], [
 434         AC_MSG_CHECKING([whether debugging is enabled])
 435         AC_ARG_ENABLE([debug],
 436                 [AS_HELP_STRING([--enable-debug],
 437                 [Enable generic debug support @<:@default=no@:>@])],
 438                 [],
 439                 [enable_debug=no])
 440
 441         AS_IF([test "x$enable_debug" = xyes],
 442         [
 443                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
 444                 DEBUG_CFLAGS="-DDEBUG -Werror"
 445                 DEBUG_SPL="_with_debug"
 446         ], [
 447                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG"
 448                 DEBUG_CFLAGS="-DNDEBUG"
 449                 DEBUG_SPL="_without_debug"
 450         ])
 451
 452         AC_SUBST(DEBUG_CFLAGS)
 453         AC_SUBST(DEBUG_SPL)
 454         AC_MSG_RESULT([$enable_debug])
 455 ])
 456
 457 dnl #
 458 dnl # Enabled by default it provides a minimal level of memory tracking.
 459 dnl # A total count of bytes allocated is kept for each alloc and free.
 460 dnl # Then at module unload time a report to the console will be printed
 461 dnl # if memory was leaked.
 462 dnl #
 463 AC_DEFUN([SPL_AC_DEBUG_KMEM], [
 464         AC_ARG_ENABLE([debug-kmem],
 465                 [AS_HELP_STRING([--enable-debug-kmem],
 466                 [Enable basic kmem accounting @<:@default=no@:>@])],
 467                 [],
 468                 [enable_debug_kmem=no])
 469
 470         AS_IF([test "x$enable_debug_kmem" = xyes],
 471         [
 472                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM"
 473                 DEBUG_KMEM="_with_debug_kmem"
 474                 AC_DEFINE([DEBUG_KMEM], [1],
 475                 [Define to 1 to enable basic kmem accounting])
 476         ], [
 477                 DEBUG_KMEM="_without_debug_kmem"
 478         ])
 479
 480         AC_SUBST(DEBUG_KMEM)
 481         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 482         AC_MSG_RESULT([$enable_debug_kmem])
 483 ])
 484
 485 dnl #
 486 dnl # Disabled by default it provides detailed memory tracking.  This
 487 dnl # feature also requires --enable-debug-kmem to be set.  When enabled
 488 dnl # not only will total bytes be tracked but also the location of every
 489 dnl # alloc and free.  When the SPL module is unloaded a list of all leaked
 490 dnl # addresses and where they were allocated will be dumped to the console.
 491 dnl # Enabling this feature has a significant impact on performance but it
 492 dnl # makes finding memory leaks pretty straight forward.
 493 dnl #
 494 AC_DEFUN([SPL_AC_DEBUG_KMEM_TRACKING], [
 495         AC_ARG_ENABLE([debug-kmem-tracking],
 496                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 497                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 498                 [],
 499                 [enable_debug_kmem_tracking=no])
 500
 501         AS_IF([test "x$enable_debug_kmem_tracking" = xyes],
 502         [
 503                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_KMEM_TRACKING"
 504                 DEBUG_KMEM_TRACKING="_with_debug_kmem_tracking"
 505                 AC_DEFINE([DEBUG_KMEM_TRACKING], [1],
 506                 [Define to 1 to enable detailed kmem tracking])
 507         ], [
 508                 DEBUG_KMEM_TRACKING="_without_debug_kmem_tracking"
 509         ])
 510
 511         AC_SUBST(DEBUG_KMEM_TRACKING)
 512         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 513         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 514 ])
 515
 516 dnl #
 517 dnl # SPL_LINUX_CONFTEST
 518 dnl #
 519 AC_DEFUN([SPL_LINUX_CONFTEST], [
 520 cat confdefs.h - <<_ACEOF >conftest.c
 521 $1
 522 _ACEOF
 523 ])
 524
 525 dnl #
 526 dnl # SPL_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 527 dnl #
 528 m4_define([SPL_LANG_PROGRAM], [
 529 $1
 530 int
 531 main (void)
 532 {
 533 dnl Do *not* indent the following line: there may be CPP directives.
 534 dnl Don't move the `;' right after for the same reason.
 535 $2
 536   ;
 537   return 0;
 538 }
 539 ])
 540
 541 dnl #
 542 dnl # SPL_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 543 dnl #
 544 AC_DEFUN([SPL_LINUX_COMPILE_IFELSE], [
 545         m4_ifvaln([$1], [SPL_LINUX_CONFTEST([$1])])
 546         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 547         echo "obj-m := conftest.o" >build/Makefile
 548         modpost_flag=''
 549         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 550         AS_IF(
 551                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 552                 [$4],
 553                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 554         )
 555         rm -Rf build
 556 ])
 557
 558 dnl #
 559 dnl # SPL_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 560 dnl #
 561 AC_DEFUN([SPL_LINUX_TRY_COMPILE],
 562         [SPL_LINUX_COMPILE_IFELSE(
 563         [AC_LANG_SOURCE([SPL_LANG_PROGRAM([[$1]], [[$2]])])],
 564         [modules],
 565         [test -s build/conftest.o],
 566         [$3], [$4])
 567 ])
 568
 569 dnl #
 570 dnl # SPL_CHECK_SYMBOL_EXPORT
 571 dnl # check symbol exported or not
 572 dnl #
 573 AC_DEFUN([SPL_CHECK_SYMBOL_EXPORT], [
 574         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 575                 $LINUX_OBJ/Module*.symvers 2>/dev/null
 576         rc=$?
 577         if test $rc -ne 0; then
 578                 export=0
 579                 for file in $2; do
 580                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 581                                 "$LINUX_OBJ/$file" 2>/dev/null
 582                         rc=$?
 583                         if test $rc -eq 0; then
 584                                 export=1
 585                                 break;
 586                         fi
 587                 done
 588                 if test $export -eq 0; then :
 589                         $4
 590                 else :
 591                         $3
 592                 fi
 593         else :
 594                 $3
 595         fi
 596 ])
 597
 598 dnl #
 599 dnl # SPL_LINUX_TRY_COMPILE_SYMBOL
 600 dnl # like SPL_LINUX_TRY_COMPILE, except SPL_CHECK_SYMBOL_EXPORT
 601 dnl # is called if not compiling for builtin
 602 dnl #
 603 AC_DEFUN([SPL_LINUX_TRY_COMPILE_SYMBOL], [
 604         SPL_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 605         if test $rc -ne 0; then :
 606                 $6
 607         else
 608                 if test "x$enable_linux_builtin" != xyes; then
 609                         SPL_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 610                 fi
 611                 if test $rc -ne 0; then :
 612                         $6
 613                 else :
 614                         $5
 615                 fi
 616         fi
 617 ])
 618
 619 dnl #
 620 dnl # SPL_CHECK_SYMBOL_HEADER
 621 dnl # check if a symbol prototype is defined in listed headers.
 622 dnl #
 623 AC_DEFUN([SPL_CHECK_SYMBOL_HEADER], [
 624         AC_MSG_CHECKING([whether symbol $1 exists in header])
 625         header=0
 626         for file in $3; do
 627                 grep -q "$2" "$LINUX/$file" 2>/dev/null
 628                 rc=$?
 629                 if test $rc -eq 0; then
 630                         header=1
 631                         break;
 632                 fi
 633         done
 634         if test $header -eq 0; then
 635                 AC_MSG_RESULT([no])
 636                 $5
 637         else
 638                 AC_MSG_RESULT([yes])
 639                 $4
 640         fi
 641 ])
 642
 643 dnl #
 644 dnl # SPL_CHECK_HEADER
 645 dnl # check whether header exists and define HAVE_$2_HEADER
 646 dnl #
 647 AC_DEFUN([SPL_CHECK_HEADER],
 648         [AC_MSG_CHECKING([whether header $1 exists])
 649         SPL_LINUX_TRY_COMPILE([
 650                 #include <$1>
 651         ],[
 652                 return 0;
 653         ],[
 654                 AC_DEFINE(HAVE_$2_HEADER, 1, [$1 exists])
 655                 AC_MSG_RESULT(yes)
 656                 $3
 657         ],[
 658                 AC_MSG_RESULT(no)
 659                 $4
 660         ])
 661 ])
 662
 663 dnl #
 664 dnl # Basic toolchain sanity check.  Verify that kernel modules can
 665 dnl # be built and which symbols can be used.
 666 dnl #
 667 AC_DEFUN([SPL_AC_TEST_MODULE],
 668         [AC_MSG_CHECKING([whether modules can be built])
 669         SPL_LINUX_TRY_COMPILE([],[],[
 670                 AC_MSG_RESULT([yes])
 671         ],[
 672                 AC_MSG_RESULT([no])
 673                 if test "x$enable_linux_builtin" != xyes; then
 674                         AC_MSG_ERROR([*** Unable to build an empty module.])
 675                 else
 676                         AC_MSG_ERROR([
 677         *** Unable to build an empty module.
 678         *** Please run 'make scripts' inside the kernel source tree.])
 679                 fi
 680         ])
 681
 682         AS_IF([test "x$cross_compiling" != xyes], [
 683                 AC_RUN_IFELSE([
 684                         AC_LANG_PROGRAM([
 685                                 #include "$LINUX/include/linux/license.h"
 686                         ], [
 687                                 return !license_is_gpl_compatible(
 688                                     "$SPL_META_LICENSE");
 689                         ])
 690                 ], [
 691                         AC_DEFINE([SPL_IS_GPL_COMPATIBLE], [1],
 692                             [Define to 1 if GPL-only symbols can be used])
 693                 ], [
 694                 ])
 695         ])
 696 ])
 697
 698 dnl #
 699 dnl # Use the atomic implemenation based on global spinlocks.  This
 700 dnl # should only be needed by 32-bit kernels which do not provide
 701 dnl # the atomic64_* API.  It may be optionally enabled as a fallback
 702 dnl # if problems are observed with the direct mapping to the native
 703 dnl # Linux atomic operations.  You may not disable atomic spinlocks
 704 dnl # if you kernel does not an atomic64_* API.
 705 dnl #
 706 AC_DEFUN([SPL_AC_ATOMIC_SPINLOCK], [
 707         AC_ARG_ENABLE([atomic-spinlocks],
 708                 [AS_HELP_STRING([--enable-atomic-spinlocks],
 709                 [Atomic types use spinlocks @<:@default=check@:>@])],
 710                 [],
 711                 [enable_atomic_spinlocks=check])
 712
 713         SPL_LINUX_TRY_COMPILE([
 714                 #include <linux/fs.h>
 715         ],[
 716                 atomic64_t *ptr __attribute__ ((unused));
 717         ],[
 718                 have_atomic64_t=yes
 719                 AC_DEFINE(HAVE_ATOMIC64_T, 1,
 720                         [kernel defines atomic64_t])
 721         ],[
 722                 have_atomic64_t=no
 723         ])
 724
 725         AS_IF([test "x$enable_atomic_spinlocks" = xcheck], [
 726                 AS_IF([test "x$have_atomic64_t" = xyes], [
 727                         enable_atomic_spinlocks=no
 728                 ],[
 729                         enable_atomic_spinlocks=yes
 730                 ])
 731         ])
 732
 733         AS_IF([test "x$enable_atomic_spinlocks" = xyes], [
 734                 AC_DEFINE([ATOMIC_SPINLOCK], [1],
 735                         [Atomic types use spinlocks])
 736         ],[
 737                 AS_IF([test "x$have_atomic64_t" = xno], [
 738                         AC_MSG_FAILURE(
 739                         [--disable-atomic-spinlocks given but required atomic64 support is unavailable])
 740                 ])
 741         ])
 742
 743         AC_MSG_CHECKING([whether atomic types use spinlocks])
 744         AC_MSG_RESULT([$enable_atomic_spinlocks])
 745
 746         AC_MSG_CHECKING([whether kernel defines atomic64_t])
 747         AC_MSG_RESULT([$have_atomic64_t])
 748 ])
 749
 750 AC_DEFUN([SPL_AC_SHRINKER_CALLBACK],[
 751         tmp_flags="$EXTRA_KCFLAGS"
 752         EXTRA_KCFLAGS="-Werror"
 753         dnl #
 754         dnl # 2.6.23 to 2.6.34 API change
 755         dnl # ->shrink(int nr_to_scan, gfp_t gfp_mask)
 756         dnl #
 757         AC_MSG_CHECKING([whether old 2-argument shrinker exists])
 758         SPL_LINUX_TRY_COMPILE([
 759                 #include <linux/mm.h>
 760
 761                 int shrinker_cb(int nr_to_scan, gfp_t gfp_mask);
 762         ],[
 763                 struct shrinker cache_shrinker = {
 764                         .shrink = shrinker_cb,
 765                         .seeks = DEFAULT_SEEKS,
 766                 };
 767                 register_shrinker(&cache_shrinker);
 768         ],[
 769                 AC_MSG_RESULT(yes)
 770                 AC_DEFINE(HAVE_2ARGS_OLD_SHRINKER_CALLBACK, 1,
 771                         [old shrinker callback wants 2 args])
 772         ],[
 773                 AC_MSG_RESULT(no)
 774                 dnl #
 775                 dnl # 2.6.35 - 2.6.39 API change
 776                 dnl # ->shrink(struct shrinker *,
 777                 dnl #          int nr_to_scan, gfp_t gfp_mask)
 778                 dnl #
 779                 AC_MSG_CHECKING([whether old 3-argument shrinker exists])
 780                 SPL_LINUX_TRY_COMPILE([
 781                         #include <linux/mm.h>
 782
 783                         int shrinker_cb(struct shrinker *, int nr_to_scan,
 784                                         gfp_t gfp_mask);
 785                 ],[
 786                         struct shrinker cache_shrinker = {
 787                                 .shrink = shrinker_cb,
 788                                 .seeks = DEFAULT_SEEKS,
 789                         };
 790                         register_shrinker(&cache_shrinker);
 791                 ],[
 792                         AC_MSG_RESULT(yes)
 793                         AC_DEFINE(HAVE_3ARGS_SHRINKER_CALLBACK, 1,
 794                                 [old shrinker callback wants 3 args])
 795                 ],[
 796                         AC_MSG_RESULT(no)
 797                         dnl #
 798                         dnl # 3.0 - 3.11 API change
 799                         dnl # ->shrink(struct shrinker *,
 800                         dnl #          struct shrink_control *sc)
 801                         dnl #
 802                         AC_MSG_CHECKING(
 803                                 [whether new 2-argument shrinker exists])
 804                         SPL_LINUX_TRY_COMPILE([
 805                                 #include <linux/mm.h>
 806
 807                                 int shrinker_cb(struct shrinker *,
 808                                                 struct shrink_control *sc);
 809                         ],[
 810                                 struct shrinker cache_shrinker = {
 811                                         .shrink = shrinker_cb,
 812                                         .seeks = DEFAULT_SEEKS,
 813                                 };
 814                                 register_shrinker(&cache_shrinker);
 815                         ],[
 816                                 AC_MSG_RESULT(yes)
 817                                 AC_DEFINE(HAVE_2ARGS_NEW_SHRINKER_CALLBACK, 1,
 818                                         [new shrinker callback wants 2 args])
 819                         ],[
 820                                 AC_MSG_RESULT(no)
 821                                 dnl #
 822                                 dnl # 3.12 API change,
 823                                 dnl # ->shrink() is logically split in to
 824                                 dnl # ->count_objects() and ->scan_objects()
 825                                 dnl #
 826                                 AC_MSG_CHECKING(
 827                                     [whether ->count_objects callback exists])
 828                                 SPL_LINUX_TRY_COMPILE([
 829                                         #include <linux/mm.h>
 830
 831                                         unsigned long shrinker_cb(
 832                                                 struct shrinker *,
 833                                                 struct shrink_control *sc);
 834                                 ],[
 835                                         struct shrinker cache_shrinker = {
 836                                                 .count_objects = shrinker_cb,
 837                                                 .scan_objects = shrinker_cb,
 838                                                 .seeks = DEFAULT_SEEKS,
 839                                         };
 840                                         register_shrinker(&cache_shrinker);
 841                                 ],[
 842                                         AC_MSG_RESULT(yes)
 843                                         AC_DEFINE(HAVE_SPLIT_SHRINKER_CALLBACK,
 844                                                 1, [->count_objects exists])
 845                                 ],[
 846                                         AC_MSG_ERROR(error)
 847                                 ])
 848                         ])
 849                 ])
 850         ])
 851         EXTRA_KCFLAGS="$tmp_flags"
 852 ])
 853
 854 dnl #
 855 dnl # 2.6.33 API change,
 856 dnl # Removed .ctl_name from struct ctl_table.
 857 dnl #
 858 AC_DEFUN([SPL_AC_CTL_NAME], [
 859         AC_MSG_CHECKING([whether struct ctl_table has ctl_name])
 860         SPL_LINUX_TRY_COMPILE([
 861                 #include <linux/sysctl.h>
 862         ],[
 863                 struct ctl_table ctl __attribute__ ((unused));
 864                 ctl.ctl_name = 0;
 865         ],[
 866                 AC_MSG_RESULT(yes)
 867                 AC_DEFINE(HAVE_CTL_NAME, 1, [struct ctl_table has ctl_name])
 868         ],[
 869                 AC_MSG_RESULT(no)
 870         ])
 871 ])
 872
 873 dnl #
 874 dnl # 3.10 API change,
 875 dnl # PDE is replaced by PDE_DATA
 876 dnl #
 877 AC_DEFUN([SPL_AC_PDE_DATA], [
 878         AC_MSG_CHECKING([whether PDE_DATA() is available])
 879         SPL_LINUX_TRY_COMPILE_SYMBOL([
 880                 #include <linux/proc_fs.h>
 881         ], [
 882                 PDE_DATA(NULL);
 883         ], [PDE_DATA], [], [
 884                 AC_MSG_RESULT(yes)
 885                 AC_DEFINE(HAVE_PDE_DATA, 1, [yes])
 886         ],[
 887                 AC_MSG_RESULT(no)
 888         ])
 889 ])
 890
 891 dnl #
 892 dnl # 3.9 API change
 893 dnl # set_fs_pwd takes const struct path *
 894 dnl #
 895 AC_DEFUN([SPL_AC_SET_FS_PWD_WITH_CONST],
 896         tmp_flags="$EXTRA_KCFLAGS"
 897         EXTRA_KCFLAGS="-Werror"
 898         [AC_MSG_CHECKING([whether set_fs_pwd() requires const struct path *])
 899         SPL_LINUX_TRY_COMPILE([
 900                 #include <linux/spinlock.h>
 901                 #include <linux/fs_struct.h>
 902                 #include <linux/path.h>
 903                 void (*const set_fs_pwd_func)
 904                         (struct fs_struct *, const struct path *)
 905                         = set_fs_pwd;
 906         ],[
 907                 return 0;
 908         ],[
 909                 AC_MSG_RESULT(yes)
 910                 AC_DEFINE(HAVE_SET_FS_PWD_WITH_CONST, 1,
 911                         [set_fs_pwd() needs const path *])
 912         ],[
 913                 SPL_LINUX_TRY_COMPILE([
 914                         #include <linux/spinlock.h>
 915                         #include <linux/fs_struct.h>
 916                         #include <linux/path.h>
 917                         void (*const set_fs_pwd_func)
 918                                 (struct fs_struct *, struct path *)
 919                                 = set_fs_pwd;
 920                 ],[
 921                         return 0;
 922                 ],[
 923                         AC_MSG_RESULT(no)
 924                 ],[
 925                         AC_MSG_ERROR(unknown)
 926                 ])
 927         ])
 928         EXTRA_KCFLAGS="$tmp_flags"
 929 ])
 930
 931 dnl #
 932 dnl # 3.13 API change
 933 dnl # vfs_unlink() updated to take a third delegated_inode argument.
 934 dnl #
 935 AC_DEFUN([SPL_AC_2ARGS_VFS_UNLINK],
 936         [AC_MSG_CHECKING([whether vfs_unlink() wants 2 args])
 937         SPL_LINUX_TRY_COMPILE([
 938                 #include <linux/fs.h>
 939         ],[
 940                 vfs_unlink((struct inode *) NULL, (struct dentry *) NULL);
 941         ],[
 942                 AC_MSG_RESULT(yes)
 943                 AC_DEFINE(HAVE_2ARGS_VFS_UNLINK, 1,
 944                           [vfs_unlink() wants 2 args])
 945         ],[
 946                 AC_MSG_RESULT(no)
 947                 dnl #
 948                 dnl # Linux 3.13 API change
 949                 dnl # Added delegated inode
 950                 dnl #
 951                 AC_MSG_CHECKING([whether vfs_unlink() wants 3 args])
 952                 SPL_LINUX_TRY_COMPILE([
 953                         #include <linux/fs.h>
 954                 ],[
 955                         vfs_unlink((struct inode *) NULL,
 956                                 (struct dentry *) NULL,
 957                                 (struct inode **) NULL);
 958                 ],[
 959                         AC_MSG_RESULT(yes)
 960                         AC_DEFINE(HAVE_3ARGS_VFS_UNLINK, 1,
 961                                   [vfs_unlink() wants 3 args])
 962                 ],[
 963                         AC_MSG_ERROR(no)
 964                 ])
 965
 966         ])
 967 ])
 968
 969 dnl #
 970 dnl # 3.13 and 3.15 API changes
 971 dnl # Added delegated inode and flags argument.
 972 dnl #
 973 AC_DEFUN([SPL_AC_4ARGS_VFS_RENAME],
 974         [AC_MSG_CHECKING([whether vfs_rename() wants 4 args])
 975         SPL_LINUX_TRY_COMPILE([
 976                 #include <linux/fs.h>
 977         ],[
 978                 vfs_rename((struct inode *) NULL, (struct dentry *) NULL,
 979                         (struct inode *) NULL, (struct dentry *) NULL);
 980         ],[
 981                 AC_MSG_RESULT(yes)
 982                 AC_DEFINE(HAVE_4ARGS_VFS_RENAME, 1,
 983                           [vfs_rename() wants 4 args])
 984         ],[
 985                 AC_MSG_RESULT(no)
 986                 dnl #
 987                 dnl # Linux 3.13 API change
 988                 dnl # Added delegated inode
 989                 dnl #
 990                 AC_MSG_CHECKING([whether vfs_rename() wants 5 args])
 991                 SPL_LINUX_TRY_COMPILE([
 992                         #include <linux/fs.h>
 993                 ],[
 994                         vfs_rename((struct inode *) NULL,
 995                                 (struct dentry *) NULL,
 996                                 (struct inode *) NULL,
 997                                 (struct dentry *) NULL,
 998                                 (struct inode **) NULL);
 999                 ],[
1000                         AC_MSG_RESULT(yes)
1001                         AC_DEFINE(HAVE_5ARGS_VFS_RENAME, 1,
1002                                   [vfs_rename() wants 5 args])
1003                 ],[
1004                         AC_MSG_RESULT(no)
1005                         dnl #
1006                         dnl # Linux 3.15 API change
1007                         dnl # Added flags
1008                         dnl #
1009                         AC_MSG_CHECKING([whether vfs_rename() wants 6 args])
1010                         SPL_LINUX_TRY_COMPILE([
1011                                 #include <linux/fs.h>
1012                         ],[
1013                                 vfs_rename((struct inode *) NULL,
1014                                         (struct dentry *) NULL,
1015                                         (struct inode *) NULL,
1016                                         (struct dentry *) NULL,
1017                                         (struct inode **) NULL,
1018                                         (unsigned int) 0);
1019                         ],[
1020                                 AC_MSG_RESULT(yes)
1021                                 AC_DEFINE(HAVE_6ARGS_VFS_RENAME, 1,
1022                                           [vfs_rename() wants 6 args])
1023                         ],[
1024                                 AC_MSG_ERROR(no)
1025                         ])
1026                 ])
1027         ])
1028 ])
1029
1030 dnl #
1031 dnl # 2.6.36 API change,
1032 dnl # The 'struct fs_struct->lock' was changed from a rwlock_t to
1033 dnl # a spinlock_t to improve the fastpath performance.
1034 dnl #
1035 AC_DEFUN([SPL_AC_FS_STRUCT_SPINLOCK], [
1036         AC_MSG_CHECKING([whether struct fs_struct uses spinlock_t])
1037         tmp_flags="$EXTRA_KCFLAGS"
1038         EXTRA_KCFLAGS="-Werror"
1039         SPL_LINUX_TRY_COMPILE([
1040                 #include <linux/sched.h>
1041                 #include <linux/fs_struct.h>
1042         ],[
1043                 static struct fs_struct fs;
1044                 spin_lock_init(&fs.lock);
1045         ],[
1046                 AC_MSG_RESULT(yes)
1047                 AC_DEFINE(HAVE_FS_STRUCT_SPINLOCK, 1,
1048                           [struct fs_struct uses spinlock_t])
1049         ],[
1050                 AC_MSG_RESULT(no)
1051         ])
1052         EXTRA_KCFLAGS="$tmp_flags"
1053 ])
1054
1055 dnl #
1056 dnl # User namespaces, use kuid_t in place of uid_t
1057 dnl # where available. Not strictly a user namespaces thing
1058 dnl # but it should prevent surprises
1059 dnl #
1060 AC_DEFUN([SPL_AC_KUIDGID_T], [
1061         AC_MSG_CHECKING([whether kuid_t/kgid_t is available])
1062         SPL_LINUX_TRY_COMPILE([
1063                 #include <linux/uidgid.h>
1064         ], [
1065                 kuid_t userid = KUIDT_INIT(0);
1066                 kgid_t groupid = KGIDT_INIT(0);
1067         ],[
1068                 SPL_LINUX_TRY_COMPILE([
1069                         #include <linux/uidgid.h>
1070                 ], [
1071                         kuid_t userid = 0;
1072                         kgid_t groupid = 0;
1073                 ],[
1074                         AC_MSG_RESULT(yes; optional)
1075                 ],[
1076                         AC_MSG_RESULT(yes; mandatory)
1077                         AC_DEFINE(HAVE_KUIDGID_T, 1, [kuid_t/kgid_t in use])
1078                 ])
1079         ],[
1080                 AC_MSG_RESULT(no)
1081         ])
1082 ])
1083
1084 dnl #
1085 dnl # 2.6.39 API change,
1086 dnl # __put_task_struct() was exported by the mainline kernel.
1087 dnl #
1088 AC_DEFUN([SPL_AC_PUT_TASK_STRUCT],
1089         [AC_MSG_CHECKING([whether __put_task_struct() is available])
1090         SPL_LINUX_TRY_COMPILE_SYMBOL([
1091                 #include <linux/sched.h>
1092         ], [
1093                 __put_task_struct(NULL);
1094         ], [__put_task_struct], [], [
1095                 AC_MSG_RESULT(yes)
1096                 AC_DEFINE(HAVE_PUT_TASK_STRUCT, 1,
1097                           [__put_task_struct() is available])
1098         ], [
1099                 AC_MSG_RESULT(no)
1100         ])
1101 ])
1102
1103 dnl #
1104 dnl # 2.6.35 API change,
1105 dnl # Unused 'struct dentry *' removed from vfs_fsync() prototype.
1106 dnl #
1107 AC_DEFUN([SPL_AC_2ARGS_VFS_FSYNC], [
1108         AC_MSG_CHECKING([whether vfs_fsync() wants 2 args])
1109         SPL_LINUX_TRY_COMPILE([
1110                 #include <linux/fs.h>
1111         ],[
1112                 vfs_fsync(NULL, 0);
1113         ],[
1114                 AC_MSG_RESULT(yes)
1115                 AC_DEFINE(HAVE_2ARGS_VFS_FSYNC, 1, [vfs_fsync() wants 2 args])
1116         ],[
1117                 AC_MSG_RESULT(no)
1118         ])
1119 ])
1120
1121 dnl #
1122 dnl # 3.5 API change,
1123 dnl # inode_operations.truncate_range removed
1124 dnl #
1125 AC_DEFUN([SPL_AC_INODE_TRUNCATE_RANGE], [
1126         AC_MSG_CHECKING([whether truncate_range() inode operation is available])
1127         SPL_LINUX_TRY_COMPILE([
1128                 #include <linux/fs.h>
1129         ],[
1130                 struct inode_operations ops;
1131                 ops.truncate_range = NULL;
1132         ],[
1133                 AC_MSG_RESULT(yes)
1134                 AC_DEFINE(HAVE_INODE_TRUNCATE_RANGE, 1,
1135                         [truncate_range() inode operation is available])
1136         ],[
1137                 AC_MSG_RESULT(no)
1138         ])
1139 ])
1140
1141 dnl #
1142 dnl # Linux 2.6.38 - 3.x API
1143 dnl #
1144 AC_DEFUN([SPL_AC_KERNEL_FILE_FALLOCATE], [
1145         AC_MSG_CHECKING([whether fops->fallocate() exists])
1146         SPL_LINUX_TRY_COMPILE([
1147                 #include <linux/fs.h>
1148         ],[
1149                 long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
1150                 struct file_operations fops __attribute__ ((unused)) = {
1151                         .fallocate = fallocate,
1152                 };
1153         ],[
1154                 AC_MSG_RESULT(yes)
1155                 AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
1156         ],[
1157                 AC_MSG_RESULT(no)
1158         ])
1159 ])
1160
1161 dnl #
1162 dnl # Linux 2.6.x - 2.6.37 API
1163 dnl #
1164 AC_DEFUN([SPL_AC_KERNEL_INODE_FALLOCATE], [
1165         AC_MSG_CHECKING([whether iops->fallocate() exists])
1166         SPL_LINUX_TRY_COMPILE([
1167                 #include <linux/fs.h>
1168         ],[
1169                 long (*fallocate) (struct inode *, int, loff_t, loff_t) = NULL;
1170                 struct inode_operations fops __attribute__ ((unused)) = {
1171                         .fallocate = fallocate,
1172                 };
1173         ],[
1174                 AC_MSG_RESULT(yes)
1175                 AC_DEFINE(HAVE_INODE_FALLOCATE, 1, [fops->fallocate() exists])
1176         ],[
1177                 AC_MSG_RESULT(no)
1178         ])
1179 ])
1180
1181 dnl #
1182 dnl # PaX Linux 2.6.38 - 3.x API
1183 dnl #
1184 AC_DEFUN([SPL_AC_PAX_KERNEL_FILE_FALLOCATE], [
1185         AC_MSG_CHECKING([whether fops->fallocate() exists])
1186         SPL_LINUX_TRY_COMPILE([
1187                 #include <linux/fs.h>
1188         ],[
1189                 long (*fallocate) (struct file *, int, loff_t, loff_t) = NULL;
1190                 struct file_operations_no_const fops __attribute__ ((unused)) = {
1191                         .fallocate = fallocate,
1192                 };
1193         ],[
1194                 AC_MSG_RESULT(yes)
1195                 AC_DEFINE(HAVE_FILE_FALLOCATE, 1, [fops->fallocate() exists])
1196         ],[
1197                 AC_MSG_RESULT(no)
1198         ])
1199 ])
1200
1201 dnl #
1202 dnl # The fallocate callback was moved from the inode_operations
1203 dnl # structure to the file_operations structure.
1204 dnl #
1205 AC_DEFUN([SPL_AC_KERNEL_FALLOCATE], [
1206         SPL_AC_KERNEL_FILE_FALLOCATE
1207         SPL_AC_KERNEL_INODE_FALLOCATE
1208         SPL_AC_PAX_KERNEL_FILE_FALLOCATE
1209 ])
1210
1211 dnl #
1212 dnl # zlib inflate compat,
1213 dnl # Verify the kernel has CONFIG_ZLIB_INFLATE support enabled.
1214 dnl #
1215 AC_DEFUN([SPL_AC_CONFIG_ZLIB_INFLATE], [
1216         AC_MSG_CHECKING([whether CONFIG_ZLIB_INFLATE is defined])
1217         SPL_LINUX_TRY_COMPILE([
1218                 #if !defined(CONFIG_ZLIB_INFLATE) && \
1219                     !defined(CONFIG_ZLIB_INFLATE_MODULE)
1220                 #error CONFIG_ZLIB_INFLATE not defined
1221                 #endif
1222         ],[ ],[
1223                 AC_MSG_RESULT([yes])
1224         ],[
1225                 AC_MSG_RESULT([no])
1226                 AC_MSG_ERROR([
1227         *** This kernel does not include the required zlib inflate support.
1228         *** Rebuild the kernel with CONFIG_ZLIB_INFLATE=y|m set.])
1229         ])
1230 ])
1231
1232 dnl #
1233 dnl # zlib deflate compat,
1234 dnl # Verify the kernel has CONFIG_ZLIB_DEFLATE support enabled.
1235 dnl #
1236 AC_DEFUN([SPL_AC_CONFIG_ZLIB_DEFLATE], [
1237         AC_MSG_CHECKING([whether CONFIG_ZLIB_DEFLATE is defined])
1238         SPL_LINUX_TRY_COMPILE([
1239                 #if !defined(CONFIG_ZLIB_DEFLATE) && \
1240                     !defined(CONFIG_ZLIB_DEFLATE_MODULE)
1241                 #error CONFIG_ZLIB_DEFLATE not defined
1242                 #endif
1243         ],[ ],[
1244                 AC_MSG_RESULT([yes])
1245         ],[
1246                 AC_MSG_RESULT([no])
1247                 AC_MSG_ERROR([
1248         *** This kernel does not include the required zlib deflate support.
1249         *** Rebuild the kernel with CONFIG_ZLIB_DEFLATE=y|m set.])
1250         ])
1251 ])
1252
1253 dnl #
1254 dnl # config trim unused symbols,
1255 dnl # Verify the kernel has CONFIG_TRIM_UNUSED_KSYMS DISABLED.
1256 dnl #
1257 AC_DEFUN([SPL_AC_CONFIG_TRIM_UNUSED_KSYMS], [
1258         AC_MSG_CHECKING([whether CONFIG_TRIM_UNUSED_KSYM is disabled])
1259         SPL_LINUX_TRY_COMPILE([
1260                 #if defined(CONFIG_TRIM_UNUSED_KSYMS)
1261                 #error CONFIG_TRIM_UNUSED_KSYMS not defined
1262                 #endif
1263         ],[ ],[
1264                 AC_MSG_RESULT([yes])
1265         ],[
1266                 AC_MSG_RESULT([no])
1267                 AC_MSG_ERROR([
1268         *** This kernel has unused symbols trimming enabled, please disable.
1269         *** Rebuild the kernel with CONFIG_TRIM_UNUSED_KSYMS=n set.])
1270         ])
1271 ])
1272
1273 dnl #
1274 dnl # 2.6.39 API compat,
1275 dnl # The function zlib_deflate_workspacesize() now take 2 arguments.
1276 dnl # This was done to avoid always having to allocate the maximum size
1277 dnl # workspace (268K).  The caller can now specific the windowBits and
1278 dnl # memLevel compression parameters to get a smaller workspace.
1279 dnl #
1280 AC_DEFUN([SPL_AC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE],
1281         [AC_MSG_CHECKING([whether zlib_deflate_workspacesize() wants 2 args])
1282         SPL_LINUX_TRY_COMPILE([
1283                 #include <linux/zlib.h>
1284         ],[
1285                 return zlib_deflate_workspacesize(MAX_WBITS, MAX_MEM_LEVEL);
1286         ],[
1287                 AC_MSG_RESULT(yes)
1288                 AC_DEFINE(HAVE_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE, 1,
1289                           [zlib_deflate_workspacesize() wants 2 args])
1290         ],[
1291                 AC_MSG_RESULT(no)
1292         ])
1293 ])
1294
1295 dnl #
1296 dnl # 2.6.39 API change,
1297 dnl # Shrinker adjust to use common shrink_control structure.
1298 dnl #
1299 AC_DEFUN([SPL_AC_SHRINK_CONTROL_STRUCT], [
1300         AC_MSG_CHECKING([whether struct shrink_control exists])
1301         SPL_LINUX_TRY_COMPILE([
1302                 #include <linux/mm.h>
1303         ],[
1304                 struct shrink_control sc __attribute__ ((unused));
1305
1306                 sc.nr_to_scan = 0;
1307                 sc.gfp_mask = GFP_KERNEL;
1308         ],[
1309                 AC_MSG_RESULT(yes)
1310                 AC_DEFINE(HAVE_SHRINK_CONTROL_STRUCT, 1,
1311                         [struct shrink_control exists])
1312         ],[
1313                 AC_MSG_RESULT(no)
1314         ])
1315 ])
1316
1317 dnl #
1318 dnl # 3.1 API Change
1319 dnl #
1320 dnl # The rw_semaphore.wait_lock member was changed from spinlock_t to
1321 dnl # raw_spinlock_t at commit ddb6c9b58a19edcfac93ac670b066c836ff729f1.
1322 dnl #
1323 AC_DEFUN([SPL_AC_RWSEM_SPINLOCK_IS_RAW], [
1324         AC_MSG_CHECKING([whether struct rw_semaphore member wait_lock is raw])
1325         tmp_flags="$EXTRA_KCFLAGS"
1326         EXTRA_KCFLAGS="-Werror"
1327         SPL_LINUX_TRY_COMPILE([
1328                 #include <linux/rwsem.h>
1329         ],[
1330                 struct rw_semaphore dummy_semaphore __attribute__ ((unused));
1331                 raw_spinlock_t dummy_lock __attribute__ ((unused));
1332                 dummy_semaphore.wait_lock = dummy_lock;
1333         ],[
1334                 AC_MSG_RESULT(yes)
1335                 AC_DEFINE(RWSEM_SPINLOCK_IS_RAW, 1,
1336                 [struct rw_semaphore member wait_lock is raw_spinlock_t])
1337         ],[
1338                 AC_MSG_RESULT(no)
1339         ])
1340         EXTRA_KCFLAGS="$tmp_flags"
1341 ])
1342
1343 dnl #
1344 dnl # 3.16 API Change
1345 dnl #
1346 dnl # rwsem-spinlock "->activity" changed to "->count"
1347 dnl #
1348 AC_DEFUN([SPL_AC_RWSEM_ACTIVITY], [
1349         AC_MSG_CHECKING([whether struct rw_semaphore has member activity])
1350         tmp_flags="$EXTRA_KCFLAGS"
1351         EXTRA_KCFLAGS="-Werror"
1352         SPL_LINUX_TRY_COMPILE([
1353                 #include <linux/rwsem.h>
1354         ],[
1355                 struct rw_semaphore dummy_semaphore __attribute__ ((unused));
1356                 dummy_semaphore.activity = 0;
1357         ],[
1358                 AC_MSG_RESULT(yes)
1359                 AC_DEFINE(HAVE_RWSEM_ACTIVITY, 1,
1360                 [struct rw_semaphore has member activity])
1361         ],[
1362                 AC_MSG_RESULT(no)
1363         ])
1364         EXTRA_KCFLAGS="$tmp_flags"
1365 ])
1366
1367 dnl #
1368 dnl # 4.8 API Change
1369 dnl #
1370 dnl # rwsem "->count" changed to atomic_long_t type
1371 dnl #
1372 AC_DEFUN([SPL_AC_RWSEM_ATOMIC_LONG_COUNT], [
1373         AC_MSG_CHECKING(
1374         [whether struct rw_semaphore has atomic_long_t member count])
1375         tmp_flags="$EXTRA_KCFLAGS"
1376         EXTRA_KCFLAGS="-Werror"
1377         SPL_LINUX_TRY_COMPILE([
1378                 #include <linux/rwsem.h>
1379         ],[
1380                 DECLARE_RWSEM(dummy_semaphore);
1381                 (void) atomic_long_read(&dummy_semaphore.count);
1382         ],[
1383                 AC_MSG_RESULT(yes)
1384                 AC_DEFINE(HAVE_RWSEM_ATOMIC_LONG_COUNT, 1,
1385                 [struct rw_semaphore has atomic_long_t member count])
1386         ],[
1387                 AC_MSG_RESULT(no)
1388         ])
1389         EXTRA_KCFLAGS="$tmp_flags"
1390 ])
1391
1392 dnl #
1393 dnl # 3.9 API change,
1394 dnl # Moved things from linux/sched.h to linux/sched/rt.h
1395 dnl #
1396 AC_DEFUN([SPL_AC_SCHED_RT_HEADER],
1397         [AC_MSG_CHECKING([whether header linux/sched/rt.h exists])
1398         SPL_LINUX_TRY_COMPILE([
1399                 #include <linux/sched.h>
1400                 #include <linux/sched/rt.h>
1401         ],[
1402                 return 0;
1403         ],[
1404                 AC_DEFINE(HAVE_SCHED_RT_HEADER, 1, [linux/sched/rt.h exists])
1405                 AC_MSG_RESULT(yes)
1406         ],[
1407                 AC_MSG_RESULT(no)
1408         ])
1409 ])
1410
1411 dnl #
1412 dnl # 3.9 API change,
1413 dnl # vfs_getattr() uses 2 args
1414 dnl # It takes struct path * instead of struct vfsmount * and struct dentry *
1415 dnl #
1416 AC_DEFUN([SPL_AC_2ARGS_VFS_GETATTR], [
1417         AC_MSG_CHECKING([whether vfs_getattr() wants])
1418         SPL_LINUX_TRY_COMPILE([
1419                 #include <linux/fs.h>
1420         ],[
1421                 vfs_getattr((struct path *) NULL,
1422                         (struct kstat *)NULL);
1423         ],[
1424                 AC_MSG_RESULT(2 args)
1425                 AC_DEFINE(HAVE_2ARGS_VFS_GETATTR, 1,
1426                           [vfs_getattr wants 2 args])
1427         ],[
1428                 SPL_LINUX_TRY_COMPILE([
1429                         #include <linux/fs.h>
1430                 ],[
1431                         vfs_getattr((struct vfsmount *)NULL,
1432                                 (struct dentry *)NULL,
1433                                 (struct kstat *)NULL);
1434                 ],[
1435                         AC_MSG_RESULT(3 args)
1436                 ],[
1437                         AC_MSG_ERROR(unknown)
1438                 ])
1439         ])
1440 ])
1441
1442 dnl #
1443 dnl # 2.6.36 API compatibility.
1444 dnl # Added usleep_range timer.
1445 dnl # usleep_range is a finer precision implementation of msleep
1446 dnl # designed to be a drop-in replacement for udelay where a precise
1447 dnl # sleep / busy-wait is unnecessary.
1448 dnl #
1449 AC_DEFUN([SPL_AC_USLEEP_RANGE], [
1450         AC_MSG_CHECKING([whether usleep_range() is available])
1451         SPL_LINUX_TRY_COMPILE([
1452                 #include <linux/delay.h>
1453         ],[
1454                 usleep_range(0, 0);
1455         ],[
1456                 AC_MSG_RESULT(yes)
1457                 AC_DEFINE(HAVE_USLEEP_RANGE, 1,
1458                           [usleep_range is available])
1459         ],[
1460                 AC_MSG_RESULT(no)
1461         ])
1462 ])
1463
1464 dnl #
1465 dnl # 2.6.35 API change,
1466 dnl # The cachep->gfpflags member was renamed cachep->allocflags.  These are
1467 dnl # private allocation flags which are applied when allocating a new slab
1468 dnl # in kmem_getpages().  Unfortunately there is no public API for setting
1469 dnl # non-default flags.
1470 dnl #
1471 AC_DEFUN([SPL_AC_KMEM_CACHE_ALLOCFLAGS], [
1472         AC_MSG_CHECKING([whether struct kmem_cache has allocflags])
1473         SPL_LINUX_TRY_COMPILE([
1474                 #include <linux/slab.h>
1475         ],[
1476                 struct kmem_cache cachep __attribute__ ((unused));
1477                 cachep.allocflags = GFP_KERNEL;
1478         ],[
1479                 AC_MSG_RESULT(yes)
1480                 AC_DEFINE(HAVE_KMEM_CACHE_ALLOCFLAGS, 1,
1481                         [struct kmem_cache has allocflags])
1482         ],[
1483                 AC_MSG_RESULT(no)
1484
1485                 AC_MSG_CHECKING([whether struct kmem_cache has gfpflags])
1486                 SPL_LINUX_TRY_COMPILE([
1487                         #include <linux/slab.h>
1488                 ],[
1489                         struct kmem_cache cachep __attribute__ ((unused));
1490                         cachep.gfpflags = GFP_KERNEL;
1491                 ],[
1492                         AC_MSG_RESULT(yes)
1493                         AC_DEFINE(HAVE_KMEM_CACHE_GFPFLAGS, 1,
1494                                 [struct kmem_cache has gfpflags])
1495                 ],[
1496                         AC_MSG_RESULT(no)
1497                 ])
1498         ])
1499 ])
1500
1501 dnl #
1502 dnl # 3.17 API change,
1503 dnl # wait_on_bit() no longer requires an action argument. The former
1504 dnl # "wait_on_bit" interface required an 'action' function to be provided
1505 dnl # which does the actual waiting. There were over 20 such functions in the
1506 dnl # kernel, many of them identical, though most cases can be satisfied by one
1507 dnl # of just two functions: one which uses io_schedule() and one which just
1508 dnl # uses schedule().  This API change was made to consolidate all of those
1509 dnl # redundant wait functions.
1510 dnl #
1511 AC_DEFUN([SPL_AC_WAIT_ON_BIT], [
1512         AC_MSG_CHECKING([whether wait_on_bit() takes an action])
1513         SPL_LINUX_TRY_COMPILE([
1514                 #include <linux/wait.h>
1515         ],[
1516                 int (*action)(void *) = NULL;
1517                 wait_on_bit(NULL, 0, action, 0);
1518         ],[
1519                 AC_MSG_RESULT(yes)
1520                 AC_DEFINE(HAVE_WAIT_ON_BIT_ACTION, 1, [yes])
1521         ],[
1522                 AC_MSG_RESULT(no)
1523         ])
1524 ])
1525
1526 dnl #
1527 dnl # Check whether mutex has owner with task_struct type.
1528 dnl #
1529 dnl # Note that before Linux 3.0, mutex owner is of type thread_info.
1530 dnl #
1531 dnl # Note that in Linux 3.18, the condition for owner is changed from
1532 dnl # defined(CONFIG_DEBUG_MUTEXES) || defined(CONFIG_SMP) to
1533 dnl # defined(CONFIG_DEBUG_MUTEXES) || defined(CONFIG_MUTEX_SPIN_ON_OWNER)
1534 dnl #
1535 AC_DEFUN([SPL_AC_MUTEX_OWNER], [
1536         AC_MSG_CHECKING([whether mutex has owner])
1537         tmp_flags="$EXTRA_KCFLAGS"
1538         EXTRA_KCFLAGS="-Werror"
1539         SPL_LINUX_TRY_COMPILE([
1540                 #include <linux/mutex.h>
1541                 #include <linux/spinlock.h>
1542         ],[
1543                 DEFINE_MUTEX(m);
1544                 struct task_struct *t __attribute__ ((unused));
1545                 t = m.owner;
1546         ],[
1547                 AC_MSG_RESULT(yes)
1548                 AC_DEFINE(HAVE_MUTEX_OWNER, 1, [yes])
1549         ],[
1550                 AC_MSG_RESULT(no)
1551         ])
1552         EXTRA_KCFLAGS="$tmp_flags"
1553 ])
1554
1555 dnl #
1556 dnl # 4.7 API change
1557 dnl # i_mutex is changed to i_rwsem. Instead of directly using
1558 dnl # i_mutex/i_rwsem, we should use inode_lock() and inode_lock_shared()
1559 dnl # We test inode_lock_shared because inode_lock is introduced earlier.
1560 dnl #
1561 AC_DEFUN([SPL_AC_INODE_LOCK], [
1562         AC_MSG_CHECKING([whether inode_lock_shared() exists])
1563         tmp_flags="$EXTRA_KCFLAGS"
1564         EXTRA_KCFLAGS="-Werror"
1565         SPL_LINUX_TRY_COMPILE([
1566                 #include <linux/fs.h>
1567         ],[
1568                 struct inode *inode = NULL;
1569                 inode_lock_shared(inode);
1570         ],[
1571                 AC_MSG_RESULT(yes)
1572                 AC_DEFINE(HAVE_INODE_LOCK_SHARED, 1, [yes])
1573         ],[
1574                 AC_MSG_RESULT(no)
1575         ])
1576         EXTRA_KCFLAGS="$tmp_flags"
1577 ])
1578
1579 dnl #
1580 dnl # 4.9 API change
1581 dnl # group_info changed from 2d array via >blocks to 1d array via ->gid
1582 dnl #
1583 AC_DEFUN([SPL_AC_GROUP_INFO_GID], [
1584         AC_MSG_CHECKING([whether group_info->gid exists])
1585         tmp_flags="$EXTRA_KCFLAGS"
1586         EXTRA_KCFLAGS="-Werror"
1587         SPL_LINUX_TRY_COMPILE([
1588                 #include <linux/cred.h>
1589         ],[
1590                 struct group_info *gi = groups_alloc(1);
1591                 gi->gid[0] = KGIDT_INIT(0);
1592         ],[
1593                 AC_MSG_RESULT(yes)
1594                 AC_DEFINE(HAVE_GROUP_INFO_GID, 1, [group_info->gid exists])
1595         ],[
1596                 AC_MSG_RESULT(no)
1597         ])
1598         EXTRA_KCFLAGS="$tmp_flags"
1599 ])