[pve-common.git] / src / PVE / CLIFormatter.pm

package PVE::CLIFormatter;

use strict;
use warnings;

use I18N::Langinfo;
use POSIX qw(strftime);
use CPAN::Meta::YAML; # comes with perl-modules

use PVE::JSONSchema;
use PVE::PTY;

use JSON;
use utf8;
use Encode;

sub render_timestamp {
    my ($epoch) = @_;

    # ISO 8601 date format
    return strftime("%F %H:%M:%S", localtime($epoch));
}

PVE::JSONSchema::register_renderer('timestamp', \&render_timestamp);

sub render_timestamp_gmt {
    my ($epoch) = @_;

    # ISO 8601 date format, standard Greenwich time zone
    return strftime("%F %H:%M:%S", gmtime($epoch));
}

PVE::JSONSchema::register_renderer('timestamp_gmt', \&render_timestamp_gmt);

sub render_duration {
    my ($duration_in_seconds) = @_;

    my $text = '';
    my $rest = $duration_in_seconds;

    my $step = sub {
	my ($unit, $unitlength) = @_;

	if ((my $v = int($rest/$unitlength)) > 0) {
	    $text .= " " if length($text);
	    $text .= "${v}${unit}";
	    $rest -= $v * $unitlength;
	}
    };

    $step->('w', 7*24*3600);
    $step->('d', 24*3600);
    $step->('h', 3600);
    $step->('m', 60);
    $step->('s', 1);

    return $text;
}

PVE::JSONSchema::register_renderer('duration', \&render_duration);

sub render_fraction_as_percentage {
    my ($fraction) = @_;

    return sprintf("%.2f%%", $fraction*100);
}

PVE::JSONSchema::register_renderer(
    'fraction_as_percentage', \&render_fraction_as_percentage);

sub render_bytes {
    my ($value) = @_;

    my @units = qw(B KiB MiB GiB TiB PiB);

    my $max_unit = 0;
    if ($value > 1023) {
        $max_unit = int(log($value)/log(1024));
        $value /= 1024**($max_unit);
    }
    my $unit = $units[$max_unit];
    return sprintf "%.2f $unit", $value;
}

PVE::JSONSchema::register_renderer('bytes', \&render_bytes);

sub render_yaml {
    my ($value) = @_;

    my $data = CPAN::Meta::YAML::Dump($value);
    $data =~ s/^---[\n\s]//; # remove yaml marker

    return $data;
}

PVE::JSONSchema::register_renderer('yaml', \&render_yaml);

sub query_terminal_options {
    my ($options) = @_;

    $options //= {};

    if (-t STDOUT) {
	($options->{columns}) = PVE::PTY::tcgetsize(*STDOUT);
    }

    $options->{encoding} = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET());

    $options->{utf8} = 1 if $options->{encoding} eq 'UTF-8';

    return $options;
}

sub data_to_text {
    my ($data, $propdef, $options, $terminal_opts) = @_;

    return '' if !defined($data);

    $terminal_opts //= {};

    my $human_readable = $options->{'human-readable'} // 1;

     if ($human_readable && defined($propdef)) {
	if (my $type = $propdef->{type}) {
	    if ($type eq 'boolean') {
		return $data ? 1 : 0;
	    }
	}
	if (!defined($data) && defined($propdef->{default})) {
	    return "($propdef->{default})";
	}
	if (defined(my $renderer = $propdef->{renderer})) {
	    my $code = PVE::JSONSchema::get_renderer($renderer);
	    die "internal error: unknown renderer '$renderer'" if !$code;
	    return $code->($data, $options, $terminal_opts);
	}
    }

    if (my $class = ref($data)) {
	# JSON::PP::Boolean requires allow_nonref
	return to_json($data, { allow_nonref => 1, canonical => 1 });
    } else {
	return "$data";
    }
}

# prints a formatted table with a title row.
# $data - the data to print (array of objects)
# $returnprops -json schema property description
# $props_to_print - ordered list of properties to print
# $options
# - sort_key: can be used to sort after a specific column, if it isn't set we sort
#   after the leftmost column (with no undef value in $data) this can be
#   turned off by passing 0 as sort_key
# - noborder: print without asciiart border
# - noheader: print without table header
# - columns: limit output width (if > 0)
# - utf8: use utf8 characters for table delimiters

sub print_text_table {
    my ($data, $returnprops, $props_to_print, $options, $terminal_opts) = @_;

    $terminal_opts //= query_terminal_options({});

    my $sort_key = $options->{sort_key};
    my $border = !$options->{noborder};
    my $header = !$options->{noheader};

    my $columns = $terminal_opts->{columns};
    my $utf8 = $terminal_opts->{utf8};
    my $encoding = $terminal_opts->{encoding} // 'UTF-8';

    $sort_key //= $props_to_print->[0];

    if (defined($sort_key) && $sort_key ne 0) {
	my $type = $returnprops->{$sort_key}->{type} // 'string';
	if ($type eq 'integer' || $type eq 'number') {
	    @$data = sort { $a->{$sort_key} <=> $b->{$sort_key} } @$data;
	} else {
	    @$data = sort { $a->{$sort_key} cmp $b->{$sort_key} } @$data;
	}
    }

    my $colopts = {};

    my $borderstring_m = '';
    my $borderstring_b = '';
    my $borderstring_t = '';
    my $formatstring = '';

    my $column_count = scalar(@$props_to_print);

    my $tabledata = [];

    foreach my $entry (@$data) {

	my $height = 1;
	my $rowdata = {};

	for (my $i = 0; $i < $column_count; $i++) {
	    my $prop = $props_to_print->[$i];
	    my $propinfo = $returnprops->{$prop} // {};

	    my $text = data_to_text($entry->{$prop}, $propinfo, $options, $terminal_opts);
	    my $lines = [ split(/\n/, $text) ];
	    my $linecount = scalar(@$lines);
	    $height = $linecount if $linecount > $height;

	    my $width = 0;
	    foreach my $line (@$lines) {
		my $len = length($line);
		$width = $len if $len > $width;
	    }

	    $width = ($width =~ m/^(\d+)$/) ? int($1) : 0; # untaint int

	    $rowdata->{$prop} = {
		lines => $lines,
		width => $width,
	    };
	}

	push @$tabledata, {
	    height => $height,
	    rowdata => $rowdata,
	};
    }

    for (my $i = 0; $i < $column_count; $i++) {
	my $prop = $props_to_print->[$i];
	my $propinfo = $returnprops->{$prop} // {};
	my $type = $propinfo->{type} // 'string';
	my $alignstr = ($type eq 'integer' || $type eq 'number') ? '' : '-';

	my $title = $propinfo->{title} // $prop;
	my $cutoff = $propinfo->{print_width} // $propinfo->{maxLength};

	# calculate maximal print width and cutoff
	my $titlelen = length($title);

	my $longest = $titlelen;
	foreach my $coldata (@$tabledata) {
	    my $rowdata = $coldata->{rowdata}->{$prop};
	    $longest = $rowdata->{width} if $rowdata->{width} > $longest;
	}
	$cutoff = $longest if !defined($cutoff) || $cutoff > $longest;

	$colopts->{$prop} = {
	    title => $title,
	    cutoff => $cutoff,
	};

	if ($border) {
	    if ($i == 0 && ($column_count == 1)) {
		if ($utf8) {
		    $formatstring .= "│ %$alignstr${cutoff}s │";
		    $borderstring_t .= "┌─" . ('─' x $cutoff) . "─┐";
		    $borderstring_m .= "├─" . ('─' x $cutoff) . "─┤";
		    $borderstring_b .= "└─" . ('─' x $cutoff) . "─┘";
		} else {
		    $formatstring .= "| %$alignstr${cutoff}s |";
		    $borderstring_m .= "+-" . ('-' x $cutoff) . "-+";
		}
	    } elsif ($i == 0) {
		if ($utf8) {
		    $formatstring .= "│ %$alignstr${cutoff}s ";
		    $borderstring_t .= "┌─" . ('─' x $cutoff) . '─';
		    $borderstring_m .= "├─" . ('─' x $cutoff) . '─';
		    $borderstring_b .= "└─" . ('─' x $cutoff) . '─';
		} else {
		    $formatstring .= "| %$alignstr${cutoff}s ";
		    $borderstring_m .= "+-" . ('-' x $cutoff) . '-';
		}
	    } elsif ($i == ($column_count - 1)) {
		if ($utf8) {
		    $formatstring .= "│ %$alignstr${cutoff}s │";
		    $borderstring_t .= "┬─" . ('─' x $cutoff) . "─┐";
		    $borderstring_m .= "┼─" . ('─' x $cutoff) . "─┤";
		    $borderstring_b .= "┴─" . ('─' x $cutoff) . "─┘";
		} else {
		    $formatstring .= "| %$alignstr${cutoff}s |";
		    $borderstring_m .= "+-" . ('-' x $cutoff) . "-+";
		}
	    } else {
		if ($utf8) {
		    $formatstring .= "│ %$alignstr${cutoff}s ";
		    $borderstring_t .= "┬─" . ('─' x $cutoff) . '─';
		    $borderstring_m .= "┼─" . ('─' x $cutoff) . '─';
		    $borderstring_b .= "┴─" . ('─' x $cutoff) . '─';
		} else {
		    $formatstring .= "| %$alignstr${cutoff}s ";
		    $borderstring_m .= "+-" . ('-' x $cutoff) . '-';
		}
	    }
	} else {
	    # skip alignment and cutoff on last column
	    $formatstring .= ($i == ($column_count - 1)) ? "%s" : "%$alignstr${cutoff}s ";
	}
    }

    $borderstring_t = $borderstring_m if !length($borderstring_t);
    $borderstring_b = $borderstring_m if !length($borderstring_b);

    my $writeln = sub {
	my ($text) = @_;

	if ($columns) {
	    print encode($encoding, substr($text, 0, $columns) . "\n");
	} else {
	    print encode($encoding, $text) . "\n";
	}
    };

    $writeln->($borderstring_t) if $border;

    if ($header) {
	my $text = sprintf $formatstring, map { $colopts->{$_}->{title} } @$props_to_print;
	$writeln->($text);
    }

    for (my $i = 0; $i < scalar(@$tabledata); $i++) {
	my $coldata = $tabledata->[$i];

	$writeln->($borderstring_m) if $border && ($i != 0 || $header);

	for (my $i = 0; $i < $coldata->{height}; $i++) {

	    my $text = sprintf $formatstring, map {
		substr($coldata->{rowdata}->{$_}->{lines}->[$i] // '', 0, $colopts->{$_}->{cutoff});
	    } @$props_to_print;

	    $writeln->($text);
	}
    }

    $writeln->($borderstring_b) if $border;
}

sub extract_properties_to_print {
    my ($propdef) = @_;

    my $required = [];
    my $optional = [];

    foreach my $key (keys %$propdef) {
	my $prop = $propdef->{$key};
	if ($prop->{optional}) {
	    push @$optional, $key;
	} else {
	    push @$required, $key;
	}
    }

    return [ sort(@$required), sort(@$optional) ];
}

# prints the result of an API GET call returning an array as a table.
# takes formatting information from the results property of the call
# if $props_to_print is provided, prints only those columns. otherwise
# takes all fields of the results property, with a fallback
# to all fields occurring in items of $data.
sub print_api_list {
    my ($data, $result_schema, $props_to_print, $options, $terminal_opts) = @_;

    die "can only print object lists\n"
	if !($result_schema->{type} eq 'array' && $result_schema->{items}->{type} eq 'object');

    my $returnprops = $result_schema->{items}->{properties};

    $props_to_print = extract_properties_to_print($returnprops)
	if !defined($props_to_print);

    if (!scalar(@$props_to_print)) {
	my $all_props = {};
	foreach my $obj (@$data) {
	    foreach my $key (keys %$obj) {
		$all_props->{$key} = 1;
	    }
	}
	$props_to_print = [ sort keys %{$all_props} ];
    }

    die "unable to detect list properties\n" if !scalar(@$props_to_print);

    print_text_table($data, $returnprops, $props_to_print, $options, $terminal_opts);
}

my $guess_type = sub {
    my $data = shift;

    return 'null' if !defined($data);

    my $class = ref($data);
    return 'string' if !$class;

    if ($class eq 'HASH') {
	return 'object';
    } elsif ($class eq 'ARRAY') {
	return 'array';
    } else {
	return 'string'; # better than nothing
    }
};

sub print_api_result {
    my ($data, $result_schema, $props_to_print, $options, $terminal_opts) = @_;

    return if $options->{quiet};

    $terminal_opts //= query_terminal_options({});

    my $format = $options->{'output-format'} // 'text';

    if ($result_schema && defined($result_schema->{type})) {
	return if $result_schema->{type} eq 'null';
    } else {
	my $type = $guess_type->($data);
	$result_schema = { type => $type };
	$result_schema->{items} = { type => $guess_type->($data->[0]) } if $type eq 'array';
    }

    if ($format eq 'yaml') {
	print encode('UTF-8', CPAN::Meta::YAML::Dump($data));
    } elsif ($format eq 'json') {
	# Note: we always use utf8 encoding for json format
	print to_json($data, {utf8 => 1, allow_nonref => 1, canonical => 1 }) . "\n";
    } elsif ($format eq 'json-pretty') {
	# Note: we always use utf8 encoding for json format
	print to_json($data, {utf8 => 1, allow_nonref => 1, canonical => 1, pretty => 1 });
    } elsif ($format eq 'text') {
	my $encoding = $options->{encoding} // 'UTF-8';
	my $type = $result_schema->{type};
	if ($type eq 'object') {
	    $props_to_print = extract_properties_to_print($result_schema->{properties})
		if !defined($props_to_print);
	    $props_to_print = [ sort keys %$data ] if !scalar(@$props_to_print);
	    my $kvstore = [];
	    foreach my $key (@$props_to_print) {
		next if !defined($data->{$key});
		push @$kvstore, { key => $key, value => data_to_text($data->{$key}, $result_schema->{properties}->{$key}, $options, $terminal_opts) };
	    }
	    my $schema = { type => 'array', items => { type => 'object' }};
	    print_api_list($kvstore, $schema, ['key', 'value'], $options, $terminal_opts);
	} elsif ($type eq 'array') {
	    return if !scalar(@$data);
	    my $item_type = $result_schema->{items}->{type};
	    if ($item_type eq 'object') {
		print_api_list($data, $result_schema, $props_to_print, $options, $terminal_opts);
	    } else {
		my $kvstore = [];
		foreach my $value (@$data) {
		    push @$kvstore, { value => $value };
		}
		my $schema = { type => 'array', items => { type => 'object', properties => { value => $result_schema->{items} }}};
		print_api_list($kvstore, $schema, ['value'], { %$options, noheader => 1 },  $terminal_opts);
	    }
	} else {
	    print encode($encoding, "$data\n");
	}
    } else {
	die "internal error: unknown output format"; # should not happen
    }
}

sub print_api_result_plain {
    my ($data, $result_schema, $props_to_print, $options) = @_;

    # avoid borders and header, ignore terminal width
    $options = $options ? { %$options } : {}; # copy

    $options->{noheader} //= 1;
    $options->{noborder} //= 1;

    print_api_result($data, $result_schema, $props_to_print, $options, {});
}

1;
Commit	Line	Data
f53ad23a DM	1	package PVE::CLIFormatter;
	2
	3	use strict;
	4	use warnings;
fb3a1b29	5
4ac85000	6	use I18N::Langinfo;
5e287f60	7	use POSIX qw(strftime);
ba752c80	8	use CPAN::Meta::YAML; # comes with perl-modules
4ac85000	9
84142f1d	10	use PVE::JSONSchema;
4ac85000	11	use PVE::PTY;
fb3a1b29	12
f53ad23a	13	use JSON;
eb1c51c2 DM	14	use utf8;
eb1c51c2 DM	15	use Encode;
f53ad23a	16
5e287f60 DM	17	sub render_timestamp {
	18	my ($epoch) = @_;
	19
	20	# ISO 8601 date format
	21	return strftime("%F %H:%M:%S", localtime($epoch));
	22	}
	23
	24	PVE::JSONSchema::register_renderer('timestamp', \&render_timestamp);
	25
e735d7b0 DM	26	sub render_timestamp_gmt {
	27	my ($epoch) = @_;
	28
	29	# ISO 8601 date format, standard Greenwich time zone
	30	return strftime("%F %H:%M:%S", gmtime($epoch));
	31	}
	32
	33	PVE::JSONSchema::register_renderer('timestamp_gmt', \&render_timestamp_gmt);
	34
f495c868 DM	35	sub render_duration {
	36	my ($duration_in_seconds) = @_;
	37
	38	my $text = '';
	39	my $rest = $duration_in_seconds;
	40
	41	my $step = sub {
	42	my ($unit, $unitlength) = @_;
	43
	44	if ((my $v = int($rest/$unitlength)) > 0) {
	45	$text .= " " if length($text);
	46	$text .= "${v}${unit}";
	47	$rest -= $v * $unitlength;
	48	}
	49	};
	50
	51	$step->('w', 7243600);
	52	$step->('d', 24*3600);
	53	$step->('h', 3600);
	54	$step->('m', 60);
	55	$step->('s', 1);
	56
	57	return $text;
	58	}
	59
	60	PVE::JSONSchema::register_renderer('duration', \&render_duration);
	61
	62	sub render_fraction_as_percentage {
	63	my ($fraction) = @_;
	64
	65	return sprintf("%.2f%%", $fraction*100);
	66	}
	67
	68	PVE::JSONSchema::register_renderer(
	69	'fraction_as_percentage', \&render_fraction_as_percentage);
	70
	71	sub render_bytes {
	72	my ($value) = @_;
	73
	74	my @units = qw(B KiB MiB GiB TiB PiB);
	75
	76	my $max_unit = 0;
	77	if ($value > 1023) {
	78	$max_unit = int(log($value)/log(1024));
	79	$value /= 1024**($max_unit);
	80	}
3496d4bf DM	81	my $unit = $units[$max_unit];
3496d4bf DM	82	return sprintf "%.2f $unit", $value;
f495c868 DM	83	}
	84
	85	PVE::JSONSchema::register_renderer('bytes', \&render_bytes);
	86
ba752c80 DM	87	sub render_yaml {
	88	my ($value) = @_;
	89
	90	my $data = CPAN::Meta::YAML::Dump($value);
	91	$data =~ s/^---[\n\s]//; # remove yaml marker
	92
	93	return $data;
	94	}
	95
	96	PVE::JSONSchema::register_renderer('yaml', \&render_yaml);
	97
4ac85000 DM	98	sub query_terminal_options {
	99	my ($options) = @_;
	100
	101	$options //= {};
	102
	103	if (-t STDOUT) {
	104	($options->{columns}) = PVE::PTY::tcgetsize(*STDOUT);
	105	}
	106
	107	$options->{encoding} = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET());
	108
	109	$options->{utf8} = 1 if $options->{encoding} eq 'UTF-8';
	110
	111	return $options;
	112	}
	113
f53ad23a	114	sub data_to_text {
b01a09e7	115	my ($data, $propdef, $options, $terminal_opts) = @_;
f53ad23a	116
3cd6f2f3 DM	117	return '' if !defined($data);
3cd6f2f3 DM	118
b01a09e7 DM	119	$terminal_opts //= {};
b01a09e7 DM	120
352b7a14 DM	121	my $human_readable = $options->{'human-readable'} // 1;
	122
	123	if ($human_readable && defined($propdef)) {
84142f1d DM	124	if (my $type = $propdef->{type}) {
	125	if ($type eq 'boolean') {
	126	return $data ? 1 : 0;
	127	}
	128	}
	129	if (!defined($data) && defined($propdef->{default})) {
	130	return "($propdef->{default})";
	131	}
	132	if (defined(my $renderer = $propdef->{renderer})) {
	133	my $code = PVE::JSONSchema::get_renderer($renderer);
	134	die "internal error: unknown renderer '$renderer'" if !$code;
b01a09e7	135	return $code->($data, $options, $terminal_opts);
84142f1d DM	136	}
84142f1d DM	137	}
f53ad23a DM	138
f53ad23a DM	139	if (my $class = ref($data)) {
b51b930d DM	140	# JSON::PP::Boolean requires allow_nonref
b51b930d DM	141	return to_json($data, { allow_nonref => 1, canonical => 1 });
f53ad23a DM	142	} else {
	143	return "$data";
	144	}
	145	}
	146
	147	# prints a formatted table with a title row.
	148	# $data - the data to print (array of objects)
	149	# $returnprops -json schema property description
	150	# $props_to_print - ordered list of properties to print
0c22b00c	151	# $options
2e2a4502	152	# - sort_key: can be used to sort after a specific column, if it isn't set we sort
f53ad23a	153	# after the leftmost column (with no undef value in $data) this can be
0c22b00c	154	# turned off by passing 0 as sort_key
352b7a14 DM	155	# - noborder: print without asciiart border
352b7a14 DM	156	# - noheader: print without table header
0c22b00c DM	157	# - columns: limit output width (if > 0)
	158	# - utf8: use utf8 characters for table delimiters
	159
f53ad23a	160	sub print_text_table {
b01a09e7 DM	161	my ($data, $returnprops, $props_to_print, $options, $terminal_opts) = @_;
	162
	163	$terminal_opts //= query_terminal_options({});
0c22b00c DM	164
0c22b00c DM	165	my $sort_key = $options->{sort_key};
352b7a14 DM	166	my $border = !$options->{noborder};
352b7a14 DM	167	my $header = !$options->{noheader};
b01a09e7 DM	168
	169	my $columns = $terminal_opts->{columns};
	170	my $utf8 = $terminal_opts->{utf8};
	171	my $encoding = $terminal_opts->{encoding} // 'UTF-8';
f53ad23a	172
2e2a4502	173	$sort_key //= $props_to_print->[0];
41d554d9	174
2e2a4502	175	if (defined($sort_key) && $sort_key ne 0) {
41d554d9 DM	176	my $type = $returnprops->{$sort_key}->{type} // 'string';
	177	if ($type eq 'integer' \|\| $type eq 'number') {
	178	@$data = sort { $a->{$sort_key} <=> $b->{$sort_key} } @$data;
	179	} else {
	180	@$data = sort { $a->{$sort_key} cmp $b->{$sort_key} } @$data;
	181	}
f53ad23a DM	182	}
	183
	184	my $colopts = {};
793ad69b	185
eb1c51c2 DM	186	my $borderstring_m = '';
	187	my $borderstring_b = '';
	188	my $borderstring_t = '';
f53ad23a DM	189	my $formatstring = '';
	190
	191	my $column_count = scalar(@$props_to_print);
	192
41d554d9 DM	193	my $tabledata = [];
	194
	195	foreach my $entry (@$data) {
	196
	197	my $height = 1;
	198	my $rowdata = {};
	199
	200	for (my $i = 0; $i < $column_count; $i++) {
	201	my $prop = $props_to_print->[$i];
	202	my $propinfo = $returnprops->{$prop} // {};
	203
b01a09e7	204	my $text = data_to_text($entry->{$prop}, $propinfo, $options, $terminal_opts);
41d554d9 DM	205	my $lines = [ split(/\n/, $text) ];
	206	my $linecount = scalar(@$lines);
	207	$height = $linecount if $linecount > $height;
	208
	209	my $width = 0;
	210	foreach my $line (@$lines) {
	211	my $len = length($line);
	212	$width = $len if $len > $width;
	213	}
	214
b9474c96 DM	215	$width = ($width =~ m/^(\d+)$/) ? int($1) : 0; # untaint int
b9474c96 DM	216
41d554d9 DM	217	$rowdata->{$prop} = {
	218	lines => $lines,
	219	width => $width,
	220	};
	221	}
	222
	223	push @$tabledata, {
	224	height => $height,
	225	rowdata => $rowdata,
	226	};
	227	}
	228
f53ad23a DM	229	for (my $i = 0; $i < $column_count; $i++) {
	230	my $prop = $props_to_print->[$i];
	231	my $propinfo = $returnprops->{$prop} // {};
2ec79c0f DM	232	my $type = $propinfo->{type} // 'string';
2ec79c0f DM	233	my $alignstr = ($type eq 'integer' \|\| $type eq 'number') ? '' : '-';
f53ad23a DM	234
	235	my $title = $propinfo->{title} // $prop;
	236	my $cutoff = $propinfo->{print_width} // $propinfo->{maxLength};
	237
	238	# calculate maximal print width and cutoff
	239	my $titlelen = length($title);
	240
	241	my $longest = $titlelen;
41d554d9 DM	242	foreach my $coldata (@$tabledata) {
	243	my $rowdata = $coldata->{rowdata}->{$prop};
	244	$longest = $rowdata->{width} if $rowdata->{width} > $longest;
f53ad23a DM	245	}
f53ad23a DM	246	$cutoff = $longest if !defined($cutoff) \|\| $cutoff > $longest;
f53ad23a DM	247
	248	$colopts->{$prop} = {
	249	title => $title,
f53ad23a DM	250	cutoff => $cutoff,
	251	};
	252
793ad69b	253	if ($border) {
eb1c51c2 DM	254	if ($i == 0 && ($column_count == 1)) {
eb1c51c2 DM	255	if ($utf8) {
2ec79c0f	256	$formatstring .= "│ %$alignstr${cutoff}s │";
41d554d9 DM	257	$borderstring_t .= "┌─" . ('─' x $cutoff) . "─┐";
	258	$borderstring_m .= "├─" . ('─' x $cutoff) . "─┤";
	259	$borderstring_b .= "└─" . ('─' x $cutoff) . "─┘";
eb1c51c2	260	} else {
2ec79c0f	261	$formatstring .= "\| %$alignstr${cutoff}s \|";
41d554d9	262	$borderstring_m .= "+-" . ('-' x $cutoff) . "-+";
eb1c51c2 DM	263	}
	264	} elsif ($i == 0) {
	265	if ($utf8) {
2ec79c0f	266	$formatstring .= "│ %$alignstr${cutoff}s ";
eb1c51c2 DM	267	$borderstring_t .= "┌─" . ('─' x $cutoff) . '─';
	268	$borderstring_m .= "├─" . ('─' x $cutoff) . '─';
	269	$borderstring_b .= "└─" . ('─' x $cutoff) . '─';
	270	} else {
2ec79c0f	271	$formatstring .= "\| %$alignstr${cutoff}s ";
eb1c51c2 DM	272	$borderstring_m .= "+-" . ('-' x $cutoff) . '-';
	273	}
	274	} elsif ($i == ($column_count - 1)) {
	275	if ($utf8) {
2ec79c0f	276	$formatstring .= "│ %$alignstr${cutoff}s │";
41d554d9 DM	277	$borderstring_t .= "┬─" . ('─' x $cutoff) . "─┐";
	278	$borderstring_m .= "┼─" . ('─' x $cutoff) . "─┤";
	279	$borderstring_b .= "┴─" . ('─' x $cutoff) . "─┘";
eb1c51c2	280	} else {
2ec79c0f	281	$formatstring .= "\| %$alignstr${cutoff}s \|";
41d554d9	282	$borderstring_m .= "+-" . ('-' x $cutoff) . "-+";
eb1c51c2	283	}
793ad69b	284	} else {
eb1c51c2	285	if ($utf8) {
2ec79c0f	286	$formatstring .= "│ %$alignstr${cutoff}s ";
eb1c51c2 DM	287	$borderstring_t .= "┬─" . ('─' x $cutoff) . '─';
	288	$borderstring_m .= "┼─" . ('─' x $cutoff) . '─';
	289	$borderstring_b .= "┴─" . ('─' x $cutoff) . '─';
	290	} else {
2ec79c0f	291	$formatstring .= "\| %$alignstr${cutoff}s ";
eb1c51c2 DM	292	$borderstring_m .= "+-" . ('-' x $cutoff) . '-';
eb1c51c2 DM	293	}
793ad69b DM	294	}
	295	} else {
	296	# skip alignment and cutoff on last column
2ec79c0f	297	$formatstring .= ($i == ($column_count - 1)) ? "%s" : "%$alignstr${cutoff}s ";
f53ad23a DM	298	}
	299	}
	300
eb1c51c2 DM	301	$borderstring_t = $borderstring_m if !length($borderstring_t);
	302	$borderstring_b = $borderstring_m if !length($borderstring_b);
	303
41d554d9 DM	304	my $writeln = sub {
	305	my ($text) = @_;
	306
	307	if ($columns) {
	308	print encode($encoding, substr($text, 0, $columns) . "\n");
	309	} else {
	310	print encode($encoding, $text) . "\n";
	311	}
	312	};
	313
	314	$writeln->($borderstring_t) if $border;
793ad69b	315
352b7a14 DM	316	if ($header) {
	317	my $text = sprintf $formatstring, map { $colopts->{$_}->{title} } @$props_to_print;
	318	$writeln->($text);
	319	}
	320
	321	for (my $i = 0; $i < scalar(@$tabledata); $i++) {
	322	my $coldata = $tabledata->[$i];
	323
	324	$writeln->($borderstring_m) if $border && ($i != 0 \|\| $header);
41d554d9 DM	325
	326	for (my $i = 0; $i < $coldata->{height}; $i++) {
	327
352b7a14	328	my $text = sprintf $formatstring, map {
41d554d9 DM	329	substr($coldata->{rowdata}->{$_}->{lines}->[$i] // '', 0, $colopts->{$_}->{cutoff});
	330	} @$props_to_print;
	331
	332	$writeln->($text);
	333	}
f53ad23a	334	}
41d554d9 DM	335
41d554d9 DM	336	$writeln->($borderstring_b) if $border;
f53ad23a DM	337	}
f53ad23a DM	338
c5adc5f9 DM	339	sub extract_properties_to_print {
	340	my ($propdef) = @_;
	341
	342	my $required = [];
	343	my $optional = [];
	344
	345	foreach my $key (keys %$propdef) {
	346	my $prop = $propdef->{$key};
	347	if ($prop->{optional}) {
	348	push @$optional, $key;
	349	} else {
	350	push @$required, $key;
	351	}
	352	}
	353
	354	return [ sort(@$required), sort(@$optional) ];
	355	}
	356
f53ad23a DM	357	# prints the result of an API GET call returning an array as a table.
	358	# takes formatting information from the results property of the call
	359	# if $props_to_print is provided, prints only those columns. otherwise
	360	# takes all fields of the results property, with a fallback
fb3a1b29	361	# to all fields occurring in items of $data.
f53ad23a	362	sub print_api_list {
b01a09e7	363	my ($data, $result_schema, $props_to_print, $options, $terminal_opts) = @_;
f53ad23a DM	364
	365	die "can only print object lists\n"
	366	if !($result_schema->{type} eq 'array' && $result_schema->{items}->{type} eq 'object');
	367
	368	my $returnprops = $result_schema->{items}->{properties};
	369
c5adc5f9 DM	370	$props_to_print = extract_properties_to_print($returnprops)
	371	if !defined($props_to_print);
	372
	373	if (!scalar(@$props_to_print)) {
	374	my $all_props = {};
	375	foreach my $obj (@$data) {
	376	foreach my $key (keys %$obj) {
	377	$all_props->{$key} = 1;
f53ad23a	378	}
f53ad23a	379	}
c5adc5f9	380	$props_to_print = [ sort keys %{$all_props} ];
f53ad23a DM	381	}
f53ad23a DM	382
c5adc5f9 DM	383	die "unable to detect list properties\n" if !scalar(@$props_to_print);
c5adc5f9 DM	384
b01a09e7	385	print_text_table($data, $returnprops, $props_to_print, $options, $terminal_opts);
f53ad23a DM	386	}
f53ad23a DM	387
b51b930d DM	388	my $guess_type = sub {
	389	my $data = shift;
	390
	391	return 'null' if !defined($data);
	392
	393	my $class = ref($data);
	394	return 'string' if !$class;
	395
	396	if ($class eq 'HASH') {
	397	return 'object';
	398	} elsif ($class eq 'ARRAY') {
	399	return 'array';
	400	} else {
	401	return 'string'; # better than nothing
	402	}
	403	};
	404
f53ad23a	405	sub print_api_result {
b01a09e7	406	my ($data, $result_schema, $props_to_print, $options, $terminal_opts) = @_;
0c22b00c	407
352b7a14 DM	408	return if $options->{quiet};
352b7a14 DM	409
b01a09e7	410	$terminal_opts //= query_terminal_options({});
f53ad23a	411
4cbcd138	412	my $format = $options->{'output-format'} // 'text';
f0bcf4d4	413
fbd10e04	414	if ($result_schema && defined($result_schema->{type})) {
b51b930d DM	415	return if $result_schema->{type} eq 'null';
	416	} else {
	417	my $type = $guess_type->($data);
	418	$result_schema = { type => $type };
	419	$result_schema->{items} = { type => $guess_type->($data->[0]) } if $type eq 'array';
	420	}
f53ad23a	421
ac6c61bf DM	422	if ($format eq 'yaml') {
	423	print encode('UTF-8', CPAN::Meta::YAML::Dump($data));
	424	} elsif ($format eq 'json') {
cd6591d3 DM	425	# Note: we always use utf8 encoding for json format
	426	print to_json($data, {utf8 => 1, allow_nonref => 1, canonical => 1 }) . "\n";
	427	} elsif ($format eq 'json-pretty') {
43b104c4	428	# Note: we always use utf8 encoding for json format
f53ad23a	429	print to_json($data, {utf8 => 1, allow_nonref => 1, canonical => 1, pretty => 1 });
cd6591d3	430	} elsif ($format eq 'text') {
43b104c4	431	my $encoding = $options->{encoding} // 'UTF-8';
f53ad23a DM	432	my $type = $result_schema->{type};
f53ad23a DM	433	if ($type eq 'object') {
c5adc5f9 DM	434	$props_to_print = extract_properties_to_print($result_schema->{properties})
	435	if !defined($props_to_print);
	436	$props_to_print = [ sort keys %$data ] if !scalar(@$props_to_print);
2a174d2a	437	my $kvstore = [];
f53ad23a	438	foreach my $key (@$props_to_print) {
a05db8b5	439	next if !defined($data->{$key});
b01a09e7	440	push @$kvstore, { key => $key, value => data_to_text($data->{$key}, $result_schema->{properties}->{$key}, $options, $terminal_opts) };
f53ad23a	441	}
2a174d2a	442	my $schema = { type => 'array', items => { type => 'object' }};
b01a09e7	443	print_api_list($kvstore, $schema, ['key', 'value'], $options, $terminal_opts);
f53ad23a DM	444	} elsif ($type eq 'array') {
	445	return if !scalar(@$data);
	446	my $item_type = $result_schema->{items}->{type};
	447	if ($item_type eq 'object') {
b01a09e7	448	print_api_list($data, $result_schema, $props_to_print, $options, $terminal_opts);
f53ad23a	449	} else {
c850b998 DM	450	my $kvstore = [];
	451	foreach my $value (@$data) {
	452	push @$kvstore, { value => $value };
f53ad23a	453	}
c850b998	454	my $schema = { type => 'array', items => { type => 'object', properties => { value => $result_schema->{items} }}};
b01a09e7	455	print_api_list($kvstore, $schema, ['value'], { %$options, noheader => 1 }, $terminal_opts);
f53ad23a DM	456	}
f53ad23a DM	457	} else {
43b104c4	458	print encode($encoding, "$data\n");
f53ad23a DM	459	}
	460	} else {
	461	die "internal error: unknown output format"; # should not happen
	462	}
	463	}
	464
6bc09493 DM	465	sub print_api_result_plain {
	466	my ($data, $result_schema, $props_to_print, $options) = @_;
	467
	468	# avoid borders and header, ignore terminal width
	469	$options = $options ? { %$options } : {}; # copy
	470
	471	$options->{noheader} //= 1;
	472	$options->{noborder} //= 1;
	473
	474	print_api_result($data, $result_schema, $props_to_print, $options, {});
	475	}
	476
f53ad23a	477	1;