config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_QAT
   7         ZFS_AC_KERNEL_ACCESS_OK_TYPE
   8         ZFS_AC_TEST_MODULE
   9         ZFS_AC_KERNEL_MISC_MINOR
  10         ZFS_AC_KERNEL_OBJTOOL
  11         ZFS_AC_KERNEL_CONFIG
  12         ZFS_AC_KERNEL_CTL_NAME
  13         ZFS_AC_KERNEL_PDE_DATA
  14         ZFS_AC_KERNEL_SET_FS_PWD_WITH_CONST
  15         ZFS_AC_KERNEL_2ARGS_VFS_FSYNC
  16         ZFS_AC_KERNEL_FS_STRUCT_SPINLOCK
  17         ZFS_AC_KERNEL_KUIDGID_T
  18         ZFS_AC_KERNEL_FALLOCATE
  19         ZFS_AC_KERNEL_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  20         ZFS_AC_KERNEL_RWSEM_SPINLOCK_IS_RAW
  21         ZFS_AC_KERNEL_RWSEM_ACTIVITY
  22         ZFS_AC_KERNEL_RWSEM_ATOMIC_LONG_COUNT
  23         ZFS_AC_KERNEL_SCHED_RT_HEADER
  24         ZFS_AC_KERNEL_SCHED_SIGNAL_HEADER
  25         ZFS_AC_KERNEL_IO_SCHEDULE_TIMEOUT
  26         ZFS_AC_KERNEL_4ARGS_VFS_GETATTR
  27         ZFS_AC_KERNEL_3ARGS_VFS_GETATTR
  28         ZFS_AC_KERNEL_2ARGS_VFS_GETATTR
  29         ZFS_AC_KERNEL_USLEEP_RANGE
  30         ZFS_AC_KERNEL_KMEM_CACHE_ALLOCFLAGS
  31         ZFS_AC_KERNEL_KMEM_CACHE_CREATE_USERCOPY
  32         ZFS_AC_KERNEL_WAIT_ON_BIT
  33         ZFS_AC_KERNEL_WAIT_QUEUE_ENTRY_T
  34         ZFS_AC_KERNEL_WAIT_QUEUE_HEAD_ENTRY
  35         ZFS_AC_KERNEL_INODE_TIMES
  36         ZFS_AC_KERNEL_INODE_LOCK
  37         ZFS_AC_KERNEL_GROUP_INFO_GID
  38         ZFS_AC_KERNEL_WRITE
  39         ZFS_AC_KERNEL_READ
  40         ZFS_AC_KERNEL_TIMER_SETUP
  41         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  42         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  43         ZFS_AC_KERNEL_SUPER_USER_NS
  44         ZFS_AC_KERNEL_SUBMIT_BIO
  45         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_CHECK_EVENTS
  46         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  47         ZFS_AC_KERNEL_TYPE_FMODE_T
  48         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  49         ZFS_AC_KERNEL_BLKDEV_REREAD_PART
  50         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  51         ZFS_AC_KERNEL_LOOKUP_BDEV
  52         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  53         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  54         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  55         ZFS_AC_KERNEL_BIO_BVEC_ITER
  56         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  57         ZFS_AC_KERNEL_BIO_SET_DEV
  58         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  59         ZFS_AC_KERNEL_REQ_OP_DISCARD
  60         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  61         ZFS_AC_KERNEL_REQ_OP_FLUSH
  62         ZFS_AC_KERNEL_BIO_BI_OPF
  63         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  64         ZFS_AC_KERNEL_BIO_BI_STATUS
  65         ZFS_AC_KERNEL_BIO_RW_BARRIER
  66         ZFS_AC_KERNEL_BIO_RW_DISCARD
  67         ZFS_AC_KERNEL_BLK_QUEUE_BDI
  68         ZFS_AC_KERNEL_BLK_QUEUE_FLAG_CLEAR
  69         ZFS_AC_KERNEL_BLK_QUEUE_FLAG_SET
  70         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  71         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  72         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  73         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  74         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  75         ZFS_AC_KERNEL_GET_DISK_AND_MODULE
  76         ZFS_AC_KERNEL_GET_DISK_RO
  77         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  78         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  79         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  80         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  81         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  82         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  83         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  84         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  85         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  86         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  87         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  88         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  89         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  90         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  91         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  92         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  93         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  94         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  95         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  96         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  97         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  98         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  99         ZFS_AC_KERNEL_INODE_SET_FLAGS
 100         ZFS_AC_KERNEL_INODE_SET_IVERSION
 101         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
 102         ZFS_AC_KERNEL_SHOW_OPTIONS
 103         ZFS_AC_KERNEL_FILE_INODE
 104         ZFS_AC_KERNEL_FILE_DENTRY
 105         ZFS_AC_KERNEL_FSYNC
 106         ZFS_AC_KERNEL_EVICT_INODE
 107         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
 108         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
 109         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
 110         ZFS_AC_KERNEL_FALLOCATE
 111         ZFS_AC_KERNEL_AIO_FSYNC
 112         ZFS_AC_KERNEL_MKDIR_UMODE_T
 113         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
 114         ZFS_AC_KERNEL_CREATE_NAMEIDATA
 115         ZFS_AC_KERNEL_GET_LINK
 116         ZFS_AC_KERNEL_PUT_LINK
 117         ZFS_AC_KERNEL_TMPFILE
 118         ZFS_AC_KERNEL_TRUNCATE_RANGE
 119         ZFS_AC_KERNEL_AUTOMOUNT
 120         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
 121         ZFS_AC_KERNEL_COMMIT_METADATA
 122         ZFS_AC_KERNEL_CLEAR_INODE
 123         ZFS_AC_KERNEL_SETATTR_PREPARE
 124         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
 125         ZFS_AC_KERNEL_D_MAKE_ROOT
 126         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
 127         ZFS_AC_KERNEL_D_PRUNE_ALIASES
 128         ZFS_AC_KERNEL_D_SET_D_OP
 129         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
 130         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
 131         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
 132         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
 133         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
 134         ZFS_AC_KERNEL_FST_MOUNT
 135         ZFS_AC_KERNEL_SHRINK
 136         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
 137         ZFS_AC_KERNEL_SHRINK_CONTROL_STRUCT
 138         ZFS_AC_KERNEL_SHRINKER_CALLBACK
 139         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
 140         ZFS_AC_KERNEL_S_D_OP
 141         ZFS_AC_KERNEL_BDI
 142         ZFS_AC_KERNEL_SET_NLINK
 143         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 144         ZFS_AC_KERNEL_5ARG_SGET
 145         ZFS_AC_KERNEL_LSEEK_EXECUTE
 146         ZFS_AC_KERNEL_VFS_ITERATE
 147         ZFS_AC_KERNEL_VFS_RW_ITERATE
 148         ZFS_AC_KERNEL_VFS_DIRECT_IO
 149         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 150         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 151         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 152         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 153         ZFS_AC_KERNEL_GENERIC_IO_ACCT_3ARG
 154         ZFS_AC_KERNEL_GENERIC_IO_ACCT_4ARG
 155         ZFS_AC_KERNEL_FPU
 156         ZFS_AC_KERNEL_KUID_HELPERS
 157         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 158         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 159         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 160         ZFS_AC_KERNEL_CURRENT_TIME
 161         ZFS_AC_KERNEL_GLOBAL_PAGE_STATE
 162         ZFS_AC_KERNEL_ACL_HAS_REFCOUNT
 163         ZFS_AC_KERNEL_USERNS_CAPABILITIES
 164         ZFS_AC_KERNEL_IN_COMPAT_SYSCALL
 165         ZFS_AC_KERNEL_KTIME_GET_COARSE_REAL_TS64
 166         ZFS_AC_KERNEL_TOTALRAM_PAGES_FUNC
 167         ZFS_AC_KERNEL_TOTALHIGH_PAGES
 168         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
 169         ZFS_AC_KERNEL_BLK_QUEUE_SECURE_ERASE
 170
 171         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 172                 KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
 173         ])
 174
 175         AC_SUBST(KERNEL_MAKE)
 176 ])
 177
 178 dnl #
 179 dnl # Detect name used for Module.symvers file in kernel
 180 dnl #
 181 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 182         modpost=$LINUX/scripts/Makefile.modpost
 183         AC_MSG_CHECKING([kernel file name for module symbols])
 184         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 185                 AS_IF([grep -q Modules.symvers $modpost], [
 186                         LINUX_SYMBOLS=Modules.symvers
 187                 ], [
 188                         LINUX_SYMBOLS=Module.symvers
 189                 ])
 190
 191                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 192                         AC_MSG_ERROR([
 193         *** Please make sure the kernel devel package for your distribution
 194         *** is installed.  If you are building with a custom kernel, make sure the
 195         *** kernel is configured, built, and the '--with-linux=PATH' configure
 196         *** option refers to the location of the kernel source.])
 197                 ])
 198         ], [
 199                 LINUX_SYMBOLS=NONE
 200         ])
 201         AC_MSG_RESULT($LINUX_SYMBOLS)
 202         AC_SUBST(LINUX_SYMBOLS)
 203 ])
 204
 205 dnl #
 206 dnl # Detect the kernel to be built against
 207 dnl #
 208 AC_DEFUN([ZFS_AC_KERNEL], [
 209         AC_ARG_WITH([linux],
 210                 AS_HELP_STRING([--with-linux=PATH],
 211                 [Path to kernel source]),
 212                 [kernelsrc="$withval"])
 213
 214         AC_ARG_WITH(linux-obj,
 215                 AS_HELP_STRING([--with-linux-obj=PATH],
 216                 [Path to kernel build objects]),
 217                 [kernelbuild="$withval"])
 218
 219         AC_MSG_CHECKING([kernel source directory])
 220         AS_IF([test -z "$kernelsrc"], [
 221                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 222                         headersdir="/lib/modules/$(uname -r)/source"
 223                         sourcelink=$(readlink -f "$headersdir")
 224                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 225                         headersdir="/lib/modules/$(uname -r)/build"
 226                         sourcelink=$(readlink -f "$headersdir")
 227                 ], [
 228                         sourcelink=$(ls -1d /usr/src/kernels/* \
 229                                      /usr/src/linux-* \
 230                                      2>/dev/null | grep -v obj | tail -1)
 231                 ])
 232
 233                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 234                         kernelsrc=`readlink -f ${sourcelink}`
 235                 ], [
 236                         kernelsrc="[Not found]"
 237                 ])
 238         ], [
 239                 AS_IF([test "$kernelsrc" = "NONE"], [
 240                         kernsrcver=NONE
 241                 ])
 242                 withlinux=yes
 243         ])
 244
 245         AC_MSG_RESULT([$kernelsrc])
 246         AS_IF([test ! -d "$kernelsrc"], [
 247                 AC_MSG_ERROR([
 248         *** Please make sure the kernel devel package for your distribution
 249         *** is installed and then try again.  If that fails, you can specify the
 250         *** location of the kernel source with the '--with-linux=PATH' option.])
 251         ])
 252
 253         AC_MSG_CHECKING([kernel build directory])
 254         AS_IF([test -z "$kernelbuild"], [
 255                 AS_IF([test x$withlinux != xyes -a -e "/lib/modules/$(uname -r)/build"], [
 256                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 257                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 258                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 259                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 260                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 261                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 262                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 263                 ], [
 264                         kernelbuild=${kernelsrc}
 265                 ])
 266         ])
 267         AC_MSG_RESULT([$kernelbuild])
 268
 269         AC_MSG_CHECKING([kernel source version])
 270         utsrelease1=$kernelbuild/include/linux/version.h
 271         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 272         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 273         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 274                 utsrelease=linux/version.h
 275         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 276                 utsrelease=linux/utsrelease.h
 277         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 278                 utsrelease=generated/utsrelease.h
 279         ])
 280
 281         AS_IF([test "$utsrelease"], [
 282                 kernsrcver=`(echo "#include <$utsrelease>";
 283                              echo "kernsrcver=UTS_RELEASE") |
 284                              ${CPP} -I $kernelbuild/include - |
 285                              grep "^kernsrcver=" | cut -d \" -f 2`
 286
 287                 AS_IF([test -z "$kernsrcver"], [
 288                         AC_MSG_RESULT([Not found])
 289                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 290                 ])
 291         ], [
 292                 AC_MSG_RESULT([Not found])
 293                 if test "x$enable_linux_builtin" != xyes; then
 294                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 295                 else
 296                         AC_MSG_ERROR([
 297         *** Cannot find UTS_RELEASE definition.
 298         *** Please run 'make prepare' inside the kernel source tree.])
 299                 fi
 300         ])
 301
 302         AC_MSG_RESULT([$kernsrcver])
 303
 304         LINUX=${kernelsrc}
 305         LINUX_OBJ=${kernelbuild}
 306         LINUX_VERSION=${kernsrcver}
 307
 308         AC_SUBST(LINUX)
 309         AC_SUBST(LINUX_OBJ)
 310         AC_SUBST(LINUX_VERSION)
 311
 312         ZFS_AC_MODULE_SYMVERS
 313 ])
 314
 315 dnl #
 316 dnl # Detect the QAT module to be built against
 317 dnl # QAT provides hardware acceleration for data compression:
 318 dnl #   https://01.org/intel-quickassist-technology
 319 dnl # * Download and install QAT driver from the above link
 320 dnl # * Start QAT driver in your system:
 321 dnl #   service qat_service start
 322 dnl # * Enable QAT in ZFS, e.g.:
 323 dnl #   ./configure --with-qat=<qat-driver-path>/QAT1.6
 324 dnl #   make
 325 dnl # * Set GZIP compression in ZFS dataset:
 326 dnl #   zfs set compression = gzip <dataset>
 327 dnl # Then the data written to this ZFS pool is compressed
 328 dnl # by QAT accelerator automatically, and de-compressed by
 329 dnl # QAT when read from the pool.
 330 dnl # * Get QAT hardware statistics by:
 331 dnl #   cat /proc/icp_dh895xcc_dev/qat
 332 dnl # * To disable QAT:
 333 dnl #   insmod zfs.ko zfs_qat_disable=1
 334 dnl #
 335 AC_DEFUN([ZFS_AC_QAT], [
 336         AC_ARG_WITH([qat],
 337                 AS_HELP_STRING([--with-qat=PATH],
 338                 [Path to qat source]),
 339                 AS_IF([test "$withval" = "yes"],
 340                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 341                         [qatsrc="$withval"]))
 342
 343         AC_ARG_WITH([qat-obj],
 344                 AS_HELP_STRING([--with-qat-obj=PATH],
 345                 [Path to qat build objects]),
 346                 [qatbuild="$withval"])
 347
 348         AS_IF([test ! -z "${qatsrc}"], [
 349                 AC_MSG_CHECKING([qat source directory])
 350                 AC_MSG_RESULT([$qatsrc])
 351                 QAT_SRC="${qatsrc}/quickassist"
 352                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 353                         AC_MSG_ERROR([
 354                 *** Please make sure the qat driver package is installed
 355                 *** and specify the location of the qat source with the
 356                 *** '--with-qat=PATH' option then try again. Failed to
 357                 *** find cpa.h in:
 358                 ${QAT_SRC}/include])
 359                 ])
 360         ])
 361
 362         AS_IF([test ! -z "${qatsrc}"], [
 363                 AC_MSG_CHECKING([qat build directory])
 364                 AS_IF([test -z "$qatbuild"], [
 365                         qatbuild="${qatsrc}/build"
 366                 ])
 367
 368                 AC_MSG_RESULT([$qatbuild])
 369                 QAT_OBJ=${qatbuild}
 370                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 371                         AC_MSG_ERROR([
 372                 *** Please make sure the qat driver is installed then try again.
 373                 *** Failed to find icp_qa_al.ko or qat_api.ko in:
 374                 $QAT_OBJ])
 375                 ])
 376
 377                 AC_SUBST(QAT_SRC)
 378                 AC_SUBST(QAT_OBJ)
 379
 380                 AC_DEFINE(HAVE_QAT, 1,
 381                 [qat is enabled and existed])
 382         ])
 383
 384         dnl #
 385         dnl # Detect the name used for the QAT Module.symvers file.
 386         dnl #
 387         AS_IF([test ! -z "${qatsrc}"], [
 388                 AC_MSG_CHECKING([qat file for module symbols])
 389                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 390
 391                 AS_IF([test -r $QAT_SYMBOLS], [
 392                         AC_MSG_RESULT([$QAT_SYMBOLS])
 393                         AC_SUBST(QAT_SYMBOLS)
 394                 ],[
 395                        AC_MSG_ERROR([
 396                         *** Please make sure the qat driver is installed then try again.
 397                         *** Failed to find Module.symvers in:
 398                         $QAT_SYMBOLS])
 399                         ])
 400                 ])
 401         ])
 402 ])
 403
 404 dnl #
 405 dnl # Basic toolchain sanity check.
 406 dnl #
 407 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 408         AC_MSG_CHECKING([whether modules can be built])
 409         ZFS_LINUX_TRY_COMPILE([],[],[
 410                 AC_MSG_RESULT([yes])
 411         ],[
 412                 AC_MSG_RESULT([no])
 413                 if test "x$enable_linux_builtin" != xyes; then
 414                         AC_MSG_ERROR([*** Unable to build an empty module.])
 415                 else
 416                         AC_MSG_ERROR([
 417         *** Unable to build an empty module.
 418         *** Please run 'make scripts' inside the kernel source tree.])
 419                 fi
 420         ])
 421 ])
 422
 423 dnl #
 424 dnl # Certain kernel build options are not supported.  These must be
 425 dnl # detected at configure time and cause a build failure.  Otherwise
 426 dnl # modules may be successfully built that behave incorrectly.
 427 dnl #
 428 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 429         AS_IF([test "x$cross_compiling" != xyes], [
 430                 AC_RUN_IFELSE([
 431                         AC_LANG_PROGRAM([
 432                                 #include "$LINUX/include/linux/license.h"
 433                         ], [
 434                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 435                         ])
 436                 ], [
 437                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 438                             [Define to 1 if GPL-only symbols can be used])
 439                 ], [
 440                 ])
 441         ])
 442
 443         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 444         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 445         ZFS_AC_KERNEL_CONFIG_TRIM_UNUSED_KSYMS
 446         ZFS_AC_KERNEL_CONFIG_ZLIB_INFLATE
 447         ZFS_AC_KERNEL_CONFIG_ZLIB_DEFLATE
 448 ])
 449
 450 dnl #
 451 dnl # Check configured THREAD_SIZE
 452 dnl #
 453 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 454 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 455 dnl # on newer kernels and some architectures stack usage optimizations can be
 456 dnl # conditionally applied to improve performance without negatively impacting
 457 dnl # stability.
 458 dnl #
 459 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 460         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 461         ZFS_LINUX_TRY_COMPILE([
 462                 #include <linux/module.h>
 463         ],[
 464                 #if (THREAD_SIZE < 16384)
 465                 #error "THREAD_SIZE is less than 16K"
 466                 #endif
 467         ],[
 468                 AC_MSG_RESULT([yes])
 469                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 470         ],[
 471                 AC_MSG_RESULT([no])
 472         ])
 473 ])
 474
 475 dnl #
 476 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 477 dnl #
 478 dnl # This is typically only set for debug kernels because it comes with
 479 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 480 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 481 dnl # This will cause a failure at link time which we'd rather know about
 482 dnl # at compile time.
 483 dnl #
 484 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 485 dnl # with the upstream community we add a check to detect this case.
 486 dnl #
 487 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 488
 489         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 490                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 491                 tmp_flags="$EXTRA_KCFLAGS"
 492                 ZFS_LINUX_TRY_COMPILE([
 493                         #include <linux/module.h>
 494                         #include <linux/mutex.h>
 495
 496                         MODULE_LICENSE("$ZFS_META_LICENSE");
 497                 ],[
 498                         struct mutex lock;
 499
 500                         mutex_init(&lock);
 501                         mutex_lock(&lock);
 502                         mutex_unlock(&lock);
 503                 ],[
 504                         AC_MSG_RESULT(no)
 505                 ],[
 506                         AC_MSG_RESULT(yes)
 507                         AC_MSG_ERROR([
 508         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 509         *** with the CDDL license and will prevent the module linking stage
 510         *** from succeeding.  You must rebuild your kernel without this
 511         *** option enabled.])
 512                 ])
 513                 EXTRA_KCFLAGS="$tmp_flags"
 514         ], [])
 515 ])
 516
 517 dnl #
 518 dnl # Check CONFIG_TRIM_UNUSED_KSYMS
 519 dnl #
 520 dnl # Verify the kernel has CONFIG_TRIM_UNUSED_KSYMS disabled.
 521 dnl #
 522 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_TRIM_UNUSED_KSYMS], [
 523         AC_MSG_CHECKING([whether CONFIG_TRIM_UNUSED_KSYM is disabled])
 524         ZFS_LINUX_TRY_COMPILE([
 525                 #if defined(CONFIG_TRIM_UNUSED_KSYMS)
 526                 #error CONFIG_TRIM_UNUSED_KSYMS not defined
 527                 #endif
 528         ],[ ],[
 529                 AC_MSG_RESULT([yes])
 530         ],[
 531                 AC_MSG_RESULT([no])
 532                 AC_MSG_ERROR([
 533         *** This kernel has unused symbols trimming enabled, please disable.
 534         *** Rebuild the kernel with CONFIG_TRIM_UNUSED_KSYMS=n set.])
 535         ])
 536 ])
 537
 538 dnl #
 539 dnl # ZFS_LINUX_CONFTEST_H
 540 dnl #
 541 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 542 cat - <<_ACEOF >conftest.h
 543 $1
 544 _ACEOF
 545 ])
 546
 547 dnl #
 548 dnl # ZFS_LINUX_CONFTEST_C
 549 dnl #
 550 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 551 cat confdefs.h - <<_ACEOF >conftest.c
 552 $1
 553 _ACEOF
 554 ])
 555
 556 dnl #
 557 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 558 dnl #
 559 m4_define([ZFS_LANG_PROGRAM], [
 560 $1
 561 int
 562 main (void)
 563 {
 564 dnl Do *not* indent the following line: there may be CPP directives.
 565 dnl Don't move the `;' right after for the same reason.
 566 $2
 567   ;
 568   return 0;
 569 }
 570 ])
 571
 572 dnl #
 573 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 574 dnl #
 575 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 576         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 577         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 578         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 579         echo "obj-m := conftest.o" >build/Makefile
 580         modpost_flag=''
 581         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 582         AS_IF(
 583                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $FRAME_LARGER_THAN $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 584                 [$4],
 585                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 586         )
 587         rm -Rf build
 588 ])
 589
 590 dnl #
 591 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 592 dnl #
 593 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 594         [ZFS_LINUX_COMPILE_IFELSE(
 595         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 596         [modules],
 597         [test -s build/conftest.o],
 598         [$3], [$4])
 599 ])
 600
 601 dnl #
 602 dnl # ZFS_LINUX_CONFIG
 603 dnl #
 604 AC_DEFUN([ZFS_LINUX_CONFIG],
 605         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 606         ZFS_LINUX_TRY_COMPILE([
 607                 #include <linux/module.h>
 608         ],[
 609                 #ifndef CONFIG_$1
 610                 #error CONFIG_$1 not #defined
 611                 #endif
 612         ],[
 613                 AC_MSG_RESULT([yes])
 614                 $2
 615         ],[
 616                 AC_MSG_RESULT([no])
 617                 $3
 618         ])
 619 ])
 620
 621 dnl #
 622 dnl # ZFS_CHECK_SYMBOL_EXPORT
 623 dnl # check symbol exported or not
 624 dnl #
 625 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 626         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 627                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 628         rc=$?
 629         if test $rc -ne 0; then
 630                 export=0
 631                 for file in $2; do
 632                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 633                                 "$LINUX/$file" 2>/dev/null
 634                         rc=$?
 635                         if test $rc -eq 0; then
 636                                 export=1
 637                                 break;
 638                         fi
 639                 done
 640                 if test $export -eq 0; then :
 641                         $4
 642                 else :
 643                         $3
 644                 fi
 645         else :
 646                 $3
 647         fi
 648 ])
 649
 650 dnl #
 651 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 652 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 653 dnl # is called if not compiling for builtin
 654 dnl #
 655 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 656         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 657         if test $rc -ne 0; then :
 658                 $6
 659         else
 660                 if test "x$enable_linux_builtin" != xyes; then
 661                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 662                 fi
 663                 if test $rc -ne 0; then :
 664                         $6
 665                 else :
 666                         $5
 667                 fi
 668         fi
 669 ])
 670
 671 dnl #
 672 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 673 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 674 dnl # provided via the fifth parameter
 675 dnl #
 676 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 677         [ZFS_LINUX_COMPILE_IFELSE(
 678         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 679         [modules],
 680         [test -s build/conftest.o],
 681         [$3], [$4], [$5])
 682 ])