PVE/CLI/pve6to7.pm

   1 package PVE::CLI::pve6to7;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::API2::APT;
   7 use PVE::API2::Ceph;
   8 use PVE::API2::LXC;
   9 use PVE::API2::Qemu;
  10 use PVE::API2::Certificates;
  11 use PVE::API2::Cluster::Ceph;
  12
  13 use PVE::AccessControl;
  14 use PVE::Ceph::Tools;
  15 use PVE::Cluster;
  16 use PVE::Corosync;
  17 use PVE::INotify;
  18 use PVE::JSONSchema;
  19 use PVE::NodeConfig;
  20 use PVE::RPCEnvironment;
  21 use PVE::Storage;
  22 use PVE::Storage::Plugin;
  23 use PVE::Tools qw(run_command split_list);
  24 use PVE::QemuConfig;
  25 use PVE::QemuServer;
  26 use PVE::VZDump::Common;
  27 use PVE::LXC;
  28 use PVE::LXC::Config;
  29 use PVE::LXC::Setup;
  30
  31 use Term::ANSIColor;
  32
  33 use PVE::CLIHandler;
  34
  35 use base qw(PVE::CLIHandler);
  36
  37 my $nodename = PVE::INotify::nodename();
  38
  39 sub setup_environment {
  40     PVE::RPCEnvironment->setup_default_cli_env();
  41 }
  42
  43 my $min_pve_major = 6;
  44 my $min_pve_minor = 4;
  45 my $min_pve_pkgrel = 1;
  46
  47 my $counters = {
  48     pass => 0,
  49     skip => 0,
  50     warn => 0,
  51     fail => 0,
  52 };
  53
  54 my $log_line = sub {
  55     my ($level, $line) = @_;
  56
  57     $counters->{$level}++ if defined($level) && defined($counters->{$level});
  58
  59     print uc($level), ': ' if defined($level);
  60     print "$line\n";
  61 };
  62
  63 sub log_pass {
  64     print color('green');
  65     $log_line->('pass', @_);
  66     print color('reset');
  67 }
  68
  69 sub log_info {
  70     $log_line->('info', @_);
  71 }
  72 sub log_skip {
  73     $log_line->('skip', @_);
  74 }
  75 sub log_warn {
  76     print color('yellow');
  77     $log_line->('warn', @_);
  78     print color('reset');
  79 }
  80 sub log_fail {
  81     print color('red');
  82     $log_line->('fail', @_);
  83     print color('reset');
  84 }
  85
  86 my $print_header_first = 1;
  87 sub print_header {
  88     my ($h) = @_;
  89     print "\n" if !$print_header_first;
  90     print "= $h =\n\n";
  91     $print_header_first = 0;
  92 }
  93
  94 my $get_systemd_unit_state = sub {
  95     my ($unit) = @_;
  96
  97     my $state;
  98     my $filter_output = sub {
  99         $state = shift;
 100         chomp $state;
 101     };
 102     eval {
 103         run_command(['systemctl', 'is-enabled', "$unit"], outfunc => $filter_output, noerr => 1);
 104         return if !defined($state);
 105         run_command(['systemctl', 'is-active', "$unit"], outfunc => $filter_output, noerr => 1);
 106     };
 107
 108     return $state // 'unknown';
 109 };
 110 my $log_systemd_unit_state = sub {
 111     my ($unit, $no_fail_on_inactive) = @_;
 112
 113     my $log_method = \&log_warn;
 114
 115     my $state = $get_systemd_unit_state->($unit);
 116     if ($state eq 'active') {
 117         $log_method = \&log_pass;
 118     } elsif ($state eq 'inactive') {
 119         $log_method = $no_fail_on_inactive ? \&log_warn : \&log_fail;
 120     } elsif ($state eq 'failed') {
 121         $log_method = \&log_fail;
 122     }
 123
 124     $log_method->("systemd unit '$unit' is in state '$state'");
 125 };
 126
 127 my $versions;
 128 my $get_pkg = sub {
 129     my ($pkg) = @_;
 130
 131     $versions = eval { PVE::API2::APT->versions({ node => $nodename }) } if !defined($versions);
 132
 133     if (!defined($versions)) {
 134         my $msg = "unable to retrieve package version information";
 135         $msg .= "- $@" if $@;
 136         log_fail("$msg");
 137         return undef;
 138     }
 139
 140     my $pkgs = [ grep { $_->{Package} eq $pkg } @$versions ];
 141     if (!defined $pkgs || $pkgs == 0) {
 142         log_fail("unable to determine installed $pkg version.");
 143         return undef;
 144     } else {
 145         return $pkgs->[0];
 146     }
 147 };
 148
 149 sub check_pve_packages {
 150     print_header("CHECKING VERSION INFORMATION FOR PVE PACKAGES");
 151
 152     print "Checking for package updates..\n";
 153     my $updates = eval { PVE::API2::APT->list_updates({ node => $nodename }); };
 154     if (!defined($updates)) {
 155         log_warn("$@") if $@;
 156         log_fail("unable to retrieve list of package updates!");
 157     } elsif (@$updates > 0) {
 158         my $pkgs = join(', ', map { $_->{Package} } @$updates);
 159         log_warn("updates for the following packages are available:\n  $pkgs");
 160     } else {
 161         log_pass("all packages uptodate");
 162     }
 163
 164     print "\nChecking proxmox-ve package version..\n";
 165     if (defined(my $proxmox_ve = $get_pkg->('proxmox-ve'))) {
 166         my $min_pve_ver = "$min_pve_major.$min_pve_minor-$min_pve_pkgrel";
 167
 168         my ($maj, $min, $pkgrel) = $proxmox_ve->{OldVersion} =~ m/^(\d+)\.(\d+)-(\d+)/;
 169
 170         my $upgraded = 0;
 171
 172         if ($maj > $min_pve_major) {
 173             log_pass("already upgraded to Proxmox VE " . ($min_pve_major + 1));
 174             $upgraded = 1;
 175         } elsif ($maj >= $min_pve_major && $min >= $min_pve_minor && $pkgrel >= $min_pve_pkgrel) {
 176             log_pass("proxmox-ve package has version >= $min_pve_ver");
 177         } else {
 178             log_fail("proxmox-ve package is too old, please upgrade to >= $min_pve_ver!");
 179         }
 180
 181         my ($krunning, $kinstalled) = (qr/5\.11/, 'pve-kernel-5.11');
 182         if (!$upgraded) {
 183             ($krunning, $kinstalled) = (qr/5\.(?:4|11)/, 'pve-kernel-4.15');
 184         }
 185
 186         print "\nChecking running kernel version..\n";
 187         my $kernel_ver = $proxmox_ve->{RunningKernel};
 188         if (!defined($kernel_ver)) {
 189             log_fail("unable to determine running kernel version.");
 190         } elsif ($kernel_ver =~ /^$krunning/) {
 191             log_pass("expected running kernel '$kernel_ver'.");
 192         } elsif ($get_pkg->($kinstalled)) {
 193             log_warn("expected kernel '$kinstalled' intalled but not yet rebooted!");
 194         } else {
 195             log_warn("unexpected running and installed kernel '$kernel_ver'.");
 196         }
 197     } else {
 198         log_fail("proxmox-ve package not found!");
 199     }
 200 }
 201
 202
 203 sub check_storage_health {
 204     print_header("CHECKING CONFIGURED STORAGES");
 205     my $cfg = PVE::Storage::config();
 206
 207     my $ctime = time();
 208
 209     my $info = PVE::Storage::storage_info($cfg);
 210
 211     foreach my $storeid (sort keys %$info) {
 212         my $d = $info->{$storeid};
 213         if ($d->{enabled}) {
 214             if ($d->{type} eq 'sheepdog') {
 215                 log_fail("storage '$storeid' of type 'sheepdog' is enabled - experimental sheepdog support dropped in PVE 6")
 216             } elsif ($d->{active}) {
 217                 log_pass("storage '$storeid' enabled and active.");
 218             } else {
 219                 log_warn("storage '$storeid' enabled but not active!");
 220             }
 221         } else {
 222             log_skip("storage '$storeid' disabled.");
 223         }
 224     }
 225 }
 226
 227 sub check_cluster_corosync {
 228     print_header("CHECKING CLUSTER HEALTH/SETTINGS");
 229
 230     if (!PVE::Corosync::check_conf_exists(1)) {
 231         log_skip("standalone node.");
 232         return;
 233     }
 234
 235     $log_systemd_unit_state->('pve-cluster.service');
 236     $log_systemd_unit_state->('corosync.service');
 237
 238     if (PVE::Cluster::check_cfs_quorum(1)) {
 239         log_pass("Cluster Filesystem is quorate.");
 240     } else {
 241         log_fail("Cluster Filesystem readonly, lost quorum?!");
 242     }
 243
 244     my $conf = PVE::Cluster::cfs_read_file('corosync.conf');
 245     my $conf_nodelist = PVE::Corosync::nodelist($conf);
 246     my $node_votes = 0;
 247
 248     print "\nAnalzying quorum settings and state..\n";
 249     if (!defined($conf_nodelist)) {
 250         log_fail("unable to retrieve nodelist from corosync.conf");
 251     } else {
 252         if (grep { $conf_nodelist->{$_}->{quorum_votes} != 1 } keys %$conf_nodelist) {
 253             log_warn("non-default quorum_votes distribution detected!");
 254         }
 255         map { $node_votes += $conf_nodelist->{$_}->{quorum_votes} // 0 } keys %$conf_nodelist;
 256     }
 257
 258     my ($expected_votes, $total_votes);
 259     my $filter_output = sub {
 260         my $line = shift;
 261         ($expected_votes) = $line =~ /^Expected votes:\s*(\d+)\s*$/
 262             if !defined($expected_votes);
 263         ($total_votes) = $line =~ /^Total votes:\s*(\d+)\s*$/
 264             if !defined($total_votes);
 265     };
 266     eval {
 267         run_command(['corosync-quorumtool', '-s'], outfunc => $filter_output, noerr => 1);
 268     };
 269
 270     if (!defined($expected_votes)) {
 271         log_fail("unable to get expected number of votes, setting to 0.");
 272         $expected_votes = 0;
 273     }
 274     if (!defined($total_votes)) {
 275         log_fail("unable to get expected number of votes, setting to 0.");
 276         $total_votes = 0;
 277     }
 278
 279     my $cfs_nodelist = PVE::Cluster::get_clinfo()->{nodelist};
 280     my $offline_nodes = grep { $cfs_nodelist->{$_}->{online} != 1 } keys %$cfs_nodelist;
 281     if ($offline_nodes > 0) {
 282         log_fail("$offline_nodes nodes are offline!");
 283     }
 284
 285     my $qdevice_votes = 0;
 286     if (my $qdevice_setup = $conf->{main}->{quorum}->{device}) {
 287         $qdevice_votes = $qdevice_setup->{votes} // 1;
 288     }
 289
 290     log_info("configured votes - nodes: $node_votes");
 291     log_info("configured votes - qdevice: $qdevice_votes");
 292     log_info("current expected votes: $expected_votes");
 293     log_info("current total votes: $total_votes");
 294
 295     log_warn("expected votes set to non-standard value '$expected_votes'.")
 296         if $expected_votes != $node_votes + $qdevice_votes;
 297     log_warn("total votes < expected votes: $total_votes/$expected_votes!")
 298         if $total_votes < $expected_votes;
 299
 300     my $conf_nodelist_count = scalar(keys %$conf_nodelist);
 301     my $cfs_nodelist_count = scalar(keys %$cfs_nodelist);
 302     log_warn("cluster consists of less than three quorum-providing nodes!")
 303         if $conf_nodelist_count < 3 && $conf_nodelist_count + $qdevice_votes < 3;
 304
 305     log_fail("corosync.conf ($conf_nodelist_count) and pmxcfs ($cfs_nodelist_count) don't agree about size of nodelist.")
 306         if $conf_nodelist_count != $cfs_nodelist_count;
 307
 308     print "\nChecking nodelist entries..\n";
 309     my $nodelist_pass = 1;
 310     for my $cs_node (sort keys %$conf_nodelist) {
 311         my $entry = $conf_nodelist->{$cs_node};
 312         if (!defined($entry->{name})) {
 313             $nodelist_pass = 0;
 314             log_fail("$cs_node: no name entry in corosync.conf.");
 315         }
 316         if (!defined($entry->{nodeid})) {
 317             $nodelist_pass = 0;
 318             log_fail("$cs_node: no nodeid configured in corosync.conf.");
 319         }
 320         my $gotLinks = 0;
 321         for my $link (0..7) {
 322             $gotLinks++ if defined($entry->{"ring${link}_addr"});
 323         }
 324         if ($gotLinks <= 0) {
 325             $nodelist_pass = 0;
 326             log_fail("$cs_node: no ringX_addr (0 <= X <= 7) link defined in corosync.conf.");
 327         }
 328
 329         my $verify_ring_ip = sub {
 330             my $key = shift;
 331             if (defined(my $ring = $entry->{$key})) {
 332                 my ($resolved_ip, undef) = PVE::Corosync::resolve_hostname_like_corosync($ring, $conf);
 333                 if (defined($resolved_ip)) {
 334                     if ($resolved_ip ne $ring) {
 335                         $nodelist_pass = 0;
 336                         log_warn("$cs_node: $key '$ring' resolves to '$resolved_ip'.\n Consider replacing it with the currently resolved IP address.");
 337                     }
 338                 } else {
 339                     $nodelist_pass = 0;
 340                     log_fail("$cs_node: unable to resolve $key '$ring' to an IP address according to Corosync's resolve strategy - cluster will potentially fail with Corosync 3.x/kronosnet!");
 341                 }
 342             }
 343         };
 344         for my $link (0..7) {
 345             $verify_ring_ip->("ring${link}_addr");
 346         }
 347     }
 348     log_pass("nodelist settings OK") if $nodelist_pass;
 349
 350     print "\nChecking totem settings..\n";
 351     my $totem = $conf->{main}->{totem};
 352     my $totem_pass = 1;
 353
 354     my $transport = $totem->{transport};
 355     if (defined($transport)) {
 356         if ($transport ne 'knet') {
 357             $totem_pass = 0;
 358             log_fail("Corosync transport explicitly set to '$transport' instead of implicit default!");
 359         }
 360     }
 361
 362     # TODO: are those values still up-to-date?
 363     if ((!defined($totem->{secauth}) || $totem->{secauth} ne 'on') && (!defined($totem->{crypto_cipher}) || $totem->{crypto_cipher} eq 'none')) {
 364         $totem_pass = 0;
 365         log_fail("Corosync authentication/encryption is not explicitly enabled (secauth / crypto_cipher / crypto_hash)!");
 366     } elsif (defined($totem->{crypto_cipher}) && $totem->{crypto_cipher} eq '3des') {
 367         $totem_pass = 0;
 368         log_fail("Corosync encryption cipher set to '3des', no longer supported in Corosync 3.x!"); # FIXME: can be removed?
 369     }
 370
 371     log_pass("totem settings OK") if $totem_pass;
 372     print "\n";
 373     log_info("run 'pvecm status' to get detailed cluster status..");
 374
 375     if (defined(my $corosync = $get_pkg->('corosync'))) {
 376         if ($corosync->{OldVersion} =~ m/^2\./) {
 377             log_fail("\ncorosync 2.x installed, cluster-wide upgrade to 3.x needed!");
 378         } elsif ($corosync->{OldVersion} !~ m/^3\./) {
 379             log_fail("\nunexpected corosync version installed: $corosync->{OldVersion}!");
 380         }
 381     }
 382 }
 383
 384 sub check_ceph {
 385     print_header("CHECKING HYPER-CONVERGED CEPH STATUS");
 386
 387     if (PVE::Ceph::Tools::check_ceph_inited(1)) {
 388         log_info("hyper-converged ceph setup detected!");
 389     } else {
 390         log_skip("no hyper-converged ceph setup detected!");
 391         return;
 392     }
 393
 394     log_info("getting Ceph status/health information..");
 395     my $ceph_status = eval { PVE::API2::Ceph->status({ node => $nodename }); };
 396     my $noout = eval { PVE::API2::Cluster::Ceph->get_flag({ flag => "noout" }); };
 397     if ($@) {
 398         log_fail("failed to get 'noout' flag status - $@");
 399     }
 400
 401     my $noout_wanted = 1;
 402
 403     if (!$ceph_status || !$ceph_status->{health}) {
 404         log_fail("unable to determine Ceph status!");
 405     } else {
 406         my $ceph_health = $ceph_status->{health}->{status};
 407         if (!$ceph_health) {
 408             log_fail("unable to determine Ceph health!");
 409         } elsif ($ceph_health eq 'HEALTH_OK') {
 410             log_pass("Ceph health reported as 'HEALTH_OK'.");
 411         } elsif ($ceph_health eq 'HEALTH_WARN' && $noout && (keys %{$ceph_status->{health}->{checks}} == 1)) {
 412                 log_pass("Ceph health reported as 'HEALTH_WARN' with a single failing check and 'noout' flag set.");
 413         } else {
 414                 log_warn("Ceph health reported as '$ceph_health'.\n      Use the PVE ".
 415                   "dashboard or 'ceph -s' to determine the specific issues and try to resolve them.");
 416         }
 417     }
 418
 419     # TODO: check OSD min-required version, if to low it breaks stuff!
 420
 421     log_info("getting Ceph daemon versions..");
 422     my $ceph_versions = eval { PVE::Ceph::Tools::get_cluster_versions(undef, 1); };
 423     if (!$ceph_versions) {
 424         log_fail("unable to determine Ceph daemon versions!");
 425     } else {
 426         my $services = [
 427             { 'key' => 'mon', 'name' => 'monitor' },
 428             { 'key' => 'mgr', 'name' => 'manager' },
 429             { 'key' => 'mds', 'name' => 'MDS' },
 430             { 'key' => 'osd', 'name' => 'OSD' },
 431         ];
 432
 433         foreach my $service (@$services) {
 434             my $name = $service->{name};
 435             if (my $service_versions = $ceph_versions->{$service->{key}}) {
 436                 if (keys %$service_versions == 0) {
 437                     log_skip("no running instances detected for daemon type $name.");
 438                 } elsif (keys %$service_versions == 1) {
 439                     log_pass("single running version detected for daemon type $name.");
 440                 } else {
 441                     log_warn("multiple running versions detected for daemon type $name!");
 442                 }
 443             } else {
 444                 log_skip("unable to determine versions of running Ceph $name instances.");
 445             }
 446         }
 447
 448         my $overall_versions = $ceph_versions->{overall};
 449         if (!$overall_versions) {
 450             log_warn("unable to determine overall Ceph daemon versions!");
 451         } elsif (keys %$overall_versions == 1) {
 452             log_pass("single running overall version detected for all Ceph daemon types.");
 453             if ((keys %$overall_versions)[0] =~ /^ceph version 15\./) {
 454                 $noout_wanted = 0;
 455             }
 456         } else {
 457             log_warn("overall version mismatch detected, check 'ceph versions' output for details!");
 458         }
 459     }
 460
 461     if ($noout) {
 462         if ($noout_wanted) {
 463             log_pass("'noout' flag set to prevent rebalancing during cluster-wide upgrades.");
 464         } else {
 465             log_warn("'noout' flag set, Ceph cluster upgrade seems finished.");
 466         }
 467     } elsif ($noout_wanted) {
 468         log_warn("'noout' flag not set - recommended to prevent rebalancing during upgrades.");
 469     }
 470
 471     log_info("checking Ceph config..");
 472     my $conf = PVE::Cluster::cfs_read_file('ceph.conf');
 473     if (%$conf) {
 474         my $global = $conf->{global};
 475
 476         my $global_monhost = $global->{mon_host} // $global->{"mon host"} // $global->{"mon-host"};
 477         if (!defined($global_monhost)) {
 478             log_warn("No 'mon_host' entry found in ceph config.\n  It's recommended to add mon_host with all monitor addresses (without ports) to the global section.");
 479         }
 480
 481         my $ipv6 = $global->{ms_bind_ipv6} // $global->{"ms bind ipv6"} // $global->{"ms-bind-ipv6"};
 482         if ($ipv6) {
 483             my $ipv4 = $global->{ms_bind_ipv4} // $global->{"ms bind ipv4"} // $global->{"ms-bind-ipv4"};
 484             if ($ipv6 eq 'true' && (!defined($ipv4) || $ipv4 ne 'false')) {
 485                 log_warn("'ms_bind_ipv6' is enabled but 'ms_bind_ipv4' is not disabled.\n  Make sure to disable 'ms_bind_ipv4' for ipv6 only clusters, or add an ipv4 network to public/cluster network.");
 486             }
 487         }
 488
 489         if (defined($global->{keyring})) {
 490             log_warn("[global] config section contains 'keyring' option, which will prevent services from starting with Nautilus.\n Move 'keyring' option to [client] section instead.");
 491         }
 492
 493     } else {
 494         log_warn("Empty ceph config found");
 495     }
 496
 497     my $local_ceph_ver = PVE::Ceph::Tools::get_local_version(1);
 498     if (defined($local_ceph_ver)) {
 499         if ($local_ceph_ver == 14) {
 500             my $ceph_volume_osds = PVE::Ceph::Tools::ceph_volume_list();
 501             my $scanned_osds = PVE::Tools::dir_glob_regex('/etc/ceph/osd', '^.*\.json$');
 502             if (-e '/var/lib/ceph/osd/' && !defined($scanned_osds) && !(keys %$ceph_volume_osds)) {
 503                 log_warn("local Ceph version is Nautilus, local OSDs detected, but no conversion from ceph-disk to ceph-volume done (yet).");
 504             }
 505         }
 506     } else {
 507         log_fail("unable to determine local Ceph version.");
 508     }
 509 }
 510
 511 sub check_backup_retention_settings {
 512     log_info("Checking backup retention settings..");
 513
 514     my $pass = 1;
 515
 516     my $node_has_retention;
 517
 518     my $maxfiles_msg = "parameter 'maxfiles' is deprecated with PVE 7.x and will be removed in a " .
 519         "future version, use 'prune-backups' instead.";
 520
 521     eval {
 522         my $confdesc = PVE::VZDump::Common::get_confdesc();
 523
 524         my $fn = "/etc/vzdump.conf";
 525         my $raw = PVE::Tools::file_get_contents($fn);
 526
 527         my $conf_schema = { type => 'object', properties => $confdesc, };
 528         my $param = PVE::JSONSchema::parse_config($conf_schema, $fn, $raw);
 529
 530         if (defined($param->{maxfiles})) {
 531             $pass = 0;
 532             log_warn("$fn - $maxfiles_msg");
 533         }
 534
 535         $node_has_retention = defined($param->{maxfiles}) || defined($param->{'prune-backups'});
 536     };
 537     if (my $err = $@) {
 538         $pass = 0;
 539         log_warn("unable to parse node's VZDump configuration - $err");
 540     }
 541
 542     my $storage_cfg = PVE::Storage::config();
 543
 544     for my $storeid (keys $storage_cfg->{ids}->%*) {
 545         my $scfg = $storage_cfg->{ids}->{$storeid};
 546
 547         if (defined($scfg->{maxfiles})) {
 548             $pass = 0;
 549             log_warn("storage '$storeid' - $maxfiles_msg");
 550         }
 551
 552         next if !$scfg->{content}->{backup};
 553         next if defined($scfg->{maxfiles}) || defined($scfg->{'prune-backups'});
 554         next if $node_has_retention;
 555
 556         log_info("storage '$storeid' - no backup retention settings defined - by default, PVE " .
 557             "7.x will no longer keep only the last backup, but all backups");
 558     }
 559
 560     eval {
 561         my $vzdump_cron = PVE::Cluster::cfs_read_file('vzdump.cron');
 562
 563         # only warn once, there might be many jobs...
 564         if (scalar(grep { defined($_->{maxfiles}) } $vzdump_cron->{jobs}->@*)) {
 565             $pass = 0;
 566             log_warn("/etc/pve/vzdump.cron - $maxfiles_msg");
 567         }
 568     };
 569     if (my $err = $@) {
 570         $pass = 0;
 571         log_warn("unable to parse node's VZDump configuration - $err");
 572     }
 573
 574     log_pass("no problems found.") if $pass;
 575 }
 576
 577 sub check_cifs_credential_location {
 578     log_info("checking CIFS credential location..");
 579
 580     my $regex = qr/^(.*)\.cred$/;
 581
 582     my $found;
 583
 584     PVE::Tools::dir_glob_foreach('/etc/pve/priv/', $regex, sub {
 585         my ($filename) = @_;
 586
 587         my ($basename) = $filename =~ $regex;
 588
 589         log_warn("CIFS credentials '/etc/pve/priv/$filename' will be moved to " .
 590             "'/etc/pve/priv/storage/$basename.pw' during the update");
 591
 592         $found = 1;
 593     });
 594
 595     log_pass("no CIFS credentials at outdated location found.") if !$found;
 596 }
 597
 598 sub check_custom_pool_roles {
 599     log_info("Checking custom roles for pool permissions..");
 600
 601     if (! -f "/etc/pve/user.cfg") {
 602         log_skip("user.cfg does not exist");
 603         return;
 604     }
 605
 606     my $raw = eval { PVE::Tools::file_get_contents('/etc/pve/user.cfg'); };
 607     if ($@) {
 608         log_fail("Failed to read '/etc/pve/user.cfg' - $@");
 609         return;
 610     }
 611
 612     my $roles = {};
 613     while ($raw =~ /^\s*(.+?)\s*$/gm) {
 614         my $line = $1;
 615         my @data;
 616
 617         foreach my $d (split (/:/, $line)) {
 618             $d =~ s/^\s+//;
 619             $d =~ s/\s+$//;
 620             push @data, $d
 621         }
 622
 623         my $et = shift @data;
 624         next if $et ne 'role';
 625
 626         my ($role, $privlist) = @data;
 627         if (!PVE::AccessControl::verify_rolename($role, 1)) {
 628             warn "user config - ignore role '$role' - invalid characters in role name\n";
 629             next;
 630         }
 631
 632         $roles->{$role} = {} if !$roles->{$role};
 633         foreach my $priv (split_list($privlist)) {
 634             $roles->{$role}->{$priv} = 1;
 635         }
 636     }
 637
 638     foreach my $role (sort keys %{$roles}) {
 639         if (PVE::AccessControl::role_is_special($role)) {
 640             next;
 641         }
 642
 643         if ($role eq "PVEPoolUser") {
 644             # the user created a custom role named PVEPoolUser
 645             log_fail("Custom role '$role' has a restricted name - a built-in role 'PVEPoolUser' will be available with the upgrade");
 646         } else {
 647             log_pass("Custom role '$role' has no restricted name");
 648         }
 649
 650         my $perms = $roles->{$role};
 651         if ($perms->{'Pool.Allocate'} && $perms->{'Pool.Audit'}) {
 652             log_pass("Custom role '$role' contains updated pool permissions");
 653         } elsif ($perms->{'Pool.Allocate'}) {
 654             log_warn("Custom role '$role' contains permission 'Pool.Allocate' - to ensure same behavior add 'Pool.Audit' to this role");
 655         } else {
 656             log_pass("Custom role '$role' contains no permissions that need to be updated");
 657         }
 658     }
 659 }
 660
 661 my sub check_max_length {
 662     my ($raw, $max_length, $warning) = @_;
 663     log_warn($warning) if defined($raw) && length($raw) > $max_length;
 664 }
 665
 666 sub check_description_lengths {
 667     log_info("Checking node and guest description/note legnth..");
 668
 669     my @affected_nodes = grep {
 670         my $desc = PVE::NodeConfig::load_config($_)->{desc};
 671         defined($desc) && length($desc) > 64 * 1024
 672     } PVE::Cluster::get_nodelist();
 673
 674     if (scalar(@affected_nodes) > 0) {
 675         log_warn("Node config description of the following nodes too long for new limit of 64 KiB:\n    "
 676             . join(', ', @affected_nodes));
 677     } else {
 678         log_pass("All node config descriptions fit in the new limit of 64 KiB");
 679     }
 680
 681     my $affected_guests = [];
 682
 683     my $cts = PVE::LXC::config_list();
 684     for my $vmid (sort { $a <=> $b } keys %$cts) {
 685         my $desc = PVE::LXC::Config->load_config($vmid)->{description};
 686         push @$affected_guests, "CT $vmid" if defined($desc) && length($desc) > 8 * 1024;
 687     }
 688     my $vms = PVE::QemuServer::config_list();
 689     for my $vmid (sort { $a <=> $b } keys %$vms) {
 690         my $desc = PVE::QemuConfig->load_config($vmid)->{description};
 691         push @$affected_guests, "VM $vmid" if defined($desc) && length($desc) > 8 * 1024;
 692     }
 693     if (scalar($affected_guests->@*) > 0) {
 694         log_warn("Guest config description of the following virtual-guests too long for new limit of 64 KiB:\n"
 695             ."    * " . join("\n    * ", $affected_guests->@*));
 696     } else {
 697         log_pass("All guest config descriptions fit in the new limit of 8 KiB");
 698     }
 699 }
 700
 701 sub check_storage_content {
 702     log_info("Checking storage content type configuration..");
 703
 704     my $found_referenced;
 705     my $found_unreferenced;
 706     my $pass = 1;
 707
 708     my $storage_cfg = PVE::Storage::config();
 709
 710     my $potentially_affected = {};
 711     my $referenced_volids = {};
 712
 713     for my $storeid (sort keys $storage_cfg->{ids}->%*) {
 714         my $scfg = $storage_cfg->{ids}->{$storeid};
 715
 716         next if !PVE::Storage::storage_check_enabled($storage_cfg, $storeid, undef, 1);
 717
 718         my $valid_content = PVE::Storage::Plugin::valid_content_types($scfg->{type});
 719
 720         if (scalar(keys $scfg->{content}->%*) == 0 && !$valid_content->{none}) {
 721             $pass = 0;
 722             log_fail("storage '$storeid' does not support configured content type 'none'");
 723             delete $scfg->{content}->{none}; # scan for guest images below
 724         }
 725
 726         next if $scfg->{content}->{images} && $scfg->{content}->{rootdir};
 727
 728         # Skip 'iscsi(direct)' (and foreign plugins with potentially similiar behavior) with 'none',
 729         # because that means "use LUNs directly" and vdisk_list() in PVE 6.x still lists those.
 730         # It's enough to *not* skip 'dir', because it is the only other storage that supports 'none'
 731         # and 'images' or 'rootdir', hence being potentially misconfigured.
 732         next if $scfg->{type} ne 'dir' && $scfg->{content}->{none};
 733
 734         eval { PVE::Storage::activate_storage($storage_cfg, $storeid) };
 735         if (my $err = $@) {
 736             log_warn("activating '$storeid' failed - $err");
 737             next;
 738         }
 739
 740         my $res = eval { PVE::Storage::vdisk_list($storage_cfg, $storeid); };
 741         if (my $err = $@) {
 742             log_warn("listing images on '$storeid' failed - $err");
 743             next;
 744         }
 745         my @volids = map { $_->{volid} } $res->{$storeid}->@*;
 746
 747         for my $volid (@volids) {
 748             $potentially_affected->{$volid} = 1;
 749         }
 750
 751         my $number = scalar(@volids);
 752         if ($number > 0 && !$scfg->{content}->{images} && !$scfg->{content}->{rootdir}) {
 753             log_info("storage '$storeid' - neither content type 'images' nor 'rootdir' configured"
 754                 .", but found $number guest volume(s)");
 755         }
 756     }
 757
 758     my $check_volid = sub {
 759         my ($volid, $vmid, $vmtype, $reference) = @_;
 760
 761         $referenced_volids->{$volid} = 1 if $reference ne 'unreferenced';
 762
 763         my $guesttext = $vmtype eq 'qemu' ? 'VM' : 'CT';
 764         my $prefix = "$guesttext $vmid - volume '$volid' ($reference)";
 765
 766         my ($storeid) = PVE::Storage::parse_volume_id($volid, 1);
 767         return if !defined($storeid);
 768
 769         my $scfg = $storage_cfg->{ids}->{$storeid};
 770         if (!$scfg) {
 771             $pass = 0;
 772             log_warn("$prefix - storage does not exist!");
 773             return;
 774         }
 775
 776         # cannot use parse_volname for containers, as it can return 'images'
 777         # but containers cannot have ISO images attached, so assume 'rootdir'
 778         my $vtype = 'rootdir';
 779         if ($vmtype eq 'qemu') {
 780             ($vtype) = eval { PVE::Storage::parse_volname($storage_cfg, $volid); };
 781             return if $@;
 782         }
 783
 784         if (!$scfg->{content}->{$vtype}) {
 785             $found_referenced = 1 if $reference ne 'unreferenced';
 786             $found_unreferenced = 1 if $reference eq 'unreferenced';
 787             $pass = 0;
 788             log_warn("$prefix - storage does not have content type '$vtype' configured.");
 789         }
 790     };
 791
 792     my $guests = {};
 793
 794     my $cts = PVE::LXC::config_list();
 795     for my $vmid (sort { $a <=> $b } keys %$cts) {
 796         $guests->{$vmid} = 'lxc';
 797
 798         my $conf = PVE::LXC::Config->load_config($vmid);
 799
 800         my $volhash = {};
 801
 802         my $check = sub {
 803             my ($ms, $mountpoint, $reference) = @_;
 804
 805             my $volid = $mountpoint->{volume};
 806             return if !$volid || $mountpoint->{type} ne 'volume';
 807
 808             return if $volhash->{$volid}; # volume might be referenced multiple times
 809
 810             $volhash->{$volid} = 1;
 811
 812             $check_volid->($volid, $vmid, 'lxc', $reference);
 813         };
 814
 815         my $opts = { include_unused => 1 };
 816         PVE::LXC::Config->foreach_volume_full($conf, $opts, $check, 'in config');
 817         for my $snapname (keys $conf->{snapshots}->%*) {
 818             my $snap = $conf->{snapshots}->{$snapname};
 819             PVE::LXC::Config->foreach_volume_full($snap, $opts, $check, "in snapshot '$snapname'");
 820         }
 821     }
 822
 823     my $vms = PVE::QemuServer::config_list();
 824     for my $vmid (sort { $a <=> $b } keys %$vms) {
 825         $guests->{$vmid} = 'qemu';
 826
 827         my $conf = PVE::QemuConfig->load_config($vmid);
 828
 829         my $volhash = {};
 830
 831         my $check = sub {
 832             my ($key, $drive, $reference) = @_;
 833
 834             my $volid = $drive->{file};
 835             return if $volid =~ m|^/|;
 836
 837             return if $volhash->{$volid}; # volume might be referenced multiple times
 838
 839             $volhash->{$volid} = 1;
 840
 841             $check_volid->($volid, $vmid, 'qemu', $reference);
 842         };
 843
 844         my $opts = {
 845             extra_keys => ['vmstate'],
 846             include_unused => 1,
 847         };
 848         # startup from a suspended state works even without 'images' content type on the
 849         # state storage, so do not check 'vmstate' for $conf
 850         PVE::QemuConfig->foreach_volume_full($conf, { include_unused => 1 }, $check, 'in config');
 851         for my $snapname (keys $conf->{snapshots}->%*) {
 852             my $snap = $conf->{snapshots}->{$snapname};
 853             PVE::QemuConfig->foreach_volume_full($snap, $opts, $check, "in snapshot '$snapname'");
 854         }
 855     }
 856
 857     if ($found_referenced) {
 858         log_warn("Proxmox VE 7.0 enforces stricter content type checks. The guests above " .
 859             "might not work until the storage configuration is fixed.");
 860     }
 861
 862     for my $volid (sort keys $potentially_affected->%*) {
 863         next if $referenced_volids->{$volid}; # already checked
 864
 865         my (undef, undef, $vmid) = PVE::Storage::parse_volname($storage_cfg, $volid);
 866         my $vmtype = $guests->{$vmid};
 867         next if !$vmtype;
 868
 869         $check_volid->($volid, $vmid, $vmtype, 'unreferenced');
 870     }
 871
 872     if ($found_unreferenced) {
 873         log_warn("When migrating, Proxmox VE 7.0 only scans storages with the appropriate " .
 874             "content types for unreferenced guest volumes.");
 875     }
 876
 877     if ($pass) {
 878         log_pass("no problems found");
 879     }
 880 }
 881
 882 sub check_containers_cgroup_compat {
 883
 884     my $kernel_cli = PVE::Tools::file_get_contents('/proc/cmdline');
 885     if ($kernel_cli =~ /systemd.unified_cgroup_hierarchy=0/){
 886         log_skip("System explicitly configured for legacy hybrid cgroup hierarchy.");
 887         return;
 888     }
 889
 890     my $supports_cgroupv2 = sub {
 891         my ($conf, $rootdir, $ctid) = @_;
 892
 893         my $get_systemd_version = sub {
 894             my ($self) = @_;
 895
 896             my $sd_lib_dir = -d "/lib/systemd" ? "/lib/systemd" : "/usr/lib/systemd";
 897             my $libsd = PVE::Tools::dir_glob_regex($sd_lib_dir, "libsystemd-shared-.+\.so");
 898             if (defined($libsd) && $libsd =~ /libsystemd-shared-(\d+)\.so/) {
 899                 return $1;
 900             }
 901
 902             return undef;
 903         };
 904
 905         my  $unified_cgroupv2_support = sub {
 906             my ($self) = @_;
 907
 908             # https://www.freedesktop.org/software/systemd/man/systemd.html
 909             # systemd is installed as symlink to /sbin/init
 910             my $systemd = CORE::readlink('/sbin/init');
 911
 912             # assume non-systemd init will run with unified cgroupv2
 913             if (!defined($systemd) || $systemd !~ m@/systemd$@) {
 914                 return 1;
 915             }
 916
 917             # systemd version 232 (e.g. debian stretch) supports the unified hierarchy
 918             my $sdver = $get_systemd_version->();
 919             if (!defined($sdver) || $sdver < 232) {
 920                 return 0;
 921             }
 922
 923             return 1;
 924         };
 925
 926         my $ostype = $conf->{ostype};
 927         if (!defined($ostype)) {
 928             log_warn("Found CT ($ctid) without 'ostype' set!");
 929         } elsif ($ostype eq 'devuan' || $ostype eq 'alpine') {
 930             return 1; # no systemd, no cgroup problems
 931         }
 932
 933         my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 934         return $lxc_setup->protected_call($unified_cgroupv2_support);
 935     };
 936
 937     my $log_problem = sub {
 938         my ($ctid) = @_;
 939         log_warn("Found at least one CT ($ctid) which does not support running in a unified cgroup v2" .
 940             " layout.\n    Either upgrade the Container distro or set systemd.unified_cgroup_hierarchy=0 " .
 941             "in the Proxmox VE hosts' kernel cmdline! Skipping further CT compat checks."
 942         );
 943     };
 944
 945     my $cts = eval { PVE::API2::LXC->vmlist({ node => $nodename }) };
 946     if ($@) {
 947         log_warn("Failed to retrieve information about this node's CTs - $@");
 948         return;
 949     }
 950
 951     if (!defined($cts) || !scalar(@$cts)) {
 952         log_skip("No containers on node detected.");
 953         return;
 954     }
 955
 956     my @running_cts = sort { $a <=> $b } grep { $_->{status} eq 'running' } @$cts;
 957     my @offline_cts = sort { $a <=> $b } grep { $_->{status} ne 'running' } @$cts;
 958
 959     for my $ct (@running_cts) {
 960         my $ctid = $ct->{vmid};
 961         my $pid = eval { PVE::LXC::find_lxc_pid($ctid) };
 962         if (my $err = $@) {
 963             log_warn("Failed to get PID for running CT $ctid - $err");
 964             next;
 965         }
 966         my $rootdir = "/proc/$pid/root";
 967         my $conf = PVE::LXC::Config->load_config($ctid);
 968
 969         my $ret = eval { $supports_cgroupv2->($conf, $rootdir, $ctid) };
 970         if (my $err = $@) {
 971             log_warn("Failed to get cgroup support status for CT $ctid - $err");
 972             next;
 973         }
 974         if (!$ret) {
 975             $log_problem->($ctid);
 976             return;
 977         }
 978     }
 979
 980     my $storage_cfg = PVE::Storage::config();
 981     for my $ct (@offline_cts) {
 982         my $ctid = $ct->{vmid};
 983         my ($conf, $rootdir, $ret);
 984         eval {
 985             $conf = PVE::LXC::Config->load_config($ctid);
 986             $rootdir = PVE::LXC::mount_all($ctid, $storage_cfg, $conf);
 987             $ret = $supports_cgroupv2->($conf, $rootdir, $ctid);
 988         };
 989         if (my $err = $@) {
 990             log_warn("Failed to load config and mount CT $ctid - $err");
 991             eval { PVE::LXC::umount_all($ctid, $storage_cfg, $conf) };
 992             next;
 993         }
 994         if (!$ret) {
 995             $log_problem->($ctid);
 996             eval { PVE::LXC::umount_all($ctid, $storage_cfg, $conf) };
 997             last;
 998         }
 999
1000         eval { PVE::LXC::umount_all($ctid, $storage_cfg, $conf) };
1001     }
1002 };
1003
1004 sub check_misc {
1005     print_header("MISCELLANEOUS CHECKS");
1006     my $ssh_config = eval { PVE::Tools::file_get_contents('/root/.ssh/config') };
1007     if (defined($ssh_config)) {
1008         log_fail("Unsupported SSH Cipher configured for root in /root/.ssh/config: $1")
1009             if $ssh_config =~ /^Ciphers .*(blowfish|arcfour|3des).*$/m;
1010     } else {
1011         log_skip("No SSH config file found.");
1012     }
1013
1014     log_info("Checking common daemon services..");
1015     $log_systemd_unit_state->('pveproxy.service');
1016     $log_systemd_unit_state->('pvedaemon.service');
1017     $log_systemd_unit_state->('pvestatd.service');
1018
1019     my $root_free = PVE::Tools::df('/', 10);
1020     log_warn("Less than 4 GiB free space on root file system.")
1021         if defined($root_free) && $root_free->{avail} < 4*1024*1024*1024;
1022
1023     log_info("Checking for running guests..");
1024     my $running_guests = 0;
1025
1026     my $vms = eval { PVE::API2::Qemu->vmlist({ node => $nodename }) };
1027     log_warn("Failed to retrieve information about this node's VMs - $@") if $@;
1028     $running_guests += grep { $_->{status} eq 'running' } @$vms if defined($vms);
1029
1030     my $cts = eval { PVE::API2::LXC->vmlist({ node => $nodename }) };
1031     log_warn("Failed to retrieve information about this node's CTs - $@") if $@;
1032     $running_guests += grep { $_->{status} eq 'running' } @$cts if defined($cts);
1033
1034     if ($running_guests > 0) {
1035         log_warn("$running_guests running guest(s) detected - consider migrating or stopping them.")
1036     } else {
1037         log_pass("no running guest detected.")
1038     }
1039
1040     log_info("Checking if the local node's hostname '$nodename' is resolvable..");
1041     my $local_ip = eval { PVE::Network::get_ip_from_hostname($nodename) };
1042     if ($@) {
1043         log_warn("Failed to resolve hostname '$nodename' to IP - $@");
1044     } else {
1045         log_info("Checking if resolved IP is configured on local node..");
1046         my $cidr = Net::IP::ip_is_ipv6($local_ip) ? "$local_ip/128" : "$local_ip/32";
1047         my $configured_ips = PVE::Network::get_local_ip_from_cidr($cidr);
1048         my $ip_count = scalar(@$configured_ips);
1049
1050         if ($ip_count <= 0) {
1051             log_fail("Resolved node IP '$local_ip' not configured or active for '$nodename'");
1052         } elsif ($ip_count > 1) {
1053             log_warn("Resolved node IP '$local_ip' active on multiple ($ip_count) interfaces!");
1054         } else {
1055             log_pass("Resolved node IP '$local_ip' configured and active on single interface.");
1056         }
1057     }
1058
1059     log_info("Check node certificate's RSA key size");
1060     my $certs = PVE::API2::Certificates->info({ node => $nodename });
1061     my $certs_check = {
1062         'rsaEncryption' => {
1063             minsize => 2048,
1064             name => 'RSA',
1065         },
1066         'id-ecPublicKey' => {
1067             minsize => 224,
1068             name => 'ECC',
1069         },
1070     };
1071
1072     my $certs_check_failed = 0;
1073     foreach my $cert (@$certs) {
1074         my ($type, $size, $fn) = $cert->@{qw(public-key-type public-key-bits filename)};
1075
1076         if (!defined($type) || !defined($size)) {
1077             log_warn("'$fn': cannot check certificate, failed to get it's type or size!");
1078         }
1079
1080         my $check = $certs_check->{$type};
1081         if (!defined($check)) {
1082             log_warn("'$fn': certificate's public key type '$type' unknown, check Debian Busters release notes");
1083             next;
1084         }
1085
1086         if ($size < $check->{minsize}) {
1087             log_fail("'$fn', certificate's $check->{name} public key size is less than 2048 bit");
1088             $certs_check_failed = 1;
1089         } else {
1090             log_pass("Certificate '$fn' passed Debian Busters security level for TLS connections ($size >= 2048)");
1091         }
1092     }
1093
1094     check_backup_retention_settings();
1095     check_cifs_credential_location();
1096     check_custom_pool_roles();
1097     check_description_lengths();
1098     check_storage_content();
1099 }
1100
1101 __PACKAGE__->register_method ({
1102     name => 'checklist',
1103     path => 'checklist',
1104     method => 'GET',
1105     description => 'Check (pre-/post-)upgrade conditions.',
1106     parameters => {
1107         additionalProperties => 0,
1108         properties => {
1109             full => {
1110                 description => 'perform additional, expensive checks.',
1111                 type => 'boolean',
1112                 optional => 1,
1113                 default => 0,
1114             },
1115         },
1116     },
1117     returns => { type => 'null' },
1118     code => sub {
1119         my ($param) = @_;
1120
1121         check_pve_packages();
1122         check_cluster_corosync();
1123         check_ceph();
1124         check_storage_health();
1125         check_misc();
1126
1127         if ($param->{full}) {
1128             check_containers_cgroup_compat();
1129         } else {
1130             log_skip("NOTE: Expensive checks, like CT cgroupv2 compat, not performed without '--full' parameter");
1131         }
1132
1133         print_header("SUMMARY");
1134
1135         my $total = 0;
1136         $total += $_ for values %$counters;
1137
1138         print "TOTAL:    $total\n";
1139         print colored("PASSED:   $counters->{pass}\n", 'green');
1140         print "SKIPPED:  $counters->{skip}\n";
1141         print colored("WARNINGS: $counters->{warn}\n", 'yellow');
1142         print colored("FAILURES: $counters->{fail}\n", 'red');
1143
1144         if ($counters->{warn} > 0 || $counters->{fail} > 0) {
1145             my $color = $counters->{fail} > 0 ? 'red' : 'yellow';
1146             print colored("\nATTENTION: Please check the output for detailed information!\n", $color);
1147             print colored("Try to solve the problems one at a time and then run this checklist tool again.\n", $color) if $counters->{fail} > 0;
1148         }
1149
1150         return undef;
1151     }});
1152
1153 our $cmddef = [ __PACKAGE__, 'checklist', [], {}];
1154
1155 1;