+sub data_to_text {
+ my ($data) = @_;
+
+ return undef if !defined($data);
+
+ if (my $class = ref($data)) {
+ return to_json($data, { utf8 => 1, canonical => 1 });
+ } else {
+ return "$data";
+ }
+}
+
+# prints a formatted table with a title row.
+# $formatopts is an array of hashes, with the following keys:
+# 'key' - key of $data element to print
+# 'title' - column title, defaults to 'key' - won't get cutoff
+# 'cutoff' - maximal (print) length of this column values, if set
+# the last column will never be cutoff
+# 'default' - optional default value for the column
+# formatopts element order defines column order (left to right)
+# sorts the output according to the leftmost column not containing any undef
+sub print_text_table {
+ my ($formatopts, $data) = @_;
+
+ my ($formatstring, @keys, @titles, %cutoffs, %defaults, $sort_key);
+ my $last_col = $formatopts->[$#{$formatopts}];
+
+ foreach my $col ( @$formatopts ) {
+ my ($key, $title, $cutoff) = @$col{qw(key title cutoff)};
+ $title //= $key;
+
+ push @keys, $key;
+ push @titles, $title;
+ $defaults{$key} = $col->{default} // '';
+
+ # calculate maximal print width and cutoff
+ my $titlelen = length($title);
+
+ my $longest = $titlelen;
+ my $sortable = 1;
+ foreach my $entry (@$data) {
+ my $len = length(data_to_text($entry->{$key})) // 0;
+ $longest = $len if $len > $longest;
+ $sortable = 0 if !defined($entry->{$key});
+ }
+
+ $sort_key //= $key if $sortable;
+ $cutoff = (defined($cutoff) && $cutoff < $longest) ? $cutoff : $longest;
+ $cutoffs{$key} = $cutoff;
+
+ my $printalign = $cutoff > $titlelen ? '-' : '';
+ if ($col == $last_col) {
+ $formatstring .= "%${printalign}${titlelen}s\n";
+ } else {
+ $formatstring .= "%${printalign}${cutoff}s ";
+ }
+ }
+
+ printf $formatstring, @titles;
+
+ if (defined($sort_key)){
+ @$data = sort { $a->{$sort_key} cmp $b->{$sort_key} } @$data;
+ }
+ foreach my $entry (@$data) {
+ printf $formatstring, map { substr((data_to_text($entry->{$_}) // $defaults{$_}), 0 , $cutoffs{$_}) } @keys;
+ }
+}
+
+# prints the result of an API GET call returning an array as a table.
+# takes formatting information from the results property of the call
+# if $props_to_print is provided, prints only those columns. otherwise
+# takes all fields of the results property, with a fallback
+# to all fields occuring in items of $data.
+sub print_api_list {
+ my ($data, $result_schema, $props_to_print) = @_;
+
+ die "can only print object lists\n"
+ if !($result_schema->{type} eq 'array' && $result_schema->{items}->{type} eq 'object');
+
+ my $returnprops = $result_schema->{items}->{properties};
+
+ if (!defined($props_to_print)) {
+ $props_to_print = [ sort keys %$returnprops ];
+ if (!scalar(@$props_to_print)) {
+ my $all_props = {};
+ foreach my $obj (@{$data}) {
+ foreach my $key (keys %{$obj}) {
+ $all_props->{ $key } = 1;
+ }
+ }
+ $props_to_print = [ sort keys %{$all_props} ];
+ }
+ die "unable to detect list properties\n" if !scalar(@$props_to_print);
+ }
+
+ my $formatopts = [];
+ foreach my $prop ( @$props_to_print ) {
+ my $propinfo = $returnprops->{$prop};
+ my $colopts = {
+ key => $prop,
+ title => $propinfo->{title},
+ default => $propinfo->{default},
+ cutoff => $propinfo->{print_width} // $propinfo->{maxLength},
+ };
+ push @$formatopts, $colopts;
+ }
+
+ print_text_table($formatopts, $data);
+}
+
+sub print_api_result {
+ my ($format, $data, $result_schema, $props_to_print) = @_;
+
+ return if $result_schema->{type} eq 'null';
+
+ if ($format eq 'json') {
+ print to_json($data, {utf8 => 1, allow_nonref => 1, canonical => 1, pretty => 1 });
+ } elsif ($format eq 'text') {
+ my $type = $result_schema->{type};
+ if ($type eq 'object') {
+ if (defined($props_to_print)) {
+ foreach my $key (@$props_to_print) {
+ print $key . ": " . data_to_text($data->{$key}) . "\n";
+ }
+ } else {
+ foreach my $key (sort keys %$data) {
+ print $key . ": " . data_to_text($data->{$key}) . "\n";
+ }
+ }
+ } elsif ($type eq 'array') {
+ return if !scalar(@$data);
+ my $item_type = $result_schema->{items}->{type};
+ if ($item_type eq 'object') {
+ print_api_list($data, $result_schema, $props_to_print);
+ } else {
+ foreach my $entry (@$data) {
+ print data_to_text($entry) . "\n";
+ }
+ }
+ } else {
+ print "$data\n";
+ }
+ } else {
+ die "internal error: unknown output format"; # should not happen
+ }
+}
+