PVE/APLInfo.pm

   1 package PVE::APLInfo;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use PVE::SafeSyslog;
   7 use PVE::Tools;
   8 use LWP::UserAgent;
   9 use POSIX qw(strftime);
  10 use PVE::pvecfg;
  11
  12 my $logfile = "/var/log/pveam.log";
  13 my $aplinfodir = "/var/lib/pve-manager/apl-info";
  14
  15 sub logmsg {
  16     my ($logfd, $msg) = @_;
  17
  18     chomp $msg;
  19
  20     my $tstr = strftime ("%F %H:%M:%S", localtime);
  21
  22     foreach my $line (split (/\n/, $msg)) {
  23         print $logfd "$tstr $line\n";
  24     }
  25 }
  26
  27 sub read_aplinfo_from_fh {
  28     my ($fh, $list, $source, $update) = @_;
  29
  30     local $/ = "";
  31
  32     while (my $rec = <$fh>) {
  33         chomp $rec;
  34
  35         my $res = {};
  36
  37         while ($rec) {
  38
  39             if ($rec =~ s/^Description:\s*([^\n]*)(\n\s+.*)*$//si) {
  40                 $res->{headline} = $1;
  41                 my $long = $2 || '';
  42                 $long =~ s/\n\s+/ /g;
  43                 $long =~ s/^\s+//g;
  44                 $long =~ s/\s+$//g;
  45                 $res->{description} = $long;
  46             } elsif ($rec =~ s/^Version:\s*(.*\S)\s*\n//i) {
  47                 my $version = $1;
  48                 if ($version =~ m/^(\d[a-zA-Z0-9\.\+\-\:\~]*)(-(\d+))?$/) {
  49                     $res->{version} = $version;
  50                 } else {
  51                     my $msg = "unable to parse appliance record: version = '$version'\n";
  52                     $update ? die $msg : warn $msg;
  53                 }
  54             } elsif ($rec =~ s/^Type:\s*(.*\S)\s*\n//i) {
  55                 my $type = $1;
  56                 if ($type =~ m/^(openvz|lxc)$/) {
  57                     $res->{type} = $type;
  58                 } else {
  59                     my $msg = "unable to parse appliance record: unknown type '$type'\n";
  60                     $update ? die $msg : warn $msg;
  61                 }
  62             } elsif ($rec =~ s/^([^:]+):\s*(.*\S)\s*\n//) {
  63                 $res->{lc $1} = $2;
  64             } else {
  65                 my $msg = "unable to parse appliance record: $rec\n";
  66                 $update ? die $msg : warn $msg;
  67                 $res = {};
  68                 last;
  69             }
  70         }
  71
  72         if ($res->{'package'} eq 'pve-web-news' && $res->{description}) {
  73             $list->{'all'}->{$res->{'package'}} = $res;
  74             next;
  75         }
  76
  77         $res->{section} = 'unknown' if !$res->{section};
  78
  79         if ($res->{'package'} && $res->{type} && $res->{os} && $res->{version} &&
  80             $res->{infopage}) {
  81             my $template;
  82             if ($res->{location}) {
  83                 $template = $res->{location};
  84                 $template =~ s|.*/([^/]+.tar.[gx]z)$|$1|;
  85                 if ($res->{location} !~ m|^([a-zA-Z]+)\://|) {
  86                     # relative localtion (no http:// prefix)
  87                     $res->{location} = "$source/$res->{location}";
  88                 }
  89             } else {
  90                 my $arch = $res->{architecture} || 'i386';
  91                 $template = "$res->{os}-$res->{package}_$res->{version}_$arch.tar.gz";
  92                 $template =~ s/$res->{os}-$res->{os}-/$res->{os}-/;
  93                 $res->{location} = "$source/$res->{section}/$template";
  94             }
  95             $res->{source} = $source;
  96             $res->{template} = $template;
  97             $list->{$res->{section}}->{$template} = $res;
  98             $list->{'all'}->{$template} = $res;
  99         } else {
 100             my $msg = "found incomplete appliance records\n";
 101             $update ? die $msg : warn $msg;
 102         }
 103     }
 104 }
 105
 106 sub read_aplinfo {
 107     my ($filename, $list, $source, $update) = @_;
 108
 109     my $fh = IO::File->new("<$filename") ||
 110         die "unable to open file '$filename' - $!\n";
 111
 112     eval { read_aplinfo_from_fh($fh, $list, $source, $update); };
 113     my $err = $@;
 114
 115     close($fh);
 116
 117     die $err if $err;
 118
 119     return $list;
 120 }
 121
 122 sub url_get {
 123     my ($ua, $url, $file, $logfh) = @_;
 124
 125     my $req = HTTP::Request->new(GET => $url);
 126
 127     logmsg ($logfh, "start download $url");
 128     my $res = $ua->request($req, $file);
 129
 130     if ($res->is_success) {
 131         logmsg ($logfh, "download finished: " . $res->status_line);
 132         return 0;
 133     }
 134
 135     logmsg ($logfh, "download failed: " . $res->status_line);
 136
 137     return 1;
 138 }
 139
 140 sub download_aplinfo {
 141     my ($ua, $aplurl, $host, $logfd) = @_;
 142
 143     my $aplsrcurl = "$aplurl/aplinfo.dat.gz";
 144     my $aplsigurl = "$aplurl/aplinfo.dat.asc";
 145
 146     my $tmp = "$aplinfodir/pveam-${host}.tmp.$$";
 147     my $tmpgz = "$tmp.gz";
 148     my $sigfn = "$tmp.asc";
 149
 150     eval {
 151
 152         if (url_get($ua, $aplsigurl, $sigfn, $logfd) != 0) {
 153             die "update failed - no signature file '$sigfn'\n";
 154         }
 155
 156         if (url_get($ua, $aplsrcurl, $tmpgz, $logfd) != 0) {
 157             die "update failed - no data file '$aplsrcurl'\n";
 158         }
 159
 160        eval {
 161            PVE::Tools::run_command(["gunzip", "-f", $tmpgz]);
 162        };
 163        die "update failed: unable to unpack '$tmpgz'\n" if $@;
 164
 165
 166
 167         # verify signature
 168         my $trustedkeyring = "/usr/share/doc/pve-manager/trustedkeys.gpg";
 169         my $cmd = "/usr/bin/gpgv -q --keyring $trustedkeyring $sigfn $tmp";
 170
 171         eval {
 172             my $logfunc = sub {
 173                 my $line = shift;
 174                 logmsg($logfd, "signature verification: $line");
 175             };
 176
 177             PVE::Tools::run_command($cmd,
 178                                     outfunc => $logfunc,
 179                                     errfunc => $logfunc);
 180         };
 181         die "unable to verify signature - $@\n" if $@;
 182
 183         # test syntax
 184         eval {
 185             read_aplinfo($tmp, {}, $aplurl, 1);
 186         };
 187         die "update failed: $@" if $@;
 188
 189         if (!rename($tmp, "$aplinfodir/$host")) {
 190             die "update failed: unable to store data\n";
 191         }
 192
 193         logmsg($logfd, "update sucessful");
 194     };
 195
 196     my $err = $@;
 197
 198     unlink $tmp;
 199     unlink $tmpgz;
 200     unlink $sigfn;
 201
 202     die $err if $err;
 203 }
 204
 205 sub get_apl_sources {
 206
 207     my $urls = [];
 208     push @$urls, "http://download.proxmox.com/images";
 209     push @$urls, "https://releases.turnkeylinux.org/pve";
 210
 211     return $urls;
 212 }
 213
 214 sub update {
 215     my ($proxy) = @_;
 216
 217     my $size;
 218     if (($size = (-s $logfile) || 0) > (1024*50)) {
 219         rename($logfile, "$logfile.0");
 220     }
 221     my $logfd = IO::File->new (">>$logfile");
 222     logmsg($logfd, "starting update");
 223
 224     my $ua = LWP::UserAgent->new;
 225     my $version = PVE::pvecfg::version();
 226     $ua->agent("PVE/$version");
 227
 228     if ($proxy) {
 229         $ua->proxy(['http', 'https'], $proxy);
 230     } else {
 231         $ua->env_proxy;
 232     }
 233
 234     my $urls = get_apl_sources();
 235
 236     mkdir $aplinfodir;
 237
 238     my @dlerr = ();
 239     foreach my $aplurl (@$urls) {
 240         eval {
 241             my $uri = URI->new($aplurl);
 242             my $host = $uri->host();
 243             download_aplinfo($ua, $aplurl, $host, $logfd);
 244         };
 245         if (my $err = $@) {
 246             logmsg ($logfd, $err);
 247             push @dlerr, $aplurl;
 248         }
 249     }
 250
 251     close($logfd);
 252
 253     return 0 if scalar(@dlerr);
 254
 255     return 1;
 256 }
 257
 258 sub load_data {
 259
 260    my $urls = get_apl_sources();
 261
 262     my $list = {};
 263
 264     foreach my $aplurl (@$urls) {
 265
 266         eval {
 267
 268             my $uri = URI->new($aplurl);
 269             my $host = $uri->host();
 270             read_aplinfo("$aplinfodir/$host", $list, $aplurl);
 271         };
 272         warn $@ if $@;
 273     }
 274
 275     return $list;
 276 }
 277
 278 1;
 279