[mirror_zfs.git] / config / zfs-meta.m4

dnl #
dnl # DESCRIPTION:
dnl # Read meta data from the META file.  When building from a git repository
dnl # the ZFS_META_RELEASE field will be overwritten if there is an annotated
dnl # tag matching the form ZFS_META_NAME-ZFS_META_VERSION-*.  This allows
dnl # for working builds to be uniquely identified using the git commit hash.
dnl #
dnl #    The META file format is as follows:
dnl #      ^[ ]*KEY:[ \t]+VALUE$
dnl #
dnl #    In other words:
dnl #    - KEY is separated from VALUE by a colon and one or more spaces/tabs.
dnl #    - KEY and VALUE are case sensitive.
dnl #    - Leading spaces are ignored.
dnl #    - First match wins for duplicate keys.
dnl #
dnl #    A line can be commented out by preceding it with a '#' (or technically
dnl #    any non-space character since that will prevent the regex from
dnl #    matching).
dnl #
dnl # WARNING:
dnl #   Placing a colon followed by a space or tab (ie, ":[ \t]+") within the
dnl #   VALUE will prematurely terminate the string since that sequence is
dnl #   used as the awk field separator.
dnl #
dnl # KEYS:
dnl #   The following META keys are recognized:
dnl #     Name, Version, Release, Date, Author, LT_Current, LT_Revision, LT_Age
dnl #
dnl # Written by Chris Dunlap <cdunlap@llnl.gov>.
dnl # Modified by Brian Behlendorf <behlendorf1@llnl.gov>.
dnl #
AC_DEFUN([ZFS_AC_META], [

	AH_BOTTOM([
#undef PACKAGE
#undef PACKAGE_BUGREPORT
#undef PACKAGE_NAME
#undef PACKAGE_STRING
#undef PACKAGE_TARNAME
#undef PACKAGE_VERSION
#undef STDC_HEADERS
#undef VERSION])

	AC_PROG_AWK
	AC_MSG_CHECKING([metadata])

	META="$srcdir/META"
	_zfs_ac_meta_type="none"
	if test -f "$META"; then
		_zfs_ac_meta_type="META file"

		ZFS_META_NAME=_ZFS_AC_META_GETVAL([(Name|Project|Package)]);
		if test -n "$ZFS_META_NAME"; then
			AC_DEFINE_UNQUOTED([ZFS_META_NAME], ["$ZFS_META_NAME"],
				[Define the project name.]
			)
			AC_SUBST([ZFS_META_NAME])
		fi

		ZFS_META_VERSION=_ZFS_AC_META_GETVAL([Version]);
		if test -n "$ZFS_META_VERSION"; then
			AC_DEFINE_UNQUOTED([ZFS_META_VERSION],
			    ["$ZFS_META_VERSION"],
			    [Define the project version.])
			AC_DEFINE_UNQUOTED([SPL_META_VERSION],
			    [ZFS_META_VERSION],
			    [Defined for legacy compatibility.])
			AC_SUBST([ZFS_META_VERSION])
		fi

		ZFS_META_RELEASE=_ZFS_AC_META_GETVAL([Release]);
		if test ! -f ".nogitrelease" && git rev-parse --git-dir > /dev/null 2>&1; then
			_match="${ZFS_META_NAME}-${ZFS_META_VERSION}"
			_alias=$(git describe --match=${_match} 2>/dev/null)
			_release=$(echo ${_alias}|cut -f3- -d'-'|sed 's/-/_/g')
			if test -n "${_release}"; then
				ZFS_META_RELEASE=${_release}
				_zfs_ac_meta_type="git describe"
			else
				_match="${ZFS_META_NAME}-${ZFS_META_VERSION}-${ZFS_META_RELEASE}"
	                        _alias=$(git describe --match=${_match} 2>/dev/null)
	                        _release=$(echo ${_alias}|cut -f3- -d'-'|sed 's/-/_/g')
				if test -n "${_release}"; then
					ZFS_META_RELEASE=${_release}
					_zfs_ac_meta_type="git describe"
				fi
			fi
		fi

		if test -n "$ZFS_META_RELEASE"; then
			AC_DEFINE_UNQUOTED([ZFS_META_RELEASE],
			     ["$ZFS_META_RELEASE"],
			     [Define the project release.])
			AC_DEFINE_UNQUOTED([SPL_META_RELEASE],
			    [ZFS_META_RELEASE],
			    [Defined for legacy compatibility.])
			AC_SUBST([ZFS_META_RELEASE])

			RELEASE="$ZFS_META_RELEASE"
			AC_SUBST([RELEASE])
		fi

		ZFS_META_LICENSE=_ZFS_AC_META_GETVAL([License]);
		if test -n "$ZFS_META_LICENSE"; then
			AC_DEFINE_UNQUOTED([ZFS_META_LICENSE], ["$ZFS_META_LICENSE"],
				[Define the project license.]
			)
			AC_SUBST([ZFS_META_LICENSE])
		fi

		if test -n "$ZFS_META_NAME" -a -n "$ZFS_META_VERSION"; then
				ZFS_META_ALIAS="$ZFS_META_NAME-$ZFS_META_VERSION"
				test -n "$ZFS_META_RELEASE" && 
				        ZFS_META_ALIAS="$ZFS_META_ALIAS-$ZFS_META_RELEASE"
				AC_DEFINE_UNQUOTED([ZFS_META_ALIAS],
				    ["$ZFS_META_ALIAS"],
				    [Define the project alias string.])
				AC_DEFINE_UNQUOTED([SPL_META_ALIAS],
				    [ZFS_META_ALIAS],
				    [Defined for legacy compatibility.])
				AC_SUBST([ZFS_META_ALIAS])
		fi

		ZFS_META_DATA=_ZFS_AC_META_GETVAL([Date]);
		if test -n "$ZFS_META_DATA"; then
			AC_DEFINE_UNQUOTED([ZFS_META_DATA], ["$ZFS_META_DATA"],
				[Define the project release date.] 
			)
			AC_SUBST([ZFS_META_DATA])
		fi

		ZFS_META_AUTHOR=_ZFS_AC_META_GETVAL([Author]);
		if test -n "$ZFS_META_AUTHOR"; then
			AC_DEFINE_UNQUOTED([ZFS_META_AUTHOR], ["$ZFS_META_AUTHOR"],
				[Define the project author.]
			)
			AC_SUBST([ZFS_META_AUTHOR])
		fi

		m4_pattern_allow([^LT_(CURRENT|REVISION|AGE)$])
		ZFS_META_LT_CURRENT=_ZFS_AC_META_GETVAL([LT_Current]);
		ZFS_META_LT_REVISION=_ZFS_AC_META_GETVAL([LT_Revision]);
		ZFS_META_LT_AGE=_ZFS_AC_META_GETVAL([LT_Age]);
		if test -n "$ZFS_META_LT_CURRENT" \
				 -o -n "$ZFS_META_LT_REVISION" \
				 -o -n "$ZFS_META_LT_AGE"; then
			test -n "$ZFS_META_LT_CURRENT" || ZFS_META_LT_CURRENT="0"
			test -n "$ZFS_META_LT_REVISION" || ZFS_META_LT_REVISION="0"
			test -n "$ZFS_META_LT_AGE" || ZFS_META_LT_AGE="0"
			AC_DEFINE_UNQUOTED([ZFS_META_LT_CURRENT],
				["$ZFS_META_LT_CURRENT"],
				[Define the libtool library 'current'
				 version information.]
			)
			AC_DEFINE_UNQUOTED([ZFS_META_LT_REVISION],
				["$ZFS_META_LT_REVISION"],
				[Define the libtool library 'revision'
				 version information.]
			)
			AC_DEFINE_UNQUOTED([ZFS_META_LT_AGE], ["$ZFS_META_LT_AGE"],
				[Define the libtool library 'age' 
				 version information.]
			)
			AC_SUBST([ZFS_META_LT_CURRENT])
			AC_SUBST([ZFS_META_LT_REVISION])
			AC_SUBST([ZFS_META_LT_AGE])
		fi
	fi

	AC_MSG_RESULT([$_zfs_ac_meta_type])
	]
)

dnl # _ZFS_AC_META_GETVAL (KEY_NAME_OR_REGEX)
dnl #
dnl # Returns the META VALUE associated with the given KEY_NAME_OR_REGEX expr.
dnl #
dnl # Despite their resemblance to line noise,
dnl #   the "@<:@" and "@:>@" constructs are quadrigraphs for "[" and "]".
dnl #   <www.gnu.org/software/autoconf/manual/autoconf.html#Quadrigraphs>
dnl #
dnl # The "$[]1" and "$[]2" constructs prevent M4 parameter expansion
dnl #   so a literal $1 and $2 will be passed to the resulting awk script,
dnl #   whereas the "$1" will undergo M4 parameter expansion for the META key.
dnl #
AC_DEFUN([_ZFS_AC_META_GETVAL],
	[`$AWK -F ':@<:@ \t@:>@+' '$[]1 ~ /^ *$1$/ { print $[]2; exit }' $META`]dnl
)
Commit	Line	Data
d17eeafb BB	1	dnl #
	2	dnl # DESCRIPTION:
	3	dnl # Read meta data from the META file. When building from a git repository
	4	dnl # the ZFS_META_RELEASE field will be overwritten if there is an annotated
	5	dnl # tag matching the form ZFS_META_NAME-ZFS_META_VERSION-*. This allows
	6	dnl # for working builds to be uniquely identified using the git commit hash.
	7	dnl #
	8	dnl # The META file format is as follows:
	9	dnl # ^[ ]*KEY:[ \t]+VALUE$
	10	dnl #
	11	dnl # In other words:
	12	dnl # - KEY is separated from VALUE by a colon and one or more spaces/tabs.
	13	dnl # - KEY and VALUE are case sensitive.
	14	dnl # - Leading spaces are ignored.
	15	dnl # - First match wins for duplicate keys.
	16	dnl #
	17	dnl # A line can be commented out by preceding it with a '#' (or technically
	18	dnl # any non-space character since that will prevent the regex from
	19	dnl # matching).
	20	dnl #
	21	dnl # WARNING:
	22	dnl # Placing a colon followed by a space or tab (ie, ":[ \t]+") within the
	23	dnl # VALUE will prematurely terminate the string since that sequence is
	24	dnl # used as the awk field separator.
	25	dnl #
	26	dnl # KEYS:
	27	dnl # The following META keys are recognized:
	28	dnl # Name, Version, Release, Date, Author, LT_Current, LT_Revision, LT_Age
	29	dnl #
	30	dnl # Written by Chris Dunlap <cdunlap@llnl.gov>.
	31	dnl # Modified by Brian Behlendorf <behlendorf1@llnl.gov>.
	32	dnl #
c9c0d073 BB	33	AC_DEFUN([ZFS_AC_META], [
	34
	35	AH_BOTTOM([
	36	#undef PACKAGE
	37	#undef PACKAGE_BUGREPORT
	38	#undef PACKAGE_NAME
	39	#undef PACKAGE_STRING
	40	#undef PACKAGE_TARNAME
	41	#undef PACKAGE_VERSION
	42	#undef STDC_HEADERS
	43	#undef VERSION])
	44
d17eeafb	45	AC_PROG_AWK
c9c0d073 BB	46	AC_MSG_CHECKING([metadata])
	47
	48	META="$srcdir/META"
f6fb7651	49	_zfs_ac_meta_type="none"
c9c0d073	50	if test -f "$META"; then
f6fb7651	51	_zfs_ac_meta_type="META file"
c9c0d073	52
d17eeafb	53	ZFS_META_NAME=_ZFS_AC_META_GETVAL([(Name\|Project\|Package)]);
c9c0d073 BB	54	if test -n "$ZFS_META_NAME"; then
	55	AC_DEFINE_UNQUOTED([ZFS_META_NAME], ["$ZFS_META_NAME"],
	56	[Define the project name.]
	57	)
	58	AC_SUBST([ZFS_META_NAME])
	59	fi
	60
d17eeafb	61	ZFS_META_VERSION=_ZFS_AC_META_GETVAL([Version]);
c9c0d073	62	if test -n "$ZFS_META_VERSION"; then
93ce2b4c BB	63	AC_DEFINE_UNQUOTED([ZFS_META_VERSION],
	64	["$ZFS_META_VERSION"],
	65	[Define the project version.])
	66	AC_DEFINE_UNQUOTED([SPL_META_VERSION],
	67	[ZFS_META_VERSION],
	68	[Defined for legacy compatibility.])
c9c0d073 BB	69	AC_SUBST([ZFS_META_VERSION])
	70	fi
	71
d17eeafb	72	ZFS_META_RELEASE=_ZFS_AC_META_GETVAL([Release]);
d012ba38	73	if test ! -f ".nogitrelease" && git rev-parse --git-dir > /dev/null 2>&1; then
79aada61	74	_match="${ZFS_META_NAME}-${ZFS_META_VERSION}"
f6fb7651 BB	75	_alias=$(git describe --match=${_match} 2>/dev/null)
	76	_release=$(echo ${_alias}\|cut -f3- -d'-'\|sed 's/-/_/g')
	77	if test -n "${_release}"; then
	78	ZFS_META_RELEASE=${_release}
	79	_zfs_ac_meta_type="git describe"
66e93f5e BB	80	else
	81	_match="${ZFS_META_NAME}-${ZFS_META_VERSION}-${ZFS_META_RELEASE}"
	82	_alias=$(git describe --match=${_match} 2>/dev/null)
	83	_release=$(echo ${_alias}\|cut -f3- -d'-'\|sed 's/-/_/g')
	84	if test -n "${_release}"; then
	85	ZFS_META_RELEASE=${_release}
	86	_zfs_ac_meta_type="git describe"
	87	fi
f6fb7651 BB	88	fi
	89	fi
	90
c9c0d073	91	if test -n "$ZFS_META_RELEASE"; then
93ce2b4c BB	92	AC_DEFINE_UNQUOTED([ZFS_META_RELEASE],
	93	["$ZFS_META_RELEASE"],
	94	[Define the project release.])
	95	AC_DEFINE_UNQUOTED([SPL_META_RELEASE],
	96	[ZFS_META_RELEASE],
	97	[Defined for legacy compatibility.])
c9c0d073	98	AC_SUBST([ZFS_META_RELEASE])
f3757573 BB	99
	100	RELEASE="$ZFS_META_RELEASE"
	101	AC_SUBST([RELEASE])
c9c0d073 BB	102	fi
c9c0d073 BB	103
d17eeafb	104	ZFS_META_LICENSE=_ZFS_AC_META_GETVAL([License]);
c9c0d073 BB	105	if test -n "$ZFS_META_LICENSE"; then
	106	AC_DEFINE_UNQUOTED([ZFS_META_LICENSE], ["$ZFS_META_LICENSE"],
	107	[Define the project license.]
	108	)
	109	AC_SUBST([ZFS_META_LICENSE])
	110	fi
	111
	112	if test -n "$ZFS_META_NAME" -a -n "$ZFS_META_VERSION"; then
	113	ZFS_META_ALIAS="$ZFS_META_NAME-$ZFS_META_VERSION"
	114	test -n "$ZFS_META_RELEASE" &&
	115	ZFS_META_ALIAS="$ZFS_META_ALIAS-$ZFS_META_RELEASE"
	116	AC_DEFINE_UNQUOTED([ZFS_META_ALIAS],
93ce2b4c BB	117	["$ZFS_META_ALIAS"],
	118	[Define the project alias string.])
	119	AC_DEFINE_UNQUOTED([SPL_META_ALIAS],
	120	[ZFS_META_ALIAS],
	121	[Defined for legacy compatibility.])
c9c0d073 BB	122	AC_SUBST([ZFS_META_ALIAS])
	123	fi
	124
d17eeafb	125	ZFS_META_DATA=_ZFS_AC_META_GETVAL([Date]);
c9c0d073 BB	126	if test -n "$ZFS_META_DATA"; then
	127	AC_DEFINE_UNQUOTED([ZFS_META_DATA], ["$ZFS_META_DATA"],
	128	[Define the project release date.]
	129	)
	130	AC_SUBST([ZFS_META_DATA])
	131	fi
	132
d17eeafb	133	ZFS_META_AUTHOR=_ZFS_AC_META_GETVAL([Author]);
c9c0d073 BB	134	if test -n "$ZFS_META_AUTHOR"; then
	135	AC_DEFINE_UNQUOTED([ZFS_META_AUTHOR], ["$ZFS_META_AUTHOR"],
	136	[Define the project author.]
	137	)
	138	AC_SUBST([ZFS_META_AUTHOR])
	139	fi
	140
	141	m4_pattern_allow([^LT_(CURRENT\|REVISION\|AGE)$])
d17eeafb BB	142	ZFS_META_LT_CURRENT=_ZFS_AC_META_GETVAL([LT_Current]);
	143	ZFS_META_LT_REVISION=_ZFS_AC_META_GETVAL([LT_Revision]);
	144	ZFS_META_LT_AGE=_ZFS_AC_META_GETVAL([LT_Age]);
c9c0d073 BB	145	if test -n "$ZFS_META_LT_CURRENT" \
	146	-o -n "$ZFS_META_LT_REVISION" \
	147	-o -n "$ZFS_META_LT_AGE"; then
	148	test -n "$ZFS_META_LT_CURRENT" \|\| ZFS_META_LT_CURRENT="0"
	149	test -n "$ZFS_META_LT_REVISION" \|\| ZFS_META_LT_REVISION="0"
	150	test -n "$ZFS_META_LT_AGE" \|\| ZFS_META_LT_AGE="0"
	151	AC_DEFINE_UNQUOTED([ZFS_META_LT_CURRENT],
	152	["$ZFS_META_LT_CURRENT"],
	153	[Define the libtool library 'current'
	154	version information.]
	155	)
	156	AC_DEFINE_UNQUOTED([ZFS_META_LT_REVISION],
	157	["$ZFS_META_LT_REVISION"],
	158	[Define the libtool library 'revision'
	159	version information.]
	160	)
	161	AC_DEFINE_UNQUOTED([ZFS_META_LT_AGE], ["$ZFS_META_LT_AGE"],
	162	[Define the libtool library 'age'
	163	version information.]
	164	)
	165	AC_SUBST([ZFS_META_LT_CURRENT])
	166	AC_SUBST([ZFS_META_LT_REVISION])
	167	AC_SUBST([ZFS_META_LT_AGE])
	168	fi
	169	fi
	170
f6fb7651	171	AC_MSG_RESULT([$_zfs_ac_meta_type])
c9c0d073 BB	172	]
	173	)
	174
d17eeafb BB	175	dnl # _ZFS_AC_META_GETVAL (KEY_NAME_OR_REGEX)
	176	dnl #
	177	dnl # Returns the META VALUE associated with the given KEY_NAME_OR_REGEX expr.
	178	dnl #
	179	dnl # Despite their resemblance to line noise,
	180	dnl # the "@<:@" and "@:>@" constructs are quadrigraphs for "[" and "]".
	181	dnl # <www.gnu.org/software/autoconf/manual/autoconf.html#Quadrigraphs>
	182	dnl #
	183	dnl # The "$[]1" and "$[]2" constructs prevent M4 parameter expansion
	184	dnl # so a literal $1 and $2 will be passed to the resulting awk script,
	185	dnl # whereas the "$1" will undergo M4 parameter expansion for the META key.
	186	dnl #
	187	AC_DEFUN([_ZFS_AC_META_GETVAL],
	188	[`$AWK -F ':@<:@ \t@:>@+' '$[]1 ~ /^ *$1$/ { print $[]2; exit }' $META`]dnl
c9c0d073	189	)