PVE/Report.pm

   1 package PVE::Report;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Tools;
   7
   8 $ENV{'PATH'} = '/sbin:/bin:/usr/sbin:/usr/bin';
   9
  10 my $cmd_timeout = 10; # generous timeout
  11
  12 my $init_report_cmds = sub {
  13     # NOTE: always add new sections to the report_order array!
  14     my $report_def = {
  15         general => {
  16             title => 'general system info',
  17             cmds => [
  18                 'hostname',
  19                 'pveversion --verbose',
  20                 'cat /etc/hosts',
  21                 'top -b -n 1  | head -n 15',
  22                 'pvesubscription get',
  23                 'lscpu',
  24                 'pvesh get /cluster/resources --type node --output-format=yaml',
  25             ],
  26         },
  27         storage => [
  28             'cat /etc/pve/storage.cfg',
  29             'pvesm status',
  30             'cat /etc/fstab',
  31             'findmnt --ascii',
  32             'df --human',
  33         ],
  34         'virtual guests' => [
  35            'qm list',
  36            sub { dir2text('/etc/pve/qemu-server/', '\d.*conf') },
  37            'pct list',
  38            sub { dir2text('/etc/pve/lxc/', '\d.*conf') },
  39         ],
  40         network => [
  41             'ip -details -statistics address',
  42             'ip -details -4 route show',
  43             'ip -details -6 route show',
  44             'cat /etc/network/interfaces',
  45         ],
  46         firewall => [
  47             sub { dir2text('/etc/pve/firewall/', '.*fw') },
  48             'cat /etc/pve/local/host.fw',
  49             'iptables-save',
  50         ],
  51         cluster => [
  52             'pvecm nodes',
  53             'pvecm status',
  54             'cat /etc/pve/corosync.conf 2>/dev/null'
  55         ],
  56         bios => [
  57             'dmidecode -t bios',
  58         ],
  59         pci => [
  60             'lspci -nnk',
  61         ],
  62         disks => [
  63             'lsblk --ascii',
  64             'ls -l /dev/disk/by-*/',
  65             'iscsiadm -m node',
  66             'iscsiadm -m session',
  67         ],
  68         volumes => [
  69             'pvs',
  70             'lvs',
  71             'vgs',
  72         ],
  73     };
  74
  75     push @{$report_def->{volumes}}, 'zpool status', 'zpool list -v', 'zfs list' if cmd_exists('zfs');
  76
  77     if (-e '/etc/ceph/ceph.conf') {
  78         # TODO: add (now working) rdb ls over all pools? really needed?
  79         push @{$report_def->{volumes}}, 'ceph status', 'ceph osd status', 'ceph df', 'pveceph status', 'pveceph pool ls';
  80     }
  81
  82     push @{$report_def->{disks}}, 'multipath -ll', 'multipath -v3'
  83         if cmd_exists('multipath');
  84
  85     return $report_def;
  86 };
  87
  88 my $report;
  89 # output the content of all the files of a directory
  90 sub dir2text {
  91     my ($target_dir, $regexp) = @_;
  92
  93     PVE::Tools::dir_glob_foreach($target_dir, $regexp, sub {
  94         my ($file) = @_;
  95         $report .=  "\n# cat $target_dir$file\n";
  96         $report .= PVE::Tools::file_get_contents($target_dir.$file)."\n";
  97     });
  98 }
  99
 100 # command -v is the posix equivalent of 'which'
 101 sub cmd_exists { system("command -v '$_[0]' > /dev/null 2>&1") == 0 }
 102
 103 sub generate {
 104
 105     my $report_def = $init_report_cmds->();
 106
 107     my @report_order = ('general', 'storage', 'virtual guests', 'network',
 108     'firewall', 'cluster', 'bios', 'pci', 'disks', 'volumes');
 109
 110     $report = '';
 111     my $record_output = sub {
 112         $report .= shift . "\n";
 113     };
 114
 115     my $run_cmd_params = {
 116         outfunc => $record_output,
 117         errfunc => $record_output,
 118         timeout => $cmd_timeout,
 119         noerr => 1, # avoid checking programs exit code
 120     };
 121
 122     foreach my $section (@report_order) {
 123         my $s = $report_def->{$section};
 124
 125         my $title = "info about $section";
 126         my $commands = $s;
 127
 128         if (ref($s) eq 'HASH') {
 129             $commands = $s->{cmds};
 130             $title = $s->{title} if defined($s->{title});
 131         } elsif (ref($s) ne 'ARRAY') {
 132             die "unknown report definition in section '$section'!";
 133         }
 134
 135         $report .= "\n==== $title ====\n";
 136         foreach my $command (@$commands) {
 137             eval {
 138                 if (ref $command eq 'CODE') {
 139                     PVE::Tools::run_with_timeout($cmd_timeout, $command);
 140                 } else {
 141                     print STDERR "Process ".$command."...";
 142                     $report .= "\n# $command\n";
 143                     PVE::Tools::run_command($command, %$run_cmd_params);
 144                 }
 145                 print STDERR "OK";
 146             };
 147             print STDERR "\n";
 148             $report .= "\nERROR: $@\n" if $@;
 149         }
 150     }
 151
 152     return $report;
 153 }
 154
 155 1;