PVE/Service/pveproxy.pm

   1 package PVE::Service::pveproxy;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Daemon;
   8 use HTTP::Response;
   9 use Encode;
  10 use URI;
  11 use URI::QueryParam;
  12 use Data::Dumper;
  13 use PVE::API2Tools;
  14 use PVE::API2;
  15 use PVE::APIServer::Formatter;
  16 use PVE::APIServer::Formatter::Standard;
  17 use PVE::APIServer::Formatter::HTML;
  18 use PVE::APIServer::AnyEvent;
  19 use PVE::HTTPServer;
  20
  21 use PVE::ExtJSIndex;
  22 use PVE::NoVncIndex;
  23 use PVE::TouchIndex;
  24
  25 use PVE::Tools;
  26
  27 use base qw(PVE::Daemon);
  28
  29 my $cmdline = [$0, @ARGV];
  30
  31 my %daemon_options = (
  32     max_workers => 3,
  33     restart_on_error => 5,
  34     stop_wait_time => 15,
  35     leave_children_open_on_reload => 1,
  36     setuid => 'www-data',
  37     setgid => 'www-data',
  38     pidfile => '/var/run/pveproxy/pveproxy.pid',
  39 );
  40
  41 my $daemon = __PACKAGE__->new('pveproxy', $cmdline, %daemon_options);
  42
  43 sub add_dirs {
  44     my ($result_hash, $alias, $subdir) = @_;
  45
  46     PVE::APIServer::AnyEvent::add_dirs($result_hash, $alias, $subdir);
  47 }
  48
  49 sub init {
  50     my ($self) = @_;
  51
  52     # we use same ALLOW/DENY/POLICY as pveproxy
  53     my $proxyconf = PVE::API2Tools::read_proxy_config();
  54
  55     my $accept_lock_fn = "/var/lock/pveproxy.lck";
  56
  57     my $lockfh = IO::File->new(">>${accept_lock_fn}") ||
  58         die "unable to open lock file '${accept_lock_fn}' - $!\n";
  59
  60     my $family = PVE::Tools::get_host_address_family($self->{nodename});
  61     my $socket = $self->create_reusable_socket(8006, undef, $family);
  62
  63     my $dirs = {};
  64
  65     add_dirs($dirs, '/pve2/locale/', '/usr/share/pve-manager/locale/');
  66     add_dirs($dirs, '/pve2/touch/', '/usr/share/pve-manager/touch/');
  67     add_dirs($dirs, '/pve2/ext6/', '/usr/share/javascript/extjs/');
  68     add_dirs($dirs, '/pve2/images/' => '/usr/share/pve-manager/images/');
  69     add_dirs($dirs, '/pve2/css/' => '/usr/share/pve-manager/css/');
  70     add_dirs($dirs, '/pve2/js/' => '/usr/share/pve-manager/js/');
  71     add_dirs($dirs, '/pve-docs/' => '/usr/share/pve-docs/');
  72     add_dirs($dirs, '/vncterm/' => '/usr/share/vncterm/');
  73     add_dirs($dirs, '/novnc/' => '/usr/share/novnc-pve/');
  74
  75     $self->{server_config} = {
  76         title => 'Proxmox VE API',
  77         keep_alive => 100,
  78         max_conn => 500,
  79         max_requests => 1000,
  80         lockfile => $accept_lock_fn,
  81         socket => $socket,
  82         lockfh => $lockfh,
  83         debug => $self->{debug},
  84         trusted_env => 0, # not trusted, anyone can connect
  85         logfile => '/var/log/pveproxy/access.log',
  86         allow_from => $proxyconf->{ALLOW_FROM},
  87         deny_from => $proxyconf->{DENY_FROM},
  88         policy => $proxyconf->{POLICY},
  89         ssl => {
  90             # Note: older versions are considered insecure, for example
  91             # search for "Poodle"-Attac
  92             method => 'any',
  93             sslv2 => 0,
  94             sslv3 => 0,
  95             cipher_list => $proxyconf->{CIPHERS} || 'HIGH:MEDIUM:!aNULL:!MD5',
  96             key_file => '/etc/pve/local/pve-ssl.key',
  97             cert_file => '/etc/pve/local/pve-ssl.pem',
  98         },
  99         # Note: there is no authentication for those pages and dirs!
 100         pages => {
 101             '/' => sub { get_index($self->{nodename}, @_) },
 102             # avoid authentication when accessing favicon
 103             '/favicon.ico' => {
 104                 file => '/usr/share/pve-manager/images/favicon.ico',
 105             },
 106         },
 107         dirs => $dirs,
 108     };
 109
 110     if ($proxyconf->{DHPARAMS}) {
 111         $self->{server_config}->{ssl}->{dh_file} = $proxyconf->{DHPARAMS};
 112     } else {
 113         $self->{server_config}->{ssl}->{dh} = 'skip2048';
 114     }
 115
 116     if (-f '/etc/pve/local/pveproxy-ssl.pem' && -f '/etc/pve/local/pveproxy-ssl.key') {
 117         $self->{server_config}->{ssl}->{cert_file} = '/etc/pve/local/pveproxy-ssl.pem';
 118         $self->{server_config}->{ssl}->{key_file} = '/etc/pve/local/pveproxy-ssl.key';
 119         syslog('info', 'Using \'/etc/pve/local/pveproxy-ssl.pem\' as certificate for the web interface.');
 120     }
 121 }
 122
 123 sub run {
 124     my ($self) = @_;
 125
 126     my $server = PVE::HTTPServer->new(%{$self->{server_config}});
 127     $server->run();
 128 }
 129
 130 $daemon->register_start_command();
 131 $daemon->register_restart_command(1);
 132 $daemon->register_stop_command();
 133 $daemon->register_status_command();
 134
 135 our $cmddef = {
 136     start => [ __PACKAGE__, 'start', []],
 137     restart => [ __PACKAGE__, 'restart', []],
 138     stop => [ __PACKAGE__, 'stop', []],
 139     status => [ __PACKAGE__, 'status', [], undef, sub { print shift . "\n";} ],
 140 };
 141
 142 sub is_phone {
 143     my ($ua) = @_;
 144
 145     return 0 if !$ua;
 146
 147     return 1 if $ua =~ m/(iPhone|iPod|Windows Phone)/;
 148
 149     if ($ua =~ m/Mobile(\/|\s)/) {
 150         return 1 if $ua =~ m/(BlackBerry|BB)/;
 151         return 1 if ($ua =~ m/(Android)/) && ($ua !~ m/(Silk)/);
 152     }
 153
 154     return 0;
 155 }
 156
 157 # NOTE: Requests to those pages are not authenticated
 158 # so we must be very careful here
 159
 160 sub get_index {
 161     my ($nodename, $server, $r, $args) = @_;
 162
 163     my $lang = 'en';
 164     my $username;
 165     my $token = 'null';
 166
 167     if (my $cookie = $r->header('Cookie')) {
 168         if (my $newlang = ($cookie =~ /(?:^|\s)PVELangCookie=([^;]*)/)[0]) {
 169             if ($newlang =~ m/^[a-z]{2,3}(_[A-Z]{2,3})?$/) {
 170                 $lang = $newlang;
 171             }
 172         }
 173         my $ticket = PVE::APIServer::Formatter::extract_auth_cookie($cookie, $server->{cookie_name});
 174         if (($username = PVE::AccessControl::verify_ticket($ticket, 1))) {
 175             $token = PVE::AccessControl::assemble_csrf_prevention_token($username);
 176         }
 177     }
 178
 179     $username = '' if !$username;
 180
 181     my $mobile = is_phone($r->header('User-Agent')) ? 1 : 0;
 182
 183     if (defined($args->{mobile})) {
 184         $mobile = $args->{mobile} ? 1 : 0;
 185     }
 186
 187     my $page;
 188
 189     if (defined($args->{console}) && $args->{novnc}) {
 190         $page = PVE::NoVncIndex::get_index($lang, $username, $token, $args->{console}, $nodename);
 191     } elsif ($mobile) {
 192         $page = PVE::TouchIndex::get_index($lang, $username, $token, $args->{console}, $nodename);
 193     } else {
 194         $page = PVE::ExtJSIndex::get_index($lang, $username, $token, $args->{console}, $nodename,
 195             $server->{debug});
 196     }
 197     my $headers = HTTP::Headers->new(Content_Type => "text/html; charset=utf-8");
 198     my $resp = HTTP::Response->new(200, "OK", $headers, $page);
 199
 200     return $resp;
 201 }
 202
 203 1;