PVE/Service/pveproxy.pm

   1 package PVE::Service::pveproxy;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Daemon;
   8 use HTTP::Response;
   9 use Encode;
  10 use URI;
  11 use URI::QueryParam;
  12 use Data::Dumper;
  13 use PVE::Cluster;
  14 use PVE::APIServer::Utils;
  15 use PVE::API2;
  16 use PVE::APIServer::Formatter;
  17 use PVE::APIServer::Formatter::Standard;
  18 use PVE::APIServer::Formatter::HTML;
  19 use PVE::APIServer::AnyEvent;
  20 use PVE::HTTPServer;
  21 use PVE::pvecfg;
  22
  23 use Template;
  24
  25 use PVE::Tools;
  26
  27 use base qw(PVE::Daemon);
  28
  29 my $cmdline = [$0, @ARGV];
  30
  31 my %daemon_options = (
  32     max_workers => 3,
  33     restart_on_error => 5,
  34     stop_wait_time => 15,
  35     leave_children_open_on_reload => 1,
  36     setuid => 'www-data',
  37     setgid => 'www-data',
  38     pidfile => '/var/run/pveproxy/pveproxy.pid',
  39 );
  40
  41 my $daemon = __PACKAGE__->new('pveproxy', $cmdline, %daemon_options);
  42
  43 sub add_dirs {
  44     my ($result_hash, $alias, $subdir) = @_;
  45
  46     PVE::APIServer::AnyEvent::add_dirs($result_hash, $alias, $subdir);
  47 }
  48
  49 my $basedirs = {
  50     novnc => '/usr/share/novnc-pve',
  51     extjs => '/usr/share/javascript/extjs',
  52     manager => '/usr/share/pve-manager',
  53     i18n => '/usr/share/pve-i18n',
  54     docs => '/usr/share/pve-docs',
  55     fontawesome => '/usr/share/fonts-font-awesome',
  56     xtermjs => '/usr/share/pve-xtermjs',
  57     widgettoolkit => '/usr/share/javascript/proxmox-widget-toolkit',
  58 };
  59
  60 sub init {
  61     my ($self) = @_;
  62
  63     # we use same ALLOW/DENY/POLICY as pveproxy
  64     my $proxyconf = PVE::APIServer::Utils::read_proxy_config($self->{name});
  65
  66     my $accept_lock_fn = "/var/lock/pveproxy.lck";
  67
  68     my $lockfh = IO::File->new(">>${accept_lock_fn}") ||
  69         die "unable to open lock file '${accept_lock_fn}' - $!\n";
  70
  71     my $family = PVE::Tools::get_host_address_family($self->{nodename});
  72     my $socket = $self->create_reusable_socket(8006, undef, $family);
  73
  74     my $dirs = {};
  75
  76     add_dirs($dirs, '/pve2/locale/', "$basedirs->{i18n}/");
  77     add_dirs($dirs, '/pve2/touch/', "$basedirs->{manager}/touch/");
  78     add_dirs($dirs, '/pve2/ext6/', "$basedirs->{extjs}/");
  79     add_dirs($dirs, '/pve2/images/' =>  "$basedirs->{manager}/images/");
  80     add_dirs($dirs, '/pve2/css/' =>  "$basedirs->{manager}/css/");
  81     add_dirs($dirs, '/pve2/js/' =>  "$basedirs->{manager}/js/");
  82     add_dirs($dirs, '/pve2/fa/fonts/' =>  "$basedirs->{fontawesome}/fonts/");
  83     add_dirs($dirs, '/pve2/fa/css/' =>  "$basedirs->{fontawesome}/css/");
  84     add_dirs($dirs, '/pve-docs/' => "$basedirs->{docs}/");
  85     add_dirs($dirs, '/pve-docs/api-viewer/extjs/' => "$basedirs->{extjs}/");
  86     add_dirs($dirs, '/novnc/' => "$basedirs->{novnc}/");
  87     add_dirs($dirs, '/xtermjs/' => "$basedirs->{xtermjs}/");
  88     add_dirs($dirs, '/pwt/images/' => "$basedirs->{widgettoolkit}/images/");
  89     add_dirs($dirs, '/pwt/css/' => "$basedirs->{widgettoolkit}/css/");
  90
  91     $self->{server_config} = {
  92         title => 'Proxmox VE API',
  93         keep_alive => 100,
  94         max_conn => 500,
  95         max_requests => 1000,
  96         lockfile => $accept_lock_fn,
  97         socket => $socket,
  98         lockfh => $lockfh,
  99         debug => $self->{debug},
 100         trusted_env => 0, # not trusted, anyone can connect
 101         logfile => '/var/log/pveproxy/access.log',
 102         allow_from => $proxyconf->{ALLOW_FROM},
 103         deny_from => $proxyconf->{DENY_FROM},
 104         policy => $proxyconf->{POLICY},
 105         ssl => {
 106             cipher_list => $proxyconf->{CIPHERS},
 107             key_file => '/etc/pve/local/pve-ssl.key',
 108             cert_file => '/etc/pve/local/pve-ssl.pem',
 109             honor_cipher_order => $proxyconf->{HONOR_CIPHER_ORDER},
 110         },
 111         compression => $proxyconf->{COMPRESSION},
 112         # Note: there is no authentication for those pages and dirs!
 113         pages => {
 114             '/' => sub { get_index($self->{nodename}, @_) },
 115             # avoid authentication when accessing favicon
 116             '/favicon.ico' => {
 117                 file => "$basedirs->{manager}/images/favicon.ico",
 118             },
 119             '/proxmoxlib.js' => {
 120                 file => "$basedirs->{widgettoolkit}/proxmoxlib.js",
 121             },
 122         },
 123         dirs => $dirs,
 124     };
 125
 126     if (defined($proxyconf->{DHPARAMS})) {
 127         $self->{server_config}->{ssl}->{dh_file} = $proxyconf->{DHPARAMS};
 128     }
 129     if (-f '/etc/pve/local/pveproxy-ssl.pem' && -f '/etc/pve/local/pveproxy-ssl.key') {
 130         $self->{server_config}->{ssl}->{cert_file} = '/etc/pve/local/pveproxy-ssl.pem';
 131         $self->{server_config}->{ssl}->{key_file} = '/etc/pve/local/pveproxy-ssl.key';
 132         syslog('info', 'Using \'/etc/pve/local/pveproxy-ssl.pem\' as certificate for the web interface.');
 133     }
 134 }
 135
 136 sub run {
 137     my ($self) = @_;
 138
 139     my $server = PVE::HTTPServer->new(%{$self->{server_config}});
 140     $server->run();
 141 }
 142
 143 $daemon->register_start_command();
 144 $daemon->register_restart_command(1);
 145 $daemon->register_stop_command();
 146 $daemon->register_status_command();
 147
 148 our $cmddef = {
 149     start => [ __PACKAGE__, 'start', []],
 150     restart => [ __PACKAGE__, 'restart', []],
 151     stop => [ __PACKAGE__, 'stop', []],
 152     status => [ __PACKAGE__, 'status', [], undef, sub { print shift . "\n";} ],
 153 };
 154
 155 sub is_phone {
 156     my ($ua) = @_;
 157
 158     return 0 if !$ua;
 159
 160     return 1 if $ua =~ m/(iPhone|iPod|Windows Phone)/;
 161
 162     if ($ua =~ m/Mobile(\/|\s)/) {
 163         return 1 if $ua =~ m/(BlackBerry|BB)/;
 164         return 1 if ($ua =~ m/(Android)/) && ($ua !~ m/(Silk)/);
 165     }
 166
 167     return 0;
 168 }
 169
 170 # NOTE: Requests to those pages are not authenticated
 171 # so we must be very careful here
 172
 173 sub get_index {
 174     my ($nodename, $server, $r, $args) = @_;
 175
 176     my $lang;
 177     my $username;
 178     my $token = 'null';
 179
 180     if (my $cookie = $r->header('Cookie')) {
 181         if (my $newlang = ($cookie =~ /(?:^|\s)PVELangCookie=([^;]*)/)[0]) {
 182             if ($newlang =~ m/^[a-z]{2,3}(_[A-Z]{2,3})?$/) {
 183                 $lang = $newlang;
 184             }
 185         }
 186         my $ticket = PVE::APIServer::Formatter::extract_auth_cookie($cookie, $server->{cookie_name});
 187         if (($username = PVE::AccessControl::verify_ticket($ticket, 1))) {
 188             $token = PVE::AccessControl::assemble_csrf_prevention_token($username);
 189         }
 190     }
 191
 192     if (!$lang) {
 193         my $dc_conf = PVE::Cluster::cfs_read_file('datacenter.cfg');
 194         $lang = $dc_conf->{language} // 'en';
 195     }
 196
 197     $username = '' if !$username;
 198
 199     my $mobile = is_phone($r->header('User-Agent')) ? 1 : 0;
 200
 201     if (defined($args->{mobile})) {
 202         $mobile = $args->{mobile} ? 1 : 0;
 203     }
 204
 205     my $novnc = defined($args->{console}) && $args->{novnc};
 206     my $xtermjs = defined($args->{console}) && $args->{xtermjs};
 207
 208     my $page = '';
 209     my $template = Template->new({ABSOLUTE => 1});
 210
 211     my $langfile = 0;
 212
 213     if (-f  "$basedirs->{i18n}/pve-lang-$lang.js") {
 214         $langfile = 1;
 215     }
 216
 217     my $version = PVE::pvecfg::version();
 218
 219     my $wtversionraw = PVE::Tools::file_read_firstline("$basedirs->{widgettoolkit}/proxmoxlib.js");
 220     my $wtversion;
 221     if ($wtversionraw =~ m|^// (.*)$|) {
 222         $wtversion = $1;
 223     };
 224
 225     my $debug = $server->{debug};
 226     if (exists $args->{debug}) {
 227         $debug = !defined($args->{debug}) || $args->{debug};
 228     }
 229
 230     my $vars = {
 231         lang => $lang,
 232         langfile => $langfile,
 233         username => $username,
 234         token => $token,
 235         console => $args->{console},
 236         nodename => $nodename,
 237         debug => $debug,
 238         version => "$version",
 239         wtversion => $wtversion,
 240     };
 241
 242     # by default, load the normal index
 243     my $dir = $basedirs->{manager};
 244
 245     if ($novnc) {
 246         $dir = $basedirs->{novnc};
 247     } elsif ($xtermjs) {
 248         $dir = $basedirs->{xtermjs};
 249     } elsif ($mobile) {
 250         $dir = "$basedirs->{manager}/touch";
 251     }
 252
 253     $template->process("$dir/index.html.tpl", $vars, \$page)
 254         || die $template->error(), "\n";
 255     my $headers = HTTP::Headers->new(Content_Type => "text/html; charset=utf-8");
 256     my $resp = HTTP::Response->new(200, "OK", $headers, $page);
 257
 258     return $resp;
 259 }
 260
 261 1;