config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  12         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  13         ZFS_AC_KERNEL_TYPE_FMODE_T
  14         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  15         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  16         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  17         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  18         ZFS_AC_KERNEL_LOOKUP_BDEV
  19         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  20         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  21         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BIO_BVEC_ITER
  23         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  24         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  25         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  26         ZFS_AC_KERNEL_BIO_RW_BARRIER
  27         ZFS_AC_KERNEL_BIO_RW_DISCARD
  28         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  30         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  31         ZFS_AC_KERNEL_GET_DISK_RO
  32         ZFS_AC_KERNEL_GET_GENDISK
  33         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  34         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  35         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  36         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  37         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  38         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  39         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  40         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  41         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  42         ZFS_AC_KERNEL_POSIX_ACL_CACHING
  43         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  44         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  45         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  46         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  47         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  48         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  49         ZFS_AC_KERNEL_CURRENT_UMASK
  50         ZFS_AC_KERNEL_SHOW_OPTIONS
  51         ZFS_AC_KERNEL_FILE_INODE
  52         ZFS_AC_KERNEL_FSYNC
  53         ZFS_AC_KERNEL_EVICT_INODE
  54         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  55         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  56         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  57         ZFS_AC_KERNEL_FALLOCATE
  58         ZFS_AC_KERNEL_MKDIR_UMODE_T
  59         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  60         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  61         ZFS_AC_KERNEL_FOLLOW_LINK
  62         ZFS_AC_KERNEL_PUT_LINK
  63         ZFS_AC_KERNEL_TRUNCATE_RANGE
  64         ZFS_AC_KERNEL_AUTOMOUNT
  65         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  66         ZFS_AC_KERNEL_COMMIT_METADATA
  67         ZFS_AC_KERNEL_CLEAR_INODE
  68         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  69         ZFS_AC_KERNEL_D_MAKE_ROOT
  70         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  71         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  72         ZFS_AC_KERNEL_D_SET_D_OP
  73         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  74         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  75         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  76         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  77         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  78         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  79         ZFS_AC_KERNEL_MOUNT_NODEV
  80         ZFS_AC_KERNEL_SHRINK
  81         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  82         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  83         ZFS_AC_KERNEL_S_D_OP
  84         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  85         ZFS_AC_KERNEL_SET_NLINK
  86         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  87         ZFS_AC_KERNEL_5ARG_SGET
  88         ZFS_AC_KERNEL_LSEEK_EXECUTE
  89         ZFS_AC_KERNEL_VFS_ITERATE
  90         ZFS_AC_KERNEL_VFS_RW_ITERATE
  91         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
  92         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
  93         ZFS_AC_KERNEL_MAKE_REQUEST_FN
  94         ZFS_AC_KERNEL_GENERIC_IO_ACCT
  95
  96         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  97                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  98         ])
  99         AC_SUBST(KERNELMAKE_PARAMS)
 100
 101
 102         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 103         dnl # compiler options are added by the kernel build system.
 104         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 105         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 106         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 107         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 108
 109         AC_SUBST(KERNELCPPFLAGS)
 110 ])
 111
 112 dnl #
 113 dnl # Detect name used for Module.symvers file in kernel
 114 dnl #
 115 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 116         modpost=$LINUX/scripts/Makefile.modpost
 117         AC_MSG_CHECKING([kernel file name for module symbols])
 118         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 119                 AS_IF([grep -q Modules.symvers $modpost], [
 120                         LINUX_SYMBOLS=Modules.symvers
 121                 ], [
 122                         LINUX_SYMBOLS=Module.symvers
 123                 ])
 124
 125                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 126                         AC_MSG_ERROR([
 127         *** Please make sure the kernel devel package for your distribution
 128         *** is installed.  If you are building with a custom kernel, make sure the
 129         *** kernel is configured, built, and the '--with-linux=PATH' configure
 130         *** option refers to the location of the kernel source.])
 131                 ])
 132         ], [
 133                 LINUX_SYMBOLS=NONE
 134         ])
 135         AC_MSG_RESULT($LINUX_SYMBOLS)
 136         AC_SUBST(LINUX_SYMBOLS)
 137 ])
 138
 139 dnl #
 140 dnl # Detect the kernel to be built against
 141 dnl #
 142 AC_DEFUN([ZFS_AC_KERNEL], [
 143         AC_ARG_WITH([linux],
 144                 AS_HELP_STRING([--with-linux=PATH],
 145                 [Path to kernel source]),
 146                 [kernelsrc="$withval"])
 147
 148         AC_ARG_WITH(linux-obj,
 149                 AS_HELP_STRING([--with-linux-obj=PATH],
 150                 [Path to kernel build objects]),
 151                 [kernelbuild="$withval"])
 152
 153         AC_MSG_CHECKING([kernel source directory])
 154         AS_IF([test -z "$kernelsrc"], [
 155                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 156                         headersdir="/lib/modules/$(uname -r)/source"
 157                         sourcelink=$(readlink -f "$headersdir")
 158                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 159                         headersdir="/lib/modules/$(uname -r)/build"
 160                         sourcelink=$(readlink -f "$headersdir")
 161                 ], [
 162                         sourcelink=$(ls -1d /usr/src/kernels/* \
 163                                      /usr/src/linux-* \
 164                                      2>/dev/null | grep -v obj | tail -1)
 165                 ])
 166
 167                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 168                         kernelsrc=`readlink -f ${sourcelink}`
 169                 ], [
 170                         kernelsrc="[Not found]"
 171                 ])
 172         ], [
 173                 AS_IF([test "$kernelsrc" = "NONE"], [
 174                         kernsrcver=NONE
 175                 ])
 176         ])
 177
 178         AC_MSG_RESULT([$kernelsrc])
 179         AS_IF([test ! -d "$kernelsrc"], [
 180                 AC_MSG_ERROR([
 181         *** Please make sure the kernel devel package for your distribution
 182         *** is installed and then try again.  If that fails, you can specify the
 183         *** location of the kernel source with the '--with-linux=PATH' option.])
 184         ])
 185
 186         AC_MSG_CHECKING([kernel build directory])
 187         AS_IF([test -z "$kernelbuild"], [
 188                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 189                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 190                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 191                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 192                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 193                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 194                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 195                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 196                 ], [
 197                         kernelbuild=${kernelsrc}
 198                 ])
 199         ])
 200         AC_MSG_RESULT([$kernelbuild])
 201
 202         AC_MSG_CHECKING([kernel source version])
 203         utsrelease1=$kernelbuild/include/linux/version.h
 204         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 205         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 206         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 207                 utsrelease=linux/version.h
 208         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 209                 utsrelease=linux/utsrelease.h
 210         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 211                 utsrelease=generated/utsrelease.h
 212         ])
 213
 214         AS_IF([test "$utsrelease"], [
 215                 kernsrcver=`(echo "#include <$utsrelease>";
 216                              echo "kernsrcver=UTS_RELEASE") |
 217                              cpp -I $kernelbuild/include |
 218                              grep "^kernsrcver=" | cut -d \" -f 2`
 219
 220                 AS_IF([test -z "$kernsrcver"], [
 221                         AC_MSG_RESULT([Not found])
 222                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 223                 ])
 224         ], [
 225                 AC_MSG_RESULT([Not found])
 226                 if test "x$enable_linux_builtin" != xyes; then
 227                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 228                 else
 229                         AC_MSG_ERROR([
 230         *** Cannot find UTS_RELEASE definition.
 231         *** Please run 'make prepare' inside the kernel source tree.])
 232                 fi
 233         ])
 234
 235         AC_MSG_RESULT([$kernsrcver])
 236
 237         LINUX=${kernelsrc}
 238         LINUX_OBJ=${kernelbuild}
 239         LINUX_VERSION=${kernsrcver}
 240
 241         AC_SUBST(LINUX)
 242         AC_SUBST(LINUX_OBJ)
 243         AC_SUBST(LINUX_VERSION)
 244
 245         ZFS_AC_MODULE_SYMVERS
 246 ])
 247
 248
 249 dnl #
 250 dnl # Detect the SPL module to be built against
 251 dnl #
 252 AC_DEFUN([ZFS_AC_SPL], [
 253         AC_ARG_WITH([spl],
 254                 AS_HELP_STRING([--with-spl=PATH],
 255                 [Path to spl source]),
 256                 [splsrc="$withval"])
 257
 258         AC_ARG_WITH([spl-obj],
 259                 AS_HELP_STRING([--with-spl-obj=PATH],
 260                 [Path to spl build objects]),
 261                 [splbuild="$withval"])
 262
 263         AC_ARG_WITH([spl-timeout],
 264                 AS_HELP_STRING([--with-spl-timeout=SECS],
 265                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 266                 [timeout="$withval"], [timeout=0])
 267
 268         dnl #
 269         dnl # The existence of spl.release.in is used to identify a valid
 270         dnl # source directory.  In order of preference:
 271         dnl #
 272         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 273         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 274         splsrc2="/usr/local/src/spl-${VERSION}"
 275         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 276         splsrc4="/usr/src/spl-${VERSION}"
 277         splsrc5="../spl/"
 278         splsrc6="$LINUX"
 279
 280         AC_MSG_CHECKING([spl source directory])
 281         AS_IF([test -z "${splsrc}"], [
 282                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 283                         splsrc=${splsrc0}
 284                 ], [ test -e "${splsrc1}/spl.release.in"], [
 285                         splsrc=${splsrc1}
 286                 ], [ test -e "${splsrc2}/spl.release.in"], [
 287                         splsrc=${splsrc2}
 288                 ], [ test -e "${splsrc3}/spl.release.in"], [
 289                         splsrc=$(readlink -f "${splsrc3}")
 290                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 291                         splsrc=${splsrc4}
 292                 ], [ test -e "${splsrc5}/spl.release.in"], [
 293                         splsrc=$(readlink -f "${splsrc5}")
 294                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 295                         splsrc=${splsrc6}
 296                 ], [
 297                         splsrc="[Not found]"
 298                 ])
 299         ], [
 300                 AS_IF([test "$splsrc" = "NONE"], [
 301                         splbuild=NONE
 302                         splsrcver=NONE
 303                 ])
 304         ])
 305
 306         AC_MSG_RESULT([$splsrc])
 307         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 308                 AC_MSG_ERROR([
 309         *** Please make sure the kmod spl devel package for your distribution
 310         *** is installed then try again.  If that fails you can specify the
 311         *** location of the spl source with the '--with-spl=PATH' option.])
 312         ])
 313
 314         dnl #
 315         dnl # The existence of the spl_config.h is used to identify a valid
 316         dnl # spl object directory.  In many cases the object and source
 317         dnl # directory are the same, however the objects may also reside
 318         dnl # is a subdirectory named after the kernel version.
 319         dnl #
 320         dnl # This file is supposed to be available after DKMS finishes
 321         dnl # building the SPL kernel module for the target kernel.  The
 322         dnl # '--with-spl-timeout' option can be passed to pause here,
 323         dnl # waiting for the file to appear from a concurrently building
 324         dnl # SPL package.
 325         dnl #
 326         AC_MSG_CHECKING([spl build directory])
 327         while true; do
 328                 AS_IF([test -z "$splbuild"], [
 329                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 330                                 splbuild="${splsrc}/${LINUX_VERSION}"
 331                         ], [ test -e "${splsrc}/spl_config.h" ], [
 332                                 splbuild="${splsrc}"
 333                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 334                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 335                         ], [
 336                                 splbuild="[Not found]"
 337                         ])
 338                 ])
 339                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 340                         break;
 341                 ], [
 342                         sleep 1
 343                         timeout=$((timeout-1))
 344                 ])
 345         done
 346
 347         AC_MSG_RESULT([$splbuild])
 348         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 349                 AC_MSG_ERROR([
 350         *** Please make sure the kmod spl devel <kernel> package for your
 351         *** distribution is installed then try again.  If that fails you
 352         *** can specify the location of the spl objects with the
 353         *** '--with-spl-obj=PATH' option.])
 354         ])
 355
 356         AC_MSG_CHECKING([spl source version])
 357         AS_IF([test -r $splbuild/spl_config.h &&
 358                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 359
 360                 splsrcver=`(echo "#include <spl_config.h>";
 361                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 362                             cpp -I $splbuild |
 363                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 364         ])
 365
 366         AS_IF([test -z "$splsrcver"], [
 367                 AC_MSG_RESULT([Not found])
 368                 AC_MSG_ERROR([
 369         *** Cannot determine the version of the spl source.
 370         *** Please prepare the spl source before running this script])
 371         ])
 372
 373         AC_MSG_RESULT([$splsrcver])
 374
 375         SPL=${splsrc}
 376         SPL_OBJ=${splbuild}
 377         SPL_VERSION=${splsrcver}
 378
 379         AC_SUBST(SPL)
 380         AC_SUBST(SPL_OBJ)
 381         AC_SUBST(SPL_VERSION)
 382
 383         dnl #
 384         dnl # Detect the name used for the SPL Module.symvers file.  If one
 385         dnl # does not exist this is likely because the SPL has been configured
 386         dnl # but not built.  The '--with-spl-timeout' option can be passed
 387         dnl # to pause here, waiting for the file to appear from a concurrently
 388         dnl # building SPL package.  If the file does not appear in time, a good
 389         dnl # guess is made as to what this file will be named based on what it
 390         dnl # is named in the kernel build products.  This file will first be
 391         dnl # used at link time so if the guess is wrong the build will fail
 392         dnl # then.  This unfortunately means the ZFS package does not contain a
 393         dnl # reliable mechanism to detect symbols exported by the SPL at
 394         dnl # configure time.
 395         dnl #
 396         AC_MSG_CHECKING([spl file name for module symbols])
 397         SPL_SYMBOLS=NONE
 398
 399         while true; do
 400                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 401                         SPL_SYMBOLS=Module.symvers
 402                 ], [test -r $SPL_OBJ/Modules.symvers], [
 403                         SPL_SYMBOLS=Modules.symvers
 404                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 405                         SPL_SYMBOLS=Module.symvers
 406                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 407                         SPL_SYMBOLS=Modules.symvers
 408                 ])
 409
 410                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 411                         break;
 412                 ], [
 413                         sleep 1
 414                         timeout=$((timeout-1))
 415                 ])
 416         done
 417
 418         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 419                 SPL_SYMBOLS=$LINUX_SYMBOLS
 420         ])
 421
 422         AC_MSG_RESULT([$SPL_SYMBOLS])
 423         AC_SUBST(SPL_SYMBOLS)
 424 ])
 425
 426 dnl #
 427 dnl # Basic toolchain sanity check.
 428 dnl #
 429 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 430         AC_MSG_CHECKING([whether modules can be built])
 431         ZFS_LINUX_TRY_COMPILE([],[],[
 432                 AC_MSG_RESULT([yes])
 433         ],[
 434                 AC_MSG_RESULT([no])
 435                 if test "x$enable_linux_builtin" != xyes; then
 436                         AC_MSG_ERROR([*** Unable to build an empty module.])
 437                 else
 438                         AC_MSG_ERROR([
 439         *** Unable to build an empty module.
 440         *** Please run 'make scripts' inside the kernel source tree.])
 441                 fi
 442         ])
 443 ])
 444
 445 dnl #
 446 dnl # Certain kernel build options are not supported.  These must be
 447 dnl # detected at configure time and cause a build failure.  Otherwise
 448 dnl # modules may be successfully built that behave incorrectly.
 449 dnl #
 450 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 451         AC_RUN_IFELSE([
 452                 AC_LANG_PROGRAM([
 453                         #include "$LINUX/include/linux/license.h"
 454                 ], [
 455                         return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 456                 ])
 457         ], [
 458                 AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 459                     [Define to 1 if GPL-only symbols can be used])
 460         ], [
 461         ])
 462
 463         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 464 ])
 465
 466 dnl #
 467 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 468 dnl #
 469 dnl # This is typically only set for debug kernels because it comes with
 470 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 471 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 472 dnl # This will cause a failure at link time which we'd rather know about
 473 dnl # at compile time.
 474 dnl #
 475 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 476 dnl # with the upstream community we add a check to detect this case.
 477 dnl #
 478 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 479
 480         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 481                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 482                 tmp_flags="$EXTRA_KCFLAGS"
 483                 ZFS_LINUX_TRY_COMPILE([
 484                         #include <linux/module.h>
 485                         #include <linux/mutex.h>
 486
 487                         MODULE_LICENSE("$ZFS_META_LICENSE");
 488                 ],[
 489                         struct mutex lock;
 490
 491                         mutex_init(&lock);
 492                         mutex_lock(&lock);
 493                         mutex_unlock(&lock);
 494                 ],[
 495                         AC_MSG_RESULT(no)
 496                 ],[
 497                         AC_MSG_RESULT(yes)
 498                         AC_MSG_ERROR([
 499         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 500         *** with the CDDL license and will prevent the module linking stage
 501         *** from succeeding.  You must rebuild your kernel without this
 502         *** option enabled.])
 503                 ])
 504                 EXTRA_KCFLAGS="$tmp_flags"
 505         ], [])
 506 ])
 507
 508 dnl #
 509 dnl # ZFS_LINUX_CONFTEST_H
 510 dnl #
 511 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 512 cat - <<_ACEOF >conftest.h
 513 $1
 514 _ACEOF
 515 ])
 516
 517 dnl #
 518 dnl # ZFS_LINUX_CONFTEST_C
 519 dnl #
 520 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 521 cat confdefs.h - <<_ACEOF >conftest.c
 522 $1
 523 _ACEOF
 524 ])
 525
 526 dnl #
 527 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 528 dnl #
 529 m4_define([ZFS_LANG_PROGRAM], [
 530 $1
 531 int
 532 main (void)
 533 {
 534 dnl Do *not* indent the following line: there may be CPP directives.
 535 dnl Don't move the `;' right after for the same reason.
 536 $2
 537   ;
 538   return 0;
 539 }
 540 ])
 541
 542 dnl #
 543 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 544 dnl #
 545 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 546         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 547         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 548         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 549         echo "obj-m := conftest.o" >build/Makefile
 550         modpost_flag=''
 551         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 552         AS_IF(
 553                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 554                 [$4],
 555                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 556         )
 557         rm -Rf build
 558 ])
 559
 560 dnl #
 561 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 562 dnl #
 563 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 564         [ZFS_LINUX_COMPILE_IFELSE(
 565         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 566         [modules],
 567         [test -s build/conftest.o],
 568         [$3], [$4])
 569 ])
 570
 571 dnl #
 572 dnl # ZFS_LINUX_CONFIG
 573 dnl #
 574 AC_DEFUN([ZFS_LINUX_CONFIG],
 575         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 576         ZFS_LINUX_TRY_COMPILE([
 577                 #include <linux/module.h>
 578         ],[
 579                 #ifndef CONFIG_$1
 580                 #error CONFIG_$1 not #defined
 581                 #endif
 582         ],[
 583                 AC_MSG_RESULT([yes])
 584                 $2
 585         ],[
 586                 AC_MSG_RESULT([no])
 587                 $3
 588         ])
 589 ])
 590
 591 dnl #
 592 dnl # ZFS_CHECK_SYMBOL_EXPORT
 593 dnl # check symbol exported or not
 594 dnl #
 595 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 596         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 597                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 598         rc=$?
 599         if test $rc -ne 0; then
 600                 export=0
 601                 for file in $2; do
 602                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 603                                 "$LINUX/$file" 2>/dev/null
 604                         rc=$?
 605                         if test $rc -eq 0; then
 606                                 export=1
 607                                 break;
 608                         fi
 609                 done
 610                 if test $export -eq 0; then :
 611                         $4
 612                 else :
 613                         $3
 614                 fi
 615         else :
 616                 $3
 617         fi
 618 ])
 619
 620 dnl #
 621 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 622 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 623 dnl # is called if not compiling for builtin
 624 dnl #
 625 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 626         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 627         if test $rc -ne 0; then :
 628                 $6
 629         else
 630                 if test "x$enable_linux_builtin" != xyes; then
 631                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 632                 fi
 633                 if test $rc -ne 0; then :
 634                         $6
 635                 else :
 636                         $5
 637                 fi
 638         fi
 639 ])
 640
 641 dnl #
 642 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 643 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 644 dnl # provided via the fifth parameter
 645 dnl #
 646 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 647         [ZFS_LINUX_COMPILE_IFELSE(
 648         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 649         [modules],
 650         [test -s build/conftest.o],
 651         [$3], [$4], [$5])
 652 ])