IntelFsp2Pkg: Add missing OEM status code defines.

[mirror_edk2.git] / IntelFsp2Pkg / FspSecCore / Ia32 / FspApiEntryM.nasm

;; @file\r
;  Provide FSP API entry points.\r
;\r
; Copyright (c) 2016, Intel Corporation. All rights reserved.<BR>\r
; This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php.\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;;\r
\r
    SECTION .text\r
\r
;\r
; Following are fixed PCDs\r
;\r
extern   ASM_PFX(PcdGet32(PcdTemporaryRamBase))\r
extern   ASM_PFX(PcdGet32(PcdTemporaryRamSize))\r
extern   ASM_PFX(PcdGet32(PcdFspTemporaryRamSize))\r
\r
struc FSPM_UPD_COMMON\r
    ; FSP_UPD_HEADER {\r
    .FspUpdHeader:            resd    8\r
    ; }\r
    ; FSPM_ARCH_UPD {\r
    .Revision:                resb    1\r
    .Reserved:                resb    3\r
    .NvsBufferPtr:            resd    1\r
    .StackBase:               resd    1\r
    .StackSize:               resd    1\r
    .BootLoaderTolumSize:     resd    1\r
    .BootMode:                resd    1\r
    .Reserved1:               resb    8\r
    ; }\r
    .size:\r
endstruc\r
\r
;\r
; Following functions will be provided in C\r
;\r
extern ASM_PFX(SecStartup)\r
extern ASM_PFX(FspApiCommon)\r
\r
;\r
; Following functions will be provided in PlatformSecLib\r
;\r
extern ASM_PFX(AsmGetFspBaseAddress)\r
extern ASM_PFX(AsmGetFspInfoHeader)\r
\r
API_PARAM1_OFFSET            EQU   34h  ; ApiParam1 [ sub esp,8 + pushad + pushfd + push eax + call]\r
FSP_HEADER_IMGBASE_OFFSET    EQU   1Ch\r
FSP_HEADER_CFGREG_OFFSET     EQU   24h\r
\r
;----------------------------------------------------------------------------\r
; FspMemoryInit API\r
;\r
; This FSP API is called after TempRamInit and initializes the memory.\r
;\r
;----------------------------------------------------------------------------\r
global ASM_PFX(FspMemoryInitApi)\r
ASM_PFX(FspMemoryInitApi):\r
  mov    eax,  3 ; FSP_API_INDEX.FspMemoryInitApiIndex\r
  jmp    ASM_PFX(FspApiCommon)\r
\r
;----------------------------------------------------------------------------\r
; TempRamExitApi API\r
;\r
; This API tears down temporary RAM\r
;\r
;----------------------------------------------------------------------------\r
global ASM_PFX(TempRamExitApi)\r
ASM_PFX(TempRamExitApi):\r
  mov    eax,  4 ; FSP_API_INDEX.TempRamExitApiIndex\r
  jmp    ASM_PFX(FspApiCommon)\r
\r
;----------------------------------------------------------------------------\r
; FspApiCommonContinue API\r
;\r
; This is the FSP API common entry point to resume the FSP execution\r
;\r
;----------------------------------------------------------------------------\r
global ASM_PFX(FspApiCommonContinue)\r
ASM_PFX(FspApiCommonContinue):\r
  ;\r
  ; EAX holds the API index\r
  ;\r
\r
  ;\r
  ; FspMemoryInit API setup the initial stack frame\r
  ;\r
\r
  ;\r
  ; Place holder to store the FspInfoHeader pointer\r
  ;\r
  push   eax\r
\r
  ;\r
  ; Update the FspInfoHeader pointer\r
  ;\r
  push   eax\r
  call   ASM_PFX(AsmGetFspInfoHeader)\r
  mov    [esp + 4], eax\r
  pop    eax\r
\r
  ;\r
  ; Create a Task Frame in the stack for the Boot Loader\r
  ;\r
  pushfd     ; 2 pushf for 4 byte alignment\r
  cli\r
  pushad\r
\r
  ; Reserve 8 bytes for IDT save/restore\r
  sub     esp, 8\r
  sidt    [esp]\r
\r
\r
  ;  Get Stackbase and StackSize from FSPM_UPD Param \r
  mov    edx, [esp + API_PARAM1_OFFSET] \r
  cmp    edx, 0\r
  jnz    FspStackSetup  \r
\r
  ; Get UPD default values if FspmUpdDataPtr (ApiParam1) is null\r
  push   eax\r
  call   ASM_PFX(AsmGetFspInfoHeader)\r
  mov    edx, [eax + FSP_HEADER_IMGBASE_OFFSET]\r
  add    edx, [eax + FSP_HEADER_CFGREG_OFFSET]\r
  pop    eax\r
  \r
  FspStackSetup:\r
  mov    edi, [edx + FSPM_UPD_COMMON.StackBase]\r
  mov    ecx, [edx + FSPM_UPD_COMMON.StackSize]\r
  add    edi, ecx\r
  ;\r
  ; Setup new FSP stack\r
  ;\r
  xchg    edi, esp                                ; Exchange edi and esp, edi will be assigned to the current esp pointer and esp will be Stack base + Stack size\r
  mov     ebx, esp                                ; Put Stack base + Stack size in ebx\r
\r
  ;\r
  ; Pass the API Idx to SecStartup\r
  ;\r
  push    eax\r
\r
  ;\r
  ; Pass the BootLoader stack to SecStartup\r
  ;\r
  push    edi\r
\r
  ;\r
  ; Pass entry point of the PEI core\r
  ;\r
  call    ASM_PFX(AsmGetFspBaseAddress)\r
  mov     edi, eax\r
  call    ASM_PFX(AsmGetPeiCoreOffset)\r
  add     edi, eax\r
  push    edi\r
\r
  ;\r
  ; Pass BFV into the PEI Core\r
  ; It uses relative address to calucate the actual boot FV base\r
  ; For FSP implementation with single FV, PcdFspBootFirmwareVolumeBase and\r
  ; PcdFspAreaBaseAddress are the same. For FSP with mulitple FVs,\r
  ; they are different. The code below can handle both cases.\r
  ;\r
  call    ASM_PFX(AsmGetFspBaseAddress)\r
  push    eax\r
\r
  ;\r
  ; Pass stack base and size into the PEI Core\r
  ;\r
  sub     ebx, ecx            ; Stack base + Stack size - Stack size\r
  push    ebx\r
  push    ecx\r
\r
  ;\r
  ; Pass Control into the PEI Core\r
  ;\r
  call    ASM_PFX(SecStartup)\r
  add     esp, 4\r
exit:\r
  ret\r
\r
global ASM_PFX(FspPeiCoreEntryOff)\r
ASM_PFX(FspPeiCoreEntryOff):\r
   ;\r
   ; This value will be pached by the build script\r
   ;\r
   DD    0x12345678\r
\r
global ASM_PFX(AsmGetPeiCoreOffset)\r
ASM_PFX(AsmGetPeiCoreOffset):\r
   mov   eax, dword [ASM_PFX(FspPeiCoreEntryOff)]\r
   ret\r
\r
;----------------------------------------------------------------------------\r
; Module Entrypoint API\r
;----------------------------------------------------------------------------\r
global ASM_PFX(_ModuleEntryPoint)\r
ASM_PFX(_ModuleEntryPoint):\r
  jmp $\r