PVE/CLI/pve6to7.pm

   1 package PVE::CLI::pve6to7;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::API2::APT;
   7 use PVE::API2::Ceph;
   8 use PVE::API2::LXC;
   9 use PVE::API2::Qemu;
  10 use PVE::API2::Certificates;
  11 use PVE::API2::Cluster::Ceph;
  12
  13 use PVE::AccessControl;
  14 use PVE::Ceph::Tools;
  15 use PVE::Cluster;
  16 use PVE::Corosync;
  17 use PVE::INotify;
  18 use PVE::JSONSchema;
  19 use PVE::NodeConfig;
  20 use PVE::RPCEnvironment;
  21 use PVE::Storage;
  22 use PVE::Storage::Plugin;
  23 use PVE::Tools qw(run_command split_list);
  24 use PVE::QemuConfig;
  25 use PVE::QemuServer;
  26 use PVE::VZDump::Common;
  27 use PVE::LXC;
  28 use PVE::LXC::Config;
  29 use PVE::LXC::Setup;
  30
  31 use Term::ANSIColor;
  32
  33 use PVE::CLIHandler;
  34
  35 use base qw(PVE::CLIHandler);
  36
  37 my $nodename = PVE::INotify::nodename();
  38
  39 sub setup_environment {
  40     PVE::RPCEnvironment->setup_default_cli_env();
  41 }
  42
  43 my $min_pve_major = 6;
  44 my $min_pve_minor = 4;
  45 my $min_pve_pkgrel = 1;
  46
  47 my $forced_legacy_cgroup = 0;
  48
  49 my $counters = {
  50     pass => 0,
  51     skip => 0,
  52     warn => 0,
  53     fail => 0,
  54 };
  55
  56 my $log_line = sub {
  57     my ($level, $line) = @_;
  58
  59     $counters->{$level}++ if defined($level) && defined($counters->{$level});
  60
  61     print uc($level), ': ' if defined($level);
  62     print "$line\n";
  63 };
  64
  65 sub log_pass {
  66     print color('green');
  67     $log_line->('pass', @_);
  68     print color('reset');
  69 }
  70
  71 sub log_info {
  72     $log_line->('info', @_);
  73 }
  74 sub log_skip {
  75     $log_line->('skip', @_);
  76 }
  77 sub log_warn {
  78     print color('yellow');
  79     $log_line->('warn', @_);
  80     print color('reset');
  81 }
  82 sub log_fail {
  83     print color('red');
  84     $log_line->('fail', @_);
  85     print color('reset');
  86 }
  87
  88 my $print_header_first = 1;
  89 sub print_header {
  90     my ($h) = @_;
  91     print "\n" if !$print_header_first;
  92     print "= $h =\n\n";
  93     $print_header_first = 0;
  94 }
  95
  96 my $get_systemd_unit_state = sub {
  97     my ($unit) = @_;
  98
  99     my $state;
 100     my $filter_output = sub {
 101         $state = shift;
 102         chomp $state;
 103     };
 104     eval {
 105         run_command(['systemctl', 'is-enabled', "$unit"], outfunc => $filter_output, noerr => 1);
 106         return if !defined($state);
 107         run_command(['systemctl', 'is-active', "$unit"], outfunc => $filter_output, noerr => 1);
 108     };
 109
 110     return $state // 'unknown';
 111 };
 112 my $log_systemd_unit_state = sub {
 113     my ($unit, $no_fail_on_inactive) = @_;
 114
 115     my $log_method = \&log_warn;
 116
 117     my $state = $get_systemd_unit_state->($unit);
 118     if ($state eq 'active') {
 119         $log_method = \&log_pass;
 120     } elsif ($state eq 'inactive') {
 121         $log_method = $no_fail_on_inactive ? \&log_warn : \&log_fail;
 122     } elsif ($state eq 'failed') {
 123         $log_method = \&log_fail;
 124     }
 125
 126     $log_method->("systemd unit '$unit' is in state '$state'");
 127 };
 128
 129 my $versions;
 130 my $get_pkg = sub {
 131     my ($pkg) = @_;
 132
 133     $versions = eval { PVE::API2::APT->versions({ node => $nodename }) } if !defined($versions);
 134
 135     if (!defined($versions)) {
 136         my $msg = "unable to retrieve package version information";
 137         $msg .= "- $@" if $@;
 138         log_fail("$msg");
 139         return undef;
 140     }
 141
 142     my $pkgs = [ grep { $_->{Package} eq $pkg } @$versions ];
 143     if (!defined $pkgs || $pkgs == 0) {
 144         log_fail("unable to determine installed $pkg version.");
 145         return undef;
 146     } else {
 147         return $pkgs->[0];
 148     }
 149 };
 150
 151 sub check_pve_packages {
 152     print_header("CHECKING VERSION INFORMATION FOR PVE PACKAGES");
 153
 154     print "Checking for package updates..\n";
 155     my $updates = eval { PVE::API2::APT->list_updates({ node => $nodename }); };
 156     if (!defined($updates)) {
 157         log_warn("$@") if $@;
 158         log_fail("unable to retrieve list of package updates!");
 159     } elsif (@$updates > 0) {
 160         my $pkgs = join(', ', map { $_->{Package} } @$updates);
 161         log_warn("updates for the following packages are available:\n  $pkgs");
 162     } else {
 163         log_pass("all packages uptodate");
 164     }
 165
 166     print "\nChecking proxmox-ve package version..\n";
 167     if (defined(my $proxmox_ve = $get_pkg->('proxmox-ve'))) {
 168         my $min_pve_ver = "$min_pve_major.$min_pve_minor-$min_pve_pkgrel";
 169
 170         my ($maj, $min, $pkgrel) = $proxmox_ve->{OldVersion} =~ m/^(\d+)\.(\d+)-(\d+)/;
 171
 172         my $upgraded = 0;
 173
 174         if ($maj > $min_pve_major) {
 175             log_pass("already upgraded to Proxmox VE " . ($min_pve_major + 1));
 176             $upgraded = 1;
 177         } elsif ($maj >= $min_pve_major && $min >= $min_pve_minor && $pkgrel >= $min_pve_pkgrel) {
 178             log_pass("proxmox-ve package has version >= $min_pve_ver");
 179         } else {
 180             log_fail("proxmox-ve package is too old, please upgrade to >= $min_pve_ver!");
 181         }
 182
 183         my ($krunning, $kinstalled) = (qr/5\.11/, 'pve-kernel-5.11');
 184         if (!$upgraded) {
 185             ($krunning, $kinstalled) = (qr/5\.(?:4|11)/, 'pve-kernel-4.15');
 186         }
 187
 188         print "\nChecking running kernel version..\n";
 189         my $kernel_ver = $proxmox_ve->{RunningKernel};
 190         if (!defined($kernel_ver)) {
 191             log_fail("unable to determine running kernel version.");
 192         } elsif ($kernel_ver =~ /^$krunning/) {
 193             log_pass("expected running kernel '$kernel_ver'.");
 194         } elsif ($get_pkg->($kinstalled)) {
 195             log_warn("expected kernel '$kinstalled' intalled but not yet rebooted!");
 196         } else {
 197             log_warn("unexpected running and installed kernel '$kernel_ver'.");
 198         }
 199     } else {
 200         log_fail("proxmox-ve package not found!");
 201     }
 202 }
 203
 204
 205 sub check_storage_health {
 206     print_header("CHECKING CONFIGURED STORAGES");
 207     my $cfg = PVE::Storage::config();
 208
 209     my $ctime = time();
 210
 211     my $info = PVE::Storage::storage_info($cfg);
 212
 213     foreach my $storeid (sort keys %$info) {
 214         my $d = $info->{$storeid};
 215         if ($d->{enabled}) {
 216             if ($d->{type} eq 'sheepdog') {
 217                 log_fail("storage '$storeid' of type 'sheepdog' is enabled - experimental sheepdog support dropped in PVE 6")
 218             } elsif ($d->{active}) {
 219                 log_pass("storage '$storeid' enabled and active.");
 220             } else {
 221                 log_warn("storage '$storeid' enabled but not active!");
 222             }
 223         } else {
 224             log_skip("storage '$storeid' disabled.");
 225         }
 226     }
 227 }
 228
 229 sub check_cluster_corosync {
 230     print_header("CHECKING CLUSTER HEALTH/SETTINGS");
 231
 232     if (!PVE::Corosync::check_conf_exists(1)) {
 233         log_skip("standalone node.");
 234         return;
 235     }
 236
 237     $log_systemd_unit_state->('pve-cluster.service');
 238     $log_systemd_unit_state->('corosync.service');
 239
 240     if (PVE::Cluster::check_cfs_quorum(1)) {
 241         log_pass("Cluster Filesystem is quorate.");
 242     } else {
 243         log_fail("Cluster Filesystem readonly, lost quorum?!");
 244     }
 245
 246     my $conf = PVE::Cluster::cfs_read_file('corosync.conf');
 247     my $conf_nodelist = PVE::Corosync::nodelist($conf);
 248     my $node_votes = 0;
 249
 250     print "\nAnalzying quorum settings and state..\n";
 251     if (!defined($conf_nodelist)) {
 252         log_fail("unable to retrieve nodelist from corosync.conf");
 253     } else {
 254         if (grep { $conf_nodelist->{$_}->{quorum_votes} != 1 } keys %$conf_nodelist) {
 255             log_warn("non-default quorum_votes distribution detected!");
 256         }
 257         map { $node_votes += $conf_nodelist->{$_}->{quorum_votes} // 0 } keys %$conf_nodelist;
 258     }
 259
 260     my ($expected_votes, $total_votes);
 261     my $filter_output = sub {
 262         my $line = shift;
 263         ($expected_votes) = $line =~ /^Expected votes:\s*(\d+)\s*$/
 264             if !defined($expected_votes);
 265         ($total_votes) = $line =~ /^Total votes:\s*(\d+)\s*$/
 266             if !defined($total_votes);
 267     };
 268     eval {
 269         run_command(['corosync-quorumtool', '-s'], outfunc => $filter_output, noerr => 1);
 270     };
 271
 272     if (!defined($expected_votes)) {
 273         log_fail("unable to get expected number of votes, setting to 0.");
 274         $expected_votes = 0;
 275     }
 276     if (!defined($total_votes)) {
 277         log_fail("unable to get expected number of votes, setting to 0.");
 278         $total_votes = 0;
 279     }
 280
 281     my $cfs_nodelist = PVE::Cluster::get_clinfo()->{nodelist};
 282     my $offline_nodes = grep { $cfs_nodelist->{$_}->{online} != 1 } keys %$cfs_nodelist;
 283     if ($offline_nodes > 0) {
 284         log_fail("$offline_nodes nodes are offline!");
 285     }
 286
 287     my $qdevice_votes = 0;
 288     if (my $qdevice_setup = $conf->{main}->{quorum}->{device}) {
 289         $qdevice_votes = $qdevice_setup->{votes} // 1;
 290     }
 291
 292     log_info("configured votes - nodes: $node_votes");
 293     log_info("configured votes - qdevice: $qdevice_votes");
 294     log_info("current expected votes: $expected_votes");
 295     log_info("current total votes: $total_votes");
 296
 297     log_warn("expected votes set to non-standard value '$expected_votes'.")
 298         if $expected_votes != $node_votes + $qdevice_votes;
 299     log_warn("total votes < expected votes: $total_votes/$expected_votes!")
 300         if $total_votes < $expected_votes;
 301
 302     my $conf_nodelist_count = scalar(keys %$conf_nodelist);
 303     my $cfs_nodelist_count = scalar(keys %$cfs_nodelist);
 304     log_warn("cluster consists of less than three quorum-providing nodes!")
 305         if $conf_nodelist_count < 3 && $conf_nodelist_count + $qdevice_votes < 3;
 306
 307     log_fail("corosync.conf ($conf_nodelist_count) and pmxcfs ($cfs_nodelist_count) don't agree about size of nodelist.")
 308         if $conf_nodelist_count != $cfs_nodelist_count;
 309
 310     print "\nChecking nodelist entries..\n";
 311     my $nodelist_pass = 1;
 312     for my $cs_node (sort keys %$conf_nodelist) {
 313         my $entry = $conf_nodelist->{$cs_node};
 314         if (!defined($entry->{name})) {
 315             $nodelist_pass = 0;
 316             log_fail("$cs_node: no name entry in corosync.conf.");
 317         }
 318         if (!defined($entry->{nodeid})) {
 319             $nodelist_pass = 0;
 320             log_fail("$cs_node: no nodeid configured in corosync.conf.");
 321         }
 322         my $gotLinks = 0;
 323         for my $link (0..7) {
 324             $gotLinks++ if defined($entry->{"ring${link}_addr"});
 325         }
 326         if ($gotLinks <= 0) {
 327             $nodelist_pass = 0;
 328             log_fail("$cs_node: no ringX_addr (0 <= X <= 7) link defined in corosync.conf.");
 329         }
 330
 331         my $verify_ring_ip = sub {
 332             my $key = shift;
 333             if (defined(my $ring = $entry->{$key})) {
 334                 my ($resolved_ip, undef) = PVE::Corosync::resolve_hostname_like_corosync($ring, $conf);
 335                 if (defined($resolved_ip)) {
 336                     if ($resolved_ip ne $ring) {
 337                         $nodelist_pass = 0;
 338                         log_warn("$cs_node: $key '$ring' resolves to '$resolved_ip'.\n Consider replacing it with the currently resolved IP address.");
 339                     }
 340                 } else {
 341                     $nodelist_pass = 0;
 342                     log_fail("$cs_node: unable to resolve $key '$ring' to an IP address according to Corosync's resolve strategy - cluster will potentially fail with Corosync 3.x/kronosnet!");
 343                 }
 344             }
 345         };
 346         for my $link (0..7) {
 347             $verify_ring_ip->("ring${link}_addr");
 348         }
 349     }
 350     log_pass("nodelist settings OK") if $nodelist_pass;
 351
 352     print "\nChecking totem settings..\n";
 353     my $totem = $conf->{main}->{totem};
 354     my $totem_pass = 1;
 355
 356     my $transport = $totem->{transport};
 357     if (defined($transport)) {
 358         if ($transport ne 'knet') {
 359             $totem_pass = 0;
 360             log_fail("Corosync transport explicitly set to '$transport' instead of implicit default!");
 361         }
 362     }
 363
 364     # TODO: are those values still up-to-date?
 365     if ((!defined($totem->{secauth}) || $totem->{secauth} ne 'on') && (!defined($totem->{crypto_cipher}) || $totem->{crypto_cipher} eq 'none')) {
 366         $totem_pass = 0;
 367         log_fail("Corosync authentication/encryption is not explicitly enabled (secauth / crypto_cipher / crypto_hash)!");
 368     } elsif (defined($totem->{crypto_cipher}) && $totem->{crypto_cipher} eq '3des') {
 369         $totem_pass = 0;
 370         log_fail("Corosync encryption cipher set to '3des', no longer supported in Corosync 3.x!"); # FIXME: can be removed?
 371     }
 372
 373     log_pass("totem settings OK") if $totem_pass;
 374     print "\n";
 375     log_info("run 'pvecm status' to get detailed cluster status..");
 376
 377     if (defined(my $corosync = $get_pkg->('corosync'))) {
 378         if ($corosync->{OldVersion} =~ m/^2\./) {
 379             log_fail("\ncorosync 2.x installed, cluster-wide upgrade to 3.x needed!");
 380         } elsif ($corosync->{OldVersion} !~ m/^3\./) {
 381             log_fail("\nunexpected corosync version installed: $corosync->{OldVersion}!");
 382         }
 383     }
 384 }
 385
 386 sub check_ceph {
 387     print_header("CHECKING HYPER-CONVERGED CEPH STATUS");
 388
 389     if (PVE::Ceph::Tools::check_ceph_inited(1)) {
 390         log_info("hyper-converged ceph setup detected!");
 391     } else {
 392         log_skip("no hyper-converged ceph setup detected!");
 393         return;
 394     }
 395
 396     log_info("getting Ceph status/health information..");
 397     my $ceph_status = eval { PVE::API2::Ceph->status({ node => $nodename }); };
 398     my $noout = eval { PVE::API2::Cluster::Ceph->get_flag({ flag => "noout" }); };
 399     if ($@) {
 400         log_fail("failed to get 'noout' flag status - $@");
 401     }
 402
 403     my $noout_wanted = 1;
 404
 405     if (!$ceph_status || !$ceph_status->{health}) {
 406         log_fail("unable to determine Ceph status!");
 407     } else {
 408         my $ceph_health = $ceph_status->{health}->{status};
 409         if (!$ceph_health) {
 410             log_fail("unable to determine Ceph health!");
 411         } elsif ($ceph_health eq 'HEALTH_OK') {
 412             log_pass("Ceph health reported as 'HEALTH_OK'.");
 413         } elsif ($ceph_health eq 'HEALTH_WARN' && $noout && (keys %{$ceph_status->{health}->{checks}} == 1)) {
 414                 log_pass("Ceph health reported as 'HEALTH_WARN' with a single failing check and 'noout' flag set.");
 415         } else {
 416                 log_warn("Ceph health reported as '$ceph_health'.\n      Use the PVE ".
 417                   "dashboard or 'ceph -s' to determine the specific issues and try to resolve them.");
 418         }
 419     }
 420
 421     # TODO: check OSD min-required version, if to low it breaks stuff!
 422
 423     log_info("getting Ceph daemon versions..");
 424     my $ceph_versions = eval { PVE::Ceph::Tools::get_cluster_versions(undef, 1); };
 425     if (!$ceph_versions) {
 426         log_fail("unable to determine Ceph daemon versions!");
 427     } else {
 428         my $services = [
 429             { 'key' => 'mon', 'name' => 'monitor' },
 430             { 'key' => 'mgr', 'name' => 'manager' },
 431             { 'key' => 'mds', 'name' => 'MDS' },
 432             { 'key' => 'osd', 'name' => 'OSD' },
 433         ];
 434
 435         foreach my $service (@$services) {
 436             my $name = $service->{name};
 437             if (my $service_versions = $ceph_versions->{$service->{key}}) {
 438                 if (keys %$service_versions == 0) {
 439                     log_skip("no running instances detected for daemon type $name.");
 440                 } elsif (keys %$service_versions == 1) {
 441                     log_pass("single running version detected for daemon type $name.");
 442                 } else {
 443                     log_warn("multiple running versions detected for daemon type $name!");
 444                 }
 445             } else {
 446                 log_skip("unable to determine versions of running Ceph $name instances.");
 447             }
 448         }
 449
 450         my $overall_versions = $ceph_versions->{overall};
 451         if (!$overall_versions) {
 452             log_warn("unable to determine overall Ceph daemon versions!");
 453         } elsif (keys %$overall_versions == 1) {
 454             log_pass("single running overall version detected for all Ceph daemon types.");
 455             $noout_wanted = 1; # off post-upgrade, on pre-upgrade
 456         } else {
 457             log_warn("overall version mismatch detected, check 'ceph versions' output for details!");
 458         }
 459     }
 460
 461     if ($noout) {
 462         if ($noout_wanted) {
 463             log_pass("'noout' flag set to prevent rebalancing during cluster-wide upgrades.");
 464         } else {
 465             log_warn("'noout' flag set, Ceph cluster upgrade seems finished.");
 466         }
 467     } elsif ($noout_wanted) {
 468         log_warn("'noout' flag not set - recommended to prevent rebalancing during cluster-wide upgrades.");
 469     }
 470
 471     log_info("checking Ceph config..");
 472     my $conf = PVE::Cluster::cfs_read_file('ceph.conf');
 473     if (%$conf) {
 474         my $global = $conf->{global};
 475
 476         my $global_monhost = $global->{mon_host} // $global->{"mon host"} // $global->{"mon-host"};
 477         if (!defined($global_monhost)) {
 478             log_warn("No 'mon_host' entry found in ceph config.\n  It's recommended to add mon_host with all monitor addresses (without ports) to the global section.");
 479         }
 480
 481         my $ipv6 = $global->{ms_bind_ipv6} // $global->{"ms bind ipv6"} // $global->{"ms-bind-ipv6"};
 482         if ($ipv6) {
 483             my $ipv4 = $global->{ms_bind_ipv4} // $global->{"ms bind ipv4"} // $global->{"ms-bind-ipv4"};
 484             if ($ipv6 eq 'true' && (!defined($ipv4) || $ipv4 ne 'false')) {
 485                 log_warn("'ms_bind_ipv6' is enabled but 'ms_bind_ipv4' is not disabled.\n  Make sure to disable 'ms_bind_ipv4' for ipv6 only clusters, or add an ipv4 network to public/cluster network.");
 486             }
 487         }
 488
 489         if (defined($global->{keyring})) {
 490             log_warn("[global] config section contains 'keyring' option, which will prevent services from starting with Nautilus.\n Move 'keyring' option to [client] section instead.");
 491         }
 492
 493     } else {
 494         log_warn("Empty ceph config found");
 495     }
 496
 497     my $local_ceph_ver = PVE::Ceph::Tools::get_local_version(1);
 498     if (defined($local_ceph_ver)) {
 499         if ($local_ceph_ver <= 14) {
 500             log_fail("local Ceph version too low, at least Octopus required..");
 501         }
 502     } else {
 503         log_fail("unable to determine local Ceph version.");
 504     }
 505 }
 506
 507 sub check_backup_retention_settings {
 508     log_info("Checking backup retention settings..");
 509
 510     my $pass = 1;
 511
 512     my $node_has_retention;
 513
 514     my $maxfiles_msg = "parameter 'maxfiles' is deprecated with PVE 7.x and will be removed in a " .
 515         "future version, use 'prune-backups' instead.";
 516
 517     eval {
 518         my $confdesc = PVE::VZDump::Common::get_confdesc();
 519
 520         my $fn = "/etc/vzdump.conf";
 521         my $raw = PVE::Tools::file_get_contents($fn);
 522
 523         my $conf_schema = { type => 'object', properties => $confdesc, };
 524         my $param = PVE::JSONSchema::parse_config($conf_schema, $fn, $raw);
 525
 526         if (defined($param->{maxfiles})) {
 527             $pass = 0;
 528             log_warn("$fn - $maxfiles_msg");
 529         }
 530
 531         $node_has_retention = defined($param->{maxfiles}) || defined($param->{'prune-backups'});
 532     };
 533     if (my $err = $@) {
 534         $pass = 0;
 535         log_warn("unable to parse node's VZDump configuration - $err");
 536     }
 537
 538     my $storage_cfg = PVE::Storage::config();
 539
 540     for my $storeid (keys $storage_cfg->{ids}->%*) {
 541         my $scfg = $storage_cfg->{ids}->{$storeid};
 542
 543         if (defined($scfg->{maxfiles})) {
 544             $pass = 0;
 545             log_warn("storage '$storeid' - $maxfiles_msg");
 546         }
 547
 548         next if !$scfg->{content}->{backup};
 549         next if defined($scfg->{maxfiles}) || defined($scfg->{'prune-backups'});
 550         next if $node_has_retention;
 551
 552         log_info("storage '$storeid' - no backup retention settings defined - by default, PVE " .
 553             "7.x will no longer keep only the last backup, but all backups");
 554     }
 555
 556     eval {
 557         my $vzdump_cron = PVE::Cluster::cfs_read_file('vzdump.cron');
 558
 559         # only warn once, there might be many jobs...
 560         if (scalar(grep { defined($_->{maxfiles}) } $vzdump_cron->{jobs}->@*)) {
 561             $pass = 0;
 562             log_warn("/etc/pve/vzdump.cron - $maxfiles_msg");
 563         }
 564     };
 565     if (my $err = $@) {
 566         $pass = 0;
 567         log_warn("unable to parse node's VZDump configuration - $err");
 568     }
 569
 570     log_pass("no problems found.") if $pass;
 571 }
 572
 573 sub check_cifs_credential_location {
 574     log_info("checking CIFS credential location..");
 575
 576     my $regex = qr/^(.*)\.cred$/;
 577
 578     my $found;
 579
 580     PVE::Tools::dir_glob_foreach('/etc/pve/priv/', $regex, sub {
 581         my ($filename) = @_;
 582
 583         my ($basename) = $filename =~ $regex;
 584
 585         log_warn("CIFS credentials '/etc/pve/priv/$filename' will be moved to " .
 586             "'/etc/pve/priv/storage/$basename.pw' during the update");
 587
 588         $found = 1;
 589     });
 590
 591     log_pass("no CIFS credentials at outdated location found.") if !$found;
 592 }
 593
 594 sub check_custom_pool_roles {
 595     log_info("Checking custom roles for pool permissions..");
 596
 597     if (! -f "/etc/pve/user.cfg") {
 598         log_skip("user.cfg does not exist");
 599         return;
 600     }
 601
 602     my $raw = eval { PVE::Tools::file_get_contents('/etc/pve/user.cfg'); };
 603     if ($@) {
 604         log_fail("Failed to read '/etc/pve/user.cfg' - $@");
 605         return;
 606     }
 607
 608     my $roles = {};
 609     while ($raw =~ /^\s*(.+?)\s*$/gm) {
 610         my $line = $1;
 611         my @data;
 612
 613         foreach my $d (split (/:/, $line)) {
 614             $d =~ s/^\s+//;
 615             $d =~ s/\s+$//;
 616             push @data, $d
 617         }
 618
 619         my $et = shift @data;
 620         next if $et ne 'role';
 621
 622         my ($role, $privlist) = @data;
 623         if (!PVE::AccessControl::verify_rolename($role, 1)) {
 624             warn "user config - ignore role '$role' - invalid characters in role name\n";
 625             next;
 626         }
 627
 628         $roles->{$role} = {} if !$roles->{$role};
 629         foreach my $priv (split_list($privlist)) {
 630             $roles->{$role}->{$priv} = 1;
 631         }
 632     }
 633
 634     foreach my $role (sort keys %{$roles}) {
 635         if (PVE::AccessControl::role_is_special($role)) {
 636             next;
 637         }
 638
 639         if ($role eq "PVEPoolUser") {
 640             # the user created a custom role named PVEPoolUser
 641             log_fail("Custom role '$role' has a restricted name - a built-in role 'PVEPoolUser' will be available with the upgrade");
 642         } else {
 643             log_pass("Custom role '$role' has no restricted name");
 644         }
 645
 646         my $perms = $roles->{$role};
 647         if ($perms->{'Pool.Allocate'} && $perms->{'Pool.Audit'}) {
 648             log_pass("Custom role '$role' contains updated pool permissions");
 649         } elsif ($perms->{'Pool.Allocate'}) {
 650             log_warn("Custom role '$role' contains permission 'Pool.Allocate' - to ensure same behavior add 'Pool.Audit' to this role");
 651         } else {
 652             log_pass("Custom role '$role' contains no permissions that need to be updated");
 653         }
 654     }
 655 }
 656
 657 my sub check_max_length {
 658     my ($raw, $max_length, $warning) = @_;
 659     log_warn($warning) if defined($raw) && length($raw) > $max_length;
 660 }
 661
 662 sub check_node_and_guest_configurations {
 663     log_info("Checking node and guest description/note legnth..");
 664
 665     my @affected_nodes = grep {
 666         my $desc = PVE::NodeConfig::load_config($_)->{desc};
 667         defined($desc) && length($desc) > 64 * 1024
 668     } PVE::Cluster::get_nodelist();
 669
 670     if (scalar(@affected_nodes) > 0) {
 671         log_warn("Node config description of the following nodes too long for new limit of 64 KiB:\n    "
 672             . join(', ', @affected_nodes));
 673     } else {
 674         log_pass("All node config descriptions fit in the new limit of 64 KiB");
 675     }
 676
 677     my $affected_guests_long_desc = [];
 678     my $affected_cts_cgroup_keys = [];
 679
 680     my $cts = PVE::LXC::config_list();
 681     for my $vmid (sort { $a <=> $b } keys %$cts) {
 682         my $conf = PVE::LXC::Config->load_config($vmid);
 683
 684         my $desc = $conf->{description};
 685         push @$affected_guests_long_desc, "CT $vmid" if defined($desc) && length($desc) > 8 * 1024;
 686
 687         my $lxc_raw_conf = $conf->{lxc};
 688         push @$affected_cts_cgroup_keys, "CT $vmid"  if (grep (@$_[0] =~ /^lxc\.cgroup\./, @$lxc_raw_conf));
 689     }
 690     my $vms = PVE::QemuServer::config_list();
 691     for my $vmid (sort { $a <=> $b } keys %$vms) {
 692         my $desc = PVE::QemuConfig->load_config($vmid)->{description};
 693         push @$affected_guests_long_desc, "VM $vmid" if defined($desc) && length($desc) > 8 * 1024;
 694     }
 695     if (scalar($affected_guests_long_desc->@*) > 0) {
 696         log_warn("Guest config description of the following virtual-guests too long for new limit of 64 KiB:\n"
 697             ."    " . join(", ", $affected_guests_long_desc->@*));
 698     } else {
 699         log_pass("All guest config descriptions fit in the new limit of 8 KiB");
 700     }
 701
 702     log_info("Checking container configs for deprecated lxc.cgroup entries");
 703
 704     if (scalar($affected_cts_cgroup_keys->@*) > 0) {
 705         if ($forced_legacy_cgroup) {
 706             log_pass("Found legacy 'lxc.cgroup' keys, but system explicitly configured for legacy hybrid cgroup hierarchy.");
 707         }  else {
 708             log_warn("The following CTs have 'lxc.cgroup' keys configured, which will be ignored in the new default unified cgroupv2:\n"
 709                 ."    " . join(", ", $affected_cts_cgroup_keys->@*) ."\n"
 710                 ."    Often it can be enough to change to the new 'lxc.cgroup2' prefix after the upgrade to Proxmox VE 7.x");
 711         }
 712     } else {
 713         log_pass("No legacy 'lxc.cgroup' keys found.");
 714     }
 715 }
 716
 717 sub check_storage_content {
 718     log_info("Checking storage content type configuration..");
 719
 720     my $found;
 721     my $pass = 1;
 722
 723     my $storage_cfg = PVE::Storage::config();
 724
 725     for my $storeid (sort keys $storage_cfg->{ids}->%*) {
 726         my $scfg = $storage_cfg->{ids}->{$storeid};
 727
 728         next if $scfg->{shared};
 729         next if !PVE::Storage::storage_check_enabled($storage_cfg, $storeid, undef, 1);
 730
 731         my $valid_content = PVE::Storage::Plugin::valid_content_types($scfg->{type});
 732
 733         if (scalar(keys $scfg->{content}->%*) == 0 && !$valid_content->{none}) {
 734             $pass = 0;
 735             log_fail("storage '$storeid' does not support configured content type 'none'");
 736             delete $scfg->{content}->{none}; # scan for guest images below
 737         }
 738
 739         next if $scfg->{content}->{images};
 740         next if $scfg->{content}->{rootdir};
 741
 742         # Skip 'iscsi(direct)' (and foreign plugins with potentially similiar behavior) with 'none',
 743         # because that means "use LUNs directly" and vdisk_list() in PVE 6.x still lists those.
 744         # It's enough to *not* skip 'dir', because it is the only other storage that supports 'none'
 745         # and 'images' or 'rootdir', hence being potentially misconfigured.
 746         next if $scfg->{type} ne 'dir' && $scfg->{content}->{none};
 747
 748         eval { PVE::Storage::activate_storage($storage_cfg, $storeid) };
 749         if (my $err = $@) {
 750             log_warn("activating '$storeid' failed - $err");
 751             next;
 752         }
 753
 754         my $res = eval { PVE::Storage::vdisk_list($storage_cfg, $storeid); };
 755         if (my $err = $@) {
 756             log_warn("listing images on '$storeid' failed - $err");
 757             next;
 758         }
 759         my @volids = map { $_->{volid} } $res->{$storeid}->@*;
 760
 761         my $number = scalar(@volids);
 762         if ($number > 0) {
 763             log_info("storage '$storeid' - neither content type 'images' nor 'rootdir' configured"
 764                 .", but found $number guest volume(s)");
 765         }
 766     }
 767
 768     my $check_volid = sub {
 769         my ($volid, $vmid, $vmtype, $reference) = @_;
 770
 771         my $guesttext = $vmtype eq 'qemu' ? 'VM' : 'CT';
 772         my $prefix = "$guesttext $vmid - volume '$volid' ($reference)";
 773
 774         my ($storeid) = PVE::Storage::parse_volume_id($volid, 1);
 775         return if !defined($storeid);
 776
 777         my $scfg = $storage_cfg->{ids}->{$storeid};
 778         if (!$scfg) {
 779             $pass = 0;
 780             log_warn("$prefix - storage does not exist!");
 781             return;
 782         }
 783
 784         # cannot use parse_volname for containers, as it can return 'images'
 785         # but containers cannot have ISO images attached, so assume 'rootdir'
 786         my $vtype = 'rootdir';
 787         if ($vmtype eq 'qemu') {
 788             ($vtype) = eval { PVE::Storage::parse_volname($storage_cfg, $volid); };
 789             return if $@;
 790         }
 791
 792         if (!$scfg->{content}->{$vtype}) {
 793             $found = 1;
 794             $pass = 0;
 795             log_warn("$prefix - storage does not have content type '$vtype' configured.");
 796         }
 797     };
 798
 799     my $cts = PVE::LXC::config_list();
 800     for my $vmid (sort { $a <=> $b } keys %$cts) {
 801         my $conf = PVE::LXC::Config->load_config($vmid);
 802
 803         my $volhash = {};
 804
 805         my $check = sub {
 806             my ($ms, $mountpoint, $reference) = @_;
 807
 808             my $volid = $mountpoint->{volume};
 809             return if !$volid || $mountpoint->{type} ne 'volume';
 810
 811             return if $volhash->{$volid}; # volume might be referenced multiple times
 812
 813             $volhash->{$volid} = 1;
 814
 815             $check_volid->($volid, $vmid, 'lxc', $reference);
 816         };
 817
 818         my $opts = { include_unused => 1 };
 819         PVE::LXC::Config->foreach_volume_full($conf, $opts, $check, 'in config');
 820         for my $snapname (keys $conf->{snapshots}->%*) {
 821             my $snap = $conf->{snapshots}->{$snapname};
 822             PVE::LXC::Config->foreach_volume_full($snap, $opts, $check, "in snapshot '$snapname'");
 823         }
 824     }
 825
 826     my $vms = PVE::QemuServer::config_list();
 827     for my $vmid (sort { $a <=> $b } keys %$vms) {
 828         my $conf = PVE::QemuConfig->load_config($vmid);
 829
 830         my $volhash = {};
 831
 832         my $check = sub {
 833             my ($key, $drive, $reference) = @_;
 834
 835             my $volid = $drive->{file};
 836             return if $volid =~ m|^/|;
 837
 838             return if $volhash->{$volid}; # volume might be referenced multiple times
 839
 840             $volhash->{$volid} = 1;
 841
 842             $check_volid->($volid, $vmid, 'qemu', $reference);
 843         };
 844
 845         my $opts = {
 846             extra_keys => ['vmstate'],
 847             include_unused => 1,
 848         };
 849         # startup from a suspended state works even without 'images' content type on the
 850         # state storage, so do not check 'vmstate' for $conf
 851         PVE::QemuConfig->foreach_volume_full($conf, { include_unused => 1 }, $check, 'in config');
 852         for my $snapname (keys $conf->{snapshots}->%*) {
 853             my $snap = $conf->{snapshots}->{$snapname};
 854             PVE::QemuConfig->foreach_volume_full($snap, $opts, $check, "in snapshot '$snapname'");
 855         }
 856     }
 857
 858     if ($found) {
 859         log_warn("Proxmox VE 7.0 enforces stricter content type checks. The guests above " .
 860             "might not work until the storage configuration is fixed.");
 861     }
 862
 863     if ($pass) {
 864         log_pass("no problems found");
 865     }
 866 }
 867
 868 sub check_containers_cgroup_compat {
 869     if ($forced_legacy_cgroup) {
 870         log_skip("System explicitly configured for legacy hybrid cgroup hierarchy.");
 871         return;
 872     }
 873
 874     my $supports_cgroupv2 = sub {
 875         my ($conf, $rootdir, $ctid) = @_;
 876
 877         my $get_systemd_version = sub {
 878             my ($self) = @_;
 879
 880             my $sd_lib_dir = -d "/lib/systemd" ? "/lib/systemd" : "/usr/lib/systemd";
 881             my $libsd = PVE::Tools::dir_glob_regex($sd_lib_dir, "libsystemd-shared-.+\.so");
 882             if (defined($libsd) && $libsd =~ /libsystemd-shared-(\d+)\.so/) {
 883                 return $1;
 884             }
 885
 886             return undef;
 887         };
 888
 889         my  $unified_cgroupv2_support = sub {
 890             my ($self) = @_;
 891
 892             # https://www.freedesktop.org/software/systemd/man/systemd.html
 893             # systemd is installed as symlink to /sbin/init
 894             my $systemd = CORE::readlink('/sbin/init');
 895
 896             # assume non-systemd init will run with unified cgroupv2
 897             if (!defined($systemd) || $systemd !~ m@/systemd$@) {
 898                 return 1;
 899             }
 900
 901             # systemd version 232 (e.g. debian stretch) supports the unified hierarchy
 902             my $sdver = $get_systemd_version->();
 903             if (!defined($sdver) || $sdver < 232) {
 904                 return 0;
 905             }
 906
 907             return 1;
 908         };
 909
 910         my $ostype = $conf->{ostype};
 911         if (!defined($ostype)) {
 912             log_warn("Found CT ($ctid) without 'ostype' set!");
 913         } elsif ($ostype eq 'devuan' || $ostype eq 'alpine') {
 914             return 1; # no systemd, no cgroup problems
 915         }
 916
 917         my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 918         return $lxc_setup->protected_call($unified_cgroupv2_support);
 919     };
 920
 921     my $log_problem = sub {
 922         my ($ctid) = @_;
 923         log_warn("Found at least one CT ($ctid) which does not support running in a unified cgroup v2" .
 924             " layout.\n    Either upgrade the Container distro or set systemd.unified_cgroup_hierarchy=0 " .
 925             "in the Proxmox VE hosts' kernel cmdline! Skipping further CT compat checks."
 926         );
 927     };
 928
 929     my $cts = eval { PVE::API2::LXC->vmlist({ node => $nodename }) };
 930     if ($@) {
 931         log_warn("Failed to retrieve information about this node's CTs - $@");
 932         return;
 933     }
 934
 935     if (!defined($cts) || !scalar(@$cts)) {
 936         log_skip("No containers on node detected.");
 937         return;
 938     }
 939
 940     my @running_cts = sort { $a <=> $b } grep { $_->{status} eq 'running' } @$cts;
 941     my @offline_cts = sort { $a <=> $b } grep { $_->{status} ne 'running' } @$cts;
 942
 943     for my $ct (@running_cts) {
 944         my $ctid = $ct->{vmid};
 945         my $pid = eval { PVE::LXC::find_lxc_pid($ctid) };
 946         if (my $err = $@) {
 947             log_warn("Failed to get PID for running CT $ctid - $err");
 948             next;
 949         }
 950         my $rootdir = "/proc/$pid/root";
 951         my $conf = PVE::LXC::Config->load_config($ctid);
 952
 953         my $ret = eval { $supports_cgroupv2->($conf, $rootdir, $ctid) };
 954         if (my $err = $@) {
 955             log_warn("Failed to get cgroup support status for CT $ctid - $err");
 956             next;
 957         }
 958         if (!$ret) {
 959             $log_problem->($ctid);
 960             return;
 961         }
 962     }
 963
 964     my $storage_cfg = PVE::Storage::config();
 965     for my $ct (@offline_cts) {
 966         my $ctid = $ct->{vmid};
 967         my ($conf, $rootdir, $ret);
 968         eval {
 969             $conf = PVE::LXC::Config->load_config($ctid);
 970             $rootdir = PVE::LXC::mount_all($ctid, $storage_cfg, $conf);
 971             $ret = $supports_cgroupv2->($conf, $rootdir, $ctid);
 972         };
 973         if (my $err = $@) {
 974             log_warn("Failed to load config and mount CT $ctid - $err");
 975             eval { PVE::LXC::umount_all($ctid, $storage_cfg, $conf) };
 976             next;
 977         }
 978         if (!$ret) {
 979             $log_problem->($ctid);
 980             eval { PVE::LXC::umount_all($ctid, $storage_cfg, $conf) };
 981             last;
 982         }
 983
 984         eval { PVE::LXC::umount_all($ctid, $storage_cfg, $conf) };
 985     }
 986 };
 987
 988 sub check_security_repo {
 989     log_info("Checking if the suite for the Debian security repository is correct..");
 990
 991     my $found = 0;
 992
 993     my $dir = '/etc/apt/sources.list.d';
 994     my $in_dir = 0;
 995
 996     my $check_file = sub {
 997         my ($file) = @_;
 998
 999         $file = "${dir}/${file}" if $in_dir;
1000
1001         my $raw = eval { PVE::Tools::file_get_contents($file) };
1002         return if !defined($raw);
1003         my @lines = split(/\n/, $raw);
1004
1005         my $number = 0;
1006         for my $line (@lines) {
1007             $number++;
1008
1009             next if length($line) == 0; # split would result in undef then...
1010
1011             ($line) = split(/#/, $line);
1012
1013             next if $line !~ m/^deb[[:space:]]/; # is case sensitive
1014
1015             my $suite;
1016
1017             # catch any of
1018             # https://deb.debian.org/debian-security
1019             # http://security.debian.org/debian-security
1020             # http://security.debian.org/
1021             if ($line =~ m|https?://deb\.debian\.org/debian-security/?\s+(\S*)|i) {
1022                 $suite = $1;
1023             } elsif ($line =~ m|https?://security\.debian\.org(?:.*?)\s+(\S*)|i) {
1024                 $suite = $1;
1025             } else {
1026                 next;
1027             }
1028
1029             $found = 1;
1030
1031             my $where = "in ${file}:${number}";
1032
1033             if ($suite eq 'buster/updates') {
1034                 log_info("Make sure to change the suite of the Debian security repository " .
1035                     "from 'buster/updates' to 'bullseye-security' - $where");
1036             } elsif ($suite eq 'bullseye-security') {
1037                 log_pass("already using 'bullseye-security'");
1038             } else {
1039                 log_fail("The new suite of the Debian security repository should be " .
1040                     "'bullseye-security' - $where");
1041             }
1042         }
1043     };
1044
1045     $check_file->("/etc/apt/sources.list");
1046
1047     $in_dir = 1;
1048
1049     PVE::Tools::dir_glob_foreach($dir, '^.*\.list$', $check_file);
1050
1051     if (!$found) {
1052         # only warn, it might be defined in a .sources file or in a way not catched above
1053         log_warn("No Debian security repository detected in /etc/apt/sources.list and " .
1054             "/etc/apt/sources.list.d/*.list");
1055     }
1056 }
1057
1058 sub check_misc {
1059     print_header("MISCELLANEOUS CHECKS");
1060     my $ssh_config = eval { PVE::Tools::file_get_contents('/root/.ssh/config') };
1061     if (defined($ssh_config)) {
1062         log_fail("Unsupported SSH Cipher configured for root in /root/.ssh/config: $1")
1063             if $ssh_config =~ /^Ciphers .*(blowfish|arcfour|3des).*$/m;
1064     } else {
1065         log_skip("No SSH config file found.");
1066     }
1067
1068     log_info("Checking common daemon services..");
1069     $log_systemd_unit_state->('pveproxy.service');
1070     $log_systemd_unit_state->('pvedaemon.service');
1071     $log_systemd_unit_state->('pvestatd.service');
1072
1073     my $root_free = PVE::Tools::df('/', 10);
1074     log_warn("Less than 4 GiB free space on root file system.")
1075         if defined($root_free) && $root_free->{avail} < 4*1024*1024*1024;
1076
1077     log_info("Checking for running guests..");
1078     my $running_guests = 0;
1079
1080     my $vms = eval { PVE::API2::Qemu->vmlist({ node => $nodename }) };
1081     log_warn("Failed to retrieve information about this node's VMs - $@") if $@;
1082     $running_guests += grep { $_->{status} eq 'running' } @$vms if defined($vms);
1083
1084     my $cts = eval { PVE::API2::LXC->vmlist({ node => $nodename }) };
1085     log_warn("Failed to retrieve information about this node's CTs - $@") if $@;
1086     $running_guests += grep { $_->{status} eq 'running' } @$cts if defined($cts);
1087
1088     if ($running_guests > 0) {
1089         log_warn("$running_guests running guest(s) detected - consider migrating or stopping them.")
1090     } else {
1091         log_pass("no running guest detected.")
1092     }
1093
1094     log_info("Checking if the local node's hostname '$nodename' is resolvable..");
1095     my $local_ip = eval { PVE::Network::get_ip_from_hostname($nodename) };
1096     if ($@) {
1097         log_warn("Failed to resolve hostname '$nodename' to IP - $@");
1098     } else {
1099         log_info("Checking if resolved IP is configured on local node..");
1100         my $cidr = Net::IP::ip_is_ipv6($local_ip) ? "$local_ip/128" : "$local_ip/32";
1101         my $configured_ips = PVE::Network::get_local_ip_from_cidr($cidr);
1102         my $ip_count = scalar(@$configured_ips);
1103
1104         if ($ip_count <= 0) {
1105             log_fail("Resolved node IP '$local_ip' not configured or active for '$nodename'");
1106         } elsif ($ip_count > 1) {
1107             log_warn("Resolved node IP '$local_ip' active on multiple ($ip_count) interfaces!");
1108         } else {
1109             log_pass("Resolved node IP '$local_ip' configured and active on single interface.");
1110         }
1111     }
1112
1113     my $certs = PVE::API2::Certificates->info({ node => $nodename });
1114     my $certs_check = {
1115         'rsaEncryption' => {
1116             minsize => 2048,
1117             name => 'RSA',
1118         },
1119         'id-ecPublicKey' => {
1120             minsize => 224,
1121             name => 'ECC',
1122         },
1123     };
1124
1125     my $log_cert_heading_called;
1126     my $log_cert_heading_once = sub {
1127         return if $log_cert_heading_called;
1128         log_info("Check node certificate's RSA key size");
1129         $log_cert_heading_called = 1;
1130     };
1131
1132     my $certs_check_failed = 0;
1133     foreach my $cert (@$certs) {
1134         my ($type, $size, $fn) = $cert->@{qw(public-key-type public-key-bits filename)};
1135
1136         if (!defined($type) || !defined($size)) {
1137             $log_cert_heading_once->();
1138             log_warn("'$fn': cannot check certificate, failed to get it's type or size!");
1139         }
1140
1141         my $check = $certs_check->{$type};
1142         if (!defined($check)) {
1143             $log_cert_heading_once->();
1144             log_warn("'$fn': certificate's public key type '$type' unknown, check Debian Busters release notes");
1145             next;
1146         }
1147
1148         if ($size < $check->{minsize}) {
1149             $log_cert_heading_once->();
1150             log_fail("'$fn', certificate's $check->{name} public key size is less than 2048 bit");
1151             $certs_check_failed = 1;
1152         }
1153     }
1154
1155     check_backup_retention_settings();
1156     check_cifs_credential_location();
1157     check_custom_pool_roles();
1158     check_node_and_guest_configurations();
1159     check_storage_content();
1160     check_security_repo();
1161 }
1162
1163 __PACKAGE__->register_method ({
1164     name => 'checklist',
1165     path => 'checklist',
1166     method => 'GET',
1167     description => 'Check (pre-/post-)upgrade conditions.',
1168     parameters => {
1169         additionalProperties => 0,
1170         properties => {
1171             full => {
1172                 description => 'perform additional, expensive checks.',
1173                 type => 'boolean',
1174                 optional => 1,
1175                 default => 0,
1176             },
1177         },
1178     },
1179     returns => { type => 'null' },
1180     code => sub {
1181         my ($param) = @_;
1182
1183         my $kernel_cli = PVE::Tools::file_get_contents('/proc/cmdline');
1184         if ($kernel_cli =~ /systemd.unified_cgroup_hierarchy=0/){
1185             $forced_legacy_cgroup = 1;
1186         }
1187
1188         check_pve_packages();
1189         check_cluster_corosync();
1190         check_ceph();
1191         check_storage_health();
1192         check_misc();
1193
1194         if ($param->{full}) {
1195             check_containers_cgroup_compat();
1196         } else {
1197             log_skip("NOTE: Expensive checks, like CT cgroupv2 compat, not performed without '--full' parameter");
1198         }
1199
1200         print_header("SUMMARY");
1201
1202         my $total = 0;
1203         $total += $_ for values %$counters;
1204
1205         print "TOTAL:    $total\n";
1206         print colored("PASSED:   $counters->{pass}\n", 'green');
1207         print "SKIPPED:  $counters->{skip}\n";
1208         print colored("WARNINGS: $counters->{warn}\n", 'yellow');
1209         print colored("FAILURES: $counters->{fail}\n", 'red');
1210
1211         if ($counters->{warn} > 0 || $counters->{fail} > 0) {
1212             my $color = $counters->{fail} > 0 ? 'red' : 'yellow';
1213             print colored("\nATTENTION: Please check the output for detailed information!\n", $color);
1214             print colored("Try to solve the problems one at a time and then run this checklist tool again.\n", $color) if $counters->{fail} > 0;
1215         }
1216
1217         return undef;
1218     }});
1219
1220 our $cmddef = [ __PACKAGE__, 'checklist', [], {}];
1221
1222 1;