src/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::INotify;
   7 use PVE::ProcFSTools;
   8 use PVE::Tools qw(run_command lock_file);
   9
  10 use File::Basename;
  11 use IO::Socket::IP;
  12 use Net::IP;
  13 use NetAddr::IP qw(:lower);
  14 use POSIX qw(ECONNREFUSED);
  15 use Socket qw(NI_NUMERICHOST NI_NUMERICSERV);
  16
  17 # host network related utility functions
  18
  19 our $PHYSICAL_NIC_RE = qr/(?:eth\d+|en[^:.]+|ib[^:.]+)/;
  20
  21 our $ipv4_reverse_mask = [
  22     '0.0.0.0',
  23     '128.0.0.0',
  24     '192.0.0.0',
  25     '224.0.0.0',
  26     '240.0.0.0',
  27     '248.0.0.0',
  28     '252.0.0.0',
  29     '254.0.0.0',
  30     '255.0.0.0',
  31     '255.128.0.0',
  32     '255.192.0.0',
  33     '255.224.0.0',
  34     '255.240.0.0',
  35     '255.248.0.0',
  36     '255.252.0.0',
  37     '255.254.0.0',
  38     '255.255.0.0',
  39     '255.255.128.0',
  40     '255.255.192.0',
  41     '255.255.224.0',
  42     '255.255.240.0',
  43     '255.255.248.0',
  44     '255.255.252.0',
  45     '255.255.254.0',
  46     '255.255.255.0',
  47     '255.255.255.128',
  48     '255.255.255.192',
  49     '255.255.255.224',
  50     '255.255.255.240',
  51     '255.255.255.248',
  52     '255.255.255.252',
  53     '255.255.255.254',
  54     '255.255.255.255',
  55 ];
  56
  57 our $ipv4_mask_hash_localnet = {
  58     '255.0.0.0' => 8,
  59     '255.128.0.0' => 9,
  60     '255.192.0.0' => 10,
  61     '255.224.0.0' => 11,
  62     '255.240.0.0' => 12,
  63     '255.248.0.0' => 13,
  64     '255.252.0.0' => 14,
  65     '255.254.0.0' => 15,
  66     '255.255.0.0' => 16,
  67     '255.255.128.0' => 17,
  68     '255.255.192.0' => 18,
  69     '255.255.224.0' => 19,
  70     '255.255.240.0' => 20,
  71     '255.255.248.0' => 21,
  72     '255.255.252.0' => 22,
  73     '255.255.254.0' => 23,
  74     '255.255.255.0' => 24,
  75     '255.255.255.128' => 25,
  76     '255.255.255.192' => 26,
  77     '255.255.255.224' => 27,
  78     '255.255.255.240' => 28,
  79     '255.255.255.248' => 29,
  80     '255.255.255.252' => 30,
  81     '255.255.255.254' => 31,
  82     '255.255.255.255' => 32,
  83 };
  84
  85 sub setup_tc_rate_limit {
  86     my ($iface, $rate, $burst) = @_;
  87
  88     # these are allowed / expected to fail, e.g. when there is no previous rate limit to remove
  89     eval { run_command("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1"); };
  90     eval { run_command("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1"); };
  91     eval { run_command("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1"); };
  92     eval { run_command("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1"); };
  93
  94     return if !$rate;
  95
  96     # tbf does not work for unknown reason
  97     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
  98     # so we use htb instead
  99     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
 100     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
 101                 "htb rate ${rate}bps burst ${burst}b");
 102
 103     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
 104     run_command("/sbin/tc filter add dev $iface parent ffff: " .
 105                 "prio 50 basic " .
 106                 "police rate ${rate}bps burst ${burst}b mtu 64kb " .
 107                 "drop");
 108 }
 109
 110 sub tap_rate_limit {
 111     my ($iface, $rate) = @_;
 112
 113     $rate = int($rate*1024*1024) if $rate;
 114     my $burst = 1024*1024;
 115
 116     setup_tc_rate_limit($iface, $rate, $burst);
 117 }
 118
 119 sub read_bridge_mtu {
 120     my ($bridge) = @_;
 121
 122     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
 123     die "bridge '$bridge' does not exist\n" if !$mtu;
 124     # avoid insecure dependency;
 125     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
 126     $mtu = int($1);
 127
 128     return $mtu;
 129 };
 130
 131 my $parse_tap_device_name = sub {
 132     my ($iface, $noerr) = @_;
 133
 134     my ($vmid, $devid);
 135
 136     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
 137         $vmid = $1;
 138         $devid = $2;
 139     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
 140         $vmid = $1;
 141         $devid = $2;
 142     } else {
 143         return undef if $noerr;
 144         die "can't create firewall bridge for random interface name '$iface'\n";
 145     }
 146
 147     return ($vmid, $devid);
 148 };
 149
 150 my $compute_fwbr_names = sub {
 151     my ($vmid, $devid) = @_;
 152
 153     my $fwbr = "fwbr${vmid}i${devid}";
 154     # Note: the firewall use 'fwln+' to filter traffic to VMs
 155     my $vethfw = "fwln${vmid}i${devid}";
 156     my $vethfwpeer = "fwpr${vmid}p${devid}";
 157     my $ovsintport = "fwln${vmid}o${devid}";
 158
 159     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
 160 };
 161
 162 sub iface_delete($) {
 163     my ($iface) = @_;
 164     run_command(['/sbin/ip', 'link', 'delete', 'dev', $iface], noerr => 1)
 165         == 0 or die "failed to delete interface '$iface'\n";
 166 }
 167
 168 sub iface_create($$@) {
 169     my ($iface, $type, @args) = @_;
 170     run_command(['/sbin/ip', 'link', 'add', $iface, 'type', $type, @args], noerr => 1)
 171         == 0 or die "failed to create interface '$iface'\n";
 172 }
 173
 174 sub iface_set($@) {
 175     my ($iface, @opts) = @_;
 176     run_command(['/sbin/ip', 'link', 'set', $iface, @opts], noerr => 1)
 177         == 0 or die "failed to set interface options for '$iface' (".join(' ', @opts).")\n";
 178 }
 179
 180 # helper for nicer error messages:
 181 sub iface_set_master($$) {
 182     my ($iface, $master) = @_;
 183     if (defined($master)) {
 184         eval { iface_set($iface, 'master', $master) };
 185         die "can't enslave '$iface' to '$master'\n" if $@;
 186     } else {
 187         eval { iface_set($iface, 'nomaster') };
 188         die "can't unenslave '$iface'\n" if $@;
 189     }
 190 }
 191
 192 my $cond_create_bridge = sub {
 193     my ($bridge) = @_;
 194
 195     if (! -d "/sys/class/net/$bridge") {
 196         iface_create($bridge, 'bridge');
 197         disable_ipv6($bridge);
 198     }
 199 };
 200
 201 sub disable_ipv6 {
 202     my ($iface) = @_;
 203     return if !-d '/proc/sys/net/ipv6'; # ipv6 might be completely disabled
 204     my $file = "/proc/sys/net/ipv6/conf/$iface/disable_ipv6";
 205     open(my $fh, '>', $file) or die "failed to open $file for writing: $!\n";
 206     print {$fh} "1\n" or die "failed to disable link-local ipv6 for $iface\n";
 207     close($fh);
 208 }
 209
 210 my $bridge_add_interface = sub {
 211     my ($bridge, $iface, $tag, $trunks) = @_;
 212
 213     # drop link local address (it can't be used when on a bridge anyway)
 214     disable_ipv6($iface);
 215     iface_set_master($iface, $bridge);
 216
 217    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 218
 219    if ($vlan_aware) {
 220
 221         eval { run_command(['/sbin/bridge', 'vlan', 'del', 'dev', $iface, 'vid', '1-4094']) };
 222         die "failed to remove default vlan tags of $iface - $@\n" if $@;
 223
 224         if ($trunks) {
 225             my @trunks_array = split /;/, $trunks;
 226             foreach my $trunk (@trunks_array) {
 227                 eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', $trunk]) };
 228                 die "unable to add vlan $trunk to interface $iface - $@\n" if $@;
 229             }
 230         } elsif (!$tag) {
 231             eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', '2-4094']) };
 232             die "unable to add default vlan tags to interface $iface - $@\n" if $@;
 233         }
 234
 235         $tag = 1 if !$tag;
 236         eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', $tag, 'pvid', 'untagged']) };
 237         die "unable to add vlan $tag to interface $iface - $@\n" if $@;
 238    }
 239 };
 240
 241 my $ovs_bridge_add_port = sub {
 242     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
 243
 244     $trunks =~ s/;/,/g if $trunks;
 245
 246     my $cmd = ['/usr/bin/ovs-vsctl'];
 247     # first command
 248     push @$cmd, '--', 'add-port', $bridge, $iface;
 249     push @$cmd, "tag=$tag" if $tag;
 250     push @$cmd, "trunks=". join(',', $trunks) if $trunks;
 251     push @$cmd, "vlan_mode=native-untagged" if $tag && $trunks;
 252
 253     if ($internal) {
 254         # second command
 255         push @$cmd, '--', 'set', 'Interface', $iface, 'type=internal';
 256     }
 257
 258     eval { run_command($cmd) };
 259     die "can't add ovs port '$iface' - $@\n" if $@;
 260
 261     disable_ipv6($iface);
 262 };
 263
 264 my $activate_interface = sub {
 265     my ($iface) = @_;
 266
 267     eval { run_command(['/sbin/ip', 'link', 'set', $iface, 'up']) };
 268     die "can't activate interface '$iface' - $@\n" if $@;
 269 };
 270
 271 sub tap_create {
 272     my ($iface, $bridge) = @_;
 273
 274     die "unable to get bridge setting\n" if !$bridge;
 275
 276     my $bridgemtu = read_bridge_mtu($bridge);
 277
 278     eval {
 279         disable_ipv6($iface);
 280         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $iface, 'up', 'promisc', 'on', 'mtu', $bridgemtu]);
 281     };
 282     die "interface activation failed\n" if $@;
 283 }
 284
 285 sub veth_create {
 286     my ($veth, $vethpeer, $bridge, $mac) = @_;
 287
 288     die "unable to get bridge setting\n" if !$bridge;
 289
 290     my $bridgemtu = read_bridge_mtu($bridge);
 291
 292     # create veth pair
 293     if (! -d "/sys/class/net/$veth") {
 294         my $cmd = ['/sbin/ip', 'link', 'add'];
 295         # veth device + MTU
 296         push @$cmd, 'name', $veth;
 297         push @$cmd, 'mtu', $bridgemtu;
 298         push @$cmd, 'type', 'veth';
 299         # peer device + MTU
 300         push @$cmd, 'peer', 'name', $vethpeer, 'mtu', $bridgemtu;
 301
 302         push @$cmd, 'addr', $mac if $mac;
 303
 304         eval { run_command($cmd) };
 305         die "can't create interface $veth - $@\n" if $@;
 306     }
 307
 308     # up vethpair
 309     disable_ipv6($veth);
 310     disable_ipv6($vethpeer);
 311     &$activate_interface($veth);
 312     &$activate_interface($vethpeer);
 313 }
 314
 315 sub veth_delete {
 316     my ($veth) = @_;
 317
 318     if (-d "/sys/class/net/$veth") {
 319         iface_delete($veth);
 320     }
 321     eval { tap_unplug($veth) };
 322 }
 323
 324 my $create_firewall_bridge_linux = sub {
 325     my ($iface, $bridge, $tag, $trunks) = @_;
 326
 327     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 328     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 329
 330     &$cond_create_bridge($fwbr);
 331     &$activate_interface($fwbr);
 332
 333     copy_bridge_config($bridge, $fwbr);
 334     veth_create($vethfw, $vethfwpeer, $bridge);
 335
 336     &$bridge_add_interface($fwbr, $vethfw);
 337     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
 338
 339     &$bridge_add_interface($fwbr, $iface);
 340 };
 341
 342 my $create_firewall_bridge_ovs = sub {
 343     my ($iface, $bridge, $tag, $trunks) = @_;
 344
 345     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 346     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 347
 348     my $bridgemtu = read_bridge_mtu($bridge);
 349
 350     &$cond_create_bridge($fwbr);
 351     &$activate_interface($fwbr);
 352
 353     &$bridge_add_interface($fwbr, $iface);
 354
 355     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
 356     &$activate_interface($ovsintport);
 357
 358     # set the same mtu for ovs int port
 359     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $ovsintport, 'mtu', $bridgemtu]);
 360
 361     &$bridge_add_interface($fwbr, $ovsintport);
 362 };
 363
 364 my $cleanup_firewall_bridge = sub {
 365     my ($iface) = @_;
 366
 367     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 368     return if !defined($vmid);
 369     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 370
 371     # cleanup old port config from any openvswitch bridge
 372     if (-d "/sys/class/net/$ovsintport") {
 373         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 374     }
 375
 376     # delete old vethfw interface
 377     veth_delete($vethfw);
 378
 379     # cleanup fwbr bridge
 380     if (-d "/sys/class/net/$fwbr") {
 381         iface_delete($fwbr);
 382     }
 383 };
 384
 385 sub tap_plug {
 386     my ($iface, $bridge, $tag, $firewall, $trunks, $rate) = @_;
 387
 388     #cleanup old port config from any openvswitch bridge
 389     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 390
 391     if (-d "/sys/class/net/$bridge/bridge") {
 392         &$cleanup_firewall_bridge($iface); # remove stale devices
 393
 394         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 395
 396         if (!$vlan_aware) {
 397             die "vlan aware feature need to be enabled to use trunks" if $trunks;
 398             my $newbridge = activate_bridge_vlan($bridge, $tag);
 399             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 400             $bridge = $newbridge;
 401             $tag = undef;
 402         }
 403
 404         if ($firewall) {
 405             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks);
 406         } else {
 407             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
 408         }
 409
 410     } else {
 411         &$cleanup_firewall_bridge($iface); # remove stale devices
 412
 413         if ($firewall) {
 414             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks);
 415         } else {
 416             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
 417         }
 418     }
 419
 420     tap_rate_limit($iface, $rate);
 421 }
 422
 423 sub tap_unplug {
 424     my ($iface) = @_;
 425
 426     my $path= "/sys/class/net/$iface/brport/bridge";
 427     if (-l $path) {
 428         my $bridge = basename(readlink($path));
 429         #avoid insecure dependency;
 430         ($bridge) = $bridge =~ /(\S+)/;
 431
 432         iface_set_master($iface, undef);
 433     }
 434
 435     &$cleanup_firewall_bridge($iface);
 436     #cleanup old port config from any openvswitch bridge
 437     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 438 }
 439
 440 sub copy_bridge_config {
 441     my ($br0, $br1) = @_;
 442
 443     return if $br0 eq $br1;
 444
 445     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
 446                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
 447
 448     foreach my $sysname (@$br_configs) {
 449         eval {
 450             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 451             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 452             if ($v0 ne $v1) {
 453                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 454             }
 455         };
 456         warn $@ if $@;
 457     }
 458 }
 459
 460 sub activate_bridge_vlan_slave {
 461     my ($bridgevlan, $iface, $tag) = @_;
 462     my $ifacevlan = "${iface}.$tag";
 463
 464     # create vlan on $iface is not already exist
 465     if (! -d "/sys/class/net/$ifacevlan") {
 466         eval {
 467             my $cmd = ['/sbin/ip', 'link', 'add'];
 468             push @$cmd, 'link', $iface;
 469             push @$cmd, 'name', $ifacevlan;
 470             push @$cmd, 'type', 'vlan', 'id', $tag;
 471             run_command($cmd);
 472         };
 473         die "can't add vlan tag $tag to interface $iface - $@\n" if $@;
 474
 475         # remove ipv6 link-local address before activation
 476         disable_ipv6($ifacevlan);
 477     }
 478
 479     # be sure to have the $ifacevlan up
 480     &$activate_interface($ifacevlan);
 481
 482     # test if $vlaniface is already enslaved in another bridge
 483     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 484     if (-l $path) {
 485         my $tbridge = basename(readlink($path));
 486         if ($tbridge ne $bridgevlan) {
 487             die "interface $ifacevlan already exist in bridge $tbridge\n";
 488         } else {
 489             # Port already attached to bridge: do nothing.
 490             return;
 491         }
 492     }
 493
 494     # add $ifacevlan to the bridge
 495     &$bridge_add_interface($bridgevlan, $ifacevlan);
 496 }
 497
 498 sub activate_bridge_vlan {
 499     my ($bridge, $tag_param) = @_;
 500
 501     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 502
 503     return $bridge if !defined($tag_param); # no vlan, simply return
 504
 505     my $tag = int($tag_param);
 506
 507     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 508
 509     my $bridgevlan = "${bridge}v$tag";
 510
 511     my @ifaces = ();
 512     my $dir = "/sys/class/net/$bridge/brif";
 513     PVE::Tools::dir_glob_foreach($dir, '(((eth|bond)\d+|en[^.]+)(\.\d+)?)', sub {
 514         push @ifaces, $_[0];
 515     });
 516
 517     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 518
 519     lock_network(sub {
 520         # add bridgevlan if it doesn't already exist
 521         if (! -d "/sys/class/net/$bridgevlan") {
 522             iface_create($bridgevlan, 'bridge');
 523         }
 524
 525         # for each physical interface (eth or bridge) bind them to bridge vlan
 526         foreach my $iface (@ifaces) {
 527             activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 528         }
 529
 530         #fixme: set other bridge flags
 531
 532         # remove ipv6 link-local address before activation
 533         disable_ipv6($bridgevlan);
 534         # be sure to have the bridge up
 535         &$activate_interface($bridgevlan);
 536     });
 537     return $bridgevlan;
 538 }
 539
 540 sub tcp_ping {
 541     my ($host, $port, $timeout) = @_;
 542
 543     my $refused = 1;
 544
 545     $timeout = 3 if !$timeout; # sane default
 546     if (!$port) {
 547         # Net::Ping defaults to the echo port
 548         $port = 7;
 549     } else {
 550         # Net::Ping's port_number() implies service_check(1)
 551         $refused = 0;
 552     }
 553
 554     my ($sock, $result);
 555     eval {
 556         $result = PVE::Tools::run_with_timeout($timeout, sub {
 557             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
 558             $result = $refused if $! == ECONNREFUSED;
 559         });
 560     };
 561     if ($sock) {
 562         $sock->close();
 563         $result = 1;
 564     }
 565     return $result;
 566 }
 567
 568 sub IP_from_cidr {
 569     my ($cidr, $version) = @_;
 570
 571     return if $cidr !~ m!^(\S+?)/(\S+)$!;
 572     my ($ip, $prefix) = ($1, $2);
 573
 574     my $ipobj = Net::IP->new($ip, $version);
 575     return if !$ipobj;
 576
 577     $version = $ipobj->version();
 578
 579     my $binmask = Net::IP::ip_get_mask($prefix, $version);
 580     return if !$binmask;
 581
 582     my $masked_binip = $ipobj->binip() & $binmask;
 583     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
 584     return Net::IP->new("$masked_ip/$prefix");
 585 }
 586
 587 sub is_ip_in_cidr {
 588     my ($ip, $cidr, $version) = @_;
 589
 590     my $cidr_obj = IP_from_cidr($cidr, $version);
 591     return undef if !$cidr_obj;
 592
 593     my $ip_obj = Net::IP->new($ip, $version);
 594     return undef if !$ip_obj;
 595
 596     my $overlap = $cidr_obj->overlaps($ip_obj);
 597
 598     return if !defined($overlap);
 599
 600     return $overlap == $Net::IP::IP_B_IN_A_OVERLAP || $overlap == $Net::IP::IP_IDENTICAL;
 601 }
 602
 603
 604 sub get_local_ip_from_cidr {
 605     my ($cidr) = @_;
 606
 607     my $IPs = {};
 608     my $i = 1;
 609     run_command(['/sbin/ip', 'address', 'show', 'to', $cidr, 'up'], outfunc => sub {
 610         if ($_[0] =~ m!^\s*inet(?:6)?\s+($PVE::Tools::IPRE)(?:/\d+|\s+peer\s+)!) {
 611             $IPs->{$1} = $i++ if !exists($IPs->{$1});
 612         }
 613     });
 614
 615     return [ sort { $IPs->{$a} <=> $IPs->{$b} } keys %{$IPs} ];
 616 }
 617
 618 sub addr_to_ip {
 619     my ($addr) = @_;
 620     my ($err, $host, $port) = Socket::getnameinfo($addr, NI_NUMERICHOST | NI_NUMERICSERV);
 621     die "failed to get numerical host address: $err\n" if $err;
 622     return ($host, $port) if wantarray;
 623     return $host;
 624 }
 625
 626 sub get_ip_from_hostname {
 627     my ($hostname, $noerr) = @_;
 628
 629     my @res = eval { PVE::Tools::getaddrinfo_all($hostname) };
 630     if ($@) {
 631         die "hostname lookup '$hostname' failed - $@" if !$noerr;
 632         return undef;
 633     }
 634
 635     my ($ip, $family);
 636     for my $ai (@res) {
 637         $family = $ai->{family};
 638         my $tmpip = addr_to_ip($ai->{addr});
 639         if ($tmpip !~ m/^127\.|^::1$/) {
 640             $ip = $tmpip;
 641             last;
 642         }
 643     }
 644     if (!defined($ip) ) {
 645         die "address lookup for '$hostname' did not find any IP address\n" if !$noerr;
 646         return undef;
 647     }
 648
 649     return wantarray ? ($ip, $family) : $ip;
 650 }
 651
 652 sub lock_network {
 653     my ($code, @param) = @_;
 654     my $res = lock_file('/var/lock/pve-network.lck', 10, $code, @param);
 655     die $@ if $@;
 656     return $res;
 657 }
 658
 659 # the canonical form of the given IP, i.e. dotted quad for IPv4 and RFC 5952 for IPv6
 660 sub canonical_ip {
 661     my ($ip) = @_;
 662
 663     my $ip_obj = NetAddr::IP->new($ip) or die "invalid IP string '$ip'\n";
 664
 665     return $ip_obj->canon();
 666 }
 667
 668 # List of unique, canonical IPs in the provided list.
 669 # Keeps the original order, filtering later duplicates.
 670 sub unique_ips {
 671     my ($ips) = @_;
 672
 673     my $res = [];
 674     my $seen = {};
 675
 676     for my $ip (@{$ips}) {
 677         $ip = canonical_ip($ip);
 678
 679         next if $seen->{$ip};
 680
 681         $seen->{$ip} = 1;
 682         push @{$res}, $ip;
 683     }
 684
 685     return $res;
 686 }
 687
 688 1;