[mirror_zfs.git] / config / zfs-build.m4

AC_DEFUN([ZFS_AC_LICENSE], [
	AC_MSG_CHECKING([zfs author])
	AC_MSG_RESULT([$ZFS_META_AUTHOR])

	AC_MSG_CHECKING([zfs license])
	AC_MSG_RESULT([$ZFS_META_LICENSE])
])

AC_DEFUN([ZFS_AC_DEBUG], [
	AC_MSG_CHECKING([whether debugging is enabled])
	AC_ARG_ENABLE([debug],
		[AS_HELP_STRING([--enable-debug],
		[Enable generic debug support @<:@default=no@:>@])],
		[],
		[enable_debug=no])

	AS_IF([test "x$enable_debug" = xyes],
	[
		KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
		HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
		DEBUG_CFLAGS="-DDEBUG -Werror"
		DEBUG_STACKFLAGS="-fstack-check"
		DEBUG_ZFS="_with_debug"
		AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
	],
	[
		KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
		HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
		DEBUG_CFLAGS="-DNDEBUG"
		DEBUG_STACKFLAGS=""
		DEBUG_ZFS="_without_debug"
	])

	AC_SUBST(DEBUG_CFLAGS)
	AC_SUBST(DEBUG_STACKFLAGS)
	AC_SUBST(DEBUG_ZFS)
	AC_MSG_RESULT([$enable_debug])
])

AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
	ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE
])

AC_DEFUN([ZFS_AC_CONFIG], [
	TARGET_ASM_DIR=asm-generic
	AC_SUBST(TARGET_ASM_DIR)

	ZFS_CONFIG=all
	AC_ARG_WITH([config],
		AS_HELP_STRING([--with-config=CONFIG],
		[Config file 'kernel|user|all|srpm']),
		[ZFS_CONFIG="$withval"])

	AC_MSG_CHECKING([zfs config])
	AC_MSG_RESULT([$ZFS_CONFIG]);
	AC_SUBST(ZFS_CONFIG)

	ZFS_AC_CONFIG_ALWAYS

	case "$ZFS_CONFIG" in
		kernel) ZFS_AC_CONFIG_KERNEL ;;
		user)	ZFS_AC_CONFIG_USER   ;;
		all)    ZFS_AC_CONFIG_KERNEL
			ZFS_AC_CONFIG_USER   ;;
		srpm)                        ;;
		*)
		AC_MSG_RESULT([Error!])
		AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
		              user kernel|user|all|srpm]) ;;
	esac

	AM_CONDITIONAL([CONFIG_USER],
	               [test "$ZFS_CONFIG" = user] ||
	               [test "$ZFS_CONFIG" = all])
	AM_CONDITIONAL([CONFIG_KERNEL],
	               [test "$ZFS_CONFIG" = kernel] ||
	               [test "$ZFS_CONFIG" = all])
])

dnl #
dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
dnl # are missing it is non-fatal but you will not be able to build
dnl # RPM packages and will be warned if you try too.
dnl #
AC_DEFUN([ZFS_AC_RPM], [
	RPM=rpm
	RPMBUILD=rpmbuild

	AC_MSG_CHECKING([whether $RPM is available])
	AS_IF([tmp=$($RPM --version 2>/dev/null)], [
		RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
		HAVE_RPM=yes
		AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
	],[
		HAVE_RPM=no
		AC_MSG_RESULT([$HAVE_RPM])
	])

	AC_MSG_CHECKING([whether $RPMBUILD is available])
	AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
		RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
		HAVE_RPMBUILD=yes
		AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
	],[
		HAVE_RPMBUILD=no
		AC_MSG_RESULT([$HAVE_RPMBUILD])
	])

	AC_SUBST(HAVE_RPM)
	AC_SUBST(RPM)
	AC_SUBST(RPM_VERSION)

	AC_SUBST(HAVE_RPMBUILD)
	AC_SUBST(RPMBUILD)
	AC_SUBST(RPMBUILD_VERSION)
])

dnl #
dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
dnl # tools are missing it is non-fatal but you will not be able to build
dnl # DEB packages and will be warned if you try too.
dnl #
AC_DEFUN([ZFS_AC_DPKG], [
	DPKG=dpkg
	DPKGBUILD=dpkg-buildpackage

	AC_MSG_CHECKING([whether $DPKG is available])
	AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
		DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
		HAVE_DPKG=yes
		AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
	],[
		HAVE_DPKG=no
		AC_MSG_RESULT([$HAVE_DPKG])
	])

	AC_MSG_CHECKING([whether $DPKGBUILD is available])
	AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
		DPKGBUILD_VERSION=$(echo $tmp | \
		    $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
		HAVE_DPKGBUILD=yes
		AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
	],[
		HAVE_DPKGBUILD=no
		AC_MSG_RESULT([$HAVE_DPKGBUILD])
	])

	AC_SUBST(HAVE_DPKG)
	AC_SUBST(DPKG)
	AC_SUBST(DPKG_VERSION)

	AC_SUBST(HAVE_DPKGBUILD)
	AC_SUBST(DPKGBUILD)
	AC_SUBST(DPKGBUILD_VERSION)
])

dnl #
dnl # Until native packaging for various different packing systems
dnl # can be added the least we can do is attempt to use alien to
dnl # convert the RPM packages to the needed package type.  This is
dnl # a hack but so far it has worked reasonable well.
dnl #
AC_DEFUN([ZFS_AC_ALIEN], [
	ALIEN=alien

	AC_MSG_CHECKING([whether $ALIEN is available])
	AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
		ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
		HAVE_ALIEN=yes
		AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
	],[
		HAVE_ALIEN=no
		AC_MSG_RESULT([$HAVE_ALIEN])
	])

	AC_SUBST(HAVE_ALIEN)
	AC_SUBST(ALIEN)
	AC_SUBST(ALIEN_VERSION)
])

dnl #
dnl # Check for pacman+makepkg to build Arch Linux packages.  If these
dnl # tools are missing it is non-fatal but you will not be able to
dnl # build Arch Linux packages and will be warned if you try too.
dnl #
AC_DEFUN([ZFS_AC_PACMAN], [
	PACMAN=pacman
	MAKEPKG=makepkg

	AC_MSG_CHECKING([whether $PACMAN is available])
	tmp=$($PACMAN --version 2>/dev/null)
	AS_IF([test -n "$tmp"], [
		PACMAN_VERSION=$(echo $tmp |
		                 $AWK '/Pacman/ { print $[3] }' |
		                 $SED 's/^v//')
		HAVE_PACMAN=yes
		AC_MSG_RESULT([$HAVE_PACMAN ($PACMAN_VERSION)])
	],[
		HAVE_PACMAN=no
		AC_MSG_RESULT([$HAVE_PACMAN])
	])

	AC_MSG_CHECKING([whether $MAKEPKG is available])
	tmp=$($MAKEPKG --version 2>/dev/null)
	AS_IF([test -n "$tmp"], [
		MAKEPKG_VERSION=$(echo $tmp | $AWK '/makepkg/ { print $[3] }')
		HAVE_MAKEPKG=yes
		AC_MSG_RESULT([$HAVE_MAKEPKG ($MAKEPKG_VERSION)])
	],[
		HAVE_MAKEPKG=no
		AC_MSG_RESULT([$HAVE_MAKEPKG])
	])

	AC_SUBST(HAVE_PACMAN)
	AC_SUBST(PACMAN)
	AC_SUBST(PACMAN_VERSION)

	AC_SUBST(HAVE_MAKEPKG)
	AC_SUBST(MAKEPKG)
	AC_SUBST(MAKEPKG_VERSION)
])

dnl #
dnl # Using the VENDOR tag from config.guess set the default
dnl # package type for 'make pkg': (rpm | deb | tgz)
dnl #
AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
	AC_MSG_CHECKING([linux distribution])
	if test -f /etc/redhat-release ; then
		VENDOR=redhat ;
	elif test -f /etc/fedora-release ; then
		VENDOR=fedora ;
	elif test -f /etc/gentoo-release ; then
		VENDOR=gentoo ;
	elif test -f /etc/debian_version ; then
		VENDOR=debian ;
	elif test -f /etc/SuSE-release ; then
		VENDOR=sles ;
	elif test -f /etc/slackware-version ; then
		VENDOR=slackware ;
	elif test -f /etc/arch-release ; then
		VENDOR=arch ;
	elif test -f /etc/lsb-release ; then
		VENDOR=ubuntu ;
	elif test -f /etc/lunar.release ; then
		VENDOR=lunar ;
	else
		VENDOR= ;
	fi
	AC_MSG_RESULT([$VENDOR])
	AC_SUBST(VENDOR)

	AC_MSG_CHECKING([default package type])
	case "$VENDOR" in
		redhat)     DEFAULT_PACKAGE=rpm ;;
		fedora)     DEFAULT_PACKAGE=rpm ;;
		ubuntu)     DEFAULT_PACKAGE=deb ;;
		debian)     DEFAULT_PACKAGE=deb ;;
		sles)       DEFAULT_PACKAGE=rpm ;;
		slackware)  DEFAULT_PACKAGE=tgz ;;
		gentoo)     DEFAULT_PACKAGE=tgz ;;
		lunar)      DEFAULT_PACKAGE=tgz ;;
		arch)       DEFAULT_PACKAGE=arch;;
		*)          DEFAULT_PACKAGE=rpm ;;
	esac

	AC_MSG_RESULT([$DEFAULT_PACKAGE])
	AC_SUBST(DEFAULT_PACKAGE)

	AC_MSG_CHECKING([default init directory])
	case "$VENDOR" in
		arch)       DEFAULT_INIT_DIR=$sysconfdir/rc.d ;;
		*)          DEFAULT_INIT_DIR=$sysconfdir/init.d ;;
	esac

	AC_MSG_RESULT([$DEFAULT_INIT_DIR])
	AC_SUBST(DEFAULT_INIT_DIR)

	AC_MSG_CHECKING([default init script type])
	case "$VENDOR" in
		redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
		fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
		ubuntu)     DEFAULT_INIT_SCRIPT=lsb ;;
		debian)     DEFAULT_INIT_SCRIPT=lsb ;;
		sles)       DEFAULT_INIT_SCRIPT=lsb ;;
		slackware)  DEFAULT_INIT_SCRIPT=lsb ;;
		gentoo)     DEFAULT_INIT_SCRIPT=gentoo ;;
		lunar)      DEFAULT_INIT_SCRIPT=lunar ;;
		arch)       DEFAULT_INIT_SCRIPT=arch ;;
		*)          DEFAULT_INIT_SCRIPT=lsb ;;
	esac

	AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
	AC_SUBST(DEFAULT_INIT_SCRIPT)
])

dnl #
dnl # Default ZFS package configuration
dnl #
AC_DEFUN([ZFS_AC_PACKAGE], [
	ZFS_AC_DEFAULT_PACKAGE
	ZFS_AC_RPM
	ZFS_AC_DPKG
	ZFS_AC_ALIEN

	AS_IF([test "$VENDOR" = "arch"], [ZFS_AC_PACMAN])
])
Commit	Line	Data
c9c0d073 BB	1	AC_DEFUN([ZFS_AC_LICENSE], [
	2	AC_MSG_CHECKING([zfs author])
	3	AC_MSG_RESULT([$ZFS_META_AUTHOR])
	4
	5	AC_MSG_CHECKING([zfs license])
	6	AC_MSG_RESULT([$ZFS_META_LICENSE])
	7	])
	8
	9	AC_DEFUN([ZFS_AC_DEBUG], [
	10	AC_MSG_CHECKING([whether debugging is enabled])
	11	AC_ARG_ENABLE([debug],
	12	[AS_HELP_STRING([--enable-debug],
	13	[Enable generic debug support @<:@default=no@:>@])],
	14	[],
	15	[enable_debug=no])
	16
	17	AS_IF([test "x$enable_debug" = xyes],
	18	[
	19	KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
	20	HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
	21	DEBUG_CFLAGS="-DDEBUG -Werror"
	22	DEBUG_STACKFLAGS="-fstack-check"
4b787d75 BB	23	DEBUG_ZFS="_with_debug"
4b787d75 BB	24	AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
c9c0d073 BB	25	],
	26	[
	27	KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
	28	HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
	29	DEBUG_CFLAGS="-DNDEBUG"
	30	DEBUG_STACKFLAGS=""
4b787d75	31	DEBUG_ZFS="_without_debug"
c9c0d073 BB	32	])
	33
	34	AC_SUBST(DEBUG_CFLAGS)
	35	AC_SUBST(DEBUG_STACKFLAGS)
4b787d75	36	AC_SUBST(DEBUG_ZFS)
c9c0d073 BB	37	AC_MSG_RESULT([$enable_debug])
	38	])
	39
2e08aedb BB	40	AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
	41	ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE
	42	])
	43
c9c0d073	44	AC_DEFUN([ZFS_AC_CONFIG], [
c9c0d073	45	TARGET_ASM_DIR=asm-generic
c9c0d073 BB	46	AC_SUBST(TARGET_ASM_DIR)
	47
	48	ZFS_CONFIG=all
	49	AC_ARG_WITH([config],
	50	AS_HELP_STRING([--with-config=CONFIG],
	51	[Config file 'kernel\|user\|all\|srpm']),
	52	[ZFS_CONFIG="$withval"])
	53
	54	AC_MSG_CHECKING([zfs config])
	55	AC_MSG_RESULT([$ZFS_CONFIG]);
	56	AC_SUBST(ZFS_CONFIG)
	57
2e08aedb BB	58	ZFS_AC_CONFIG_ALWAYS
2e08aedb BB	59
c9c0d073 BB	60	case "$ZFS_CONFIG" in
	61	kernel) ZFS_AC_CONFIG_KERNEL ;;
	62	user) ZFS_AC_CONFIG_USER ;;
	63	all) ZFS_AC_CONFIG_KERNEL
	64	ZFS_AC_CONFIG_USER ;;
	65	srpm) ;;
	66	*)
	67	AC_MSG_RESULT([Error!])
	68	AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
	69	user kernel\|user\|all\|srpm]) ;;
	70	esac
	71
	72	AM_CONDITIONAL([CONFIG_USER],
	73	[test "$ZFS_CONFIG" = user] \|\|
	74	[test "$ZFS_CONFIG" = all])
	75	AM_CONDITIONAL([CONFIG_KERNEL],
	76	[test "$ZFS_CONFIG" = kernel] \|\|
	77	[test "$ZFS_CONFIG" = all])
c9c0d073 BB	78	])
	79
	80	dnl #
	81	dnl # Check for rpm+rpmbuild to build RPM packages. If these tools
	82	dnl # are missing it is non-fatal but you will not be able to build
	83	dnl # RPM packages and will be warned if you try too.
	84	dnl #
	85	AC_DEFUN([ZFS_AC_RPM], [
	86	RPM=rpm
	87	RPMBUILD=rpmbuild
	88
	89	AC_MSG_CHECKING([whether $RPM is available])
	90	AS_IF([tmp=$($RPM --version 2>/dev/null)], [
	91	RPM_VERSION=$(echo $tmp \| $AWK '/RPM/ { print $[3] }')
	92	HAVE_RPM=yes
	93	AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
	94	],[
	95	HAVE_RPM=no
	96	AC_MSG_RESULT([$HAVE_RPM])
	97	])
	98
	99	AC_MSG_CHECKING([whether $RPMBUILD is available])
	100	AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
	101	RPMBUILD_VERSION=$(echo $tmp \| $AWK '/RPM/ { print $[3] }')
	102	HAVE_RPMBUILD=yes
	103	AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
	104	],[
	105	HAVE_RPMBUILD=no
	106	AC_MSG_RESULT([$HAVE_RPMBUILD])
	107	])
	108
	109	AC_SUBST(HAVE_RPM)
	110	AC_SUBST(RPM)
	111	AC_SUBST(RPM_VERSION)
	112
	113	AC_SUBST(HAVE_RPMBUILD)
	114	AC_SUBST(RPMBUILD)
	115	AC_SUBST(RPMBUILD_VERSION)
	116	])
	117
	118	dnl #
	119	dnl # Check for dpkg+dpkg-buildpackage to build DEB packages. If these
	120	dnl # tools are missing it is non-fatal but you will not be able to build
	121	dnl # DEB packages and will be warned if you try too.
	122	dnl #
	123	AC_DEFUN([ZFS_AC_DPKG], [
	124	DPKG=dpkg
	125	DPKGBUILD=dpkg-buildpackage
	126
	127	AC_MSG_CHECKING([whether $DPKG is available])
	128	AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
	129	DPKG_VERSION=$(echo $tmp \| $AWK '/Debian/ { print $[7] }')
	130	HAVE_DPKG=yes
	131	AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
	132	],[
	133	HAVE_DPKG=no
	134	AC_MSG_RESULT([$HAVE_DPKG])
	135	])
	136
	137	AC_MSG_CHECKING([whether $DPKGBUILD is available])
	138	AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
	139	DPKGBUILD_VERSION=$(echo $tmp \| \
	140	$AWK '/Debian/ { print $[4] }' \| cut -f-4 -d'.')
	141	HAVE_DPKGBUILD=yes
142	AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
143	],[
144	HAVE_DPKGBUILD=no
145	AC_MSG_RESULT([$HAVE_DPKGBUILD])
146	])
147
148	AC_SUBST(HAVE_DPKG)
149	AC_SUBST(DPKG)
150	AC_SUBST(DPKG_VERSION)
151
152	AC_SUBST(HAVE_DPKGBUILD)
153	AC_SUBST(DPKGBUILD)
154	AC_SUBST(DPKGBUILD_VERSION)
155	])
156
157	dnl #
158	dnl # Until native packaging for various different packing systems
159	dnl # can be added the least we can do is attempt to use alien to
160	dnl # convert the RPM packages to the needed package type. This is
161	dnl # a hack but so far it has worked reasonable well.
162	dnl #
163	AC_DEFUN([ZFS_AC_ALIEN], [
164	ALIEN=alien
165
166	AC_MSG_CHECKING([whether $ALIEN is available])
167	AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
168	ALIEN_VERSION=$(echo $tmp \| $AWK '{ print $[3] }')
169	HAVE_ALIEN=yes
170	AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
171	],[
172	HAVE_ALIEN=no
173	AC_MSG_RESULT([$HAVE_ALIEN])
174	])
175
176	AC_SUBST(HAVE_ALIEN)
177	AC_SUBST(ALIEN)
178	AC_SUBST(ALIEN_VERSION)
179	])
180
6ba3b446 PS	181	dnl #
	182	dnl # Check for pacman+makepkg to build Arch Linux packages. If these
	183	dnl # tools are missing it is non-fatal but you will not be able to
	184	dnl # build Arch Linux packages and will be warned if you try too.
	185	dnl #
	186	AC_DEFUN([ZFS_AC_PACMAN], [
	187	PACMAN=pacman
	188	MAKEPKG=makepkg
	189
	190	AC_MSG_CHECKING([whether $PACMAN is available])
	191	tmp=$($PACMAN --version 2>/dev/null)
	192	AS_IF([test -n "$tmp"], [
	193	PACMAN_VERSION=$(echo $tmp \|
	194	$AWK '/Pacman/ { print $[3] }' \|
	195	$SED 's/^v//')
	196	HAVE_PACMAN=yes
	197	AC_MSG_RESULT([$HAVE_PACMAN ($PACMAN_VERSION)])
	198	],[
	199	HAVE_PACMAN=no
	200	AC_MSG_RESULT([$HAVE_PACMAN])
	201	])
	202
	203	AC_MSG_CHECKING([whether $MAKEPKG is available])
	204	tmp=$($MAKEPKG --version 2>/dev/null)
	205	AS_IF([test -n "$tmp"], [
	206	MAKEPKG_VERSION=$(echo $tmp \| $AWK '/makepkg/ { print $[3] }')
	207	HAVE_MAKEPKG=yes
	208	AC_MSG_RESULT([$HAVE_MAKEPKG ($MAKEPKG_VERSION)])
	209	],[
	210	HAVE_MAKEPKG=no
	211	AC_MSG_RESULT([$HAVE_MAKEPKG])
	212	])
	213
	214	AC_SUBST(HAVE_PACMAN)
	215	AC_SUBST(PACMAN)
	216	AC_SUBST(PACMAN_VERSION)
	217
	218	AC_SUBST(HAVE_MAKEPKG)
	219	AC_SUBST(MAKEPKG)
	220	AC_SUBST(MAKEPKG_VERSION)
	221	])
	222
c9c0d073 BB	223	dnl #
	224	dnl # Using the VENDOR tag from config.guess set the default
	225	dnl # package type for 'make pkg': (rpm \| deb \| tgz)
	226	dnl #
	227	AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
	228	AC_MSG_CHECKING([linux distribution])
	229	if test -f /etc/redhat-release ; then
	230	VENDOR=redhat ;
	231	elif test -f /etc/fedora-release ; then
	232	VENDOR=fedora ;
d9bfe0f5 AS	233	elif test -f /etc/gentoo-release ; then
d9bfe0f5 AS	234	VENDOR=gentoo ;
6283f55e BB	235	elif test -f /etc/debian_version ; then
6283f55e BB	236	VENDOR=debian ;
c9c0d073 BB	237	elif test -f /etc/SuSE-release ; then
	238	VENDOR=sles ;
	239	elif test -f /etc/slackware-version ; then
	240	VENDOR=slackware ;
8eaa020b PS	241	elif test -f /etc/arch-release ; then
8eaa020b PS	242	VENDOR=arch ;
d9bfe0f5 AS	243	elif test -f /etc/lsb-release ; then
d9bfe0f5 AS	244	VENDOR=ubuntu ;
712f8bd8 BB	245	elif test -f /etc/lunar.release ; then
712f8bd8 BB	246	VENDOR=lunar ;
c9c0d073 BB	247	else
	248	VENDOR= ;
	249	fi
	250	AC_MSG_RESULT([$VENDOR])
	251	AC_SUBST(VENDOR)
	252
	253	AC_MSG_CHECKING([default package type])
	254	case "$VENDOR" in
c9c0d073	255	redhat) DEFAULT_PACKAGE=rpm ;;
712f8bd8	256	fedora) DEFAULT_PACKAGE=rpm ;;
c9c0d073 BB	257	ubuntu) DEFAULT_PACKAGE=deb ;;
c9c0d073 BB	258	debian) DEFAULT_PACKAGE=deb ;;
712f8bd8	259	sles) DEFAULT_PACKAGE=rpm ;;
c9c0d073	260	slackware) DEFAULT_PACKAGE=tgz ;;
712f8bd8 BB	261	gentoo) DEFAULT_PACKAGE=tgz ;;
712f8bd8 BB	262	lunar) DEFAULT_PACKAGE=tgz ;;
6ba3b446	263	arch) DEFAULT_PACKAGE=arch;;
c9c0d073 BB	264	*) DEFAULT_PACKAGE=rpm ;;
	265	esac
	266
	267	AC_MSG_RESULT([$DEFAULT_PACKAGE])
	268	AC_SUBST(DEFAULT_PACKAGE)
01c0e61d	269
615ab66d KF	270	AC_MSG_CHECKING([default init directory])
	271	case "$VENDOR" in
	272	arch) DEFAULT_INIT_DIR=$sysconfdir/rc.d ;;
	273	*) DEFAULT_INIT_DIR=$sysconfdir/init.d ;;
	274	esac
	275
	276	AC_MSG_RESULT([$DEFAULT_INIT_DIR])
	277	AC_SUBST(DEFAULT_INIT_DIR)
	278
01c0e61d BB	279	AC_MSG_CHECKING([default init script type])
01c0e61d BB	280	case "$VENDOR" in
712f8bd8	281	redhat) DEFAULT_INIT_SCRIPT=redhat ;;
01c0e61d	282	fedora) DEFAULT_INIT_SCRIPT=fedora ;;
01c0e61d BB	283	ubuntu) DEFAULT_INIT_SCRIPT=lsb ;;
01c0e61d BB	284	debian) DEFAULT_INIT_SCRIPT=lsb ;;
712f8bd8	285	sles) DEFAULT_INIT_SCRIPT=lsb ;;
01c0e61d	286	slackware) DEFAULT_INIT_SCRIPT=lsb ;;
712f8bd8 BB	287	gentoo) DEFAULT_INIT_SCRIPT=gentoo ;;
712f8bd8 BB	288	lunar) DEFAULT_INIT_SCRIPT=lunar ;;
615ab66d	289	arch) DEFAULT_INIT_SCRIPT=arch ;;
01c0e61d BB	290	*) DEFAULT_INIT_SCRIPT=lsb ;;
	291	esac
	292
	293	AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
	294	AC_SUBST(DEFAULT_INIT_SCRIPT)
c9c0d073 BB	295	])
	296
	297	dnl #
	298	dnl # Default ZFS package configuration
	299	dnl #
	300	AC_DEFUN([ZFS_AC_PACKAGE], [
58d956b0	301	ZFS_AC_DEFAULT_PACKAGE
c9c0d073 BB	302	ZFS_AC_RPM
	303	ZFS_AC_DPKG
	304	ZFS_AC_ALIEN
58d956b0 PS	305
58d956b0 PS	306	AS_IF([test "$VENDOR" = "arch"], [ZFS_AC_PACMAN])
c9c0d073	307	])