PVE/Service/pveproxy.pm

   1 package PVE::Service::pveproxy;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Daemon;
   8 use HTTP::Response;
   9 use Encode;
  10 use URI;
  11 use URI::QueryParam;
  12 use Data::Dumper;
  13 use PVE::Cluster;
  14 use PVE::API2Tools;
  15 use PVE::API2;
  16 use PVE::APIServer::Formatter;
  17 use PVE::APIServer::Formatter::Standard;
  18 use PVE::APIServer::Formatter::HTML;
  19 use PVE::APIServer::AnyEvent;
  20 use PVE::HTTPServer;
  21 use PVE::pvecfg;
  22
  23 use Template;
  24
  25 use PVE::Tools;
  26
  27 use base qw(PVE::Daemon);
  28
  29 my $cmdline = [$0, @ARGV];
  30
  31 my %daemon_options = (
  32     max_workers => 3,
  33     restart_on_error => 5,
  34     stop_wait_time => 15,
  35     leave_children_open_on_reload => 1,
  36     setuid => 'www-data',
  37     setgid => 'www-data',
  38     pidfile => '/var/run/pveproxy/pveproxy.pid',
  39 );
  40
  41 my $daemon = __PACKAGE__->new('pveproxy', $cmdline, %daemon_options);
  42
  43 sub add_dirs {
  44     my ($result_hash, $alias, $subdir) = @_;
  45
  46     PVE::APIServer::AnyEvent::add_dirs($result_hash, $alias, $subdir);
  47 }
  48
  49 my $basedirs = {
  50     novnc => '/usr/share/novnc-pve',
  51     extjs => '/usr/share/javascript/extjs',
  52     manager => '/usr/share/pve-manager',
  53     i18n => '/usr/share/pve-i18n',
  54     docs => '/usr/share/pve-docs',
  55     fontawesome => '/usr/share/fonts-font-awesome',
  56     xtermjs => '/usr/share/pve-xtermjs',
  57     widgettoolkit => '/usr/share/javascript/proxmox-widget-toolkit',
  58 };
  59
  60 sub init {
  61     my ($self) = @_;
  62
  63     # we use same ALLOW/DENY/POLICY as pveproxy
  64     my $proxyconf = PVE::API2Tools::read_proxy_config();
  65
  66     my $accept_lock_fn = "/var/lock/pveproxy.lck";
  67
  68     my $lockfh = IO::File->new(">>${accept_lock_fn}") ||
  69         die "unable to open lock file '${accept_lock_fn}' - $!\n";
  70
  71     my $family = PVE::Tools::get_host_address_family($self->{nodename});
  72     my $socket = $self->create_reusable_socket(8006, undef, $family);
  73
  74     my $dirs = {};
  75
  76     add_dirs($dirs, '/pve2/locale/', "$basedirs->{i18n}/");
  77     add_dirs($dirs, '/pve2/touch/', "$basedirs->{manager}/touch/");
  78     add_dirs($dirs, '/pve2/ext6/', "$basedirs->{extjs}/");
  79     add_dirs($dirs, '/pve2/images/' =>  "$basedirs->{manager}/images/");
  80     add_dirs($dirs, '/pve2/css/' =>  "$basedirs->{manager}/css/");
  81     add_dirs($dirs, '/pve2/js/' =>  "$basedirs->{manager}/js/");
  82     add_dirs($dirs, '/pve2/fa/fonts/' =>  "$basedirs->{fontawesome}/fonts/");
  83     add_dirs($dirs, '/pve2/fa/css/' =>  "$basedirs->{fontawesome}/css/");
  84     add_dirs($dirs, '/pve-docs/' => "$basedirs->{docs}/");
  85     add_dirs($dirs, '/pve-docs/api-viewer/extjs/' => "$basedirs->{extjs}/");
  86     add_dirs($dirs, '/novnc/' => "$basedirs->{novnc}/");
  87     add_dirs($dirs, '/xtermjs/' => "$basedirs->{xtermjs}/");
  88
  89     $self->{server_config} = {
  90         title => 'Proxmox VE API',
  91         keep_alive => 100,
  92         max_conn => 500,
  93         max_requests => 1000,
  94         lockfile => $accept_lock_fn,
  95         socket => $socket,
  96         lockfh => $lockfh,
  97         debug => $self->{debug},
  98         trusted_env => 0, # not trusted, anyone can connect
  99         logfile => '/var/log/pveproxy/access.log',
 100         allow_from => $proxyconf->{ALLOW_FROM},
 101         deny_from => $proxyconf->{DENY_FROM},
 102         policy => $proxyconf->{POLICY},
 103         ssl => {
 104             # Note: older versions are considered insecure, for example
 105             # search for "Poodle"-Attack
 106             method => 'any',
 107             sslv2 => 0,
 108             sslv3 => 0,
 109             cipher_list => $proxyconf->{CIPHERS} || 'ECDHE-ECDSA-AES256-GCM-SHA384:ECDHE-RSA-AES256-GCM-SHA384:ECDHE-ECDSA-CHACHA20-POLY1305:ECDHE-RSA-CHACHA20-POLY1305:ECDHE-ECDSA-AES128-GCM-SHA256:ECDHE-RSA-AES128-GCM-SHA256:ECDHE-ECDSA-AES256-SHA384:ECDHE-RSA-AES256-SHA384:ECDHE-ECDSA-AES128-SHA256:ECDHE-RSA-AES128-SHA256',
 110             key_file => '/etc/pve/local/pve-ssl.key',
 111             cert_file => '/etc/pve/local/pve-ssl.pem',
 112             honor_cipher_order => $proxyconf->{HONOR_CIPHER_ORDER} // 1,
 113         },
 114         compression => $proxyconf->{COMPRESSION},
 115         # Note: there is no authentication for those pages and dirs!
 116         pages => {
 117             '/' => sub { get_index($self->{nodename}, @_) },
 118             # avoid authentication when accessing favicon
 119             '/favicon.ico' => {
 120                 file => "$basedirs->{manager}/images/favicon.ico",
 121             },
 122             '/proxmoxlib.js' => {
 123                 file => "$basedirs->{widgettoolkit}/proxmoxlib.js",
 124             },
 125         },
 126         dirs => $dirs,
 127     };
 128
 129     if ($proxyconf->{DHPARAMS}) {
 130         $self->{server_config}->{ssl}->{dh_file} = $proxyconf->{DHPARAMS};
 131     } else {
 132         $self->{server_config}->{ssl}->{dh} = 'skip2048';
 133     }
 134
 135     if (-f '/etc/pve/local/pveproxy-ssl.pem' && -f '/etc/pve/local/pveproxy-ssl.key') {
 136         $self->{server_config}->{ssl}->{cert_file} = '/etc/pve/local/pveproxy-ssl.pem';
 137         $self->{server_config}->{ssl}->{key_file} = '/etc/pve/local/pveproxy-ssl.key';
 138         syslog('info', 'Using \'/etc/pve/local/pveproxy-ssl.pem\' as certificate for the web interface.');
 139     }
 140 }
 141
 142 sub run {
 143     my ($self) = @_;
 144
 145     my $server = PVE::HTTPServer->new(%{$self->{server_config}});
 146     $server->run();
 147 }
 148
 149 $daemon->register_start_command();
 150 $daemon->register_restart_command(1);
 151 $daemon->register_stop_command();
 152 $daemon->register_status_command();
 153
 154 our $cmddef = {
 155     start => [ __PACKAGE__, 'start', []],
 156     restart => [ __PACKAGE__, 'restart', []],
 157     stop => [ __PACKAGE__, 'stop', []],
 158     status => [ __PACKAGE__, 'status', [], undef, sub { print shift . "\n";} ],
 159 };
 160
 161 sub is_phone {
 162     my ($ua) = @_;
 163
 164     return 0 if !$ua;
 165
 166     return 1 if $ua =~ m/(iPhone|iPod|Windows Phone)/;
 167
 168     if ($ua =~ m/Mobile(\/|\s)/) {
 169         return 1 if $ua =~ m/(BlackBerry|BB)/;
 170         return 1 if ($ua =~ m/(Android)/) && ($ua !~ m/(Silk)/);
 171     }
 172
 173     return 0;
 174 }
 175
 176 # NOTE: Requests to those pages are not authenticated
 177 # so we must be very careful here
 178
 179 sub get_index {
 180     my ($nodename, $server, $r, $args) = @_;
 181
 182     my $lang;
 183     my $username;
 184     my $token = 'null';
 185
 186     if (my $cookie = $r->header('Cookie')) {
 187         if (my $newlang = ($cookie =~ /(?:^|\s)PVELangCookie=([^;]*)/)[0]) {
 188             if ($newlang =~ m/^[a-z]{2,3}(_[A-Z]{2,3})?$/) {
 189                 $lang = $newlang;
 190             }
 191         }
 192         my $ticket = PVE::APIServer::Formatter::extract_auth_cookie($cookie, $server->{cookie_name});
 193         if (($username = PVE::AccessControl::verify_ticket($ticket, 1))) {
 194             $token = PVE::AccessControl::assemble_csrf_prevention_token($username);
 195         }
 196     }
 197
 198     if (!$lang) {
 199         my $dc_conf = PVE::Cluster::cfs_read_file('datacenter.cfg');
 200         $lang = $dc_conf->{language} // 'en';
 201     }
 202
 203     $username = '' if !$username;
 204
 205     my $mobile = is_phone($r->header('User-Agent')) ? 1 : 0;
 206
 207     if (defined($args->{mobile})) {
 208         $mobile = $args->{mobile} ? 1 : 0;
 209     }
 210
 211     my $novnc = defined($args->{console}) && $args->{novnc};
 212     my $xtermjs = defined($args->{console}) && $args->{xtermjs};
 213
 214     my $page = '';
 215     my $template = Template->new({ABSOLUTE => 1});
 216
 217     my $langfile = 0;
 218
 219     if (-f  "$basedirs->{i18n}/pve-lang-$lang.js") {
 220         $langfile = 1;
 221     }
 222
 223     my $ver = PVE::pvecfg::version();
 224     my $release = PVE::pvecfg::release();
 225
 226     my $wtversionraw = PVE::Tools::file_read_firstline("$basedirs->{widgettoolkit}/proxmoxlib.js");
 227     my $wtversion;
 228     if ($wtversionraw =~ m|^// (.*)$|) {
 229         $wtversion = $1;
 230     };
 231
 232     my $vars = {
 233         lang => $lang,
 234         langfile => $langfile,
 235         username => $username,
 236         token => $token,
 237         console => $args->{console},
 238         nodename => $nodename,
 239         debug => $server->{debug},
 240         version => "$ver-$release",
 241         wtversion => $wtversion,
 242     };
 243
 244     # by default, load the normal index
 245     my $dir = $basedirs->{manager};
 246
 247     if ($novnc) {
 248         $dir = $basedirs->{novnc};
 249     } elsif ($xtermjs) {
 250         $dir = $basedirs->{xtermjs};
 251     } elsif ($mobile) {
 252         $dir = "$basedirs->{manager}/touch";
 253     }
 254
 255     $template->process("$dir/index.html.tpl", $vars, \$page)
 256         || die $template->error(), "\n";
 257     my $headers = HTTP::Headers->new(Content_Type => "text/html; charset=utf-8");
 258     my $resp = HTTP::Response->new(200, "OK", $headers, $page);
 259
 260     return $resp;
 261 }
 262
 263 1;