MdeModulePkg/Universal/Acpi/BootScriptExecutorDxe: Add support for PCD PcdPteMemoryEn...

[mirror_edk2.git] / MdeModulePkg / Universal / Acpi / BootScriptExecutorDxe / X64 / S3Asm.nasm

;; @file\r
;   This is the assembly code for transferring to control to OS S3 waking vector\r
;   for X64 platform\r
;\r
; Copyright (c) 2006 - 2012, Intel Corporation. All rights reserved.<BR>\r
;\r
; This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
;;\r
\r
extern ASM_PFX(mOriginalHandler)\r
extern ASM_PFX(PageFaultHandler)\r
\r
    DEFAULT REL\r
    SECTION .text\r
\r
global ASM_PFX(AsmFixAddress16)\r
global ASM_PFX(AsmJmpAddr32)\r
\r
global ASM_PFX(AsmTransferControl)\r
ASM_PFX(AsmTransferControl):\r
    ; rcx S3WakingVector    :DWORD\r
    ; rdx AcpiLowMemoryBase :DWORD\r
    lea   eax, [.0]\r
    mov   r8, 0x2800000000\r
    or    rax, r8\r
    push  rax\r
    shrd  ebx, ecx, 20\r
    and   ecx, 0xf\r
    mov   bx, cx\r
    mov   [@jmp_addr + 1], ebx\r
    retf\r
BITS 16\r
.0:\r
    mov ax, 0x30\r
    mov   ds, ax\r
    mov   es, ax\r
    mov   fs, ax\r
    mov   gs, ax\r
    mov   ss, ax\r
    mov   eax, cr0\r
    mov   ebx, cr4\r
    and   eax, ((~ 0x80000001) & 0xffffffff)\r
    and   bl, ~ (1 << 5)\r
    mov   cr0, eax\r
    mov   ecx, 0xc0000080\r
    rdmsr\r
    and   ah, ~ 1\r
    wrmsr\r
    mov   cr4, ebx\r
@jmp_addr:\r
    jmp   0x0:0x0\r
\r
global ASM_PFX(AsmTransferControl32)\r
ASM_PFX(AsmTransferControl32):\r
BITS 32\r
    ; S3WakingVector    :DWORD\r
    ; AcpiLowMemoryBase :DWORD\r
    push  ebp\r
    mov   ebp, esp\r
    DB    0x8d, 0x5          ;  lea   eax, AsmTransferControl16\r
ASM_PFX(AsmFixAddress16): DD 0\r
    push  0x28               ; CS\r
    push  eax\r
    retf\r
\r
global ASM_PFX(AsmTransferControl16)\r
ASM_PFX(AsmTransferControl16):\r
BITS 16\r
    mov   ax, 0x30\r
o32 mov   ds, eax\r
o32 mov   es, eax\r
o32 mov   fs, eax\r
o32 mov   gs, eax\r
o32 mov   ss, eax\r
    mov   eax, cr0          ; Get control register 0\r
    and   eax, 0fffffffeh  ; Clear PE bit (bit #0)\r
    mov   cr0, eax         ; Activate real mode\r
    DB    0xea              ; jmp far AsmJmpAddr32\r
ASM_PFX(AsmJmpAddr32): DD 0\r
\r
global ASM_PFX(PageFaultHandlerHook)\r
ASM_PFX(PageFaultHandlerHook):\r
BITS 64\r
    push    rax                         ; save all volatile registers\r
    push    rcx\r
    push    rdx\r
    push    r8\r
    push    r9\r
    push    r10\r
    push    r11\r
    ; save volatile fp registers\r
    add     rsp, -0x68\r
    stmxcsr [rsp + 0x60]\r
    movdqa  [rsp + 0x0], xmm0\r
    movdqa  [rsp + 0x10], xmm1\r
    movdqa  [rsp + 0x20], xmm2\r
    movdqa  [rsp + 0x30], xmm3\r
    movdqa  [rsp + 0x40], xmm4\r
    movdqa  [rsp + 0x50], xmm5\r
\r
    add     rsp, -0x20\r
    call    ASM_PFX(PageFaultHandler)\r
    add     rsp, 0x20\r
\r
    ; load volatile fp registers\r
    ldmxcsr [rsp + 0x60]\r
    movdqa  xmm0,  [rsp + 0x0]\r
    movdqa  xmm1,  [rsp + 0x10]\r
    movdqa  xmm2,  [rsp + 0x20]\r
    movdqa  xmm3,  [rsp + 0x30]\r
    movdqa  xmm4,  [rsp + 0x40]\r
    movdqa  xmm5,  [rsp + 0x50]\r
    add     rsp, 0x68\r
\r
    test    al, al\r
\r
    pop     r11\r
    pop     r10\r
    pop     r9\r
    pop     r8\r
    pop     rdx\r
    pop     rcx\r
    pop     rax                         ; restore all volatile registers\r
    jnz     .1\r
    jmp     qword [ASM_PFX(mOriginalHandler)]\r
.1:\r
    add     rsp, 0x8                    ; skip error code for PF\r
    iretq\r
\r