Vlv2TbltDevicePkg/FspSupport/Library/SecFspPlatformSecLibVlv2/Ia32/SecEntry.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2014, Intel Corporation. All rights reserved.<BR>
   4 ; This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php.
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;  SecEntry.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;  This is the code that goes from real-mode to protected mode.
  19 ;  It consumes the reset vector, calls two basic APIs from FSP binary.
  20 ;
  21 ;------------------------------------------------------------------------------
  22   INCLUDE Fsp.inc
  23
  24 .686p
  25 .xmm
  26 .model small, c
  27
  28 EXTRN   CallPeiCoreEntryPoint:NEAR
  29 EXTRN   TempRamInitParams:FAR
  30
  31 ; Pcds
  32 EXTRN   PcdGet32 (PcdFlashFvFspBase):DWORD
  33 EXTRN   PcdGet32 (PcdFlashFvFspSize):DWORD
  34
  35 _TEXT_REALMODE      SEGMENT PARA PUBLIC USE16 'CODE'
  36                     ASSUME  CS:_TEXT_REALMODE, DS:_TEXT_REALMODE
  37
  38 ;----------------------------------------------------------------------------
  39 ;
  40 ; Procedure:    _ModuleEntryPoint
  41 ;
  42 ; Input:        None
  43 ;
  44 ; Output:       None
  45 ;
  46 ; Destroys:     Assume all registers
  47 ;
  48 ; Description:
  49 ;
  50 ;   Transition to non-paged flat-model protected mode from a
  51 ;   hard-coded GDT that provides exactly two descriptors.
  52 ;   This is a bare bones transition to protected mode only
  53 ;   used for a while in PEI and possibly DXE.
  54 ;
  55 ;   After enabling protected mode, a far jump is executed to
  56 ;   transfer to PEI using the newly loaded GDT.
  57 ;
  58 ; Return:       None
  59 ;
  60 ;  MMX Usage:
  61 ;              MM0 = BIST State
  62 ;              MM5 = Save time-stamp counter value high32bit
  63 ;              MM6 = Save time-stamp counter value low32bit.
  64 ;
  65 ;----------------------------------------------------------------------------
  66
  67 align 4
  68 _ModuleEntryPoint PROC NEAR C PUBLIC
  69   fninit                                ; clear any pending Floating point exceptions
  70   ;
  71   ; Store the BIST value in mm0
  72   ;
  73   movd    mm0, eax
  74
  75   ;
  76   ; Save time-stamp counter value
  77   ; rdtsc load 64bit time-stamp counter to EDX:EAX
  78   ;
  79   rdtsc
  80   movd    mm5, edx
  81   movd    mm6, eax
  82
  83   ;
  84   ; Load the GDT table in GdtDesc
  85   ;
  86   mov     esi,  OFFSET GdtDesc
  87   DB      66h
  88   lgdt    fword ptr cs:[si]
  89
  90   ;
  91   ; Transition to 16 bit protected mode
  92   ;
  93   mov     eax, cr0                   ; Get control register 0
  94   or      eax, 00000003h             ; Set PE bit (bit #0) & MP bit (bit #1)
  95   mov     cr0, eax                   ; Activate protected mode
  96
  97   mov     eax, cr4                   ; Get control register 4
  98   or      eax, 00000600h             ; Set OSFXSR bit (bit #9) & OSXMMEXCPT bit (bit #10)
  99   mov     cr4, eax
 100
 101   ;
 102   ; Now we're in 16 bit protected mode
 103   ; Set up the selectors for 32 bit protected mode entry
 104   ;
 105   mov     ax, SYS_DATA_SEL
 106   mov     ds, ax
 107   mov     es, ax
 108   mov     fs, ax
 109   mov     gs, ax
 110   mov     ss, ax
 111
 112   ;
 113   ; Transition to Flat 32 bit protected mode
 114   ; The jump to a far pointer causes the transition to 32 bit mode
 115   ;
 116   mov esi, offset ProtectedModeEntryLinearAddress
 117   jmp     fword ptr cs:[si]
 118
 119 _ModuleEntryPoint   ENDP
 120 _TEXT_REALMODE      ENDS
 121
 122 _TEXT_PROTECTED_MODE      SEGMENT PARA PUBLIC USE32 'CODE'
 123                           ASSUME  CS:_TEXT_PROTECTED_MODE, DS:_TEXT_PROTECTED_MODE
 124
 125 ;----------------------------------------------------------------------------
 126 ;
 127 ; Procedure:    ProtectedModeEntryPoint
 128 ;
 129 ; Input:        None
 130 ;
 131 ; Output:       None
 132 ;
 133 ; Destroys:     Assume all registers
 134 ;
 135 ; Description:
 136 ;
 137 ; This function handles:
 138 ;   Call two basic APIs from FSP binary
 139 ;   Initializes stack with some early data (BIST, PEI entry, etc)
 140 ;
 141 ; Return:       None
 142 ;
 143 ;----------------------------------------------------------------------------
 144
 145 align 4
 146 ProtectedModeEntryPoint PROC NEAR PUBLIC
 147
 148   ; Find the fsp info header
 149   mov  edi, PcdGet32 (PcdFlashFvFspBase)
 150   mov  ecx, PcdGet32 (PcdFlashFvFspSize)
 151
 152   mov  eax, dword ptr [edi + FVH_SIGINATURE_OFFSET]
 153   cmp  eax, FVH_SIGINATURE_VALID_VALUE
 154   jnz  FspHeaderNotFound
 155
 156   xor  eax, eax
 157   mov  ax, word ptr [edi + FVH_EXTHEADER_OFFSET_OFFSET]
 158   cmp  ax, 0
 159   jnz  FspFvExtHeaderExist
 160
 161   xor  eax, eax
 162   mov  ax, word ptr [edi + FVH_HEADER_LENGTH_OFFSET]   ; Bypass Fv Header
 163   add  edi, eax
 164   jmp  FspCheckFfsHeader
 165
 166 FspFvExtHeaderExist:
 167   add  edi, eax
 168   mov  eax, dword ptr [edi + FVH_EXTHEADER_SIZE_OFFSET]  ; Bypass Ext Fv Header
 169   add  edi, eax
 170
 171   ; Round up to 8 byte alignment
 172   mov  eax, edi
 173   and  al,  07h
 174   jz FspCheckFfsHeader
 175
 176   and  edi, 0FFFFFFF8h
 177   add  edi, 08h
 178
 179 FspCheckFfsHeader:
 180   ; Check the ffs guid
 181   mov  eax, dword ptr [edi]
 182   cmp  eax, FSP_HEADER_GUID_DWORD1
 183   jnz FspHeaderNotFound
 184
 185   mov  eax, dword ptr [edi + 4]
 186   cmp  eax, FSP_HEADER_GUID_DWORD2
 187   jnz FspHeaderNotFound
 188
 189   mov  eax, dword ptr [edi + 8]
 190   cmp  eax, FSP_HEADER_GUID_DWORD3
 191   jnz FspHeaderNotFound
 192
 193   mov  eax, dword ptr [edi + 0Ch]
 194   cmp  eax, FSP_HEADER_GUID_DWORD4
 195   jnz FspHeaderNotFound
 196
 197   add  edi, FFS_HEADER_SIZE_VALUE       ; Bypass the ffs header
 198
 199   ; Check the section type as raw section
 200   mov  al, byte ptr [edi + SECTION_HEADER_TYPE_OFFSET]
 201   cmp  al, 019h
 202   jnz FspHeaderNotFound
 203
 204   add  edi, RAW_SECTION_HEADER_SIZE_VALUE ; Bypass the section header
 205   jmp FspHeaderFound
 206
 207 FspHeaderNotFound:
 208   jmp  $
 209
 210 FspHeaderFound:
 211   ; Get the fsp TempRamInit Api address
 212   mov eax, dword ptr [edi + FSP_HEADER_IMAGEBASE_OFFSET]
 213   add eax, dword ptr [edi + FSP_HEADER_TEMPRAMINIT_OFFSET]
 214
 215   ; Setup the hardcode stack
 216   mov esp, OFFSET TempRamInitStack
 217
 218   ; Call the fsp TempRamInit Api
 219   jmp eax
 220
 221 TempRamInitDone:
 222   cmp eax, 0
 223   jnz FspApiFailed
 224
 225   ;   ECX: start of range
 226   ;   EDX: end of range
 227   mov     esp, edx
 228   push    edx
 229   push    ecx
 230   push    eax ; zero - no hob list yet
 231   call CallPeiCoreEntryPoint
 232
 233 FspApiFailed:
 234   jmp $
 235
 236 align 10h
 237 TempRamInitStack:
 238     DD  OFFSET TempRamInitDone
 239     DD  OFFSET TempRamInitParams
 240
 241 ProtectedModeEntryPoint ENDP
 242
 243 ;
 244 ; ROM-based Global-Descriptor Table for the Tiano PEI Phase
 245 ;
 246 align 16
 247 PUBLIC  BootGdtTable
 248
 249 ;
 250 ; GDT[0]: 0x00: Null entry, never used.
 251 ;
 252 NULL_SEL            EQU $ - GDT_BASE    ; Selector [0]
 253 GDT_BASE:
 254 BootGdtTable        DD  0
 255                     DD  0
 256 ;
 257 ; Linear data segment descriptor
 258 ;
 259 LINEAR_SEL          EQU $ - GDT_BASE    ; Selector [0x8]
 260     DW  0FFFFh                          ; limit 0xFFFFF
 261     DW  0                               ; base 0
 262     DB  0
 263     DB  092h                            ; present, ring 0, data, expand-up, writable
 264     DB  0CFh                            ; page-granular, 32-bit
 265     DB  0
 266 ;
 267 ; Linear code segment descriptor
 268 ;
 269 LINEAR_CODE_SEL     EQU $ - GDT_BASE    ; Selector [0x10]
 270     DW  0FFFFh                          ; limit 0xFFFFF
 271     DW  0                               ; base 0
 272     DB  0
 273     DB  09Bh                            ; present, ring 0, data, expand-up, not-writable
 274     DB  0CFh                            ; page-granular, 32-bit
 275     DB  0
 276 ;
 277 ; System data segment descriptor
 278 ;
 279 SYS_DATA_SEL        EQU $ - GDT_BASE    ; Selector [0x18]
 280     DW  0FFFFh                          ; limit 0xFFFFF
 281     DW  0                               ; base 0
 282     DB  0
 283     DB  093h                            ; present, ring 0, data, expand-up, not-writable
 284     DB  0CFh                            ; page-granular, 32-bit
 285     DB  0
 286
 287 ;
 288 ; System code segment descriptor
 289 ;
 290 SYS_CODE_SEL        EQU $ - GDT_BASE    ; Selector [0x20]
 291     DW  0FFFFh                          ; limit 0xFFFFF
 292     DW  0                               ; base 0
 293     DB  0
 294     DB  09Ah                            ; present, ring 0, data, expand-up, writable
 295     DB  0CFh                            ; page-granular, 32-bit
 296     DB  0
 297 ;
 298 ; Spare segment descriptor
 299 ;
 300 SYS16_CODE_SEL      EQU $ - GDT_BASE    ; Selector [0x28]
 301     DW  0FFFFh                          ; limit 0xFFFFF
 302     DW  0                               ; base 0
 303     DB  0Eh                             ; Changed from F000 to E000.
 304     DB  09Bh                            ; present, ring 0, code, expand-up, writable
 305     DB  00h                             ; byte-granular, 16-bit
 306     DB  0
 307 ;
 308 ; Spare segment descriptor
 309 ;
 310 SYS16_DATA_SEL      EQU $ - GDT_BASE    ; Selector [0x30]
 311     DW  0FFFFh                          ; limit 0xFFFF
 312     DW  0                               ; base 0
 313     DB  0
 314     DB  093h                            ; present, ring 0, data, expand-up, not-writable
 315     DB  00h                             ; byte-granular, 16-bit
 316     DB  0
 317
 318 ;
 319 ; Spare segment descriptor
 320 ;
 321 SPARE5_SEL          EQU $ - GDT_BASE    ; Selector [0x38]
 322     DW  0                               ; limit 0
 323     DW  0                               ; base 0
 324     DB  0
 325     DB  0                               ; present, ring 0, data, expand-up, writable
 326     DB  0                               ; page-granular, 32-bit
 327     DB  0
 328 GDT_SIZE            EQU $ - BootGdtTable    ; Size, in bytes
 329
 330 ;
 331 ; GDT Descriptor
 332 ;
 333 GdtDesc:                                ; GDT descriptor
 334     DW  GDT_SIZE - 1                    ; GDT limit
 335     DD  OFFSET BootGdtTable             ; GDT base address
 336
 337
 338 ProtectedModeEntryLinearAddress   LABEL   FWORD
 339 ProtectedModeEntryLinearOffset    LABEL   DWORD
 340   DD      OFFSET ProtectedModeEntryPoint  ; Offset of our 32 bit code
 341   DW      LINEAR_CODE_SEL
 342
 343 _TEXT_PROTECTED_MODE    ENDS
 344 END