[qemu-server.git] / PVE / QemuConfig.pm

package PVE::QemuConfig;

use strict;
use warnings;

use PVE::AbstractConfig;
use PVE::INotify;
use PVE::QemuServer;
use PVE::Storage;
use PVE::Tools;

use base qw(PVE::AbstractConfig);

my $nodename = PVE::INotify::nodename();

mkdir "/etc/pve/nodes/$nodename";
my $confdir = "/etc/pve/nodes/$nodename/qemu-server";
mkdir $confdir;

my $lock_dir = "/var/lock/qemu-server";
mkdir $lock_dir;

my $MAX_UNUSED_DISKS = 256;

# BEGIN implemented abstract methods from PVE::AbstractConfig

sub guest_type {
    return "VM";
}

sub __config_max_unused_disks {
    my ($class) = @_;

    return $MAX_UNUSED_DISKS;
}

sub config_file_lock {
    my ($class, $vmid) = @_;

    return "$lock_dir/lock-$vmid.conf";
}

sub cfs_config_path {
    my ($class, $vmid, $node) = @_;

    $node = $nodename if !$node;
    return "nodes/$node/qemu-server/$vmid.conf";
}

sub has_feature {
    my ($class, $feature, $conf, $storecfg, $snapname, $running, $backup_only) = @_;

    my $err;
    PVE::QemuServer::foreach_drive($conf, sub {
	my ($ds, $drive) = @_;

	return if PVE::QemuServer::drive_is_cdrom($drive);
	return if $backup_only && defined($drive->{backup}) && !$drive->{backup};
	my $volid = $drive->{file};
	$err = 1 if !PVE::Storage::volume_has_feature($storecfg, $feature, $volid, $snapname, $running);
   });

    return $err ? 0 : 1;
}

sub get_replicatable_volumes {
    my ($class, $storecfg, $vmid, $conf, $cleanup, $noerr) = @_;

    my $volhash = {};

    my $test_volid = sub {
	my ($volid, $attr) = @_;

	return if $attr->{cdrom};

	return if !$cleanup && !$attr->{replicate};

	if ($volid =~ m|^/|) {
	    return if !$attr->{replicate};
	    return if $cleanup || $noerr;
	    die "unable to replicate local file/device '$volid'\n";
	}

	my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, $noerr);
	return if !$storeid;

	my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
	return if $scfg->{shared};

	my ($path, $owner, $vtype) = PVE::Storage::path($storecfg, $volid);
	return if !$owner || ($owner != $vmid);

	if ($vtype ne 'images') {
	    return if $cleanup || $noerr;
	    die "unable to replicate volume '$volid', type '$vtype'\n";
	}

	if (!PVE::Storage::volume_has_feature($storecfg, 'replicate', $volid)) {
	    return if $cleanup || $noerr;
	    die "missing replicate feature on volume '$volid'\n";
	}

	$volhash->{$volid} = 1;
    };

    PVE::QemuServer::foreach_volid($conf, $test_volid);

    # add 'unusedX' volumes to volhash
    foreach my $key (keys %$conf) {
	if ($key =~ m/^unused/) {
	    $test_volid->($conf->{$key}, { replicate => 1 });
	}
    }

    return $volhash;
}

sub __snapshot_save_vmstate {
    my ($class, $vmid, $conf, $snapname, $storecfg, $suspend) = @_;

    # first, use explicitly configured storage
    my $target = $conf->{vmstatestorage};

    if (!$target) {
	my ($shared, $local);
	PVE::QemuServer::foreach_storage_used_by_vm($conf, sub {
	    my ($sid) = @_;
	    my $scfg = PVE::Storage::storage_config($storecfg, $sid);
	    my $dst = $scfg->{shared} ? \$shared : \$local;
	    $$dst = $sid if !$$dst || $scfg->{path}; # prefer file based storage
	});

	# second, use shared storage where VM has at least one disk
	# third, use local storage where VM has at least one disk
	# fall back to local storage
	$target = $shared // $local // 'local';
    }

    my $driver_state_size = 500; # assume 500MB is enough to safe all driver state;
    my $size = $conf->{memory}*2 + $driver_state_size;
    my $scfg = PVE::Storage::storage_config($storecfg, $target);

    my $name = "vm-$vmid-state-$snapname";
    $name .= ".raw" if $scfg->{path}; # add filename extension for file base storage

    my $statefile = PVE::Storage::vdisk_alloc($storecfg, $target, $vmid, 'raw', $name, $size*1024);
    my $runningmachine = PVE::QemuServer::get_current_qemu_machine($vmid);

    if ($suspend) {
	$conf->{vmstate} = $statefile;
	$conf->{runningmachine} = $runningmachine;
    } else {
	my $snap = $conf->{snapshots}->{$snapname};
	$snap->{vmstate} = $statefile;
	$snap->{runningmachine} = $runningmachine;
    }

    return $statefile;
}

sub __snapshot_check_running {
    my ($class, $vmid) = @_;
    return PVE::QemuServer::check_running($vmid);
}

sub __snapshot_check_freeze_needed {
    my ($class, $vmid, $config, $save_vmstate) = @_;

    my $running = $class->__snapshot_check_running($vmid);
    if (!$save_vmstate) {
	return ($running, $running && PVE::QemuServer::parse_guest_agent($config)->{enabled} && PVE::QemuServer::qga_check_running($vmid));
    } else {
	return ($running, 0);
    }
}

sub __snapshot_freeze {
    my ($class, $vmid, $unfreeze) = @_;

    if ($unfreeze) {
	eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-thaw"); };
	warn "guest-fsfreeze-thaw problems - $@" if $@;
    } else {
	eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-freeze"); };
	warn "guest-fsfreeze-freeze problems - $@" if $@;
    }
}

sub __snapshot_create_vol_snapshots_hook {
    my ($class, $vmid, $snap, $running, $hook) = @_;

    if ($running) {
	my $storecfg = PVE::Storage::config();

	if ($hook eq "before") {
	    if ($snap->{vmstate}) {
		my $path = PVE::Storage::path($storecfg, $snap->{vmstate});
		PVE::Storage::activate_volumes($storecfg, [$snap->{vmstate}]);

		PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start", statefile => $path);
		for(;;) {
		    my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
		    if (!$stat->{status}) {
			die "savevm not active\n";
		    } elsif ($stat->{status} eq 'active') {
			sleep(1);
			next;
		    } elsif ($stat->{status} eq 'completed') {
			last;
		    } else {
			die "query-savevm returned status '$stat->{status}'\n";
		    }
		}
	    } else {
		PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start");
	    }
	} elsif ($hook eq "after") {
	    eval { 
		PVE::QemuServer::vm_mon_cmd($vmid, "savevm-end");
		PVE::Storage::deactivate_volumes($storecfg, [$snap->{vmstate}]) if $snap->{vmstate};
	    };
	    warn $@ if $@;
	} elsif ($hook eq "after-freeze") {
	    # savevm-end is async, we need to wait
	    for (;;) {
		my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
		if (!$stat->{bytes}) {
		    last;
		} else {
		    print "savevm not yet finished\n";
		    sleep(1);
		    next;
		}
	    }
	}
    }
}

sub __snapshot_create_vol_snapshot {
    my ($class, $vmid, $ds, $drive, $snapname) = @_;

    return if PVE::QemuServer::drive_is_cdrom($drive);

    my $volid = $drive->{file};
    my $device = "drive-$ds";
    my $storecfg = PVE::Storage::config();

    PVE::QemuServer::qemu_volume_snapshot($vmid, $device, $storecfg, $volid, $snapname);
}

sub __snapshot_delete_remove_drive {
    my ($class, $snap, $remove_drive) = @_;

    if ($remove_drive eq 'vmstate') {
	delete $snap->{$remove_drive};
    } else {
	my $drive = PVE::QemuServer::parse_drive($remove_drive, $snap->{$remove_drive});
	return if PVE::QemuServer::drive_is_cdrom($drive);

	my $volid = $drive->{file};
	delete $snap->{$remove_drive};
	$class->add_unused_volume($snap, $volid);
    }
}

sub __snapshot_delete_vmstate_file {
    my ($class, $snap, $force) = @_;

    my $storecfg = PVE::Storage::config();

    eval {  PVE::Storage::vdisk_free($storecfg, $snap->{vmstate}); };
    if (my $err = $@) {
	die $err if !$force;
	warn $err;
    }
}

sub __snapshot_delete_vol_snapshot {
    my ($class, $vmid, $ds, $drive, $snapname, $unused) = @_;

    return if PVE::QemuServer::drive_is_cdrom($drive);
    my $storecfg = PVE::Storage::config();
    my $volid = $drive->{file};
    my $device = "drive-$ds";

    PVE::QemuServer::qemu_volume_snapshot_delete($vmid, $device, $storecfg, $volid, $snapname);

    push @$unused, $volid;
}

sub __snapshot_rollback_hook {
    my ($class, $vmid, $conf, $snap, $prepare, $data) = @_;

    if ($prepare) {
	# we save the machine of the current config
	$data->{oldmachine} = $conf->{machine};
    } else {
	# if we have a 'runningmachine' entry in the snapshot we use that
	# for the forcemachine parameter, else we use the old logic
	if (defined($conf->{runningmachine})) {
	    $data->{forcemachine} = $conf->{runningmachine};
	    delete $conf->{runningmachine};
	} else {
	    # Note: old code did not store 'machine', so we try to be smart
	    # and guess the snapshot was generated with kvm 1.4 (pc-i440fx-1.4).
	    $data->{forcemachine} = $conf->{machine} || 'pc-i440fx-1.4';

	    # we remove the 'machine' configuration if not explicitly specified
	    # in the original config.
	    delete $conf->{machine} if $snap->{vmstate} && !defined($data->{oldmachine});
	}

	if ($conf->{vmgenid}) {
	    # tell the VM that it's another generation, so it can react
	    # appropriately, e.g. dirty-mark copies of distributed databases or
	    # re-initializing its random number generator
	    $conf->{vmgenid} = PVE::QemuServer::generate_uuid();
	}
    }

    return;
}

sub __snapshot_rollback_vol_possible {
    my ($class, $drive, $snapname) = @_;

    return if PVE::QemuServer::drive_is_cdrom($drive);

    my $storecfg = PVE::Storage::config();
    my $volid = $drive->{file};

    PVE::Storage::volume_rollback_is_possible($storecfg, $volid, $snapname);
}

sub __snapshot_rollback_vol_rollback {
    my ($class, $drive, $snapname) = @_;

    return if PVE::QemuServer::drive_is_cdrom($drive);

    my $storecfg = PVE::Storage::config();
    PVE::Storage::volume_snapshot_rollback($storecfg, $drive->{file}, $snapname);
}

sub __snapshot_rollback_vm_stop {
    my ($class, $vmid) = @_;

    my $storecfg = PVE::Storage::config();
    PVE::QemuServer::vm_stop($storecfg, $vmid, undef, undef, 5, undef, undef);
}

sub __snapshot_rollback_vm_start {
    my ($class, $vmid, $vmstate, $data) = @_;

    my $storecfg = PVE::Storage::config();
    my $statefile = PVE::Storage::path($storecfg, $vmstate);
    PVE::QemuServer::vm_start($storecfg, $vmid, $statefile, undef, undef, undef, $data->{forcemachine});
}

sub __snapshot_rollback_get_unused {
    my ($class, $conf, $snap) = @_;

    my $unused = [];

    $class->__snapshot_foreach_volume($conf, sub {
	my ($vs, $volume) = @_;

	return if PVE::QemuServer::drive_is_cdrom($volume);

	my $found = 0;
	my $volid = $volume->{file};

	$class->__snapshot_foreach_volume($snap, sub {
	    my ($ds, $drive) = @_;

	    return if $found;
	    return if PVE::QemuServer::drive_is_cdrom($drive);

	    $found = 1
		if ($drive->{file} && $drive->{file} eq $volid);
	});

	push @$unused, $volid if !$found;
    });

    return $unused;
}

sub __snapshot_foreach_volume {
    my ($class, $conf, $func) = @_;

    PVE::QemuServer::foreach_drive($conf, $func);
}
# END implemented abstract methods from PVE::AbstractConfig

1;
Commit	Line	Data
ffda963f FG	1	package PVE::QemuConfig;
	2
	3	use strict;
	4	use warnings;
	5
b2c9558d FG	6	use PVE::AbstractConfig;
	7	use PVE::INotify;
	8	use PVE::QemuServer;
	9	use PVE::Storage;
	10	use PVE::Tools;
	11
ffda963f FG	12	use base qw(PVE::AbstractConfig);
	13
	14	my $nodename = PVE::INotify::nodename();
	15
	16	mkdir "/etc/pve/nodes/$nodename";
	17	my $confdir = "/etc/pve/nodes/$nodename/qemu-server";
	18	mkdir $confdir;
	19
	20	my $lock_dir = "/var/lock/qemu-server";
	21	mkdir $lock_dir;
	22
c9db2240	23	my $MAX_UNUSED_DISKS = 256;
ffda963f FG	24
	25	# BEGIN implemented abstract methods from PVE::AbstractConfig
	26
	27	sub guest_type {
	28	return "VM";
	29	}
	30
	31	sub __config_max_unused_disks {
3aa44d3b	32	my ($class) = @_;
ffda963f FG	33
	34	return $MAX_UNUSED_DISKS;
	35	}
	36
	37	sub config_file_lock {
	38	my ($class, $vmid) = @_;
	39
	40	return "$lock_dir/lock-$vmid.conf";
	41	}
	42
	43	sub cfs_config_path {
	44	my ($class, $vmid, $node) = @_;
	45
	46	$node = $nodename if !$node;
	47	return "nodes/$node/qemu-server/$vmid.conf";
	48	}
	49
b2c9558d FG	50	sub has_feature {
	51	my ($class, $feature, $conf, $storecfg, $snapname, $running, $backup_only) = @_;
	52
	53	my $err;
	54	PVE::QemuServer::foreach_drive($conf, sub {
	55	my ($ds, $drive) = @_;
	56
	57	return if PVE::QemuServer::drive_is_cdrom($drive);
5282865b	58	return if $backup_only && defined($drive->{backup}) && !$drive->{backup};
b2c9558d FG	59	my $volid = $drive->{file};
	60	$err = 1 if !PVE::Storage::volume_has_feature($storecfg, $feature, $volid, $snapname, $running);
	61	});
	62
	63	return $err ? 0 : 1;
	64	}
	65
3aa44d3b	66	sub get_replicatable_volumes {
c78f43b9	67	my ($class, $storecfg, $vmid, $conf, $cleanup, $noerr) = @_;
3aa44d3b DM	68
	69	my $volhash = {};
	70
	71	my $test_volid = sub {
f949eb77	72	my ($volid, $attr) = @_;
3aa44d3b	73
a6cb40f7 DM	74	return if $attr->{cdrom};
	75
	76	return if !$cleanup && !$attr->{replicate};
	77
4ab3bcc8 DM	78	if ($volid =~ m\|^/\|) {
4ab3bcc8 DM	79	return if !$attr->{replicate};
a6cb40f7	80	return if $cleanup \|\| $noerr;
4ab3bcc8 DM	81	die "unable to replicate local file/device '$volid'\n";
	82	}
	83
a722d4ff DM	84	my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, $noerr);
	85	return if !$storeid;
	86
6f249d94	87	my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
a722d4ff DM	88	return if $scfg->{shared};
a722d4ff DM	89
f7e7767f DM	90	my ($path, $owner, $vtype) = PVE::Storage::path($storecfg, $volid);
	91	return if !$owner \|\| ($owner != $vmid);
	92
a6cb40f7 DM	93	if ($vtype ne 'images') {
	94	return if $cleanup \|\| $noerr;
	95	die "unable to replicate volume '$volid', type '$vtype'\n";
	96	}
3aa44d3b DM	97
3aa44d3b DM	98	if (!PVE::Storage::volume_has_feature($storecfg, 'replicate', $volid)) {
e5857ca8	99	return if $cleanup \|\| $noerr;
3aa44d3b DM	100	die "missing replicate feature on volume '$volid'\n";
	101	}
	102
	103	$volhash->{$volid} = 1;
	104	};
	105
f949eb77	106	PVE::QemuServer::foreach_volid($conf, $test_volid);
3aa44d3b	107
8299257e DM	108	# add 'unusedX' volumes to volhash
	109	foreach my $key (keys %$conf) {
	110	if ($key =~ m/^unused/) {
	111	$test_volid->($conf->{$key}, { replicate => 1 });
	112	}
	113	}
	114
3aa44d3b DM	115	return $volhash;
	116	}
	117
b2c9558d	118	sub __snapshot_save_vmstate {
159719e5	119	my ($class, $vmid, $conf, $snapname, $storecfg, $suspend) = @_;
b2c9558d	120
2eeb0c93 FG	121	# first, use explicitly configured storage
2eeb0c93 FG	122	my $target = $conf->{vmstatestorage};
b2c9558d FG	123
b2c9558d FG	124	if (!$target) {
2eeb0c93	125	my ($shared, $local);
65a5ce88	126	PVE::QemuServer::foreach_storage_used_by_vm($conf, sub {
b2c9558d FG	127	my ($sid) = @_;
b2c9558d FG	128	my $scfg = PVE::Storage::storage_config($storecfg, $sid);
2eeb0c93 FG	129	my $dst = $scfg->{shared} ? \$shared : \$local;
2eeb0c93 FG	130	$$dst = $sid if !$$dst \|\| $scfg->{path}; # prefer file based storage
b2c9558d	131	});
b2c9558d	132
2eeb0c93 FG	133	# second, use shared storage where VM has at least one disk
	134	# third, use local storage where VM has at least one disk
	135	# fall back to local storage
	136	$target = $shared // $local // 'local';
	137	}
b2c9558d	138
566caaa4	139	my $driver_state_size = 500; # assume 500MB is enough to safe all driver state;
b2c9558d	140	my $size = $conf->{memory}*2 + $driver_state_size;
159719e5	141	my $scfg = PVE::Storage::storage_config($storecfg, $target);
b2c9558d FG	142
b2c9558d FG	143	my $name = "vm-$vmid-state-$snapname";
b2c9558d	144	$name .= ".raw" if $scfg->{path}; # add filename extension for file base storage
159719e5 DC	145
	146	my $statefile = PVE::Storage::vdisk_alloc($storecfg, $target, $vmid, 'raw', $name, $size*1024);
	147	my $runningmachine = PVE::QemuServer::get_current_qemu_machine($vmid);
	148
	149	if ($suspend) {
	150	$conf->{vmstate} = $statefile;
	151	$conf->{runningmachine} = $runningmachine;
	152	} else {
	153	my $snap = $conf->{snapshots}->{$snapname};
	154	$snap->{vmstate} = $statefile;
	155	$snap->{runningmachine} = $runningmachine;
	156	}
	157
	158	return $statefile;
b2c9558d FG	159	}
	160
	161	sub __snapshot_check_running {
	162	my ($class, $vmid) = @_;
	163	return PVE::QemuServer::check_running($vmid);
	164	}
	165
	166	sub __snapshot_check_freeze_needed {
	167	my ($class, $vmid, $config, $save_vmstate) = @_;
	168
	169	my $running = $class->__snapshot_check_running($vmid);
278e2c9d	170	if (!$save_vmstate) {
9d66b397	171	return ($running, $running && PVE::QemuServer::parse_guest_agent($config)->{enabled} && PVE::QemuServer::qga_check_running($vmid));
b2c9558d FG	172	} else {
	173	return ($running, 0);
	174	}
	175	}
	176
	177	sub __snapshot_freeze {
	178	my ($class, $vmid, $unfreeze) = @_;
	179
	180	if ($unfreeze) {
	181	eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-thaw"); };
	182	warn "guest-fsfreeze-thaw problems - $@" if $@;
	183	} else {
	184	eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-freeze"); };
	185	warn "guest-fsfreeze-freeze problems - $@" if $@;
	186	}
	187	}
	188
	189	sub __snapshot_create_vol_snapshots_hook {
	190	my ($class, $vmid, $snap, $running, $hook) = @_;
	191
	192	if ($running) {
3a8deb55 AD	193	my $storecfg = PVE::Storage::config();
3a8deb55 AD	194
b2c9558d FG	195	if ($hook eq "before") {
b2c9558d FG	196	if ($snap->{vmstate}) {
b2c9558d	197	my $path = PVE::Storage::path($storecfg, $snap->{vmstate});
3a8deb55 AD	198	PVE::Storage::activate_volumes($storecfg, [$snap->{vmstate}]);
3a8deb55 AD	199
b2c9558d FG	200	PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start", statefile => $path);
	201	for(;;) {
	202	my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
	203	if (!$stat->{status}) {
	204	die "savevm not active\n";
	205	} elsif ($stat->{status} eq 'active') {
	206	sleep(1);
	207	next;
	208	} elsif ($stat->{status} eq 'completed') {
	209	last;
	210	} else {
	211	die "query-savevm returned status '$stat->{status}'\n";
	212	}
	213	}
	214	} else {
	215	PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start");
	216	}
	217	} elsif ($hook eq "after") {
3a8deb55 AD	218	eval {
	219	PVE::QemuServer::vm_mon_cmd($vmid, "savevm-end");
	220	PVE::Storage::deactivate_volumes($storecfg, [$snap->{vmstate}]) if $snap->{vmstate};
	221	};
b2c9558d FG	222	warn $@ if $@;
	223	} elsif ($hook eq "after-freeze") {
	224	# savevm-end is async, we need to wait
	225	for (;;) {
	226	my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
	227	if (!$stat->{bytes}) {
	228	last;
	229	} else {
	230	print "savevm not yet finished\n";
	231	sleep(1);
	232	next;
	233	}
	234	}
	235	}
	236	}
	237	}
	238
	239	sub __snapshot_create_vol_snapshot {
	240	my ($class, $vmid, $ds, $drive, $snapname) = @_;
	241
	242	return if PVE::QemuServer::drive_is_cdrom($drive);
	243
	244	my $volid = $drive->{file};
	245	my $device = "drive-$ds";
	246	my $storecfg = PVE::Storage::config();
	247
	248	PVE::QemuServer::qemu_volume_snapshot($vmid, $device, $storecfg, $volid, $snapname);
	249	}
	250
	251	sub __snapshot_delete_remove_drive {
	252	my ($class, $snap, $remove_drive) = @_;
	253
	254	if ($remove_drive eq 'vmstate') {
	255	delete $snap->{$remove_drive};
	256	} else {
	257	my $drive = PVE::QemuServer::parse_drive($remove_drive, $snap->{$remove_drive});
	258	return if PVE::QemuServer::drive_is_cdrom($drive);
	259
	260	my $volid = $drive->{file};
	261	delete $snap->{$remove_drive};
	262	$class->add_unused_volume($snap, $volid);
	263	}
	264	}
	265
	266	sub __snapshot_delete_vmstate_file {
	267	my ($class, $snap, $force) = @_;
	268
	269	my $storecfg = PVE::Storage::config();
	270
	271	eval { PVE::Storage::vdisk_free($storecfg, $snap->{vmstate}); };
	272	if (my $err = $@) {
	273	die $err if !$force;
	274	warn $err;
	275	}
	276	}
	277
	278	sub __snapshot_delete_vol_snapshot {
	279	my ($class, $vmid, $ds, $drive, $snapname, $unused) = @_;
	280
	281	return if PVE::QemuServer::drive_is_cdrom($drive);
	282	my $storecfg = PVE::Storage::config();
	283	my $volid = $drive->{file};
	284	my $device = "drive-$ds";
	285
286	PVE::QemuServer::qemu_volume_snapshot_delete($vmid, $device, $storecfg, $volid, $snapname);
287
288	push @$unused, $volid;
289	}
290
58b1a8d7 DC	291	sub __snapshot_rollback_hook {
	292	my ($class, $vmid, $conf, $snap, $prepare, $data) = @_;
	293
	294	if ($prepare) {
	295	# we save the machine of the current config
	296	$data->{oldmachine} = $conf->{machine};
	297	} else {
e6d35c71 TL	298	# if we have a 'runningmachine' entry in the snapshot we use that
e6d35c71 TL	299	# for the forcemachine parameter, else we use the old logic
c6737ef1 DC	300	if (defined($conf->{runningmachine})) {
	301	$data->{forcemachine} = $conf->{runningmachine};
	302	delete $conf->{runningmachine};
	303	} else {
	304	# Note: old code did not store 'machine', so we try to be smart
	305	# and guess the snapshot was generated with kvm 1.4 (pc-i440fx-1.4).
	306	$data->{forcemachine} = $conf->{machine} \|\| 'pc-i440fx-1.4';
	307
	308	# we remove the 'machine' configuration if not explicitly specified
	309	# in the original config.
	310	delete $conf->{machine} if $snap->{vmstate} && !defined($data->{oldmachine});
	311	}
6ee499ff DC	312
6ee499ff DC	313	if ($conf->{vmgenid}) {
4f4d9772 TL	314	# tell the VM that it's another generation, so it can react
	315	# appropriately, e.g. dirty-mark copies of distributed databases or
	316	# re-initializing its random number generator
6ee499ff DC	317	$conf->{vmgenid} = PVE::QemuServer::generate_uuid();
6ee499ff DC	318	}
58b1a8d7 DC	319	}
	320
	321	return;
	322	}
	323
b2c9558d FG	324	sub __snapshot_rollback_vol_possible {
	325	my ($class, $drive, $snapname) = @_;
	326
	327	return if PVE::QemuServer::drive_is_cdrom($drive);
	328
	329	my $storecfg = PVE::Storage::config();
	330	my $volid = $drive->{file};
	331
	332	PVE::Storage::volume_rollback_is_possible($storecfg, $volid, $snapname);
	333	}
	334
	335	sub __snapshot_rollback_vol_rollback {
	336	my ($class, $drive, $snapname) = @_;
	337
	338	return if PVE::QemuServer::drive_is_cdrom($drive);
	339
	340	my $storecfg = PVE::Storage::config();
	341	PVE::Storage::volume_snapshot_rollback($storecfg, $drive->{file}, $snapname);
	342	}
	343
	344	sub __snapshot_rollback_vm_stop {
	345	my ($class, $vmid) = @_;
	346
	347	my $storecfg = PVE::Storage::config();
	348	PVE::QemuServer::vm_stop($storecfg, $vmid, undef, undef, 5, undef, undef);
	349	}
	350
	351	sub __snapshot_rollback_vm_start {
58b1a8d7	352	my ($class, $vmid, $vmstate, $data) = @_;
b2c9558d FG	353
	354	my $storecfg = PVE::Storage::config();
	355	my $statefile = PVE::Storage::path($storecfg, $vmstate);
58b1a8d7	356	PVE::QemuServer::vm_start($storecfg, $vmid, $statefile, undef, undef, undef, $data->{forcemachine});
b2c9558d FG	357	}
b2c9558d FG	358
c4a54ed5 FG	359	sub __snapshot_rollback_get_unused {
	360	my ($class, $conf, $snap) = @_;
	361
	362	my $unused = [];
	363
	364	$class->__snapshot_foreach_volume($conf, sub {
	365	my ($vs, $volume) = @_;
	366
	367	return if PVE::QemuServer::drive_is_cdrom($volume);
	368
	369	my $found = 0;
	370	my $volid = $volume->{file};
	371
	372	$class->__snapshot_foreach_volume($snap, sub {
	373	my ($ds, $drive) = @_;
	374
	375	return if $found;
	376	return if PVE::QemuServer::drive_is_cdrom($drive);
	377
	378	$found = 1
	379	if ($drive->{file} && $drive->{file} eq $volid);
	380	});
	381
	382	push @$unused, $volid if !$found;
	383	});
	384
	385	return $unused;
	386	}
	387
b2c9558d FG	388	sub __snapshot_foreach_volume {
	389	my ($class, $conf, $func) = @_;
	390
	391	PVE::QemuServer::foreach_drive($conf, $func);
	392	}
ffda963f FG	393	# END implemented abstract methods from PVE::AbstractConfig
	394
	395	1;