config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_QAT
   7         ZFS_AC_KERNEL_ACCESS_OK_TYPE
   8         ZFS_AC_TEST_MODULE
   9         ZFS_AC_KERNEL_MISC_MINOR
  10         ZFS_AC_KERNEL_OBJTOOL
  11         ZFS_AC_KERNEL_CONFIG
  12         ZFS_AC_KERNEL_CTL_NAME
  13         ZFS_AC_KERNEL_PDE_DATA
  14         ZFS_AC_KERNEL_SET_FS_PWD_WITH_CONST
  15         ZFS_AC_KERNEL_2ARGS_VFS_FSYNC
  16         ZFS_AC_KERNEL_FS_STRUCT_SPINLOCK
  17         ZFS_AC_KERNEL_KUIDGID_T
  18         ZFS_AC_KERNEL_FALLOCATE
  19         ZFS_AC_KERNEL_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  20         ZFS_AC_KERNEL_RWSEM_SPINLOCK_IS_RAW
  21         ZFS_AC_KERNEL_RWSEM_ACTIVITY
  22         ZFS_AC_KERNEL_RWSEM_ATOMIC_LONG_COUNT
  23         ZFS_AC_KERNEL_SCHED_RT_HEADER
  24         ZFS_AC_KERNEL_SCHED_SIGNAL_HEADER
  25         ZFS_AC_KERNEL_IO_SCHEDULE_TIMEOUT
  26         ZFS_AC_KERNEL_4ARGS_VFS_GETATTR
  27         ZFS_AC_KERNEL_3ARGS_VFS_GETATTR
  28         ZFS_AC_KERNEL_2ARGS_VFS_GETATTR
  29         ZFS_AC_KERNEL_USLEEP_RANGE
  30         ZFS_AC_KERNEL_KMEM_CACHE_ALLOCFLAGS
  31         ZFS_AC_KERNEL_KMEM_CACHE_CREATE_USERCOPY
  32         ZFS_AC_KERNEL_WAIT_ON_BIT
  33         ZFS_AC_KERNEL_WAIT_QUEUE_ENTRY_T
  34         ZFS_AC_KERNEL_WAIT_QUEUE_HEAD_ENTRY
  35         ZFS_AC_KERNEL_INODE_TIMES
  36         ZFS_AC_KERNEL_INODE_LOCK
  37         ZFS_AC_KERNEL_GROUP_INFO_GID
  38         ZFS_AC_KERNEL_WRITE
  39         ZFS_AC_KERNEL_READ
  40         ZFS_AC_KERNEL_TIMER_FUNCTION_TIMER_LIST
  41         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  42         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  43         ZFS_AC_KERNEL_SUPER_USER_NS
  44         ZFS_AC_KERNEL_SUBMIT_BIO
  45         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_CHECK_EVENTS
  46         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  47         ZFS_AC_KERNEL_TYPE_FMODE_T
  48         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  49         ZFS_AC_KERNEL_BLKDEV_REREAD_PART
  50         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  51         ZFS_AC_KERNEL_LOOKUP_BDEV
  52         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  53         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  54         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  55         ZFS_AC_KERNEL_BIO_BVEC_ITER
  56         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  57         ZFS_AC_KERNEL_BIO_SET_DEV
  58         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  59         ZFS_AC_KERNEL_REQ_OP_DISCARD
  60         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  61         ZFS_AC_KERNEL_REQ_OP_FLUSH
  62         ZFS_AC_KERNEL_BIO_BI_OPF
  63         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  64         ZFS_AC_KERNEL_BIO_BI_STATUS
  65         ZFS_AC_KERNEL_BIO_RW_BARRIER
  66         ZFS_AC_KERNEL_BIO_RW_DISCARD
  67         ZFS_AC_KERNEL_BLK_QUEUE_BDI
  68         ZFS_AC_KERNEL_BLK_QUEUE_FLAG_CLEAR
  69         ZFS_AC_KERNEL_BLK_QUEUE_FLAG_SET
  70         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  71         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  72         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  73         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  74         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  75         ZFS_AC_KERNEL_GET_DISK_AND_MODULE
  76         ZFS_AC_KERNEL_GET_DISK_RO
  77         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  78         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  79         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  80         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  81         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  82         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  83         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  84         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  85         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  86         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  87         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  88         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  89         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  90         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  91         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  92         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  93         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  94         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  95         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  96         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  97         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  98         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  99         ZFS_AC_KERNEL_INODE_SET_FLAGS
 100         ZFS_AC_KERNEL_INODE_SET_IVERSION
 101         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
 102         ZFS_AC_KERNEL_SHOW_OPTIONS
 103         ZFS_AC_KERNEL_FILE_INODE
 104         ZFS_AC_KERNEL_FILE_DENTRY
 105         ZFS_AC_KERNEL_FSYNC
 106         ZFS_AC_KERNEL_EVICT_INODE
 107         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
 108         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
 109         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
 110         ZFS_AC_KERNEL_FALLOCATE
 111         ZFS_AC_KERNEL_AIO_FSYNC
 112         ZFS_AC_KERNEL_MKDIR_UMODE_T
 113         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
 114         ZFS_AC_KERNEL_CREATE_NAMEIDATA
 115         ZFS_AC_KERNEL_GET_LINK
 116         ZFS_AC_KERNEL_PUT_LINK
 117         ZFS_AC_KERNEL_TMPFILE
 118         ZFS_AC_KERNEL_TRUNCATE_RANGE
 119         ZFS_AC_KERNEL_AUTOMOUNT
 120         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
 121         ZFS_AC_KERNEL_COMMIT_METADATA
 122         ZFS_AC_KERNEL_CLEAR_INODE
 123         ZFS_AC_KERNEL_SETATTR_PREPARE
 124         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
 125         ZFS_AC_KERNEL_D_MAKE_ROOT
 126         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
 127         ZFS_AC_KERNEL_D_PRUNE_ALIASES
 128         ZFS_AC_KERNEL_D_SET_D_OP
 129         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
 130         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
 131         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
 132         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
 133         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
 134         ZFS_AC_KERNEL_FST_MOUNT
 135         ZFS_AC_KERNEL_SHRINK
 136         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
 137         ZFS_AC_KERNEL_SHRINK_CONTROL_STRUCT
 138         ZFS_AC_KERNEL_SHRINKER_CALLBACK
 139         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
 140         ZFS_AC_KERNEL_S_D_OP
 141         ZFS_AC_KERNEL_BDI
 142         ZFS_AC_KERNEL_SET_NLINK
 143         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 144         ZFS_AC_KERNEL_5ARG_SGET
 145         ZFS_AC_KERNEL_LSEEK_EXECUTE
 146         ZFS_AC_KERNEL_VFS_ITERATE
 147         ZFS_AC_KERNEL_VFS_RW_ITERATE
 148         ZFS_AC_KERNEL_VFS_DIRECT_IO
 149         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 150         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 151         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 152         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 153         ZFS_AC_KERNEL_GENERIC_IO_ACCT_3ARG
 154         ZFS_AC_KERNEL_GENERIC_IO_ACCT_4ARG
 155         ZFS_AC_KERNEL_FPU
 156         ZFS_AC_KERNEL_KUID_HELPERS
 157         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 158         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 159         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 160         ZFS_AC_KERNEL_CURRENT_TIME
 161         ZFS_AC_KERNEL_GLOBAL_PAGE_STATE
 162         ZFS_AC_KERNEL_ACL_HAS_REFCOUNT
 163         ZFS_AC_KERNEL_USERNS_CAPABILITIES
 164         ZFS_AC_KERNEL_IN_COMPAT_SYSCALL
 165         ZFS_AC_KERNEL_KTIME_GET_COARSE_REAL_TS64
 166         ZFS_AC_KERNEL_TOTALRAM_PAGES_FUNC
 167
 168         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 169                 KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
 170         ])
 171
 172         AC_SUBST(KERNEL_MAKE)
 173 ])
 174
 175 dnl #
 176 dnl # Detect name used for Module.symvers file in kernel
 177 dnl #
 178 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 179         modpost=$LINUX/scripts/Makefile.modpost
 180         AC_MSG_CHECKING([kernel file name for module symbols])
 181         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 182                 AS_IF([grep -q Modules.symvers $modpost], [
 183                         LINUX_SYMBOLS=Modules.symvers
 184                 ], [
 185                         LINUX_SYMBOLS=Module.symvers
 186                 ])
 187
 188                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 189                         AC_MSG_ERROR([
 190         *** Please make sure the kernel devel package for your distribution
 191         *** is installed.  If you are building with a custom kernel, make sure the
 192         *** kernel is configured, built, and the '--with-linux=PATH' configure
 193         *** option refers to the location of the kernel source.])
 194                 ])
 195         ], [
 196                 LINUX_SYMBOLS=NONE
 197         ])
 198         AC_MSG_RESULT($LINUX_SYMBOLS)
 199         AC_SUBST(LINUX_SYMBOLS)
 200 ])
 201
 202 dnl #
 203 dnl # Detect the kernel to be built against
 204 dnl #
 205 AC_DEFUN([ZFS_AC_KERNEL], [
 206         AC_ARG_WITH([linux],
 207                 AS_HELP_STRING([--with-linux=PATH],
 208                 [Path to kernel source]),
 209                 [kernelsrc="$withval"])
 210
 211         AC_ARG_WITH(linux-obj,
 212                 AS_HELP_STRING([--with-linux-obj=PATH],
 213                 [Path to kernel build objects]),
 214                 [kernelbuild="$withval"])
 215
 216         AC_MSG_CHECKING([kernel source directory])
 217         AS_IF([test -z "$kernelsrc"], [
 218                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 219                         headersdir="/lib/modules/$(uname -r)/source"
 220                         sourcelink=$(readlink -f "$headersdir")
 221                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 222                         headersdir="/lib/modules/$(uname -r)/build"
 223                         sourcelink=$(readlink -f "$headersdir")
 224                 ], [
 225                         sourcelink=$(ls -1d /usr/src/kernels/* \
 226                                      /usr/src/linux-* \
 227                                      2>/dev/null | grep -v obj | tail -1)
 228                 ])
 229
 230                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 231                         kernelsrc=`readlink -f ${sourcelink}`
 232                 ], [
 233                         kernelsrc="[Not found]"
 234                 ])
 235         ], [
 236                 AS_IF([test "$kernelsrc" = "NONE"], [
 237                         kernsrcver=NONE
 238                 ])
 239                 withlinux=yes
 240         ])
 241
 242         AC_MSG_RESULT([$kernelsrc])
 243         AS_IF([test ! -d "$kernelsrc"], [
 244                 AC_MSG_ERROR([
 245         *** Please make sure the kernel devel package for your distribution
 246         *** is installed and then try again.  If that fails, you can specify the
 247         *** location of the kernel source with the '--with-linux=PATH' option.])
 248         ])
 249
 250         AC_MSG_CHECKING([kernel build directory])
 251         AS_IF([test -z "$kernelbuild"], [
 252                 AS_IF([test x$withlinux != xyes -a -e "/lib/modules/$(uname -r)/build"], [
 253                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 254                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 255                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 256                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 257                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 258                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 259                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 260                 ], [
 261                         kernelbuild=${kernelsrc}
 262                 ])
 263         ])
 264         AC_MSG_RESULT([$kernelbuild])
 265
 266         AC_MSG_CHECKING([kernel source version])
 267         utsrelease1=$kernelbuild/include/linux/version.h
 268         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 269         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 270         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 271                 utsrelease=linux/version.h
 272         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 273                 utsrelease=linux/utsrelease.h
 274         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 275                 utsrelease=generated/utsrelease.h
 276         ])
 277
 278         AS_IF([test "$utsrelease"], [
 279                 kernsrcver=`(echo "#include <$utsrelease>";
 280                              echo "kernsrcver=UTS_RELEASE") |
 281                              ${CPP} -I $kernelbuild/include - |
 282                              grep "^kernsrcver=" | cut -d \" -f 2`
 283
 284                 AS_IF([test -z "$kernsrcver"], [
 285                         AC_MSG_RESULT([Not found])
 286                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 287                 ])
 288         ], [
 289                 AC_MSG_RESULT([Not found])
 290                 if test "x$enable_linux_builtin" != xyes; then
 291                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 292                 else
 293                         AC_MSG_ERROR([
 294         *** Cannot find UTS_RELEASE definition.
 295         *** Please run 'make prepare' inside the kernel source tree.])
 296                 fi
 297         ])
 298
 299         AC_MSG_RESULT([$kernsrcver])
 300
 301         LINUX=${kernelsrc}
 302         LINUX_OBJ=${kernelbuild}
 303         LINUX_VERSION=${kernsrcver}
 304
 305         AC_SUBST(LINUX)
 306         AC_SUBST(LINUX_OBJ)
 307         AC_SUBST(LINUX_VERSION)
 308
 309         ZFS_AC_MODULE_SYMVERS
 310 ])
 311
 312 dnl #
 313 dnl # Detect the QAT module to be built against
 314 dnl # QAT provides hardware acceleration for data compression:
 315 dnl #   https://01.org/intel-quickassist-technology
 316 dnl # * Download and install QAT driver from the above link
 317 dnl # * Start QAT driver in your system:
 318 dnl #   service qat_service start
 319 dnl # * Enable QAT in ZFS, e.g.:
 320 dnl #   ./configure --with-qat=<qat-driver-path>/QAT1.6
 321 dnl #   make
 322 dnl # * Set GZIP compression in ZFS dataset:
 323 dnl #   zfs set compression = gzip <dataset>
 324 dnl # Then the data written to this ZFS pool is compressed
 325 dnl # by QAT accelerator automatically, and de-compressed by
 326 dnl # QAT when read from the pool.
 327 dnl # * Get QAT hardware statistics by:
 328 dnl #   cat /proc/icp_dh895xcc_dev/qat
 329 dnl # * To disable QAT:
 330 dnl #   insmod zfs.ko zfs_qat_disable=1
 331 dnl #
 332 AC_DEFUN([ZFS_AC_QAT], [
 333         AC_ARG_WITH([qat],
 334                 AS_HELP_STRING([--with-qat=PATH],
 335                 [Path to qat source]),
 336                 AS_IF([test "$withval" = "yes"],
 337                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 338                         [qatsrc="$withval"]))
 339
 340         AC_ARG_WITH([qat-obj],
 341                 AS_HELP_STRING([--with-qat-obj=PATH],
 342                 [Path to qat build objects]),
 343                 [qatbuild="$withval"])
 344
 345         AS_IF([test ! -z "${qatsrc}"], [
 346                 AC_MSG_CHECKING([qat source directory])
 347                 AC_MSG_RESULT([$qatsrc])
 348                 QAT_SRC="${qatsrc}/quickassist"
 349                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 350                         AC_MSG_ERROR([
 351                 *** Please make sure the qat driver package is installed
 352                 *** and specify the location of the qat source with the
 353                 *** '--with-qat=PATH' option then try again. Failed to
 354                 *** find cpa.h in:
 355                 ${QAT_SRC}/include])
 356                 ])
 357         ])
 358
 359         AS_IF([test ! -z "${qatsrc}"], [
 360                 AC_MSG_CHECKING([qat build directory])
 361                 AS_IF([test -z "$qatbuild"], [
 362                         qatbuild="${qatsrc}/build"
 363                 ])
 364
 365                 AC_MSG_RESULT([$qatbuild])
 366                 QAT_OBJ=${qatbuild}
 367                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 368                         AC_MSG_ERROR([
 369                 *** Please make sure the qat driver is installed then try again.
 370                 *** Failed to find icp_qa_al.ko or qat_api.ko in:
 371                 $QAT_OBJ])
 372                 ])
 373
 374                 AC_SUBST(QAT_SRC)
 375                 AC_SUBST(QAT_OBJ)
 376
 377                 AC_DEFINE(HAVE_QAT, 1,
 378                 [qat is enabled and existed])
 379         ])
 380
 381         dnl #
 382         dnl # Detect the name used for the QAT Module.symvers file.
 383         dnl #
 384         AS_IF([test ! -z "${qatsrc}"], [
 385                 AC_MSG_CHECKING([qat file for module symbols])
 386                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 387
 388                 AS_IF([test -r $QAT_SYMBOLS], [
 389                         AC_MSG_RESULT([$QAT_SYMBOLS])
 390                         AC_SUBST(QAT_SYMBOLS)
 391                 ],[
 392                        AC_MSG_ERROR([
 393                         *** Please make sure the qat driver is installed then try again.
 394                         *** Failed to find Module.symvers in:
 395                         $QAT_SYMBOLS])
 396                         ])
 397                 ])
 398         ])
 399 ])
 400
 401 dnl #
 402 dnl # Basic toolchain sanity check.
 403 dnl #
 404 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 405         AC_MSG_CHECKING([whether modules can be built])
 406         ZFS_LINUX_TRY_COMPILE([],[],[
 407                 AC_MSG_RESULT([yes])
 408         ],[
 409                 AC_MSG_RESULT([no])
 410                 if test "x$enable_linux_builtin" != xyes; then
 411                         AC_MSG_ERROR([*** Unable to build an empty module.])
 412                 else
 413                         AC_MSG_ERROR([
 414         *** Unable to build an empty module.
 415         *** Please run 'make scripts' inside the kernel source tree.])
 416                 fi
 417         ])
 418 ])
 419
 420 dnl #
 421 dnl # Certain kernel build options are not supported.  These must be
 422 dnl # detected at configure time and cause a build failure.  Otherwise
 423 dnl # modules may be successfully built that behave incorrectly.
 424 dnl #
 425 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 426         AS_IF([test "x$cross_compiling" != xyes], [
 427                 AC_RUN_IFELSE([
 428                         AC_LANG_PROGRAM([
 429                                 #include "$LINUX/include/linux/license.h"
 430                         ], [
 431                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 432                         ])
 433                 ], [
 434                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 435                             [Define to 1 if GPL-only symbols can be used])
 436                 ], [
 437                 ])
 438         ])
 439
 440         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 441         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 442         ZFS_AC_KERNEL_CONFIG_TRIM_UNUSED_KSYMS
 443         ZFS_AC_KERNEL_CONFIG_ZLIB_INFLATE
 444         ZFS_AC_KERNEL_CONFIG_ZLIB_DEFLATE
 445 ])
 446
 447 dnl #
 448 dnl # Check configured THREAD_SIZE
 449 dnl #
 450 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 451 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 452 dnl # on newer kernels and some architectures stack usage optimizations can be
 453 dnl # conditionally applied to improve performance without negatively impacting
 454 dnl # stability.
 455 dnl #
 456 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 457         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 458         ZFS_LINUX_TRY_COMPILE([
 459                 #include <linux/module.h>
 460         ],[
 461                 #if (THREAD_SIZE < 16384)
 462                 #error "THREAD_SIZE is less than 16K"
 463                 #endif
 464         ],[
 465                 AC_MSG_RESULT([yes])
 466                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 467         ],[
 468                 AC_MSG_RESULT([no])
 469         ])
 470 ])
 471
 472 dnl #
 473 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 474 dnl #
 475 dnl # This is typically only set for debug kernels because it comes with
 476 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 477 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 478 dnl # This will cause a failure at link time which we'd rather know about
 479 dnl # at compile time.
 480 dnl #
 481 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 482 dnl # with the upstream community we add a check to detect this case.
 483 dnl #
 484 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 485
 486         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 487                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 488                 tmp_flags="$EXTRA_KCFLAGS"
 489                 ZFS_LINUX_TRY_COMPILE([
 490                         #include <linux/module.h>
 491                         #include <linux/mutex.h>
 492
 493                         MODULE_LICENSE("$ZFS_META_LICENSE");
 494                 ],[
 495                         struct mutex lock;
 496
 497                         mutex_init(&lock);
 498                         mutex_lock(&lock);
 499                         mutex_unlock(&lock);
 500                 ],[
 501                         AC_MSG_RESULT(no)
 502                 ],[
 503                         AC_MSG_RESULT(yes)
 504                         AC_MSG_ERROR([
 505         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 506         *** with the CDDL license and will prevent the module linking stage
 507         *** from succeeding.  You must rebuild your kernel without this
 508         *** option enabled.])
 509                 ])
 510                 EXTRA_KCFLAGS="$tmp_flags"
 511         ], [])
 512 ])
 513
 514 dnl #
 515 dnl # Check CONFIG_TRIM_UNUSED_KSYMS
 516 dnl #
 517 dnl # Verify the kernel has CONFIG_TRIM_UNUSED_KSYMS disabled.
 518 dnl #
 519 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_TRIM_UNUSED_KSYMS], [
 520         AC_MSG_CHECKING([whether CONFIG_TRIM_UNUSED_KSYM is disabled])
 521         ZFS_LINUX_TRY_COMPILE([
 522                 #if defined(CONFIG_TRIM_UNUSED_KSYMS)
 523                 #error CONFIG_TRIM_UNUSED_KSYMS not defined
 524                 #endif
 525         ],[ ],[
 526                 AC_MSG_RESULT([yes])
 527         ],[
 528                 AC_MSG_RESULT([no])
 529                 AC_MSG_ERROR([
 530         *** This kernel has unused symbols trimming enabled, please disable.
 531         *** Rebuild the kernel with CONFIG_TRIM_UNUSED_KSYMS=n set.])
 532         ])
 533 ])
 534
 535 dnl #
 536 dnl # ZFS_LINUX_CONFTEST_H
 537 dnl #
 538 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 539 cat - <<_ACEOF >conftest.h
 540 $1
 541 _ACEOF
 542 ])
 543
 544 dnl #
 545 dnl # ZFS_LINUX_CONFTEST_C
 546 dnl #
 547 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 548 cat confdefs.h - <<_ACEOF >conftest.c
 549 $1
 550 _ACEOF
 551 ])
 552
 553 dnl #
 554 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 555 dnl #
 556 m4_define([ZFS_LANG_PROGRAM], [
 557 $1
 558 int
 559 main (void)
 560 {
 561 dnl Do *not* indent the following line: there may be CPP directives.
 562 dnl Don't move the `;' right after for the same reason.
 563 $2
 564   ;
 565   return 0;
 566 }
 567 ])
 568
 569 dnl #
 570 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 571 dnl #
 572 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 573         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 574         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 575         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 576         echo "obj-m := conftest.o" >build/Makefile
 577         modpost_flag=''
 578         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 579         AS_IF(
 580                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $FRAME_LARGER_THAN $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 581                 [$4],
 582                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 583         )
 584         rm -Rf build
 585 ])
 586
 587 dnl #
 588 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 589 dnl #
 590 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 591         [ZFS_LINUX_COMPILE_IFELSE(
 592         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 593         [modules],
 594         [test -s build/conftest.o],
 595         [$3], [$4])
 596 ])
 597
 598 dnl #
 599 dnl # ZFS_LINUX_CONFIG
 600 dnl #
 601 AC_DEFUN([ZFS_LINUX_CONFIG],
 602         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 603         ZFS_LINUX_TRY_COMPILE([
 604                 #include <linux/module.h>
 605         ],[
 606                 #ifndef CONFIG_$1
 607                 #error CONFIG_$1 not #defined
 608                 #endif
 609         ],[
 610                 AC_MSG_RESULT([yes])
 611                 $2
 612         ],[
 613                 AC_MSG_RESULT([no])
 614                 $3
 615         ])
 616 ])
 617
 618 dnl #
 619 dnl # ZFS_CHECK_SYMBOL_EXPORT
 620 dnl # check symbol exported or not
 621 dnl #
 622 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 623         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 624                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 625         rc=$?
 626         if test $rc -ne 0; then
 627                 export=0
 628                 for file in $2; do
 629                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 630                                 "$LINUX/$file" 2>/dev/null
 631                         rc=$?
 632                         if test $rc -eq 0; then
 633                                 export=1
 634                                 break;
 635                         fi
 636                 done
 637                 if test $export -eq 0; then :
 638                         $4
 639                 else :
 640                         $3
 641                 fi
 642         else :
 643                 $3
 644         fi
 645 ])
 646
 647 dnl #
 648 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 649 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 650 dnl # is called if not compiling for builtin
 651 dnl #
 652 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 653         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 654         if test $rc -ne 0; then :
 655                 $6
 656         else
 657                 if test "x$enable_linux_builtin" != xyes; then
 658                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 659                 fi
 660                 if test $rc -ne 0; then :
 661                         $6
 662                 else :
 663                         $5
 664                 fi
 665         fi
 666 ])
 667
 668 dnl #
 669 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 670 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 671 dnl # provided via the fifth parameter
 672 dnl #
 673 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 674         [ZFS_LINUX_COMPILE_IFELSE(
 675         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 676         [modules],
 677         [test -s build/conftest.o],
 678         [$3], [$4], [$5])
 679 ])