configure.in

   1 #
   2 # $Id: configure.in 3462 2011-10-27 19:55:10Z chrfranke $
   3 #
   4 dnl Process this file with autoconf to produce a configure script.
   5 AC_PREREQ(2.50)
   6 AC_INIT(smartmontools, 5.43, smartmontools-support@lists.sourceforge.net)
   7 AC_CONFIG_SRCDIR(smartctl.cpp)
   8
   9 smartmontools_configure_date=`date -u +'%Y-%m-%d %T %Z'`
  10 smartmontools_cvs_tag=`echo '$Id: configure.in 3462 2011-10-27 19:55:10Z chrfranke $'`
  11 smartmontools_release_date=2011-10-20
  12 smartmontools_release_time="19:19:34 UTC"
  13
  14 AC_DEFINE_UNQUOTED(SMARTMONTOOLS_CONFIGURE_ARGS, "$ac_configure_args",            [smartmontools Configure Arguments])
  15 AC_DEFINE_UNQUOTED(SMARTMONTOOLS_CONFIGURE_DATE, "$smartmontools_configure_date", [smartmontools Configure Date])
  16 AC_DEFINE_UNQUOTED(SMARTMONTOOLS_RELEASE_DATE,   "$smartmontools_release_date",   [smartmontools Release Date])
  17 AC_DEFINE_UNQUOTED(SMARTMONTOOLS_RELEASE_TIME,   "$smartmontools_release_time",   [smartmontools Release Time])
  18 AC_DEFINE_UNQUOTED(CONFIG_H_CVSID,               "$smartmontools_cvs_tag",        [smartmontools CVS Tag])
  19 AC_DEFINE_UNQUOTED(PACKAGE_HOMEPAGE,             "http://smartmontools.sourceforge.net/", [smartmontools Home Page])
  20
  21 AM_CONFIG_HEADER(config.h)
  22
  23 AM_INIT_AUTOMAKE([foreign])
  24
  25 AM_MAINTAINER_MODE
  26
  27 AC_LANG_CPLUSPLUS
  28 dnl Checks for programs.
  29 AC_PROG_CXX
  30 AM_PROG_AS
  31 AC_PROG_INSTALL
  32
  33 m4_pattern_forbid([^PKG_PROG_])
  34 if test "$cross_compiling" = "no"; then
  35   m4_ifdef([PKG_PROG_PKG_CONFIG], [PKG_PROG_PKG_CONFIG],
  36     [AC_MSG_WARN([m4/pkg.m4 missing, systemd detection disabled])])
  37 fi
  38
  39 AC_ARG_VAR(WINDMC, [Windows message compiler command])
  40 AC_ARG_VAR(WINDRES, [Windows resource compiler command])
  41 AC_ARG_VAR(MAKENSIS, [NSIS compiler command])
  42
  43 AC_CANONICAL_HOST
  44 case "${host}" in
  45   *-*-mingw*)
  46     # Cygwin gcc 4.x does no longer support '-mno-cygwin' to select MinGW gcc.
  47     if test "${build}" = "${host}" && test -x /usr/bin/uname && \
  48     /usr/bin/uname | grep -i '^CYGWIN' >/dev/null; then
  49       AC_MSG_ERROR([Build with MinGW on Cygwin requires cross-compilation, see INSTALL file.])
  50     fi
  51     AC_CHECK_PROGS(WINDMC, [${host}-windmc windmc])
  52     AC_CHECK_PROGS(WINDRES, [${host}-windres windres])
  53
  54     AC_MSG_CHECKING([checking for makensis])
  55     if test -z "$MAKENSIS"; then
  56       if test -n "$PROGRAMFILES" && "$PROGRAMFILES/NSIS/makensis" -VERSION >/dev/null 2>&1; then
  57         MAKENSIS="$PROGRAMFILES/NSIS/makensis"
  58       elif makensis -VERSION >/dev/null 2>&1; then
  59         MAKENSIS=makensis
  60       fi
  61     fi
  62     AC_MSG_RESULT([${MAKENSIS:-no}])
  63     ;;
  64 esac
  65
  66 # Check for SVN.
  67 AC_MSG_CHECKING([whether this is a build from SVN])
  68 is_svn_build=no
  69 if test -f "$srcdir/.svn/entries"; then
  70   is_svn_build=unknown
  71   if (cd "$srcdir" && svn --version && svnversion && svn info) >/dev/null 2>&1; then
  72     is_svn_build=yes
  73   fi
  74 fi
  75 AM_CONDITIONAL(IS_SVN_BUILD, [test "$is_svn_build" = "yes"])
  76 AC_MSG_RESULT([$is_svn_build])
  77
  78 dnl Checks for libraries needed for name services (Solaris needs
  79 dnl libnsl, might in the future also need libsocket)
  80 #  AC_SEARCH_LIBS (FUNCTION, SEARCH-LIBS, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND], [OTHER-LIBRARIES])
  81 AC_SEARCH_LIBS(socket, socket)
  82 AC_SEARCH_LIBS(gethostbyname, nsl)
  83 AC_SEARCH_LIBS(getaddrinfo, nsl)
  84 AC_SEARCH_LIBS(getdomainname, nsl)
  85
  86 dnl Checks for header files.
  87 AC_CHECK_HEADERS([locale.h])
  88 AC_CHECK_HEADERS([dev/ata/atavar.h])
  89 AC_CHECK_HEADERS([netdb.h])
  90 dnl we need [u]int64_t and friends.
  91 AC_CHECK_HEADERS([inttypes.h])          dnl C99, UNIX98, solaris 2.6+
  92 AC_CHECK_HEADERS([stdint.h])            dnl C99
  93 AC_CHECK_HEADERS([sys/inttypes.h])      dnl pre-UNIX98
  94 AC_CHECK_HEADERS([sys/int_types.h])     dnl pre-UNIX98, solaris 2.6+
  95 dnl Check for FreeBSD twe include files...currently missing on 5.2, but should be there
  96 AC_CHECK_HEADERS([sys/tweio.h])
  97 AC_CHECK_HEADERS([sys/twereg.h])
  98 dnl Check for FreeBSD twa include files...
  99 AC_CHECK_HEADERS([sys/tw_osl_ioctl.h])
 100 dnl This header file is needed for cciss_ioctl.h at least on SuSE LINUX
 101 AC_CHECK_HEADERS([linux/compiler.h])
 102 dnl Check for the FreeBSD CCISS system header and use internal one if not found
 103 AC_CHECK_HEADERS([dev/ciss/cissio.h],
 104     [AC_DEFINE([CISS_LOCATION],[<dev/ciss/cissio.h>],[freebsd ciss header location])],
 105     [AC_DEFINE([CISS_LOCATION],["cissio_freebsd.h"],[freebsd ciss header location])]
 106     )
 107 dnl Check for Linux CCISS include file
 108 AC_CHECK_HEADERS([linux/cciss_ioctl.h], [], [], [AC_INCLUDES_DEFAULT
 109 #ifdef HAVE_LINUX_COMPILER_H
 110 # include <linux/compiler.h>
 111 #endif
 112 ])
 113 dnl Check for Windows DDK and WMI header files
 114 AC_CHECK_HEADERS([ntdddisk.h ddk/ntdddisk.h], [], [], [AC_INCLUDES_DEFAULT
 115 #include <windows.h>
 116 ])
 117 AC_CHECK_HEADERS([wbemcli.h])
 118
 119 dnl Checks for typedefs, structures, and compiler characteristics.
 120 AC_CHECK_TYPES([int64_t, uint64_t])
 121
 122 dnl Checks for library functions.
 123 AC_CHECK_FUNCS([getopt_long], [need_getopt_long=no], [need_getopt_long=yes])
 124 AM_CONDITIONAL(NEED_GETOPT_LONG, [test "$need_getopt_long" = "yes"])
 125 AC_CHECK_FUNCS([regcomp], [need_regex=no], [need_regex=yes])
 126 AM_CONDITIONAL(NEED_REGEX, [test "$need_regex" = "yes"])
 127
 128 AC_CHECK_FUNCS([getdomainname])
 129 AC_CHECK_FUNCS([gethostname])
 130 AC_CHECK_FUNCS([getaddrinfo])
 131 AC_CHECK_FUNCS([gethostbyname])
 132 AC_CHECK_FUNCS([sigset])
 133 AC_CHECK_FUNCS([strtoull])
 134 AC_CHECK_FUNCS([uname])
 135
 136 # Check byte ordering (defines WORDS_BIGENDIAN)
 137 AC_C_BIGENDIAN
 138
 139 # Check whether snprintf appends null char and returns expected length on overflow
 140 AC_MSG_CHECKING([for working snprintf])
 141 AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[ char buf[]="ABCDEFGHI";
 142                int i=snprintf(buf,8,"12345678"); return !(!buf[7] && i==8); ]])],
 143               [libc_have_working_snprintf=yes],
 144               [libc_have_working_snprintf=no],
 145               [libc_have_working_snprintf=unknown])
 146 AC_SUBST(libc_have_working_snprintf)
 147 if test "$libc_have_working_snprintf" = "yes"; then
 148   AC_DEFINE(HAVE_WORKING_SNPRINTF, 1, [Define to 1 if the `snprintf' function is sane])
 149 fi
 150 AC_MSG_RESULT([$libc_have_working_snprintf])
 151
 152 # check for __attribute__((packed))
 153 # (sizeof() check is required to avoid false positives if other
 154 # __attribute__((x)) are supported)
 155 AC_MSG_CHECKING([whether $CXX supports __attribute__((packed))])
 156 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [[
 157     struct s { char a; short b; } __attribute__((packed));
 158     typedef char t[sizeof(struct s) == 3 ? 1 : -1];]])],
 159   [gcc_have_attr_packed=yes], [gcc_have_attr_packed=no])
 160 AC_SUBST(gcc_have_attr_packed)
 161 if test "$gcc_have_attr_packed" = "yes"; then
 162   AC_DEFINE(HAVE_ATTR_PACKED, 1, [Define to 1 if C++ compiler supports __attribute__((packed))])
 163 fi
 164 AC_MSG_RESULT([$gcc_have_attr_packed])
 165
 166 AC_SUBST(CPPFLAGS)
 167 AC_SUBST(LDFLAGS)
 168 AC_SUBST(ASFLAGS)
 169
 170 AC_ARG_WITH(systemdsystemunitdir,
 171   [AS_HELP_STRING([--with-systemdsystemunitdir@<:@=DIR|auto|yes|no@:>@], [Location of systemd service files [auto]])],
 172   [], [with_systemdsystemunitdir=auto])
 173
 174 systemdsystemunitdir=
 175 case "$with_systemdsystemunitdir" in
 176  auto|yes)
 177    if test -n "$PKG_CONFIG"; then
 178      AC_MSG_CHECKING([for systemdsystemunitdir])
 179      systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
 180      AC_MSG_RESULT([${systemdsystemunitdir:-no}])
 181    fi
 182    case "$with_systemdsystemunitdir:$sysconfdir:$systemdsystemunitdir" in
 183      yes:*:) AC_MSG_ERROR([Location of systemd service files not found]) ;;
 184      yes:*:*|auto:*:|auto:/etc:*) ;;
 185      *) systemdsystemunitdir='${prefix}'$systemdsystemunitdir ;;
 186    esac ;;
 187  no) ;;
 188  *) systemdsystemunitdir="$with_systemdsystemunitdir" ;;
 189 esac
 190 AC_SUBST(systemdsystemunitdir)
 191 AM_CONDITIONAL(INSTALL_SYSTEMDUNIT, [test -n "$systemdsystemunitdir"])
 192
 193 AC_ARG_WITH(initscriptdir,
 194   [AC_HELP_STRING([--with-initscriptdir@<:@=DIR|auto|yes|no@:>@], [Location of init scripts [auto]])],
 195   [], [with_initscriptdir=auto])
 196
 197 initddir=
 198 case "$with_initscriptdir:$cross_compiling:$systemdsystemunitdir" in
 199   auto:no:|yes:*)
 200     AC_MSG_CHECKING([for init (rc) directory])
 201     for dir in rc.d/init.d init.d rc.d; do
 202       if test -d /etc/$dir; then
 203         initddir='${sysconfdir}'/$dir
 204         break
 205       fi
 206     done
 207     AC_MSG_RESULT([${initddir:-no}])
 208     case "$with_initscriptdir:$initddir" in
 209       yes:) AC_MSG_ERROR([Location of init scripts not found]) ;;
 210     esac ;;
 211   auto:*|no:*) ;;
 212   *) initddir="$with_initscriptdir" ;;
 213 esac
 214 AC_SUBST(initddir)
 215 AM_CONDITIONAL(INSTALL_INITSCRIPT, [test -n "$initddir"])
 216
 217 # use different init script templates for different OS
 218 case "${host}" in
 219   *-*-freebsd*)
 220     initdfile="smartd.freebsd.initd"
 221     ;;
 222   *)
 223     initdfile="smartd.initd"
 224     ;;
 225 esac
 226 AC_SUBST(initdfile)
 227
 228 AC_ARG_WITH(docdir,
 229   [AC_HELP_STRING([--with-docdir=DIR],[Location of documentation [DATADIR/doc/smartmontools]])],
 230   [docdir="$withval"],
 231   [ if test -z "$docdir"; then
 232       # autoconf 2.5x without '--docdir' support
 233       docdir='${datadir}/doc/${PACKAGE}'
 234     fi
 235   ])
 236 AC_SUBST(docdir)
 237
 238 AC_ARG_WITH(exampledir,
 239   [AC_HELP_STRING([--with-exampledir=DIR],[Location of example scripts [DOCDIR/examplescripts]])],
 240   [exampledir="$withval"], [exampledir='${docdir}/examplescripts'])
 241 AC_SUBST(exampledir)
 242
 243 AC_ARG_ENABLE(drivedb,
 244   [AC_HELP_STRING([--disable-drivedb],[Disables drive database file])],
 245   [], [enable_drivedb=yes])
 246
 247 AC_ARG_WITH(drivedbdir,
 248   [AC_HELP_STRING([--with-drivedbdir=DIR],[Location of drive database file (implies --enable-drivedb) [DATADIR/smartmontools]])],
 249   [drivedbdir="$withval"; enable_drivedb=yes],
 250   [drivedbdir=; test "$enable_drivedb" = "yes" && drivedbdir='${datadir}/${PACKAGE}'])
 251 AC_SUBST(drivedbdir)
 252 AM_CONDITIONAL(ENABLE_DRIVEDB, [test "$enable_drivedb" = "yes"])
 253
 254 AC_ARG_ENABLE(savestates, [AC_HELP_STRING([--enable-savestates],[Enables default smartd state files])])
 255
 256 AC_ARG_WITH(savestates,
 257   [AC_HELP_STRING([--with-savestates=PREFIX],[Prefix for default smartd state files (implies --enable-savestates) [LOCALSTATEDIR/lib/smartmontools/smartd.]])],
 258   [savestates="$withval"; enable_savestates="yes"],
 259   [savestates=; test "$enable_savestates" = "yes" && savestates='${localstatedir}/lib/${PACKAGE}/smartd.'])
 260 savestatesdir="${savestates%/*}"
 261 AC_SUBST(savestates)
 262 AC_SUBST(savestatesdir)
 263 AM_CONDITIONAL(ENABLE_SAVESTATES, [test "$enable_savestates" = "yes"])
 264
 265 AC_ARG_ENABLE(attributelog, [AC_HELP_STRING([--enable-attributelog],[Enables default smartd attribute log files])])
 266
 267 AC_ARG_WITH(attributelog,
 268   [AC_HELP_STRING([--with-attributelog=PREFIX],[Prefix for default smartd attribute log files (implies --enable-attributelog) [LOCALSTATEDIR/lib/smartmontools/attrlog.]])],
 269   [attributelog="$withval"; enable_attributelog="yes"],
 270   [attributelog=; test "$enable_attributelog" = "yes" && attributelog='${localstatedir}/lib/${PACKAGE}/attrlog.'])
 271 attributelogdir="${attributelog%/*}"
 272 AC_SUBST(attributelog)
 273 AC_SUBST(attributelogdir)
 274 AM_CONDITIONAL(ENABLE_ATTRIBUTELOG, [test "$enable_attributelog" = "yes"])
 275
 276 AC_ARG_ENABLE(sample,
 277   [AC_HELP_STRING([--enable-sample],[Enables appending .sample to the installed smartd rc script and configuration file])],
 278   [smartd_suffix=; test "$enableval" = "yes" && smartd_suffix=".sample"],
 279   [smartd_suffix=;])
 280 AC_SUBST(smartd_suffix)
 281
 282 AC_ARG_WITH(os-deps,
 283   [AC_HELP_STRING([--with-os-deps='os_module.o ...'],[Specify OS dependent module(s) [guessed]])],
 284   [ for x in $with_os_deps; do
 285       case $x in
 286         *.o) ;;
 287         *) AC_MSG_ERROR([non-object file specified by --with-os-deps]) ;;
 288       esac
 289     done
 290   ],[])
 291
 292 AC_ARG_WITH(selinux,
 293   [AC_HELP_STRING([--with-selinux@<:@=yes|no@:>@],[Enables SELinux support [no]])],
 294   [ if test "$withval" = "yes"; then
 295       AC_CHECK_HEADERS([selinux/selinux.h], [], [AC_MSG_ERROR([Missing SELinux header files])])
 296       AC_CHECK_LIB(selinux, matchpathcon, [], [AC_MSG_ERROR([Missing or incorrect SELinux library files])])
 297     fi
 298   ],[])
 299 AC_SUBST(with_selinux)
 300 if test "$with_selinux" = "yes"; then
 301   AC_DEFINE(WITH_SELINUX, 1, [Define to 1 if SELinux support is enabled])
 302 fi
 303
 304 AC_ARG_WITH(libcap-ng,
 305   [AC_HELP_STRING([--with-libcap-ng@<:@=auto|yes|no@:>@],[Add Libcap-ng support to smartd [auto]])],
 306   [], [with_libcap_ng=auto])
 307
 308 use_libcap_ng=no
 309 if test "$with_libcap_ng" != "no"; then
 310   AC_CHECK_LIB(cap-ng, capng_clear,
 311     [AC_DEFINE(HAVE_LIBCAP_NG, 1, [Define to 1 if you have the `cap-ng' library (-lcap-ng).])
 312      CAPNG_LDADD="-lcap-ng"; use_libcap_ng=yes])
 313
 314   if test "$use_libcap_ng" = "yes"; then
 315     AC_CHECK_HEADER(cap-ng.h, [], [AC_MSG_ERROR([libcap-ng libraries found but headers are missing])])
 316   elif test "$with_libcap_ng" = "yes"; then
 317     AC_MSG_ERROR([libcap-ng support was requested but the library was not found])
 318   fi
 319 fi
 320
 321 AC_MSG_CHECKING([whether to use libcap-ng])
 322 AC_SUBST(CAPNG_LDADD)
 323 AM_CONDITIONAL(ENABLE_CAPABILITIES, [test "$use_libcap_ng" = "yes"])
 324 AC_MSG_RESULT([$use_libcap_ng])
 325
 326 if test "$prefix" = "NONE"; then
 327     dnl no prefix and no mandir, so use ${prefix}/share/man as default
 328     if test "$mandir" = '${prefix}/man'; then
 329         AC_SUBST([mandir], ['${prefix}/share/man'])
 330     fi
 331 fi
 332
 333 AC_SUBST(releaseversion,['${PACKAGE}-${VERSION}'])
 334 AC_SUBST(smartmontools_release_date)
 335 AC_SUBST(smartmontools_release_time)
 336
 337 # Set platform-specific modules and symbols
 338 os_libs=
 339 os_dltools='curl wget lynx'
 340 os_mailer=
 341 os_darwin=no
 342 os_solaris=no
 343 os_win32=no
 344 os_win32_mingw=no
 345 os_win64=no
 346 os_man_filter=
 347 case "${host}" in
 348   *-*-linux*)
 349     os_deps='os_linux.o cciss.o'
 350     os_man_filter=Linux
 351     ;;
 352   *-*-freebsd*|*-*-dragonfly*|*-*-kfreebsd*-gnu*)
 353     os_deps='os_freebsd.o cciss.o'
 354     os_libs='-lcam'
 355     os_dltools='curl wget lynx fetch'
 356     AC_CHECK_LIB(usb, libusb20_dev_get_device_desc)
 357     os_man_filter=FreeBSD
 358     ;;
 359   sparc-*-solaris*)
 360     os_deps='os_solaris.o os_solaris_ata.o'
 361     os_mailer='mailx'
 362     os_solaris=yes
 363     os_man_filter=Solaris
 364     ;;
 365   *-pc-solaris*)
 366     os_deps='os_solaris.o'
 367     os_mailer='mailx'
 368     os_solaris=yes
 369     os_man_filter=Solaris
 370     ;;
 371   *-*-netbsd*)
 372     os_deps='os_netbsd.o'
 373     os_libs='-lutil'
 374     os_man_filter=NetBSD
 375     ;;
 376   *-*-openbsd*)
 377     os_deps='os_openbsd.o'
 378     os_libs='-lutil'
 379     os_dltools='curl wget lynx ftp'
 380     os_man_filter=OpenBSD
 381     ;;
 382   *-*-cygwin*)
 383     os_deps='os_win32.o'
 384     os_win32=yes
 385     os_man_filter=Cygwin
 386     ;;
 387   x86_64-*-mingw*)
 388     os_deps='os_win32.o'
 389     os_win32=yes
 390     os_win32_mingw=yes
 391     os_win64=yes
 392     os_man_filter=Windows
 393     ;;
 394   *-*-mingw*)
 395     os_deps='os_win32.o'
 396     os_win32=yes
 397     os_win32_mingw=yes
 398     os_man_filter=Windows
 399     ;;
 400   *-*-darwin*)
 401     os_deps='os_darwin.o'
 402     os_libs='-framework CoreFoundation -framework IOKit'
 403     os_darwin=yes
 404     os_man_filter=Darwin
 405     ;;
 406   *-*-nto-qnx*)
 407     os_deps='os_qnxnto.o'
 408     ;;
 409   *)
 410     os_deps='os_generic.o'
 411     ;;
 412 esac
 413
 414 # Replace if '--with-os-deps' was specified
 415 test -z "$with_os_deps" || os_deps="$with_os_deps"
 416
 417 # Check if we need adapter to old interface (dev_legacy.cpp)
 418 os_src=`echo "${os_deps}"|sed -n 's,^\([[^ .]]*\)\.o.*$,\1.cpp,p'`
 419 AC_MSG_CHECKING([whether ${os_src} uses new interface])
 420 if grep "smart_interface" "${srcdir}/${os_src}" >/dev/null 2>&1; then
 421   os_new_interface=yes
 422 else
 423   os_new_interface=no
 424   os_deps="${os_deps} dev_legacy.o"
 425   AC_DEFINE(OLD_INTERFACE, 1, [Define to 1 if os_*.cpp still uses the old interface])
 426 fi
 427 AC_MSG_RESULT([$os_new_interface])
 428
 429 AC_SUBST([os_deps])
 430 AC_SUBST([os_libs])
 431 AC_SUBST([os_dltools])
 432 AC_SUBST([os_man_filter])
 433 if test -n "$os_mailer"; then
 434   AC_DEFINE_UNQUOTED(DEFAULT_MAILER, "$os_mailer", [Default mailer if "mail" is unavailable])
 435 fi
 436
 437 # Create drivedb.h update branch name from version: 5.41[.X] -> RELEASE_5_41_DRIVEDB
 438 DRIVEDB_BRANCH=`echo $VERSION | sed 's,^\([[0-9]]*\.[[0-9]]*\)\..*$,\1,' \
 439                 | sed -n 's,^\([[0-9]][[0-9]]*\)\.\([[0-9]][[0-9]]*\)$,RELEASE_\1_\2_DRIVEDB,p'`
 440 if test -z "$DRIVEDB_BRANCH"; then
 441   AC_MSG_ERROR([Unable to create DRIVEDB_BRANCH from VERSION=$VERSION])
 442 fi
 443 AC_SUBST([DRIVEDB_BRANCH])
 444
 445 # Enable platform-specific makefile sections
 446 AM_CONDITIONAL(OS_DARWIN, [test "$os_darwin" = "yes"])
 447 AM_CONDITIONAL(OS_SOLARIS, [test "$os_solaris" = "yes"])
 448 AM_CONDITIONAL(OS_WIN32, [test "$os_win32" = "yes"])
 449 AM_CONDITIONAL(OS_WIN32_MINGW, [test "$os_win32_mingw" = "yes"])
 450 AM_CONDITIONAL(OS_WIN32_NSIS, [test -n "$MAKENSIS"])
 451 AM_CONDITIONAL(OS_WIN32_WINDMC, [test -n "$WINDMC" && test "$WINDMC" != "no" && test -n "$WINDRES"])
 452 AM_CONDITIONAL(OS_WIN64, [test "$os_win64" = "yes"])
 453
 454 dnl Add -Wall and -W if using g++ and its not already specified.
 455 if test "$GXX" = "yes"; then
 456   if test -z "`echo "$CXXFLAGS" | grep "\-Wall" 2> /dev/null`" ; then
 457       CXXFLAGS="$CXXFLAGS -Wall"
 458   fi
 459 # In the next line, do NOT delete the 2 spaces inside double quotes.
 460   if test -z "`echo "$CXXFLAGS " | grep "\-W " 2> /dev/null`" ; then
 461       CXXFLAGS="$CXXFLAGS -W"
 462   fi
 463
 464 else
 465  dnl We are NOT using gcc, so enable host-specific compiler flags
 466  case "${host}" in
 467         sparc*-*-solaris*)
 468           dnl set CXXFLAGS for Solaris/SPARC C++ compiler
 469           if test -z "`echo "$CXXFLAGS" | grep "\-xmemalign" 2> /dev/null`" ; then
 470             dnl we have to tell the compilers about packed ATA structures
 471             CXXFLAGS="-xmemalign=1i $CXXFLAGS"
 472           fi
 473  esac
 474  case "${host}" in
 475         *-*-solaris*)
 476           if test -z "`echo "$CXXFLAGS" | grep "\-xO" 2> /dev/null`" ; then
 477             dnl turn on optimization if user has not explicitly set its value
 478             CXXFLAGS="-xO2 $CXXFLAGS"
 479           fi
 480           if test -z "`echo "$CXXFLAGS" | grep "\-erroff" 2> /dev/null`" ; then
 481             dnl suppress trivial warnings
 482             CXXFLAGS="-erroff=%none,wbadinitl,wbadasgl,badargtypel2w,badargtype2w $CXXFLAGS"
 483           fi
 484  esac
 485 fi
 486
 487 AC_DEFINE_UNQUOTED(SMARTMONTOOLS_BUILD_HOST,     "${host}",                       [smartmontools Build Host])
 488
 489 AC_SUBST(CXXFLAGS)
 490
 491 AC_CONFIG_FILES(Makefile)
 492 AC_OUTPUT
 493 AC_PROG_MAKE_SET
 494
 495 echo "-----------------------------------------------------------------------------" >&AS_MESSAGE_FD
 496 echo "${PACKAGE}-${VERSION} configuration:" >&AS_MESSAGE_FD
 497 echo "host operating system:  $host" >&AS_MESSAGE_FD
 498 echo "C++ compiler:           $CXX" >&AS_MESSAGE_FD
 499 echo "C compiler:             $CC" >&AS_MESSAGE_FD
 500 echo "preprocessor flags:     $CPPFLAGS" >&AS_MESSAGE_FD
 501 echo "C++ compiler flags:     $CXXFLAGS" >&AS_MESSAGE_FD
 502 echo "C compiler flags:       $CFLAGS" >&AS_MESSAGE_FD
 503 echo "linker flags:           $LDFLAGS" >&AS_MESSAGE_FD
 504 echo "OS specific modules:    $os_deps $os_libs $LIBS" >&AS_MESSAGE_FD
 505
 506 case "$host_os" in
 507   mingw*)
 508     echo "resource compiler:      $WINDRES" >&AS_MESSAGE_FD
 509     echo "message compiler:       $WINDMC" >&AS_MESSAGE_FD
 510     echo "NSIS compiler:          $MAKENSIS" >&AS_MESSAGE_FD
 511     if test -n "$drivedbdir"; then
 512       echo "drive database file:    EXEDIR/drivedb.h" >&AS_MESSAGE_FD
 513       if test -n "$MAKENSIS"; then
 514         echo "database update tool:   EXEDIR/update-smart-drivedb.exe" >&AS_MESSAGE_FD
 515       fi
 516     else
 517       echo "drive database file:    [[disabled]]" >&AS_MESSAGE_FD
 518     fi
 519     if test -n "$savestates"; then
 520       echo "smartd save files:      `eval eval eval echo $savestates`MODEL-SERIAL.TYPE.state" >&AS_MESSAGE_FD
 521     fi
 522     if test -n "$attributelog"; then
 523       echo "smartd attribute logs:  `eval eval eval echo $attributelog`MODEL-SERIAL.TYPE.csv" >&AS_MESSAGE_FD
 524     fi
 525     ;;
 526
 527   *)
 528     echo "binary install path:    `eval eval eval echo $sbindir`" >&AS_MESSAGE_FD
 529     echo "man page install path:  `eval eval eval echo $mandir`" >&AS_MESSAGE_FD
 530     echo "doc file install path:  `eval eval eval echo $docdir`" >&AS_MESSAGE_FD
 531     echo "examples install path:  `eval eval eval echo $exampledir`" >&AS_MESSAGE_FD
 532     if test -n "$drivedbdir"; then
 533       echo "drive database file:    `eval eval eval echo $drivedbdir`/drivedb.h" >&AS_MESSAGE_FD
 534       echo "database update script: `eval eval eval echo $sbindir`/update-smart-drivedb" >&AS_MESSAGE_FD
 535       echo "download tools:         `eval eval eval echo $os_dltools`" >&AS_MESSAGE_FD
 536     else
 537       echo "drive database file:    [[disabled]]" >&AS_MESSAGE_FD
 538     fi
 539     echo "local drive database:   `eval eval eval echo $sysconfdir`/smart_drivedb.h" >&AS_MESSAGE_FD
 540     echo "smartd config file:     `eval eval eval echo $sysconfdir`/smartd.conf${smartd_suffix}" >&AS_MESSAGE_FD
 541     if test -n "$initddir"; then
 542       echo "smartd initd script:    `eval eval eval echo $initddir`/smartd${smartd_suffix}" >&AS_MESSAGE_FD
 543     elif test -z "$systemdsystemunitdir"; then
 544       echo "smartd initd script:    [[disabled]]" >&AS_MESSAGE_FD
 545     fi
 546     if test -n "$systemdsystemunitdir"; then
 547       echo "smartd systemd file:    `eval eval eval echo $systemdsystemunitdir`/smartd.service" >&AS_MESSAGE_FD
 548     fi
 549     if test -n "$savestates"; then
 550       echo "smartd save files:      `eval eval eval echo $savestates`MODEL-SERIAL.TYPE.state" >&AS_MESSAGE_FD
 551     else
 552       echo "smartd save files:      [[disabled]]" >&AS_MESSAGE_FD
 553     fi
 554     if test -n "$attributelog"; then
 555       echo "smartd attribute logs:  `eval eval eval echo $attributelog`MODEL-SERIAL.TYPE.csv" >&AS_MESSAGE_FD
 556     else
 557       echo "smartd attribute logs:  [[disabled]]" >&AS_MESSAGE_FD
 558     fi
 559     echo "libcap-ng support:      $use_libcap_ng" >&AS_MESSAGE_FD
 560     case "$host_os" in
 561       linux*) echo "SELinux support:        ${with_selinux-no}" >&AS_MESSAGE_FD ;;
 562     esac
 563     ;;
 564 esac
 565 echo "-----------------------------------------------------------------------------" >&AS_MESSAGE_FD