[qemu-server.git] / PVE / QemuServer / Cloudinit.pm

package PVE::QemuServer::Cloudinit;

use strict;
use warnings;

use File::Path;
use Digest::SHA;
use URI::Escape;

use PVE::Tools qw(run_command file_set_contents);
use PVE::Storage;
use PVE::QemuServer;

sub commit_cloudinit_disk {
    my ($vmid, $conf, $drive, $volname, $storeid, $files, $label) = @_;

    my $path = "/run/pve/cloudinit/$vmid/";
    mkpath $path;
    foreach my $filepath (keys %$files) {
	if ($filepath !~ m@^(.*)\/[^/]+$@) {
	    die "internal error: bad file name in cloud-init image: $filepath\n";
	}
	my $dirname = $1;
	mkpath "$path/$dirname";

	my $contents = $files->{$filepath};
	file_set_contents("$path/$filepath", $contents);
    }

    my $storecfg = PVE::Storage::config();
    my $iso_path = PVE::Storage::path($storecfg, $drive->{file});
    my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
    my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);

    my $size = PVE::Storage::file_size_info($iso_path);

    eval {
	run_command([['genisoimage', '-R', '-V', $label, $path],
		     ['qemu-img', 'dd', '-f', 'raw', '-O', $format,
		      'isize=0', "osize=$size", "of=$iso_path"]]);
    };
    my $err = $@;
    rmtree($path);
    die $err if $err;
}

sub get_cloudinit_format {
    my ($conf) = @_;
    if (defined(my $format = $conf->{citype})) {
	return $format;
    }

    # No format specified, default based on ostype because windows'
    # cloudbased-init only supports configdrivev2, whereas on linux we need
    # to use mac addresses because regular cloudinit doesn't map 'ethX' to
    # the new predicatble network device naming scheme.
    if (defined(my $ostype = $conf->{ostype})) {
	return 'configdrive2'
	    if PVE::QemuServer::windows_version($ostype);
    }

    return 'nocloud';
}

sub get_hostname_fqdn {
    my ($conf, $vmid) = @_;
    my $hostname = $conf->{name} // "VM$vmid";
    my $fqdn;
    if ($hostname =~ /\./) {
	$fqdn = $hostname;
	$hostname =~ s/\..*$//;
    } elsif (my $search = $conf->{searchdomain}) {
	$fqdn = "$hostname.$search";
    }
    return ($hostname, $fqdn);
}

sub get_dns_conf {
    my ($conf) = @_;

    # Same logic as in pve-container, but without the testcase special case
    my $host_resolv_conf = PVE::INotify::read_file('resolvconf');

    my $searchdomains = [
	split(/\s+/, $conf->{searchdomain} // $host_resolv_conf->{search})
    ];

    my $nameserver = $conf->{nameserver};
    if (!defined($nameserver)) {
	$nameserver = [grep { $_ } $host_resolv_conf->@{qw(dns1 dns2 dns3)}];
    } else {
	$nameserver = [split(/\s+/, $nameserver)];
    }

    return ($searchdomains, $nameserver);
}

sub cloudinit_userdata {
    my ($conf, $vmid) = @_;

    my ($hostname, $fqdn) = get_hostname_fqdn($conf, $vmid);

    my $content = "#cloud-config\n";

    $content .= "hostname: $hostname\n";
    $content .= "fqdn: $fqdn\n" if defined($fqdn);

    my $username = $conf->{ciuser};
    my $password = $conf->{cipassword};

    $content .= "user: $username\n" if defined($username);
    $content .= "disable_root: False\n" if defined($username) && $username eq 'root';
    $content .= "password: $password\n" if defined($password);

    if (defined(my $keys = $conf->{sshkeys})) {
	$keys = URI::Escape::uri_unescape($keys);
	$keys = [map { chomp $_; $_ } split(/\n/, $keys)];
	$keys = [grep { /\S/ } @$keys];
	$content .= "ssh_authorized_keys:\n";
	foreach my $k (@$keys) {
	    $content .= "  - $k\n";
	}
    }
    $content .= "chpasswd:\n";
    $content .= "  expire: False\n";

    if (!defined($username) || $username ne 'root') {
	$content .= "users:\n";
	$content .= "  - default\n";
    }

    $content .= "package_upgrade: true\n";

    return $content;
}

sub configdrive2_network {
    my ($conf) = @_;

    my $content = "auto lo\n";
    $content .= "iface lo inet loopback\n\n";

    my ($searchdomains, $nameservers) = get_dns_conf($conf);
    if ($nameservers && @$nameservers) {
	$nameservers = join(' ', @$nameservers);
	$content .= "        dns_nameservers $nameservers\n";
    }
    if ($searchdomains && @$searchdomains) {
	$searchdomains = join(' ', @$searchdomains);
	$content .= "        dns_search $searchdomains\n";
    }

    my @ifaces = grep(/^net(\d+)$/, keys %$conf);
    foreach my $iface (@ifaces) {
	(my $id = $iface) =~ s/^net//;
	next if !$conf->{"ipconfig$id"};
	my $net = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
	$id = "eth$id";

	$content .="auto $id\n";
	if ($net->{ip}) {
	    if ($net->{ip} eq 'dhcp') {
		$content .= "iface $id inet dhcp\n";
	    } else {
		my ($addr, $mask) = split('/', $net->{ip});
		$content .= "iface $id inet static\n";
		$content .= "        address $addr\n";
		$content .= "        netmask $PVE::Network::ipv4_reverse_mask->[$mask]\n";
		$content .= "        gateway $net->{gw}\n" if $net->{gw};
	    }
	}
	if ($net->{ip6}) {
	    if ($net->{ip6} =~ /^(auto|dhcp)$/) {
		$content .= "iface $id inet6 $1\n";
	    } else {
		my ($addr, $mask) = split('/', $net->{ip6});
		$content .= "iface $id inet6 static\n";
		$content .= "        address $addr\n";
		$content .= "        netmask $mask\n";
		$content .= "        gateway $net->{gw6}\n" if $net->{gw6};
	    }
	}
    }

    return $content;
}

sub configdrive2_metadata {
    my ($uuid) = @_;
    return <<"EOF";
{
     "uuid": "$uuid",
     "network_config": { "content_path": "/content/0000" }
}
EOF
}

sub generate_configdrive2 {
    my ($conf, $vmid, $drive, $volname, $storeid) = @_;

    my $user_data = cloudinit_userdata($conf, $vmid);
    my $network_data = configdrive2_network($conf);

    my $digest_data = $user_data . $network_data;
    my $uuid_str = Digest::SHA::sha1_hex($digest_data);

    my $meta_data = configdrive2_metadata($uuid_str);

    my $files = {
	'/openstack/latest/user_data' => $user_data,
	'/openstack/content/0000' => $network_data,
	'/openstack/latest/meta_data.json' => $meta_data
    };
    commit_cloudinit_disk($vmid, $conf, $drive, $volname, $storeid, $files, 'config-2');
}

sub nocloud_network_v2 {
    my ($conf) = @_;

    my $content = '';

    my $head = "version: 2\n"
             . "ethernets:\n";

    my $dns_done;

    my @ifaces = grep(/^net(\d+)$/, keys %$conf);
    foreach my $iface (@ifaces) {
	(my $id = $iface) =~ s/^net//;
	next if !$conf->{"ipconfig$id"};

	# indentation - network interfaces are inside an 'ethernets' hash
	my $i = '    ';

	my $net = PVE::QemuServer::parse_net($conf->{$iface});
	my $ipconfig = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});

	my $mac = $net->{macaddr}
	    or die "network interface '$iface' has no mac address\n";

	$content .= "${i}$iface:\n";
	$i .= '    ';
	$content .= "${i}match:\n"
	         . "${i}    macaddress: \"$mac\"\n"
	         . "${i}set-name: eth$id\n";
	my @addresses;
	if (defined(my $ip = $ipconfig->{ip})) {
	    if ($ip eq 'dhcp') {
		$content .= "${i}dhcp4: true\n";
	    } else {
		push @addresses, $ip;
	    }
	}
	if (defined(my $ip = $ipconfig->{ip6})) {
	    if ($ip eq 'dhcp') {
		$content .= "${i}dhcp6: true\n";
	    } else {
		push @addresses, $ip;
	    }
	}
	if (@addresses) {
	    $content .= "${i}addresses:\n";
	    $content .= "${i}- $_\n" foreach @addresses;
	}
	if (defined(my $gw = $ipconfig->{gw})) {
	    $content .= "${i}gateway4: $gw\n";
	}
	if (defined(my $gw = $ipconfig->{gw6})) {
	    $content .= "${i}gateway6: $gw\n";
	}

	next if $dns_done;
	$dns_done = 1;

	my ($searchdomains, $nameservers) = get_dns_conf($conf);
	if ($searchdomains || $nameservers) {
	    $content .= "${i}nameservers:\n";
	    if (defined($nameservers) && @$nameservers) {
		$content .= "${i}  addresses:\n";
		$content .= "${i}  - $_\n" foreach @$nameservers;
	    }
	    if (defined($searchdomains) && @$searchdomains) {
		$content .= "${i}  search:\n";
		$content .= "${i}  - $_\n" foreach @$searchdomains;
	    }
	}
    }

    return $head.$content;
}

sub nocloud_network {
    my ($conf) = @_;

    my $content = "version: 1\n"
                . "config:\n";

    my @ifaces = grep(/^net(\d+)$/, keys %$conf);
    foreach my $iface (@ifaces) {
	(my $id = $iface) =~ s/^net//;
	next if !$conf->{"ipconfig$id"};

	# indentation - network interfaces are inside an 'ethernets' hash
	my $i = '    ';

	my $net = PVE::QemuServer::parse_net($conf->{$iface});
	my $ipconfig = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});

	my $mac = $net->{macaddr}
	    or die "network interface '$iface' has no mac address\n";

	$content .= "${i}- type: physical\n"
	          . "${i}  name: eth$id\n"
	          . "${i}  mac_address: $mac\n"
	          . "${i}  subnets:\n";
	$i .= '  ';
	if (defined(my $ip = $ipconfig->{ip})) {
	    if ($ip eq 'dhcp') {
		$content .= "${i}- type: dhcp4\n";
	    } else {
		$content .= "${i}- type: static\n"
		       . "${i}  address: $ip\n";
		if (defined(my $gw = $ipconfig->{gw})) {
		    $content .= "${i}  gateway: $gw\n";
		}
	    }
	}
	if (defined(my $ip = $ipconfig->{ip6})) {
	    if ($ip eq 'dhcp') {
		$content .= "${i}- type: dhcp6\n";
	    } else {
		$content .= "${i}- type: static6\n"
		       . "${i}  address: $ip\n";
		if (defined(my $gw = $ipconfig->{gw6})) {
		    $content .= "${i}  gateway: $gw\n";
		}
	    }
	}
    }

    my $i = '    ';
    my ($searchdomains, $nameservers) = get_dns_conf($conf);
    if ($searchdomains || $nameservers) {
	$content .= "${i}- type: nameserver\n";
	if (defined($nameservers) && @$nameservers) {
	    $content .= "${i}  address:\n";
	    $content .= "${i}  - $_\n" foreach @$nameservers;
	}
	if (defined($searchdomains) && @$searchdomains) {
	    $content .= "${i}  search:\n";
	    $content .= "${i}  - $_\n" foreach @$searchdomains;
	}
    }

    return $content;
}

sub nocloud_metadata {
    my ($uuid) = @_;
    return "instance-id: $uuid\n";
}

sub generate_nocloud {
    my ($conf, $vmid, $drive, $volname, $storeid) = @_;

    my $user_data = cloudinit_userdata($conf, $vmid);
    my $network_data = nocloud_network($conf);

    my $digest_data = $user_data . $network_data;
    my $uuid_str = Digest::SHA::sha1_hex($digest_data);

    my $meta_data = nocloud_metadata($uuid_str);

    my $files = {
	'/user-data' => $user_data,
	'/network-config' => $network_data,
	'/meta-data' => $meta_data
    };
    commit_cloudinit_disk($vmid, $conf, $drive, $volname, $storeid, $files, 'cidata');
}

my $cloudinit_methods = {
    configdrive2 => \&generate_configdrive2,
    nocloud => \&generate_nocloud,
};

sub generate_cloudinitconfig {
    my ($conf, $vmid) = @_;

    my $format = get_cloudinit_format($conf);

    PVE::QemuServer::foreach_drive($conf, sub {
        my ($ds, $drive) = @_;

	my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file}, 1);

	return if !$volname || $volname !~ m/vm-$vmid-cloudinit/;

	my $generator = $cloudinit_methods->{$format}
	    or die "missing cloudinit methods for format '$format'\n";

	$generator->($conf, $vmid, $drive, $volname, $storeid);
    });
}

1;
Commit	Line	Data
0c9a7596 AD	1	package PVE::QemuServer::Cloudinit;
	2
	3	use strict;
	4	use warnings;
	5
	6	use File::Path;
	7	use Digest::SHA;
	8	use URI::Escape;
	9
	10	use PVE::Tools qw(run_command file_set_contents);
	11	use PVE::Storage;
	12	use PVE::QemuServer;
	13
0c9a7596	14	sub commit_cloudinit_disk {
f62c36cf WB	15	my ($vmid, $conf, $drive, $volname, $storeid, $files, $label) = @_;
	16
	17	my $path = "/run/pve/cloudinit/$vmid/";
	18	mkpath $path;
	19	foreach my $filepath (keys %$files) {
	20	if ($filepath !~ m@^(.*)\/[^/]+$@) {
	21	die "internal error: bad file name in cloud-init image: $filepath\n";
	22	}
	23	my $dirname = $1;
	24	mkpath "$path/$dirname";
	25
	26	my $contents = $files->{$filepath};
	27	file_set_contents("$path/$filepath", $contents);
	28	}
41cd94a0 WB	29
	30	my $storecfg = PVE::Storage::config();
	31	my $iso_path = PVE::Storage::path($storecfg, $drive->{file});
	32	my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
	33	my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
0c9a7596	34
3db6e4ab	35	my $size = PVE::Storage::file_size_info($iso_path);
0c9a7596	36
f62c36cf WB	37	eval {
	38	run_command([['genisoimage', '-R', '-V', $label, $path],
	39	['qemu-img', 'dd', '-f', 'raw', '-O', $format,
	40	'isize=0', "osize=$size", "of=$iso_path"]]);
	41	};
	42	my $err = $@;
	43	rmtree($path);
	44	die $err if $err;
0c9a7596 AD	45	}
0c9a7596 AD	46
41cd94a0 WB	47	sub get_cloudinit_format {
	48	my ($conf) = @_;
	49	if (defined(my $format = $conf->{citype})) {
	50	return $format;
	51	}
0c9a7596	52
41cd94a0 WB	53	# No format specified, default based on ostype because windows'
	54	# cloudbased-init only supports configdrivev2, whereas on linux we need
	55	# to use mac addresses because regular cloudinit doesn't map 'ethX' to
	56	# the new predicatble network device naming scheme.
	57	if (defined(my $ostype = $conf->{ostype})) {
	58	return 'configdrive2'
	59	if PVE::QemuServer::windows_version($ostype);
	60	}
0c9a7596	61
41cd94a0	62	return 'nocloud';
0c9a7596 AD	63	}
0c9a7596 AD	64
e8ac2138	65	sub get_hostname_fqdn {
9a6ccb12 DC	66	my ($conf, $vmid) = @_;
9a6ccb12 DC	67	my $hostname = $conf->{name} // "VM$vmid";
e8ac2138 WB	68	my $fqdn;
	69	if ($hostname =~ /\./) {
	70	$fqdn = $hostname;
	71	$hostname =~ s/\..*$//;
	72	} elsif (my $search = $conf->{searchdomain}) {
	73	$fqdn = "$hostname.$search";
0c9a7596	74	}
e8ac2138	75	return ($hostname, $fqdn);
41cd94a0 WB	76	}
41cd94a0 WB	77
67864d19 WB	78	sub get_dns_conf {
	79	my ($conf) = @_;
	80
	81	# Same logic as in pve-container, but without the testcase special case
	82	my $host_resolv_conf = PVE::INotify::read_file('resolvconf');
	83
	84	my $searchdomains = [
	85	split(/\s+/, $conf->{searchdomain} // $host_resolv_conf->{search})
	86	];
	87
	88	my $nameserver = $conf->{nameserver};
	89	if (!defined($nameserver)) {
	90	$nameserver = [grep { $_ } $host_resolv_conf->@{qw(dns1 dns2 dns3)}];
	91	} else {
	92	$nameserver = [split(/\s+/, $nameserver)];
	93	}
	94
	95	return ($searchdomains, $nameserver);
	96	}
	97
41cd94a0	98	sub cloudinit_userdata {
9a6ccb12	99	my ($conf, $vmid) = @_;
41cd94a0	100
9a6ccb12	101	my ($hostname, $fqdn) = get_hostname_fqdn($conf, $vmid);
41cd94a0	102
7b42f951	103	my $content = "#cloud-config\n";
41cd94a0	104
e8ac2138 WB	105	$content .= "hostname: $hostname\n";
	106	$content .= "fqdn: $fqdn\n" if defined($fqdn);
	107
7b42f951 WB	108	my $username = $conf->{ciuser};
7b42f951 WB	109	my $password = $conf->{cipassword};
41cd94a0 WB	110
41cd94a0 WB	111	$content .= "user: $username\n" if defined($username);
7b42f951 WB	112	$content .= "disable_root: False\n" if defined($username) && $username eq 'root';
7b42f951 WB	113	$content .= "password: $password\n" if defined($password);
41cd94a0 WB	114
41cd94a0 WB	115	if (defined(my $keys = $conf->{sshkeys})) {
0c9a7596 AD	116	$keys = URI::Escape::uri_unescape($keys);
	117	$keys = [map { chomp $_; $_ } split(/\n/, $keys)];
	118	$keys = [grep { /\S/ } @$keys];
41cd94a0	119	$content .= "ssh_authorized_keys:\n";
0c9a7596	120	foreach my $k (@$keys) {
41cd94a0	121	$content .= " - $k\n";
0c9a7596 AD	122	}
0c9a7596 AD	123	}
41cd94a0 WB	124	$content .= "chpasswd:\n";
	125	$content .= " expire: False\n";
	126
7b42f951 WB	127	if (!defined($username) \|\| $username ne 'root') {
	128	$content .= "users:\n";
	129	$content .= " - default\n";
	130	}
0c9a7596 AD	131
	132	$content .= "package_upgrade: true\n";
	133
0c9a7596 AD	134	return $content;
	135	}
	136
41cd94a0 WB	137	sub configdrive2_network {
41cd94a0 WB	138	my ($conf) = @_;
0c9a7596 AD	139
0c9a7596 AD	140	my $content = "auto lo\n";
67864d19 WB	141	$content .= "iface lo inet loopback\n\n";
	142
	143	my ($searchdomains, $nameservers) = get_dns_conf($conf);
	144	if ($nameservers && @$nameservers) {
	145	$nameservers = join(' ', @$nameservers);
	146	$content .= " dns_nameservers $nameservers\n";
	147	}
	148	if ($searchdomains && @$searchdomains) {
	149	$searchdomains = join(' ', @$searchdomains);
	150	$content .= " dns_search $searchdomains\n";
	151	}
0c9a7596 AD	152
	153	my @ifaces = grep(/^net(\d+)$/, keys %$conf);
	154	foreach my $iface (@ifaces) {
	155	(my $id = $iface) =~ s/^net//;
	156	next if !$conf->{"ipconfig$id"};
41cd94a0	157	my $net = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
0c9a7596 AD	158	$id = "eth$id";
	159
	160	$content .="auto $id\n";
	161	if ($net->{ip}) {
	162	if ($net->{ip} eq 'dhcp') {
	163	$content .= "iface $id inet dhcp\n";
	164	} else {
	165	my ($addr, $mask) = split('/', $net->{ip});
	166	$content .= "iface $id inet static\n";
	167	$content .= " address $addr\n";
	168	$content .= " netmask $PVE::Network::ipv4_reverse_mask->[$mask]\n";
	169	$content .= " gateway $net->{gw}\n" if $net->{gw};
	170	}
	171	}
	172	if ($net->{ip6}) {
	173	if ($net->{ip6} =~ /^(auto\|dhcp)$/) {
	174	$content .= "iface $id inet6 $1\n";
	175	} else {
	176	my ($addr, $mask) = split('/', $net->{ip6});
	177	$content .= "iface $id inet6 static\n";
	178	$content .= " address $addr\n";
	179	$content .= " netmask $mask\n";
	180	$content .= " gateway $net->{gw6}\n" if $net->{gw6};
	181	}
	182	}
	183	}
	184
0c9a7596 AD	185	return $content;
	186	}
	187
41cd94a0 WB	188	sub configdrive2_metadata {
	189	my ($uuid) = @_;
	190	return <<"EOF";
	191	{
	192	"uuid": "$uuid",
	193	"network_config": { "content_path": "/content/0000" }
	194	}
	195	EOF
	196	}
	197
	198	sub generate_configdrive2 {
	199	my ($conf, $vmid, $drive, $volname, $storeid) = @_;
	200
9a6ccb12	201	my $user_data = cloudinit_userdata($conf, $vmid);
41cd94a0 WB	202	my $network_data = configdrive2_network($conf);
	203
	204	my $digest_data = $user_data . $network_data;
	205	my $uuid_str = Digest::SHA::sha1_hex($digest_data);
	206
	207	my $meta_data = configdrive2_metadata($uuid_str);
	208
f62c36cf WB	209	my $files = {
	210	'/openstack/latest/user_data' => $user_data,
	211	'/openstack/content/0000' => $network_data,
	212	'/openstack/latest/meta_data.json' => $meta_data
	213	};
	214	commit_cloudinit_disk($vmid, $conf, $drive, $volname, $storeid, $files, 'config-2');
41cd94a0 WB	215	}
	216
	217	sub nocloud_network_v2 {
	218	my ($conf) = @_;
	219
	220	my $content = '';
	221
	222	my $head = "version: 2\n"
	223	. "ethernets:\n";
	224
67864d19	225	my $dns_done;
41cd94a0 WB	226
	227	my @ifaces = grep(/^net(\d+)$/, keys %$conf);
	228	foreach my $iface (@ifaces) {
	229	(my $id = $iface) =~ s/^net//;
	230	next if !$conf->{"ipconfig$id"};
	231
	232	# indentation - network interfaces are inside an 'ethernets' hash
	233	my $i = ' ';
	234
	235	my $net = PVE::QemuServer::parse_net($conf->{$iface});
	236	my $ipconfig = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
	237
	238	my $mac = $net->{macaddr}
	239	or die "network interface '$iface' has no mac address\n";
	240
67864d19	241	$content .= "${i}$iface:\n";
41cd94a0	242	$i .= ' ';
67864d19 WB	243	$content .= "${i}match:\n"
	244	. "${i} macaddress: \"$mac\"\n"
	245	. "${i}set-name: eth$id\n";
41cd94a0 WB	246	my @addresses;
	247	if (defined(my $ip = $ipconfig->{ip})) {
	248	if ($ip eq 'dhcp') {
67864d19	249	$content .= "${i}dhcp4: true\n";
41cd94a0 WB	250	} else {
	251	push @addresses, $ip;
	252	}
	253	}
	254	if (defined(my $ip = $ipconfig->{ip6})) {
	255	if ($ip eq 'dhcp') {
67864d19	256	$content .= "${i}dhcp6: true\n";
41cd94a0 WB	257	} else {
	258	push @addresses, $ip;
	259	}
	260	}
	261	if (@addresses) {
67864d19 WB	262	$content .= "${i}addresses:\n";
67864d19 WB	263	$content .= "${i}- $_\n" foreach @addresses;
41cd94a0 WB	264	}
41cd94a0 WB	265	if (defined(my $gw = $ipconfig->{gw})) {
67864d19	266	$content .= "${i}gateway4: $gw\n";
41cd94a0 WB	267	}
41cd94a0 WB	268	if (defined(my $gw = $ipconfig->{gw6})) {
67864d19	269	$content .= "${i}gateway6: $gw\n";
41cd94a0 WB	270	}
41cd94a0 WB	271
67864d19 WB	272	next if $dns_done;
	273	$dns_done = 1;
	274
	275	my ($searchdomains, $nameservers) = get_dns_conf($conf);
	276	if ($searchdomains \|\| $nameservers) {
	277	$content .= "${i}nameservers:\n";
	278	if (defined($nameservers) && @$nameservers) {
	279	$content .= "${i} addresses:\n";
	280	$content .= "${i} - $_\n" foreach @$nameservers;
	281	}
	282	if (defined($searchdomains) && @$searchdomains) {
	283	$content .= "${i} search:\n";
	284	$content .= "${i} - $_\n" foreach @$searchdomains;
41cd94a0 WB	285	}
41cd94a0 WB	286	}
41cd94a0 WB	287	}
	288
	289	return $head.$content;
	290	}
	291
	292	sub nocloud_network {
	293	my ($conf) = @_;
	294
	295	my $content = "version: 1\n"
	296	. "config:\n";
	297
	298	my @ifaces = grep(/^net(\d+)$/, keys %$conf);
	299	foreach my $iface (@ifaces) {
	300	(my $id = $iface) =~ s/^net//;
	301	next if !$conf->{"ipconfig$id"};
	302
	303	# indentation - network interfaces are inside an 'ethernets' hash
	304	my $i = ' ';
	305
	306	my $net = PVE::QemuServer::parse_net($conf->{$iface});
	307	my $ipconfig = PVE::QemuServer::parse_ipconfig($conf->{"ipconfig$id"});
	308
	309	my $mac = $net->{macaddr}
	310	or die "network interface '$iface' has no mac address\n";
	311
67864d19 WB	312	$content .= "${i}- type: physical\n"
	313	. "${i} name: eth$id\n"
	314	. "${i} mac_address: $mac\n"
	315	. "${i} subnets:\n";
41cd94a0 WB	316	$i .= ' ';
	317	if (defined(my $ip = $ipconfig->{ip})) {
	318	if ($ip eq 'dhcp') {
67864d19	319	$content .= "${i}- type: dhcp4\n";
41cd94a0	320	} else {
67864d19	321	$content .= "${i}- type: static\n"
41cd94a0 WB	322	. "${i} address: $ip\n";
41cd94a0 WB	323	if (defined(my $gw = $ipconfig->{gw})) {
67864d19	324	$content .= "${i} gateway: $gw\n";
41cd94a0 WB	325	}
	326	}
	327	}
	328	if (defined(my $ip = $ipconfig->{ip6})) {
	329	if ($ip eq 'dhcp') {
67864d19	330	$content .= "${i}- type: dhcp6\n";
41cd94a0	331	} else {
67864d19	332	$content .= "${i}- type: static6\n"
41cd94a0 WB	333	. "${i} address: $ip\n";
41cd94a0 WB	334	if (defined(my $gw = $ipconfig->{gw6})) {
67864d19	335	$content .= "${i} gateway: $gw\n";
41cd94a0 WB	336	}
	337	}
	338	}
41cd94a0 WB	339	}
41cd94a0 WB	340
67864d19 WB	341	my $i = ' ';
	342	my ($searchdomains, $nameservers) = get_dns_conf($conf);
	343	if ($searchdomains \|\| $nameservers) {
41cd94a0	344	$content .= "${i}- type: nameserver\n";
67864d19	345	if (defined($nameservers) && @$nameservers) {
41cd94a0	346	$content .= "${i} address:\n";
67864d19	347	$content .= "${i} - $_\n" foreach @$nameservers;
41cd94a0	348	}
67864d19	349	if (defined($searchdomains) && @$searchdomains) {
41cd94a0	350	$content .= "${i} search:\n";
67864d19	351	$content .= "${i} - $_\n" foreach @$searchdomains;
41cd94a0 WB	352	}
	353	}
	354
	355	return $content;
	356	}
	357
	358	sub nocloud_metadata {
e8ac2138 WB	359	my ($uuid) = @_;
e8ac2138 WB	360	return "instance-id: $uuid\n";
41cd94a0 WB	361	}
	362
	363	sub generate_nocloud {
	364	my ($conf, $vmid, $drive, $volname, $storeid) = @_;
	365
9a6ccb12	366	my $user_data = cloudinit_userdata($conf, $vmid);
41cd94a0 WB	367	my $network_data = nocloud_network($conf);
41cd94a0 WB	368
e8ac2138	369	my $digest_data = $user_data . $network_data;
41cd94a0 WB	370	my $uuid_str = Digest::SHA::sha1_hex($digest_data);
41cd94a0 WB	371
e8ac2138	372	my $meta_data = nocloud_metadata($uuid_str);
41cd94a0	373
f62c36cf WB	374	my $files = {
	375	'/user-data' => $user_data,
	376	'/network-config' => $network_data,
	377	'/meta-data' => $meta_data
	378	};
	379	commit_cloudinit_disk($vmid, $conf, $drive, $volname, $storeid, $files, 'cidata');
41cd94a0 WB	380	}
	381
	382	my $cloudinit_methods = {
	383	configdrive2 => \&generate_configdrive2,
	384	nocloud => \&generate_nocloud,
	385	};
	386
	387	sub generate_cloudinitconfig {
	388	my ($conf, $vmid) = @_;
	389
	390	my $format = get_cloudinit_format($conf);
	391
	392	PVE::QemuServer::foreach_drive($conf, sub {
	393	my ($ds, $drive) = @_;
	394
	395	my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file}, 1);
	396
	397	return if !$volname \|\| $volname !~ m/vm-$vmid-cloudinit/;
	398
	399	my $generator = $cloudinit_methods->{$format}
	400	or die "missing cloudinit methods for format '$format'\n";
	401
	402	$generator->($conf, $vmid, $drive, $volname, $storeid);
	403	});
	404	}
0c9a7596 AD	405
0c9a7596 AD	406	1;