PVE/Service/pveproxy.pm

   1 package PVE::Service::pveproxy;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Daemon;
   8 use HTTP::Response;
   9 use Encode;
  10 use URI;
  11 use URI::QueryParam;
  12 use File::Find;
  13 use Data::Dumper;
  14 use PVE::API2Tools;
  15 use PVE::API2;
  16 use PVE::API2::Formatter::Standard;
  17 use PVE::API2::Formatter::HTML;
  18 use PVE::HTTPServer;
  19
  20 use PVE::ExtJSIndex;
  21 use PVE::ExtJSIndex6;
  22 use PVE::NoVncIndex;
  23 use PVE::TouchIndex;
  24
  25 use PVE::Tools;
  26
  27 use base qw(PVE::Daemon);
  28
  29 my $cmdline = [$0, @ARGV];
  30
  31 my %daemon_options = (
  32     max_workers => 3,
  33     restart_on_error => 5,
  34     stop_wait_time => 15,
  35     leave_children_open_on_reload => 1,
  36     setuid => 'www-data',
  37     setgid => 'www-data',
  38     pidfile => '/var/run/pveproxy/pveproxy.pid',
  39 );
  40
  41 my $daemon = __PACKAGE__->new('pveproxy', $cmdline, %daemon_options);
  42
  43 my $ext6_dir_exists;
  44
  45 sub add_dirs {
  46     my ($result_hash, $alias, $subdir) = @_;
  47
  48     $result_hash->{$alias} = $subdir;
  49
  50     my $wanted = sub {
  51         my $dir = $File::Find::dir;
  52         if ($dir =~m!^$subdir(.*)$!) {
  53             my $name = "$alias$1/";
  54             $result_hash->{$name} = "$dir/";
  55         }
  56     };
  57
  58     find({wanted => $wanted, follow => 0, no_chdir => 1}, $subdir);
  59 }
  60
  61 sub init {
  62     my ($self) = @_;
  63
  64     # we use same ALLOW/DENY/POLICY as pveproxy
  65     my $proxyconf = PVE::API2Tools::read_proxy_config();
  66
  67     my $accept_lock_fn = "/var/lock/pveproxy.lck";
  68
  69     my $lockfh = IO::File->new(">>${accept_lock_fn}") ||
  70         die "unable to open lock file '${accept_lock_fn}' - $!\n";
  71
  72     my $family = PVE::Tools::get_host_address_family($self->{nodename});
  73     my $socket = $self->create_reusable_socket(8006, undef, $family);
  74
  75     $ext6_dir_exists = (-d '/usr/share/pve-manager/ext6');
  76
  77     my $dirs = {};
  78
  79     add_dirs($dirs, '/pve2/locale/', '/usr/share/pve-manager/locale/');
  80     add_dirs($dirs, '/pve2/touch/', '/usr/share/pve-manager/touch/');
  81     add_dirs($dirs, '/pve2/ext4/', '/usr/share/pve-manager/ext4/');
  82
  83     if ($ext6_dir_exists) { # only add ext6 dirs if they exist
  84         add_dirs($dirs, '/pve2/ext6/', '/usr/share/pve-manager/ext6/');
  85         add_dirs($dirs, '/pve2/manager6/', '/usr/share/pve-manager/manager6/');
  86     }
  87
  88     add_dirs($dirs, '/pve2/images/' => '/usr/share/pve-manager/images/');
  89     add_dirs($dirs, '/pve2/css/' => '/usr/share/pve-manager/css/');
  90     add_dirs($dirs, '/pve2/js/' => '/usr/share/pve-manager/js/');
  91     add_dirs($dirs, '/vncterm/' => '/usr/share/vncterm/');
  92     add_dirs($dirs, '/novnc/' => '/usr/share/novnc-pve/');
  93
  94     $self->{server_config} = {
  95         base_handler_class => 'PVE::API2',
  96         keep_alive => 100,
  97         max_conn => 500,
  98         max_requests => 1000,
  99         lockfile => $accept_lock_fn,
 100         socket => $socket,
 101         lockfh => $lockfh,
 102         debug => $self->{debug},
 103         trusted_env => 0, # not trusted, anyone can connect
 104         logfile => '/var/log/pveproxy/access.log',
 105         allow_from => $proxyconf->{ALLOW_FROM},
 106         deny_from => $proxyconf->{DENY_FROM},
 107         policy => $proxyconf->{POLICY},
 108         ssl => {
 109             # Note: older versions are considered insecure, for example
 110             # search for "Poodle"-Attac
 111             method => 'any',
 112             sslv2 => 0,
 113             sslv3 => 0,
 114             cipher_list => $proxyconf->{CIPHERS} || 'HIGH:MEDIUM:!aNULL:!MD5',
 115             key_file => '/etc/pve/local/pve-ssl.key',
 116             cert_file => '/etc/pve/local/pve-ssl.pem',
 117         },
 118         # Note: there is no authentication for those pages and dirs!
 119         pages => {
 120             '/' => sub { get_index($self->{nodename}, @_) },
 121             # avoid authentication when accessing favicon
 122             '/favicon.ico' => {
 123                 file => '/usr/share/pve-manager/images/favicon.ico',
 124             },
 125         },
 126         dirs => $dirs,
 127     };
 128
 129     if ($proxyconf->{DHPARAMS}) {
 130         $self->{server_config}->{ssl}->{dh_file} = $proxyconf->{DHPARAMS};
 131     } else {
 132         $self->{server_config}->{ssl}->{dh} = 'skip2048';
 133     }
 134
 135     if (-f '/etc/pve/local/pveproxy-ssl.pem' && -f '/etc/pve/local/pveproxy-ssl.key') {
 136         $self->{server_config}->{ssl}->{cert_file} = '/etc/pve/local/pveproxy-ssl.pem';
 137         $self->{server_config}->{ssl}->{key_file} = '/etc/pve/local/pveproxy-ssl.key';
 138         syslog('info', 'Using \'/etc/pve/local/pveproxy-ssl.pem\' as certificate for the web interface.');
 139     }
 140 }
 141
 142 sub run {
 143     my ($self) = @_;
 144
 145     my $server = PVE::HTTPServer->new(%{$self->{server_config}});
 146     $server->run();
 147 }
 148
 149 $daemon->register_start_command();
 150 $daemon->register_restart_command(1);
 151 $daemon->register_stop_command();
 152 $daemon->register_status_command();
 153
 154 our $cmddef = {
 155     start => [ __PACKAGE__, 'start', []],
 156     restart => [ __PACKAGE__, 'restart', []],
 157     stop => [ __PACKAGE__, 'stop', []],
 158     status => [ __PACKAGE__, 'status', [], undef, sub { print shift . "\n";} ],
 159 };
 160
 161 sub is_phone {
 162     my ($ua) = @_;
 163
 164     return 0 if !$ua;
 165
 166     return 1 if $ua =~ m/(iPhone|iPod|Windows Phone)/;
 167
 168     if ($ua =~ m/Mobile(\/|\s)/) {
 169         return 1 if $ua =~ m/(BlackBerry|BB)/;
 170         return 1 if ($ua =~ m/(Android)/) && ($ua !~ m/(Silk)/);
 171     }
 172
 173     return 0;
 174 }
 175
 176 # NOTE: Requests to those pages are not authenticated
 177 # so we must be very careful here
 178
 179 sub get_index {
 180     my ($nodename, $server, $r, $args) = @_;
 181
 182     my $lang = 'en';
 183     my $username;
 184     my $token = 'null';
 185
 186     if (my $cookie = $r->header('Cookie')) {
 187         if (my $newlang = ($cookie =~ /(?:^|\s)PVELangCookie=([^;]*)/)[0]) {
 188             if ($newlang =~ m/^[a-z]{2,3}(_[A-Z]{2,3})?$/) {
 189                 $lang = $newlang;
 190             }
 191         }
 192         my $ticket = PVE::REST::extract_auth_cookie($cookie);
 193         if (($username = PVE::AccessControl::verify_ticket($ticket, 1))) {
 194             $token = PVE::AccessControl::assemble_csrf_prevention_token($username);
 195         }
 196     }
 197
 198     $username = '' if !$username;
 199
 200     my $mobile = is_phone($r->header('User-Agent')) ? 1 : 0;
 201
 202     if (defined($args->{mobile})) {
 203         $mobile = $args->{mobile} ? 1 : 0;
 204     }
 205
 206     my $ext6;
 207     if (defined($args->{ext6})) {
 208         $ext6 = $args->{ext6} ? 1 : 0;
 209     }
 210
 211     my $page;
 212
 213     if (defined($args->{console}) && $args->{novnc}) {
 214         $page = PVE::NoVncIndex::get_index($lang, $username, $token, $args->{console}, $nodename);
 215     } elsif ($mobile) {
 216         $page = PVE::TouchIndex::get_index($lang, $username, $token, $args->{console}, $nodename);
 217     } elsif ($ext6 && $ext6_dir_exists) {
 218         $page = PVE::ExtJSIndex6::get_index($lang, $username, $token, $args->{console}, $nodename);
 219     } else {
 220         $page = PVE::ExtJSIndex::get_index($lang, $username, $token, $args->{console}, $nodename);
 221     }
 222     my $headers = HTTP::Headers->new(Content_Type => "text/html; charset=utf-8");
 223     my $resp = HTTP::Response->new(200, "OK", $headers, $page);
 224
 225     return $resp;
 226 }
 227
 228 1;
 229
 230 __END__
 231
 232 =head1 NAME
 233
 234 pveproxy - the PVE API proxy server
 235
 236 =head1 SYNOPSIS
 237
 238 =include synopsis
 239
 240 =head1 DESCRIPTION
 241
 242 This is the REST API proxy server, listening on port 8006. This is usually
 243 started as service using:
 244
 245  # service pveproxy start
 246
 247 =head1 Host based access control
 248
 249 It is possible to configure apache2 like access control lists. Values are read
 250 from file /etc/default/pveproxy. For example:
 251
 252  ALLOW_FROM="10.0.0.1-10.0.0.5,192.168.0.0/22"
 253  DENY_FROM="all"
 254  POLICY="allow"
 255
 256 IP addresses can be specified using any syntax understood by Net::IP. The
 257 name 'all' is an alias for '0/0'.
 258
 259 The default policy is 'allow'.
 260
 261  Match                      | POLICY=deny | POLICY=allow
 262  ---------------------------|-------------|------------
 263  Match Allow only           | allow       | allow
 264  Match Deny only            | deny        | deny
 265  No match                   | deny        | allow
 266  Match Both Allow & Deny    | deny        | allow
 267
 268 =head1 SSL Cipher Suite
 269
 270 You can define the cipher list in /etc/default/pveproxy, for example
 271
 272  CIPHERS="HIGH:MEDIUM:!aNULL:!MD5"
 273
 274 Above is the default. See the ciphers(1) man page from the openssl
 275 package for a list of all available options.
 276
 277 =head1 Diffie-Hellman Parameters
 278
 279 You can define the used Diffie-Hellman parameters in /etc/default/pveproxy
 280 by setting DHPARAMS to the path of a file containing DH parameters in PEM
 281 format, for example
 282
 283  DHPARAMS="/path/to/dhparams.pem"
 284
 285 If this option is not set, the built-in 'skip2048' parameters will be used.
 286
 287 Note: DH parameters are only used if a cipher suite utilizing the DH key
 288 exchange algorithm is negotiated.
 289
 290 =head1 FILES
 291
 292  /etc/default/pveproxy
 293
 294 =include pve_copyright