PVE/API2/Qemu.pm

   1 package PVE::API2::Qemu;
   2
   3 use strict;
   4 use warnings;
   5 use Cwd 'abs_path';
   6 use Net::SSLeay;
   7 use POSIX;
   8 use IO::Socket::IP;
   9 use URI::Escape;
  10
  11 use PVE::Cluster qw (cfs_read_file cfs_write_file);;
  12 use PVE::RRD;
  13 use PVE::SafeSyslog;
  14 use PVE::Tools qw(extract_param);
  15 use PVE::Exception qw(raise raise_param_exc raise_perm_exc);
  16 use PVE::Storage;
  17 use PVE::JSONSchema qw(get_standard_option);
  18 use PVE::RESTHandler;
  19 use PVE::ReplicationConfig;
  20 use PVE::GuestHelpers;
  21 use PVE::QemuConfig;
  22 use PVE::QemuServer;
  23 use PVE::QemuServer::Monitor qw(mon_cmd);
  24 use PVE::QemuMigrate;
  25 use PVE::RPCEnvironment;
  26 use PVE::AccessControl;
  27 use PVE::INotify;
  28 use PVE::Network;
  29 use PVE::Firewall;
  30 use PVE::API2::Firewall::VM;
  31 use PVE::API2::Qemu::Agent;
  32 use PVE::VZDump::Plugin;
  33 use PVE::DataCenterConfig;
  34 use PVE::SSHInfo;
  35
  36 BEGIN {
  37     if (!$ENV{PVE_GENERATING_DOCS}) {
  38         require PVE::HA::Env::PVE2;
  39         import PVE::HA::Env::PVE2;
  40         require PVE::HA::Config;
  41         import PVE::HA::Config;
  42     }
  43 }
  44
  45 use Data::Dumper; # fixme: remove
  46
  47 use base qw(PVE::RESTHandler);
  48
  49 my $opt_force_description = "Force physical removal. Without this, we simple remove the disk from the config file and create an additional configuration entry called 'unused[n]', which contains the volume ID. Unlink of unused[n] always cause physical removal.";
  50
  51 my $resolve_cdrom_alias = sub {
  52     my $param = shift;
  53
  54     if (my $value = $param->{cdrom}) {
  55         $value .= ",media=cdrom" if $value !~ m/media=/;
  56         $param->{ide2} = $value;
  57         delete $param->{cdrom};
  58     }
  59 };
  60
  61 my $NEW_DISK_RE = qr!^(([^/:\s]+):)?(\d+(\.\d+)?)$!;
  62 my $check_storage_access = sub {
  63    my ($rpcenv, $authuser, $storecfg, $vmid, $settings, $default_storage) = @_;
  64
  65    PVE::QemuServer::foreach_drive($settings, sub {
  66         my ($ds, $drive) = @_;
  67
  68         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
  69
  70         my $volid = $drive->{file};
  71         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
  72
  73         if (!$volid || ($volid eq 'none' || $volid eq 'cloudinit' || (defined($volname) && $volname eq 'cloudinit'))) {
  74             # nothing to check
  75         } elsif ($isCDROM && ($volid eq 'cdrom')) {
  76             $rpcenv->check($authuser, "/", ['Sys.Console']);
  77         } elsif (!$isCDROM && ($volid =~ $NEW_DISK_RE)) {
  78             my ($storeid, $size) = ($2 || $default_storage, $3);
  79             die "no storage ID specified (and no default storage)\n" if !$storeid;
  80             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
  81             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
  82             raise_param_exc({ storage => "storage '$storeid' does not support vm images"})
  83                 if !$scfg->{content}->{images};
  84         } else {
  85             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
  86         }
  87     });
  88
  89    $rpcenv->check($authuser, "/storage/$settings->{vmstatestorage}", ['Datastore.AllocateSpace'])
  90        if defined($settings->{vmstatestorage});
  91 };
  92
  93 my $check_storage_access_clone = sub {
  94    my ($rpcenv, $authuser, $storecfg, $conf, $storage) = @_;
  95
  96    my $sharedvm = 1;
  97
  98    PVE::QemuServer::foreach_drive($conf, sub {
  99         my ($ds, $drive) = @_;
 100
 101         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
 102
 103         my $volid = $drive->{file};
 104
 105         return if !$volid || $volid eq 'none';
 106
 107         if ($isCDROM) {
 108             if ($volid eq 'cdrom') {
 109                 $rpcenv->check($authuser, "/", ['Sys.Console']);
 110             } else {
 111                 # we simply allow access
 112                 my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 113                 my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 114                 $sharedvm = 0 if !$scfg->{shared};
 115
 116             }
 117         } else {
 118             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 119             my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 120             $sharedvm = 0 if !$scfg->{shared};
 121
 122             $sid = $storage if $storage;
 123             $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
 124         }
 125     });
 126
 127    $rpcenv->check($authuser, "/storage/$conf->{vmstatestorage}", ['Datastore.AllocateSpace'])
 128        if defined($conf->{vmstatestorage});
 129
 130    return $sharedvm;
 131 };
 132
 133 # Note: $pool is only needed when creating a VM, because pool permissions
 134 # are automatically inherited if VM already exists inside a pool.
 135 my $create_disks = sub {
 136     my ($rpcenv, $authuser, $conf, $arch, $storecfg, $vmid, $pool, $settings, $default_storage) = @_;
 137
 138     my $vollist = [];
 139
 140     my $res = {};
 141
 142     my $code = sub {
 143         my ($ds, $disk) = @_;
 144
 145         my $volid = $disk->{file};
 146         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 147
 148         if (!$volid || $volid eq 'none' || $volid eq 'cdrom') {
 149             delete $disk->{size};
 150             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 151         } elsif (defined($volname) && $volname eq 'cloudinit') {
 152             $storeid = $storeid // $default_storage;
 153             die "no storage ID specified (and no default storage)\n" if !$storeid;
 154             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 155             my $name = "vm-$vmid-cloudinit";
 156
 157             my $fmt = undef;
 158             if ($scfg->{path}) {
 159                 $fmt = $disk->{format} // "qcow2";
 160                 $name .= ".$fmt";
 161             } else {
 162                 $fmt = $disk->{format} // "raw";
 163             }
 164
 165             # Initial disk created with 4 MB and aligned to 4MB on regeneration
 166             my $ci_size = PVE::QemuServer::Cloudinit::CLOUDINIT_DISK_SIZE;
 167             my $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $fmt, $name, $ci_size/1024);
 168             $disk->{file} = $volid;
 169             $disk->{media} = 'cdrom';
 170             push @$vollist, $volid;
 171             delete $disk->{format}; # no longer needed
 172             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 173         } elsif ($volid =~ $NEW_DISK_RE) {
 174             my ($storeid, $size) = ($2 || $default_storage, $3);
 175             die "no storage ID specified (and no default storage)\n" if !$storeid;
 176             my $defformat = PVE::Storage::storage_default_format($storecfg, $storeid);
 177             my $fmt = $disk->{format} || $defformat;
 178
 179             $size = PVE::Tools::convert_size($size, 'gb' => 'kb'); # vdisk_alloc uses kb
 180
 181             my $volid;
 182             if ($ds eq 'efidisk0') {
 183                 ($volid, $size) = PVE::QemuServer::create_efidisk($storecfg, $storeid, $vmid, $fmt, $arch);
 184             } else {
 185                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $fmt, undef, $size);
 186             }
 187             push @$vollist, $volid;
 188             $disk->{file} = $volid;
 189             $disk->{size} = PVE::Tools::convert_size($size, 'kb' => 'b');
 190             delete $disk->{format}; # no longer needed
 191             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 192         } else {
 193
 194             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
 195
 196             my $volid_is_new = 1;
 197
 198             if ($conf->{$ds}) {
 199                 my $olddrive = PVE::QemuServer::parse_drive($ds, $conf->{$ds});
 200                 $volid_is_new = undef if $olddrive->{file} && $olddrive->{file} eq $volid;
 201             }
 202
 203             if ($volid_is_new) {
 204
 205                 PVE::Storage::activate_volumes($storecfg, [ $volid ]) if $storeid;
 206
 207                 my $size = PVE::Storage::volume_size_info($storecfg, $volid);
 208
 209                 die "volume $volid does not exists\n" if !$size;
 210
 211                 $disk->{size} = $size;
 212             }
 213
 214             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 215         }
 216     };
 217
 218     eval { PVE::QemuServer::foreach_drive($settings, $code); };
 219
 220     # free allocated images on error
 221     if (my $err = $@) {
 222         syslog('err', "VM $vmid creating disks failed");
 223         foreach my $volid (@$vollist) {
 224             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 225             warn $@ if $@;
 226         }
 227         die $err;
 228     }
 229
 230     # modify vm config if everything went well
 231     foreach my $ds (keys %$res) {
 232         $conf->{$ds} = $res->{$ds};
 233     }
 234
 235     return $vollist;
 236 };
 237
 238 my $cpuoptions = {
 239     'cores' => 1,
 240     'cpu' => 1,
 241     'cpulimit' => 1,
 242     'cpuunits' => 1,
 243     'numa' => 1,
 244     'smp' => 1,
 245     'sockets' => 1,
 246     'vcpus' => 1,
 247 };
 248
 249 my $memoryoptions = {
 250     'memory' => 1,
 251     'balloon' => 1,
 252     'shares' => 1,
 253 };
 254
 255 my $hwtypeoptions = {
 256     'acpi' => 1,
 257     'hotplug' => 1,
 258     'kvm' => 1,
 259     'machine' => 1,
 260     'scsihw' => 1,
 261     'smbios1' => 1,
 262     'tablet' => 1,
 263     'vga' => 1,
 264     'watchdog' => 1,
 265     'audio0' => 1,
 266 };
 267
 268 my $generaloptions = {
 269     'agent' => 1,
 270     'autostart' => 1,
 271     'bios' => 1,
 272     'description' => 1,
 273     'keyboard' => 1,
 274     'localtime' => 1,
 275     'migrate_downtime' => 1,
 276     'migrate_speed' => 1,
 277     'name' => 1,
 278     'onboot' => 1,
 279     'ostype' => 1,
 280     'protection' => 1,
 281     'reboot' => 1,
 282     'startdate' => 1,
 283     'startup' => 1,
 284     'tdf' => 1,
 285     'template' => 1,
 286     'tags' => 1,
 287 };
 288
 289 my $vmpoweroptions = {
 290     'freeze' => 1,
 291 };
 292
 293 my $diskoptions = {
 294     'boot' => 1,
 295     'bootdisk' => 1,
 296     'vmstatestorage' => 1,
 297 };
 298
 299 my $cloudinitoptions = {
 300     cicustom => 1,
 301     cipassword => 1,
 302     citype => 1,
 303     ciuser => 1,
 304     nameserver => 1,
 305     searchdomain => 1,
 306     sshkeys => 1,
 307 };
 308
 309 my $check_vm_modify_config_perm = sub {
 310     my ($rpcenv, $authuser, $vmid, $pool, $key_list) = @_;
 311
 312     return 1 if $authuser eq 'root@pam';
 313
 314     foreach my $opt (@$key_list) {
 315         # some checks (e.g., disk, serial port, usb) need to be done somewhere
 316         # else, as there the permission can be value dependend
 317         next if PVE::QemuServer::is_valid_drivename($opt);
 318         next if $opt eq 'cdrom';
 319         next if $opt =~ m/^(?:unused|serial|usb)\d+$/;
 320
 321
 322         if ($cpuoptions->{$opt} || $opt =~ m/^numa\d+$/) {
 323             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
 324         } elsif ($memoryoptions->{$opt}) {
 325             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
 326         } elsif ($hwtypeoptions->{$opt}) {
 327             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.HWType']);
 328         } elsif ($generaloptions->{$opt}) {
 329             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
 330             # special case for startup since it changes host behaviour
 331             if ($opt eq 'startup') {
 332                 $rpcenv->check_full($authuser, "/", ['Sys.Modify']);
 333             }
 334         } elsif ($vmpoweroptions->{$opt}) {
 335             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.PowerMgmt']);
 336         } elsif ($diskoptions->{$opt}) {
 337             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
 338         } elsif ($cloudinitoptions->{$opt} || ($opt =~ m/^(?:net|ipconfig)\d+$/)) {
 339             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
 340         } else {
 341             # catches hostpci\d+, args, lock, etc.
 342             # new options will be checked here
 343             die "only root can set '$opt' config\n";
 344         }
 345     }
 346
 347     return 1;
 348 };
 349
 350 __PACKAGE__->register_method({
 351     name => 'vmlist',
 352     path => '',
 353     method => 'GET',
 354     description => "Virtual machine index (per node).",
 355     permissions => {
 356         description => "Only list VMs where you have VM.Audit permissons on /vms/<vmid>.",
 357         user => 'all',
 358     },
 359     proxyto => 'node',
 360     protected => 1, # qemu pid files are only readable by root
 361     parameters => {
 362         additionalProperties => 0,
 363         properties => {
 364             node => get_standard_option('pve-node'),
 365             full => {
 366                 type => 'boolean',
 367                 optional => 1,
 368                 description => "Determine the full status of active VMs.",
 369             },
 370         },
 371     },
 372     returns => {
 373         type => 'array',
 374         items => {
 375             type => "object",
 376             properties => $PVE::QemuServer::vmstatus_return_properties,
 377         },
 378         links => [ { rel => 'child', href => "{vmid}" } ],
 379     },
 380     code => sub {
 381         my ($param) = @_;
 382
 383         my $rpcenv = PVE::RPCEnvironment::get();
 384         my $authuser = $rpcenv->get_user();
 385
 386         my $vmstatus = PVE::QemuServer::vmstatus(undef, $param->{full});
 387
 388         my $res = [];
 389         foreach my $vmid (keys %$vmstatus) {
 390             next if !$rpcenv->check($authuser, "/vms/$vmid", [ 'VM.Audit' ], 1);
 391
 392             my $data = $vmstatus->{$vmid};
 393             push @$res, $data;
 394         }
 395
 396         return $res;
 397     }});
 398
 399
 400
 401 __PACKAGE__->register_method({
 402     name => 'create_vm',
 403     path => '',
 404     method => 'POST',
 405     description => "Create or restore a virtual machine.",
 406     permissions => {
 407         description => "You need 'VM.Allocate' permissions on /vms/{vmid} or on the VM pool /pool/{pool}. " .
 408             "For restore (option 'archive'), it is enough if the user has 'VM.Backup' permission and the VM already exists. " .
 409             "If you create disks you need 'Datastore.AllocateSpace' on any used storage.",
 410         user => 'all', # check inside
 411     },
 412     protected => 1,
 413     proxyto => 'node',
 414     parameters => {
 415         additionalProperties => 0,
 416         properties => PVE::QemuServer::json_config_properties(
 417             {
 418                 node => get_standard_option('pve-node'),
 419                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::Cluster::complete_next_vmid }),
 420                 archive => {
 421                     description => "The backup file.",
 422                     type => 'string',
 423                     optional => 1,
 424                     maxLength => 255,
 425                     completion => \&PVE::QemuServer::complete_backup_archives,
 426                 },
 427                 storage => get_standard_option('pve-storage-id', {
 428                     description => "Default storage.",
 429                     optional => 1,
 430                     completion => \&PVE::QemuServer::complete_storage,
 431                 }),
 432                 force => {
 433                     optional => 1,
 434                     type => 'boolean',
 435                     description => "Allow to overwrite existing VM.",
 436                     requires => 'archive',
 437                 },
 438                 unique => {
 439                     optional => 1,
 440                     type => 'boolean',
 441                     description => "Assign a unique random ethernet address.",
 442                     requires => 'archive',
 443                 },
 444                 pool => {
 445                     optional => 1,
 446                     type => 'string', format => 'pve-poolid',
 447                     description => "Add the VM to the specified pool.",
 448                 },
 449                 bwlimit => {
 450                     description => "Override I/O bandwidth limit (in KiB/s).",
 451                     optional => 1,
 452                     type => 'integer',
 453                     minimum => '0',
 454                     default => 'restore limit from datacenter or storage config',
 455                 },
 456                 start => {
 457                     optional => 1,
 458                     type => 'boolean',
 459                     default => 0,
 460                     description => "Start VM after it was created successfully.",
 461                 },
 462             }),
 463     },
 464     returns => {
 465         type => 'string',
 466     },
 467     code => sub {
 468         my ($param) = @_;
 469
 470         my $rpcenv = PVE::RPCEnvironment::get();
 471         my $authuser = $rpcenv->get_user();
 472
 473         my $node = extract_param($param, 'node');
 474         my $vmid = extract_param($param, 'vmid');
 475
 476         my $archive = extract_param($param, 'archive');
 477         my $is_restore = !!$archive;
 478
 479         my $bwlimit = extract_param($param, 'bwlimit');
 480         my $force = extract_param($param, 'force');
 481         my $pool = extract_param($param, 'pool');
 482         my $start_after_create = extract_param($param, 'start');
 483         my $storage = extract_param($param, 'storage');
 484         my $unique = extract_param($param, 'unique');
 485
 486         if (defined(my $ssh_keys = $param->{sshkeys})) {
 487                 $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
 488                 PVE::Tools::validate_ssh_public_keys($ssh_keys);
 489         }
 490
 491         PVE::Cluster::check_cfs_quorum();
 492
 493         my $filename = PVE::QemuConfig->config_file($vmid);
 494         my $storecfg = PVE::Storage::config();
 495
 496         if (defined($pool)) {
 497             $rpcenv->check_pool_exist($pool);
 498         }
 499
 500         $rpcenv->check($authuser, "/storage/$storage", ['Datastore.AllocateSpace'])
 501             if defined($storage);
 502
 503         if ($rpcenv->check($authuser, "/vms/$vmid", ['VM.Allocate'], 1)) {
 504             # OK
 505         } elsif ($pool && $rpcenv->check($authuser, "/pool/$pool", ['VM.Allocate'], 1)) {
 506             # OK
 507         } elsif ($archive && $force && (-f $filename) &&
 508                  $rpcenv->check($authuser, "/vms/$vmid", ['VM.Backup'], 1)) {
 509             # OK: user has VM.Backup permissions, and want to restore an existing VM
 510         } else {
 511             raise_perm_exc();
 512         }
 513
 514         if (!$archive) {
 515             &$resolve_cdrom_alias($param);
 516
 517             &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param, $storage);
 518
 519             &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, $pool, [ keys %$param]);
 520
 521             foreach my $opt (keys %$param) {
 522                 if (PVE::QemuServer::is_valid_drivename($opt)) {
 523                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
 524                     raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
 525
 526                     PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
 527                     $param->{$opt} = PVE::QemuServer::print_drive($vmid, $drive);
 528                 }
 529             }
 530
 531             PVE::QemuServer::add_random_macs($param);
 532         } else {
 533             my $keystr = join(' ', keys %$param);
 534             raise_param_exc({ archive => "option conflicts with other options ($keystr)"}) if $keystr;
 535
 536             if ($archive eq '-') {
 537                 die "pipe requires cli environment\n"
 538                     if $rpcenv->{type} ne 'cli';
 539             } else {
 540                 PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $archive);
 541                 $archive = PVE::Storage::abs_filesystem_path($storecfg, $archive);
 542             }
 543         }
 544
 545         my $emsg = $is_restore ? "unable to restore VM $vmid -" : "unable to create VM $vmid -";
 546
 547         eval { PVE::QemuConfig->create_and_lock_config($vmid, $force) };
 548         die "$emsg $@" if $@;
 549
 550         my $restorefn = sub {
 551             my $conf = PVE::QemuConfig->load_config($vmid);
 552
 553             PVE::QemuConfig->check_protection($conf, $emsg);
 554
 555             die "$emsg vm is running\n" if PVE::QemuServer::check_running($vmid);
 556
 557             my $realcmd = sub {
 558                 PVE::QemuServer::restore_archive($archive, $vmid, $authuser, {
 559                     storage => $storage,
 560                     pool => $pool,
 561                     unique => $unique,
 562                     bwlimit => $bwlimit,
 563                 });
 564                 my $restored_conf = PVE::QemuConfig->load_config($vmid);
 565                 # Convert restored VM to template if backup was VM template
 566                 if (PVE::QemuConfig->is_template($restored_conf)) {
 567                     warn "Convert to template.\n";
 568                     eval { PVE::QemuServer::template_create($vmid, $restored_conf) };
 569                     warn $@ if $@;
 570                 }
 571
 572                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 573
 574                 if ($start_after_create) {
 575                     eval { PVE::API2::Qemu->vm_start({ vmid => $vmid, node => $node }) };
 576                     warn $@ if $@;
 577                 }
 578             };
 579
 580             # ensure no old replication state are exists
 581             PVE::ReplicationState::delete_guest_states($vmid);
 582
 583             return PVE::QemuConfig->lock_config_full($vmid, 1, $realcmd);
 584         };
 585
 586         my $createfn = sub {
 587             # ensure no old replication state are exists
 588             PVE::ReplicationState::delete_guest_states($vmid);
 589
 590             my $realcmd = sub {
 591
 592                 my $vollist = [];
 593
 594                 my $conf = $param;
 595
 596                 my ($arch, undef) = PVE::QemuServer::get_basic_machine_info($conf);
 597
 598                 eval {
 599
 600                     $vollist = &$create_disks($rpcenv, $authuser, $conf, $arch, $storecfg, $vmid, $pool, $param, $storage);
 601
 602                     if (!$conf->{bootdisk}) {
 603                         my $firstdisk = PVE::QemuServer::resolve_first_disk($conf);
 604                         $conf->{bootdisk} = $firstdisk if $firstdisk;
 605                     }
 606
 607                     # auto generate uuid if user did not specify smbios1 option
 608                     if (!$conf->{smbios1}) {
 609                         $conf->{smbios1} = PVE::QemuServer::generate_smbios1_uuid();
 610                     }
 611
 612                     if ((!defined($conf->{vmgenid}) || $conf->{vmgenid} eq '1') && $arch ne 'aarch64') {
 613                         $conf->{vmgenid} = PVE::QemuServer::generate_uuid();
 614                     }
 615
 616                     PVE::QemuConfig->write_config($vmid, $conf);
 617
 618                 };
 619                 my $err = $@;
 620
 621                 if ($err) {
 622                     foreach my $volid (@$vollist) {
 623                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 624                         warn $@ if $@;
 625                     }
 626                     die "$emsg $err";
 627                 }
 628
 629                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 630             };
 631
 632             PVE::QemuConfig->lock_config_full($vmid, 1, $realcmd);
 633
 634             if ($start_after_create) {
 635                 print "Execute autostart\n";
 636                 eval { PVE::API2::Qemu->vm_start({vmid => $vmid, node => $node}) };
 637                 warn $@ if $@;
 638             }
 639         };
 640
 641         my ($code, $worker_name);
 642         if ($is_restore) {
 643             $worker_name = 'qmrestore';
 644             $code = sub {
 645                 eval { $restorefn->() };
 646                 if (my $err = $@) {
 647                     eval { PVE::QemuConfig->remove_lock($vmid, 'create') };
 648                     warn $@ if $@;
 649                     die $err;
 650                 }
 651             };
 652         } else {
 653             $worker_name = 'qmcreate';
 654             $code = sub {
 655                 eval { $createfn->() };
 656                 if (my $err = $@) {
 657                     eval {
 658                         my $conffile = PVE::QemuConfig->config_file($vmid);
 659                         unlink($conffile) or die "failed to remove config file: $!\n";
 660                     };
 661                     warn $@ if $@;
 662                     die $err;
 663                 }
 664             };
 665         }
 666
 667         return $rpcenv->fork_worker($worker_name, $vmid, $authuser, $code);
 668     }});
 669
 670 __PACKAGE__->register_method({
 671     name => 'vmdiridx',
 672     path => '{vmid}',
 673     method => 'GET',
 674     proxyto => 'node',
 675     description => "Directory index",
 676     permissions => {
 677         user => 'all',
 678     },
 679     parameters => {
 680         additionalProperties => 0,
 681         properties => {
 682             node => get_standard_option('pve-node'),
 683             vmid => get_standard_option('pve-vmid'),
 684         },
 685     },
 686     returns => {
 687         type => 'array',
 688         items => {
 689             type => "object",
 690             properties => {
 691                 subdir => { type => 'string' },
 692             },
 693         },
 694         links => [ { rel => 'child', href => "{subdir}" } ],
 695     },
 696     code => sub {
 697         my ($param) = @_;
 698
 699         my $res = [
 700             { subdir => 'config' },
 701             { subdir => 'pending' },
 702             { subdir => 'status' },
 703             { subdir => 'unlink' },
 704             { subdir => 'vncproxy' },
 705             { subdir => 'termproxy' },
 706             { subdir => 'migrate' },
 707             { subdir => 'resize' },
 708             { subdir => 'move' },
 709             { subdir => 'rrd' },
 710             { subdir => 'rrddata' },
 711             { subdir => 'monitor' },
 712             { subdir => 'agent' },
 713             { subdir => 'snapshot' },
 714             { subdir => 'spiceproxy' },
 715             { subdir => 'sendkey' },
 716             { subdir => 'firewall' },
 717             ];
 718
 719         return $res;
 720     }});
 721
 722 __PACKAGE__->register_method ({
 723     subclass => "PVE::API2::Firewall::VM",
 724     path => '{vmid}/firewall',
 725 });
 726
 727 __PACKAGE__->register_method ({
 728     subclass => "PVE::API2::Qemu::Agent",
 729     path => '{vmid}/agent',
 730 });
 731
 732 __PACKAGE__->register_method({
 733     name => 'rrd',
 734     path => '{vmid}/rrd',
 735     method => 'GET',
 736     protected => 1, # fixme: can we avoid that?
 737     permissions => {
 738         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 739     },
 740     description => "Read VM RRD statistics (returns PNG)",
 741     parameters => {
 742         additionalProperties => 0,
 743         properties => {
 744             node => get_standard_option('pve-node'),
 745             vmid => get_standard_option('pve-vmid'),
 746             timeframe => {
 747                 description => "Specify the time frame you are interested in.",
 748                 type => 'string',
 749                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 750             },
 751             ds => {
 752                 description => "The list of datasources you want to display.",
 753                 type => 'string', format => 'pve-configid-list',
 754             },
 755             cf => {
 756                 description => "The RRD consolidation function",
 757                 type => 'string',
 758                 enum => [ 'AVERAGE', 'MAX' ],
 759                 optional => 1,
 760             },
 761         },
 762     },
 763     returns => {
 764         type => "object",
 765         properties => {
 766             filename => { type => 'string' },
 767         },
 768     },
 769     code => sub {
 770         my ($param) = @_;
 771
 772         return PVE::RRD::create_rrd_graph(
 773             "pve2-vm/$param->{vmid}", $param->{timeframe},
 774             $param->{ds}, $param->{cf});
 775
 776     }});
 777
 778 __PACKAGE__->register_method({
 779     name => 'rrddata',
 780     path => '{vmid}/rrddata',
 781     method => 'GET',
 782     protected => 1, # fixme: can we avoid that?
 783     permissions => {
 784         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 785     },
 786     description => "Read VM RRD statistics",
 787     parameters => {
 788         additionalProperties => 0,
 789         properties => {
 790             node => get_standard_option('pve-node'),
 791             vmid => get_standard_option('pve-vmid'),
 792             timeframe => {
 793                 description => "Specify the time frame you are interested in.",
 794                 type => 'string',
 795                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 796             },
 797             cf => {
 798                 description => "The RRD consolidation function",
 799                 type => 'string',
 800                 enum => [ 'AVERAGE', 'MAX' ],
 801                 optional => 1,
 802             },
 803         },
 804     },
 805     returns => {
 806         type => "array",
 807         items => {
 808             type => "object",
 809             properties => {},
 810         },
 811     },
 812     code => sub {
 813         my ($param) = @_;
 814
 815         return PVE::RRD::create_rrd_data(
 816             "pve2-vm/$param->{vmid}", $param->{timeframe}, $param->{cf});
 817     }});
 818
 819
 820 __PACKAGE__->register_method({
 821     name => 'vm_config',
 822     path => '{vmid}/config',
 823     method => 'GET',
 824     proxyto => 'node',
 825     description => "Get current virtual machine configuration. This does not include pending configuration changes (see 'pending' API).",
 826     permissions => {
 827         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 828     },
 829     parameters => {
 830         additionalProperties => 0,
 831         properties => {
 832             node => get_standard_option('pve-node'),
 833             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 834             current => {
 835                 description => "Get current values (instead of pending values).",
 836                 optional => 1,
 837                 default => 0,
 838                 type => 'boolean',
 839             },
 840             snapshot => get_standard_option('pve-snapshot-name', {
 841                 description => "Fetch config values from given snapshot.",
 842                 optional => 1,
 843                 completion => sub {
 844                     my ($cmd, $pname, $cur, $args) = @_;
 845                     PVE::QemuConfig->snapshot_list($args->[0]);
 846                 },
 847             }),
 848         },
 849     },
 850     returns => {
 851         description => "The current VM configuration.",
 852         type => "object",
 853         properties => PVE::QemuServer::json_config_properties({
 854             digest => {
 855                 type => 'string',
 856                 description => 'SHA1 digest of configuration file. This can be used to prevent concurrent modifications.',
 857             }
 858         }),
 859     },
 860     code => sub {
 861         my ($param) = @_;
 862
 863         raise_param_exc({ snapshot => "cannot use 'snapshot' parameter with 'current'",
 864                           current => "cannot use 'snapshot' parameter with 'current'"})
 865             if ($param->{snapshot} && $param->{current});
 866
 867         my $conf;
 868         if ($param->{snapshot}) {
 869             $conf = PVE::QemuConfig->load_snapshot_config($param->{vmid}, $param->{snapshot});
 870         } else {
 871             $conf = PVE::QemuConfig->load_current_config($param->{vmid}, $param->{current});
 872         }
 873         $conf->{cipassword} = '**********' if $conf->{cipassword};
 874         return $conf;
 875
 876     }});
 877
 878 __PACKAGE__->register_method({
 879     name => 'vm_pending',
 880     path => '{vmid}/pending',
 881     method => 'GET',
 882     proxyto => 'node',
 883     description => "Get virtual machine configuration, including pending changes.",
 884     permissions => {
 885         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 886     },
 887     parameters => {
 888         additionalProperties => 0,
 889         properties => {
 890             node => get_standard_option('pve-node'),
 891             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 892         },
 893     },
 894     returns => {
 895         type => "array",
 896         items => {
 897             type => "object",
 898             properties => {
 899                 key => {
 900                     description => "Configuration option name.",
 901                     type => 'string',
 902                 },
 903                 value => {
 904                     description => "Current value.",
 905                     type => 'string',
 906                     optional => 1,
 907                 },
 908                 pending => {
 909                     description => "Pending value.",
 910                     type => 'string',
 911                     optional => 1,
 912                 },
 913                 delete => {
 914                     description => "Indicates a pending delete request if present and not 0. " .
 915                                    "The value 2 indicates a force-delete request.",
 916                     type => 'integer',
 917                     minimum => 0,
 918                     maximum => 2,
 919                     optional => 1,
 920                 },
 921             },
 922         },
 923     },
 924     code => sub {
 925         my ($param) = @_;
 926
 927         my $conf = PVE::QemuConfig->load_config($param->{vmid});
 928
 929         my $pending_delete_hash = PVE::QemuConfig->parse_pending_delete($conf->{pending}->{delete});
 930
 931         $conf->{cipassword} = '**********' if defined($conf->{cipassword});
 932         $conf->{pending}->{cipassword} = '********** ' if defined($conf->{pending}->{cipassword});
 933
 934         return PVE::GuestHelpers::config_with_pending_array($conf, $pending_delete_hash);
 935    }});
 936
 937 # POST/PUT {vmid}/config implementation
 938 #
 939 # The original API used PUT (idempotent) an we assumed that all operations
 940 # are fast. But it turned out that almost any configuration change can
 941 # involve hot-plug actions, or disk alloc/free. Such actions can take long
 942 # time to complete and have side effects (not idempotent).
 943 #
 944 # The new implementation uses POST and forks a worker process. We added
 945 # a new option 'background_delay'. If specified we wait up to
 946 # 'background_delay' second for the worker task to complete. It returns null
 947 # if the task is finished within that time, else we return the UPID.
 948
 949 my $update_vm_api  = sub {
 950     my ($param, $sync) = @_;
 951
 952     my $rpcenv = PVE::RPCEnvironment::get();
 953
 954     my $authuser = $rpcenv->get_user();
 955
 956     my $node = extract_param($param, 'node');
 957
 958     my $vmid = extract_param($param, 'vmid');
 959
 960     my $digest = extract_param($param, 'digest');
 961
 962     my $background_delay = extract_param($param, 'background_delay');
 963
 964     if (defined(my $cipassword = $param->{cipassword})) {
 965         # Same logic as in cloud-init (but with the regex fixed...)
 966         $param->{cipassword} = PVE::Tools::encrypt_pw($cipassword)
 967             if $cipassword !~ /^\$(?:[156]|2[ay])(\$.+){2}/;
 968     }
 969
 970     my @paramarr = (); # used for log message
 971     foreach my $key (sort keys %$param) {
 972         my $value = $key eq 'cipassword' ? '<hidden>' : $param->{$key};
 973         push @paramarr, "-$key", $value;
 974     }
 975
 976     my $skiplock = extract_param($param, 'skiplock');
 977     raise_param_exc({ skiplock => "Only root may use this option." })
 978         if $skiplock && $authuser ne 'root@pam';
 979
 980     my $delete_str = extract_param($param, 'delete');
 981
 982     my $revert_str = extract_param($param, 'revert');
 983
 984     my $force = extract_param($param, 'force');
 985
 986     if (defined(my $ssh_keys = $param->{sshkeys})) {
 987         $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
 988         PVE::Tools::validate_ssh_public_keys($ssh_keys);
 989     }
 990
 991     die "no options specified\n" if !$delete_str && !$revert_str && !scalar(keys %$param);
 992
 993     my $storecfg = PVE::Storage::config();
 994
 995     my $defaults = PVE::QemuServer::load_defaults();
 996
 997     &$resolve_cdrom_alias($param);
 998
 999     # now try to verify all parameters
1000
1001     my $revert = {};
1002     foreach my $opt (PVE::Tools::split_list($revert_str)) {
1003         if (!PVE::QemuServer::option_exists($opt)) {
1004             raise_param_exc({ revert => "unknown option '$opt'" });
1005         }
1006
1007         raise_param_exc({ delete => "you can't use '-$opt' and " .
1008                               "-revert $opt' at the same time" })
1009             if defined($param->{$opt});
1010
1011         $revert->{$opt} = 1;
1012     }
1013
1014     my @delete = ();
1015     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1016         $opt = 'ide2' if $opt eq 'cdrom';
1017
1018         raise_param_exc({ delete => "you can't use '-$opt' and " .
1019                               "-delete $opt' at the same time" })
1020             if defined($param->{$opt});
1021
1022         raise_param_exc({ revert => "you can't use '-delete $opt' and " .
1023                               "-revert $opt' at the same time" })
1024             if $revert->{$opt};
1025
1026         if (!PVE::QemuServer::option_exists($opt)) {
1027             raise_param_exc({ delete => "unknown option '$opt'" });
1028         }
1029
1030         push @delete, $opt;
1031     }
1032
1033     my $repl_conf = PVE::ReplicationConfig->new();
1034     my $is_replicated = $repl_conf->check_for_existing_jobs($vmid, 1);
1035     my $check_replication = sub {
1036         my ($drive) = @_;
1037         return if !$is_replicated;
1038         my $volid = $drive->{file};
1039         return if !$volid || !($drive->{replicate}//1);
1040         return if PVE::QemuServer::drive_is_cdrom($drive);
1041
1042         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1043         return if $volname eq 'cloudinit';
1044
1045         my $format;
1046         if ($volid =~ $NEW_DISK_RE) {
1047             $storeid = $2;
1048             $format = $drive->{format} || PVE::Storage::storage_default_format($storecfg, $storeid);
1049         } else {
1050             $format = (PVE::Storage::parse_volname($storecfg, $volid))[6];
1051         }
1052         return if PVE::Storage::storage_can_replicate($storecfg, $storeid, $format);
1053         my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
1054         return if $scfg->{shared};
1055         die "cannot add non-replicatable volume to a replicated VM\n";
1056     };
1057
1058     foreach my $opt (keys %$param) {
1059         if (PVE::QemuServer::is_valid_drivename($opt)) {
1060             # cleanup drive path
1061             my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1062             raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
1063             PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
1064             $check_replication->($drive);
1065             $param->{$opt} = PVE::QemuServer::print_drive($vmid, $drive);
1066         } elsif ($opt =~ m/^net(\d+)$/) {
1067             # add macaddr
1068             my $net = PVE::QemuServer::parse_net($param->{$opt});
1069             $param->{$opt} = PVE::QemuServer::print_net($net);
1070         } elsif ($opt eq 'vmgenid') {
1071             if ($param->{$opt} eq '1') {
1072                 $param->{$opt} = PVE::QemuServer::generate_uuid();
1073             }
1074         } elsif ($opt eq 'hookscript') {
1075             eval { PVE::GuestHelpers::check_hookscript($param->{$opt}, $storecfg); };
1076             raise_param_exc({ $opt => $@ }) if $@;
1077         }
1078     }
1079
1080     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [@delete]);
1081
1082     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [keys %$param]);
1083
1084     &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param);
1085
1086     my $updatefn =  sub {
1087
1088         my $conf = PVE::QemuConfig->load_config($vmid);
1089
1090         die "checksum missmatch (file change by other user?)\n"
1091             if $digest && $digest ne $conf->{digest};
1092
1093         PVE::QemuConfig->check_lock($conf) if !$skiplock;
1094
1095         foreach my $opt (keys %$revert) {
1096             if (defined($conf->{$opt})) {
1097                 $param->{$opt} = $conf->{$opt};
1098             } elsif (defined($conf->{pending}->{$opt})) {
1099                 push @delete, $opt;
1100             }
1101         }
1102
1103         if ($param->{memory} || defined($param->{balloon})) {
1104             my $maxmem = $param->{memory} || $conf->{pending}->{memory} || $conf->{memory} || $defaults->{memory};
1105             my $balloon = defined($param->{balloon}) ? $param->{balloon} : $conf->{pending}->{balloon} || $conf->{balloon};
1106
1107             die "balloon value too large (must be smaller than assigned memory)\n"
1108                 if $balloon && $balloon > $maxmem;
1109         }
1110
1111         PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: " . join (' ', @paramarr));
1112
1113         my $worker = sub {
1114
1115             print "update VM $vmid: " . join (' ', @paramarr) . "\n";
1116
1117             # write updates to pending section
1118
1119             my $modified = {}; # record what $option we modify
1120
1121             foreach my $opt (@delete) {
1122                 $modified->{$opt} = 1;
1123                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1124
1125                 # value of what we want to delete, independent if pending or not
1126                 my $val = $conf->{$opt} // $conf->{pending}->{$opt};
1127                 if (!defined($val)) {
1128                     warn "cannot delete '$opt' - not set in current configuration!\n";
1129                     $modified->{$opt} = 0;
1130                     next;
1131                 }
1132                 my $is_pending_val = defined($conf->{pending}->{$opt});
1133                 delete $conf->{pending}->{$opt};
1134
1135                 if ($opt =~ m/^unused/) {
1136                     my $drive = PVE::QemuServer::parse_drive($opt, $val);
1137                     PVE::QemuConfig->check_protection($conf, "can't remove unused disk '$drive->{file}'");
1138                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1139                     if (PVE::QemuServer::try_deallocate_drive($storecfg, $vmid, $conf, $opt, $drive, $rpcenv, $authuser)) {
1140                         delete $conf->{$opt};
1141                         PVE::QemuConfig->write_config($vmid, $conf);
1142                     }
1143                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
1144                     PVE::QemuConfig->check_protection($conf, "can't remove drive '$opt'");
1145                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1146                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $val))
1147                         if $is_pending_val;
1148                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1149                     PVE::QemuConfig->write_config($vmid, $conf);
1150                 } elsif ($opt =~ m/^serial\d+$/) {
1151                     if ($val eq 'socket') {
1152                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1153                     } elsif ($authuser ne 'root@pam') {
1154                         die "only root can delete '$opt' config for real devices\n";
1155                     }
1156                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1157                     PVE::QemuConfig->write_config($vmid, $conf);
1158                 } elsif ($opt =~ m/^usb\d+$/) {
1159                     if ($val =~ m/spice/) {
1160                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1161                     } elsif ($authuser ne 'root@pam') {
1162                         die "only root can delete '$opt' config for real devices\n";
1163                     }
1164                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1165                     PVE::QemuConfig->write_config($vmid, $conf);
1166                 } else {
1167                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1168                     PVE::QemuConfig->write_config($vmid, $conf);
1169                 }
1170             }
1171
1172             foreach my $opt (keys %$param) { # add/change
1173                 $modified->{$opt} = 1;
1174                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1175                 next if defined($conf->{pending}->{$opt}) && ($param->{$opt} eq $conf->{pending}->{$opt}); # skip if nothing changed
1176
1177                 my ($arch, undef) = PVE::QemuServer::get_basic_machine_info($conf);
1178
1179                 if (PVE::QemuServer::is_valid_drivename($opt)) {
1180                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1181                     # FIXME: cloudinit: CDROM or Disk?
1182                     if (PVE::QemuServer::drive_is_cdrom($drive)) { # CDROM
1183                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.CDROM']);
1184                     } else {
1185                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1186                     }
1187                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $conf->{pending}->{$opt}))
1188                         if defined($conf->{pending}->{$opt});
1189
1190                     &$create_disks($rpcenv, $authuser, $conf->{pending}, $arch, $storecfg, $vmid, undef, {$opt => $param->{$opt}});
1191                 } elsif ($opt =~ m/^serial\d+/) {
1192                     if ((!defined($conf->{$opt}) || $conf->{$opt} eq 'socket') && $param->{$opt} eq 'socket') {
1193                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1194                     } elsif ($authuser ne 'root@pam') {
1195                         die "only root can modify '$opt' config for real devices\n";
1196                     }
1197                     $conf->{pending}->{$opt} = $param->{$opt};
1198                 } elsif ($opt =~ m/^usb\d+/) {
1199                     if ((!defined($conf->{$opt}) || $conf->{$opt} =~ m/spice/) && $param->{$opt} =~ m/spice/) {
1200                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1201                     } elsif ($authuser ne 'root@pam') {
1202                         die "only root can modify '$opt' config for real devices\n";
1203                     }
1204                     $conf->{pending}->{$opt} = $param->{$opt};
1205                 } else {
1206                     $conf->{pending}->{$opt} = $param->{$opt};
1207                 }
1208                 PVE::QemuConfig->remove_from_pending_delete($conf, $opt);
1209                 PVE::QemuConfig->write_config($vmid, $conf);
1210             }
1211
1212             # remove pending changes when nothing changed
1213             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1214             my $changes = PVE::QemuConfig->cleanup_pending($conf);
1215             PVE::QemuConfig->write_config($vmid, $conf) if $changes;
1216
1217             return if !scalar(keys %{$conf->{pending}});
1218
1219             my $running = PVE::QemuServer::check_running($vmid);
1220
1221             # apply pending changes
1222
1223             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1224
1225             if ($running) {
1226                 my $errors = {};
1227                 PVE::QemuServer::vmconfig_hotplug_pending($vmid, $conf, $storecfg, $modified, $errors);
1228                 raise_param_exc($errors) if scalar(keys %$errors);
1229             } else {
1230                 PVE::QemuServer::vmconfig_apply_pending($vmid, $conf, $storecfg, $running);
1231             }
1232
1233             return;
1234         };
1235
1236         if ($sync) {
1237             &$worker();
1238             return undef;
1239         } else {
1240             my $upid = $rpcenv->fork_worker('qmconfig', $vmid, $authuser, $worker);
1241
1242             if ($background_delay) {
1243
1244                 # Note: It would be better to do that in the Event based HTTPServer
1245                 # to avoid blocking call to sleep.
1246
1247                 my $end_time = time() + $background_delay;
1248
1249                 my $task = PVE::Tools::upid_decode($upid);
1250
1251                 my $running = 1;
1252                 while (time() < $end_time) {
1253                     $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
1254                     last if !$running;
1255                     sleep(1); # this gets interrupted when child process ends
1256                 }
1257
1258                 if (!$running) {
1259                     my $status = PVE::Tools::upid_read_status($upid);
1260                     return undef if $status eq 'OK';
1261                     die $status;
1262                 }
1263             }
1264
1265             return $upid;
1266         }
1267     };
1268
1269     return PVE::QemuConfig->lock_config($vmid, $updatefn);
1270 };
1271
1272 my $vm_config_perm_list = [
1273             'VM.Config.Disk',
1274             'VM.Config.CDROM',
1275             'VM.Config.CPU',
1276             'VM.Config.Memory',
1277             'VM.Config.Network',
1278             'VM.Config.HWType',
1279             'VM.Config.Options',
1280     ];
1281
1282 __PACKAGE__->register_method({
1283     name => 'update_vm_async',
1284     path => '{vmid}/config',
1285     method => 'POST',
1286     protected => 1,
1287     proxyto => 'node',
1288     description => "Set virtual machine options (asynchrounous API).",
1289     permissions => {
1290         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1291     },
1292     parameters => {
1293         additionalProperties => 0,
1294         properties => PVE::QemuServer::json_config_properties(
1295             {
1296                 node => get_standard_option('pve-node'),
1297                 vmid => get_standard_option('pve-vmid'),
1298                 skiplock => get_standard_option('skiplock'),
1299                 delete => {
1300                     type => 'string', format => 'pve-configid-list',
1301                     description => "A list of settings you want to delete.",
1302                     optional => 1,
1303                 },
1304                 revert => {
1305                     type => 'string', format => 'pve-configid-list',
1306                     description => "Revert a pending change.",
1307                     optional => 1,
1308                 },
1309                 force => {
1310                     type => 'boolean',
1311                     description => $opt_force_description,
1312                     optional => 1,
1313                     requires => 'delete',
1314                 },
1315                 digest => {
1316                     type => 'string',
1317                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1318                     maxLength => 40,
1319                     optional => 1,
1320                 },
1321                 background_delay => {
1322                     type => 'integer',
1323                     description => "Time to wait for the task to finish. We return 'null' if the task finish within that time.",
1324                     minimum => 1,
1325                     maximum => 30,
1326                     optional => 1,
1327                 },
1328             }),
1329     },
1330     returns => {
1331         type => 'string',
1332         optional => 1,
1333     },
1334     code => $update_vm_api,
1335 });
1336
1337 __PACKAGE__->register_method({
1338     name => 'update_vm',
1339     path => '{vmid}/config',
1340     method => 'PUT',
1341     protected => 1,
1342     proxyto => 'node',
1343     description => "Set virtual machine options (synchrounous API) - You should consider using the POST method instead for any actions involving hotplug or storage allocation.",
1344     permissions => {
1345         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1346     },
1347     parameters => {
1348         additionalProperties => 0,
1349         properties => PVE::QemuServer::json_config_properties(
1350             {
1351                 node => get_standard_option('pve-node'),
1352                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1353                 skiplock => get_standard_option('skiplock'),
1354                 delete => {
1355                     type => 'string', format => 'pve-configid-list',
1356                     description => "A list of settings you want to delete.",
1357                     optional => 1,
1358                 },
1359                 revert => {
1360                     type => 'string', format => 'pve-configid-list',
1361                     description => "Revert a pending change.",
1362                     optional => 1,
1363                 },
1364                 force => {
1365                     type => 'boolean',
1366                     description => $opt_force_description,
1367                     optional => 1,
1368                     requires => 'delete',
1369                 },
1370                 digest => {
1371                     type => 'string',
1372                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1373                     maxLength => 40,
1374                     optional => 1,
1375                 },
1376             }),
1377     },
1378     returns => { type => 'null' },
1379     code => sub {
1380         my ($param) = @_;
1381         &$update_vm_api($param, 1);
1382         return undef;
1383     }
1384 });
1385
1386 __PACKAGE__->register_method({
1387     name => 'destroy_vm',
1388     path => '{vmid}',
1389     method => 'DELETE',
1390     protected => 1,
1391     proxyto => 'node',
1392     description => "Destroy the vm (also delete all used/owned volumes).",
1393     permissions => {
1394         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
1395     },
1396     parameters => {
1397         additionalProperties => 0,
1398         properties => {
1399             node => get_standard_option('pve-node'),
1400             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
1401             skiplock => get_standard_option('skiplock'),
1402             purge => {
1403                 type => 'boolean',
1404                 description => "Remove vmid from backup cron jobs.",
1405                 optional => 1,
1406             },
1407         },
1408     },
1409     returns => {
1410         type => 'string',
1411     },
1412     code => sub {
1413         my ($param) = @_;
1414
1415         my $rpcenv = PVE::RPCEnvironment::get();
1416         my $authuser = $rpcenv->get_user();
1417         my $vmid = $param->{vmid};
1418
1419         my $skiplock = $param->{skiplock};
1420         raise_param_exc({ skiplock => "Only root may use this option." })
1421             if $skiplock && $authuser ne 'root@pam';
1422
1423         # test if VM exists
1424         my $conf = PVE::QemuConfig->load_config($vmid);
1425         my $storecfg = PVE::Storage::config();
1426         PVE::QemuConfig->check_protection($conf, "can't remove VM $vmid");
1427         die "unable to remove VM $vmid - used in HA resources\n"
1428             if PVE::HA::Config::vm_is_ha_managed($vmid);
1429
1430         if (!$param->{purge}) {
1431             # don't allow destroy if with replication jobs but no purge param
1432             my $repl_conf = PVE::ReplicationConfig->new();
1433             $repl_conf->check_for_existing_jobs($vmid);
1434         }
1435
1436         # early tests (repeat after locking)
1437         die "VM $vmid is running - destroy failed\n"
1438             if PVE::QemuServer::check_running($vmid);
1439
1440         my $realcmd = sub {
1441             my $upid = shift;
1442
1443             syslog('info', "destroy VM $vmid: $upid\n");
1444             PVE::QemuConfig->lock_config($vmid, sub {
1445                 die "VM $vmid is running - destroy failed\n"
1446                     if (PVE::QemuServer::check_running($vmid));
1447
1448                 PVE::QemuServer::destroy_vm($storecfg, $vmid, $skiplock, { lock => 'destroyed' });
1449
1450                 PVE::AccessControl::remove_vm_access($vmid);
1451                 PVE::Firewall::remove_vmfw_conf($vmid);
1452                 if ($param->{purge}) {
1453                     PVE::ReplicationConfig::remove_vmid_jobs($vmid);
1454                     PVE::VZDump::Plugin::remove_vmid_from_backup_jobs($vmid);
1455                 }
1456
1457                 # only now remove the zombie config, else we can have reuse race
1458                 PVE::QemuConfig->destroy_config($vmid);
1459             });
1460         };
1461
1462         return $rpcenv->fork_worker('qmdestroy', $vmid, $authuser, $realcmd);
1463     }});
1464
1465 __PACKAGE__->register_method({
1466     name => 'unlink',
1467     path => '{vmid}/unlink',
1468     method => 'PUT',
1469     protected => 1,
1470     proxyto => 'node',
1471     description => "Unlink/delete disk images.",
1472     permissions => {
1473         check => [ 'perm', '/vms/{vmid}', ['VM.Config.Disk']],
1474     },
1475     parameters => {
1476         additionalProperties => 0,
1477         properties => {
1478             node => get_standard_option('pve-node'),
1479             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1480             idlist => {
1481                 type => 'string', format => 'pve-configid-list',
1482                 description => "A list of disk IDs you want to delete.",
1483             },
1484             force => {
1485                 type => 'boolean',
1486                 description => $opt_force_description,
1487                 optional => 1,
1488             },
1489         },
1490     },
1491     returns => { type => 'null'},
1492     code => sub {
1493         my ($param) = @_;
1494
1495         $param->{delete} = extract_param($param, 'idlist');
1496
1497         __PACKAGE__->update_vm($param);
1498
1499         return undef;
1500     }});
1501
1502 my $sslcert;
1503
1504 __PACKAGE__->register_method({
1505     name => 'vncproxy',
1506     path => '{vmid}/vncproxy',
1507     method => 'POST',
1508     protected => 1,
1509     permissions => {
1510         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1511     },
1512     description => "Creates a TCP VNC proxy connections.",
1513     parameters => {
1514         additionalProperties => 0,
1515         properties => {
1516             node => get_standard_option('pve-node'),
1517             vmid => get_standard_option('pve-vmid'),
1518             websocket => {
1519                 optional => 1,
1520                 type => 'boolean',
1521                 description => "starts websockify instead of vncproxy",
1522             },
1523         },
1524     },
1525     returns => {
1526         additionalProperties => 0,
1527         properties => {
1528             user => { type => 'string' },
1529             ticket => { type => 'string' },
1530             cert => { type => 'string' },
1531             port => { type => 'integer' },
1532             upid => { type => 'string' },
1533         },
1534     },
1535     code => sub {
1536         my ($param) = @_;
1537
1538         my $rpcenv = PVE::RPCEnvironment::get();
1539
1540         my $authuser = $rpcenv->get_user();
1541
1542         my $vmid = $param->{vmid};
1543         my $node = $param->{node};
1544         my $websocket = $param->{websocket};
1545
1546         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1547         my $use_serial = ($conf->{vga} && ($conf->{vga} =~ m/^serial\d+$/));
1548
1549         my $authpath = "/vms/$vmid";
1550
1551         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1552
1553         $sslcert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192)
1554             if !$sslcert;
1555
1556         my $family;
1557         my $remcmd = [];
1558
1559         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1560             (undef, $family) = PVE::Cluster::remote_node_ip($node);
1561             my $sshinfo = PVE::SSHInfo::get_ssh_info($node);
1562             # NOTE: kvm VNC traffic is already TLS encrypted or is known unsecure
1563             $remcmd = PVE::SSHInfo::ssh_info_to_command($sshinfo, $use_serial ? '-t' : '-T');
1564         } else {
1565             $family = PVE::Tools::get_host_address_family($node);
1566         }
1567
1568         my $port = PVE::Tools::next_vnc_port($family);
1569
1570         my $timeout = 10;
1571
1572         my $realcmd = sub {
1573             my $upid = shift;
1574
1575             syslog('info', "starting vnc proxy $upid\n");
1576
1577             my $cmd;
1578
1579             if ($use_serial) {
1580
1581                 my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-iface', $conf->{vga}, '-escape', '0' ];
1582
1583                 $cmd = ['/usr/bin/vncterm', '-rfbport', $port,
1584                         '-timeout', $timeout, '-authpath', $authpath,
1585                         '-perm', 'Sys.Console'];
1586
1587                 if ($param->{websocket}) {
1588                     $ENV{PVE_VNC_TICKET} = $ticket; # pass ticket to vncterm
1589                     push @$cmd, '-notls', '-listen', 'localhost';
1590                 }
1591
1592                 push @$cmd, '-c', @$remcmd, @$termcmd;
1593
1594                 PVE::Tools::run_command($cmd);
1595
1596             } else {
1597
1598                 $ENV{LC_PVE_TICKET} = $ticket if $websocket; # set ticket with "qm vncproxy"
1599
1600                 $cmd = [@$remcmd, "/usr/sbin/qm", 'vncproxy', $vmid];
1601
1602                 my $sock = IO::Socket::IP->new(
1603                     ReuseAddr => 1,
1604                     Listen => 1,
1605                     LocalPort => $port,
1606                     Proto => 'tcp',
1607                     GetAddrInfoFlags => 0,
1608                     ) or die "failed to create socket: $!\n";
1609                 # Inside the worker we shouldn't have any previous alarms
1610                 # running anyway...:
1611                 alarm(0);
1612                 local $SIG{ALRM} = sub { die "connection timed out\n" };
1613                 alarm $timeout;
1614                 accept(my $cli, $sock) or die "connection failed: $!\n";
1615                 alarm(0);
1616                 close($sock);
1617                 if (PVE::Tools::run_command($cmd,
1618                     output => '>&'.fileno($cli),
1619                     input => '<&'.fileno($cli),
1620                     noerr => 1) != 0)
1621                 {
1622                     die "Failed to run vncproxy.\n";
1623                 }
1624             }
1625
1626             return;
1627         };
1628
1629         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1630
1631         PVE::Tools::wait_for_vnc_port($port);
1632
1633         return {
1634             user => $authuser,
1635             ticket => $ticket,
1636             port => $port,
1637             upid => $upid,
1638             cert => $sslcert,
1639         };
1640     }});
1641
1642 __PACKAGE__->register_method({
1643     name => 'termproxy',
1644     path => '{vmid}/termproxy',
1645     method => 'POST',
1646     protected => 1,
1647     permissions => {
1648         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1649     },
1650     description => "Creates a TCP proxy connections.",
1651     parameters => {
1652         additionalProperties => 0,
1653         properties => {
1654             node => get_standard_option('pve-node'),
1655             vmid => get_standard_option('pve-vmid'),
1656             serial=> {
1657                 optional => 1,
1658                 type => 'string',
1659                 enum => [qw(serial0 serial1 serial2 serial3)],
1660                 description => "opens a serial terminal (defaults to display)",
1661             },
1662         },
1663     },
1664     returns => {
1665         additionalProperties => 0,
1666         properties => {
1667             user => { type => 'string' },
1668             ticket => { type => 'string' },
1669             port => { type => 'integer' },
1670             upid => { type => 'string' },
1671         },
1672     },
1673     code => sub {
1674         my ($param) = @_;
1675
1676         my $rpcenv = PVE::RPCEnvironment::get();
1677
1678         my $authuser = $rpcenv->get_user();
1679
1680         my $vmid = $param->{vmid};
1681         my $node = $param->{node};
1682         my $serial = $param->{serial};
1683
1684         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1685
1686         if (!defined($serial)) {
1687             if ($conf->{vga} && $conf->{vga} =~ m/^serial\d+$/) {
1688                 $serial = $conf->{vga};
1689             }
1690         }
1691
1692         my $authpath = "/vms/$vmid";
1693
1694         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1695
1696         my $family;
1697         my $remcmd = [];
1698
1699         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1700             (undef, $family) = PVE::Cluster::remote_node_ip($node);
1701             my $sshinfo = PVE::SSHInfo::get_ssh_info($node);
1702             $remcmd = PVE::SSHInfo::ssh_info_to_command($sshinfo, '-t');
1703             push @$remcmd, '--';
1704         } else {
1705             $family = PVE::Tools::get_host_address_family($node);
1706         }
1707
1708         my $port = PVE::Tools::next_vnc_port($family);
1709
1710         my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-escape', '0'];
1711         push @$termcmd, '-iface', $serial if $serial;
1712
1713         my $realcmd = sub {
1714             my $upid = shift;
1715
1716             syslog('info', "starting qemu termproxy $upid\n");
1717
1718             my $cmd = ['/usr/bin/termproxy', $port, '--path', $authpath,
1719                        '--perm', 'VM.Console', '--'];
1720             push @$cmd, @$remcmd, @$termcmd;
1721
1722             PVE::Tools::run_command($cmd);
1723         };
1724
1725         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1726
1727         PVE::Tools::wait_for_vnc_port($port);
1728
1729         return {
1730             user => $authuser,
1731             ticket => $ticket,
1732             port => $port,
1733             upid => $upid,
1734         };
1735     }});
1736
1737 __PACKAGE__->register_method({
1738     name => 'vncwebsocket',
1739     path => '{vmid}/vncwebsocket',
1740     method => 'GET',
1741     permissions => {
1742         description => "You also need to pass a valid ticket (vncticket).",
1743         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1744     },
1745     description => "Opens a weksocket for VNC traffic.",
1746     parameters => {
1747         additionalProperties => 0,
1748         properties => {
1749             node => get_standard_option('pve-node'),
1750             vmid => get_standard_option('pve-vmid'),
1751             vncticket => {
1752                 description => "Ticket from previous call to vncproxy.",
1753                 type => 'string',
1754                 maxLength => 512,
1755             },
1756             port => {
1757                 description => "Port number returned by previous vncproxy call.",
1758                 type => 'integer',
1759                 minimum => 5900,
1760                 maximum => 5999,
1761             },
1762         },
1763     },
1764     returns => {
1765         type => "object",
1766         properties => {
1767             port => { type => 'string' },
1768         },
1769     },
1770     code => sub {
1771         my ($param) = @_;
1772
1773         my $rpcenv = PVE::RPCEnvironment::get();
1774
1775         my $authuser = $rpcenv->get_user();
1776
1777         my $vmid = $param->{vmid};
1778         my $node = $param->{node};
1779
1780         my $authpath = "/vms/$vmid";
1781
1782         PVE::AccessControl::verify_vnc_ticket($param->{vncticket}, $authuser, $authpath);
1783
1784         my $conf = PVE::QemuConfig->load_config($vmid, $node); # VM exists ?
1785
1786         # Note: VNC ports are acessible from outside, so we do not gain any
1787         # security if we verify that $param->{port} belongs to VM $vmid. This
1788         # check is done by verifying the VNC ticket (inside VNC protocol).
1789
1790         my $port = $param->{port};
1791
1792         return { port => $port };
1793     }});
1794
1795 __PACKAGE__->register_method({
1796     name => 'spiceproxy',
1797     path => '{vmid}/spiceproxy',
1798     method => 'POST',
1799     protected => 1,
1800     proxyto => 'node',
1801     permissions => {
1802         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1803     },
1804     description => "Returns a SPICE configuration to connect to the VM.",
1805     parameters => {
1806         additionalProperties => 0,
1807         properties => {
1808             node => get_standard_option('pve-node'),
1809             vmid => get_standard_option('pve-vmid'),
1810             proxy => get_standard_option('spice-proxy', { optional => 1 }),
1811         },
1812     },
1813     returns => get_standard_option('remote-viewer-config'),
1814     code => sub {
1815         my ($param) = @_;
1816
1817         my $rpcenv = PVE::RPCEnvironment::get();
1818
1819         my $authuser = $rpcenv->get_user();
1820
1821         my $vmid = $param->{vmid};
1822         my $node = $param->{node};
1823         my $proxy = $param->{proxy};
1824
1825         my $conf = PVE::QemuConfig->load_config($vmid, $node);
1826         my $title = "VM $vmid";
1827         $title .= " - ". $conf->{name} if $conf->{name};
1828
1829         my $port = PVE::QemuServer::spice_port($vmid);
1830
1831         my ($ticket, undef, $remote_viewer_config) =
1832             PVE::AccessControl::remote_viewer_config($authuser, $vmid, $node, $proxy, $title, $port);
1833
1834         mon_cmd($vmid, "set_password", protocol => 'spice', password => $ticket);
1835         mon_cmd($vmid, "expire_password", protocol => 'spice', time => "+30");
1836
1837         return $remote_viewer_config;
1838     }});
1839
1840 __PACKAGE__->register_method({
1841     name => 'vmcmdidx',
1842     path => '{vmid}/status',
1843     method => 'GET',
1844     proxyto => 'node',
1845     description => "Directory index",
1846     permissions => {
1847         user => 'all',
1848     },
1849     parameters => {
1850         additionalProperties => 0,
1851         properties => {
1852             node => get_standard_option('pve-node'),
1853             vmid => get_standard_option('pve-vmid'),
1854         },
1855     },
1856     returns => {
1857         type => 'array',
1858         items => {
1859             type => "object",
1860             properties => {
1861                 subdir => { type => 'string' },
1862             },
1863         },
1864         links => [ { rel => 'child', href => "{subdir}" } ],
1865     },
1866     code => sub {
1867         my ($param) = @_;
1868
1869         # test if VM exists
1870         my $conf = PVE::QemuConfig->load_config($param->{vmid});
1871
1872         my $res = [
1873             { subdir => 'current' },
1874             { subdir => 'start' },
1875             { subdir => 'stop' },
1876             { subdir => 'reset' },
1877             { subdir => 'shutdown' },
1878             { subdir => 'suspend' },
1879             { subdir => 'reboot' },
1880             ];
1881
1882         return $res;
1883     }});
1884
1885 __PACKAGE__->register_method({
1886     name => 'vm_status',
1887     path => '{vmid}/status/current',
1888     method => 'GET',
1889     proxyto => 'node',
1890     protected => 1, # qemu pid files are only readable by root
1891     description => "Get virtual machine status.",
1892     permissions => {
1893         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1894     },
1895     parameters => {
1896         additionalProperties => 0,
1897         properties => {
1898             node => get_standard_option('pve-node'),
1899             vmid => get_standard_option('pve-vmid'),
1900         },
1901     },
1902     returns => {
1903         type => 'object',
1904         properties => {
1905             %$PVE::QemuServer::vmstatus_return_properties,
1906             ha => {
1907                 description => "HA manager service status.",
1908                 type => 'object',
1909             },
1910             spice => {
1911                 description => "Qemu VGA configuration supports spice.",
1912                 type => 'boolean',
1913                 optional => 1,
1914             },
1915             agent => {
1916                 description => "Qemu GuestAgent enabled in config.",
1917                 type => 'boolean',
1918                 optional => 1,
1919             },
1920         },
1921     },
1922     code => sub {
1923         my ($param) = @_;
1924
1925         # test if VM exists
1926         my $conf = PVE::QemuConfig->load_config($param->{vmid});
1927
1928         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid}, 1);
1929         my $status = $vmstatus->{$param->{vmid}};
1930
1931         $status->{ha} = PVE::HA::Config::get_service_status("vm:$param->{vmid}");
1932
1933         $status->{spice} = 1 if PVE::QemuServer::vga_conf_has_spice($conf->{vga});
1934         $status->{agent} = 1 if (PVE::QemuServer::parse_guest_agent($conf)->{enabled});
1935
1936         return $status;
1937     }});
1938
1939 __PACKAGE__->register_method({
1940     name => 'vm_start',
1941     path => '{vmid}/status/start',
1942     method => 'POST',
1943     protected => 1,
1944     proxyto => 'node',
1945     description => "Start virtual machine.",
1946     permissions => {
1947         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
1948     },
1949     parameters => {
1950         additionalProperties => 0,
1951         properties => {
1952             node => get_standard_option('pve-node'),
1953             vmid => get_standard_option('pve-vmid',
1954                                         { completion => \&PVE::QemuServer::complete_vmid_stopped }),
1955             skiplock => get_standard_option('skiplock'),
1956             stateuri => get_standard_option('pve-qm-stateuri'),
1957             migratedfrom => get_standard_option('pve-node',{ optional => 1 }),
1958             migration_type => {
1959                 type => 'string',
1960                 enum => ['secure', 'insecure'],
1961                 description => "Migration traffic is encrypted using an SSH " .
1962                   "tunnel by default. On secure, completely private networks " .
1963                   "this can be disabled to increase performance.",
1964                 optional => 1,
1965             },
1966             migration_network => {
1967                 type => 'string', format => 'CIDR',
1968                 description => "CIDR of the (sub) network that is used for migration.",
1969                 optional => 1,
1970             },
1971             machine => get_standard_option('pve-qemu-machine'),
1972             targetstorage => {
1973                 description => "Target storage for the migration. (Can be '1' to use the same storage id as on the source node.)",
1974                 type => 'string',
1975                 optional => 1
1976             }
1977         },
1978     },
1979     returns => {
1980         type => 'string',
1981     },
1982     code => sub {
1983         my ($param) = @_;
1984
1985         my $rpcenv = PVE::RPCEnvironment::get();
1986         my $authuser = $rpcenv->get_user();
1987
1988         my $node = extract_param($param, 'node');
1989         my $vmid = extract_param($param, 'vmid');
1990
1991         my $machine = extract_param($param, 'machine');
1992
1993         my $get_root_param = sub {
1994             my $value = extract_param($param, $_[0]);
1995             raise_param_exc({ "$_[0]" => "Only root may use this option." })
1996                 if $value && $authuser ne 'root@pam';
1997             return $value;
1998         };
1999
2000         my $stateuri = $get_root_param->('stateuri');
2001         my $skiplock = $get_root_param->('skiplock');
2002         my $migratedfrom = $get_root_param->('migratedfrom');
2003         my $migration_type = $get_root_param->('migration_type');
2004         my $migration_network = $get_root_param->('migration_network');
2005         my $targetstorage = $get_root_param->('targetstorage');
2006
2007         raise_param_exc({ targetstorage => "targetstorage can only by used with migratedfrom." })
2008             if $targetstorage && !$migratedfrom;
2009
2010         # read spice ticket from STDIN
2011         my $spice_ticket;
2012         if ($stateuri && ($stateuri eq 'tcp' || $stateuri eq 'unix') && $migratedfrom && ($rpcenv->{type} eq 'cli')) {
2013             if (defined(my $line = <STDIN>)) {
2014                 chomp $line;
2015                 $spice_ticket = $line;
2016             }
2017         }
2018
2019         PVE::Cluster::check_cfs_quorum();
2020
2021         my $storecfg = PVE::Storage::config();
2022
2023         if (PVE::HA::Config::vm_is_ha_managed($vmid) && !$stateuri &&  $rpcenv->{type} ne 'ha') {
2024             my $hacmd = sub {
2025                 my $upid = shift;
2026
2027                 print "Requesting HA start for VM $vmid\n";
2028
2029                 my $cmd = ['ha-manager', 'set',  "vm:$vmid", '--state', 'started'];
2030                 PVE::Tools::run_command($cmd);
2031                 return;
2032             };
2033
2034             return $rpcenv->fork_worker('hastart', $vmid, $authuser, $hacmd);
2035
2036         } else {
2037
2038             my $realcmd = sub {
2039                 my $upid = shift;
2040
2041                 syslog('info', "start VM $vmid: $upid\n");
2042
2043                 PVE::QemuServer::vm_start($storecfg, $vmid, $stateuri, $skiplock, $migratedfrom, undef,
2044                                           $machine, $spice_ticket, $migration_network, $migration_type, $targetstorage);
2045                 return;
2046             };
2047
2048             return $rpcenv->fork_worker('qmstart', $vmid, $authuser, $realcmd);
2049         }
2050     }});
2051
2052 __PACKAGE__->register_method({
2053     name => 'vm_stop',
2054     path => '{vmid}/status/stop',
2055     method => 'POST',
2056     protected => 1,
2057     proxyto => 'node',
2058     description => "Stop virtual machine. The qemu process will exit immediately. This" .
2059         "is akin to pulling the power plug of a running computer and may damage the VM data",
2060     permissions => {
2061         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2062     },
2063     parameters => {
2064         additionalProperties => 0,
2065         properties => {
2066             node => get_standard_option('pve-node'),
2067             vmid => get_standard_option('pve-vmid',
2068                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2069             skiplock => get_standard_option('skiplock'),
2070             migratedfrom => get_standard_option('pve-node', { optional => 1 }),
2071             timeout => {
2072                 description => "Wait maximal timeout seconds.",
2073                 type => 'integer',
2074                 minimum => 0,
2075                 optional => 1,
2076             },
2077             keepActive => {
2078                 description => "Do not deactivate storage volumes.",
2079                 type => 'boolean',
2080                 optional => 1,
2081                 default => 0,
2082             }
2083         },
2084     },
2085     returns => {
2086         type => 'string',
2087     },
2088     code => sub {
2089         my ($param) = @_;
2090
2091         my $rpcenv = PVE::RPCEnvironment::get();
2092         my $authuser = $rpcenv->get_user();
2093
2094         my $node = extract_param($param, 'node');
2095         my $vmid = extract_param($param, 'vmid');
2096
2097         my $skiplock = extract_param($param, 'skiplock');
2098         raise_param_exc({ skiplock => "Only root may use this option." })
2099             if $skiplock && $authuser ne 'root@pam';
2100
2101         my $keepActive = extract_param($param, 'keepActive');
2102         raise_param_exc({ keepActive => "Only root may use this option." })
2103             if $keepActive && $authuser ne 'root@pam';
2104
2105         my $migratedfrom = extract_param($param, 'migratedfrom');
2106         raise_param_exc({ migratedfrom => "Only root may use this option." })
2107             if $migratedfrom && $authuser ne 'root@pam';
2108
2109
2110         my $storecfg = PVE::Storage::config();
2111
2112         if (PVE::HA::Config::vm_is_ha_managed($vmid) && ($rpcenv->{type} ne 'ha') && !defined($migratedfrom)) {
2113
2114             my $hacmd = sub {
2115                 my $upid = shift;
2116
2117                 print "Requesting HA stop for VM $vmid\n";
2118
2119                 my $cmd = ['ha-manager', 'crm-command', 'stop',  "vm:$vmid", '0'];
2120                 PVE::Tools::run_command($cmd);
2121                 return;
2122             };
2123
2124             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2125
2126         } else {
2127             my $realcmd = sub {
2128                 my $upid = shift;
2129
2130                 syslog('info', "stop VM $vmid: $upid\n");
2131
2132                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0,
2133                                          $param->{timeout}, 0, 1, $keepActive, $migratedfrom);
2134                 return;
2135             };
2136
2137             return $rpcenv->fork_worker('qmstop', $vmid, $authuser, $realcmd);
2138         }
2139     }});
2140
2141 __PACKAGE__->register_method({
2142     name => 'vm_reset',
2143     path => '{vmid}/status/reset',
2144     method => 'POST',
2145     protected => 1,
2146     proxyto => 'node',
2147     description => "Reset virtual machine.",
2148     permissions => {
2149         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2150     },
2151     parameters => {
2152         additionalProperties => 0,
2153         properties => {
2154             node => get_standard_option('pve-node'),
2155             vmid => get_standard_option('pve-vmid',
2156                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2157             skiplock => get_standard_option('skiplock'),
2158         },
2159     },
2160     returns => {
2161         type => 'string',
2162     },
2163     code => sub {
2164         my ($param) = @_;
2165
2166         my $rpcenv = PVE::RPCEnvironment::get();
2167
2168         my $authuser = $rpcenv->get_user();
2169
2170         my $node = extract_param($param, 'node');
2171
2172         my $vmid = extract_param($param, 'vmid');
2173
2174         my $skiplock = extract_param($param, 'skiplock');
2175         raise_param_exc({ skiplock => "Only root may use this option." })
2176             if $skiplock && $authuser ne 'root@pam';
2177
2178         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2179
2180         my $realcmd = sub {
2181             my $upid = shift;
2182
2183             PVE::QemuServer::vm_reset($vmid, $skiplock);
2184
2185             return;
2186         };
2187
2188         return $rpcenv->fork_worker('qmreset', $vmid, $authuser, $realcmd);
2189     }});
2190
2191 __PACKAGE__->register_method({
2192     name => 'vm_shutdown',
2193     path => '{vmid}/status/shutdown',
2194     method => 'POST',
2195     protected => 1,
2196     proxyto => 'node',
2197     description => "Shutdown virtual machine. This is similar to pressing the power button on a physical machine." .
2198         "This will send an ACPI event for the guest OS, which should then proceed to a clean shutdown.",
2199     permissions => {
2200         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2201     },
2202     parameters => {
2203         additionalProperties => 0,
2204         properties => {
2205             node => get_standard_option('pve-node'),
2206             vmid => get_standard_option('pve-vmid',
2207                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2208             skiplock => get_standard_option('skiplock'),
2209             timeout => {
2210                 description => "Wait maximal timeout seconds.",
2211                 type => 'integer',
2212                 minimum => 0,
2213                 optional => 1,
2214             },
2215             forceStop => {
2216                 description => "Make sure the VM stops.",
2217                 type => 'boolean',
2218                 optional => 1,
2219                 default => 0,
2220             },
2221             keepActive => {
2222                 description => "Do not deactivate storage volumes.",
2223                 type => 'boolean',
2224                 optional => 1,
2225                 default => 0,
2226             }
2227         },
2228     },
2229     returns => {
2230         type => 'string',
2231     },
2232     code => sub {
2233         my ($param) = @_;
2234
2235         my $rpcenv = PVE::RPCEnvironment::get();
2236         my $authuser = $rpcenv->get_user();
2237
2238         my $node = extract_param($param, 'node');
2239         my $vmid = extract_param($param, 'vmid');
2240
2241         my $skiplock = extract_param($param, 'skiplock');
2242         raise_param_exc({ skiplock => "Only root may use this option." })
2243             if $skiplock && $authuser ne 'root@pam';
2244
2245         my $keepActive = extract_param($param, 'keepActive');
2246         raise_param_exc({ keepActive => "Only root may use this option." })
2247             if $keepActive && $authuser ne 'root@pam';
2248
2249         my $storecfg = PVE::Storage::config();
2250
2251         my $shutdown = 1;
2252
2253         # if vm is paused, do not shutdown (but stop if forceStop = 1)
2254         # otherwise, we will infer a shutdown command, but run into the timeout,
2255         # then when the vm is resumed, it will instantly shutdown
2256         #
2257         # checking the qmp status here to get feedback to the gui/cli/api
2258         # and the status query should not take too long
2259         my $qmpstatus = eval {
2260             PVE::QemuConfig::assert_config_exists_on_node($vmid);
2261             mon_cmd($vmid, "query-status");
2262         };
2263         my $err = $@ if $@;
2264
2265         if (!$err && $qmpstatus->{status} eq "paused") {
2266             if ($param->{forceStop}) {
2267                 warn "VM is paused - stop instead of shutdown\n";
2268                 $shutdown = 0;
2269             } else {
2270                 die "VM is paused - cannot shutdown\n";
2271             }
2272         }
2273
2274         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
2275
2276             my $timeout = $param->{timeout} // 60;
2277             my $hacmd = sub {
2278                 my $upid = shift;
2279
2280                 print "Requesting HA stop for VM $vmid\n";
2281
2282                 my $cmd = ['ha-manager', 'crm-command', 'stop', "vm:$vmid", "$timeout"];
2283                 PVE::Tools::run_command($cmd);
2284                 return;
2285             };
2286
2287             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2288
2289         } else {
2290
2291             my $realcmd = sub {
2292                 my $upid = shift;
2293
2294                 syslog('info', "shutdown VM $vmid: $upid\n");
2295
2296                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0, $param->{timeout},
2297                                          $shutdown, $param->{forceStop}, $keepActive);
2298                 return;
2299             };
2300
2301             return $rpcenv->fork_worker('qmshutdown', $vmid, $authuser, $realcmd);
2302         }
2303     }});
2304
2305 __PACKAGE__->register_method({
2306     name => 'vm_reboot',
2307     path => '{vmid}/status/reboot',
2308     method => 'POST',
2309     protected => 1,
2310     proxyto => 'node',
2311     description => "Reboot the VM by shutting it down, and starting it again. Applies pending changes.",
2312     permissions => {
2313         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2314     },
2315     parameters => {
2316         additionalProperties => 0,
2317         properties => {
2318             node => get_standard_option('pve-node'),
2319             vmid => get_standard_option('pve-vmid',
2320                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2321             timeout => {
2322                 description => "Wait maximal timeout seconds for the shutdown.",
2323                 type => 'integer',
2324                 minimum => 0,
2325                 optional => 1,
2326             },
2327         },
2328     },
2329     returns => {
2330         type => 'string',
2331     },
2332     code => sub {
2333         my ($param) = @_;
2334
2335         my $rpcenv = PVE::RPCEnvironment::get();
2336         my $authuser = $rpcenv->get_user();
2337
2338         my $node = extract_param($param, 'node');
2339         my $vmid = extract_param($param, 'vmid');
2340
2341         my $qmpstatus = eval {
2342             PVE::QemuConfig::assert_config_exists_on_node($vmid);
2343             mon_cmd($vmid, "query-status");
2344         };
2345         my $err = $@ if $@;
2346
2347         if (!$err && $qmpstatus->{status} eq "paused") {
2348             die "VM is paused - cannot shutdown\n";
2349         }
2350
2351         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2352
2353         my $realcmd = sub {
2354             my $upid = shift;
2355
2356             syslog('info', "requesting reboot of VM $vmid: $upid\n");
2357             PVE::QemuServer::vm_reboot($vmid, $param->{timeout});
2358             return;
2359         };
2360
2361         return $rpcenv->fork_worker('qmreboot', $vmid, $authuser, $realcmd);
2362     }});
2363
2364 __PACKAGE__->register_method({
2365     name => 'vm_suspend',
2366     path => '{vmid}/status/suspend',
2367     method => 'POST',
2368     protected => 1,
2369     proxyto => 'node',
2370     description => "Suspend virtual machine.",
2371     permissions => {
2372         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2373     },
2374     parameters => {
2375         additionalProperties => 0,
2376         properties => {
2377             node => get_standard_option('pve-node'),
2378             vmid => get_standard_option('pve-vmid',
2379                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2380             skiplock => get_standard_option('skiplock'),
2381             todisk => {
2382                 type => 'boolean',
2383                 default => 0,
2384                 optional => 1,
2385                 description => 'If set, suspends the VM to disk. Will be resumed on next VM start.',
2386             },
2387             statestorage => get_standard_option('pve-storage-id', {
2388                 description => "The storage for the VM state",
2389                 requires => 'todisk',
2390                 optional => 1,
2391                 completion => \&PVE::Storage::complete_storage_enabled,
2392             }),
2393         },
2394     },
2395     returns => {
2396         type => 'string',
2397     },
2398     code => sub {
2399         my ($param) = @_;
2400
2401         my $rpcenv = PVE::RPCEnvironment::get();
2402         my $authuser = $rpcenv->get_user();
2403
2404         my $node = extract_param($param, 'node');
2405         my $vmid = extract_param($param, 'vmid');
2406
2407         my $todisk = extract_param($param, 'todisk') // 0;
2408
2409         my $statestorage = extract_param($param, 'statestorage');
2410
2411         my $skiplock = extract_param($param, 'skiplock');
2412         raise_param_exc({ skiplock => "Only root may use this option." })
2413             if $skiplock && $authuser ne 'root@pam';
2414
2415         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2416
2417         die "Cannot suspend HA managed VM to disk\n"
2418             if $todisk && PVE::HA::Config::vm_is_ha_managed($vmid);
2419
2420         my $realcmd = sub {
2421             my $upid = shift;
2422
2423             syslog('info', "suspend VM $vmid: $upid\n");
2424
2425             PVE::QemuServer::vm_suspend($vmid, $skiplock, $todisk, $statestorage);
2426
2427             return;
2428         };
2429
2430         my $taskname = $todisk ? 'qmsuspend' : 'qmpause';
2431         return $rpcenv->fork_worker($taskname, $vmid, $authuser, $realcmd);
2432     }});
2433
2434 __PACKAGE__->register_method({
2435     name => 'vm_resume',
2436     path => '{vmid}/status/resume',
2437     method => 'POST',
2438     protected => 1,
2439     proxyto => 'node',
2440     description => "Resume virtual machine.",
2441     permissions => {
2442         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2443     },
2444     parameters => {
2445         additionalProperties => 0,
2446         properties => {
2447             node => get_standard_option('pve-node'),
2448             vmid => get_standard_option('pve-vmid',
2449                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2450             skiplock => get_standard_option('skiplock'),
2451             nocheck => { type => 'boolean', optional => 1 },
2452
2453         },
2454     },
2455     returns => {
2456         type => 'string',
2457     },
2458     code => sub {
2459         my ($param) = @_;
2460
2461         my $rpcenv = PVE::RPCEnvironment::get();
2462
2463         my $authuser = $rpcenv->get_user();
2464
2465         my $node = extract_param($param, 'node');
2466
2467         my $vmid = extract_param($param, 'vmid');
2468
2469         my $skiplock = extract_param($param, 'skiplock');
2470         raise_param_exc({ skiplock => "Only root may use this option." })
2471             if $skiplock && $authuser ne 'root@pam';
2472
2473         my $nocheck = extract_param($param, 'nocheck');
2474
2475         my $to_disk_suspended;
2476         eval {
2477             PVE::QemuConfig->lock_config($vmid, sub {
2478                 my $conf = PVE::QemuConfig->load_config($vmid);
2479                 $to_disk_suspended = PVE::QemuConfig->has_lock($conf, 'suspended');
2480             });
2481         };
2482
2483         die "VM $vmid not running\n"
2484             if !$to_disk_suspended && !PVE::QemuServer::check_running($vmid, $nocheck);
2485
2486         my $realcmd = sub {
2487             my $upid = shift;
2488
2489             syslog('info', "resume VM $vmid: $upid\n");
2490
2491             if (!$to_disk_suspended) {
2492                 PVE::QemuServer::vm_resume($vmid, $skiplock, $nocheck);
2493             } else {
2494                 my $storecfg = PVE::Storage::config();
2495                 PVE::QemuServer::vm_start($storecfg, $vmid, undef, $skiplock);
2496             }
2497
2498             return;
2499         };
2500
2501         return $rpcenv->fork_worker('qmresume', $vmid, $authuser, $realcmd);
2502     }});
2503
2504 __PACKAGE__->register_method({
2505     name => 'vm_sendkey',
2506     path => '{vmid}/sendkey',
2507     method => 'PUT',
2508     protected => 1,
2509     proxyto => 'node',
2510     description => "Send key event to virtual machine.",
2511     permissions => {
2512         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
2513     },
2514     parameters => {
2515         additionalProperties => 0,
2516         properties => {
2517             node => get_standard_option('pve-node'),
2518             vmid => get_standard_option('pve-vmid',
2519                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2520             skiplock => get_standard_option('skiplock'),
2521             key => {
2522                 description => "The key (qemu monitor encoding).",
2523                 type => 'string'
2524             }
2525         },
2526     },
2527     returns => { type => 'null'},
2528     code => sub {
2529         my ($param) = @_;
2530
2531         my $rpcenv = PVE::RPCEnvironment::get();
2532
2533         my $authuser = $rpcenv->get_user();
2534
2535         my $node = extract_param($param, 'node');
2536
2537         my $vmid = extract_param($param, 'vmid');
2538
2539         my $skiplock = extract_param($param, 'skiplock');
2540         raise_param_exc({ skiplock => "Only root may use this option." })
2541             if $skiplock && $authuser ne 'root@pam';
2542
2543         PVE::QemuServer::vm_sendkey($vmid, $skiplock, $param->{key});
2544
2545         return;
2546     }});
2547
2548 __PACKAGE__->register_method({
2549     name => 'vm_feature',
2550     path => '{vmid}/feature',
2551     method => 'GET',
2552     proxyto => 'node',
2553     protected => 1,
2554     description => "Check if feature for virtual machine is available.",
2555     permissions => {
2556         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
2557     },
2558     parameters => {
2559         additionalProperties => 0,
2560         properties => {
2561             node => get_standard_option('pve-node'),
2562             vmid => get_standard_option('pve-vmid'),
2563             feature => {
2564                 description => "Feature to check.",
2565                 type => 'string',
2566                 enum => [ 'snapshot', 'clone', 'copy' ],
2567             },
2568             snapname => get_standard_option('pve-snapshot-name', {
2569                 optional => 1,
2570             }),
2571         },
2572     },
2573     returns => {
2574         type => "object",
2575         properties => {
2576             hasFeature => { type => 'boolean' },
2577             nodes => {
2578                 type => 'array',
2579                 items => { type => 'string' },
2580             }
2581         },
2582     },
2583     code => sub {
2584         my ($param) = @_;
2585
2586         my $node = extract_param($param, 'node');
2587
2588         my $vmid = extract_param($param, 'vmid');
2589
2590         my $snapname = extract_param($param, 'snapname');
2591
2592         my $feature = extract_param($param, 'feature');
2593
2594         my $running = PVE::QemuServer::check_running($vmid);
2595
2596         my $conf = PVE::QemuConfig->load_config($vmid);
2597
2598         if($snapname){
2599             my $snap = $conf->{snapshots}->{$snapname};
2600             die "snapshot '$snapname' does not exist\n" if !defined($snap);
2601             $conf = $snap;
2602         }
2603         my $storecfg = PVE::Storage::config();
2604
2605         my $nodelist = PVE::QemuServer::shared_nodes($conf, $storecfg);
2606         my $hasFeature = PVE::QemuConfig->has_feature($feature, $conf, $storecfg, $snapname, $running);
2607
2608         return {
2609             hasFeature => $hasFeature,
2610             nodes => [ keys %$nodelist ],
2611         };
2612     }});
2613
2614 __PACKAGE__->register_method({
2615     name => 'clone_vm',
2616     path => '{vmid}/clone',
2617     method => 'POST',
2618     protected => 1,
2619     proxyto => 'node',
2620     description => "Create a copy of virtual machine/template.",
2621     permissions => {
2622         description => "You need 'VM.Clone' permissions on /vms/{vmid}, and 'VM.Allocate' permissions " .
2623             "on /vms/{newid} (or on the VM pool /pool/{pool}). You also need " .
2624             "'Datastore.AllocateSpace' on any used storage.",
2625         check =>
2626         [ 'and',
2627           ['perm', '/vms/{vmid}', [ 'VM.Clone' ]],
2628           [ 'or',
2629             [ 'perm', '/vms/{newid}', ['VM.Allocate']],
2630             [ 'perm', '/pool/{pool}', ['VM.Allocate'], require_param => 'pool'],
2631           ],
2632         ]
2633     },
2634     parameters => {
2635         additionalProperties => 0,
2636         properties => {
2637             node => get_standard_option('pve-node'),
2638             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
2639             newid => get_standard_option('pve-vmid', {
2640                 completion => \&PVE::Cluster::complete_next_vmid,
2641                 description => 'VMID for the clone.' }),
2642             name => {
2643                 optional => 1,
2644                 type => 'string', format => 'dns-name',
2645                 description => "Set a name for the new VM.",
2646             },
2647             description => {
2648                 optional => 1,
2649                 type => 'string',
2650                 description => "Description for the new VM.",
2651             },
2652             pool => {
2653                 optional => 1,
2654                 type => 'string', format => 'pve-poolid',
2655                 description => "Add the new VM to the specified pool.",
2656             },
2657             snapname => get_standard_option('pve-snapshot-name', {
2658                 optional => 1,
2659             }),
2660             storage => get_standard_option('pve-storage-id', {
2661                 description => "Target storage for full clone.",
2662                 optional => 1,
2663             }),
2664             'format' => {
2665                 description => "Target format for file storage. Only valid for full clone.",
2666                 type => 'string',
2667                 optional => 1,
2668                 enum => [ 'raw', 'qcow2', 'vmdk'],
2669             },
2670             full => {
2671                 optional => 1,
2672                 type => 'boolean',
2673                 description => "Create a full copy of all disks. This is always done when " .
2674                     "you clone a normal VM. For VM templates, we try to create a linked clone by default.",
2675             },
2676             target => get_standard_option('pve-node', {
2677                 description => "Target node. Only allowed if the original VM is on shared storage.",
2678                 optional => 1,
2679             }),
2680             bwlimit => {
2681                 description => "Override I/O bandwidth limit (in KiB/s).",
2682                 optional => 1,
2683                 type => 'integer',
2684                 minimum => '0',
2685                 default => 'clone limit from datacenter or storage config',
2686             },
2687         },
2688     },
2689     returns => {
2690         type => 'string',
2691     },
2692     code => sub {
2693         my ($param) = @_;
2694
2695         my $rpcenv = PVE::RPCEnvironment::get();
2696
2697         my $authuser = $rpcenv->get_user();
2698
2699         my $node = extract_param($param, 'node');
2700
2701         my $vmid = extract_param($param, 'vmid');
2702
2703         my $newid = extract_param($param, 'newid');
2704
2705         my $pool = extract_param($param, 'pool');
2706
2707         if (defined($pool)) {
2708             $rpcenv->check_pool_exist($pool);
2709         }
2710
2711         my $snapname = extract_param($param, 'snapname');
2712
2713         my $storage = extract_param($param, 'storage');
2714
2715         my $format = extract_param($param, 'format');
2716
2717         my $target = extract_param($param, 'target');
2718
2719         my $localnode = PVE::INotify::nodename();
2720
2721         undef $target if $target && ($target eq $localnode || $target eq 'localhost');
2722
2723         PVE::Cluster::check_node_exists($target) if $target;
2724
2725         my $storecfg = PVE::Storage::config();
2726
2727         if ($storage) {
2728             # check if storage is enabled on local node
2729             PVE::Storage::storage_check_enabled($storecfg, $storage);
2730             if ($target) {
2731                 # check if storage is available on target node
2732                 PVE::Storage::storage_check_node($storecfg, $storage, $target);
2733                 # clone only works if target storage is shared
2734                 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2735                 die "can't clone to non-shared storage '$storage'\n" if !$scfg->{shared};
2736             }
2737         }
2738
2739         PVE::Cluster::check_cfs_quorum();
2740
2741         my $running = PVE::QemuServer::check_running($vmid) || 0;
2742
2743         # exclusive lock if VM is running - else shared lock is enough;
2744         my $shared_lock = $running ? 0 : 1;
2745
2746         my $clonefn = sub {
2747
2748             # do all tests after lock
2749             # we also try to do all tests before we fork the worker
2750
2751             my $conf = PVE::QemuConfig->load_config($vmid);
2752
2753             PVE::QemuConfig->check_lock($conf);
2754
2755             my $verify_running = PVE::QemuServer::check_running($vmid) || 0;
2756
2757             die "unexpected state change\n" if $verify_running != $running;
2758
2759             die "snapshot '$snapname' does not exist\n"
2760                 if $snapname && !defined( $conf->{snapshots}->{$snapname});
2761
2762             my $full = extract_param($param, 'full');
2763             if (!defined($full)) {
2764                 $full = !PVE::QemuConfig->is_template($conf);
2765             }
2766
2767             die "parameter 'storage' not allowed for linked clones\n"
2768                 if defined($storage) && !$full;
2769
2770             die "parameter 'format' not allowed for linked clones\n"
2771                 if defined($format) && !$full;
2772
2773             my $oldconf = $snapname ? $conf->{snapshots}->{$snapname} : $conf;
2774
2775             my $sharedvm = &$check_storage_access_clone($rpcenv, $authuser, $storecfg, $oldconf, $storage);
2776
2777             die "can't clone VM to node '$target' (VM uses local storage)\n" if $target && !$sharedvm;
2778
2779             my $conffile = PVE::QemuConfig->config_file($newid);
2780
2781             die "unable to create VM $newid: config file already exists\n"
2782                 if -f $conffile;
2783
2784             my $newconf = { lock => 'clone' };
2785             my $drives = {};
2786             my $fullclone = {};
2787             my $vollist = [];
2788
2789             foreach my $opt (keys %$oldconf) {
2790                 my $value = $oldconf->{$opt};
2791
2792                 # do not copy snapshot related info
2793                 next if $opt eq 'snapshots' ||  $opt eq 'parent' || $opt eq 'snaptime' ||
2794                     $opt eq 'vmstate' || $opt eq 'snapstate';
2795
2796                 # no need to copy unused images, because VMID(owner) changes anyways
2797                 next if $opt =~ m/^unused\d+$/;
2798
2799                 # always change MAC! address
2800                 if ($opt =~ m/^net(\d+)$/) {
2801                     my $net = PVE::QemuServer::parse_net($value);
2802                     my $dc = PVE::Cluster::cfs_read_file('datacenter.cfg');
2803                     $net->{macaddr} =  PVE::Tools::random_ether_addr($dc->{mac_prefix});
2804                     $newconf->{$opt} = PVE::QemuServer::print_net($net);
2805                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
2806                     my $drive = PVE::QemuServer::parse_drive($opt, $value);
2807                     die "unable to parse drive options for '$opt'\n" if !$drive;
2808                     if (PVE::QemuServer::drive_is_cdrom($drive, 1)) {
2809                         $newconf->{$opt} = $value; # simply copy configuration
2810                     } else {
2811                         if ($full || PVE::QemuServer::drive_is_cloudinit($drive)) {
2812                             die "Full clone feature is not supported for drive '$opt'\n"
2813                                 if !PVE::Storage::volume_has_feature($storecfg, 'copy', $drive->{file}, $snapname, $running);
2814                             $fullclone->{$opt} = 1;
2815                         } else {
2816                             # not full means clone instead of copy
2817                             die "Linked clone feature is not supported for drive '$opt'\n"
2818                                 if !PVE::Storage::volume_has_feature($storecfg, 'clone', $drive->{file}, $snapname, $running);
2819                         }
2820                         $drives->{$opt} = $drive;
2821                         push @$vollist, $drive->{file};
2822                     }
2823                 } else {
2824                     # copy everything else
2825                     $newconf->{$opt} = $value;
2826                 }
2827             }
2828
2829             # auto generate a new uuid
2830             my $smbios1 = PVE::QemuServer::parse_smbios1($newconf->{smbios1} || '');
2831             $smbios1->{uuid} = PVE::QemuServer::generate_uuid();
2832             $newconf->{smbios1} = PVE::QemuServer::print_smbios1($smbios1);
2833
2834             # auto generate a new vmgenid if the option was set
2835             if ($newconf->{vmgenid}) {
2836                 $newconf->{vmgenid} = PVE::QemuServer::generate_uuid();
2837             }
2838
2839             delete $newconf->{template};
2840
2841             if ($param->{name}) {
2842                 $newconf->{name} = $param->{name};
2843             } else {
2844                 if ($oldconf->{name}) {
2845                     $newconf->{name} = "Copy-of-$oldconf->{name}";
2846                 } else {
2847                     $newconf->{name} = "Copy-of-VM-$vmid";
2848                 }
2849             }
2850
2851             if ($param->{description}) {
2852                 $newconf->{description} = $param->{description};
2853             }
2854
2855             # create empty/temp config - this fails if VM already exists on other node
2856             PVE::Tools::file_set_contents($conffile, "# qmclone temporary file\nlock: clone\n");
2857
2858             my $realcmd = sub {
2859                 my $upid = shift;
2860
2861                 my $newvollist = [];
2862                 my $jobs = {};
2863
2864                 eval {
2865                     local $SIG{INT} =
2866                         local $SIG{TERM} =
2867                         local $SIG{QUIT} =
2868                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
2869
2870                     PVE::Storage::activate_volumes($storecfg, $vollist, $snapname);
2871
2872                     my $bwlimit = extract_param($param, 'bwlimit');
2873
2874                     my $total_jobs = scalar(keys %{$drives});
2875                     my $i = 1;
2876
2877                     foreach my $opt (keys %$drives) {
2878                         my $drive = $drives->{$opt};
2879                         my $skipcomplete = ($total_jobs != $i); # finish after last drive
2880
2881                         my $src_sid = PVE::Storage::parse_volume_id($drive->{file});
2882                         my $storage_list = [ $src_sid ];
2883                         push @$storage_list, $storage if defined($storage);
2884                         my $clonelimit = PVE::Storage::get_bandwidth_limit('clone', $storage_list, $bwlimit);
2885
2886                         my $newdrive = PVE::QemuServer::clone_disk($storecfg, $vmid, $running, $opt, $drive, $snapname,
2887                                                                    $newid, $storage, $format, $fullclone->{$opt}, $newvollist,
2888                                                                    $jobs, $skipcomplete, $oldconf->{agent}, $clonelimit);
2889
2890                         $newconf->{$opt} = PVE::QemuServer::print_drive($vmid, $newdrive);
2891
2892                         PVE::QemuConfig->write_config($newid, $newconf);
2893                         $i++;
2894                     }
2895
2896                     delete $newconf->{lock};
2897
2898                     # do not write pending changes
2899                     if (my @changes = keys %{$newconf->{pending}}) {
2900                         my $pending = join(',', @changes);
2901                         warn "found pending changes for '$pending', discarding for clone\n";
2902                         delete $newconf->{pending};
2903                     }
2904
2905                     PVE::QemuConfig->write_config($newid, $newconf);
2906
2907                     if ($target) {
2908                         # always deactivate volumes - avoid lvm LVs to be active on several nodes
2909                         PVE::Storage::deactivate_volumes($storecfg, $vollist, $snapname) if !$running;
2910                         PVE::Storage::deactivate_volumes($storecfg, $newvollist);
2911
2912                         my $newconffile = PVE::QemuConfig->config_file($newid, $target);
2913                         die "Failed to move config to node '$target' - rename failed: $!\n"
2914                             if !rename($conffile, $newconffile);
2915                     }
2916
2917                     PVE::AccessControl::add_vm_to_pool($newid, $pool) if $pool;
2918                 };
2919                 if (my $err = $@) {
2920                     unlink $conffile;
2921
2922                     eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $jobs) };
2923
2924                     sleep 1; # some storage like rbd need to wait before release volume - really?
2925
2926                     foreach my $volid (@$newvollist) {
2927                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2928                         warn $@ if $@;
2929                     }
2930                     die "clone failed: $err";
2931                 }
2932
2933                 return;
2934             };
2935
2936             PVE::Firewall::clone_vmfw_conf($vmid, $newid);
2937
2938             return $rpcenv->fork_worker('qmclone', $vmid, $authuser, $realcmd);
2939         };
2940
2941         return PVE::QemuConfig->lock_config_mode($vmid, 1, $shared_lock, sub {
2942             # Aquire exclusive lock lock for $newid
2943             return PVE::QemuConfig->lock_config_full($newid, 1, $clonefn);
2944         });
2945
2946     }});
2947
2948 __PACKAGE__->register_method({
2949     name => 'move_vm_disk',
2950     path => '{vmid}/move_disk',
2951     method => 'POST',
2952     protected => 1,
2953     proxyto => 'node',
2954     description => "Move volume to different storage.",
2955     permissions => {
2956         description => "You need 'VM.Config.Disk' permissions on /vms/{vmid}, and 'Datastore.AllocateSpace' permissions on the storage.",
2957         check => [ 'and',
2958                    ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
2959                    ['perm', '/storage/{storage}', [ 'Datastore.AllocateSpace' ]],
2960             ],
2961     },
2962     parameters => {
2963         additionalProperties => 0,
2964         properties => {
2965             node => get_standard_option('pve-node'),
2966             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
2967             disk => {
2968                 type => 'string',
2969                 description => "The disk you want to move.",
2970                 enum => [ PVE::QemuServer::valid_drive_names() ],
2971             },
2972             storage => get_standard_option('pve-storage-id', {
2973                 description => "Target storage.",
2974                 completion => \&PVE::QemuServer::complete_storage,
2975             }),
2976             'format' => {
2977                 type => 'string',
2978                 description => "Target Format.",
2979                 enum => [ 'raw', 'qcow2', 'vmdk' ],
2980                 optional => 1,
2981             },
2982             delete => {
2983                 type => 'boolean',
2984                 description => "Delete the original disk after successful copy. By default the original disk is kept as unused disk.",
2985                 optional => 1,
2986                 default => 0,
2987             },
2988             digest => {
2989                 type => 'string',
2990                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
2991                 maxLength => 40,
2992                 optional => 1,
2993             },
2994             bwlimit => {
2995                 description => "Override I/O bandwidth limit (in KiB/s).",
2996                 optional => 1,
2997                 type => 'integer',
2998                 minimum => '0',
2999                 default => 'move limit from datacenter or storage config',
3000             },
3001         },
3002     },
3003     returns => {
3004         type => 'string',
3005         description => "the task ID.",
3006     },
3007     code => sub {
3008         my ($param) = @_;
3009
3010         my $rpcenv = PVE::RPCEnvironment::get();
3011
3012         my $authuser = $rpcenv->get_user();
3013
3014         my $node = extract_param($param, 'node');
3015
3016         my $vmid = extract_param($param, 'vmid');
3017
3018         my $digest = extract_param($param, 'digest');
3019
3020         my $disk = extract_param($param, 'disk');
3021
3022         my $storeid = extract_param($param, 'storage');
3023
3024         my $format = extract_param($param, 'format');
3025
3026         my $storecfg = PVE::Storage::config();
3027
3028         my $updatefn =  sub {
3029
3030             my $conf = PVE::QemuConfig->load_config($vmid);
3031
3032             PVE::QemuConfig->check_lock($conf);
3033
3034             die "checksum missmatch (file change by other user?)\n"
3035                 if $digest && $digest ne $conf->{digest};
3036
3037             die "disk '$disk' does not exist\n" if !$conf->{$disk};
3038
3039             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
3040
3041             my $old_volid = $drive->{file} || die "disk '$disk' has no associated volume\n";
3042
3043             die "you can't move a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive, 1);
3044
3045             my $oldfmt;
3046             my ($oldstoreid, $oldvolname) = PVE::Storage::parse_volume_id($old_volid);
3047             if ($oldvolname =~ m/\.(raw|qcow2|vmdk)$/){
3048                 $oldfmt = $1;
3049             }
3050
3051             die "you can't move on the same storage with same format\n" if $oldstoreid eq $storeid &&
3052                 (!$format || !$oldfmt || $oldfmt eq $format);
3053
3054             # this only checks snapshots because $disk is passed!
3055             my $snapshotted = PVE::QemuServer::is_volume_in_use($storecfg, $conf, $disk, $old_volid);
3056             die "you can't move a disk with snapshots and delete the source\n"
3057                 if $snapshotted && $param->{delete};
3058
3059             PVE::Cluster::log_msg('info', $authuser, "move disk VM $vmid: move --disk $disk --storage $storeid");
3060
3061             my $running = PVE::QemuServer::check_running($vmid);
3062
3063             PVE::Storage::activate_volumes($storecfg, [ $drive->{file} ]);
3064
3065             my $realcmd = sub {
3066
3067                 my $newvollist = [];
3068
3069                 eval {
3070                     local $SIG{INT} =
3071                         local $SIG{TERM} =
3072                         local $SIG{QUIT} =
3073                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
3074
3075                     warn "moving disk with snapshots, snapshots will not be moved!\n"
3076                         if $snapshotted;
3077
3078                     my $bwlimit = extract_param($param, 'bwlimit');
3079                     my $movelimit = PVE::Storage::get_bandwidth_limit('move', [$oldstoreid, $storeid], $bwlimit);
3080
3081                     my $newdrive = PVE::QemuServer::clone_disk($storecfg, $vmid, $running, $disk, $drive, undef,
3082                                                                $vmid, $storeid, $format, 1, $newvollist, undef, undef, undef, $movelimit);
3083
3084                     $conf->{$disk} = PVE::QemuServer::print_drive($vmid, $newdrive);
3085
3086                     PVE::QemuConfig->add_unused_volume($conf, $old_volid) if !$param->{delete};
3087
3088                     # convert moved disk to base if part of template
3089                     PVE::QemuServer::template_create($vmid, $conf, $disk)
3090                         if PVE::QemuConfig->is_template($conf);
3091
3092                     PVE::QemuConfig->write_config($vmid, $conf);
3093
3094                     if ($running && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && PVE::QemuServer::qga_check_running($vmid)) {
3095                         eval { mon_cmd($vmid, "guest-fstrim"); };
3096                     }
3097
3098                     eval {
3099                         # try to deactivate volumes - avoid lvm LVs to be active on several nodes
3100                         PVE::Storage::deactivate_volumes($storecfg, [ $newdrive->{file} ])
3101                             if !$running;
3102                     };
3103                     warn $@ if $@;
3104                 };
3105                 if (my $err = $@) {
3106
3107                    foreach my $volid (@$newvollist) {
3108                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
3109                         warn $@ if $@;
3110                     }
3111                     die "storage migration failed: $err";
3112                 }
3113
3114                 if ($param->{delete}) {
3115                     eval {
3116                         PVE::Storage::deactivate_volumes($storecfg, [$old_volid]);
3117                         PVE::Storage::vdisk_free($storecfg, $old_volid);
3118                     };
3119                     warn $@ if $@;
3120                 }
3121             };
3122
3123             return $rpcenv->fork_worker('qmmove', $vmid, $authuser, $realcmd);
3124         };
3125
3126         return PVE::QemuConfig->lock_config($vmid, $updatefn);
3127     }});
3128
3129 my $check_vm_disks_local = sub {
3130     my ($storecfg, $vmconf, $vmid) = @_;
3131
3132     my $local_disks = {};
3133
3134     # add some more information to the disks e.g. cdrom
3135     PVE::QemuServer::foreach_volid($vmconf, sub {
3136         my ($volid, $attr) = @_;
3137
3138         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
3139         if ($storeid) {
3140             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
3141             return if $scfg->{shared};
3142         }
3143         # The shared attr here is just a special case where the vdisk
3144         # is marked as shared manually
3145         return if $attr->{shared};
3146         return if $attr->{cdrom} and $volid eq "none";
3147
3148         if (exists $local_disks->{$volid}) {
3149             @{$local_disks->{$volid}}{keys %$attr} = values %$attr
3150         } else {
3151             $local_disks->{$volid} = $attr;
3152             # ensure volid is present in case it's needed
3153             $local_disks->{$volid}->{volid} = $volid;
3154         }
3155     });
3156
3157     return $local_disks;
3158 };
3159
3160 __PACKAGE__->register_method({
3161     name => 'migrate_vm_precondition',
3162     path => '{vmid}/migrate',
3163     method => 'GET',
3164     protected => 1,
3165     proxyto => 'node',
3166     description => "Get preconditions for migration.",
3167     permissions => {
3168         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
3169     },
3170     parameters => {
3171         additionalProperties => 0,
3172         properties => {
3173             node => get_standard_option('pve-node'),
3174             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3175             target => get_standard_option('pve-node', {
3176                 description => "Target node.",
3177                 completion =>  \&PVE::Cluster::complete_migration_target,
3178                 optional => 1,
3179             }),
3180         },
3181     },
3182     returns => {
3183         type => "object",
3184         properties => {
3185             running => { type => 'boolean' },
3186             allowed_nodes => {
3187                 type => 'array',
3188                 optional => 1,
3189                 description => "List nodes allowed for offline migration, only passed if VM is offline"
3190             },
3191             not_allowed_nodes => {
3192                 type => 'object',
3193                 optional => 1,
3194                 description => "List not allowed nodes with additional informations, only passed if VM is offline"
3195             },
3196             local_disks => {
3197                 type => 'array',
3198                 description => "List local disks including CD-Rom, unsused and not referenced disks"
3199             },
3200             local_resources => {
3201                 type => 'array',
3202                 description => "List local resources e.g. pci, usb"
3203             }
3204         },
3205     },
3206     code => sub {
3207         my ($param) = @_;
3208
3209         my $rpcenv = PVE::RPCEnvironment::get();
3210
3211         my $authuser = $rpcenv->get_user();
3212
3213         PVE::Cluster::check_cfs_quorum();
3214
3215         my $res = {};
3216
3217         my $vmid = extract_param($param, 'vmid');
3218         my $target = extract_param($param, 'target');
3219         my $localnode = PVE::INotify::nodename();
3220
3221
3222         # test if VM exists
3223         my $vmconf = PVE::QemuConfig->load_config($vmid);
3224         my $storecfg = PVE::Storage::config();
3225
3226
3227         # try to detect errors early
3228         PVE::QemuConfig->check_lock($vmconf);
3229
3230         $res->{running} = PVE::QemuServer::check_running($vmid) ? 1:0;
3231
3232         # if vm is not running, return target nodes where local storage is available
3233         # for offline migration
3234         if (!$res->{running}) {
3235             $res->{allowed_nodes} = [];
3236             my $checked_nodes = PVE::QemuServer::check_local_storage_availability($vmconf, $storecfg);
3237             delete $checked_nodes->{$localnode};
3238
3239             foreach my $node (keys %$checked_nodes) {
3240                 if (!defined $checked_nodes->{$node}->{unavailable_storages}) {
3241                     push @{$res->{allowed_nodes}}, $node;
3242                 }
3243
3244             }
3245             $res->{not_allowed_nodes} = $checked_nodes;
3246         }
3247
3248
3249         my $local_disks = &$check_vm_disks_local($storecfg, $vmconf, $vmid);
3250         $res->{local_disks} = [ values %$local_disks ];;
3251
3252         my $local_resources =  PVE::QemuServer::check_local_resources($vmconf, 1);
3253
3254         $res->{local_resources} = $local_resources;
3255
3256         return $res;
3257
3258
3259     }});
3260
3261 __PACKAGE__->register_method({
3262     name => 'migrate_vm',
3263     path => '{vmid}/migrate',
3264     method => 'POST',
3265     protected => 1,
3266     proxyto => 'node',
3267     description => "Migrate virtual machine. Creates a new migration task.",
3268     permissions => {
3269         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
3270     },
3271     parameters => {
3272         additionalProperties => 0,
3273         properties => {
3274             node => get_standard_option('pve-node'),
3275             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3276             target => get_standard_option('pve-node', {
3277                 description => "Target node.",
3278                 completion =>  \&PVE::Cluster::complete_migration_target,
3279             }),
3280             online => {
3281                 type => 'boolean',
3282                 description => "Use online/live migration if VM is running. Ignored if VM is stopped.",
3283                 optional => 1,
3284             },
3285             force => {
3286                 type => 'boolean',
3287                 description => "Allow to migrate VMs which use local devices. Only root may use this option.",
3288                 optional => 1,
3289             },
3290             migration_type => {
3291                 type => 'string',
3292                 enum => ['secure', 'insecure'],
3293                 description => "Migration traffic is encrypted using an SSH tunnel by default. On secure, completely private networks this can be disabled to increase performance.",
3294                 optional => 1,
3295             },
3296             migration_network => {
3297                 type => 'string', format => 'CIDR',
3298                 description => "CIDR of the (sub) network that is used for migration.",
3299                 optional => 1,
3300             },
3301             "with-local-disks" => {
3302                 type => 'boolean',
3303                 description => "Enable live storage migration for local disk",
3304                 optional => 1,
3305             },
3306             targetstorage => get_standard_option('pve-storage-id', {
3307                 description => "Default target storage.",
3308                 optional => 1,
3309                 completion => \&PVE::QemuServer::complete_migration_storage,
3310             }),
3311             bwlimit => {
3312                 description => "Override I/O bandwidth limit (in KiB/s).",
3313                 optional => 1,
3314                 type => 'integer',
3315                 minimum => '0',
3316                 default => 'migrate limit from datacenter or storage config',
3317             },
3318         },
3319     },
3320     returns => {
3321         type => 'string',
3322         description => "the task ID.",
3323     },
3324     code => sub {
3325         my ($param) = @_;
3326
3327         my $rpcenv = PVE::RPCEnvironment::get();
3328         my $authuser = $rpcenv->get_user();
3329
3330         my $target = extract_param($param, 'target');
3331
3332         my $localnode = PVE::INotify::nodename();
3333         raise_param_exc({ target => "target is local node."}) if $target eq $localnode;
3334
3335         PVE::Cluster::check_cfs_quorum();
3336
3337         PVE::Cluster::check_node_exists($target);
3338
3339         my $targetip = PVE::Cluster::remote_node_ip($target);
3340
3341         my $vmid = extract_param($param, 'vmid');
3342
3343         raise_param_exc({ force => "Only root may use this option." })
3344             if $param->{force} && $authuser ne 'root@pam';
3345
3346         raise_param_exc({ migration_type => "Only root may use this option." })
3347             if $param->{migration_type} && $authuser ne 'root@pam';
3348
3349         # allow root only until better network permissions are available
3350         raise_param_exc({ migration_network => "Only root may use this option." })
3351             if $param->{migration_network} && $authuser ne 'root@pam';
3352
3353         # test if VM exists
3354         my $conf = PVE::QemuConfig->load_config($vmid);
3355
3356         # try to detect errors early
3357
3358         PVE::QemuConfig->check_lock($conf);
3359
3360         if (PVE::QemuServer::check_running($vmid)) {
3361             die "can't migrate running VM without --online\n" if !$param->{online};
3362         } else {
3363             warn "VM isn't running. Doing offline migration instead\n." if $param->{online};
3364             $param->{online} = 0;
3365         }
3366
3367         raise_param_exc({ targetstorage => "Live storage migration can only be done online." })
3368             if !$param->{online} && $param->{targetstorage};
3369
3370         my $storecfg = PVE::Storage::config();
3371
3372         if( $param->{targetstorage}) {
3373             PVE::Storage::storage_check_node($storecfg, $param->{targetstorage}, $target);
3374         } else {
3375             PVE::QemuServer::check_storage_availability($storecfg, $conf, $target);
3376         }
3377
3378         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
3379
3380             my $hacmd = sub {
3381                 my $upid = shift;
3382
3383                 print "Requesting HA migration for VM $vmid to node $target\n";
3384
3385                 my $cmd = ['ha-manager', 'migrate', "vm:$vmid", $target];
3386                 PVE::Tools::run_command($cmd);
3387                 return;
3388             };
3389
3390             return $rpcenv->fork_worker('hamigrate', $vmid, $authuser, $hacmd);
3391
3392         } else {
3393
3394             my $realcmd = sub {
3395                 PVE::QemuMigrate->migrate($target, $targetip, $vmid, $param);
3396             };
3397
3398             my $worker = sub {
3399                 return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
3400             };
3401
3402             return $rpcenv->fork_worker('qmigrate', $vmid, $authuser, $worker);
3403         }
3404
3405     }});
3406
3407 __PACKAGE__->register_method({
3408     name => 'monitor',
3409     path => '{vmid}/monitor',
3410     method => 'POST',
3411     protected => 1,
3412     proxyto => 'node',
3413     description => "Execute Qemu monitor commands.",
3414     permissions => {
3415         description => "Sys.Modify is required for (sub)commands which are not read-only ('info *' and 'help')",
3416         check => ['perm', '/vms/{vmid}', [ 'VM.Monitor' ]],
3417     },
3418     parameters => {
3419         additionalProperties => 0,
3420         properties => {
3421             node => get_standard_option('pve-node'),
3422             vmid => get_standard_option('pve-vmid'),
3423             command => {
3424                 type => 'string',
3425                 description => "The monitor command.",
3426             }
3427         },
3428     },
3429     returns => { type => 'string'},
3430     code => sub {
3431         my ($param) = @_;
3432
3433         my $rpcenv = PVE::RPCEnvironment::get();
3434         my $authuser = $rpcenv->get_user();
3435
3436         my $is_ro = sub {
3437             my $command = shift;
3438             return $command =~ m/^\s*info(\s+|$)/
3439                 || $command =~ m/^\s*help\s*$/;
3440         };
3441
3442         $rpcenv->check_full($authuser, "/", ['Sys.Modify'])
3443             if !&$is_ro($param->{command});
3444
3445         my $vmid = $param->{vmid};
3446
3447         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
3448
3449         my $res = '';
3450         eval {
3451             $res = PVE::QemuServer::Monitor::hmp_cmd($vmid, $param->{command});
3452         };
3453         $res = "ERROR: $@" if $@;
3454
3455         return $res;
3456     }});
3457
3458 __PACKAGE__->register_method({
3459     name => 'resize_vm',
3460     path => '{vmid}/resize',
3461     method => 'PUT',
3462     protected => 1,
3463     proxyto => 'node',
3464     description => "Extend volume size.",
3465     permissions => {
3466         check => ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
3467     },
3468     parameters => {
3469         additionalProperties => 0,
3470         properties => {
3471             node => get_standard_option('pve-node'),
3472             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3473             skiplock => get_standard_option('skiplock'),
3474             disk => {
3475                 type => 'string',
3476                 description => "The disk you want to resize.",
3477                 enum => [PVE::QemuServer::valid_drive_names()],
3478             },
3479             size => {
3480                 type => 'string',
3481                 pattern => '\+?\d+(\.\d+)?[KMGT]?',
3482                 description => "The new size. With the `+` sign the value is added to the actual size of the volume and without it, the value is taken as an absolute one. Shrinking disk size is not supported.",
3483             },
3484             digest => {
3485                 type => 'string',
3486                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
3487                 maxLength => 40,
3488                 optional => 1,
3489             },
3490         },
3491     },
3492     returns => { type => 'null'},
3493     code => sub {
3494         my ($param) = @_;
3495
3496         my $rpcenv = PVE::RPCEnvironment::get();
3497
3498         my $authuser = $rpcenv->get_user();
3499
3500         my $node = extract_param($param, 'node');
3501
3502         my $vmid = extract_param($param, 'vmid');
3503
3504         my $digest = extract_param($param, 'digest');
3505
3506         my $disk = extract_param($param, 'disk');
3507
3508         my $sizestr = extract_param($param, 'size');
3509
3510         my $skiplock = extract_param($param, 'skiplock');
3511         raise_param_exc({ skiplock => "Only root may use this option." })
3512             if $skiplock && $authuser ne 'root@pam';
3513
3514         my $storecfg = PVE::Storage::config();
3515
3516         my $updatefn =  sub {
3517
3518             my $conf = PVE::QemuConfig->load_config($vmid);
3519
3520             die "checksum missmatch (file change by other user?)\n"
3521                 if $digest && $digest ne $conf->{digest};
3522             PVE::QemuConfig->check_lock($conf) if !$skiplock;
3523
3524             die "disk '$disk' does not exist\n" if !$conf->{$disk};
3525
3526             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
3527
3528             my (undef, undef, undef, undef, undef, undef, $format) =
3529                 PVE::Storage::parse_volname($storecfg, $drive->{file});
3530
3531             die "can't resize volume: $disk if snapshot exists\n"
3532                 if %{$conf->{snapshots}} && $format eq 'qcow2';
3533
3534             my $volid = $drive->{file};
3535
3536             die "disk '$disk' has no associated volume\n" if !$volid;
3537
3538             die "you can't resize a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive);
3539
3540             my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid);
3541
3542             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
3543
3544             PVE::Storage::activate_volumes($storecfg, [$volid]);
3545             my $size = PVE::Storage::volume_size_info($storecfg, $volid, 5);
3546
3547             die "Could not determine current size of volume '$volid'\n" if !defined($size);
3548
3549             die "internal error" if $sizestr !~ m/^(\+)?(\d+(\.\d+)?)([KMGT])?$/;
3550             my ($ext, $newsize, $unit) = ($1, $2, $4);
3551             if ($unit) {
3552                 if ($unit eq 'K') {
3553                     $newsize = $newsize * 1024;
3554                 } elsif ($unit eq 'M') {
3555                     $newsize = $newsize * 1024 * 1024;
3556                 } elsif ($unit eq 'G') {
3557                     $newsize = $newsize * 1024 * 1024 * 1024;
3558                 } elsif ($unit eq 'T') {
3559                     $newsize = $newsize * 1024 * 1024 * 1024 * 1024;
3560                 }
3561             }
3562             $newsize += $size if $ext;
3563             $newsize = int($newsize);
3564
3565             die "shrinking disks is not supported\n" if $newsize < $size;
3566
3567             return if $size == $newsize;
3568
3569             PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: resize --disk $disk --size $sizestr");
3570
3571             PVE::QemuServer::qemu_block_resize($vmid, "drive-$disk", $storecfg, $volid, $newsize);
3572
3573             $drive->{size} = $newsize;
3574             $conf->{$disk} = PVE::QemuServer::print_drive($vmid, $drive);
3575
3576             PVE::QemuConfig->write_config($vmid, $conf);
3577         };
3578
3579         PVE::QemuConfig->lock_config($vmid, $updatefn);
3580         return undef;
3581     }});
3582
3583 __PACKAGE__->register_method({
3584     name => 'snapshot_list',
3585     path => '{vmid}/snapshot',
3586     method => 'GET',
3587     description => "List all snapshots.",
3588     permissions => {
3589         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
3590     },
3591     proxyto => 'node',
3592     protected => 1, # qemu pid files are only readable by root
3593     parameters => {
3594         additionalProperties => 0,
3595         properties => {
3596             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3597             node => get_standard_option('pve-node'),
3598         },
3599     },
3600     returns => {
3601         type => 'array',
3602         items => {
3603             type => "object",
3604             properties => {
3605                 name => {
3606                     description => "Snapshot identifier. Value 'current' identifies the current VM.",
3607                     type => 'string',
3608                 },
3609                 vmstate => {
3610                     description => "Snapshot includes RAM.",
3611                     type => 'boolean',
3612                     optional => 1,
3613                 },
3614                 description => {
3615                     description => "Snapshot description.",
3616                     type => 'string',
3617                 },
3618                 snaptime => {
3619                     description => "Snapshot creation time",
3620                     type => 'integer',
3621                     renderer => 'timestamp',
3622                     optional => 1,
3623                 },
3624                 parent => {
3625                     description => "Parent snapshot identifier.",
3626                     type => 'string',
3627                     optional => 1,
3628                 },
3629             },
3630         },
3631         links => [ { rel => 'child', href => "{name}" } ],
3632     },
3633     code => sub {
3634         my ($param) = @_;
3635
3636         my $vmid = $param->{vmid};
3637
3638         my $conf = PVE::QemuConfig->load_config($vmid);
3639         my $snaphash = $conf->{snapshots} || {};
3640
3641         my $res = [];
3642
3643         foreach my $name (keys %$snaphash) {
3644             my $d = $snaphash->{$name};
3645             my $item = {
3646                 name => $name,
3647                 snaptime => $d->{snaptime} || 0,
3648                 vmstate => $d->{vmstate} ? 1 : 0,
3649                 description => $d->{description} || '',
3650             };
3651             $item->{parent} = $d->{parent} if $d->{parent};
3652             $item->{snapstate} = $d->{snapstate} if $d->{snapstate};
3653             push @$res, $item;
3654         }
3655
3656         my $running = PVE::QemuServer::check_running($vmid, 1) ? 1 : 0;
3657         my $current = {
3658             name => 'current',
3659             digest => $conf->{digest},
3660             running => $running,
3661             description => "You are here!",
3662         };
3663         $current->{parent} = $conf->{parent} if $conf->{parent};
3664
3665         push @$res, $current;
3666
3667         return $res;
3668     }});
3669
3670 __PACKAGE__->register_method({
3671     name => 'snapshot',
3672     path => '{vmid}/snapshot',
3673     method => 'POST',
3674     protected => 1,
3675     proxyto => 'node',
3676     description => "Snapshot a VM.",
3677     permissions => {
3678         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3679     },
3680     parameters => {
3681         additionalProperties => 0,
3682         properties => {
3683             node => get_standard_option('pve-node'),
3684             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3685             snapname => get_standard_option('pve-snapshot-name'),
3686             vmstate => {
3687                 optional => 1,
3688                 type => 'boolean',
3689                 description => "Save the vmstate",
3690             },
3691             description => {
3692                 optional => 1,
3693                 type => 'string',
3694                 description => "A textual description or comment.",
3695             },
3696         },
3697     },
3698     returns => {
3699         type => 'string',
3700         description => "the task ID.",
3701     },
3702     code => sub {
3703         my ($param) = @_;
3704
3705         my $rpcenv = PVE::RPCEnvironment::get();
3706
3707         my $authuser = $rpcenv->get_user();
3708
3709         my $node = extract_param($param, 'node');
3710
3711         my $vmid = extract_param($param, 'vmid');
3712
3713         my $snapname = extract_param($param, 'snapname');
3714
3715         die "unable to use snapshot name 'current' (reserved name)\n"
3716             if $snapname eq 'current';
3717
3718         my $realcmd = sub {
3719             PVE::Cluster::log_msg('info', $authuser, "snapshot VM $vmid: $snapname");
3720             PVE::QemuConfig->snapshot_create($vmid, $snapname, $param->{vmstate},
3721                                              $param->{description});
3722         };
3723
3724         return $rpcenv->fork_worker('qmsnapshot', $vmid, $authuser, $realcmd);
3725     }});
3726
3727 __PACKAGE__->register_method({
3728     name => 'snapshot_cmd_idx',
3729     path => '{vmid}/snapshot/{snapname}',
3730     description => '',
3731     method => 'GET',
3732     permissions => {
3733         user => 'all',
3734     },
3735     parameters => {
3736         additionalProperties => 0,
3737         properties => {
3738             vmid => get_standard_option('pve-vmid'),
3739             node => get_standard_option('pve-node'),
3740             snapname => get_standard_option('pve-snapshot-name'),
3741         },
3742     },
3743     returns => {
3744         type => 'array',
3745         items => {
3746             type => "object",
3747             properties => {},
3748         },
3749         links => [ { rel => 'child', href => "{cmd}" } ],
3750     },
3751     code => sub {
3752         my ($param) = @_;
3753
3754         my $res = [];
3755
3756         push @$res, { cmd => 'rollback' };
3757         push @$res, { cmd => 'config' };
3758
3759         return $res;
3760     }});
3761
3762 __PACKAGE__->register_method({
3763     name => 'update_snapshot_config',
3764     path => '{vmid}/snapshot/{snapname}/config',
3765     method => 'PUT',
3766     protected => 1,
3767     proxyto => 'node',
3768     description => "Update snapshot metadata.",
3769     permissions => {
3770         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3771     },
3772     parameters => {
3773         additionalProperties => 0,
3774         properties => {
3775             node => get_standard_option('pve-node'),
3776             vmid => get_standard_option('pve-vmid'),
3777             snapname => get_standard_option('pve-snapshot-name'),
3778             description => {
3779                 optional => 1,
3780                 type => 'string',
3781                 description => "A textual description or comment.",
3782             },
3783         },
3784     },
3785     returns => { type => 'null' },
3786     code => sub {
3787         my ($param) = @_;
3788
3789         my $rpcenv = PVE::RPCEnvironment::get();
3790
3791         my $authuser = $rpcenv->get_user();
3792
3793         my $vmid = extract_param($param, 'vmid');
3794
3795         my $snapname = extract_param($param, 'snapname');
3796
3797         return undef if !defined($param->{description});
3798
3799         my $updatefn =  sub {
3800
3801             my $conf = PVE::QemuConfig->load_config($vmid);
3802
3803             PVE::QemuConfig->check_lock($conf);
3804
3805             my $snap = $conf->{snapshots}->{$snapname};
3806
3807             die "snapshot '$snapname' does not exist\n" if !defined($snap);
3808
3809             $snap->{description} = $param->{description} if defined($param->{description});
3810
3811              PVE::QemuConfig->write_config($vmid, $conf);
3812         };
3813
3814         PVE::QemuConfig->lock_config($vmid, $updatefn);
3815
3816         return undef;
3817     }});
3818
3819 __PACKAGE__->register_method({
3820     name => 'get_snapshot_config',
3821     path => '{vmid}/snapshot/{snapname}/config',
3822     method => 'GET',
3823     proxyto => 'node',
3824     description => "Get snapshot configuration",
3825     permissions => {
3826         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback' ], any => 1],
3827     },
3828     parameters => {
3829         additionalProperties => 0,
3830         properties => {
3831             node => get_standard_option('pve-node'),
3832             vmid => get_standard_option('pve-vmid'),
3833             snapname => get_standard_option('pve-snapshot-name'),
3834         },
3835     },
3836     returns => { type => "object" },
3837     code => sub {
3838         my ($param) = @_;
3839
3840         my $rpcenv = PVE::RPCEnvironment::get();
3841
3842         my $authuser = $rpcenv->get_user();
3843
3844         my $vmid = extract_param($param, 'vmid');
3845
3846         my $snapname = extract_param($param, 'snapname');
3847
3848         my $conf = PVE::QemuConfig->load_config($vmid);
3849
3850         my $snap = $conf->{snapshots}->{$snapname};
3851
3852         die "snapshot '$snapname' does not exist\n" if !defined($snap);
3853
3854         return $snap;
3855     }});
3856
3857 __PACKAGE__->register_method({
3858     name => 'rollback',
3859     path => '{vmid}/snapshot/{snapname}/rollback',
3860     method => 'POST',
3861     protected => 1,
3862     proxyto => 'node',
3863     description => "Rollback VM state to specified snapshot.",
3864     permissions => {
3865         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback' ], any => 1],
3866     },
3867     parameters => {
3868         additionalProperties => 0,
3869         properties => {
3870             node => get_standard_option('pve-node'),
3871             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3872             snapname => get_standard_option('pve-snapshot-name'),
3873         },
3874     },
3875     returns => {
3876         type => 'string',
3877         description => "the task ID.",
3878     },
3879     code => sub {
3880         my ($param) = @_;
3881
3882         my $rpcenv = PVE::RPCEnvironment::get();
3883
3884         my $authuser = $rpcenv->get_user();
3885
3886         my $node = extract_param($param, 'node');
3887
3888         my $vmid = extract_param($param, 'vmid');
3889
3890         my $snapname = extract_param($param, 'snapname');
3891
3892         my $realcmd = sub {
3893             PVE::Cluster::log_msg('info', $authuser, "rollback snapshot VM $vmid: $snapname");
3894             PVE::QemuConfig->snapshot_rollback($vmid, $snapname);
3895         };
3896
3897         my $worker = sub {
3898             # hold migration lock, this makes sure that nobody create replication snapshots
3899             return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
3900         };
3901
3902         return $rpcenv->fork_worker('qmrollback', $vmid, $authuser, $worker);
3903     }});
3904
3905 __PACKAGE__->register_method({
3906     name => 'delsnapshot',
3907     path => '{vmid}/snapshot/{snapname}',
3908     method => 'DELETE',
3909     protected => 1,
3910     proxyto => 'node',
3911     description => "Delete a VM snapshot.",
3912     permissions => {
3913         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3914     },
3915     parameters => {
3916         additionalProperties => 0,
3917         properties => {
3918             node => get_standard_option('pve-node'),
3919             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3920             snapname => get_standard_option('pve-snapshot-name'),
3921             force => {
3922                 optional => 1,
3923                 type => 'boolean',
3924                 description => "For removal from config file, even if removing disk snapshots fails.",
3925             },
3926         },
3927     },
3928     returns => {
3929         type => 'string',
3930         description => "the task ID.",
3931     },
3932     code => sub {
3933         my ($param) = @_;
3934
3935         my $rpcenv = PVE::RPCEnvironment::get();
3936
3937         my $authuser = $rpcenv->get_user();
3938
3939         my $node = extract_param($param, 'node');
3940
3941         my $vmid = extract_param($param, 'vmid');
3942
3943         my $snapname = extract_param($param, 'snapname');
3944
3945         my $realcmd = sub {
3946             PVE::Cluster::log_msg('info', $authuser, "delete snapshot VM $vmid: $snapname");
3947             PVE::QemuConfig->snapshot_delete($vmid, $snapname, $param->{force});
3948         };
3949
3950         return $rpcenv->fork_worker('qmdelsnapshot', $vmid, $authuser, $realcmd);
3951     }});
3952
3953 __PACKAGE__->register_method({
3954     name => 'template',
3955     path => '{vmid}/template',
3956     method => 'POST',
3957     protected => 1,
3958     proxyto => 'node',
3959     description => "Create a Template.",
3960     permissions => {
3961         description => "You need 'VM.Allocate' permissions on /vms/{vmid}",
3962         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
3963     },
3964     parameters => {
3965         additionalProperties => 0,
3966         properties => {
3967             node => get_standard_option('pve-node'),
3968             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
3969             disk => {
3970                 optional => 1,
3971                 type => 'string',
3972                 description => "If you want to convert only 1 disk to base image.",
3973                 enum => [PVE::QemuServer::valid_drive_names()],
3974             },
3975
3976         },
3977     },
3978     returns => { type => 'null'},
3979     code => sub {
3980         my ($param) = @_;
3981
3982         my $rpcenv = PVE::RPCEnvironment::get();
3983
3984         my $authuser = $rpcenv->get_user();
3985
3986         my $node = extract_param($param, 'node');
3987
3988         my $vmid = extract_param($param, 'vmid');
3989
3990         my $disk = extract_param($param, 'disk');
3991
3992         my $updatefn =  sub {
3993
3994             my $conf = PVE::QemuConfig->load_config($vmid);
3995
3996             PVE::QemuConfig->check_lock($conf);
3997
3998             die "unable to create template, because VM contains snapshots\n"
3999                 if $conf->{snapshots} && scalar(keys %{$conf->{snapshots}});
4000
4001             die "you can't convert a template to a template\n"
4002                 if PVE::QemuConfig->is_template($conf) && !$disk;
4003
4004             die "you can't convert a VM to template if VM is running\n"
4005                 if PVE::QemuServer::check_running($vmid);
4006
4007             my $realcmd = sub {
4008                 PVE::QemuServer::template_create($vmid, $conf, $disk);
4009             };
4010
4011             $conf->{template} = 1;
4012             PVE::QemuConfig->write_config($vmid, $conf);
4013
4014             return $rpcenv->fork_worker('qmtemplate', $vmid, $authuser, $realcmd);
4015         };
4016
4017         PVE::QemuConfig->lock_config($vmid, $updatefn);
4018         return undef;
4019     }});
4020
4021 __PACKAGE__->register_method({
4022     name => 'cloudinit_generated_config_dump',
4023     path => '{vmid}/cloudinit/dump',
4024     method => 'GET',
4025     proxyto => 'node',
4026     description => "Get automatically generated cloudinit config.",
4027     permissions => {
4028         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
4029     },
4030     parameters => {
4031         additionalProperties => 0,
4032         properties => {
4033             node => get_standard_option('pve-node'),
4034             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
4035             type => {
4036                 description => 'Config type.',
4037                 type => 'string',
4038                 enum => ['user', 'network', 'meta'],
4039             },
4040         },
4041     },
4042     returns => {
4043         type => 'string',
4044     },
4045     code => sub {
4046         my ($param) = @_;
4047
4048         my $conf = PVE::QemuConfig->load_config($param->{vmid});
4049
4050         return PVE::QemuServer::Cloudinit::dump_cloudinit_config($conf, $param->{vmid}, $param->{type});
4051     }});
4052
4053 1;