src/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::Tools qw(run_command lock_file);
   6 use PVE::ProcFSTools;
   7 use PVE::INotify;
   8 use File::Basename;
   9 use IO::Socket::IP;
  10 use POSIX qw(ECONNREFUSED);
  11
  12 use Net::IP;
  13
  14 # host network related utility functions
  15
  16 our $ipv4_reverse_mask = [
  17     '0.0.0.0',
  18     '128.0.0.0',
  19     '192.0.0.0',
  20     '224.0.0.0',
  21     '240.0.0.0',
  22     '248.0.0.0',
  23     '252.0.0.0',
  24     '254.0.0.0',
  25     '255.0.0.0',
  26     '255.128.0.0',
  27     '255.192.0.0',
  28     '255.224.0.0',
  29     '255.240.0.0',
  30     '255.248.0.0',
  31     '255.252.0.0',
  32     '255.254.0.0',
  33     '255.255.0.0',
  34     '255.255.128.0',
  35     '255.255.192.0',
  36     '255.255.224.0',
  37     '255.255.240.0',
  38     '255.255.248.0',
  39     '255.255.252.0',
  40     '255.255.254.0',
  41     '255.255.255.0',
  42     '255.255.255.128',
  43     '255.255.255.192',
  44     '255.255.255.224',
  45     '255.255.255.240',
  46     '255.255.255.248',
  47     '255.255.255.252',
  48     '255.255.255.254',
  49     '255.255.255.255',
  50 ];
  51
  52 our $ipv4_mask_hash_localnet = {
  53     '255.0.0.0' => 8,
  54     '255.128.0.0' => 9,
  55     '255.192.0.0' => 10,
  56     '255.224.0.0' => 11,
  57     '255.240.0.0' => 12,
  58     '255.248.0.0' => 13,
  59     '255.252.0.0' => 14,
  60     '255.254.0.0' => 15,
  61     '255.255.0.0' => 16,
  62     '255.255.128.0' => 17,
  63     '255.255.192.0' => 18,
  64     '255.255.224.0' => 19,
  65     '255.255.240.0' => 20,
  66     '255.255.248.0' => 21,
  67     '255.255.252.0' => 22,
  68     '255.255.254.0' => 23,
  69     '255.255.255.0' => 24,
  70     '255.255.255.128' => 25,
  71     '255.255.255.192' => 26,
  72     '255.255.255.224' => 27,
  73     '255.255.255.240' => 28,
  74     '255.255.255.248' => 29,
  75     '255.255.255.252' => 30,
  76     '255.255.255.254' => 31,
  77     '255.255.255.255' => 32,
  78 };
  79
  80 sub setup_tc_rate_limit {
  81     my ($iface, $rate, $burst, $debug) = @_;
  82
  83     # these are allowed / expected to fail, e.g. when there is no previous rate limit to remove
  84     eval { run_command("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1"); };
  85     eval { run_command("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1"); };
  86     eval { run_command("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1"); };
  87     eval { run_command("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1"); };
  88
  89     return if !$rate;
  90
  91     # tbf does not work for unknown reason
  92     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
  93     # so we use htb instead
  94     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
  95     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
  96                 "htb rate ${rate}bps burst ${burst}b");
  97
  98     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
  99     run_command("/sbin/tc filter add dev $iface parent ffff: " .
 100                 "prio 50 basic " .
 101                 "police rate ${rate}bps burst ${burst}b mtu 64kb " .
 102                 "drop flowid :1");
 103
 104     if ($debug) {
 105         print "DEBUG tc settings\n";
 106         system("/sbin/tc qdisc ls dev $iface");
 107         system("/sbin/tc class ls dev $iface");
 108         system("/sbin/tc filter ls dev $iface parent ffff:");
 109     }
 110 }
 111
 112 sub tap_rate_limit {
 113     my ($iface, $rate) = @_;
 114
 115     my $debug = 0;
 116     $rate = int($rate*1024*1024) if $rate;
 117     my $burst = 1024*1024;
 118
 119     setup_tc_rate_limit($iface, $rate, $burst, $debug);
 120 }
 121
 122 my $read_bridge_mtu = sub {
 123     my ($bridge) = @_;
 124
 125     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
 126     die "bridge '$bridge' does not exist\n" if !$mtu;
 127     # avoid insecure dependency;
 128     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
 129     $mtu = int($1);
 130
 131     return $mtu;
 132 };
 133
 134 my $parse_tap_device_name = sub {
 135     my ($iface, $noerr) = @_;
 136
 137     my ($vmid, $devid);
 138
 139     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
 140         $vmid = $1;
 141         $devid = $2;
 142     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
 143         $vmid = $1;
 144         $devid = $2;
 145     } else {
 146         return undef if $noerr;
 147         die "can't create firewall bridge for random interface name '$iface'\n";
 148     }
 149
 150     return ($vmid, $devid);
 151 };
 152
 153 my $compute_fwbr_names = sub {
 154     my ($vmid, $devid) = @_;
 155
 156     my $fwbr = "fwbr${vmid}i${devid}";
 157     # Note: the firewall use 'fwln+' to filter traffic to VMs
 158     my $vethfw = "fwln${vmid}i${devid}";
 159     my $vethfwpeer = "fwpr${vmid}p${devid}";
 160     my $ovsintport = "fwln${vmid}o${devid}";
 161
 162     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
 163 };
 164
 165 my $cond_create_bridge = sub {
 166     my ($bridge) = @_;
 167
 168     if (! -d "/sys/class/net/$bridge") {
 169         system("/sbin/brctl addbr $bridge") == 0 ||
 170             die "can't add bridge '$bridge'\n";
 171         disable_ipv6($bridge);
 172     }
 173 };
 174
 175 sub disable_ipv6 {
 176     my ($iface) = @_;
 177     return if !-d '/proc/sys/net/ipv6'; # ipv6 might be completely disabled
 178     my $file = "/proc/sys/net/ipv6/conf/$iface/disable_ipv6";
 179     open(my $fh, '>', $file) or die "failed to open $file for writing: $!\n";
 180     print {$fh} "1\n" or die "failed to disable link-local ipv6 for $iface\n";
 181     close($fh);
 182 }
 183
 184 my $bridge_add_interface = sub {
 185     my ($bridge, $iface, $tag, $trunks) = @_;
 186
 187     # drop link local address (it can't be used when on a bridge anyway)
 188     disable_ipv6($iface);
 189     system("/sbin/brctl addif $bridge $iface") == 0 ||
 190         die "can't add interface 'iface' to bridge '$bridge'\n";
 191
 192    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 193
 194    if ($vlan_aware) {
 195         if ($tag) {
 196             system({'/sbin/bridge'} 'bridge', 'vlan', 'del', 'dev', $iface, 'vid', '1-4094') == 0
 197                 or die "failed to remove default vlan tags of $iface\n";
 198             system({'/sbin/bridge'} 'bridge', 'vlan', 'add', 'dev', $iface, 'vid', $tag, 'pvid', 'untagged') == 0
 199                 or die "unable to add vlan $tag to interface $iface\n";
 200
 201             warn "Caution: Setting VLAN ID 1 on a VLAN aware bridge may be dangerous\n" if $tag == 1;
 202         } else {
 203             system("/sbin/bridge vlan add dev $iface vid 2-4094") == 0 ||
 204             die "unable to add default vlan tags to interface $iface\n" if !$trunks;
 205         }
 206
 207         if ($trunks) {
 208             my @trunks_array = split /;/, $trunks;
 209             foreach my $trunk (@trunks_array) {
 210                 system("/sbin/bridge vlan add dev $iface vid $trunk") == 0 ||
 211                 die "unable to add vlan $trunk to interface $iface\n";
 212             }
 213         }
 214    }
 215 };
 216
 217 my $ovs_bridge_add_port = sub {
 218     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
 219
 220     $trunks =~ s/;/,/g if $trunks;
 221
 222     my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
 223     $cmd .= " tag=$tag" if $tag;
 224     $cmd .= " trunks=". join(',', $trunks) if $trunks;
 225     $cmd .= " vlan_mode=native-untagged" if $tag && $trunks;
 226
 227     $cmd .= " -- set Interface $iface type=internal" if $internal;
 228     system($cmd) == 0 ||
 229         die "can't add ovs port '$iface'\n";
 230     disable_ipv6($iface);
 231 };
 232
 233 my $activate_interface = sub {
 234     my ($iface) = @_;
 235
 236     system("/sbin/ip link set $iface up") == 0 ||
 237         die "can't activate interface '$iface'\n";
 238 };
 239
 240 sub tap_create {
 241     my ($iface, $bridge) = @_;
 242
 243     die "unable to get bridge setting\n" if !$bridge;
 244
 245     my $bridgemtu = &$read_bridge_mtu($bridge);
 246
 247     eval {
 248         disable_ipv6($iface);
 249         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $iface, 'up', 'promisc', 'on', 'mtu', $bridgemtu]);
 250     };
 251     die "interface activation failed\n" if $@;
 252 }
 253
 254 sub veth_create {
 255     my ($veth, $vethpeer, $bridge, $mac) = @_;
 256
 257     die "unable to get bridge setting\n" if !$bridge;
 258
 259     my $bridgemtu = &$read_bridge_mtu($bridge);
 260
 261     # create veth pair
 262     if (! -d "/sys/class/net/$veth") {
 263         my $cmd = "/sbin/ip link add name $veth type veth peer name $vethpeer mtu $bridgemtu";
 264         $cmd .= " addr $mac" if $mac;
 265         system($cmd) == 0 || die "can't create interface $veth\n";
 266     }
 267
 268     # up vethpair
 269     disable_ipv6($veth);
 270     disable_ipv6($vethpeer);
 271     &$activate_interface($veth);
 272     &$activate_interface($vethpeer);
 273 }
 274
 275 sub veth_delete {
 276     my ($veth) = @_;
 277
 278     if (-d "/sys/class/net/$veth") {
 279         run_command("/sbin/ip link delete dev $veth", outfunc => sub {}, errfunc => sub {});
 280     }
 281     eval { tap_unplug($veth) };
 282 }
 283
 284 my $create_firewall_bridge_linux = sub {
 285     my ($iface, $bridge, $tag, $trunks) = @_;
 286
 287     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 288     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 289
 290     &$cond_create_bridge($fwbr);
 291     &$activate_interface($fwbr);
 292
 293     copy_bridge_config($bridge, $fwbr);
 294     veth_create($vethfw, $vethfwpeer, $bridge);
 295
 296     &$bridge_add_interface($fwbr, $vethfw);
 297     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
 298
 299     &$bridge_add_interface($fwbr, $iface);
 300 };
 301
 302 my $create_firewall_bridge_ovs = sub {
 303     my ($iface, $bridge, $tag, $trunks) = @_;
 304
 305     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 306     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 307
 308     my $bridgemtu = &$read_bridge_mtu($bridge);
 309
 310     &$cond_create_bridge($fwbr);
 311     &$activate_interface($fwbr);
 312
 313     &$bridge_add_interface($fwbr, $iface);
 314
 315     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
 316     &$activate_interface($ovsintport);
 317
 318     # set the same mtu for ovs int port
 319     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $ovsintport, 'mtu', $bridgemtu]);
 320
 321     &$bridge_add_interface($fwbr, $ovsintport);
 322 };
 323
 324 my $cleanup_firewall_bridge = sub {
 325     my ($iface) = @_;
 326
 327     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 328     return if !defined($vmid);
 329     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 330
 331     # cleanup old port config from any openvswitch bridge
 332     if (-d "/sys/class/net/$ovsintport") {
 333         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 334     }
 335
 336     # delete old vethfw interface
 337     veth_delete($vethfw);
 338
 339     # cleanup fwbr bridge
 340     if (-d "/sys/class/net/$fwbr") {
 341         run_command("/sbin/ip link set dev $fwbr down", outfunc => sub {}, errfunc => sub {});
 342         run_command("/sbin/brctl delbr $fwbr", outfunc => sub {}, errfunc => sub {});
 343     }
 344 };
 345
 346 sub tap_plug {
 347     my ($iface, $bridge, $tag, $firewall, $trunks, $rate) = @_;
 348
 349     #cleanup old port config from any openvswitch bridge
 350     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 351
 352     if (-d "/sys/class/net/$bridge/bridge") {
 353         &$cleanup_firewall_bridge($iface); # remove stale devices
 354
 355         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 356
 357         if (!$vlan_aware) {
 358             die "vlan aware feature need to be enabled to use trunks" if $trunks;
 359             my $newbridge = activate_bridge_vlan($bridge, $tag);
 360             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 361             $bridge = $newbridge;
 362             $tag = undef;
 363         }
 364
 365         if ($firewall) {
 366             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks);
 367         } else {
 368             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
 369         }
 370
 371     } else {
 372         &$cleanup_firewall_bridge($iface); # remove stale devices
 373
 374         if ($firewall) {
 375             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks);
 376         } else {
 377             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
 378         }
 379     }
 380
 381     tap_rate_limit($iface, $rate);
 382 }
 383
 384 sub tap_unplug {
 385     my ($iface) = @_;
 386
 387     my $path= "/sys/class/net/$iface/brport/bridge";
 388     if (-l $path) {
 389         my $bridge = basename(readlink($path));
 390         #avoid insecure dependency;
 391         ($bridge) = $bridge =~ /(\S+)/;
 392
 393         system("/sbin/brctl delif $bridge $iface") == 0 ||
 394             die "can't del interface '$iface' from bridge '$bridge'\n";
 395
 396     }
 397
 398     &$cleanup_firewall_bridge($iface);
 399     #cleanup old port config from any openvswitch bridge
 400     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 401 }
 402
 403 sub copy_bridge_config {
 404     my ($br0, $br1) = @_;
 405
 406     return if $br0 eq $br1;
 407
 408     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
 409                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
 410
 411     foreach my $sysname (@$br_configs) {
 412         eval {
 413             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 414             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 415             if ($v0 ne $v1) {
 416                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 417             }
 418         };
 419         warn $@ if $@;
 420     }
 421 }
 422
 423 sub activate_bridge_vlan_slave {
 424     my ($bridgevlan, $iface, $tag) = @_;
 425     my $ifacevlan = "${iface}.$tag";
 426
 427     # create vlan on $iface is not already exist
 428     if (! -d "/sys/class/net/$ifacevlan") {
 429         system("/sbin/ip link add link $iface name $ifacevlan type vlan id $tag") == 0 ||
 430             die "can't add vlan tag $tag to interface $iface\n";
 431
 432         # remove ipv6 link-local address before activation
 433         disable_ipv6($ifacevlan);
 434     }
 435
 436     # be sure to have the $ifacevlan up
 437     &$activate_interface($ifacevlan);
 438
 439     # test if $vlaniface is already enslaved in another bridge
 440     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 441     if (-l $path) {
 442         my $tbridge = basename(readlink($path));
 443         if ($tbridge ne $bridgevlan) {
 444             die "interface $ifacevlan already exist in bridge $tbridge\n";
 445         } else {
 446             # Port already attached to bridge: do nothing.
 447             return;
 448         }
 449     }
 450
 451     # add $ifacevlan to the bridge
 452     &$bridge_add_interface($bridgevlan, $ifacevlan);
 453 }
 454
 455 sub activate_bridge_vlan {
 456     my ($bridge, $tag_param) = @_;
 457
 458     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 459
 460     return $bridge if !defined($tag_param); # no vlan, simply return
 461
 462     my $tag = int($tag_param);
 463
 464     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 465
 466     my $bridgevlan = "${bridge}v$tag";
 467
 468     my @ifaces = ();
 469     my $dir = "/sys/class/net/$bridge/brif";
 470     PVE::Tools::dir_glob_foreach($dir, '(((eth|bond)\d+|en[^.]+)(\.\d+)?)', sub {
 471         push @ifaces, $_[0];
 472     });
 473
 474     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 475
 476     lock_network(sub {
 477         # add bridgevlan if it doesn't already exist
 478         if (! -d "/sys/class/net/$bridgevlan") {
 479             system("/sbin/brctl addbr $bridgevlan") == 0 ||
 480                 die "can't add bridge $bridgevlan\n";
 481         }
 482
 483         # for each physical interface (eth or bridge) bind them to bridge vlan
 484         foreach my $iface (@ifaces) {
 485             activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 486         }
 487
 488         #fixme: set other bridge flags
 489
 490         # remove ipv6 link-local address before activation
 491         disable_ipv6($bridgevlan);
 492         # be sure to have the bridge up
 493         &$activate_interface($bridgevlan);
 494     });
 495     return $bridgevlan;
 496 }
 497
 498 sub tcp_ping {
 499     my ($host, $port, $timeout) = @_;
 500
 501     my $refused = 1;
 502
 503     $timeout = 3 if !$timeout; # sane default
 504     if (!$port) {
 505         # Net::Ping defaults to the echo port
 506         $port = 7;
 507     } else {
 508         # Net::Ping's port_number() implies service_check(1)
 509         $refused = 0;
 510     }
 511
 512     my ($sock, $result);
 513     eval {
 514         $result = PVE::Tools::run_with_timeout($timeout, sub {
 515             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
 516             $result = $refused if $! == ECONNREFUSED;
 517         });
 518     };
 519     if ($sock) {
 520         $sock->close();
 521         $result = 1;
 522     }
 523     return $result;
 524 }
 525
 526 sub IP_from_cidr {
 527     my ($cidr, $version) = @_;
 528
 529     return if $cidr !~ m!^(\S+?)/(\S+)$!;
 530     my ($ip, $prefix) = ($1, $2);
 531
 532     my $ipobj = Net::IP->new($ip, $version);
 533     return if !$ipobj;
 534
 535     $version = $ipobj->version();
 536
 537     my $binmask = Net::IP::ip_get_mask($prefix, $version);
 538     return if !$binmask;
 539
 540     my $masked_binip = $ipobj->binip() & $binmask;
 541     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
 542     return Net::IP->new("$masked_ip/$prefix");
 543 }
 544
 545 sub is_ip_in_cidr {
 546     my ($ip, $cidr, $version) = @_;
 547
 548     my $cidr_obj = IP_from_cidr($cidr, $version);
 549     return undef if !$cidr_obj;
 550
 551     my $ip_obj = Net::IP->new($ip, $version);
 552     return undef if !$ip_obj;
 553
 554     return $cidr_obj->overlaps($ip_obj) == $Net::IP::IP_B_IN_A_OVERLAP;
 555 }
 556
 557
 558 sub get_local_ip_from_cidr {
 559     my ($cidr) = @_;
 560
 561     my $cmd = ['/sbin/ip', 'address', 'show', 'to', $cidr, 'up'];
 562
 563     my $IPs = [];
 564
 565     my $code = sub {
 566         my $line = shift;
 567
 568         if ($line =~ m!^\s*inet(?:6)?\s+($PVE::Tools::IPRE)/\d+!) {
 569             push @$IPs, $1;
 570         }
 571     };
 572
 573     PVE::Tools::run_command($cmd, outfunc => $code);
 574
 575     return $IPs;
 576 }
 577
 578 sub lock_network {
 579     my ($code, @param) = @_;
 580     my $res = lock_file('/var/lock/pve-network.lck', 10, $code, @param);
 581     die $@ if $@;
 582     return $res;
 583 }
 584
 585 1;