src/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::INotify;
   7 use PVE::ProcFSTools;
   8 use PVE::Tools qw(run_command lock_file);
   9
  10 use File::Basename;
  11 use IO::Socket::IP;
  12 use Net::IP;
  13 use POSIX qw(ECONNREFUSED);
  14 use Socket qw(NI_NUMERICHOST NI_NUMERICSERV);
  15
  16 my $have_sdn;
  17 eval {
  18     require PVE::Network::SDN::Zones;
  19     $have_sdn = 1;
  20 };
  21
  22 # host network related utility functions
  23
  24 our $PHYSICAL_NIC_RE = qr/(?:eth\d+|en[^:.]+|ib\d+)/;
  25
  26 our $ipv4_reverse_mask = [
  27     '0.0.0.0',
  28     '128.0.0.0',
  29     '192.0.0.0',
  30     '224.0.0.0',
  31     '240.0.0.0',
  32     '248.0.0.0',
  33     '252.0.0.0',
  34     '254.0.0.0',
  35     '255.0.0.0',
  36     '255.128.0.0',
  37     '255.192.0.0',
  38     '255.224.0.0',
  39     '255.240.0.0',
  40     '255.248.0.0',
  41     '255.252.0.0',
  42     '255.254.0.0',
  43     '255.255.0.0',
  44     '255.255.128.0',
  45     '255.255.192.0',
  46     '255.255.224.0',
  47     '255.255.240.0',
  48     '255.255.248.0',
  49     '255.255.252.0',
  50     '255.255.254.0',
  51     '255.255.255.0',
  52     '255.255.255.128',
  53     '255.255.255.192',
  54     '255.255.255.224',
  55     '255.255.255.240',
  56     '255.255.255.248',
  57     '255.255.255.252',
  58     '255.255.255.254',
  59     '255.255.255.255',
  60 ];
  61
  62 our $ipv4_mask_hash_localnet = {
  63     '255.0.0.0' => 8,
  64     '255.128.0.0' => 9,
  65     '255.192.0.0' => 10,
  66     '255.224.0.0' => 11,
  67     '255.240.0.0' => 12,
  68     '255.248.0.0' => 13,
  69     '255.252.0.0' => 14,
  70     '255.254.0.0' => 15,
  71     '255.255.0.0' => 16,
  72     '255.255.128.0' => 17,
  73     '255.255.192.0' => 18,
  74     '255.255.224.0' => 19,
  75     '255.255.240.0' => 20,
  76     '255.255.248.0' => 21,
  77     '255.255.252.0' => 22,
  78     '255.255.254.0' => 23,
  79     '255.255.255.0' => 24,
  80     '255.255.255.128' => 25,
  81     '255.255.255.192' => 26,
  82     '255.255.255.224' => 27,
  83     '255.255.255.240' => 28,
  84     '255.255.255.248' => 29,
  85     '255.255.255.252' => 30,
  86     '255.255.255.254' => 31,
  87     '255.255.255.255' => 32,
  88 };
  89
  90 sub setup_tc_rate_limit {
  91     my ($iface, $rate, $burst, $debug) = @_;
  92
  93     # these are allowed / expected to fail, e.g. when there is no previous rate limit to remove
  94     eval { run_command("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1"); };
  95     eval { run_command("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1"); };
  96     eval { run_command("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1"); };
  97     eval { run_command("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1"); };
  98
  99     return if !$rate;
 100
 101     # tbf does not work for unknown reason
 102     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
 103     # so we use htb instead
 104     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
 105     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
 106                 "htb rate ${rate}bps burst ${burst}b");
 107
 108     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
 109     run_command("/sbin/tc filter add dev $iface parent ffff: " .
 110                 "prio 50 basic " .
 111                 "police rate ${rate}bps burst ${burst}b mtu 64kb " .
 112                 "drop");
 113
 114     if ($debug) {
 115         print "DEBUG tc settings\n";
 116         system("/sbin/tc qdisc ls dev $iface");
 117         system("/sbin/tc class ls dev $iface");
 118         system("/sbin/tc filter ls dev $iface parent ffff:");
 119     }
 120 }
 121
 122 sub tap_rate_limit {
 123     my ($iface, $rate) = @_;
 124
 125     my $debug = 0;
 126     $rate = int($rate*1024*1024) if $rate;
 127     my $burst = 1024*1024;
 128
 129     setup_tc_rate_limit($iface, $rate, $burst, $debug);
 130 }
 131
 132 my $read_bridge_mtu = sub {
 133     my ($bridge) = @_;
 134
 135     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
 136     die "bridge '$bridge' does not exist\n" if !$mtu;
 137     # avoid insecure dependency;
 138     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
 139     $mtu = int($1);
 140
 141     return $mtu;
 142 };
 143
 144 my $parse_tap_device_name = sub {
 145     my ($iface, $noerr) = @_;
 146
 147     my ($vmid, $devid);
 148
 149     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
 150         $vmid = $1;
 151         $devid = $2;
 152     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
 153         $vmid = $1;
 154         $devid = $2;
 155     } else {
 156         return undef if $noerr;
 157         die "can't create firewall bridge for random interface name '$iface'\n";
 158     }
 159
 160     return ($vmid, $devid);
 161 };
 162
 163 my $compute_fwbr_names = sub {
 164     my ($vmid, $devid) = @_;
 165
 166     my $fwbr = "fwbr${vmid}i${devid}";
 167     # Note: the firewall use 'fwln+' to filter traffic to VMs
 168     my $vethfw = "fwln${vmid}i${devid}";
 169     my $vethfwpeer = "fwpr${vmid}p${devid}";
 170     my $ovsintport = "fwln${vmid}o${devid}";
 171
 172     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
 173 };
 174
 175 sub iface_delete($) {
 176     my ($iface) = @_;
 177     run_command(['/sbin/ip', 'link', 'delete', 'dev', $iface], noerr => 1)
 178         == 0 or die "failed to delete interface '$iface'\n";
 179 }
 180
 181 sub iface_create($$@) {
 182     my ($iface, $type, @args) = @_;
 183     run_command(['/sbin/ip', 'link', 'add', $iface, 'type', $type, @args], noerr => 1)
 184         == 0 or die "failed to create interface '$iface'\n";
 185 }
 186
 187 sub iface_set($@) {
 188     my ($iface, @opts) = @_;
 189     run_command(['/sbin/ip', 'link', 'set', $iface, @opts], noerr => 1)
 190         == 0 or die "failed to set interface options for '$iface' (".join(' ', @opts).")\n";
 191 }
 192
 193 # helper for nicer error messages:
 194 sub iface_set_master($$) {
 195     my ($iface, $master) = @_;
 196     if (defined($master)) {
 197         eval { iface_set($iface, 'master', $master) };
 198         die "can't enslave '$iface' to '$master'\n" if $@;
 199     } else {
 200         eval { iface_set($iface, 'nomaster') };
 201         die "can't unenslave '$iface'\n" if $@;
 202     }
 203 }
 204
 205 my $cond_create_bridge = sub {
 206     my ($bridge) = @_;
 207
 208     if (! -d "/sys/class/net/$bridge") {
 209         iface_create($bridge, 'bridge');
 210         disable_ipv6($bridge);
 211     }
 212 };
 213
 214 sub disable_ipv6 {
 215     my ($iface) = @_;
 216     return if !-d '/proc/sys/net/ipv6'; # ipv6 might be completely disabled
 217     my $file = "/proc/sys/net/ipv6/conf/$iface/disable_ipv6";
 218     open(my $fh, '>', $file) or die "failed to open $file for writing: $!\n";
 219     print {$fh} "1\n" or die "failed to disable link-local ipv6 for $iface\n";
 220     close($fh);
 221 }
 222
 223 my $bridge_add_interface = sub {
 224     my ($bridge, $iface, $tag, $trunks) = @_;
 225
 226     # drop link local address (it can't be used when on a bridge anyway)
 227     disable_ipv6($iface);
 228     iface_set_master($iface, $bridge);
 229
 230    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 231
 232    if ($vlan_aware) {
 233         if ($tag) {
 234             system({'/sbin/bridge'} 'bridge', 'vlan', 'del', 'dev', $iface, 'vid', '1-4094') == 0
 235                 or die "failed to remove default vlan tags of $iface\n";
 236             system({'/sbin/bridge'} 'bridge', 'vlan', 'add', 'dev', $iface, 'vid', $tag, 'pvid', 'untagged') == 0
 237                 or die "unable to add vlan $tag to interface $iface\n";
 238
 239             warn "Caution: Setting VLAN ID 1 on a VLAN aware bridge may be dangerous\n" if $tag == 1;
 240         } else {
 241             system("/sbin/bridge vlan add dev $iface vid 2-4094") == 0 ||
 242             die "unable to add default vlan tags to interface $iface\n" if !$trunks;
 243         }
 244
 245         if ($trunks) {
 246             my @trunks_array = split /;/, $trunks;
 247             foreach my $trunk (@trunks_array) {
 248                 system("/sbin/bridge vlan add dev $iface vid $trunk") == 0 ||
 249                 die "unable to add vlan $trunk to interface $iface\n";
 250             }
 251         }
 252    }
 253 };
 254
 255 my $ovs_bridge_add_port = sub {
 256     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
 257
 258     $trunks =~ s/;/,/g if $trunks;
 259
 260     my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
 261     $cmd .= " tag=$tag" if $tag;
 262     $cmd .= " trunks=". join(',', $trunks) if $trunks;
 263     $cmd .= " vlan_mode=native-untagged" if $tag && $trunks;
 264
 265     $cmd .= " -- set Interface $iface type=internal" if $internal;
 266     system($cmd) == 0 ||
 267         die "can't add ovs port '$iface'\n";
 268     disable_ipv6($iface);
 269 };
 270
 271 my $activate_interface = sub {
 272     my ($iface) = @_;
 273
 274     system("/sbin/ip link set $iface up") == 0 ||
 275         die "can't activate interface '$iface'\n";
 276 };
 277
 278 sub tap_create {
 279     my ($iface, $bridge) = @_;
 280
 281     if ($have_sdn) {
 282         my ($bridgesdn, undef) = PVE::Network::SDN::Zones::get_bridge_vlan($bridge);
 283         $bridge = $bridgesdn if $bridgesdn;
 284     }
 285
 286     die "unable to get bridge setting\n" if !$bridge;
 287
 288     my $bridgemtu = &$read_bridge_mtu($bridge);
 289
 290     eval {
 291         disable_ipv6($iface);
 292         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $iface, 'up', 'promisc', 'on', 'mtu', $bridgemtu]);
 293     };
 294     die "interface activation failed\n" if $@;
 295 }
 296
 297 sub veth_create {
 298     my ($veth, $vethpeer, $bridge, $mac) = @_;
 299
 300     if ($have_sdn) {
 301         my ($bridgesdn, undef) = PVE::Network::SDN::Zones::get_bridge_vlan($bridge);
 302         $bridge = $bridgesdn if $bridgesdn;
 303     }
 304
 305     die "unable to get bridge setting\n" if !$bridge;
 306
 307     my $bridgemtu = &$read_bridge_mtu($bridge);
 308
 309     # create veth pair
 310     if (! -d "/sys/class/net/$veth") {
 311         my $cmd = "/sbin/ip link add name $veth mtu $bridgemtu type veth peer name $vethpeer mtu $bridgemtu";
 312         $cmd .= " addr $mac" if $mac;
 313         system($cmd) == 0 || die "can't create interface $veth\n";
 314     }
 315
 316     # up vethpair
 317     disable_ipv6($veth);
 318     disable_ipv6($vethpeer);
 319     &$activate_interface($veth);
 320     &$activate_interface($vethpeer);
 321 }
 322
 323 sub veth_delete {
 324     my ($veth) = @_;
 325
 326     if (-d "/sys/class/net/$veth") {
 327         iface_delete($veth);
 328     }
 329     eval { tap_unplug($veth) };
 330 }
 331
 332 my $create_firewall_bridge_linux = sub {
 333     my ($iface, $bridge, $tag, $trunks) = @_;
 334
 335     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 336     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 337
 338     &$cond_create_bridge($fwbr);
 339     &$activate_interface($fwbr);
 340
 341     copy_bridge_config($bridge, $fwbr);
 342     veth_create($vethfw, $vethfwpeer, $bridge);
 343
 344     &$bridge_add_interface($fwbr, $vethfw);
 345     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
 346
 347     &$bridge_add_interface($fwbr, $iface);
 348 };
 349
 350 my $create_firewall_bridge_ovs = sub {
 351     my ($iface, $bridge, $tag, $trunks) = @_;
 352
 353     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 354     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 355
 356     my $bridgemtu = &$read_bridge_mtu($bridge);
 357
 358     &$cond_create_bridge($fwbr);
 359     &$activate_interface($fwbr);
 360
 361     &$bridge_add_interface($fwbr, $iface);
 362
 363     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
 364     &$activate_interface($ovsintport);
 365
 366     # set the same mtu for ovs int port
 367     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $ovsintport, 'mtu', $bridgemtu]);
 368
 369     &$bridge_add_interface($fwbr, $ovsintport);
 370 };
 371
 372 my $cleanup_firewall_bridge = sub {
 373     my ($iface) = @_;
 374
 375     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 376     return if !defined($vmid);
 377     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 378
 379     # cleanup old port config from any openvswitch bridge
 380     if (-d "/sys/class/net/$ovsintport") {
 381         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 382     }
 383
 384     # delete old vethfw interface
 385     veth_delete($vethfw);
 386
 387     # cleanup fwbr bridge
 388     if (-d "/sys/class/net/$fwbr") {
 389         iface_delete($fwbr);
 390     }
 391 };
 392
 393 sub tap_plug {
 394     my ($iface, $bridge, $tag, $firewall, $trunks, $rate) = @_;
 395
 396     if ($have_sdn) {
 397         my ($bridgesdn, $tag) = PVE::Network::SDN::Zones::get_bridge_vlan($bridge);
 398         $bridge = $bridgesdn if $bridgesdn;
 399         $trunks = undef;
 400     }
 401
 402     #cleanup old port config from any openvswitch bridge
 403     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 404
 405     if (-d "/sys/class/net/$bridge/bridge") {
 406         &$cleanup_firewall_bridge($iface); # remove stale devices
 407
 408         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 409
 410         if (!$vlan_aware) {
 411             die "vlan aware feature need to be enabled to use trunks" if $trunks;
 412             my $newbridge = activate_bridge_vlan($bridge, $tag);
 413             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 414             $bridge = $newbridge;
 415             $tag = undef;
 416         }
 417
 418         if ($firewall) {
 419             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks);
 420         } else {
 421             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
 422         }
 423
 424     } else {
 425         &$cleanup_firewall_bridge($iface); # remove stale devices
 426
 427         if ($firewall) {
 428             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks);
 429         } else {
 430             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
 431         }
 432     }
 433
 434     tap_rate_limit($iface, $rate);
 435 }
 436
 437 sub tap_unplug {
 438     my ($iface) = @_;
 439
 440     my $path= "/sys/class/net/$iface/brport/bridge";
 441     if (-l $path) {
 442         my $bridge = basename(readlink($path));
 443         #avoid insecure dependency;
 444         ($bridge) = $bridge =~ /(\S+)/;
 445
 446         iface_set_master($iface, undef);
 447     }
 448
 449     &$cleanup_firewall_bridge($iface);
 450     #cleanup old port config from any openvswitch bridge
 451     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 452 }
 453
 454 sub copy_bridge_config {
 455     my ($br0, $br1) = @_;
 456
 457     return if $br0 eq $br1;
 458
 459     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
 460                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
 461
 462     foreach my $sysname (@$br_configs) {
 463         eval {
 464             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 465             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 466             if ($v0 ne $v1) {
 467                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 468             }
 469         };
 470         warn $@ if $@;
 471     }
 472 }
 473
 474 sub activate_bridge_vlan_slave {
 475     my ($bridgevlan, $iface, $tag) = @_;
 476     my $ifacevlan = "${iface}.$tag";
 477
 478     # create vlan on $iface is not already exist
 479     if (! -d "/sys/class/net/$ifacevlan") {
 480         system("/sbin/ip link add link $iface name $ifacevlan type vlan id $tag") == 0 ||
 481             die "can't add vlan tag $tag to interface $iface\n";
 482
 483         # remove ipv6 link-local address before activation
 484         disable_ipv6($ifacevlan);
 485     }
 486
 487     # be sure to have the $ifacevlan up
 488     &$activate_interface($ifacevlan);
 489
 490     # test if $vlaniface is already enslaved in another bridge
 491     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 492     if (-l $path) {
 493         my $tbridge = basename(readlink($path));
 494         if ($tbridge ne $bridgevlan) {
 495             die "interface $ifacevlan already exist in bridge $tbridge\n";
 496         } else {
 497             # Port already attached to bridge: do nothing.
 498             return;
 499         }
 500     }
 501
 502     # add $ifacevlan to the bridge
 503     &$bridge_add_interface($bridgevlan, $ifacevlan);
 504 }
 505
 506 sub activate_bridge_vlan {
 507     my ($bridge, $tag_param) = @_;
 508
 509     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 510
 511     return $bridge if !defined($tag_param); # no vlan, simply return
 512
 513     my $tag = int($tag_param);
 514
 515     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 516
 517     my $bridgevlan = "${bridge}v$tag";
 518
 519     my @ifaces = ();
 520     my $dir = "/sys/class/net/$bridge/brif";
 521     PVE::Tools::dir_glob_foreach($dir, '(((eth|bond)\d+|en[^.]+)(\.\d+)?)', sub {
 522         push @ifaces, $_[0];
 523     });
 524
 525     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 526
 527     lock_network(sub {
 528         # add bridgevlan if it doesn't already exist
 529         if (! -d "/sys/class/net/$bridgevlan") {
 530             iface_create($bridgevlan, 'bridge');
 531         }
 532
 533         # for each physical interface (eth or bridge) bind them to bridge vlan
 534         foreach my $iface (@ifaces) {
 535             activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 536         }
 537
 538         #fixme: set other bridge flags
 539
 540         # remove ipv6 link-local address before activation
 541         disable_ipv6($bridgevlan);
 542         # be sure to have the bridge up
 543         &$activate_interface($bridgevlan);
 544     });
 545     return $bridgevlan;
 546 }
 547
 548 sub tcp_ping {
 549     my ($host, $port, $timeout) = @_;
 550
 551     my $refused = 1;
 552
 553     $timeout = 3 if !$timeout; # sane default
 554     if (!$port) {
 555         # Net::Ping defaults to the echo port
 556         $port = 7;
 557     } else {
 558         # Net::Ping's port_number() implies service_check(1)
 559         $refused = 0;
 560     }
 561
 562     my ($sock, $result);
 563     eval {
 564         $result = PVE::Tools::run_with_timeout($timeout, sub {
 565             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
 566             $result = $refused if $! == ECONNREFUSED;
 567         });
 568     };
 569     if ($sock) {
 570         $sock->close();
 571         $result = 1;
 572     }
 573     return $result;
 574 }
 575
 576 sub IP_from_cidr {
 577     my ($cidr, $version) = @_;
 578
 579     return if $cidr !~ m!^(\S+?)/(\S+)$!;
 580     my ($ip, $prefix) = ($1, $2);
 581
 582     my $ipobj = Net::IP->new($ip, $version);
 583     return if !$ipobj;
 584
 585     $version = $ipobj->version();
 586
 587     my $binmask = Net::IP::ip_get_mask($prefix, $version);
 588     return if !$binmask;
 589
 590     my $masked_binip = $ipobj->binip() & $binmask;
 591     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
 592     return Net::IP->new("$masked_ip/$prefix");
 593 }
 594
 595 sub is_ip_in_cidr {
 596     my ($ip, $cidr, $version) = @_;
 597
 598     my $cidr_obj = IP_from_cidr($cidr, $version);
 599     return undef if !$cidr_obj;
 600
 601     my $ip_obj = Net::IP->new($ip, $version);
 602     return undef if !$ip_obj;
 603
 604     return $cidr_obj->overlaps($ip_obj) == $Net::IP::IP_B_IN_A_OVERLAP;
 605 }
 606
 607
 608 sub get_local_ip_from_cidr {
 609     my ($cidr) = @_;
 610
 611     my $IPs = [];
 612     run_command(['/sbin/ip', 'address', 'show', 'to', $cidr, 'up'], outfunc => sub {
 613         if ($_[0] =~ m!^\s*inet(?:6)?\s+($PVE::Tools::IPRE)(?:/\d+|\s+peer\s+)!) {
 614             push @$IPs, $1;
 615         }
 616     });
 617
 618     return $IPs;
 619 }
 620
 621 sub addr_to_ip {
 622     my ($addr) = @_;
 623     my ($err, $host, $port) = Socket::getnameinfo($addr, NI_NUMERICHOST | NI_NUMERICSERV);
 624     die "failed to get numerical host address: $err\n" if $err;
 625     return ($host, $port) if wantarray;
 626     return $host;
 627 }
 628
 629 sub get_ip_from_hostname {
 630     my ($hostname, $noerr) = @_;
 631
 632     my @res = eval { PVE::Tools::getaddrinfo_all($hostname) };
 633     if ($@) {
 634         die "hostname lookup '$hostname' failed - $@" if !$noerr;
 635         return undef;
 636     }
 637
 638     my ($ip, $family);
 639     for my $ai (@res) {
 640         $family = $ai->{family};
 641         my $tmpip = addr_to_ip($ai->{addr});
 642         if ($tmpip !~ m/^127\.|^::1$/) {
 643             $ip = $tmpip;
 644             last;
 645         }
 646     }
 647     if (!defined($ip) ) {
 648         die "hostname lookup '$hostname' failed - got local IP address '$ip'\n" if !$noerr;
 649         return undef;
 650     }
 651
 652     return wantarray ? ($ip, $family) : $ip;
 653 }
 654
 655 sub lock_network {
 656     my ($code, @param) = @_;
 657     my $res = lock_file('/var/lock/pve-network.lck', 10, $code, @param);
 658     die $@ if $@;
 659     return $res;
 660 }
 661
 662 1;