PVE/Service/pveproxy.pm

   1 package PVE::Service::pveproxy;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Daemon;
   8 use HTTP::Response;
   9 use Encode;
  10 use URI;
  11 use URI::QueryParam;
  12 use Data::Dumper;
  13 use PVE::API2Tools;
  14 use PVE::API2;
  15 use PVE::APIServer::Formatter;
  16 use PVE::APIServer::Formatter::Standard;
  17 use PVE::APIServer::Formatter::HTML;
  18 use PVE::APIServer::AnyEvent;
  19 use PVE::HTTPServer;
  20 use PVE::pvecfg;
  21
  22 use Template;
  23
  24 use PVE::Tools;
  25
  26 use base qw(PVE::Daemon);
  27
  28 my $cmdline = [$0, @ARGV];
  29
  30 my %daemon_options = (
  31     max_workers => 3,
  32     restart_on_error => 5,
  33     stop_wait_time => 15,
  34     leave_children_open_on_reload => 1,
  35     setuid => 'www-data',
  36     setgid => 'www-data',
  37     pidfile => '/var/run/pveproxy/pveproxy.pid',
  38 );
  39
  40 my $daemon = __PACKAGE__->new('pveproxy', $cmdline, %daemon_options);
  41
  42 sub add_dirs {
  43     my ($result_hash, $alias, $subdir) = @_;
  44
  45     PVE::APIServer::AnyEvent::add_dirs($result_hash, $alias, $subdir);
  46 }
  47
  48 my $basedirs = {
  49     novnc => '/usr/share/novnc-pve',
  50     extjs => '/usr/share/javascript/extjs',
  51     manager => '/usr/share/pve-manager',
  52     docs => '/usr/share/pve-docs',
  53     fontawesome => '/usr/share/fonts-font-awesome',
  54     xtermjs => '/usr/share/pve-xtermjs',
  55 };
  56
  57 sub init {
  58     my ($self) = @_;
  59
  60     # we use same ALLOW/DENY/POLICY as pveproxy
  61     my $proxyconf = PVE::API2Tools::read_proxy_config();
  62
  63     my $accept_lock_fn = "/var/lock/pveproxy.lck";
  64
  65     my $lockfh = IO::File->new(">>${accept_lock_fn}") ||
  66         die "unable to open lock file '${accept_lock_fn}' - $!\n";
  67
  68     my $family = PVE::Tools::get_host_address_family($self->{nodename});
  69     my $socket = $self->create_reusable_socket(8006, undef, $family);
  70
  71     my $dirs = {};
  72
  73     add_dirs($dirs, '/pve2/locale/', "$basedirs->{manager}/locale/");
  74     add_dirs($dirs, '/pve2/touch/', "$basedirs->{manager}/touch/");
  75     add_dirs($dirs, '/pve2/ext6/', "$basedirs->{extjs}/");
  76     add_dirs($dirs, '/pve2/images/' =>  "$basedirs->{manager}/images/");
  77     add_dirs($dirs, '/pve2/css/' =>  "$basedirs->{manager}/css/");
  78     add_dirs($dirs, '/pve2/js/' =>  "$basedirs->{manager}/js/");
  79     add_dirs($dirs, '/pve2/fa/fonts/' =>  "$basedirs->{fontawesome}/fonts/");
  80     add_dirs($dirs, '/pve2/fa/css/' =>  "$basedirs->{fontawesome}/css/");
  81     add_dirs($dirs, '/pve-docs/' => "$basedirs->{docs}/");
  82     add_dirs($dirs, '/novnc/' => "$basedirs->{novnc}/");
  83     add_dirs($dirs, '/xtermjs/' => "$basedirs->{xtermjs}/");
  84
  85     $self->{server_config} = {
  86         title => 'Proxmox VE API',
  87         keep_alive => 100,
  88         max_conn => 500,
  89         max_requests => 1000,
  90         lockfile => $accept_lock_fn,
  91         socket => $socket,
  92         lockfh => $lockfh,
  93         debug => $self->{debug},
  94         trusted_env => 0, # not trusted, anyone can connect
  95         logfile => '/var/log/pveproxy/access.log',
  96         allow_from => $proxyconf->{ALLOW_FROM},
  97         deny_from => $proxyconf->{DENY_FROM},
  98         policy => $proxyconf->{POLICY},
  99         ssl => {
 100             # Note: older versions are considered insecure, for example
 101             # search for "Poodle"-Attac
 102             method => 'any',
 103             sslv2 => 0,
 104             sslv3 => 0,
 105             cipher_list => $proxyconf->{CIPHERS} || 'HIGH:MEDIUM:!aNULL:!MD5',
 106             key_file => '/etc/pve/local/pve-ssl.key',
 107             cert_file => '/etc/pve/local/pve-ssl.pem',
 108         },
 109         # Note: there is no authentication for those pages and dirs!
 110         pages => {
 111             '/' => sub { get_index($self->{nodename}, @_) },
 112             # avoid authentication when accessing favicon
 113             '/favicon.ico' => {
 114                 file => "$basedirs->{manager}/images/favicon.ico",
 115             },
 116         },
 117         dirs => $dirs,
 118     };
 119
 120     if ($proxyconf->{DHPARAMS}) {
 121         $self->{server_config}->{ssl}->{dh_file} = $proxyconf->{DHPARAMS};
 122     } else {
 123         $self->{server_config}->{ssl}->{dh} = 'skip2048';
 124     }
 125
 126     if (-f '/etc/pve/local/pveproxy-ssl.pem' && -f '/etc/pve/local/pveproxy-ssl.key') {
 127         $self->{server_config}->{ssl}->{cert_file} = '/etc/pve/local/pveproxy-ssl.pem';
 128         $self->{server_config}->{ssl}->{key_file} = '/etc/pve/local/pveproxy-ssl.key';
 129         syslog('info', 'Using \'/etc/pve/local/pveproxy-ssl.pem\' as certificate for the web interface.');
 130     }
 131 }
 132
 133 sub run {
 134     my ($self) = @_;
 135
 136     my $server = PVE::HTTPServer->new(%{$self->{server_config}});
 137     $server->run();
 138 }
 139
 140 $daemon->register_start_command();
 141 $daemon->register_restart_command(1);
 142 $daemon->register_stop_command();
 143 $daemon->register_status_command();
 144
 145 our $cmddef = {
 146     start => [ __PACKAGE__, 'start', []],
 147     restart => [ __PACKAGE__, 'restart', []],
 148     stop => [ __PACKAGE__, 'stop', []],
 149     status => [ __PACKAGE__, 'status', [], undef, sub { print shift . "\n";} ],
 150 };
 151
 152 sub is_phone {
 153     my ($ua) = @_;
 154
 155     return 0 if !$ua;
 156
 157     return 1 if $ua =~ m/(iPhone|iPod|Windows Phone)/;
 158
 159     if ($ua =~ m/Mobile(\/|\s)/) {
 160         return 1 if $ua =~ m/(BlackBerry|BB)/;
 161         return 1 if ($ua =~ m/(Android)/) && ($ua !~ m/(Silk)/);
 162     }
 163
 164     return 0;
 165 }
 166
 167 # NOTE: Requests to those pages are not authenticated
 168 # so we must be very careful here
 169
 170 sub get_index {
 171     my ($nodename, $server, $r, $args) = @_;
 172
 173     my $lang = 'en';
 174     my $username;
 175     my $token = 'null';
 176
 177     if (my $cookie = $r->header('Cookie')) {
 178         if (my $newlang = ($cookie =~ /(?:^|\s)PVELangCookie=([^;]*)/)[0]) {
 179             if ($newlang =~ m/^[a-z]{2,3}(_[A-Z]{2,3})?$/) {
 180                 $lang = $newlang;
 181             }
 182         }
 183         my $ticket = PVE::APIServer::Formatter::extract_auth_cookie($cookie, $server->{cookie_name});
 184         if (($username = PVE::AccessControl::verify_ticket($ticket, 1))) {
 185             $token = PVE::AccessControl::assemble_csrf_prevention_token($username);
 186         }
 187     }
 188
 189     $username = '' if !$username;
 190
 191     my $mobile = is_phone($r->header('User-Agent')) ? 1 : 0;
 192
 193     if (defined($args->{mobile})) {
 194         $mobile = $args->{mobile} ? 1 : 0;
 195     }
 196
 197     my $novnc = defined($args->{console}) && $args->{novnc};
 198     my $xtermjs = defined($args->{console}) && $args->{xtermjs};
 199
 200     my $page = '';
 201     my $template = Template->new({ABSOLUTE => 1});
 202
 203     my $langfile = 0;
 204
 205     if (-f  "$basedirs->{manager}/locale/pve-lang-$lang.js") {
 206         $langfile = 1;
 207     }
 208
 209     my $ver = PVE::pvecfg::version();
 210     my $release = PVE::pvecfg::release();
 211
 212     my $vars = {
 213         lang => $lang,
 214         langfile => $langfile,
 215         username => $username,
 216         token => $token,
 217         console => $args->{console},
 218         nodename => $nodename,
 219         debug => $server->{debug},
 220         version => "$ver-$release",
 221     };
 222
 223     # by default, load the normal index
 224     my $dir = $basedirs->{manager};
 225
 226     if ($novnc) {
 227         $dir = $basedirs->{novnc};
 228     } elsif ($xtermjs) {
 229         $dir = $basedirs->{xtermjs};
 230     } elsif ($mobile) {
 231         $dir = "$basedirs->{manager}/touch";
 232     }
 233
 234     $template->process("$dir/index.html.tpl", $vars, \$page)
 235         || die $template->error(), "\n";
 236     my $headers = HTTP::Headers->new(Content_Type => "text/html; charset=utf-8");
 237     my $resp = HTTP::Response->new(200, "OK", $headers, $page);
 238
 239     return $resp;
 240 }
 241
 242 1;