ArmPlatformPkg/PrePi/ModuleEntryPoint.S

   1 //
   2 //  Copyright (c) 2011-2012, ARM Limited. All rights reserved.
   3 //
   4 //  This program and the accompanying materials
   5 //  are licensed and made available under the terms and conditions of the BSD License
   6 //  which accompanies this distribution.  The full text of the license may be found at
   7 //  http://opensource.org/licenses/bsd-license.php
   8 //
   9 //  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 //  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 //
  12 //
  13
  14 #include <AsmMacroIoLib.h>
  15 #include <Base.h>
  16 #include <Library/PcdLib.h>
  17 #include <AutoGen.h>
  18
  19 .text
  20 .align 3
  21
  22 GCC_ASM_IMPORT(CEntryPoint)
  23 GCC_ASM_IMPORT(ArmReadMpidr)
  24 GCC_ASM_IMPORT(ArmIsMpCore)
  25 GCC_ASM_EXPORT(_ModuleEntryPoint)
  26
  27 StartupAddr: .word    CEntryPoint
  28
  29
  30 ASM_PFX(_ModuleEntryPoint):
  31   // Get ID of this CPU in Multicore system
  32   bl    ASM_PFX(ArmReadMpidr)
  33   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCoreMask), r1)
  34   and   r5, r0, r1
  35
  36 _SetSVCMode:
  37   // Enter SVC mode, Disable FIQ and IRQ
  38   mov     r1, #0x13|0x80|0x40
  39   msr     CPSR_c, r1
  40
  41 // Check if we can install the stack at the top of the System Memory or if we need
  42 // to install the stacks at the bottom of the Firmware Device (case the FD is located
  43 // at the top of the DRAM)
  44 _SetupStackPosition:
  45   // Compute Top of System Memory
  46   LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryBase), r1)
  47   LoadConstantToReg (FixedPcdGet32(PcdSystemMemorySize), r2)
  48   sub   r2, r2, #1
  49   add   r1, r1, r2      // r1 = SystemMemoryTop = PcdSystemMemoryBase + PcdSystemMemorySize
  50
  51   // Calculate Top of the Firmware Device
  52   LoadConstantToReg (FixedPcdGet32(PcdFdBaseAddress), r2)
  53   LoadConstantToReg (FixedPcdGet32(PcdFdSize), r3)
  54   sub   r3, r3, #1
  55   add   r3, r3, r2      // r3 = FdTop = PcdFdBaseAddress + PcdFdSize
  56
  57   // UEFI Memory Size (stacks are allocated in this region)
  58   LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryUefiRegionSize), r4)
  59
  60   //
  61   // Reserve the memory for the UEFI region (contain stacks on its top)
  62   //
  63
  64   // Calculate how much space there is between the top of the Firmware and the Top of the System Memory
  65   subs  r0, r1, r3      // r0 = SystemMemoryTop - FdTop
  66   bmi   _SetupStack     // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM
  67   cmp   r0, r4
  68   bge   _SetupStack
  69
  70   // Case the top of stacks is the FdBaseAddress
  71   mov   r1, r2
  72
  73 _SetupStack:
  74   // r1 contains the top of the stack (and the UEFI Memory)
  75
  76   // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment
  77   // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the
  78   // top of the memory space)
  79   adds  r6, r1, #1
  80   bcs   _SetupOverflowStack
  81
  82 _SetupAlignedStack:
  83   mov   r1, r6
  84   b     _GetBaseUefiMemory
  85
  86 _SetupOverflowStack:
  87   // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE
  88   // aligned (4KB)
  89   LoadConstantToReg (EFI_PAGE_MASK, r6)
  90   and   r6, r6, r1
  91   sub   r1, r1, r6
  92
  93 _GetBaseUefiMemory:
  94   // Calculate the Base of the UEFI Memory
  95   sub   r6, r1, r4
  96
  97 _GetStackBase:
  98   // Compute Base of Normal stacks for CPU Cores
  99   // Is it MpCore system
 100   bl    ASM_PFX(ArmIsMpCore)
 101   cmp   r0, #0
 102   // Case it is not an MP Core system. Just setup the primary core
 103   beq   _SetupUnicoreStack
 104
 105 _GetStackBaseMpCore:
 106   // r1 = The top of the Mpcore Stacks
 107   // Stack for the primary core = PrimaryCoreStack
 108   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)
 109   sub   r7, r1, r2
 110
 111   // Stack for the secondary core = Number of Cluster * (4 Core per cluster) * SecondaryStackSize
 112   LoadConstantToReg (FixedPcdGet32(PcdClusterCount), r2)
 113   lsl   r2, r2, #2
 114   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), r3)
 115   mul   r2, r2, r3
 116   sub   r7, r7, r2
 117
 118   // The base of the secondary Stacks = Top of Primary stack
 119   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)
 120   add   r1, r7, r2
 121
 122   // r7 = The base of the MpCore Stacks (primary stack + cluster_count * 4 * secondary stacks)
 123   // r1 = The base of the secondary Stacks = Top of the Primary stack
 124
 125   // Is it the Primary Core ?
 126   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCore), r4)
 127   cmp   r5, r4
 128   beq   _SetupPrimaryCoreStack
 129
 130 _SetupSecondaryCoreStack:
 131   // r1 = The base of the secondary Stacks
 132
 133   // Get the position of the cores (ClusterId * 4) + CoreId
 134   GetCorePositionInStack(r0, r5, r4)
 135   // The stack starts at the top of the stack region. Add '1' to the Core Position to get the top of the stack
 136   add   r0, r0, #1
 137   // Get the offset for the Secondary Stack
 138   mul   r0, r0, r3
 139   add   sp, r1, r0
 140
 141   bne   _PrepareArguments
 142
 143 _SetupPrimaryCoreStack:
 144   // r1 = Top of the primary stack
 145   LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), r2)
 146   b     _PreparePrimaryStack
 147
 148 _SetupUnicoreStack:
 149   // The top of the Unicore Stack is in r1
 150   LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), r2)
 151   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r3)
 152
 153   // Calculate the bottom of the primary stack (StackBase)
 154   sub   r7, r1, r3
 155
 156 _PreparePrimaryStack:
 157   // The reserved space for global variable must be 8-bytes aligned for pushing
 158   // 64-bit variable on the stack
 159   SetPrimaryStack (r1, r2, r3)
 160
 161 _PrepareArguments:
 162   mov   r0, r5
 163   mov   r1, r6
 164   mov   r2, r7
 165   mov   r3, sp
 166
 167   // Move sec startup address into a data register
 168   // Ensure we're jumping to FV version of the code (not boot remapped alias)
 169   ldr   r4, StartupAddr
 170
 171   // Jump to PrePiCore C code
 172   //    r0 = MpId
 173   //    r1 = UefiMemoryBase
 174   //    r2 = StacksBase
 175   //    r3 = GlobalVariableBase
 176   blx   r4
 177
 178 _NeverReturn:
 179   b _NeverReturn
 180