PVE/API2/Qemu.pm

   1 package PVE::API2::Qemu;
   2
   3 use strict;
   4 use warnings;
   5 use Cwd 'abs_path';
   6 use Net::SSLeay;
   7 use UUID;
   8 use POSIX;
   9 use IO::Socket::IP;
  10 use URI::Escape;
  11
  12 use PVE::Cluster qw (cfs_read_file cfs_write_file);;
  13 use PVE::SafeSyslog;
  14 use PVE::Tools qw(extract_param);
  15 use PVE::Exception qw(raise raise_param_exc raise_perm_exc);
  16 use PVE::Storage;
  17 use PVE::JSONSchema qw(get_standard_option);
  18 use PVE::RESTHandler;
  19 use PVE::ReplicationConfig;
  20 use PVE::GuestHelpers;
  21 use PVE::QemuConfig;
  22 use PVE::QemuServer;
  23 use PVE::QemuMigrate;
  24 use PVE::RPCEnvironment;
  25 use PVE::AccessControl;
  26 use PVE::INotify;
  27 use PVE::Network;
  28 use PVE::Firewall;
  29 use PVE::API2::Firewall::VM;
  30 use PVE::API2::Qemu::Agent;
  31
  32 BEGIN {
  33     if (!$ENV{PVE_GENERATING_DOCS}) {
  34         require PVE::HA::Env::PVE2;
  35         import PVE::HA::Env::PVE2;
  36         require PVE::HA::Config;
  37         import PVE::HA::Config;
  38     }
  39 }
  40
  41 use Data::Dumper; # fixme: remove
  42
  43 use base qw(PVE::RESTHandler);
  44
  45 my $opt_force_description = "Force physical removal. Without this, we simple remove the disk from the config file and create an additional configuration entry called 'unused[n]', which contains the volume ID. Unlink of unused[n] always cause physical removal.";
  46
  47 my $resolve_cdrom_alias = sub {
  48     my $param = shift;
  49
  50     if (my $value = $param->{cdrom}) {
  51         $value .= ",media=cdrom" if $value !~ m/media=/;
  52         $param->{ide2} = $value;
  53         delete $param->{cdrom};
  54     }
  55 };
  56
  57 my $NEW_DISK_RE = qr!^(([^/:\s]+):)?(\d+(\.\d+)?)$!;
  58 my $check_storage_access = sub {
  59    my ($rpcenv, $authuser, $storecfg, $vmid, $settings, $default_storage) = @_;
  60
  61    PVE::QemuServer::foreach_drive($settings, sub {
  62         my ($ds, $drive) = @_;
  63
  64         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
  65
  66         my $volid = $drive->{file};
  67
  68         if (!$volid || ($volid eq 'none' || $volid eq 'cloudinit')) {
  69             # nothing to check
  70         } elsif ($volid =~ m/^(([^:\s]+):)?(cloudinit)$/) {
  71             # nothing to check
  72         } elsif ($isCDROM && ($volid eq 'cdrom')) {
  73             $rpcenv->check($authuser, "/", ['Sys.Console']);
  74         } elsif (!$isCDROM && ($volid =~ $NEW_DISK_RE)) {
  75             my ($storeid, $size) = ($2 || $default_storage, $3);
  76             die "no storage ID specified (and no default storage)\n" if !$storeid;
  77             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
  78             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
  79             raise_param_exc({ storage => "storage '$storeid' does not support vm images"})
  80                 if !$scfg->{content}->{images};
  81         } else {
  82             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
  83         }
  84     });
  85
  86    $rpcenv->check($authuser, "/storage/$settings->{vmstatestorage}", ['Datastore.AllocateSpace'])
  87        if defined($settings->{vmstatestorage});
  88 };
  89
  90 my $check_storage_access_clone = sub {
  91    my ($rpcenv, $authuser, $storecfg, $conf, $storage) = @_;
  92
  93    my $sharedvm = 1;
  94
  95    PVE::QemuServer::foreach_drive($conf, sub {
  96         my ($ds, $drive) = @_;
  97
  98         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
  99
 100         my $volid = $drive->{file};
 101
 102         return if !$volid || $volid eq 'none';
 103
 104         if ($isCDROM) {
 105             if ($volid eq 'cdrom') {
 106                 $rpcenv->check($authuser, "/", ['Sys.Console']);
 107             } else {
 108                 # we simply allow access
 109                 my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 110                 my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 111                 $sharedvm = 0 if !$scfg->{shared};
 112
 113             }
 114         } else {
 115             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 116             my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 117             $sharedvm = 0 if !$scfg->{shared};
 118
 119             $sid = $storage if $storage;
 120             $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
 121         }
 122     });
 123
 124    $rpcenv->check($authuser, "/storage/$conf->{vmstatestorage}", ['Datastore.AllocateSpace'])
 125        if defined($conf->{vmstatestorage});
 126
 127    return $sharedvm;
 128 };
 129
 130 # Note: $pool is only needed when creating a VM, because pool permissions
 131 # are automatically inherited if VM already exists inside a pool.
 132 my $create_disks = sub {
 133     my ($rpcenv, $authuser, $conf, $storecfg, $vmid, $pool, $settings, $default_storage) = @_;
 134
 135     my $vollist = [];
 136
 137     my $res = {};
 138
 139     my $code = sub {
 140         my ($ds, $disk) = @_;
 141
 142         my $volid = $disk->{file};
 143
 144         if (!$volid || $volid eq 'none' || $volid eq 'cdrom') {
 145             delete $disk->{size};
 146             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 147         } elsif ($volid =~ m!^(?:([^/:\s]+):)?cloudinit$!) {
 148             my $storeid = $1 || $default_storage;
 149             die "no storage ID specified (and no default storage)\n" if !$storeid;
 150             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 151             my $name = "vm-$vmid-cloudinit";
 152             my $fmt = undef;
 153             if ($scfg->{path}) {
 154                 $name .= ".qcow2";
 155                 $fmt = 'qcow2';
 156             }else{
 157                 $fmt = 'raw';
 158             }
 159             # FIXME: Reasonable size? qcow2 shouldn't grow if the space isn't used anyway?
 160             my $cloudinit_iso_size = 5; # in MB
 161             my $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid,
 162                                                   $fmt, $name, $cloudinit_iso_size*1024);
 163             $disk->{file} = $volid;
 164             $disk->{media} = 'cdrom';
 165             push @$vollist, $volid;
 166             delete $disk->{format}; # no longer needed
 167             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 168         } elsif ($volid =~ $NEW_DISK_RE) {
 169             my ($storeid, $size) = ($2 || $default_storage, $3);
 170             die "no storage ID specified (and no default storage)\n" if !$storeid;
 171             my $defformat = PVE::Storage::storage_default_format($storecfg, $storeid);
 172             my $fmt = $disk->{format} || $defformat;
 173
 174             $size = PVE::Tools::convert_size($size, 'gb' => 'kb'); # vdisk_alloc uses kb
 175
 176             my $volid;
 177             if ($ds eq 'efidisk0') {
 178                 ($volid, $size) = PVE::QemuServer::create_efidisk($storecfg, $storeid, $vmid, $fmt);
 179             } else {
 180                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $fmt, undef, $size);
 181             }
 182             push @$vollist, $volid;
 183             $disk->{file} = $volid;
 184             $disk->{size} = PVE::Tools::convert_size($size, 'kb' => 'b');
 185             delete $disk->{format}; # no longer needed
 186             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 187         } else {
 188
 189             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
 190
 191             my $volid_is_new = 1;
 192
 193             if ($conf->{$ds}) {
 194                 my $olddrive = PVE::QemuServer::parse_drive($ds, $conf->{$ds});
 195                 $volid_is_new = undef if $olddrive->{file} && $olddrive->{file} eq $volid;
 196             }
 197
 198             if ($volid_is_new) {
 199
 200                 my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 201
 202                 PVE::Storage::activate_volumes($storecfg, [ $volid ]) if $storeid;
 203
 204                 my $size = PVE::Storage::volume_size_info($storecfg, $volid);
 205
 206                 die "volume $volid does not exists\n" if !$size;
 207
 208                 $disk->{size} = $size;
 209             }
 210
 211             $res->{$ds} = PVE::QemuServer::print_drive($vmid, $disk);
 212         }
 213     };
 214
 215     eval { PVE::QemuServer::foreach_drive($settings, $code); };
 216
 217     # free allocated images on error
 218     if (my $err = $@) {
 219         syslog('err', "VM $vmid creating disks failed");
 220         foreach my $volid (@$vollist) {
 221             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 222             warn $@ if $@;
 223         }
 224         die $err;
 225     }
 226
 227     # modify vm config if everything went well
 228     foreach my $ds (keys %$res) {
 229         $conf->{$ds} = $res->{$ds};
 230     }
 231
 232     return $vollist;
 233 };
 234
 235 my $cpuoptions = {
 236     'cores' => 1,
 237     'cpu' => 1,
 238     'cpulimit' => 1,
 239     'cpuunits' => 1,
 240     'numa' => 1,
 241     'smp' => 1,
 242     'sockets' => 1,
 243     'vcpus' => 1,
 244 };
 245
 246 my $memoryoptions = {
 247     'memory' => 1,
 248     'balloon' => 1,
 249     'shares' => 1,
 250 };
 251
 252 my $hwtypeoptions = {
 253     'acpi' => 1,
 254     'hotplug' => 1,
 255     'kvm' => 1,
 256     'machine' => 1,
 257     'scsihw' => 1,
 258     'smbios1' => 1,
 259     'tablet' => 1,
 260     'vga' => 1,
 261     'watchdog' => 1,
 262 };
 263
 264 my $generaloptions = {
 265     'agent' => 1,
 266     'autostart' => 1,
 267     'bios' => 1,
 268     'description' => 1,
 269     'keyboard' => 1,
 270     'localtime' => 1,
 271     'migrate_downtime' => 1,
 272     'migrate_speed' => 1,
 273     'name' => 1,
 274     'onboot' => 1,
 275     'ostype' => 1,
 276     'protection' => 1,
 277     'reboot' => 1,
 278     'startdate' => 1,
 279     'startup' => 1,
 280     'tdf' => 1,
 281     'template' => 1,
 282 };
 283
 284 my $vmpoweroptions = {
 285     'freeze' => 1,
 286 };
 287
 288 my $diskoptions = {
 289     'boot' => 1,
 290     'bootdisk' => 1,
 291     'vmstatestorage' => 1,
 292 };
 293
 294 my $cloudinitoptions = {
 295     cipassword => 1,
 296     citype => 1,
 297     ciuser => 1,
 298     nameserver => 1,
 299     searchdomain => 1,
 300     sshkeys => 1,
 301 };
 302
 303 my $check_vm_modify_config_perm = sub {
 304     my ($rpcenv, $authuser, $vmid, $pool, $key_list) = @_;
 305
 306     return 1 if $authuser eq 'root@pam';
 307
 308     foreach my $opt (@$key_list) {
 309         # disk checks need to be done somewhere else
 310         next if PVE::QemuServer::is_valid_drivename($opt);
 311         next if $opt eq 'cdrom';
 312         next if $opt =~ m/^unused\d+$/;
 313
 314         if ($cpuoptions->{$opt} || $opt =~ m/^numa\d+$/) {
 315             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
 316         } elsif ($memoryoptions->{$opt}) {
 317             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
 318         } elsif ($hwtypeoptions->{$opt}) {
 319             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.HWType']);
 320         } elsif ($generaloptions->{$opt}) {
 321             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
 322             # special case for startup since it changes host behaviour
 323             if ($opt eq 'startup') {
 324                 $rpcenv->check_full($authuser, "/", ['Sys.Modify']);
 325             }
 326         } elsif ($vmpoweroptions->{$opt}) {
 327             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.PowerMgmt']);
 328         } elsif ($diskoptions->{$opt}) {
 329             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
 330         } elsif ($cloudinitoptions->{$opt} || ($opt =~ m/^(?:net|ipconfig)\d+$/)) {
 331             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
 332         } else {
 333             # catches usb\d+, hostpci\d+, args, lock, etc.
 334             # new options will be checked here
 335             die "only root can set '$opt' config\n";
 336         }
 337     }
 338
 339     return 1;
 340 };
 341
 342 __PACKAGE__->register_method({
 343     name => 'vmlist',
 344     path => '',
 345     method => 'GET',
 346     description => "Virtual machine index (per node).",
 347     permissions => {
 348         description => "Only list VMs where you have VM.Audit permissons on /vms/<vmid>.",
 349         user => 'all',
 350     },
 351     proxyto => 'node',
 352     protected => 1, # qemu pid files are only readable by root
 353     parameters => {
 354         additionalProperties => 0,
 355         properties => {
 356             node => get_standard_option('pve-node'),
 357             full => {
 358                 type => 'boolean',
 359                 optional => 1,
 360                 description => "Determine the full status of active VMs.",
 361             },
 362         },
 363     },
 364     returns => {
 365         type => 'array',
 366         items => {
 367             type => "object",
 368             properties => {},
 369         },
 370         links => [ { rel => 'child', href => "{vmid}" } ],
 371     },
 372     code => sub {
 373         my ($param) = @_;
 374
 375         my $rpcenv = PVE::RPCEnvironment::get();
 376         my $authuser = $rpcenv->get_user();
 377
 378         my $vmstatus = PVE::QemuServer::vmstatus(undef, $param->{full});
 379
 380         my $res = [];
 381         foreach my $vmid (keys %$vmstatus) {
 382             next if !$rpcenv->check($authuser, "/vms/$vmid", [ 'VM.Audit' ], 1);
 383
 384             my $data = $vmstatus->{$vmid};
 385             $data->{vmid} = int($vmid);
 386             push @$res, $data;
 387         }
 388
 389         return $res;
 390     }});
 391
 392
 393
 394 __PACKAGE__->register_method({
 395     name => 'create_vm',
 396     path => '',
 397     method => 'POST',
 398     description => "Create or restore a virtual machine.",
 399     permissions => {
 400         description => "You need 'VM.Allocate' permissions on /vms/{vmid} or on the VM pool /pool/{pool}. " .
 401             "For restore (option 'archive'), it is enough if the user has 'VM.Backup' permission and the VM already exists. " .
 402             "If you create disks you need 'Datastore.AllocateSpace' on any used storage.",
 403         user => 'all', # check inside
 404     },
 405     protected => 1,
 406     proxyto => 'node',
 407     parameters => {
 408         additionalProperties => 0,
 409         properties => PVE::QemuServer::json_config_properties(
 410             {
 411                 node => get_standard_option('pve-node'),
 412                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::Cluster::complete_next_vmid }),
 413                 archive => {
 414                     description => "The backup file.",
 415                     type => 'string',
 416                     optional => 1,
 417                     maxLength => 255,
 418                     completion => \&PVE::QemuServer::complete_backup_archives,
 419                 },
 420                 storage => get_standard_option('pve-storage-id', {
 421                     description => "Default storage.",
 422                     optional => 1,
 423                     completion => \&PVE::QemuServer::complete_storage,
 424                 }),
 425                 force => {
 426                     optional => 1,
 427                     type => 'boolean',
 428                     description => "Allow to overwrite existing VM.",
 429                     requires => 'archive',
 430                 },
 431                 unique => {
 432                     optional => 1,
 433                     type => 'boolean',
 434                     description => "Assign a unique random ethernet address.",
 435                     requires => 'archive',
 436                 },
 437                 pool => {
 438                     optional => 1,
 439                     type => 'string', format => 'pve-poolid',
 440                     description => "Add the VM to the specified pool.",
 441                 },
 442                 bwlimit => {
 443                     description => "Override i/o bandwidth limit (in KiB/s).",
 444                     optional => 1,
 445                     type => 'integer',
 446                     minimum => '0',
 447                 },
 448                 start => {
 449                     optional => 1,
 450                     type => 'boolean',
 451                     default => 0,
 452                     description => "Start VM after it was created successfully.",
 453                 },
 454             }),
 455     },
 456     returns => {
 457         type => 'string',
 458     },
 459     code => sub {
 460         my ($param) = @_;
 461
 462         my $rpcenv = PVE::RPCEnvironment::get();
 463
 464         my $authuser = $rpcenv->get_user();
 465
 466         my $node = extract_param($param, 'node');
 467
 468         my $vmid = extract_param($param, 'vmid');
 469
 470         my $archive = extract_param($param, 'archive');
 471         my $is_restore = !!$archive;
 472
 473         my $storage = extract_param($param, 'storage');
 474
 475         my $force = extract_param($param, 'force');
 476
 477         my $unique = extract_param($param, 'unique');
 478
 479         my $pool = extract_param($param, 'pool');
 480
 481         my $bwlimit = extract_param($param, 'bwlimit');
 482
 483         my $start_after_create = extract_param($param, 'start');
 484
 485         my $filename = PVE::QemuConfig->config_file($vmid);
 486
 487         my $storecfg = PVE::Storage::config();
 488
 489         if (defined(my $ssh_keys = $param->{sshkeys})) {
 490                 $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
 491                 PVE::Tools::validate_ssh_public_keys($ssh_keys);
 492         }
 493
 494         PVE::Cluster::check_cfs_quorum();
 495
 496         if (defined($pool)) {
 497             $rpcenv->check_pool_exist($pool);
 498         }
 499
 500         $rpcenv->check($authuser, "/storage/$storage", ['Datastore.AllocateSpace'])
 501             if defined($storage);
 502
 503         if ($rpcenv->check($authuser, "/vms/$vmid", ['VM.Allocate'], 1)) {
 504             # OK
 505         } elsif ($pool && $rpcenv->check($authuser, "/pool/$pool", ['VM.Allocate'], 1)) {
 506             # OK
 507         } elsif ($archive && $force && (-f $filename) &&
 508                  $rpcenv->check($authuser, "/vms/$vmid", ['VM.Backup'], 1)) {
 509             # OK: user has VM.Backup permissions, and want to restore an existing VM
 510         } else {
 511             raise_perm_exc();
 512         }
 513
 514         if (!$archive) {
 515             &$resolve_cdrom_alias($param);
 516
 517             &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param, $storage);
 518
 519             &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, $pool, [ keys %$param]);
 520
 521             foreach my $opt (keys %$param) {
 522                 if (PVE::QemuServer::is_valid_drivename($opt)) {
 523                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
 524                     raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
 525
 526                     PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
 527                     $param->{$opt} = PVE::QemuServer::print_drive($vmid, $drive);
 528                 }
 529             }
 530
 531             PVE::QemuServer::add_random_macs($param);
 532         } else {
 533             my $keystr = join(' ', keys %$param);
 534             raise_param_exc({ archive => "option conflicts with other options ($keystr)"}) if $keystr;
 535
 536             if ($archive eq '-') {
 537                 die "pipe requires cli environment\n"
 538                     if $rpcenv->{type} ne 'cli';
 539             } else {
 540                 PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $archive);
 541                 $archive = PVE::Storage::abs_filesystem_path($storecfg, $archive);
 542             }
 543         }
 544
 545         my $emsg = $is_restore ? "unable to restore VM $vmid -" : "unable to create VM $vmid -";
 546
 547         eval { PVE::QemuConfig->create_and_lock_config($vmid, $force) };
 548         die "$emsg $@" if $@;
 549
 550         my $restorefn = sub {
 551             my $conf = PVE::QemuConfig->load_config($vmid);
 552
 553             PVE::QemuConfig->check_protection($conf, $emsg);
 554
 555             die "$emsg vm is running\n" if PVE::QemuServer::check_running($vmid);
 556             die "$emsg vm is a template\n" if PVE::QemuConfig->is_template($conf);
 557
 558             my $realcmd = sub {
 559                 PVE::QemuServer::restore_archive($archive, $vmid, $authuser, {
 560                     storage => $storage,
 561                     pool => $pool,
 562                     unique => $unique,
 563                     bwlimit => $bwlimit, });
 564
 565                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 566
 567                 if ($start_after_create) {
 568                     eval { PVE::API2::Qemu->vm_start({ vmid => $vmid, node => $node }) };
 569                     warn $@ if $@;
 570                 }
 571             };
 572
 573             # ensure no old replication state are exists
 574             PVE::ReplicationState::delete_guest_states($vmid);
 575
 576             return PVE::QemuConfig->lock_config_full($vmid, 1, $realcmd);
 577         };
 578
 579         my $createfn = sub {
 580             # ensure no old replication state are exists
 581             PVE::ReplicationState::delete_guest_states($vmid);
 582
 583             my $realcmd = sub {
 584
 585                 my $vollist = [];
 586
 587                 my $conf = $param;
 588
 589                 eval {
 590
 591                     $vollist = &$create_disks($rpcenv, $authuser, $conf, $storecfg, $vmid, $pool, $param, $storage);
 592
 593                     if (!$conf->{bootdisk}) {
 594                         my $firstdisk = PVE::QemuServer::resolve_first_disk($conf);
 595                         $conf->{bootdisk} = $firstdisk if $firstdisk;
 596                     }
 597
 598                     # auto generate uuid if user did not specify smbios1 option
 599                     if (!$conf->{smbios1}) {
 600                         $conf->{smbios1} = PVE::QemuServer::generate_smbios1_uuid();
 601                     }
 602
 603                     PVE::QemuConfig->write_config($vmid, $conf);
 604
 605                 };
 606                 my $err = $@;
 607
 608                 if ($err) {
 609                     foreach my $volid (@$vollist) {
 610                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 611                         warn $@ if $@;
 612                     }
 613                     die "$emsg $err";
 614                 }
 615
 616                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 617             };
 618
 619             PVE::QemuConfig->lock_config_full($vmid, 1, $realcmd);
 620
 621             if ($start_after_create) {
 622                 print "Execute autostart\n";
 623                 eval { PVE::API2::Qemu->vm_start({vmid => $vmid, node => $node}) };
 624                 warn $@ if $@;
 625             }
 626         };
 627
 628         my ($code, $worker_name);
 629         if ($is_restore) {
 630             $worker_name = 'qmrestore';
 631             $code = sub {
 632                 eval { $restorefn->() };
 633                 if (my $err = $@) {
 634                     eval { PVE::QemuConfig->remove_lock($vmid, 'create') };
 635                     warn $@ if $@;
 636                     die $err;
 637                 }
 638             };
 639         } else {
 640             $worker_name = 'qmcreate';
 641             $code = sub {
 642                 eval { $createfn->() };
 643                 if (my $err = $@) {
 644                     eval {
 645                         my $conffile = PVE::QemuConfig->config_file($vmid);
 646                         unlink($conffile)
 647                             or die "failed to remove config file: $@\n";
 648                     };
 649                     warn $@ if $@;
 650                     die $err;
 651                 }
 652             };
 653         }
 654
 655         return $rpcenv->fork_worker($worker_name, $vmid, $authuser, $code);
 656     }});
 657
 658 __PACKAGE__->register_method({
 659     name => 'vmdiridx',
 660     path => '{vmid}',
 661     method => 'GET',
 662     proxyto => 'node',
 663     description => "Directory index",
 664     permissions => {
 665         user => 'all',
 666     },
 667     parameters => {
 668         additionalProperties => 0,
 669         properties => {
 670             node => get_standard_option('pve-node'),
 671             vmid => get_standard_option('pve-vmid'),
 672         },
 673     },
 674     returns => {
 675         type => 'array',
 676         items => {
 677             type => "object",
 678             properties => {
 679                 subdir => { type => 'string' },
 680             },
 681         },
 682         links => [ { rel => 'child', href => "{subdir}" } ],
 683     },
 684     code => sub {
 685         my ($param) = @_;
 686
 687         my $res = [
 688             { subdir => 'config' },
 689             { subdir => 'pending' },
 690             { subdir => 'status' },
 691             { subdir => 'unlink' },
 692             { subdir => 'vncproxy' },
 693             { subdir => 'termproxy' },
 694             { subdir => 'migrate' },
 695             { subdir => 'resize' },
 696             { subdir => 'move' },
 697             { subdir => 'rrd' },
 698             { subdir => 'rrddata' },
 699             { subdir => 'monitor' },
 700             { subdir => 'agent' },
 701             { subdir => 'snapshot' },
 702             { subdir => 'spiceproxy' },
 703             { subdir => 'sendkey' },
 704             { subdir => 'firewall' },
 705             ];
 706
 707         return $res;
 708     }});
 709
 710 __PACKAGE__->register_method ({
 711     subclass => "PVE::API2::Firewall::VM",
 712     path => '{vmid}/firewall',
 713 });
 714
 715 __PACKAGE__->register_method ({
 716     subclass => "PVE::API2::Qemu::Agent",
 717     path => '{vmid}/agent',
 718 });
 719
 720 __PACKAGE__->register_method({
 721     name => 'rrd',
 722     path => '{vmid}/rrd',
 723     method => 'GET',
 724     protected => 1, # fixme: can we avoid that?
 725     permissions => {
 726         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 727     },
 728     description => "Read VM RRD statistics (returns PNG)",
 729     parameters => {
 730         additionalProperties => 0,
 731         properties => {
 732             node => get_standard_option('pve-node'),
 733             vmid => get_standard_option('pve-vmid'),
 734             timeframe => {
 735                 description => "Specify the time frame you are interested in.",
 736                 type => 'string',
 737                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 738             },
 739             ds => {
 740                 description => "The list of datasources you want to display.",
 741                 type => 'string', format => 'pve-configid-list',
 742             },
 743             cf => {
 744                 description => "The RRD consolidation function",
 745                 type => 'string',
 746                 enum => [ 'AVERAGE', 'MAX' ],
 747                 optional => 1,
 748             },
 749         },
 750     },
 751     returns => {
 752         type => "object",
 753         properties => {
 754             filename => { type => 'string' },
 755         },
 756     },
 757     code => sub {
 758         my ($param) = @_;
 759
 760         return PVE::Cluster::create_rrd_graph(
 761             "pve2-vm/$param->{vmid}", $param->{timeframe},
 762             $param->{ds}, $param->{cf});
 763
 764     }});
 765
 766 __PACKAGE__->register_method({
 767     name => 'rrddata',
 768     path => '{vmid}/rrddata',
 769     method => 'GET',
 770     protected => 1, # fixme: can we avoid that?
 771     permissions => {
 772         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 773     },
 774     description => "Read VM RRD statistics",
 775     parameters => {
 776         additionalProperties => 0,
 777         properties => {
 778             node => get_standard_option('pve-node'),
 779             vmid => get_standard_option('pve-vmid'),
 780             timeframe => {
 781                 description => "Specify the time frame you are interested in.",
 782                 type => 'string',
 783                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 784             },
 785             cf => {
 786                 description => "The RRD consolidation function",
 787                 type => 'string',
 788                 enum => [ 'AVERAGE', 'MAX' ],
 789                 optional => 1,
 790             },
 791         },
 792     },
 793     returns => {
 794         type => "array",
 795         items => {
 796             type => "object",
 797             properties => {},
 798         },
 799     },
 800     code => sub {
 801         my ($param) = @_;
 802
 803         return PVE::Cluster::create_rrd_data(
 804             "pve2-vm/$param->{vmid}", $param->{timeframe}, $param->{cf});
 805     }});
 806
 807
 808 __PACKAGE__->register_method({
 809     name => 'vm_config',
 810     path => '{vmid}/config',
 811     method => 'GET',
 812     proxyto => 'node',
 813     description => "Get current virtual machine configuration. This does not include pending configuration changes (see 'pending' API).",
 814     permissions => {
 815         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 816     },
 817     parameters => {
 818         additionalProperties => 0,
 819         properties => {
 820             node => get_standard_option('pve-node'),
 821             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 822             current => {
 823                 description => "Get current values (instead of pending values).",
 824                 optional => 1,
 825                 default => 0,
 826                 type => 'boolean',
 827             },
 828         },
 829     },
 830     returns => {
 831         type => "object",
 832         properties => {
 833             digest => {
 834                 type => 'string',
 835                 description => 'SHA1 digest of configuration file. This can be used to prevent concurrent modifications.',
 836             }
 837         },
 838     },
 839     code => sub {
 840         my ($param) = @_;
 841
 842         my $conf = PVE::QemuConfig->load_config($param->{vmid});
 843
 844         delete $conf->{snapshots};
 845
 846         if (!$param->{current}) {
 847             foreach my $opt (keys %{$conf->{pending}}) {
 848                 next if $opt eq 'delete';
 849                 my $value = $conf->{pending}->{$opt};
 850                 next if ref($value); # just to be sure
 851                 $conf->{$opt} = $value;
 852             }
 853             my $pending_delete_hash = PVE::QemuServer::split_flagged_list($conf->{pending}->{delete});
 854             foreach my $opt (keys %$pending_delete_hash) {
 855                 delete $conf->{$opt} if $conf->{$opt};
 856             }
 857         }
 858
 859         delete $conf->{pending};
 860
 861         # hide cloudinit password
 862         if ($conf->{cipassword}) {
 863             $conf->{cipassword} = '**********';
 864         }
 865
 866         return $conf;
 867     }});
 868
 869 __PACKAGE__->register_method({
 870     name => 'vm_pending',
 871     path => '{vmid}/pending',
 872     method => 'GET',
 873     proxyto => 'node',
 874     description => "Get virtual machine configuration, including pending changes.",
 875     permissions => {
 876         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 877     },
 878     parameters => {
 879         additionalProperties => 0,
 880         properties => {
 881             node => get_standard_option('pve-node'),
 882             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 883         },
 884     },
 885     returns => {
 886         type => "array",
 887         items => {
 888             type => "object",
 889             properties => {
 890                 key => {
 891                     description => "Configuration option name.",
 892                     type => 'string',
 893                 },
 894                 value => {
 895                     description => "Current value.",
 896                     type => 'string',
 897                     optional => 1,
 898                 },
 899                 pending => {
 900                     description => "Pending value.",
 901                     type => 'string',
 902                     optional => 1,
 903                 },
 904                 delete => {
 905                     description => "Indicates a pending delete request if present and not 0. " .
 906                                    "The value 2 indicates a force-delete request.",
 907                     type => 'integer',
 908                     minimum => 0,
 909                     maximum => 2,
 910                     optional => 1,
 911                 },
 912             },
 913         },
 914     },
 915     code => sub {
 916         my ($param) = @_;
 917
 918         my $conf = PVE::QemuConfig->load_config($param->{vmid});
 919
 920         my $pending_delete_hash = PVE::QemuServer::split_flagged_list($conf->{pending}->{delete});
 921
 922         my $res = [];
 923
 924         foreach my $opt (keys %$conf) {
 925             next if ref($conf->{$opt});
 926             my $item = { key => $opt };
 927             $item->{value} = $conf->{$opt} if defined($conf->{$opt});
 928             $item->{pending} = $conf->{pending}->{$opt} if defined($conf->{pending}->{$opt});
 929             $item->{delete} = ($pending_delete_hash->{$opt} ? 2 : 1) if exists $pending_delete_hash->{$opt};
 930
 931             # hide cloudinit password
 932             if ($opt eq 'cipassword') {
 933                 $item->{value} = '**********' if defined($item->{value});
 934                 # the trailing space so that the pending string is different
 935                 $item->{pending} = '********** ' if defined($item->{pending});
 936             }
 937             push @$res, $item;
 938         }
 939
 940         foreach my $opt (keys %{$conf->{pending}}) {
 941             next if $opt eq 'delete';
 942             next if ref($conf->{pending}->{$opt}); # just to be sure
 943             next if defined($conf->{$opt});
 944             my $item = { key => $opt };
 945             $item->{pending} = $conf->{pending}->{$opt};
 946
 947             # hide cloudinit password
 948             if ($opt eq 'cipassword') {
 949                 $item->{pending} = '**********' if defined($item->{pending});
 950             }
 951             push @$res, $item;
 952         }
 953
 954         while (my ($opt, $force) = each %$pending_delete_hash) {
 955             next if $conf->{pending}->{$opt}; # just to be sure
 956             next if $conf->{$opt};
 957             my $item = { key => $opt, delete => ($force ? 2 : 1)};
 958             push @$res, $item;
 959         }
 960
 961         return $res;
 962     }});
 963
 964 # POST/PUT {vmid}/config implementation
 965 #
 966 # The original API used PUT (idempotent) an we assumed that all operations
 967 # are fast. But it turned out that almost any configuration change can
 968 # involve hot-plug actions, or disk alloc/free. Such actions can take long
 969 # time to complete and have side effects (not idempotent).
 970 #
 971 # The new implementation uses POST and forks a worker process. We added
 972 # a new option 'background_delay'. If specified we wait up to
 973 # 'background_delay' second for the worker task to complete. It returns null
 974 # if the task is finished within that time, else we return the UPID.
 975
 976 my $update_vm_api  = sub {
 977     my ($param, $sync) = @_;
 978
 979     my $rpcenv = PVE::RPCEnvironment::get();
 980
 981     my $authuser = $rpcenv->get_user();
 982
 983     my $node = extract_param($param, 'node');
 984
 985     my $vmid = extract_param($param, 'vmid');
 986
 987     my $digest = extract_param($param, 'digest');
 988
 989     my $background_delay = extract_param($param, 'background_delay');
 990
 991     if (defined(my $cipassword = $param->{cipassword})) {
 992         # Same logic as in cloud-init (but with the regex fixed...)
 993         $param->{cipassword} = PVE::Tools::encrypt_pw($cipassword)
 994             if $cipassword !~ /^\$(?:[156]|2[ay])(\$.+){2}/;
 995     }
 996
 997     my @paramarr = (); # used for log message
 998     foreach my $key (sort keys %$param) {
 999         my $value = $key eq 'cipassword' ? '<hidden>' : $param->{$key};
1000         push @paramarr, "-$key", $value;
1001     }
1002
1003     my $skiplock = extract_param($param, 'skiplock');
1004     raise_param_exc({ skiplock => "Only root may use this option." })
1005         if $skiplock && $authuser ne 'root@pam';
1006
1007     my $delete_str = extract_param($param, 'delete');
1008
1009     my $revert_str = extract_param($param, 'revert');
1010
1011     my $force = extract_param($param, 'force');
1012
1013     if (defined(my $ssh_keys = $param->{sshkeys})) {
1014         $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
1015         PVE::Tools::validate_ssh_public_keys($ssh_keys);
1016     }
1017
1018     die "no options specified\n" if !$delete_str && !$revert_str && !scalar(keys %$param);
1019
1020     my $storecfg = PVE::Storage::config();
1021
1022     my $defaults = PVE::QemuServer::load_defaults();
1023
1024     &$resolve_cdrom_alias($param);
1025
1026     # now try to verify all parameters
1027
1028     my $revert = {};
1029     foreach my $opt (PVE::Tools::split_list($revert_str)) {
1030         if (!PVE::QemuServer::option_exists($opt)) {
1031             raise_param_exc({ revert => "unknown option '$opt'" });
1032         }
1033
1034         raise_param_exc({ delete => "you can't use '-$opt' and " .
1035                               "-revert $opt' at the same time" })
1036             if defined($param->{$opt});
1037
1038         $revert->{$opt} = 1;
1039     }
1040
1041     my @delete = ();
1042     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1043         $opt = 'ide2' if $opt eq 'cdrom';
1044
1045         raise_param_exc({ delete => "you can't use '-$opt' and " .
1046                               "-delete $opt' at the same time" })
1047             if defined($param->{$opt});
1048
1049         raise_param_exc({ revert => "you can't use '-delete $opt' and " .
1050                               "-revert $opt' at the same time" })
1051             if $revert->{$opt};
1052
1053         if (!PVE::QemuServer::option_exists($opt)) {
1054             raise_param_exc({ delete => "unknown option '$opt'" });
1055         }
1056
1057         push @delete, $opt;
1058     }
1059
1060     my $repl_conf = PVE::ReplicationConfig->new();
1061     my $is_replicated = $repl_conf->check_for_existing_jobs($vmid, 1);
1062     my $check_replication = sub {
1063         my ($drive) = @_;
1064         return if !$is_replicated;
1065         my $volid = $drive->{file};
1066         return if !$volid || !($drive->{replicate}//1);
1067         return if PVE::QemuServer::drive_is_cdrom($drive);
1068         my ($storeid, $format);
1069         if ($volid =~ $NEW_DISK_RE) {
1070             $storeid = $2;
1071             $format = $drive->{format} || PVE::Storage::storage_default_format($storecfg, $storeid);
1072         } else {
1073             ($storeid, undef) = PVE::Storage::parse_volume_id($volid, 1);
1074             $format = (PVE::Storage::parse_volname($storecfg, $volid))[6];
1075         }
1076         return if PVE::Storage::storage_can_replicate($storecfg, $storeid, $format);
1077         my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
1078         return if $scfg->{shared};
1079         die "cannot add non-replicatable volume to a replicated VM\n";
1080     };
1081
1082     foreach my $opt (keys %$param) {
1083         if (PVE::QemuServer::is_valid_drivename($opt)) {
1084             # cleanup drive path
1085             my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1086             raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
1087             PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
1088             $check_replication->($drive);
1089             $param->{$opt} = PVE::QemuServer::print_drive($vmid, $drive);
1090         } elsif ($opt =~ m/^net(\d+)$/) {
1091             # add macaddr
1092             my $net = PVE::QemuServer::parse_net($param->{$opt});
1093             $param->{$opt} = PVE::QemuServer::print_net($net);
1094         }
1095     }
1096
1097     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [@delete]);
1098
1099     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [keys %$param]);
1100
1101     &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param);
1102
1103     my $updatefn =  sub {
1104
1105         my $conf = PVE::QemuConfig->load_config($vmid);
1106
1107         die "checksum missmatch (file change by other user?)\n"
1108             if $digest && $digest ne $conf->{digest};
1109
1110         PVE::QemuConfig->check_lock($conf) if !$skiplock;
1111
1112         foreach my $opt (keys %$revert) {
1113             if (defined($conf->{$opt})) {
1114                 $param->{$opt} = $conf->{$opt};
1115             } elsif (defined($conf->{pending}->{$opt})) {
1116                 push @delete, $opt;
1117             }
1118         }
1119
1120         if ($param->{memory} || defined($param->{balloon})) {
1121             my $maxmem = $param->{memory} || $conf->{pending}->{memory} || $conf->{memory} || $defaults->{memory};
1122             my $balloon = defined($param->{balloon}) ? $param->{balloon} : $conf->{pending}->{balloon} || $conf->{balloon};
1123
1124             die "balloon value too large (must be smaller than assigned memory)\n"
1125                 if $balloon && $balloon > $maxmem;
1126         }
1127
1128         PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: " . join (' ', @paramarr));
1129
1130         my $worker = sub {
1131
1132             print "update VM $vmid: " . join (' ', @paramarr) . "\n";
1133
1134             # write updates to pending section
1135
1136             my $modified = {}; # record what $option we modify
1137
1138             foreach my $opt (@delete) {
1139                 $modified->{$opt} = 1;
1140                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1141                 if (!defined($conf->{$opt}) && !defined($conf->{pending}->{$opt})) {
1142                     warn "cannot delete '$opt' - not set in current configuration!\n";
1143                     $modified->{$opt} = 0;
1144                     next;
1145                 }
1146
1147                 if ($opt =~ m/^unused/) {
1148                     my $drive = PVE::QemuServer::parse_drive($opt, $conf->{$opt});
1149                     PVE::QemuConfig->check_protection($conf, "can't remove unused disk '$drive->{file}'");
1150                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1151                     if (PVE::QemuServer::try_deallocate_drive($storecfg, $vmid, $conf, $opt, $drive, $rpcenv, $authuser)) {
1152                         delete $conf->{$opt};
1153                         PVE::QemuConfig->write_config($vmid, $conf);
1154                     }
1155                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
1156                     PVE::QemuConfig->check_protection($conf, "can't remove drive '$opt'");
1157                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1158                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $conf->{pending}->{$opt}))
1159                         if defined($conf->{pending}->{$opt});
1160                     PVE::QemuServer::vmconfig_delete_pending_option($conf, $opt, $force);
1161                     PVE::QemuConfig->write_config($vmid, $conf);
1162                 } else {
1163                     PVE::QemuServer::vmconfig_delete_pending_option($conf, $opt, $force);
1164                     PVE::QemuConfig->write_config($vmid, $conf);
1165                 }
1166             }
1167
1168             foreach my $opt (keys %$param) { # add/change
1169                 $modified->{$opt} = 1;
1170                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1171                 next if defined($conf->{pending}->{$opt}) && ($param->{$opt} eq $conf->{pending}->{$opt}); # skip if nothing changed
1172
1173                 if (PVE::QemuServer::is_valid_drivename($opt)) {
1174                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1175                     # FIXME: cloudinit: CDROM or Disk?
1176                     if (PVE::QemuServer::drive_is_cdrom($drive)) { # CDROM
1177                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.CDROM']);
1178                     } else {
1179                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1180                     }
1181                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $conf->{pending}->{$opt}))
1182                         if defined($conf->{pending}->{$opt});
1183
1184                     &$create_disks($rpcenv, $authuser, $conf->{pending}, $storecfg, $vmid, undef, {$opt => $param->{$opt}});
1185                 } else {
1186                     $conf->{pending}->{$opt} = $param->{$opt};
1187                 }
1188                 PVE::QemuServer::vmconfig_undelete_pending_option($conf, $opt);
1189                 PVE::QemuConfig->write_config($vmid, $conf);
1190             }
1191
1192             # remove pending changes when nothing changed
1193             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1194             my $changes = PVE::QemuServer::vmconfig_cleanup_pending($conf);
1195             PVE::QemuConfig->write_config($vmid, $conf) if $changes;
1196
1197             return if !scalar(keys %{$conf->{pending}});
1198
1199             my $running = PVE::QemuServer::check_running($vmid);
1200
1201             # apply pending changes
1202
1203             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1204
1205             if ($running) {
1206                 my $errors = {};
1207                 PVE::QemuServer::vmconfig_hotplug_pending($vmid, $conf, $storecfg, $modified, $errors);
1208                 raise_param_exc($errors) if scalar(keys %$errors);
1209             } else {
1210                 PVE::QemuServer::vmconfig_apply_pending($vmid, $conf, $storecfg, $running);
1211             }
1212
1213             return;
1214         };
1215
1216         if ($sync) {
1217             &$worker();
1218             return undef;
1219         } else {
1220             my $upid = $rpcenv->fork_worker('qmconfig', $vmid, $authuser, $worker);
1221
1222             if ($background_delay) {
1223
1224                 # Note: It would be better to do that in the Event based HTTPServer
1225                 # to avoid blocking call to sleep.
1226
1227                 my $end_time = time() + $background_delay;
1228
1229                 my $task = PVE::Tools::upid_decode($upid);
1230
1231                 my $running = 1;
1232                 while (time() < $end_time) {
1233                     $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
1234                     last if !$running;
1235                     sleep(1); # this gets interrupted when child process ends
1236                 }
1237
1238                 if (!$running) {
1239                     my $status = PVE::Tools::upid_read_status($upid);
1240                     return undef if $status eq 'OK';
1241                     die $status;
1242                 }
1243             }
1244
1245             return $upid;
1246         }
1247     };
1248
1249     return PVE::QemuConfig->lock_config($vmid, $updatefn);
1250 };
1251
1252 my $vm_config_perm_list = [
1253             'VM.Config.Disk',
1254             'VM.Config.CDROM',
1255             'VM.Config.CPU',
1256             'VM.Config.Memory',
1257             'VM.Config.Network',
1258             'VM.Config.HWType',
1259             'VM.Config.Options',
1260     ];
1261
1262 __PACKAGE__->register_method({
1263     name => 'update_vm_async',
1264     path => '{vmid}/config',
1265     method => 'POST',
1266     protected => 1,
1267     proxyto => 'node',
1268     description => "Set virtual machine options (asynchrounous API).",
1269     permissions => {
1270         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1271     },
1272     parameters => {
1273         additionalProperties => 0,
1274         properties => PVE::QemuServer::json_config_properties(
1275             {
1276                 node => get_standard_option('pve-node'),
1277                 vmid => get_standard_option('pve-vmid'),
1278                 skiplock => get_standard_option('skiplock'),
1279                 delete => {
1280                     type => 'string', format => 'pve-configid-list',
1281                     description => "A list of settings you want to delete.",
1282                     optional => 1,
1283                 },
1284                 revert => {
1285                     type => 'string', format => 'pve-configid-list',
1286                     description => "Revert a pending change.",
1287                     optional => 1,
1288                 },
1289                 force => {
1290                     type => 'boolean',
1291                     description => $opt_force_description,
1292                     optional => 1,
1293                     requires => 'delete',
1294                 },
1295                 digest => {
1296                     type => 'string',
1297                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1298                     maxLength => 40,
1299                     optional => 1,
1300                 },
1301                 background_delay => {
1302                     type => 'integer',
1303                     description => "Time to wait for the task to finish. We return 'null' if the task finish within that time.",
1304                     minimum => 1,
1305                     maximum => 30,
1306                     optional => 1,
1307                 },
1308             }),
1309     },
1310     returns => {
1311         type => 'string',
1312         optional => 1,
1313     },
1314     code => $update_vm_api,
1315 });
1316
1317 __PACKAGE__->register_method({
1318     name => 'update_vm',
1319     path => '{vmid}/config',
1320     method => 'PUT',
1321     protected => 1,
1322     proxyto => 'node',
1323     description => "Set virtual machine options (synchrounous API) - You should consider using the POST method instead for any actions involving hotplug or storage allocation.",
1324     permissions => {
1325         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1326     },
1327     parameters => {
1328         additionalProperties => 0,
1329         properties => PVE::QemuServer::json_config_properties(
1330             {
1331                 node => get_standard_option('pve-node'),
1332                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1333                 skiplock => get_standard_option('skiplock'),
1334                 delete => {
1335                     type => 'string', format => 'pve-configid-list',
1336                     description => "A list of settings you want to delete.",
1337                     optional => 1,
1338                 },
1339                 revert => {
1340                     type => 'string', format => 'pve-configid-list',
1341                     description => "Revert a pending change.",
1342                     optional => 1,
1343                 },
1344                 force => {
1345                     type => 'boolean',
1346                     description => $opt_force_description,
1347                     optional => 1,
1348                     requires => 'delete',
1349                 },
1350                 digest => {
1351                     type => 'string',
1352                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1353                     maxLength => 40,
1354                     optional => 1,
1355                 },
1356             }),
1357     },
1358     returns => { type => 'null' },
1359     code => sub {
1360         my ($param) = @_;
1361         &$update_vm_api($param, 1);
1362         return undef;
1363     }
1364 });
1365
1366
1367 __PACKAGE__->register_method({
1368     name => 'destroy_vm',
1369     path => '{vmid}',
1370     method => 'DELETE',
1371     protected => 1,
1372     proxyto => 'node',
1373     description => "Destroy the vm (also delete all used/owned volumes).",
1374     permissions => {
1375         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
1376     },
1377     parameters => {
1378         additionalProperties => 0,
1379         properties => {
1380             node => get_standard_option('pve-node'),
1381             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
1382             skiplock => get_standard_option('skiplock'),
1383         },
1384     },
1385     returns => {
1386         type => 'string',
1387     },
1388     code => sub {
1389         my ($param) = @_;
1390
1391         my $rpcenv = PVE::RPCEnvironment::get();
1392
1393         my $authuser = $rpcenv->get_user();
1394
1395         my $vmid = $param->{vmid};
1396
1397         my $skiplock = $param->{skiplock};
1398         raise_param_exc({ skiplock => "Only root may use this option." })
1399             if $skiplock && $authuser ne 'root@pam';
1400
1401         # test if VM exists
1402         my $conf = PVE::QemuConfig->load_config($vmid);
1403
1404         my $storecfg = PVE::Storage::config();
1405
1406         PVE::QemuConfig->check_protection($conf, "can't remove VM $vmid");
1407
1408         die "unable to remove VM $vmid - used in HA resources\n"
1409             if PVE::HA::Config::vm_is_ha_managed($vmid);
1410
1411         # do not allow destroy if there are replication jobs
1412         my $repl_conf = PVE::ReplicationConfig->new();
1413         $repl_conf->check_for_existing_jobs($vmid);
1414
1415         # early tests (repeat after locking)
1416         die "VM $vmid is running - destroy failed\n"
1417             if PVE::QemuServer::check_running($vmid);
1418
1419         my $realcmd = sub {
1420             my $upid = shift;
1421
1422             syslog('info', "destroy VM $vmid: $upid\n");
1423
1424             PVE::QemuServer::vm_destroy($storecfg, $vmid, $skiplock);
1425
1426             PVE::AccessControl::remove_vm_access($vmid);
1427
1428             PVE::Firewall::remove_vmfw_conf($vmid);
1429         };
1430
1431         return $rpcenv->fork_worker('qmdestroy', $vmid, $authuser, $realcmd);
1432     }});
1433
1434 __PACKAGE__->register_method({
1435     name => 'unlink',
1436     path => '{vmid}/unlink',
1437     method => 'PUT',
1438     protected => 1,
1439     proxyto => 'node',
1440     description => "Unlink/delete disk images.",
1441     permissions => {
1442         check => [ 'perm', '/vms/{vmid}', ['VM.Config.Disk']],
1443     },
1444     parameters => {
1445         additionalProperties => 0,
1446         properties => {
1447             node => get_standard_option('pve-node'),
1448             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1449             idlist => {
1450                 type => 'string', format => 'pve-configid-list',
1451                 description => "A list of disk IDs you want to delete.",
1452             },
1453             force => {
1454                 type => 'boolean',
1455                 description => $opt_force_description,
1456                 optional => 1,
1457             },
1458         },
1459     },
1460     returns => { type => 'null'},
1461     code => sub {
1462         my ($param) = @_;
1463
1464         $param->{delete} = extract_param($param, 'idlist');
1465
1466         __PACKAGE__->update_vm($param);
1467
1468         return undef;
1469     }});
1470
1471 my $sslcert;
1472
1473 __PACKAGE__->register_method({
1474     name => 'vncproxy',
1475     path => '{vmid}/vncproxy',
1476     method => 'POST',
1477     protected => 1,
1478     permissions => {
1479         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1480     },
1481     description => "Creates a TCP VNC proxy connections.",
1482     parameters => {
1483         additionalProperties => 0,
1484         properties => {
1485             node => get_standard_option('pve-node'),
1486             vmid => get_standard_option('pve-vmid'),
1487             websocket => {
1488                 optional => 1,
1489                 type => 'boolean',
1490                 description => "starts websockify instead of vncproxy",
1491             },
1492         },
1493     },
1494     returns => {
1495         additionalProperties => 0,
1496         properties => {
1497             user => { type => 'string' },
1498             ticket => { type => 'string' },
1499             cert => { type => 'string' },
1500             port => { type => 'integer' },
1501             upid => { type => 'string' },
1502         },
1503     },
1504     code => sub {
1505         my ($param) = @_;
1506
1507         my $rpcenv = PVE::RPCEnvironment::get();
1508
1509         my $authuser = $rpcenv->get_user();
1510
1511         my $vmid = $param->{vmid};
1512         my $node = $param->{node};
1513         my $websocket = $param->{websocket};
1514
1515         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1516
1517         my $authpath = "/vms/$vmid";
1518
1519         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1520
1521         $sslcert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192)
1522             if !$sslcert;
1523
1524         my ($remip, $family);
1525         my $remcmd = [];
1526
1527         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1528             ($remip, $family) = PVE::Cluster::remote_node_ip($node);
1529             # NOTE: kvm VNC traffic is already TLS encrypted or is known unsecure
1530             $remcmd = ['/usr/bin/ssh', '-e', 'none', '-T', '-o', 'BatchMode=yes', $remip];
1531         } else {
1532             $family = PVE::Tools::get_host_address_family($node);
1533         }
1534
1535         my $port = PVE::Tools::next_vnc_port($family);
1536
1537         my $timeout = 10;
1538
1539         my $realcmd = sub {
1540             my $upid = shift;
1541
1542             syslog('info', "starting vnc proxy $upid\n");
1543
1544             my $cmd;
1545
1546             if ($conf->{vga} && ($conf->{vga} =~ m/^serial\d+$/)) {
1547
1548
1549                 my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-iface', $conf->{vga}, '-escape', '0' ];
1550
1551                 $cmd = ['/usr/bin/vncterm', '-rfbport', $port,
1552                         '-timeout', $timeout, '-authpath', $authpath,
1553                         '-perm', 'Sys.Console'];
1554
1555                 if ($param->{websocket}) {
1556                     $ENV{PVE_VNC_TICKET} = $ticket; # pass ticket to vncterm
1557                     push @$cmd, '-notls', '-listen', 'localhost';
1558                 }
1559
1560                 push @$cmd, '-c', @$remcmd, @$termcmd;
1561
1562                 PVE::Tools::run_command($cmd);
1563
1564             } else {
1565
1566                 $ENV{LC_PVE_TICKET} = $ticket if $websocket; # set ticket with "qm vncproxy"
1567
1568                 $cmd = [@$remcmd, "/usr/sbin/qm", 'vncproxy', $vmid];
1569
1570                 my $sock = IO::Socket::IP->new(
1571                     ReuseAddr => 1,
1572                     Listen => 1,
1573                     LocalPort => $port,
1574                     Proto => 'tcp',
1575                     GetAddrInfoFlags => 0,
1576                     ) or die "failed to create socket: $!\n";
1577                 # Inside the worker we shouldn't have any previous alarms
1578                 # running anyway...:
1579                 alarm(0);
1580                 local $SIG{ALRM} = sub { die "connection timed out\n" };
1581                 alarm $timeout;
1582                 accept(my $cli, $sock) or die "connection failed: $!\n";
1583                 alarm(0);
1584                 close($sock);
1585                 if (PVE::Tools::run_command($cmd,
1586                     output => '>&'.fileno($cli),
1587                     input => '<&'.fileno($cli),
1588                     noerr => 1) != 0)
1589                 {
1590                     die "Failed to run vncproxy.\n";
1591                 }
1592             }
1593
1594             return;
1595         };
1596
1597         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1598
1599         PVE::Tools::wait_for_vnc_port($port);
1600
1601         return {
1602             user => $authuser,
1603             ticket => $ticket,
1604             port => $port,
1605             upid => $upid,
1606             cert => $sslcert,
1607         };
1608     }});
1609
1610 __PACKAGE__->register_method({
1611     name => 'termproxy',
1612     path => '{vmid}/termproxy',
1613     method => 'POST',
1614     protected => 1,
1615     permissions => {
1616         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1617     },
1618     description => "Creates a TCP proxy connections.",
1619     parameters => {
1620         additionalProperties => 0,
1621         properties => {
1622             node => get_standard_option('pve-node'),
1623             vmid => get_standard_option('pve-vmid'),
1624             serial=> {
1625                 optional => 1,
1626                 type => 'string',
1627                 enum => [qw(serial0 serial1 serial2 serial3)],
1628                 description => "opens a serial terminal (defaults to display)",
1629             },
1630         },
1631     },
1632     returns => {
1633         additionalProperties => 0,
1634         properties => {
1635             user => { type => 'string' },
1636             ticket => { type => 'string' },
1637             port => { type => 'integer' },
1638             upid => { type => 'string' },
1639         },
1640     },
1641     code => sub {
1642         my ($param) = @_;
1643
1644         my $rpcenv = PVE::RPCEnvironment::get();
1645
1646         my $authuser = $rpcenv->get_user();
1647
1648         my $vmid = $param->{vmid};
1649         my $node = $param->{node};
1650         my $serial = $param->{serial};
1651
1652         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1653
1654         if (!defined($serial)) {
1655             if ($conf->{vga} && $conf->{vga} =~ m/^serial\d+$/) {
1656                 $serial = $conf->{vga};
1657             }
1658         }
1659
1660         my $authpath = "/vms/$vmid";
1661
1662         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1663
1664         my ($remip, $family);
1665
1666         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1667             ($remip, $family) = PVE::Cluster::remote_node_ip($node);
1668         } else {
1669             $family = PVE::Tools::get_host_address_family($node);
1670         }
1671
1672         my $port = PVE::Tools::next_vnc_port($family);
1673
1674         my $remcmd = $remip ?
1675             ['/usr/bin/ssh', '-e', 'none', '-t', $remip, '--'] : [];
1676
1677         my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-escape', '0'];
1678         push @$termcmd, '-iface', $serial if $serial;
1679
1680         my $realcmd = sub {
1681             my $upid = shift;
1682
1683             syslog('info', "starting qemu termproxy $upid\n");
1684
1685             my $cmd = ['/usr/bin/termproxy', $port, '--path', $authpath,
1686                        '--perm', 'VM.Console', '--'];
1687             push @$cmd, @$remcmd, @$termcmd;
1688
1689             PVE::Tools::run_command($cmd);
1690         };
1691
1692         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1693
1694         PVE::Tools::wait_for_vnc_port($port);
1695
1696         return {
1697             user => $authuser,
1698             ticket => $ticket,
1699             port => $port,
1700             upid => $upid,
1701         };
1702     }});
1703
1704 __PACKAGE__->register_method({
1705     name => 'vncwebsocket',
1706     path => '{vmid}/vncwebsocket',
1707     method => 'GET',
1708     permissions => {
1709         description => "You also need to pass a valid ticket (vncticket).",
1710         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1711     },
1712     description => "Opens a weksocket for VNC traffic.",
1713     parameters => {
1714         additionalProperties => 0,
1715         properties => {
1716             node => get_standard_option('pve-node'),
1717             vmid => get_standard_option('pve-vmid'),
1718             vncticket => {
1719                 description => "Ticket from previous call to vncproxy.",
1720                 type => 'string',
1721                 maxLength => 512,
1722             },
1723             port => {
1724                 description => "Port number returned by previous vncproxy call.",
1725                 type => 'integer',
1726                 minimum => 5900,
1727                 maximum => 5999,
1728             },
1729         },
1730     },
1731     returns => {
1732         type => "object",
1733         properties => {
1734             port => { type => 'string' },
1735         },
1736     },
1737     code => sub {
1738         my ($param) = @_;
1739
1740         my $rpcenv = PVE::RPCEnvironment::get();
1741
1742         my $authuser = $rpcenv->get_user();
1743
1744         my $vmid = $param->{vmid};
1745         my $node = $param->{node};
1746
1747         my $authpath = "/vms/$vmid";
1748
1749         PVE::AccessControl::verify_vnc_ticket($param->{vncticket}, $authuser, $authpath);
1750
1751         my $conf = PVE::QemuConfig->load_config($vmid, $node); # VM exists ?
1752
1753         # Note: VNC ports are acessible from outside, so we do not gain any
1754         # security if we verify that $param->{port} belongs to VM $vmid. This
1755         # check is done by verifying the VNC ticket (inside VNC protocol).
1756
1757         my $port = $param->{port};
1758
1759         return { port => $port };
1760     }});
1761
1762 __PACKAGE__->register_method({
1763     name => 'spiceproxy',
1764     path => '{vmid}/spiceproxy',
1765     method => 'POST',
1766     protected => 1,
1767     proxyto => 'node',
1768     permissions => {
1769         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1770     },
1771     description => "Returns a SPICE configuration to connect to the VM.",
1772     parameters => {
1773         additionalProperties => 0,
1774         properties => {
1775             node => get_standard_option('pve-node'),
1776             vmid => get_standard_option('pve-vmid'),
1777             proxy => get_standard_option('spice-proxy', { optional => 1 }),
1778         },
1779     },
1780     returns => get_standard_option('remote-viewer-config'),
1781     code => sub {
1782         my ($param) = @_;
1783
1784         my $rpcenv = PVE::RPCEnvironment::get();
1785
1786         my $authuser = $rpcenv->get_user();
1787
1788         my $vmid = $param->{vmid};
1789         my $node = $param->{node};
1790         my $proxy = $param->{proxy};
1791
1792         my $conf = PVE::QemuConfig->load_config($vmid, $node);
1793         my $title = "VM $vmid";
1794         $title .= " - ". $conf->{name} if $conf->{name};
1795
1796         my $port = PVE::QemuServer::spice_port($vmid);
1797
1798         my ($ticket, undef, $remote_viewer_config) =
1799             PVE::AccessControl::remote_viewer_config($authuser, $vmid, $node, $proxy, $title, $port);
1800
1801         PVE::QemuServer::vm_mon_cmd($vmid, "set_password", protocol => 'spice', password => $ticket);
1802         PVE::QemuServer::vm_mon_cmd($vmid, "expire_password", protocol => 'spice', time => "+30");
1803
1804         return $remote_viewer_config;
1805     }});
1806
1807 __PACKAGE__->register_method({
1808     name => 'vmcmdidx',
1809     path => '{vmid}/status',
1810     method => 'GET',
1811     proxyto => 'node',
1812     description => "Directory index",
1813     permissions => {
1814         user => 'all',
1815     },
1816     parameters => {
1817         additionalProperties => 0,
1818         properties => {
1819             node => get_standard_option('pve-node'),
1820             vmid => get_standard_option('pve-vmid'),
1821         },
1822     },
1823     returns => {
1824         type => 'array',
1825         items => {
1826             type => "object",
1827             properties => {
1828                 subdir => { type => 'string' },
1829             },
1830         },
1831         links => [ { rel => 'child', href => "{subdir}" } ],
1832     },
1833     code => sub {
1834         my ($param) = @_;
1835
1836         # test if VM exists
1837         my $conf = PVE::QemuConfig->load_config($param->{vmid});
1838
1839         my $res = [
1840             { subdir => 'current' },
1841             { subdir => 'start' },
1842             { subdir => 'stop' },
1843             ];
1844
1845         return $res;
1846     }});
1847
1848 __PACKAGE__->register_method({
1849     name => 'vm_status',
1850     path => '{vmid}/status/current',
1851     method => 'GET',
1852     proxyto => 'node',
1853     protected => 1, # qemu pid files are only readable by root
1854     description => "Get virtual machine status.",
1855     permissions => {
1856         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1857     },
1858     parameters => {
1859         additionalProperties => 0,
1860         properties => {
1861             node => get_standard_option('pve-node'),
1862             vmid => get_standard_option('pve-vmid'),
1863         },
1864     },
1865     returns => { type => 'object' },
1866     code => sub {
1867         my ($param) = @_;
1868
1869         # test if VM exists
1870         my $conf = PVE::QemuConfig->load_config($param->{vmid});
1871
1872         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid}, 1);
1873         my $status = $vmstatus->{$param->{vmid}};
1874
1875         $status->{ha} = PVE::HA::Config::get_service_status("vm:$param->{vmid}");
1876
1877         $status->{spice} = 1 if PVE::QemuServer::vga_conf_has_spice($conf->{vga});
1878
1879         $status->{agent} = 1 if $conf->{agent};
1880
1881         return $status;
1882     }});
1883
1884 __PACKAGE__->register_method({
1885     name => 'vm_start',
1886     path => '{vmid}/status/start',
1887     method => 'POST',
1888     protected => 1,
1889     proxyto => 'node',
1890     description => "Start virtual machine.",
1891     permissions => {
1892         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
1893     },
1894     parameters => {
1895         additionalProperties => 0,
1896         properties => {
1897             node => get_standard_option('pve-node'),
1898             vmid => get_standard_option('pve-vmid',
1899                                         { completion => \&PVE::QemuServer::complete_vmid_stopped }),
1900             skiplock => get_standard_option('skiplock'),
1901             stateuri => get_standard_option('pve-qm-stateuri'),
1902             migratedfrom => get_standard_option('pve-node',{ optional => 1 }),
1903             migration_type => {
1904                 type => 'string',
1905                 enum => ['secure', 'insecure'],
1906                 description => "Migration traffic is encrypted using an SSH " .
1907                   "tunnel by default. On secure, completely private networks " .
1908                   "this can be disabled to increase performance.",
1909                 optional => 1,
1910             },
1911             migration_network => {
1912                 type => 'string', format => 'CIDR',
1913                 description => "CIDR of the (sub) network that is used for migration.",
1914                 optional => 1,
1915             },
1916             machine => get_standard_option('pve-qm-machine'),
1917             targetstorage => {
1918                 description => "Target storage for the migration. (Can be '1' to use the same storage id as on the source node.)",
1919                 type => 'string',
1920                 optional => 1
1921             }
1922         },
1923     },
1924     returns => {
1925         type => 'string',
1926     },
1927     code => sub {
1928         my ($param) = @_;
1929
1930         my $rpcenv = PVE::RPCEnvironment::get();
1931
1932         my $authuser = $rpcenv->get_user();
1933
1934         my $node = extract_param($param, 'node');
1935
1936         my $vmid = extract_param($param, 'vmid');
1937
1938         my $machine = extract_param($param, 'machine');
1939
1940         my $stateuri = extract_param($param, 'stateuri');
1941         raise_param_exc({ stateuri => "Only root may use this option." })
1942             if $stateuri && $authuser ne 'root@pam';
1943
1944         my $skiplock = extract_param($param, 'skiplock');
1945         raise_param_exc({ skiplock => "Only root may use this option." })
1946             if $skiplock && $authuser ne 'root@pam';
1947
1948         my $migratedfrom = extract_param($param, 'migratedfrom');
1949         raise_param_exc({ migratedfrom => "Only root may use this option." })
1950             if $migratedfrom && $authuser ne 'root@pam';
1951
1952         my $migration_type = extract_param($param, 'migration_type');
1953         raise_param_exc({ migration_type => "Only root may use this option." })
1954             if $migration_type && $authuser ne 'root@pam';
1955
1956         my $migration_network = extract_param($param, 'migration_network');
1957         raise_param_exc({ migration_network => "Only root may use this option." })
1958             if $migration_network && $authuser ne 'root@pam';
1959
1960         my $targetstorage = extract_param($param, 'targetstorage');
1961         raise_param_exc({ targetstorage => "Only root may use this option." })
1962             if $targetstorage && $authuser ne 'root@pam';
1963
1964         raise_param_exc({ targetstorage => "targetstorage can only by used with migratedfrom." })
1965             if $targetstorage && !$migratedfrom;
1966
1967         # read spice ticket from STDIN
1968         my $spice_ticket;
1969         if ($stateuri && ($stateuri eq 'tcp') && $migratedfrom && ($rpcenv->{type} eq 'cli')) {
1970             if (defined(my $line = <STDIN>)) {
1971                 chomp $line;
1972                 $spice_ticket = $line;
1973             }
1974         }
1975
1976         PVE::Cluster::check_cfs_quorum();
1977
1978         my $storecfg = PVE::Storage::config();
1979
1980         if (PVE::HA::Config::vm_is_ha_managed($vmid) && !$stateuri &&
1981             $rpcenv->{type} ne 'ha') {
1982
1983             my $hacmd = sub {
1984                 my $upid = shift;
1985
1986                 my $service = "vm:$vmid";
1987
1988                 my $cmd = ['ha-manager', 'set', $service, '--state', 'started'];
1989
1990                 print "Requesting HA start for VM $vmid\n";
1991
1992                 PVE::Tools::run_command($cmd);
1993
1994                 return;
1995             };
1996
1997             return $rpcenv->fork_worker('hastart', $vmid, $authuser, $hacmd);
1998
1999         } else {
2000
2001             my $realcmd = sub {
2002                 my $upid = shift;
2003
2004                 syslog('info', "start VM $vmid: $upid\n");
2005
2006                 PVE::QemuServer::vm_start($storecfg, $vmid, $stateuri, $skiplock, $migratedfrom, undef,
2007                                           $machine, $spice_ticket, $migration_network, $migration_type, $targetstorage);
2008
2009                 return;
2010             };
2011
2012             return $rpcenv->fork_worker('qmstart', $vmid, $authuser, $realcmd);
2013         }
2014     }});
2015
2016 __PACKAGE__->register_method({
2017     name => 'vm_stop',
2018     path => '{vmid}/status/stop',
2019     method => 'POST',
2020     protected => 1,
2021     proxyto => 'node',
2022     description => "Stop virtual machine. The qemu process will exit immediately. This" .
2023         "is akin to pulling the power plug of a running computer and may damage the VM data",
2024     permissions => {
2025         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2026     },
2027     parameters => {
2028         additionalProperties => 0,
2029         properties => {
2030             node => get_standard_option('pve-node'),
2031             vmid => get_standard_option('pve-vmid',
2032                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2033             skiplock => get_standard_option('skiplock'),
2034             migratedfrom => get_standard_option('pve-node', { optional => 1 }),
2035             timeout => {
2036                 description => "Wait maximal timeout seconds.",
2037                 type => 'integer',
2038                 minimum => 0,
2039                 optional => 1,
2040             },
2041             keepActive => {
2042                 description => "Do not deactivate storage volumes.",
2043                 type => 'boolean',
2044                 optional => 1,
2045                 default => 0,
2046             }
2047         },
2048     },
2049     returns => {
2050         type => 'string',
2051     },
2052     code => sub {
2053         my ($param) = @_;
2054
2055         my $rpcenv = PVE::RPCEnvironment::get();
2056
2057         my $authuser = $rpcenv->get_user();
2058
2059         my $node = extract_param($param, 'node');
2060
2061         my $vmid = extract_param($param, 'vmid');
2062
2063         my $skiplock = extract_param($param, 'skiplock');
2064         raise_param_exc({ skiplock => "Only root may use this option." })
2065             if $skiplock && $authuser ne 'root@pam';
2066
2067         my $keepActive = extract_param($param, 'keepActive');
2068         raise_param_exc({ keepActive => "Only root may use this option." })
2069             if $keepActive && $authuser ne 'root@pam';
2070
2071         my $migratedfrom = extract_param($param, 'migratedfrom');
2072         raise_param_exc({ migratedfrom => "Only root may use this option." })
2073             if $migratedfrom && $authuser ne 'root@pam';
2074
2075
2076         my $storecfg = PVE::Storage::config();
2077
2078         if (PVE::HA::Config::vm_is_ha_managed($vmid) && ($rpcenv->{type} ne 'ha') && !defined($migratedfrom)) {
2079
2080             my $hacmd = sub {
2081                 my $upid = shift;
2082
2083                 my $service = "vm:$vmid";
2084
2085                 my $cmd = ['ha-manager', 'set', $service, '--state', 'stopped'];
2086
2087                 print "Requesting HA stop for VM $vmid\n";
2088
2089                 PVE::Tools::run_command($cmd);
2090
2091                 return;
2092             };
2093
2094             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2095
2096         } else {
2097             my $realcmd = sub {
2098                 my $upid = shift;
2099
2100                 syslog('info', "stop VM $vmid: $upid\n");
2101
2102                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0,
2103                                          $param->{timeout}, 0, 1, $keepActive, $migratedfrom);
2104
2105                 return;
2106             };
2107
2108             return $rpcenv->fork_worker('qmstop', $vmid, $authuser, $realcmd);
2109         }
2110     }});
2111
2112 __PACKAGE__->register_method({
2113     name => 'vm_reset',
2114     path => '{vmid}/status/reset',
2115     method => 'POST',
2116     protected => 1,
2117     proxyto => 'node',
2118     description => "Reset virtual machine.",
2119     permissions => {
2120         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2121     },
2122     parameters => {
2123         additionalProperties => 0,
2124         properties => {
2125             node => get_standard_option('pve-node'),
2126             vmid => get_standard_option('pve-vmid',
2127                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2128             skiplock => get_standard_option('skiplock'),
2129         },
2130     },
2131     returns => {
2132         type => 'string',
2133     },
2134     code => sub {
2135         my ($param) = @_;
2136
2137         my $rpcenv = PVE::RPCEnvironment::get();
2138
2139         my $authuser = $rpcenv->get_user();
2140
2141         my $node = extract_param($param, 'node');
2142
2143         my $vmid = extract_param($param, 'vmid');
2144
2145         my $skiplock = extract_param($param, 'skiplock');
2146         raise_param_exc({ skiplock => "Only root may use this option." })
2147             if $skiplock && $authuser ne 'root@pam';
2148
2149         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2150
2151         my $realcmd = sub {
2152             my $upid = shift;
2153
2154             PVE::QemuServer::vm_reset($vmid, $skiplock);
2155
2156             return;
2157         };
2158
2159         return $rpcenv->fork_worker('qmreset', $vmid, $authuser, $realcmd);
2160     }});
2161
2162 __PACKAGE__->register_method({
2163     name => 'vm_shutdown',
2164     path => '{vmid}/status/shutdown',
2165     method => 'POST',
2166     protected => 1,
2167     proxyto => 'node',
2168     description => "Shutdown virtual machine. This is similar to pressing the power button on a physical machine." .
2169         "This will send an ACPI event for the guest OS, which should then proceed to a clean shutdown.",
2170     permissions => {
2171         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2172     },
2173     parameters => {
2174         additionalProperties => 0,
2175         properties => {
2176             node => get_standard_option('pve-node'),
2177             vmid => get_standard_option('pve-vmid',
2178                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2179             skiplock => get_standard_option('skiplock'),
2180             timeout => {
2181                 description => "Wait maximal timeout seconds.",
2182                 type => 'integer',
2183                 minimum => 0,
2184                 optional => 1,
2185             },
2186             forceStop => {
2187                 description => "Make sure the VM stops.",
2188                 type => 'boolean',
2189                 optional => 1,
2190                 default => 0,
2191             },
2192             keepActive => {
2193                 description => "Do not deactivate storage volumes.",
2194                 type => 'boolean',
2195                 optional => 1,
2196                 default => 0,
2197             }
2198         },
2199     },
2200     returns => {
2201         type => 'string',
2202     },
2203     code => sub {
2204         my ($param) = @_;
2205
2206         my $rpcenv = PVE::RPCEnvironment::get();
2207
2208         my $authuser = $rpcenv->get_user();
2209
2210         my $node = extract_param($param, 'node');
2211
2212         my $vmid = extract_param($param, 'vmid');
2213
2214         my $skiplock = extract_param($param, 'skiplock');
2215         raise_param_exc({ skiplock => "Only root may use this option." })
2216             if $skiplock && $authuser ne 'root@pam';
2217
2218         my $keepActive = extract_param($param, 'keepActive');
2219         raise_param_exc({ keepActive => "Only root may use this option." })
2220             if $keepActive && $authuser ne 'root@pam';
2221
2222         my $storecfg = PVE::Storage::config();
2223
2224         my $shutdown = 1;
2225
2226         # if vm is paused, do not shutdown (but stop if forceStop = 1)
2227         # otherwise, we will infer a shutdown command, but run into the timeout,
2228         # then when the vm is resumed, it will instantly shutdown
2229         #
2230         # checking the qmp status here to get feedback to the gui/cli/api
2231         # and the status query should not take too long
2232         my $qmpstatus;
2233         eval {
2234             $qmpstatus = PVE::QemuServer::vm_qmp_command($vmid, { execute => "query-status" }, 0);
2235         };
2236         my $err = $@ if $@;
2237
2238         if (!$err && $qmpstatus->{status} eq "paused") {
2239             if ($param->{forceStop}) {
2240                 warn "VM is paused - stop instead of shutdown\n";
2241                 $shutdown = 0;
2242             } else {
2243                 die "VM is paused - cannot shutdown\n";
2244             }
2245         }
2246
2247         if (PVE::HA::Config::vm_is_ha_managed($vmid) &&
2248             ($rpcenv->{type} ne 'ha')) {
2249
2250             my $hacmd = sub {
2251                 my $upid = shift;
2252
2253                 my $service = "vm:$vmid";
2254
2255                 my $cmd = ['ha-manager', 'set', $service, '--state', 'stopped'];
2256
2257                 print "Requesting HA stop for VM $vmid\n";
2258
2259                 PVE::Tools::run_command($cmd);
2260
2261                 return;
2262             };
2263
2264             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2265
2266         } else {
2267
2268             my $realcmd = sub {
2269                 my $upid = shift;
2270
2271                 syslog('info', "shutdown VM $vmid: $upid\n");
2272
2273                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0, $param->{timeout},
2274                                          $shutdown, $param->{forceStop}, $keepActive);
2275
2276                 return;
2277             };
2278
2279             return $rpcenv->fork_worker('qmshutdown', $vmid, $authuser, $realcmd);
2280         }
2281     }});
2282
2283 __PACKAGE__->register_method({
2284     name => 'vm_suspend',
2285     path => '{vmid}/status/suspend',
2286     method => 'POST',
2287     protected => 1,
2288     proxyto => 'node',
2289     description => "Suspend virtual machine.",
2290     permissions => {
2291         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2292     },
2293     parameters => {
2294         additionalProperties => 0,
2295         properties => {
2296             node => get_standard_option('pve-node'),
2297             vmid => get_standard_option('pve-vmid',
2298                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2299             skiplock => get_standard_option('skiplock'),
2300         },
2301     },
2302     returns => {
2303         type => 'string',
2304     },
2305     code => sub {
2306         my ($param) = @_;
2307
2308         my $rpcenv = PVE::RPCEnvironment::get();
2309
2310         my $authuser = $rpcenv->get_user();
2311
2312         my $node = extract_param($param, 'node');
2313
2314         my $vmid = extract_param($param, 'vmid');
2315
2316         my $skiplock = extract_param($param, 'skiplock');
2317         raise_param_exc({ skiplock => "Only root may use this option." })
2318             if $skiplock && $authuser ne 'root@pam';
2319
2320         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2321
2322         my $realcmd = sub {
2323             my $upid = shift;
2324
2325             syslog('info', "suspend VM $vmid: $upid\n");
2326
2327             PVE::QemuServer::vm_suspend($vmid, $skiplock);
2328
2329             return;
2330         };
2331
2332         return $rpcenv->fork_worker('qmsuspend', $vmid, $authuser, $realcmd);
2333     }});
2334
2335 __PACKAGE__->register_method({
2336     name => 'vm_resume',
2337     path => '{vmid}/status/resume',
2338     method => 'POST',
2339     protected => 1,
2340     proxyto => 'node',
2341     description => "Resume virtual machine.",
2342     permissions => {
2343         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2344     },
2345     parameters => {
2346         additionalProperties => 0,
2347         properties => {
2348             node => get_standard_option('pve-node'),
2349             vmid => get_standard_option('pve-vmid',
2350                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2351             skiplock => get_standard_option('skiplock'),
2352             nocheck => { type => 'boolean', optional => 1 },
2353
2354         },
2355     },
2356     returns => {
2357         type => 'string',
2358     },
2359     code => sub {
2360         my ($param) = @_;
2361
2362         my $rpcenv = PVE::RPCEnvironment::get();
2363
2364         my $authuser = $rpcenv->get_user();
2365
2366         my $node = extract_param($param, 'node');
2367
2368         my $vmid = extract_param($param, 'vmid');
2369
2370         my $skiplock = extract_param($param, 'skiplock');
2371         raise_param_exc({ skiplock => "Only root may use this option." })
2372             if $skiplock && $authuser ne 'root@pam';
2373
2374         my $nocheck = extract_param($param, 'nocheck');
2375
2376         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid, $nocheck);
2377
2378         my $realcmd = sub {
2379             my $upid = shift;
2380
2381             syslog('info', "resume VM $vmid: $upid\n");
2382
2383             PVE::QemuServer::vm_resume($vmid, $skiplock, $nocheck);
2384
2385             return;
2386         };
2387
2388         return $rpcenv->fork_worker('qmresume', $vmid, $authuser, $realcmd);
2389     }});
2390
2391 __PACKAGE__->register_method({
2392     name => 'vm_sendkey',
2393     path => '{vmid}/sendkey',
2394     method => 'PUT',
2395     protected => 1,
2396     proxyto => 'node',
2397     description => "Send key event to virtual machine.",
2398     permissions => {
2399         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
2400     },
2401     parameters => {
2402         additionalProperties => 0,
2403         properties => {
2404             node => get_standard_option('pve-node'),
2405             vmid => get_standard_option('pve-vmid',
2406                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2407             skiplock => get_standard_option('skiplock'),
2408             key => {
2409                 description => "The key (qemu monitor encoding).",
2410                 type => 'string'
2411             }
2412         },
2413     },
2414     returns => { type => 'null'},
2415     code => sub {
2416         my ($param) = @_;
2417
2418         my $rpcenv = PVE::RPCEnvironment::get();
2419
2420         my $authuser = $rpcenv->get_user();
2421
2422         my $node = extract_param($param, 'node');
2423
2424         my $vmid = extract_param($param, 'vmid');
2425
2426         my $skiplock = extract_param($param, 'skiplock');
2427         raise_param_exc({ skiplock => "Only root may use this option." })
2428             if $skiplock && $authuser ne 'root@pam';
2429
2430         PVE::QemuServer::vm_sendkey($vmid, $skiplock, $param->{key});
2431
2432         return;
2433     }});
2434
2435 __PACKAGE__->register_method({
2436     name => 'vm_feature',
2437     path => '{vmid}/feature',
2438     method => 'GET',
2439     proxyto => 'node',
2440     protected => 1,
2441     description => "Check if feature for virtual machine is available.",
2442     permissions => {
2443         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
2444     },
2445     parameters => {
2446         additionalProperties => 0,
2447         properties => {
2448             node => get_standard_option('pve-node'),
2449             vmid => get_standard_option('pve-vmid'),
2450             feature => {
2451                 description => "Feature to check.",
2452                 type => 'string',
2453                 enum => [ 'snapshot', 'clone', 'copy' ],
2454             },
2455             snapname => get_standard_option('pve-snapshot-name', {
2456                 optional => 1,
2457             }),
2458         },
2459     },
2460     returns => {
2461         type => "object",
2462         properties => {
2463             hasFeature => { type => 'boolean' },
2464             nodes => {
2465                 type => 'array',
2466                 items => { type => 'string' },
2467             }
2468         },
2469     },
2470     code => sub {
2471         my ($param) = @_;
2472
2473         my $node = extract_param($param, 'node');
2474
2475         my $vmid = extract_param($param, 'vmid');
2476
2477         my $snapname = extract_param($param, 'snapname');
2478
2479         my $feature = extract_param($param, 'feature');
2480
2481         my $running = PVE::QemuServer::check_running($vmid);
2482
2483         my $conf = PVE::QemuConfig->load_config($vmid);
2484
2485         if($snapname){
2486             my $snap = $conf->{snapshots}->{$snapname};
2487             die "snapshot '$snapname' does not exist\n" if !defined($snap);
2488             $conf = $snap;
2489         }
2490         my $storecfg = PVE::Storage::config();
2491
2492         my $nodelist = PVE::QemuServer::shared_nodes($conf, $storecfg);
2493         my $hasFeature = PVE::QemuConfig->has_feature($feature, $conf, $storecfg, $snapname, $running);
2494
2495         return {
2496             hasFeature => $hasFeature,
2497             nodes => [ keys %$nodelist ],
2498         };
2499     }});
2500
2501 __PACKAGE__->register_method({
2502     name => 'clone_vm',
2503     path => '{vmid}/clone',
2504     method => 'POST',
2505     protected => 1,
2506     proxyto => 'node',
2507     description => "Create a copy of virtual machine/template.",
2508     permissions => {
2509         description => "You need 'VM.Clone' permissions on /vms/{vmid}, and 'VM.Allocate' permissions " .
2510             "on /vms/{newid} (or on the VM pool /pool/{pool}). You also need " .
2511             "'Datastore.AllocateSpace' on any used storage.",
2512         check =>
2513         [ 'and',
2514           ['perm', '/vms/{vmid}', [ 'VM.Clone' ]],
2515           [ 'or',
2516             [ 'perm', '/vms/{newid}', ['VM.Allocate']],
2517             [ 'perm', '/pool/{pool}', ['VM.Allocate'], require_param => 'pool'],
2518           ],
2519         ]
2520     },
2521     parameters => {
2522         additionalProperties => 0,
2523         properties => {
2524             node => get_standard_option('pve-node'),
2525             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
2526             newid => get_standard_option('pve-vmid', {
2527                 completion => \&PVE::Cluster::complete_next_vmid,
2528                 description => 'VMID for the clone.' }),
2529             name => {
2530                 optional => 1,
2531                 type => 'string', format => 'dns-name',
2532                 description => "Set a name for the new VM.",
2533             },
2534             description => {
2535                 optional => 1,
2536                 type => 'string',
2537                 description => "Description for the new VM.",
2538             },
2539             pool => {
2540                 optional => 1,
2541                 type => 'string', format => 'pve-poolid',
2542                 description => "Add the new VM to the specified pool.",
2543             },
2544             snapname => get_standard_option('pve-snapshot-name', {
2545                 optional => 1,
2546             }),
2547             storage => get_standard_option('pve-storage-id', {
2548                 description => "Target storage for full clone.",
2549                 optional => 1,
2550             }),
2551             'format' => {
2552                 description => "Target format for file storage. Only valid for full clone.",
2553                 type => 'string',
2554                 optional => 1,
2555                 enum => [ 'raw', 'qcow2', 'vmdk'],
2556             },
2557             full => {
2558                 optional => 1,
2559                 type => 'boolean',
2560                 description => "Create a full copy of all disks. This is always done when " .
2561                     "you clone a normal VM. For VM templates, we try to create a linked clone by default.",
2562             },
2563             target => get_standard_option('pve-node', {
2564                 description => "Target node. Only allowed if the original VM is on shared storage.",
2565                 optional => 1,
2566             }),
2567         },
2568     },
2569     returns => {
2570         type => 'string',
2571     },
2572     code => sub {
2573         my ($param) = @_;
2574
2575         my $rpcenv = PVE::RPCEnvironment::get();
2576
2577         my $authuser = $rpcenv->get_user();
2578
2579         my $node = extract_param($param, 'node');
2580
2581         my $vmid = extract_param($param, 'vmid');
2582
2583         my $newid = extract_param($param, 'newid');
2584
2585         my $pool = extract_param($param, 'pool');
2586
2587         if (defined($pool)) {
2588             $rpcenv->check_pool_exist($pool);
2589         }
2590
2591         my $snapname = extract_param($param, 'snapname');
2592
2593         my $storage = extract_param($param, 'storage');
2594
2595         my $format = extract_param($param, 'format');
2596
2597         my $target = extract_param($param, 'target');
2598
2599         my $localnode = PVE::INotify::nodename();
2600
2601         undef $target if $target && ($target eq $localnode || $target eq 'localhost');
2602
2603         PVE::Cluster::check_node_exists($target) if $target;
2604
2605         my $storecfg = PVE::Storage::config();
2606
2607         if ($storage) {
2608             # check if storage is enabled on local node
2609             PVE::Storage::storage_check_enabled($storecfg, $storage);
2610             if ($target) {
2611                 # check if storage is available on target node
2612                 PVE::Storage::storage_check_node($storecfg, $storage, $target);
2613                 # clone only works if target storage is shared
2614                 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2615                 die "can't clone to non-shared storage '$storage'\n" if !$scfg->{shared};
2616             }
2617         }
2618
2619         PVE::Cluster::check_cfs_quorum();
2620
2621         my $running = PVE::QemuServer::check_running($vmid) || 0;
2622
2623         # exclusive lock if VM is running - else shared lock is enough;
2624         my $shared_lock = $running ? 0 : 1;
2625
2626         my $clonefn = sub {
2627
2628             # do all tests after lock
2629             # we also try to do all tests before we fork the worker
2630
2631             my $conf = PVE::QemuConfig->load_config($vmid);
2632
2633             PVE::QemuConfig->check_lock($conf);
2634
2635             my $verify_running = PVE::QemuServer::check_running($vmid) || 0;
2636
2637             die "unexpected state change\n" if $verify_running != $running;
2638
2639             die "snapshot '$snapname' does not exist\n"
2640                 if $snapname && !defined( $conf->{snapshots}->{$snapname});
2641
2642             my $full = extract_param($param, 'full');
2643             if (!defined($full)) {
2644                 $full = !PVE::QemuConfig->is_template($conf);
2645             }
2646
2647             die "parameter 'storage' not allowed for linked clones\n"
2648                 if defined($storage) && !$full;
2649
2650             die "parameter 'format' not allowed for linked clones\n"
2651                 if defined($format) && !$full;
2652
2653             my $oldconf = $snapname ? $conf->{snapshots}->{$snapname} : $conf;
2654
2655             my $sharedvm = &$check_storage_access_clone($rpcenv, $authuser, $storecfg, $oldconf, $storage);
2656
2657             die "can't clone VM to node '$target' (VM uses local storage)\n" if $target && !$sharedvm;
2658
2659             my $conffile = PVE::QemuConfig->config_file($newid);
2660
2661             die "unable to create VM $newid: config file already exists\n"
2662                 if -f $conffile;
2663
2664             my $newconf = { lock => 'clone' };
2665             my $drives = {};
2666             my $fullclone = {};
2667             my $vollist = [];
2668
2669             foreach my $opt (keys %$oldconf) {
2670                 my $value = $oldconf->{$opt};
2671
2672                 # do not copy snapshot related info
2673                 next if $opt eq 'snapshots' ||  $opt eq 'parent' || $opt eq 'snaptime' ||
2674                     $opt eq 'vmstate' || $opt eq 'snapstate';
2675
2676                 # no need to copy unused images, because VMID(owner) changes anyways
2677                 next if $opt =~ m/^unused\d+$/;
2678
2679                 # always change MAC! address
2680                 if ($opt =~ m/^net(\d+)$/) {
2681                     my $net = PVE::QemuServer::parse_net($value);
2682                     my $dc = PVE::Cluster::cfs_read_file('datacenter.cfg');
2683                     $net->{macaddr} =  PVE::Tools::random_ether_addr($dc->{mac_prefix});
2684                     $newconf->{$opt} = PVE::QemuServer::print_net($net);
2685                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
2686                     my $drive = PVE::QemuServer::parse_drive($opt, $value);
2687                     die "unable to parse drive options for '$opt'\n" if !$drive;
2688                     if (PVE::QemuServer::drive_is_cdrom($drive, 1)) {
2689                         $newconf->{$opt} = $value; # simply copy configuration
2690                     } else {
2691                         if ($full || PVE::QemuServer::drive_is_cloudinit($drive)) {
2692                             die "Full clone feature is not supported for drive '$opt'\n"
2693                                 if !PVE::Storage::volume_has_feature($storecfg, 'copy', $drive->{file}, $snapname, $running);
2694                             $fullclone->{$opt} = 1;
2695                         } else {
2696                             # not full means clone instead of copy
2697                             die "Linked clone feature is not supported for drive '$opt'\n"
2698                                 if !PVE::Storage::volume_has_feature($storecfg, 'clone', $drive->{file}, $snapname, $running);
2699                         }
2700                         $drives->{$opt} = $drive;
2701                         push @$vollist, $drive->{file};
2702                     }
2703                 } else {
2704                     # copy everything else
2705                     $newconf->{$opt} = $value;
2706                 }
2707             }
2708
2709             # auto generate a new uuid
2710             my ($uuid, $uuid_str);
2711             UUID::generate($uuid);
2712             UUID::unparse($uuid, $uuid_str);
2713             my $smbios1 = PVE::QemuServer::parse_smbios1($newconf->{smbios1} || '');
2714             $smbios1->{uuid} = $uuid_str;
2715             $newconf->{smbios1} = PVE::QemuServer::print_smbios1($smbios1);
2716
2717             delete $newconf->{template};
2718
2719             if ($param->{name}) {
2720                 $newconf->{name} = $param->{name};
2721             } else {
2722                 if ($oldconf->{name}) {
2723                     $newconf->{name} = "Copy-of-$oldconf->{name}";
2724                 } else {
2725                     $newconf->{name} = "Copy-of-VM-$vmid";
2726                 }
2727             }
2728
2729             if ($param->{description}) {
2730                 $newconf->{description} = $param->{description};
2731             }
2732
2733             # create empty/temp config - this fails if VM already exists on other node
2734             PVE::Tools::file_set_contents($conffile, "# qmclone temporary file\nlock: clone\n");
2735
2736             my $realcmd = sub {
2737                 my $upid = shift;
2738
2739                 my $newvollist = [];
2740                 my $jobs = {};
2741
2742                 eval {
2743                     local $SIG{INT} =
2744                         local $SIG{TERM} =
2745                         local $SIG{QUIT} =
2746                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
2747
2748                     PVE::Storage::activate_volumes($storecfg, $vollist, $snapname);
2749
2750                     my $total_jobs = scalar(keys %{$drives});
2751                     my $i = 1;
2752
2753                     foreach my $opt (keys %$drives) {
2754                         my $drive = $drives->{$opt};
2755                         my $skipcomplete = ($total_jobs != $i); # finish after last drive
2756
2757                         my $newdrive = PVE::QemuServer::clone_disk($storecfg, $vmid, $running, $opt, $drive, $snapname,
2758                                                                    $newid, $storage, $format, $fullclone->{$opt}, $newvollist,
2759                                                                    $jobs, $skipcomplete, $oldconf->{agent});
2760
2761                         $newconf->{$opt} = PVE::QemuServer::print_drive($vmid, $newdrive);
2762
2763                         PVE::QemuConfig->write_config($newid, $newconf);
2764                         $i++;
2765                     }
2766
2767                     delete $newconf->{lock};
2768
2769                     # do not write pending changes
2770                     if ($newconf->{pending}) {
2771                         warn "found pending changes, discarding for clone\n";
2772                         delete $newconf->{pending};
2773                     }
2774
2775                     PVE::QemuConfig->write_config($newid, $newconf);
2776
2777                     if ($target) {
2778                         # always deactivate volumes - avoid lvm LVs to be active on several nodes
2779                         PVE::Storage::deactivate_volumes($storecfg, $vollist, $snapname) if !$running;
2780                         PVE::Storage::deactivate_volumes($storecfg, $newvollist);
2781
2782                         my $newconffile = PVE::QemuConfig->config_file($newid, $target);
2783                         die "Failed to move config to node '$target' - rename failed: $!\n"
2784                             if !rename($conffile, $newconffile);
2785                     }
2786
2787                     PVE::AccessControl::add_vm_to_pool($newid, $pool) if $pool;
2788                 };
2789                 if (my $err = $@) {
2790                     unlink $conffile;
2791
2792                     eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $jobs) };
2793
2794                     sleep 1; # some storage like rbd need to wait before release volume - really?
2795
2796                     foreach my $volid (@$newvollist) {
2797                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2798                         warn $@ if $@;
2799                     }
2800                     die "clone failed: $err";
2801                 }
2802
2803                 return;
2804             };
2805
2806             PVE::Firewall::clone_vmfw_conf($vmid, $newid);
2807
2808             return $rpcenv->fork_worker('qmclone', $vmid, $authuser, $realcmd);
2809         };
2810
2811         return PVE::QemuConfig->lock_config_mode($vmid, 1, $shared_lock, sub {
2812             # Aquire exclusive lock lock for $newid
2813             return PVE::QemuConfig->lock_config_full($newid, 1, $clonefn);
2814         });
2815
2816     }});
2817
2818 __PACKAGE__->register_method({
2819     name => 'move_vm_disk',
2820     path => '{vmid}/move_disk',
2821     method => 'POST',
2822     protected => 1,
2823     proxyto => 'node',
2824     description => "Move volume to different storage.",
2825     permissions => {
2826         description => "You need 'VM.Config.Disk' permissions on /vms/{vmid}, and 'Datastore.AllocateSpace' permissions on the storage.",
2827         check => [ 'and',
2828                    ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
2829                    ['perm', '/storage/{storage}', [ 'Datastore.AllocateSpace' ]],
2830             ],
2831     },
2832     parameters => {
2833         additionalProperties => 0,
2834         properties => {
2835             node => get_standard_option('pve-node'),
2836             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
2837             disk => {
2838                 type => 'string',
2839                 description => "The disk you want to move.",
2840                 enum => [ PVE::QemuServer::valid_drive_names() ],
2841             },
2842             storage => get_standard_option('pve-storage-id', {
2843                 description => "Target storage.",
2844                 completion => \&PVE::QemuServer::complete_storage,
2845             }),
2846             'format' => {
2847                 type => 'string',
2848                 description => "Target Format.",
2849                 enum => [ 'raw', 'qcow2', 'vmdk' ],
2850                 optional => 1,
2851             },
2852             delete => {
2853                 type => 'boolean',
2854                 description => "Delete the original disk after successful copy. By default the original disk is kept as unused disk.",
2855                 optional => 1,
2856                 default => 0,
2857             },
2858             digest => {
2859                 type => 'string',
2860                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
2861                 maxLength => 40,
2862                 optional => 1,
2863             },
2864         },
2865     },
2866     returns => {
2867         type => 'string',
2868         description => "the task ID.",
2869     },
2870     code => sub {
2871         my ($param) = @_;
2872
2873         my $rpcenv = PVE::RPCEnvironment::get();
2874
2875         my $authuser = $rpcenv->get_user();
2876
2877         my $node = extract_param($param, 'node');
2878
2879         my $vmid = extract_param($param, 'vmid');
2880
2881         my $digest = extract_param($param, 'digest');
2882
2883         my $disk = extract_param($param, 'disk');
2884
2885         my $storeid = extract_param($param, 'storage');
2886
2887         my $format = extract_param($param, 'format');
2888
2889         my $storecfg = PVE::Storage::config();
2890
2891         my $updatefn =  sub {
2892
2893             my $conf = PVE::QemuConfig->load_config($vmid);
2894
2895             PVE::QemuConfig->check_lock($conf);
2896
2897             die "checksum missmatch (file change by other user?)\n"
2898                 if $digest && $digest ne $conf->{digest};
2899
2900             die "disk '$disk' does not exist\n" if !$conf->{$disk};
2901
2902             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
2903
2904             my $old_volid = $drive->{file} || die "disk '$disk' has no associated volume\n";
2905
2906             die "you can't move a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive, 1);
2907
2908             my $oldfmt;
2909             my ($oldstoreid, $oldvolname) = PVE::Storage::parse_volume_id($old_volid);
2910             if ($oldvolname =~ m/\.(raw|qcow2|vmdk)$/){
2911                 $oldfmt = $1;
2912             }
2913
2914             die "you can't move on the same storage with same format\n" if $oldstoreid eq $storeid &&
2915                 (!$format || !$oldfmt || $oldfmt eq $format);
2916
2917             # this only checks snapshots because $disk is passed!
2918             my $snapshotted = PVE::QemuServer::is_volume_in_use($storecfg, $conf, $disk, $old_volid);
2919             die "you can't move a disk with snapshots and delete the source\n"
2920                 if $snapshotted && $param->{delete};
2921
2922             PVE::Cluster::log_msg('info', $authuser, "move disk VM $vmid: move --disk $disk --storage $storeid");
2923
2924             my $running = PVE::QemuServer::check_running($vmid);
2925
2926             PVE::Storage::activate_volumes($storecfg, [ $drive->{file} ]);
2927
2928             my $realcmd = sub {
2929
2930                 my $newvollist = [];
2931
2932                 eval {
2933                     local $SIG{INT} =
2934                         local $SIG{TERM} =
2935                         local $SIG{QUIT} =
2936                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
2937
2938                     warn "moving disk with snapshots, snapshots will not be moved!\n"
2939                         if $snapshotted;
2940
2941                     my $newdrive = PVE::QemuServer::clone_disk($storecfg, $vmid, $running, $disk, $drive, undef,
2942                                                                $vmid, $storeid, $format, 1, $newvollist);
2943
2944                     $conf->{$disk} = PVE::QemuServer::print_drive($vmid, $newdrive);
2945
2946                     PVE::QemuConfig->add_unused_volume($conf, $old_volid) if !$param->{delete};
2947
2948                     # convert moved disk to base if part of template
2949                     PVE::QemuServer::template_create($vmid, $conf, $disk)
2950                         if PVE::QemuConfig->is_template($conf);
2951
2952                     PVE::QemuConfig->write_config($vmid, $conf);
2953
2954                     eval {
2955                         # try to deactivate volumes - avoid lvm LVs to be active on several nodes
2956                         PVE::Storage::deactivate_volumes($storecfg, [ $newdrive->{file} ])
2957                             if !$running;
2958                     };
2959                     warn $@ if $@;
2960                 };
2961                 if (my $err = $@) {
2962
2963                    foreach my $volid (@$newvollist) {
2964                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2965                         warn $@ if $@;
2966                     }
2967                     die "storage migration failed: $err";
2968                 }
2969
2970                 if ($param->{delete}) {
2971                     eval {
2972                         PVE::Storage::deactivate_volumes($storecfg, [$old_volid]);
2973                         PVE::Storage::vdisk_free($storecfg, $old_volid);
2974                     };
2975                     warn $@ if $@;
2976                 }
2977             };
2978
2979             return $rpcenv->fork_worker('qmmove', $vmid, $authuser, $realcmd);
2980         };
2981
2982         return PVE::QemuConfig->lock_config($vmid, $updatefn);
2983     }});
2984
2985 __PACKAGE__->register_method({
2986     name => 'migrate_vm',
2987     path => '{vmid}/migrate',
2988     method => 'POST',
2989     protected => 1,
2990     proxyto => 'node',
2991     description => "Migrate virtual machine. Creates a new migration task.",
2992     permissions => {
2993         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
2994     },
2995     parameters => {
2996         additionalProperties => 0,
2997         properties => {
2998             node => get_standard_option('pve-node'),
2999             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3000             target => get_standard_option('pve-node', {
3001                 description => "Target node.",
3002                 completion =>  \&PVE::Cluster::complete_migration_target,
3003             }),
3004             online => {
3005                 type => 'boolean',
3006                 description => "Use online/live migration.",
3007                 optional => 1,
3008             },
3009             force => {
3010                 type => 'boolean',
3011                 description => "Allow to migrate VMs which use local devices. Only root may use this option.",
3012                 optional => 1,
3013             },
3014             migration_type => {
3015                 type => 'string',
3016                 enum => ['secure', 'insecure'],
3017                 description => "Migration traffic is encrypted using an SSH tunnel by default. On secure, completely private networks this can be disabled to increase performance.",
3018                 optional => 1,
3019             },
3020             migration_network => {
3021                 type => 'string', format => 'CIDR',
3022                 description => "CIDR of the (sub) network that is used for migration.",
3023                 optional => 1,
3024             },
3025             "with-local-disks" => {
3026                 type => 'boolean',
3027                 description => "Enable live storage migration for local disk",
3028                 optional => 1,
3029             },
3030             targetstorage => get_standard_option('pve-storage-id', {
3031                 description => "Default target storage.",
3032                 optional => 1,
3033                 completion => \&PVE::QemuServer::complete_storage,
3034             }),
3035         },
3036     },
3037     returns => {
3038         type => 'string',
3039         description => "the task ID.",
3040     },
3041     code => sub {
3042         my ($param) = @_;
3043
3044         my $rpcenv = PVE::RPCEnvironment::get();
3045
3046         my $authuser = $rpcenv->get_user();
3047
3048         my $target = extract_param($param, 'target');
3049
3050         my $localnode = PVE::INotify::nodename();
3051         raise_param_exc({ target => "target is local node."}) if $target eq $localnode;
3052
3053         PVE::Cluster::check_cfs_quorum();
3054
3055         PVE::Cluster::check_node_exists($target);
3056
3057         my $targetip = PVE::Cluster::remote_node_ip($target);
3058
3059         my $vmid = extract_param($param, 'vmid');
3060
3061         raise_param_exc({ targetstorage => "Live storage migration can only be done online." })
3062             if !$param->{online} && $param->{targetstorage};
3063
3064         raise_param_exc({ force => "Only root may use this option." })
3065             if $param->{force} && $authuser ne 'root@pam';
3066
3067         raise_param_exc({ migration_type => "Only root may use this option." })
3068             if $param->{migration_type} && $authuser ne 'root@pam';
3069
3070         # allow root only until better network permissions are available
3071         raise_param_exc({ migration_network => "Only root may use this option." })
3072             if $param->{migration_network} && $authuser ne 'root@pam';
3073
3074         # test if VM exists
3075         my $conf = PVE::QemuConfig->load_config($vmid);
3076
3077         # try to detect errors early
3078
3079         PVE::QemuConfig->check_lock($conf);
3080
3081         if (PVE::QemuServer::check_running($vmid)) {
3082             die "cant migrate running VM without --online\n"
3083                 if !$param->{online};
3084         }
3085
3086         my $storecfg = PVE::Storage::config();
3087
3088         if( $param->{targetstorage}) {
3089             PVE::Storage::storage_check_node($storecfg, $param->{targetstorage}, $target);
3090         } else {
3091             PVE::QemuServer::check_storage_availability($storecfg, $conf, $target);
3092         }
3093
3094         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
3095
3096             my $hacmd = sub {
3097                 my $upid = shift;
3098
3099                 my $service = "vm:$vmid";
3100
3101                 my $cmd = ['ha-manager', 'migrate', $service, $target];
3102
3103                 print "Requesting HA migration for VM $vmid to node $target\n";
3104
3105                 PVE::Tools::run_command($cmd);
3106
3107                 return;
3108             };
3109
3110             return $rpcenv->fork_worker('hamigrate', $vmid, $authuser, $hacmd);
3111
3112         } else {
3113
3114             my $realcmd = sub {
3115                 PVE::QemuMigrate->migrate($target, $targetip, $vmid, $param);
3116             };
3117
3118             my $worker = sub {
3119                 return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
3120             };
3121
3122             return $rpcenv->fork_worker('qmigrate', $vmid, $authuser, $worker);
3123         }
3124
3125     }});
3126
3127 __PACKAGE__->register_method({
3128     name => 'monitor',
3129     path => '{vmid}/monitor',
3130     method => 'POST',
3131     protected => 1,
3132     proxyto => 'node',
3133     description => "Execute Qemu monitor commands.",
3134     permissions => {
3135         description => "Sys.Modify is required for (sub)commands which are not read-only ('info *' and 'help')",
3136         check => ['perm', '/vms/{vmid}', [ 'VM.Monitor' ]],
3137     },
3138     parameters => {
3139         additionalProperties => 0,
3140         properties => {
3141             node => get_standard_option('pve-node'),
3142             vmid => get_standard_option('pve-vmid'),
3143             command => {
3144                 type => 'string',
3145                 description => "The monitor command.",
3146             }
3147         },
3148     },
3149     returns => { type => 'string'},
3150     code => sub {
3151         my ($param) = @_;
3152
3153         my $rpcenv = PVE::RPCEnvironment::get();
3154         my $authuser = $rpcenv->get_user();
3155
3156         my $is_ro = sub {
3157             my $command = shift;
3158             return $command =~ m/^\s*info(\s+|$)/
3159                 || $command =~ m/^\s*help\s*$/;
3160         };
3161
3162         $rpcenv->check_full($authuser, "/", ['Sys.Modify'])
3163             if !&$is_ro($param->{command});
3164
3165         my $vmid = $param->{vmid};
3166
3167         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
3168
3169         my $res = '';
3170         eval {
3171             $res = PVE::QemuServer::vm_human_monitor_command($vmid, $param->{command});
3172         };
3173         $res = "ERROR: $@" if $@;
3174
3175         return $res;
3176     }});
3177
3178 __PACKAGE__->register_method({
3179     name => 'resize_vm',
3180     path => '{vmid}/resize',
3181     method => 'PUT',
3182     protected => 1,
3183     proxyto => 'node',
3184     description => "Extend volume size.",
3185     permissions => {
3186         check => ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
3187     },
3188     parameters => {
3189         additionalProperties => 0,
3190         properties => {
3191             node => get_standard_option('pve-node'),
3192             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3193             skiplock => get_standard_option('skiplock'),
3194             disk => {
3195                 type => 'string',
3196                 description => "The disk you want to resize.",
3197                 enum => [PVE::QemuServer::valid_drive_names()],
3198             },
3199             size => {
3200                 type => 'string',
3201                 pattern => '\+?\d+(\.\d+)?[KMGT]?',
3202                 description => "The new size. With the `+` sign the value is added to the actual size of the volume and without it, the value is taken as an absolute one. Shrinking disk size is not supported.",
3203             },
3204             digest => {
3205                 type => 'string',
3206                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
3207                 maxLength => 40,
3208                 optional => 1,
3209             },
3210         },
3211     },
3212     returns => { type => 'null'},
3213     code => sub {
3214         my ($param) = @_;
3215
3216         my $rpcenv = PVE::RPCEnvironment::get();
3217
3218         my $authuser = $rpcenv->get_user();
3219
3220         my $node = extract_param($param, 'node');
3221
3222         my $vmid = extract_param($param, 'vmid');
3223
3224         my $digest = extract_param($param, 'digest');
3225
3226         my $disk = extract_param($param, 'disk');
3227
3228         my $sizestr = extract_param($param, 'size');
3229
3230         my $skiplock = extract_param($param, 'skiplock');
3231         raise_param_exc({ skiplock => "Only root may use this option." })
3232             if $skiplock && $authuser ne 'root@pam';
3233
3234         my $storecfg = PVE::Storage::config();
3235
3236         my $updatefn =  sub {
3237
3238             my $conf = PVE::QemuConfig->load_config($vmid);
3239
3240             die "checksum missmatch (file change by other user?)\n"
3241                 if $digest && $digest ne $conf->{digest};
3242             PVE::QemuConfig->check_lock($conf) if !$skiplock;
3243
3244             die "disk '$disk' does not exist\n" if !$conf->{$disk};
3245
3246             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
3247
3248             my (undef, undef, undef, undef, undef, undef, $format) =
3249                 PVE::Storage::parse_volname($storecfg, $drive->{file});
3250
3251             die "can't resize volume: $disk if snapshot exists\n"
3252                 if %{$conf->{snapshots}} && $format eq 'qcow2';
3253
3254             my $volid = $drive->{file};
3255
3256             die "disk '$disk' has no associated volume\n" if !$volid;
3257
3258             die "you can't resize a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive);
3259
3260             my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid);
3261
3262             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
3263
3264             PVE::Storage::activate_volumes($storecfg, [$volid]);
3265             my $size = PVE::Storage::volume_size_info($storecfg, $volid, 5);
3266
3267             die "internal error" if $sizestr !~ m/^(\+)?(\d+(\.\d+)?)([KMGT])?$/;
3268             my ($ext, $newsize, $unit) = ($1, $2, $4);
3269             if ($unit) {
3270                 if ($unit eq 'K') {
3271                     $newsize = $newsize * 1024;
3272                 } elsif ($unit eq 'M') {
3273                     $newsize = $newsize * 1024 * 1024;
3274                 } elsif ($unit eq 'G') {
3275                     $newsize = $newsize * 1024 * 1024 * 1024;
3276                 } elsif ($unit eq 'T') {
3277                     $newsize = $newsize * 1024 * 1024 * 1024 * 1024;
3278                 }
3279             }
3280             $newsize += $size if $ext;
3281             $newsize = int($newsize);
3282
3283             die "shrinking disks is not supported\n" if $newsize < $size;
3284
3285             return if $size == $newsize;
3286
3287             PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: resize --disk $disk --size $sizestr");
3288
3289             PVE::QemuServer::qemu_block_resize($vmid, "drive-$disk", $storecfg, $volid, $newsize);
3290
3291             $drive->{size} = $newsize;
3292             $conf->{$disk} = PVE::QemuServer::print_drive($vmid, $drive);
3293
3294             PVE::QemuConfig->write_config($vmid, $conf);
3295         };
3296
3297         PVE::QemuConfig->lock_config($vmid, $updatefn);
3298         return undef;
3299     }});
3300
3301 __PACKAGE__->register_method({
3302     name => 'snapshot_list',
3303     path => '{vmid}/snapshot',
3304     method => 'GET',
3305     description => "List all snapshots.",
3306     permissions => {
3307         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
3308     },
3309     proxyto => 'node',
3310     protected => 1, # qemu pid files are only readable by root
3311     parameters => {
3312         additionalProperties => 0,
3313         properties => {
3314             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3315             node => get_standard_option('pve-node'),
3316         },
3317     },
3318     returns => {
3319         type => 'array',
3320         items => {
3321             type => "object",
3322             properties => {},
3323         },
3324         links => [ { rel => 'child', href => "{name}" } ],
3325     },
3326     code => sub {
3327         my ($param) = @_;
3328
3329         my $vmid = $param->{vmid};
3330
3331         my $conf = PVE::QemuConfig->load_config($vmid);
3332         my $snaphash = $conf->{snapshots} || {};
3333
3334         my $res = [];
3335
3336         foreach my $name (keys %$snaphash) {
3337             my $d = $snaphash->{$name};
3338             my $item = {
3339                 name => $name,
3340                 snaptime => $d->{snaptime} || 0,
3341                 vmstate => $d->{vmstate} ? 1 : 0,
3342                 description => $d->{description} || '',
3343             };
3344             $item->{parent} = $d->{parent} if $d->{parent};
3345             $item->{snapstate} = $d->{snapstate} if $d->{snapstate};
3346             push @$res, $item;
3347         }
3348
3349         my $running = PVE::QemuServer::check_running($vmid, 1) ? 1 : 0;
3350         my $current = { name => 'current', digest => $conf->{digest}, running => $running };
3351         $current->{parent} = $conf->{parent} if $conf->{parent};
3352
3353         push @$res, $current;
3354
3355         return $res;
3356     }});
3357
3358 __PACKAGE__->register_method({
3359     name => 'snapshot',
3360     path => '{vmid}/snapshot',
3361     method => 'POST',
3362     protected => 1,
3363     proxyto => 'node',
3364     description => "Snapshot a VM.",
3365     permissions => {
3366         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3367     },
3368     parameters => {
3369         additionalProperties => 0,
3370         properties => {
3371             node => get_standard_option('pve-node'),
3372             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3373             snapname => get_standard_option('pve-snapshot-name'),
3374             vmstate => {
3375                 optional => 1,
3376                 type => 'boolean',
3377                 description => "Save the vmstate",
3378             },
3379             description => {
3380                 optional => 1,
3381                 type => 'string',
3382                 description => "A textual description or comment.",
3383             },
3384         },
3385     },
3386     returns => {
3387         type => 'string',
3388         description => "the task ID.",
3389     },
3390     code => sub {
3391         my ($param) = @_;
3392
3393         my $rpcenv = PVE::RPCEnvironment::get();
3394
3395         my $authuser = $rpcenv->get_user();
3396
3397         my $node = extract_param($param, 'node');
3398
3399         my $vmid = extract_param($param, 'vmid');
3400
3401         my $snapname = extract_param($param, 'snapname');
3402
3403         die "unable to use snapshot name 'current' (reserved name)\n"
3404             if $snapname eq 'current';
3405
3406         my $realcmd = sub {
3407             PVE::Cluster::log_msg('info', $authuser, "snapshot VM $vmid: $snapname");
3408             PVE::QemuConfig->snapshot_create($vmid, $snapname, $param->{vmstate},
3409                                              $param->{description});
3410         };
3411
3412         return $rpcenv->fork_worker('qmsnapshot', $vmid, $authuser, $realcmd);
3413     }});
3414
3415 __PACKAGE__->register_method({
3416     name => 'snapshot_cmd_idx',
3417     path => '{vmid}/snapshot/{snapname}',
3418     description => '',
3419     method => 'GET',
3420     permissions => {
3421         user => 'all',
3422     },
3423     parameters => {
3424         additionalProperties => 0,
3425         properties => {
3426             vmid => get_standard_option('pve-vmid'),
3427             node => get_standard_option('pve-node'),
3428             snapname => get_standard_option('pve-snapshot-name'),
3429         },
3430     },
3431     returns => {
3432         type => 'array',
3433         items => {
3434             type => "object",
3435             properties => {},
3436         },
3437         links => [ { rel => 'child', href => "{cmd}" } ],
3438     },
3439     code => sub {
3440         my ($param) = @_;
3441
3442         my $res = [];
3443
3444         push @$res, { cmd => 'rollback' };
3445         push @$res, { cmd => 'config' };
3446
3447         return $res;
3448     }});
3449
3450 __PACKAGE__->register_method({
3451     name => 'update_snapshot_config',
3452     path => '{vmid}/snapshot/{snapname}/config',
3453     method => 'PUT',
3454     protected => 1,
3455     proxyto => 'node',
3456     description => "Update snapshot metadata.",
3457     permissions => {
3458         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3459     },
3460     parameters => {
3461         additionalProperties => 0,
3462         properties => {
3463             node => get_standard_option('pve-node'),
3464             vmid => get_standard_option('pve-vmid'),
3465             snapname => get_standard_option('pve-snapshot-name'),
3466             description => {
3467                 optional => 1,
3468                 type => 'string',
3469                 description => "A textual description or comment.",
3470             },
3471         },
3472     },
3473     returns => { type => 'null' },
3474     code => sub {
3475         my ($param) = @_;
3476
3477         my $rpcenv = PVE::RPCEnvironment::get();
3478
3479         my $authuser = $rpcenv->get_user();
3480
3481         my $vmid = extract_param($param, 'vmid');
3482
3483         my $snapname = extract_param($param, 'snapname');
3484
3485         return undef if !defined($param->{description});
3486
3487         my $updatefn =  sub {
3488
3489             my $conf = PVE::QemuConfig->load_config($vmid);
3490
3491             PVE::QemuConfig->check_lock($conf);
3492
3493             my $snap = $conf->{snapshots}->{$snapname};
3494
3495             die "snapshot '$snapname' does not exist\n" if !defined($snap);
3496
3497             $snap->{description} = $param->{description} if defined($param->{description});
3498
3499              PVE::QemuConfig->write_config($vmid, $conf);
3500         };
3501
3502         PVE::QemuConfig->lock_config($vmid, $updatefn);
3503
3504         return undef;
3505     }});
3506
3507 __PACKAGE__->register_method({
3508     name => 'get_snapshot_config',
3509     path => '{vmid}/snapshot/{snapname}/config',
3510     method => 'GET',
3511     proxyto => 'node',
3512     description => "Get snapshot configuration",
3513     permissions => {
3514         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback' ], any => 1],
3515     },
3516     parameters => {
3517         additionalProperties => 0,
3518         properties => {
3519             node => get_standard_option('pve-node'),
3520             vmid => get_standard_option('pve-vmid'),
3521             snapname => get_standard_option('pve-snapshot-name'),
3522         },
3523     },
3524     returns => { type => "object" },
3525     code => sub {
3526         my ($param) = @_;
3527
3528         my $rpcenv = PVE::RPCEnvironment::get();
3529
3530         my $authuser = $rpcenv->get_user();
3531
3532         my $vmid = extract_param($param, 'vmid');
3533
3534         my $snapname = extract_param($param, 'snapname');
3535
3536         my $conf = PVE::QemuConfig->load_config($vmid);
3537
3538         my $snap = $conf->{snapshots}->{$snapname};
3539
3540         die "snapshot '$snapname' does not exist\n" if !defined($snap);
3541
3542         return $snap;
3543     }});
3544
3545 __PACKAGE__->register_method({
3546     name => 'rollback',
3547     path => '{vmid}/snapshot/{snapname}/rollback',
3548     method => 'POST',
3549     protected => 1,
3550     proxyto => 'node',
3551     description => "Rollback VM state to specified snapshot.",
3552     permissions => {
3553         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback' ], any => 1],
3554     },
3555     parameters => {
3556         additionalProperties => 0,
3557         properties => {
3558             node => get_standard_option('pve-node'),
3559             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3560             snapname => get_standard_option('pve-snapshot-name'),
3561         },
3562     },
3563     returns => {
3564         type => 'string',
3565         description => "the task ID.",
3566     },
3567     code => sub {
3568         my ($param) = @_;
3569
3570         my $rpcenv = PVE::RPCEnvironment::get();
3571
3572         my $authuser = $rpcenv->get_user();
3573
3574         my $node = extract_param($param, 'node');
3575
3576         my $vmid = extract_param($param, 'vmid');
3577
3578         my $snapname = extract_param($param, 'snapname');
3579
3580         my $realcmd = sub {
3581             PVE::Cluster::log_msg('info', $authuser, "rollback snapshot VM $vmid: $snapname");
3582             PVE::QemuConfig->snapshot_rollback($vmid, $snapname);
3583         };
3584
3585         my $worker = sub {
3586             # hold migration lock, this makes sure that nobody create replication snapshots
3587             return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
3588         };
3589
3590         return $rpcenv->fork_worker('qmrollback', $vmid, $authuser, $worker);
3591     }});
3592
3593 __PACKAGE__->register_method({
3594     name => 'delsnapshot',
3595     path => '{vmid}/snapshot/{snapname}',
3596     method => 'DELETE',
3597     protected => 1,
3598     proxyto => 'node',
3599     description => "Delete a VM snapshot.",
3600     permissions => {
3601         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3602     },
3603     parameters => {
3604         additionalProperties => 0,
3605         properties => {
3606             node => get_standard_option('pve-node'),
3607             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3608             snapname => get_standard_option('pve-snapshot-name'),
3609             force => {
3610                 optional => 1,
3611                 type => 'boolean',
3612                 description => "For removal from config file, even if removing disk snapshots fails.",
3613             },
3614         },
3615     },
3616     returns => {
3617         type => 'string',
3618         description => "the task ID.",
3619     },
3620     code => sub {
3621         my ($param) = @_;
3622
3623         my $rpcenv = PVE::RPCEnvironment::get();
3624
3625         my $authuser = $rpcenv->get_user();
3626
3627         my $node = extract_param($param, 'node');
3628
3629         my $vmid = extract_param($param, 'vmid');
3630
3631         my $snapname = extract_param($param, 'snapname');
3632
3633         my $realcmd = sub {
3634             PVE::Cluster::log_msg('info', $authuser, "delete snapshot VM $vmid: $snapname");
3635             PVE::QemuConfig->snapshot_delete($vmid, $snapname, $param->{force});
3636         };
3637
3638         return $rpcenv->fork_worker('qmdelsnapshot', $vmid, $authuser, $realcmd);
3639     }});
3640
3641 __PACKAGE__->register_method({
3642     name => 'template',
3643     path => '{vmid}/template',
3644     method => 'POST',
3645     protected => 1,
3646     proxyto => 'node',
3647     description => "Create a Template.",
3648     permissions => {
3649         description => "You need 'VM.Allocate' permissions on /vms/{vmid}",
3650         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
3651     },
3652     parameters => {
3653         additionalProperties => 0,
3654         properties => {
3655             node => get_standard_option('pve-node'),
3656             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
3657             disk => {
3658                 optional => 1,
3659                 type => 'string',
3660                 description => "If you want to convert only 1 disk to base image.",
3661                 enum => [PVE::QemuServer::valid_drive_names()],
3662             },
3663
3664         },
3665     },
3666     returns => { type => 'null'},
3667     code => sub {
3668         my ($param) = @_;
3669
3670         my $rpcenv = PVE::RPCEnvironment::get();
3671
3672         my $authuser = $rpcenv->get_user();
3673
3674         my $node = extract_param($param, 'node');
3675
3676         my $vmid = extract_param($param, 'vmid');
3677
3678         my $disk = extract_param($param, 'disk');
3679
3680         my $updatefn =  sub {
3681
3682             my $conf = PVE::QemuConfig->load_config($vmid);
3683
3684             PVE::QemuConfig->check_lock($conf);
3685
3686             die "unable to create template, because VM contains snapshots\n"
3687                 if $conf->{snapshots} && scalar(keys %{$conf->{snapshots}});
3688
3689             die "you can't convert a template to a template\n"
3690                 if PVE::QemuConfig->is_template($conf) && !$disk;
3691
3692             die "you can't convert a VM to template if VM is running\n"
3693                 if PVE::QemuServer::check_running($vmid);
3694
3695             my $realcmd = sub {
3696                 PVE::QemuServer::template_create($vmid, $conf, $disk);
3697             };
3698
3699             $conf->{template} = 1;
3700             PVE::QemuConfig->write_config($vmid, $conf);
3701
3702             return $rpcenv->fork_worker('qmtemplate', $vmid, $authuser, $realcmd);
3703         };
3704
3705         PVE::QemuConfig->lock_config($vmid, $updatefn);
3706         return undef;
3707     }});
3708
3709 1;