PVE/API2/Qemu.pm

   1 package PVE::API2::Qemu;
   2
   3 use strict;
   4 use warnings;
   5 use Cwd 'abs_path';
   6 use Net::SSLeay;
   7 use POSIX;
   8 use IO::Socket::IP;
   9 use URI::Escape;
  10 use Crypt::OpenSSL::Random;
  11
  12 use PVE::Cluster qw (cfs_read_file cfs_write_file);;
  13 use PVE::RRD;
  14 use PVE::SafeSyslog;
  15 use PVE::Tools qw(extract_param);
  16 use PVE::Exception qw(raise raise_param_exc raise_perm_exc);
  17 use PVE::Storage;
  18 use PVE::JSONSchema qw(get_standard_option);
  19 use PVE::RESTHandler;
  20 use PVE::ReplicationConfig;
  21 use PVE::GuestHelpers;
  22 use PVE::QemuConfig;
  23 use PVE::QemuServer;
  24 use PVE::QemuServer::Drive;
  25 use PVE::QemuServer::CPUConfig;
  26 use PVE::QemuServer::Monitor qw(mon_cmd);
  27 use PVE::QemuMigrate;
  28 use PVE::RPCEnvironment;
  29 use PVE::AccessControl;
  30 use PVE::INotify;
  31 use PVE::Network;
  32 use PVE::Firewall;
  33 use PVE::API2::Firewall::VM;
  34 use PVE::API2::Qemu::Agent;
  35 use PVE::VZDump::Plugin;
  36 use PVE::DataCenterConfig;
  37 use PVE::SSHInfo;
  38
  39 BEGIN {
  40     if (!$ENV{PVE_GENERATING_DOCS}) {
  41         require PVE::HA::Env::PVE2;
  42         import PVE::HA::Env::PVE2;
  43         require PVE::HA::Config;
  44         import PVE::HA::Config;
  45     }
  46 }
  47
  48 use Data::Dumper; # fixme: remove
  49
  50 use base qw(PVE::RESTHandler);
  51
  52 my $opt_force_description = "Force physical removal. Without this, we simple remove the disk from the config file and create an additional configuration entry called 'unused[n]', which contains the volume ID. Unlink of unused[n] always cause physical removal.";
  53
  54 my $resolve_cdrom_alias = sub {
  55     my $param = shift;
  56
  57     if (my $value = $param->{cdrom}) {
  58         $value .= ",media=cdrom" if $value !~ m/media=/;
  59         $param->{ide2} = $value;
  60         delete $param->{cdrom};
  61     }
  62 };
  63
  64 my $NEW_DISK_RE = qr!^(([^/:\s]+):)?(\d+(\.\d+)?)$!;
  65 my $check_storage_access = sub {
  66    my ($rpcenv, $authuser, $storecfg, $vmid, $settings, $default_storage) = @_;
  67
  68    PVE::QemuConfig->foreach_volume($settings, sub {
  69         my ($ds, $drive) = @_;
  70
  71         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
  72
  73         my $volid = $drive->{file};
  74         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
  75
  76         if (!$volid || ($volid eq 'none' || $volid eq 'cloudinit' || (defined($volname) && $volname eq 'cloudinit'))) {
  77             # nothing to check
  78         } elsif ($isCDROM && ($volid eq 'cdrom')) {
  79             $rpcenv->check($authuser, "/", ['Sys.Console']);
  80         } elsif (!$isCDROM && ($volid =~ $NEW_DISK_RE)) {
  81             my ($storeid, $size) = ($2 || $default_storage, $3);
  82             die "no storage ID specified (and no default storage)\n" if !$storeid;
  83             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
  84             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
  85             raise_param_exc({ storage => "storage '$storeid' does not support vm images"})
  86                 if !$scfg->{content}->{images};
  87         } else {
  88             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
  89         }
  90     });
  91
  92    $rpcenv->check($authuser, "/storage/$settings->{vmstatestorage}", ['Datastore.AllocateSpace'])
  93        if defined($settings->{vmstatestorage});
  94 };
  95
  96 my $check_storage_access_clone = sub {
  97    my ($rpcenv, $authuser, $storecfg, $conf, $storage) = @_;
  98
  99    my $sharedvm = 1;
 100
 101    PVE::QemuConfig->foreach_volume($conf, sub {
 102         my ($ds, $drive) = @_;
 103
 104         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
 105
 106         my $volid = $drive->{file};
 107
 108         return if !$volid || $volid eq 'none';
 109
 110         if ($isCDROM) {
 111             if ($volid eq 'cdrom') {
 112                 $rpcenv->check($authuser, "/", ['Sys.Console']);
 113             } else {
 114                 # we simply allow access
 115                 my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 116                 my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 117                 $sharedvm = 0 if !$scfg->{shared};
 118
 119             }
 120         } else {
 121             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 122             my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 123             $sharedvm = 0 if !$scfg->{shared};
 124
 125             $sid = $storage if $storage;
 126             $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
 127         }
 128     });
 129
 130    $rpcenv->check($authuser, "/storage/$conf->{vmstatestorage}", ['Datastore.AllocateSpace'])
 131        if defined($conf->{vmstatestorage});
 132
 133    return $sharedvm;
 134 };
 135
 136 # Note: $pool is only needed when creating a VM, because pool permissions
 137 # are automatically inherited if VM already exists inside a pool.
 138 my $create_disks = sub {
 139     my ($rpcenv, $authuser, $conf, $arch, $storecfg, $vmid, $pool, $settings, $default_storage) = @_;
 140
 141     my $vollist = [];
 142
 143     my $res = {};
 144
 145     my $code = sub {
 146         my ($ds, $disk) = @_;
 147
 148         my $volid = $disk->{file};
 149         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 150
 151         if (!$volid || $volid eq 'none' || $volid eq 'cdrom') {
 152             delete $disk->{size};
 153             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 154         } elsif (defined($volname) && $volname eq 'cloudinit') {
 155             $storeid = $storeid // $default_storage;
 156             die "no storage ID specified (and no default storage)\n" if !$storeid;
 157             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 158             my $name = "vm-$vmid-cloudinit";
 159
 160             my $fmt = undef;
 161             if ($scfg->{path}) {
 162                 $fmt = $disk->{format} // "qcow2";
 163                 $name .= ".$fmt";
 164             } else {
 165                 $fmt = $disk->{format} // "raw";
 166             }
 167
 168             # Initial disk created with 4 MB and aligned to 4MB on regeneration
 169             my $ci_size = PVE::QemuServer::Cloudinit::CLOUDINIT_DISK_SIZE;
 170             my $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $fmt, $name, $ci_size/1024);
 171             $disk->{file} = $volid;
 172             $disk->{media} = 'cdrom';
 173             push @$vollist, $volid;
 174             delete $disk->{format}; # no longer needed
 175             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 176         } elsif ($volid =~ $NEW_DISK_RE) {
 177             my ($storeid, $size) = ($2 || $default_storage, $3);
 178             die "no storage ID specified (and no default storage)\n" if !$storeid;
 179             my $defformat = PVE::Storage::storage_default_format($storecfg, $storeid);
 180             my $fmt = $disk->{format} || $defformat;
 181
 182             $size = PVE::Tools::convert_size($size, 'gb' => 'kb'); # vdisk_alloc uses kb
 183
 184             my $volid;
 185             if ($ds eq 'efidisk0') {
 186                 ($volid, $size) = PVE::QemuServer::create_efidisk($storecfg, $storeid, $vmid, $fmt, $arch);
 187             } else {
 188                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $fmt, undef, $size);
 189             }
 190             push @$vollist, $volid;
 191             $disk->{file} = $volid;
 192             $disk->{size} = PVE::Tools::convert_size($size, 'kb' => 'b');
 193             delete $disk->{format}; # no longer needed
 194             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 195         } else {
 196
 197             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
 198
 199             my $volid_is_new = 1;
 200
 201             if ($conf->{$ds}) {
 202                 my $olddrive = PVE::QemuServer::parse_drive($ds, $conf->{$ds});
 203                 $volid_is_new = undef if $olddrive->{file} && $olddrive->{file} eq $volid;
 204             }
 205
 206             if ($volid_is_new) {
 207
 208                 PVE::Storage::activate_volumes($storecfg, [ $volid ]) if $storeid;
 209
 210                 my $size = PVE::Storage::volume_size_info($storecfg, $volid);
 211
 212                 die "volume $volid does not exist\n" if !$size;
 213
 214                 $disk->{size} = $size;
 215             }
 216
 217             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 218         }
 219     };
 220
 221     eval { PVE::QemuConfig->foreach_volume($settings, $code); };
 222
 223     # free allocated images on error
 224     if (my $err = $@) {
 225         syslog('err', "VM $vmid creating disks failed");
 226         foreach my $volid (@$vollist) {
 227             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 228             warn $@ if $@;
 229         }
 230         die $err;
 231     }
 232
 233     # modify vm config if everything went well
 234     foreach my $ds (keys %$res) {
 235         $conf->{$ds} = $res->{$ds};
 236     }
 237
 238     return $vollist;
 239 };
 240
 241 my $check_cpu_model_access = sub {
 242     my ($rpcenv, $authuser, $new, $existing) = @_;
 243
 244     return if !defined($new->{cpu});
 245
 246     my $cpu = PVE::JSONSchema::check_format('pve-vm-cpu-conf', $new->{cpu});
 247     return if !$cpu || !$cpu->{cputype}; # always allow default
 248     my $cputype = $cpu->{cputype};
 249
 250     if ($existing && $existing->{cpu}) {
 251         # changing only other settings doesn't require permissions for CPU model
 252         my $existingCpu = PVE::JSONSchema::check_format('pve-vm-cpu-conf', $existing->{cpu});
 253         return if $existingCpu->{cputype} eq $cputype;
 254     }
 255
 256     if (PVE::QemuServer::CPUConfig::is_custom_model($cputype)) {
 257         $rpcenv->check($authuser, "/nodes", ['Sys.Audit']);
 258     }
 259 };
 260
 261 my $cpuoptions = {
 262     'cores' => 1,
 263     'cpu' => 1,
 264     'cpulimit' => 1,
 265     'cpuunits' => 1,
 266     'numa' => 1,
 267     'smp' => 1,
 268     'sockets' => 1,
 269     'vcpus' => 1,
 270 };
 271
 272 my $memoryoptions = {
 273     'memory' => 1,
 274     'balloon' => 1,
 275     'shares' => 1,
 276 };
 277
 278 my $hwtypeoptions = {
 279     'acpi' => 1,
 280     'hotplug' => 1,
 281     'kvm' => 1,
 282     'machine' => 1,
 283     'scsihw' => 1,
 284     'smbios1' => 1,
 285     'tablet' => 1,
 286     'vga' => 1,
 287     'watchdog' => 1,
 288     'audio0' => 1,
 289 };
 290
 291 my $generaloptions = {
 292     'agent' => 1,
 293     'autostart' => 1,
 294     'bios' => 1,
 295     'description' => 1,
 296     'keyboard' => 1,
 297     'localtime' => 1,
 298     'migrate_downtime' => 1,
 299     'migrate_speed' => 1,
 300     'name' => 1,
 301     'onboot' => 1,
 302     'ostype' => 1,
 303     'protection' => 1,
 304     'reboot' => 1,
 305     'startdate' => 1,
 306     'startup' => 1,
 307     'tdf' => 1,
 308     'template' => 1,
 309     'tags' => 1,
 310 };
 311
 312 my $vmpoweroptions = {
 313     'freeze' => 1,
 314 };
 315
 316 my $diskoptions = {
 317     'boot' => 1,
 318     'bootdisk' => 1,
 319     'vmstatestorage' => 1,
 320 };
 321
 322 my $cloudinitoptions = {
 323     cicustom => 1,
 324     cipassword => 1,
 325     citype => 1,
 326     ciuser => 1,
 327     nameserver => 1,
 328     searchdomain => 1,
 329     sshkeys => 1,
 330 };
 331
 332 my $check_vm_create_serial_perm = sub {
 333     my ($rpcenv, $authuser, $vmid, $pool, $param) = @_;
 334
 335     return 1 if $authuser eq 'root@pam';
 336
 337     foreach my $opt (keys %{$param}) {
 338         next if $opt !~ m/^serial\d+$/;
 339
 340         if ($param->{$opt} eq 'socket') {
 341             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.HWType']);
 342         } else {
 343             die "only root can set '$opt' config for real devices\n";
 344         }
 345     }
 346
 347     return 1;
 348 };
 349
 350 my $check_vm_create_usb_perm = sub {
 351     my ($rpcenv, $authuser, $vmid, $pool, $param) = @_;
 352
 353     return 1 if $authuser eq 'root@pam';
 354
 355     foreach my $opt (keys %{$param}) {
 356         next if $opt !~ m/^usb\d+$/;
 357
 358         if ($param->{$opt} =~ m/spice/) {
 359             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.HWType']);
 360         } else {
 361             die "only root can set '$opt' config for real devices\n";
 362         }
 363     }
 364
 365     return 1;
 366 };
 367
 368 my $check_vm_modify_config_perm = sub {
 369     my ($rpcenv, $authuser, $vmid, $pool, $key_list) = @_;
 370
 371     return 1 if $authuser eq 'root@pam';
 372
 373     foreach my $opt (@$key_list) {
 374         # some checks (e.g., disk, serial port, usb) need to be done somewhere
 375         # else, as there the permission can be value dependend
 376         next if PVE::QemuServer::is_valid_drivename($opt);
 377         next if $opt eq 'cdrom';
 378         next if $opt =~ m/^(?:unused|serial|usb)\d+$/;
 379
 380
 381         if ($cpuoptions->{$opt} || $opt =~ m/^numa\d+$/) {
 382             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
 383         } elsif ($memoryoptions->{$opt}) {
 384             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
 385         } elsif ($hwtypeoptions->{$opt}) {
 386             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.HWType']);
 387         } elsif ($generaloptions->{$opt}) {
 388             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
 389             # special case for startup since it changes host behaviour
 390             if ($opt eq 'startup') {
 391                 $rpcenv->check_full($authuser, "/", ['Sys.Modify']);
 392             }
 393         } elsif ($vmpoweroptions->{$opt}) {
 394             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.PowerMgmt']);
 395         } elsif ($diskoptions->{$opt}) {
 396             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
 397         } elsif ($opt =~ m/^(?:net|ipconfig)\d+$/) {
 398             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
 399         } elsif ($cloudinitoptions->{$opt}) {
 400             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Cloudinit', 'VM.Config.Network'], 1);
 401         } elsif ($opt eq 'vmstate') {
 402             # the user needs Disk and PowerMgmt privileges to change the vmstate
 403             # also needs privileges on the storage, that will be checked later
 404             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk', 'VM.PowerMgmt' ]);
 405         } else {
 406             # catches hostpci\d+, args, lock, etc.
 407             # new options will be checked here
 408             die "only root can set '$opt' config\n";
 409         }
 410     }
 411
 412     return 1;
 413 };
 414
 415 __PACKAGE__->register_method({
 416     name => 'vmlist',
 417     path => '',
 418     method => 'GET',
 419     description => "Virtual machine index (per node).",
 420     permissions => {
 421         description => "Only list VMs where you have VM.Audit permissons on /vms/<vmid>.",
 422         user => 'all',
 423     },
 424     proxyto => 'node',
 425     protected => 1, # qemu pid files are only readable by root
 426     parameters => {
 427         additionalProperties => 0,
 428         properties => {
 429             node => get_standard_option('pve-node'),
 430             full => {
 431                 type => 'boolean',
 432                 optional => 1,
 433                 description => "Determine the full status of active VMs.",
 434             },
 435         },
 436     },
 437     returns => {
 438         type => 'array',
 439         items => {
 440             type => "object",
 441             properties => $PVE::QemuServer::vmstatus_return_properties,
 442         },
 443         links => [ { rel => 'child', href => "{vmid}" } ],
 444     },
 445     code => sub {
 446         my ($param) = @_;
 447
 448         my $rpcenv = PVE::RPCEnvironment::get();
 449         my $authuser = $rpcenv->get_user();
 450
 451         my $vmstatus = PVE::QemuServer::vmstatus(undef, $param->{full});
 452
 453         my $res = [];
 454         foreach my $vmid (keys %$vmstatus) {
 455             next if !$rpcenv->check($authuser, "/vms/$vmid", [ 'VM.Audit' ], 1);
 456
 457             my $data = $vmstatus->{$vmid};
 458             push @$res, $data;
 459         }
 460
 461         return $res;
 462     }});
 463
 464 my $parse_restore_archive = sub {
 465     my ($storecfg, $archive) = @_;
 466
 467     my ($archive_storeid, $archive_volname) = PVE::Storage::parse_volume_id($archive, 1);
 468
 469     if (defined($archive_storeid)) {
 470         my $scfg =  PVE::Storage::storage_config($storecfg, $archive_storeid);
 471         if ($scfg->{type} eq 'pbs') {
 472             return {
 473                 type => 'pbs',
 474                 volid => $archive,
 475             };
 476         }
 477     }
 478     my $path = PVE::Storage::abs_filesystem_path($storecfg, $archive);
 479     return {
 480         type => 'file',
 481         path => $path,
 482     };
 483 };
 484
 485
 486 __PACKAGE__->register_method({
 487     name => 'create_vm',
 488     path => '',
 489     method => 'POST',
 490     description => "Create or restore a virtual machine.",
 491     permissions => {
 492         description => "You need 'VM.Allocate' permissions on /vms/{vmid} or on the VM pool /pool/{pool}. " .
 493             "For restore (option 'archive'), it is enough if the user has 'VM.Backup' permission and the VM already exists. " .
 494             "If you create disks you need 'Datastore.AllocateSpace' on any used storage.",
 495         user => 'all', # check inside
 496     },
 497     protected => 1,
 498     proxyto => 'node',
 499     parameters => {
 500         additionalProperties => 0,
 501         properties => PVE::QemuServer::json_config_properties(
 502             {
 503                 node => get_standard_option('pve-node'),
 504                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::Cluster::complete_next_vmid }),
 505                 archive => {
 506                     description => "The backup archive. Either the file system path to a .tar or .vma file (use '-' to pipe data from stdin) or a proxmox storage backup volume identifier.",
 507                     type => 'string',
 508                     optional => 1,
 509                     maxLength => 255,
 510                     completion => \&PVE::QemuServer::complete_backup_archives,
 511                 },
 512                 storage => get_standard_option('pve-storage-id', {
 513                     description => "Default storage.",
 514                     optional => 1,
 515                     completion => \&PVE::QemuServer::complete_storage,
 516                 }),
 517                 force => {
 518                     optional => 1,
 519                     type => 'boolean',
 520                     description => "Allow to overwrite existing VM.",
 521                     requires => 'archive',
 522                 },
 523                 unique => {
 524                     optional => 1,
 525                     type => 'boolean',
 526                     description => "Assign a unique random ethernet address.",
 527                     requires => 'archive',
 528                 },
 529                 'live-restore' => {
 530                     optional => 1,
 531                     type => 'boolean',
 532                     description => "Start the VM immediately from the backup and restore in background. PBS only.",
 533                     requires => 'archive',
 534                 },
 535                 pool => {
 536                     optional => 1,
 537                     type => 'string', format => 'pve-poolid',
 538                     description => "Add the VM to the specified pool.",
 539                 },
 540                 bwlimit => {
 541                     description => "Override I/O bandwidth limit (in KiB/s).",
 542                     optional => 1,
 543                     type => 'integer',
 544                     minimum => '0',
 545                     default => 'restore limit from datacenter or storage config',
 546                 },
 547                 start => {
 548                     optional => 1,
 549                     type => 'boolean',
 550                     default => 0,
 551                     description => "Start VM after it was created successfully.",
 552                 },
 553             }),
 554     },
 555     returns => {
 556         type => 'string',
 557     },
 558     code => sub {
 559         my ($param) = @_;
 560
 561         my $rpcenv = PVE::RPCEnvironment::get();
 562         my $authuser = $rpcenv->get_user();
 563
 564         my $node = extract_param($param, 'node');
 565         my $vmid = extract_param($param, 'vmid');
 566
 567         my $archive = extract_param($param, 'archive');
 568         my $is_restore = !!$archive;
 569
 570         my $bwlimit = extract_param($param, 'bwlimit');
 571         my $force = extract_param($param, 'force');
 572         my $pool = extract_param($param, 'pool');
 573         my $start_after_create = extract_param($param, 'start');
 574         my $storage = extract_param($param, 'storage');
 575         my $unique = extract_param($param, 'unique');
 576         my $live_restore = extract_param($param, 'live-restore');
 577
 578         if (defined(my $ssh_keys = $param->{sshkeys})) {
 579                 $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
 580                 PVE::Tools::validate_ssh_public_keys($ssh_keys);
 581         }
 582
 583         PVE::Cluster::check_cfs_quorum();
 584
 585         my $filename = PVE::QemuConfig->config_file($vmid);
 586         my $storecfg = PVE::Storage::config();
 587
 588         if (defined($pool)) {
 589             $rpcenv->check_pool_exist($pool);
 590         }
 591
 592         $rpcenv->check($authuser, "/storage/$storage", ['Datastore.AllocateSpace'])
 593             if defined($storage);
 594
 595         if ($rpcenv->check($authuser, "/vms/$vmid", ['VM.Allocate'], 1)) {
 596             # OK
 597         } elsif ($pool && $rpcenv->check($authuser, "/pool/$pool", ['VM.Allocate'], 1)) {
 598             # OK
 599         } elsif ($archive && $force && (-f $filename) &&
 600                  $rpcenv->check($authuser, "/vms/$vmid", ['VM.Backup'], 1)) {
 601             # OK: user has VM.Backup permissions, and want to restore an existing VM
 602         } else {
 603             raise_perm_exc();
 604         }
 605
 606         if (!$archive) {
 607             &$resolve_cdrom_alias($param);
 608
 609             &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param, $storage);
 610
 611             &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, $pool, [ keys %$param]);
 612
 613             &$check_vm_create_serial_perm($rpcenv, $authuser, $vmid, $pool, $param);
 614             &$check_vm_create_usb_perm($rpcenv, $authuser, $vmid, $pool, $param);
 615
 616             &$check_cpu_model_access($rpcenv, $authuser, $param);
 617
 618             foreach my $opt (keys %$param) {
 619                 if (PVE::QemuServer::is_valid_drivename($opt)) {
 620                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
 621                     raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
 622
 623                     PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
 624                     $param->{$opt} = PVE::QemuServer::print_drive($drive);
 625                 }
 626             }
 627
 628             PVE::QemuServer::add_random_macs($param);
 629         } else {
 630             my $keystr = join(' ', keys %$param);
 631             raise_param_exc({ archive => "option conflicts with other options ($keystr)"}) if $keystr;
 632
 633             if ($archive eq '-') {
 634                 die "pipe requires cli environment\n"
 635                     if $rpcenv->{type} ne 'cli';
 636                 $archive = { type => 'pipe' };
 637             } else {
 638                 PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $archive);
 639
 640                 $archive = $parse_restore_archive->($storecfg, $archive);
 641             }
 642         }
 643
 644         my $emsg = $is_restore ? "unable to restore VM $vmid -" : "unable to create VM $vmid -";
 645
 646         eval { PVE::QemuConfig->create_and_lock_config($vmid, $force) };
 647         die "$emsg $@" if $@;
 648
 649         my $restored_data = 0;
 650         my $restorefn = sub {
 651             my $conf = PVE::QemuConfig->load_config($vmid);
 652
 653             PVE::QemuConfig->check_protection($conf, $emsg);
 654
 655             die "$emsg vm is running\n" if PVE::QemuServer::check_running($vmid);
 656
 657             my $realcmd = sub {
 658                 my $restore_options = {
 659                     storage => $storage,
 660                     pool => $pool,
 661                     unique => $unique,
 662                     bwlimit => $bwlimit,
 663                     live => $live_restore,
 664                 };
 665                 if ($archive->{type} eq 'file' || $archive->{type} eq 'pipe') {
 666                     die "live-restore is only compatible with backup images from a Proxmox Backup Server\n"
 667                         if $live_restore;
 668                     PVE::QemuServer::restore_file_archive($archive->{path} // '-', $vmid, $authuser, $restore_options);
 669                 } elsif ($archive->{type} eq 'pbs') {
 670                     PVE::QemuServer::restore_proxmox_backup_archive($archive->{volid}, $vmid, $authuser, $restore_options);
 671                 } else {
 672                     die "unknown backup archive type\n";
 673                 }
 674                 $restored_data = 1;
 675
 676                 my $restored_conf = PVE::QemuConfig->load_config($vmid);
 677                 # Convert restored VM to template if backup was VM template
 678                 if (PVE::QemuConfig->is_template($restored_conf)) {
 679                     warn "Convert to template.\n";
 680                     eval { PVE::QemuServer::template_create($vmid, $restored_conf) };
 681                     warn $@ if $@;
 682                 }
 683             };
 684
 685             # ensure no old replication state are exists
 686             PVE::ReplicationState::delete_guest_states($vmid);
 687
 688             PVE::QemuConfig->lock_config_full($vmid, 1, $realcmd);
 689
 690             if ($start_after_create && !$live_restore) {
 691                 print "Execute autostart\n";
 692                 eval { PVE::API2::Qemu->vm_start({ vmid => $vmid, node => $node }) };
 693                 warn $@ if $@;
 694             }
 695         };
 696
 697         my $createfn = sub {
 698             # ensure no old replication state are exists
 699             PVE::ReplicationState::delete_guest_states($vmid);
 700
 701             my $realcmd = sub {
 702                 my $conf = $param;
 703                 my $arch = PVE::QemuServer::get_vm_arch($conf);
 704
 705                 my $vollist = [];
 706                 eval {
 707                     $vollist = &$create_disks($rpcenv, $authuser, $conf, $arch, $storecfg, $vmid, $pool, $param, $storage);
 708
 709                     if (!$conf->{boot}) {
 710                         my $devs = PVE::QemuServer::get_default_bootdevices($conf);
 711                         $conf->{boot} = PVE::QemuServer::print_bootorder($devs);
 712                     }
 713
 714                     # auto generate uuid if user did not specify smbios1 option
 715                     if (!$conf->{smbios1}) {
 716                         $conf->{smbios1} = PVE::QemuServer::generate_smbios1_uuid();
 717                     }
 718
 719                     if ((!defined($conf->{vmgenid}) || $conf->{vmgenid} eq '1') && $arch ne 'aarch64') {
 720                         $conf->{vmgenid} = PVE::QemuServer::generate_uuid();
 721                     }
 722
 723                     my $machine = $conf->{machine};
 724                     if (!$machine || $machine =~ m/^(?:pc|q35|virt)$/) {
 725                         # always pin Windows' machine version on create, they get to easily confused
 726                         if (PVE::QemuServer::windows_version($conf->{ostype})) {
 727                             $conf->{machine} = PVE::QemuServer::windows_get_pinned_machine_version($machine);
 728                         }
 729                     }
 730
 731                     PVE::QemuConfig->write_config($vmid, $conf);
 732
 733                 };
 734                 my $err = $@;
 735
 736                 if ($err) {
 737                     foreach my $volid (@$vollist) {
 738                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 739                         warn $@ if $@;
 740                     }
 741                     die "$emsg $err";
 742                 }
 743
 744                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 745             };
 746
 747             PVE::QemuConfig->lock_config_full($vmid, 1, $realcmd);
 748
 749             if ($start_after_create) {
 750                 print "Execute autostart\n";
 751                 eval { PVE::API2::Qemu->vm_start({vmid => $vmid, node => $node}) };
 752                 warn $@ if $@;
 753             }
 754         };
 755
 756         my ($code, $worker_name);
 757         if ($is_restore) {
 758             $worker_name = 'qmrestore';
 759             $code = sub {
 760                 eval { $restorefn->() };
 761                 if (my $err = $@) {
 762                     eval { PVE::QemuConfig->remove_lock($vmid, 'create') };
 763                     warn $@ if $@;
 764                     if ($restored_data) {
 765                         warn "error after data was restored, VM disks should be OK but config may "
 766                             ."require adaptions. VM $vmid state is NOT cleaned up.\n";
 767                     } else {
 768                         warn "error before or during data restore, some or all disks were not "
 769                             ."completely restored. VM $vmid state is NOT cleaned up.\n";
 770                     }
 771                     die $err;
 772                 }
 773             };
 774         } else {
 775             $worker_name = 'qmcreate';
 776             $code = sub {
 777                 eval { $createfn->() };
 778                 if (my $err = $@) {
 779                     eval {
 780                         my $conffile = PVE::QemuConfig->config_file($vmid);
 781                         unlink($conffile) or die "failed to remove config file: $!\n";
 782                     };
 783                     warn $@ if $@;
 784                     die $err;
 785                 }
 786             };
 787         }
 788
 789         return $rpcenv->fork_worker($worker_name, $vmid, $authuser, $code);
 790     }});
 791
 792 __PACKAGE__->register_method({
 793     name => 'vmdiridx',
 794     path => '{vmid}',
 795     method => 'GET',
 796     proxyto => 'node',
 797     description => "Directory index",
 798     permissions => {
 799         user => 'all',
 800     },
 801     parameters => {
 802         additionalProperties => 0,
 803         properties => {
 804             node => get_standard_option('pve-node'),
 805             vmid => get_standard_option('pve-vmid'),
 806         },
 807     },
 808     returns => {
 809         type => 'array',
 810         items => {
 811             type => "object",
 812             properties => {
 813                 subdir => { type => 'string' },
 814             },
 815         },
 816         links => [ { rel => 'child', href => "{subdir}" } ],
 817     },
 818     code => sub {
 819         my ($param) = @_;
 820
 821         my $res = [
 822             { subdir => 'config' },
 823             { subdir => 'pending' },
 824             { subdir => 'status' },
 825             { subdir => 'unlink' },
 826             { subdir => 'vncproxy' },
 827             { subdir => 'termproxy' },
 828             { subdir => 'migrate' },
 829             { subdir => 'resize' },
 830             { subdir => 'move' },
 831             { subdir => 'rrd' },
 832             { subdir => 'rrddata' },
 833             { subdir => 'monitor' },
 834             { subdir => 'agent' },
 835             { subdir => 'snapshot' },
 836             { subdir => 'spiceproxy' },
 837             { subdir => 'sendkey' },
 838             { subdir => 'firewall' },
 839             ];
 840
 841         return $res;
 842     }});
 843
 844 __PACKAGE__->register_method ({
 845     subclass => "PVE::API2::Firewall::VM",
 846     path => '{vmid}/firewall',
 847 });
 848
 849 __PACKAGE__->register_method ({
 850     subclass => "PVE::API2::Qemu::Agent",
 851     path => '{vmid}/agent',
 852 });
 853
 854 __PACKAGE__->register_method({
 855     name => 'rrd',
 856     path => '{vmid}/rrd',
 857     method => 'GET',
 858     protected => 1, # fixme: can we avoid that?
 859     permissions => {
 860         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 861     },
 862     description => "Read VM RRD statistics (returns PNG)",
 863     parameters => {
 864         additionalProperties => 0,
 865         properties => {
 866             node => get_standard_option('pve-node'),
 867             vmid => get_standard_option('pve-vmid'),
 868             timeframe => {
 869                 description => "Specify the time frame you are interested in.",
 870                 type => 'string',
 871                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 872             },
 873             ds => {
 874                 description => "The list of datasources you want to display.",
 875                 type => 'string', format => 'pve-configid-list',
 876             },
 877             cf => {
 878                 description => "The RRD consolidation function",
 879                 type => 'string',
 880                 enum => [ 'AVERAGE', 'MAX' ],
 881                 optional => 1,
 882             },
 883         },
 884     },
 885     returns => {
 886         type => "object",
 887         properties => {
 888             filename => { type => 'string' },
 889         },
 890     },
 891     code => sub {
 892         my ($param) = @_;
 893
 894         return PVE::RRD::create_rrd_graph(
 895             "pve2-vm/$param->{vmid}", $param->{timeframe},
 896             $param->{ds}, $param->{cf});
 897
 898     }});
 899
 900 __PACKAGE__->register_method({
 901     name => 'rrddata',
 902     path => '{vmid}/rrddata',
 903     method => 'GET',
 904     protected => 1, # fixme: can we avoid that?
 905     permissions => {
 906         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 907     },
 908     description => "Read VM RRD statistics",
 909     parameters => {
 910         additionalProperties => 0,
 911         properties => {
 912             node => get_standard_option('pve-node'),
 913             vmid => get_standard_option('pve-vmid'),
 914             timeframe => {
 915                 description => "Specify the time frame you are interested in.",
 916                 type => 'string',
 917                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 918             },
 919             cf => {
 920                 description => "The RRD consolidation function",
 921                 type => 'string',
 922                 enum => [ 'AVERAGE', 'MAX' ],
 923                 optional => 1,
 924             },
 925         },
 926     },
 927     returns => {
 928         type => "array",
 929         items => {
 930             type => "object",
 931             properties => {},
 932         },
 933     },
 934     code => sub {
 935         my ($param) = @_;
 936
 937         return PVE::RRD::create_rrd_data(
 938             "pve2-vm/$param->{vmid}", $param->{timeframe}, $param->{cf});
 939     }});
 940
 941
 942 __PACKAGE__->register_method({
 943     name => 'vm_config',
 944     path => '{vmid}/config',
 945     method => 'GET',
 946     proxyto => 'node',
 947     description => "Get the virtual machine configuration with pending configuration " .
 948         "changes applied. Set the 'current' parameter to get the current configuration instead.",
 949     permissions => {
 950         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 951     },
 952     parameters => {
 953         additionalProperties => 0,
 954         properties => {
 955             node => get_standard_option('pve-node'),
 956             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 957             current => {
 958                 description => "Get current values (instead of pending values).",
 959                 optional => 1,
 960                 default => 0,
 961                 type => 'boolean',
 962             },
 963             snapshot => get_standard_option('pve-snapshot-name', {
 964                 description => "Fetch config values from given snapshot.",
 965                 optional => 1,
 966                 completion => sub {
 967                     my ($cmd, $pname, $cur, $args) = @_;
 968                     PVE::QemuConfig->snapshot_list($args->[0]);
 969                 },
 970             }),
 971         },
 972     },
 973     returns => {
 974         description => "The VM configuration.",
 975         type => "object",
 976         properties => PVE::QemuServer::json_config_properties({
 977             digest => {
 978                 type => 'string',
 979                 description => 'SHA1 digest of configuration file. This can be used to prevent concurrent modifications.',
 980             }
 981         }),
 982     },
 983     code => sub {
 984         my ($param) = @_;
 985
 986         raise_param_exc({ snapshot => "cannot use 'snapshot' parameter with 'current'",
 987                           current => "cannot use 'snapshot' parameter with 'current'"})
 988             if ($param->{snapshot} && $param->{current});
 989
 990         my $conf;
 991         if ($param->{snapshot}) {
 992             $conf = PVE::QemuConfig->load_snapshot_config($param->{vmid}, $param->{snapshot});
 993         } else {
 994             $conf = PVE::QemuConfig->load_current_config($param->{vmid}, $param->{current});
 995         }
 996         $conf->{cipassword} = '**********' if $conf->{cipassword};
 997         return $conf;
 998
 999     }});
1000
1001 __PACKAGE__->register_method({
1002     name => 'vm_pending',
1003     path => '{vmid}/pending',
1004     method => 'GET',
1005     proxyto => 'node',
1006     description => "Get the virtual machine configuration with both current and pending values.",
1007     permissions => {
1008         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1009     },
1010     parameters => {
1011         additionalProperties => 0,
1012         properties => {
1013             node => get_standard_option('pve-node'),
1014             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1015         },
1016     },
1017     returns => {
1018         type => "array",
1019         items => {
1020             type => "object",
1021             properties => {
1022                 key => {
1023                     description => "Configuration option name.",
1024                     type => 'string',
1025                 },
1026                 value => {
1027                     description => "Current value.",
1028                     type => 'string',
1029                     optional => 1,
1030                 },
1031                 pending => {
1032                     description => "Pending value.",
1033                     type => 'string',
1034                     optional => 1,
1035                 },
1036                 delete => {
1037                     description => "Indicates a pending delete request if present and not 0. " .
1038                                    "The value 2 indicates a force-delete request.",
1039                     type => 'integer',
1040                     minimum => 0,
1041                     maximum => 2,
1042                     optional => 1,
1043                 },
1044             },
1045         },
1046     },
1047     code => sub {
1048         my ($param) = @_;
1049
1050         my $conf = PVE::QemuConfig->load_config($param->{vmid});
1051
1052         my $pending_delete_hash = PVE::QemuConfig->parse_pending_delete($conf->{pending}->{delete});
1053
1054         $conf->{cipassword} = '**********' if defined($conf->{cipassword});
1055         $conf->{pending}->{cipassword} = '********** ' if defined($conf->{pending}->{cipassword});
1056
1057         return PVE::GuestHelpers::config_with_pending_array($conf, $pending_delete_hash);
1058    }});
1059
1060 # POST/PUT {vmid}/config implementation
1061 #
1062 # The original API used PUT (idempotent) an we assumed that all operations
1063 # are fast. But it turned out that almost any configuration change can
1064 # involve hot-plug actions, or disk alloc/free. Such actions can take long
1065 # time to complete and have side effects (not idempotent).
1066 #
1067 # The new implementation uses POST and forks a worker process. We added
1068 # a new option 'background_delay'. If specified we wait up to
1069 # 'background_delay' second for the worker task to complete. It returns null
1070 # if the task is finished within that time, else we return the UPID.
1071
1072 my $update_vm_api  = sub {
1073     my ($param, $sync) = @_;
1074
1075     my $rpcenv = PVE::RPCEnvironment::get();
1076
1077     my $authuser = $rpcenv->get_user();
1078
1079     my $node = extract_param($param, 'node');
1080
1081     my $vmid = extract_param($param, 'vmid');
1082
1083     my $digest = extract_param($param, 'digest');
1084
1085     my $background_delay = extract_param($param, 'background_delay');
1086
1087     if (defined(my $cipassword = $param->{cipassword})) {
1088         # Same logic as in cloud-init (but with the regex fixed...)
1089         $param->{cipassword} = PVE::Tools::encrypt_pw($cipassword)
1090             if $cipassword !~ /^\$(?:[156]|2[ay])(\$.+){2}/;
1091     }
1092
1093     my @paramarr = (); # used for log message
1094     foreach my $key (sort keys %$param) {
1095         my $value = $key eq 'cipassword' ? '<hidden>' : $param->{$key};
1096         push @paramarr, "-$key", $value;
1097     }
1098
1099     my $skiplock = extract_param($param, 'skiplock');
1100     raise_param_exc({ skiplock => "Only root may use this option." })
1101         if $skiplock && $authuser ne 'root@pam';
1102
1103     my $delete_str = extract_param($param, 'delete');
1104
1105     my $revert_str = extract_param($param, 'revert');
1106
1107     my $force = extract_param($param, 'force');
1108
1109     if (defined(my $ssh_keys = $param->{sshkeys})) {
1110         $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
1111         PVE::Tools::validate_ssh_public_keys($ssh_keys);
1112     }
1113
1114     die "no options specified\n" if !$delete_str && !$revert_str && !scalar(keys %$param);
1115
1116     my $storecfg = PVE::Storage::config();
1117
1118     my $defaults = PVE::QemuServer::load_defaults();
1119
1120     &$resolve_cdrom_alias($param);
1121
1122     # now try to verify all parameters
1123
1124     my $revert = {};
1125     foreach my $opt (PVE::Tools::split_list($revert_str)) {
1126         if (!PVE::QemuServer::option_exists($opt)) {
1127             raise_param_exc({ revert => "unknown option '$opt'" });
1128         }
1129
1130         raise_param_exc({ delete => "you can't use '-$opt' and " .
1131                               "-revert $opt' at the same time" })
1132             if defined($param->{$opt});
1133
1134         $revert->{$opt} = 1;
1135     }
1136
1137     my @delete = ();
1138     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1139         $opt = 'ide2' if $opt eq 'cdrom';
1140
1141         raise_param_exc({ delete => "you can't use '-$opt' and " .
1142                               "-delete $opt' at the same time" })
1143             if defined($param->{$opt});
1144
1145         raise_param_exc({ revert => "you can't use '-delete $opt' and " .
1146                               "-revert $opt' at the same time" })
1147             if $revert->{$opt};
1148
1149         if (!PVE::QemuServer::option_exists($opt)) {
1150             raise_param_exc({ delete => "unknown option '$opt'" });
1151         }
1152
1153         push @delete, $opt;
1154     }
1155
1156     my $repl_conf = PVE::ReplicationConfig->new();
1157     my $is_replicated = $repl_conf->check_for_existing_jobs($vmid, 1);
1158     my $check_replication = sub {
1159         my ($drive) = @_;
1160         return if !$is_replicated;
1161         my $volid = $drive->{file};
1162         return if !$volid || !($drive->{replicate}//1);
1163         return if PVE::QemuServer::drive_is_cdrom($drive);
1164
1165         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1166         die "cannot add non-managed/pass-through volume to a replicated VM\n"
1167             if !defined($storeid);
1168
1169         return if defined($volname) && $volname eq 'cloudinit';
1170
1171         my $format;
1172         if ($volid =~ $NEW_DISK_RE) {
1173             $storeid = $2;
1174             $format = $drive->{format} || PVE::Storage::storage_default_format($storecfg, $storeid);
1175         } else {
1176             $format = (PVE::Storage::parse_volname($storecfg, $volid))[6];
1177         }
1178         return if PVE::Storage::storage_can_replicate($storecfg, $storeid, $format);
1179         my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
1180         return if $scfg->{shared};
1181         die "cannot add non-replicatable volume to a replicated VM\n";
1182     };
1183
1184     foreach my $opt (keys %$param) {
1185         if (PVE::QemuServer::is_valid_drivename($opt)) {
1186             # cleanup drive path
1187             my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1188             raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
1189             PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
1190             $check_replication->($drive);
1191             $param->{$opt} = PVE::QemuServer::print_drive($drive);
1192         } elsif ($opt =~ m/^net(\d+)$/) {
1193             # add macaddr
1194             my $net = PVE::QemuServer::parse_net($param->{$opt});
1195             $param->{$opt} = PVE::QemuServer::print_net($net);
1196         } elsif ($opt eq 'vmgenid') {
1197             if ($param->{$opt} eq '1') {
1198                 $param->{$opt} = PVE::QemuServer::generate_uuid();
1199             }
1200         } elsif ($opt eq 'hookscript') {
1201             eval { PVE::GuestHelpers::check_hookscript($param->{$opt}, $storecfg); };
1202             raise_param_exc({ $opt => $@ }) if $@;
1203         }
1204     }
1205
1206     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [@delete]);
1207
1208     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [keys %$param]);
1209
1210     &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param);
1211
1212     my $updatefn =  sub {
1213
1214         my $conf = PVE::QemuConfig->load_config($vmid);
1215
1216         die "checksum missmatch (file change by other user?)\n"
1217             if $digest && $digest ne $conf->{digest};
1218
1219         &$check_cpu_model_access($rpcenv, $authuser, $param, $conf);
1220
1221         # FIXME: 'suspended' lock should probabyl be a state or "weak" lock?!
1222         if (scalar(@delete) && grep { $_ eq 'vmstate'} @delete) {
1223             if (defined($conf->{lock}) && $conf->{lock} eq 'suspended') {
1224                 delete $conf->{lock}; # for check lock check, not written out
1225                 push @delete, 'lock'; # this is the real deal to write it out
1226             }
1227             push @delete, 'runningmachine' if $conf->{runningmachine};
1228             push @delete, 'runningcpu' if $conf->{runningcpu};
1229         }
1230
1231         PVE::QemuConfig->check_lock($conf) if !$skiplock;
1232
1233         foreach my $opt (keys %$revert) {
1234             if (defined($conf->{$opt})) {
1235                 $param->{$opt} = $conf->{$opt};
1236             } elsif (defined($conf->{pending}->{$opt})) {
1237                 push @delete, $opt;
1238             }
1239         }
1240
1241         if ($param->{memory} || defined($param->{balloon})) {
1242             my $maxmem = $param->{memory} || $conf->{pending}->{memory} || $conf->{memory} || $defaults->{memory};
1243             my $balloon = defined($param->{balloon}) ? $param->{balloon} : $conf->{pending}->{balloon} || $conf->{balloon};
1244
1245             die "balloon value too large (must be smaller than assigned memory)\n"
1246                 if $balloon && $balloon > $maxmem;
1247         }
1248
1249         PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: " . join (' ', @paramarr));
1250
1251         my $worker = sub {
1252
1253             print "update VM $vmid: " . join (' ', @paramarr) . "\n";
1254
1255             # write updates to pending section
1256
1257             my $modified = {}; # record what $option we modify
1258
1259             my @bootorder;
1260             if (my $boot = $conf->{boot}) {
1261                 my $bootcfg = PVE::JSONSchema::parse_property_string('pve-qm-boot', $boot);
1262                 @bootorder = PVE::Tools::split_list($bootcfg->{order}) if $bootcfg && $bootcfg->{order};
1263             }
1264             my $bootorder_deleted = grep {$_ eq 'bootorder'} @delete;
1265
1266             foreach my $opt (@delete) {
1267                 $modified->{$opt} = 1;
1268                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1269
1270                 # value of what we want to delete, independent if pending or not
1271                 my $val = $conf->{$opt} // $conf->{pending}->{$opt};
1272                 if (!defined($val)) {
1273                     warn "cannot delete '$opt' - not set in current configuration!\n";
1274                     $modified->{$opt} = 0;
1275                     next;
1276                 }
1277                 my $is_pending_val = defined($conf->{pending}->{$opt});
1278                 delete $conf->{pending}->{$opt};
1279
1280                 # remove from bootorder if necessary
1281                 if (!$bootorder_deleted && @bootorder && grep {$_ eq $opt} @bootorder) {
1282                     @bootorder = grep {$_ ne $opt} @bootorder;
1283                     $conf->{pending}->{boot} = PVE::QemuServer::print_bootorder(\@bootorder);
1284                     $modified->{boot} = 1;
1285                 }
1286
1287                 if ($opt =~ m/^unused/) {
1288                     my $drive = PVE::QemuServer::parse_drive($opt, $val);
1289                     PVE::QemuConfig->check_protection($conf, "can't remove unused disk '$drive->{file}'");
1290                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1291                     if (PVE::QemuServer::try_deallocate_drive($storecfg, $vmid, $conf, $opt, $drive, $rpcenv, $authuser)) {
1292                         delete $conf->{$opt};
1293                         PVE::QemuConfig->write_config($vmid, $conf);
1294                     }
1295                 } elsif ($opt eq 'vmstate') {
1296                     PVE::QemuConfig->check_protection($conf, "can't remove vmstate '$val'");
1297                     if (PVE::QemuServer::try_deallocate_drive($storecfg, $vmid, $conf, $opt, { file => $val }, $rpcenv, $authuser, 1)) {
1298                         delete $conf->{$opt};
1299                         PVE::QemuConfig->write_config($vmid, $conf);
1300                     }
1301                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
1302                     PVE::QemuConfig->check_protection($conf, "can't remove drive '$opt'");
1303                     my $drive = PVE::QemuServer::parse_drive($opt, $val);
1304                     if (PVE::QemuServer::drive_is_cdrom($drive)) {
1305                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.CDROM']);
1306                     } else {
1307                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1308                     }
1309                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $val))
1310                         if $is_pending_val;
1311                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1312                     PVE::QemuConfig->write_config($vmid, $conf);
1313                 } elsif ($opt =~ m/^serial\d+$/) {
1314                     if ($val eq 'socket') {
1315                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1316                     } elsif ($authuser ne 'root@pam') {
1317                         die "only root can delete '$opt' config for real devices\n";
1318                     }
1319                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1320                     PVE::QemuConfig->write_config($vmid, $conf);
1321                 } elsif ($opt =~ m/^usb\d+$/) {
1322                     if ($val =~ m/spice/) {
1323                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1324                     } elsif ($authuser ne 'root@pam') {
1325                         die "only root can delete '$opt' config for real devices\n";
1326                     }
1327                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1328                     PVE::QemuConfig->write_config($vmid, $conf);
1329                 } else {
1330                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1331                     PVE::QemuConfig->write_config($vmid, $conf);
1332                 }
1333             }
1334
1335             foreach my $opt (keys %$param) { # add/change
1336                 $modified->{$opt} = 1;
1337                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1338                 next if defined($conf->{pending}->{$opt}) && ($param->{$opt} eq $conf->{pending}->{$opt}); # skip if nothing changed
1339
1340                 my $arch = PVE::QemuServer::get_vm_arch($conf);
1341
1342                 if (PVE::QemuServer::is_valid_drivename($opt)) {
1343                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1344                     # FIXME: cloudinit: CDROM or Disk?
1345                     if (PVE::QemuServer::drive_is_cdrom($drive)) { # CDROM
1346                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.CDROM']);
1347                     } else {
1348                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1349                     }
1350                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $conf->{pending}->{$opt}))
1351                         if defined($conf->{pending}->{$opt});
1352
1353                     &$create_disks($rpcenv, $authuser, $conf->{pending}, $arch, $storecfg, $vmid, undef, {$opt => $param->{$opt}});
1354                 } elsif ($opt =~ m/^serial\d+/) {
1355                     if ((!defined($conf->{$opt}) || $conf->{$opt} eq 'socket') && $param->{$opt} eq 'socket') {
1356                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1357                     } elsif ($authuser ne 'root@pam') {
1358                         die "only root can modify '$opt' config for real devices\n";
1359                     }
1360                     $conf->{pending}->{$opt} = $param->{$opt};
1361                 } elsif ($opt =~ m/^usb\d+/) {
1362                     if ((!defined($conf->{$opt}) || $conf->{$opt} =~ m/spice/) && $param->{$opt} =~ m/spice/) {
1363                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1364                     } elsif ($authuser ne 'root@pam') {
1365                         die "only root can modify '$opt' config for real devices\n";
1366                     }
1367                     $conf->{pending}->{$opt} = $param->{$opt};
1368                 } else {
1369                     $conf->{pending}->{$opt} = $param->{$opt};
1370
1371                     if ($opt eq 'boot') {
1372                         my $new_bootcfg = PVE::JSONSchema::parse_property_string('pve-qm-boot', $param->{$opt});
1373                         if ($new_bootcfg->{order}) {
1374                             my @devs = PVE::Tools::split_list($new_bootcfg->{order});
1375                             for my $dev (@devs) {
1376                                 my $exists = $conf->{$dev} || $conf->{pending}->{$dev};
1377                                 my $deleted = grep {$_ eq $dev} @delete;
1378                                 die "invalid bootorder: device '$dev' does not exist'\n"
1379                                     if !$exists || $deleted;
1380                             }
1381
1382                             # remove legacy boot order settings if new one set
1383                             $conf->{pending}->{$opt} = PVE::QemuServer::print_bootorder(\@devs);
1384                             PVE::QemuConfig->add_to_pending_delete($conf, "bootdisk")
1385                                 if $conf->{bootdisk};
1386                         }
1387                     }
1388                 }
1389                 PVE::QemuConfig->remove_from_pending_delete($conf, $opt);
1390                 PVE::QemuConfig->write_config($vmid, $conf);
1391             }
1392
1393             # remove pending changes when nothing changed
1394             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1395             my $changes = PVE::QemuConfig->cleanup_pending($conf);
1396             PVE::QemuConfig->write_config($vmid, $conf) if $changes;
1397
1398             return if !scalar(keys %{$conf->{pending}});
1399
1400             my $running = PVE::QemuServer::check_running($vmid);
1401
1402             # apply pending changes
1403
1404             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1405
1406             my $errors = {};
1407             if ($running) {
1408                 PVE::QemuServer::vmconfig_hotplug_pending($vmid, $conf, $storecfg, $modified, $errors);
1409             } else {
1410                 PVE::QemuServer::vmconfig_apply_pending($vmid, $conf, $storecfg, $running, $errors);
1411             }
1412             raise_param_exc($errors) if scalar(keys %$errors);
1413
1414             return;
1415         };
1416
1417         if ($sync) {
1418             &$worker();
1419             return;
1420         } else {
1421             my $upid = $rpcenv->fork_worker('qmconfig', $vmid, $authuser, $worker);
1422
1423             if ($background_delay) {
1424
1425                 # Note: It would be better to do that in the Event based HTTPServer
1426                 # to avoid blocking call to sleep.
1427
1428                 my $end_time = time() + $background_delay;
1429
1430                 my $task = PVE::Tools::upid_decode($upid);
1431
1432                 my $running = 1;
1433                 while (time() < $end_time) {
1434                     $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
1435                     last if !$running;
1436                     sleep(1); # this gets interrupted when child process ends
1437                 }
1438
1439                 if (!$running) {
1440                     my $status = PVE::Tools::upid_read_status($upid);
1441                     return if $status eq 'OK';
1442                     die $status;
1443                 }
1444             }
1445
1446             return $upid;
1447         }
1448     };
1449
1450     return PVE::QemuConfig->lock_config($vmid, $updatefn);
1451 };
1452
1453 my $vm_config_perm_list = [
1454             'VM.Config.Disk',
1455             'VM.Config.CDROM',
1456             'VM.Config.CPU',
1457             'VM.Config.Memory',
1458             'VM.Config.Network',
1459             'VM.Config.HWType',
1460             'VM.Config.Options',
1461             'VM.Config.Cloudinit',
1462     ];
1463
1464 __PACKAGE__->register_method({
1465     name => 'update_vm_async',
1466     path => '{vmid}/config',
1467     method => 'POST',
1468     protected => 1,
1469     proxyto => 'node',
1470     description => "Set virtual machine options (asynchrounous API).",
1471     permissions => {
1472         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1473     },
1474     parameters => {
1475         additionalProperties => 0,
1476         properties => PVE::QemuServer::json_config_properties(
1477             {
1478                 node => get_standard_option('pve-node'),
1479                 vmid => get_standard_option('pve-vmid'),
1480                 skiplock => get_standard_option('skiplock'),
1481                 delete => {
1482                     type => 'string', format => 'pve-configid-list',
1483                     description => "A list of settings you want to delete.",
1484                     optional => 1,
1485                 },
1486                 revert => {
1487                     type => 'string', format => 'pve-configid-list',
1488                     description => "Revert a pending change.",
1489                     optional => 1,
1490                 },
1491                 force => {
1492                     type => 'boolean',
1493                     description => $opt_force_description,
1494                     optional => 1,
1495                     requires => 'delete',
1496                 },
1497                 digest => {
1498                     type => 'string',
1499                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1500                     maxLength => 40,
1501                     optional => 1,
1502                 },
1503                 background_delay => {
1504                     type => 'integer',
1505                     description => "Time to wait for the task to finish. We return 'null' if the task finish within that time.",
1506                     minimum => 1,
1507                     maximum => 30,
1508                     optional => 1,
1509                 },
1510             }),
1511     },
1512     returns => {
1513         type => 'string',
1514         optional => 1,
1515     },
1516     code => $update_vm_api,
1517 });
1518
1519 __PACKAGE__->register_method({
1520     name => 'update_vm',
1521     path => '{vmid}/config',
1522     method => 'PUT',
1523     protected => 1,
1524     proxyto => 'node',
1525     description => "Set virtual machine options (synchrounous API) - You should consider using the POST method instead for any actions involving hotplug or storage allocation.",
1526     permissions => {
1527         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1528     },
1529     parameters => {
1530         additionalProperties => 0,
1531         properties => PVE::QemuServer::json_config_properties(
1532             {
1533                 node => get_standard_option('pve-node'),
1534                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1535                 skiplock => get_standard_option('skiplock'),
1536                 delete => {
1537                     type => 'string', format => 'pve-configid-list',
1538                     description => "A list of settings you want to delete.",
1539                     optional => 1,
1540                 },
1541                 revert => {
1542                     type => 'string', format => 'pve-configid-list',
1543                     description => "Revert a pending change.",
1544                     optional => 1,
1545                 },
1546                 force => {
1547                     type => 'boolean',
1548                     description => $opt_force_description,
1549                     optional => 1,
1550                     requires => 'delete',
1551                 },
1552                 digest => {
1553                     type => 'string',
1554                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1555                     maxLength => 40,
1556                     optional => 1,
1557                 },
1558             }),
1559     },
1560     returns => { type => 'null' },
1561     code => sub {
1562         my ($param) = @_;
1563         &$update_vm_api($param, 1);
1564         return;
1565     }
1566 });
1567
1568 __PACKAGE__->register_method({
1569     name => 'destroy_vm',
1570     path => '{vmid}',
1571     method => 'DELETE',
1572     protected => 1,
1573     proxyto => 'node',
1574     description => "Destroy the VM and  all used/owned volumes. Removes any VM specific permissions"
1575         ." and firewall rules",
1576     permissions => {
1577         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
1578     },
1579     parameters => {
1580         additionalProperties => 0,
1581         properties => {
1582             node => get_standard_option('pve-node'),
1583             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
1584             skiplock => get_standard_option('skiplock'),
1585             purge => {
1586                 type => 'boolean',
1587                 description => "Remove VMID from configurations, like backup & replication jobs and HA.",
1588                 optional => 1,
1589             },
1590             'destroy-unreferenced-disks' => {
1591                 type => 'boolean',
1592                 description => "If set, destroy additionally all disks not referenced in the config"
1593                  ." but with a matching VMID from all enabled storages.",
1594                 optional => 1,
1595                 default => 1, # FIXME: replace to false in PVE 7.0, this is dangerous!
1596             },
1597         },
1598     },
1599     returns => {
1600         type => 'string',
1601     },
1602     code => sub {
1603         my ($param) = @_;
1604
1605         my $rpcenv = PVE::RPCEnvironment::get();
1606         my $authuser = $rpcenv->get_user();
1607         my $vmid = $param->{vmid};
1608
1609         my $skiplock = $param->{skiplock};
1610         raise_param_exc({ skiplock => "Only root may use this option." })
1611             if $skiplock && $authuser ne 'root@pam';
1612
1613         my $early_checks = sub {
1614             # test if VM exists
1615             my $conf = PVE::QemuConfig->load_config($vmid);
1616             PVE::QemuConfig->check_protection($conf, "can't remove VM $vmid");
1617
1618             my $ha_managed = PVE::HA::Config::service_is_configured("vm:$vmid");
1619
1620             if (!$param->{purge}) {
1621                 die "unable to remove VM $vmid - used in HA resources and purge parameter not set.\n"
1622                     if $ha_managed;
1623                 # don't allow destroy if with replication jobs but no purge param
1624                 my $repl_conf = PVE::ReplicationConfig->new();
1625                 $repl_conf->check_for_existing_jobs($vmid);
1626             }
1627
1628             die "VM $vmid is running - destroy failed\n"
1629                 if PVE::QemuServer::check_running($vmid);
1630
1631             return $ha_managed;
1632         };
1633
1634         $early_checks->();
1635
1636         my $realcmd = sub {
1637             my $upid = shift;
1638
1639             my $storecfg = PVE::Storage::config();
1640
1641             syslog('info', "destroy VM $vmid: $upid\n");
1642             PVE::QemuConfig->lock_config($vmid, sub {
1643                 # repeat, config might have changed
1644                 my $ha_managed = $early_checks->();
1645
1646                 # FIXME: drop fallback to true with 7.0, to dangerous for default
1647                 my $purge_unreferenced = $param->{'destroy-unreferenced-disks'} // 1;
1648
1649                 PVE::QemuServer::destroy_vm(
1650                     $storecfg,
1651                     $vmid,
1652                     $skiplock, { lock => 'destroyed' },
1653                     $purge_unreferenced,
1654                 );
1655
1656                 PVE::AccessControl::remove_vm_access($vmid);
1657                 PVE::Firewall::remove_vmfw_conf($vmid);
1658                 if ($param->{purge}) {
1659                     print "purging VM $vmid from related configurations..\n";
1660                     PVE::ReplicationConfig::remove_vmid_jobs($vmid);
1661                     PVE::VZDump::Plugin::remove_vmid_from_backup_jobs($vmid);
1662
1663                     if ($ha_managed) {
1664                         PVE::HA::Config::delete_service_from_config("vm:$vmid");
1665                         print "NOTE: removed VM $vmid from HA resource configuration.\n";
1666                     }
1667                 }
1668
1669                 # only now remove the zombie config, else we can have reuse race
1670                 PVE::QemuConfig->destroy_config($vmid);
1671             });
1672         };
1673
1674         return $rpcenv->fork_worker('qmdestroy', $vmid, $authuser, $realcmd);
1675     }});
1676
1677 __PACKAGE__->register_method({
1678     name => 'unlink',
1679     path => '{vmid}/unlink',
1680     method => 'PUT',
1681     protected => 1,
1682     proxyto => 'node',
1683     description => "Unlink/delete disk images.",
1684     permissions => {
1685         check => [ 'perm', '/vms/{vmid}', ['VM.Config.Disk']],
1686     },
1687     parameters => {
1688         additionalProperties => 0,
1689         properties => {
1690             node => get_standard_option('pve-node'),
1691             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1692             idlist => {
1693                 type => 'string', format => 'pve-configid-list',
1694                 description => "A list of disk IDs you want to delete.",
1695             },
1696             force => {
1697                 type => 'boolean',
1698                 description => $opt_force_description,
1699                 optional => 1,
1700             },
1701         },
1702     },
1703     returns => { type => 'null'},
1704     code => sub {
1705         my ($param) = @_;
1706
1707         $param->{delete} = extract_param($param, 'idlist');
1708
1709         __PACKAGE__->update_vm($param);
1710
1711         return;
1712     }});
1713
1714 # uses good entropy, each char is limited to 6 bit to get printable chars simply
1715 my $gen_rand_chars = sub {
1716     my ($length) = @_;
1717
1718     die "invalid length $length" if $length < 1;
1719
1720     my $min = ord('!'); # first printable ascii
1721
1722     my $rand_bytes = Crypt::OpenSSL::Random::random_bytes($length);
1723     die "failed to generate random bytes!\n"
1724       if !$rand_bytes;
1725
1726     my $str = join('', map { chr((ord($_) & 0x3F) + $min) } split('', $rand_bytes));
1727
1728     return $str;
1729 };
1730
1731 my $sslcert;
1732
1733 __PACKAGE__->register_method({
1734     name => 'vncproxy',
1735     path => '{vmid}/vncproxy',
1736     method => 'POST',
1737     protected => 1,
1738     permissions => {
1739         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1740     },
1741     description => "Creates a TCP VNC proxy connections.",
1742     parameters => {
1743         additionalProperties => 0,
1744         properties => {
1745             node => get_standard_option('pve-node'),
1746             vmid => get_standard_option('pve-vmid'),
1747             websocket => {
1748                 optional => 1,
1749                 type => 'boolean',
1750                 description => "starts websockify instead of vncproxy",
1751             },
1752             'generate-password' => {
1753                 optional => 1,
1754                 type => 'boolean',
1755                 default => 0,
1756                 description => "Generates a random password to be used as ticket instead of the API ticket.",
1757             },
1758         },
1759     },
1760     returns => {
1761         additionalProperties => 0,
1762         properties => {
1763             user => { type => 'string' },
1764             ticket => { type => 'string' },
1765             password => {
1766                 optional => 1,
1767                 description => "Returned if requested with 'generate-password' param."
1768                     ." Consists of printable ASCII characters ('!' .. '~').",
1769                 type => 'string',
1770             },
1771             cert => { type => 'string' },
1772             port => { type => 'integer' },
1773             upid => { type => 'string' },
1774         },
1775     },
1776     code => sub {
1777         my ($param) = @_;
1778
1779         my $rpcenv = PVE::RPCEnvironment::get();
1780
1781         my $authuser = $rpcenv->get_user();
1782
1783         my $vmid = $param->{vmid};
1784         my $node = $param->{node};
1785         my $websocket = $param->{websocket};
1786
1787         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1788
1789         my $serial;
1790         if ($conf->{vga}) {
1791             my $vga = PVE::QemuServer::parse_vga($conf->{vga});
1792             $serial = $vga->{type} if $vga->{type} =~ m/^serial\d+$/;
1793         }
1794
1795         my $authpath = "/vms/$vmid";
1796
1797         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1798         my $password = $ticket;
1799         if ($param->{'generate-password'}) {
1800             $password = $gen_rand_chars->(8);
1801         }
1802
1803         $sslcert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192)
1804             if !$sslcert;
1805
1806         my $family;
1807         my $remcmd = [];
1808
1809         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1810             (undef, $family) = PVE::Cluster::remote_node_ip($node);
1811             my $sshinfo = PVE::SSHInfo::get_ssh_info($node);
1812             # NOTE: kvm VNC traffic is already TLS encrypted or is known unsecure
1813             $remcmd = PVE::SSHInfo::ssh_info_to_command($sshinfo, defined($serial) ? '-t' : '-T');
1814         } else {
1815             $family = PVE::Tools::get_host_address_family($node);
1816         }
1817
1818         my $port = PVE::Tools::next_vnc_port($family);
1819
1820         my $timeout = 10;
1821
1822         my $realcmd = sub {
1823             my $upid = shift;
1824
1825             syslog('info', "starting vnc proxy $upid\n");
1826
1827             my $cmd;
1828
1829             if (defined($serial)) {
1830
1831                 my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-iface', $serial, '-escape', '0' ];
1832
1833                 $cmd = ['/usr/bin/vncterm', '-rfbport', $port,
1834                         '-timeout', $timeout, '-authpath', $authpath,
1835                         '-perm', 'Sys.Console'];
1836
1837                 if ($param->{websocket}) {
1838                     $ENV{PVE_VNC_TICKET} = $password; # pass ticket to vncterm
1839                     push @$cmd, '-notls', '-listen', 'localhost';
1840                 }
1841
1842                 push @$cmd, '-c', @$remcmd, @$termcmd;
1843
1844                 PVE::Tools::run_command($cmd);
1845
1846             } else {
1847
1848                 $ENV{LC_PVE_TICKET} = $password if $websocket; # set ticket with "qm vncproxy"
1849
1850                 $cmd = [@$remcmd, "/usr/sbin/qm", 'vncproxy', $vmid];
1851
1852                 my $sock = IO::Socket::IP->new(
1853                     ReuseAddr => 1,
1854                     Listen => 1,
1855                     LocalPort => $port,
1856                     Proto => 'tcp',
1857                     GetAddrInfoFlags => 0,
1858                 ) or die "failed to create socket: $!\n";
1859                 # Inside the worker we shouldn't have any previous alarms
1860                 # running anyway...:
1861                 alarm(0);
1862                 local $SIG{ALRM} = sub { die "connection timed out\n" };
1863                 alarm $timeout;
1864                 accept(my $cli, $sock) or die "connection failed: $!\n";
1865                 alarm(0);
1866                 close($sock);
1867                 if (PVE::Tools::run_command($cmd,
1868                     output => '>&'.fileno($cli),
1869                     input => '<&'.fileno($cli),
1870                     noerr => 1) != 0)
1871                 {
1872                     die "Failed to run vncproxy.\n";
1873                 }
1874             }
1875
1876             return;
1877         };
1878
1879         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1880
1881         PVE::Tools::wait_for_vnc_port($port);
1882
1883         my $res = {
1884             user => $authuser,
1885             ticket => $ticket,
1886             port => $port,
1887             upid => $upid,
1888             cert => $sslcert,
1889         };
1890         $res->{password} = $password if $param->{'generate-password'};
1891
1892         return $res;
1893     }});
1894
1895 __PACKAGE__->register_method({
1896     name => 'termproxy',
1897     path => '{vmid}/termproxy',
1898     method => 'POST',
1899     protected => 1,
1900     permissions => {
1901         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1902     },
1903     description => "Creates a TCP proxy connections.",
1904     parameters => {
1905         additionalProperties => 0,
1906         properties => {
1907             node => get_standard_option('pve-node'),
1908             vmid => get_standard_option('pve-vmid'),
1909             serial=> {
1910                 optional => 1,
1911                 type => 'string',
1912                 enum => [qw(serial0 serial1 serial2 serial3)],
1913                 description => "opens a serial terminal (defaults to display)",
1914             },
1915         },
1916     },
1917     returns => {
1918         additionalProperties => 0,
1919         properties => {
1920             user => { type => 'string' },
1921             ticket => { type => 'string' },
1922             port => { type => 'integer' },
1923             upid => { type => 'string' },
1924         },
1925     },
1926     code => sub {
1927         my ($param) = @_;
1928
1929         my $rpcenv = PVE::RPCEnvironment::get();
1930
1931         my $authuser = $rpcenv->get_user();
1932
1933         my $vmid = $param->{vmid};
1934         my $node = $param->{node};
1935         my $serial = $param->{serial};
1936
1937         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1938
1939         if (!defined($serial)) {
1940             if ($conf->{vga}) {
1941                 my $vga = PVE::QemuServer::parse_vga($conf->{vga});
1942                 $serial = $vga->{type} if $vga->{type} =~ m/^serial\d+$/;
1943             }
1944         }
1945
1946         my $authpath = "/vms/$vmid";
1947
1948         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1949
1950         my $family;
1951         my $remcmd = [];
1952
1953         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1954             (undef, $family) = PVE::Cluster::remote_node_ip($node);
1955             my $sshinfo = PVE::SSHInfo::get_ssh_info($node);
1956             $remcmd = PVE::SSHInfo::ssh_info_to_command($sshinfo, '-t');
1957             push @$remcmd, '--';
1958         } else {
1959             $family = PVE::Tools::get_host_address_family($node);
1960         }
1961
1962         my $port = PVE::Tools::next_vnc_port($family);
1963
1964         my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-escape', '0'];
1965         push @$termcmd, '-iface', $serial if $serial;
1966
1967         my $realcmd = sub {
1968             my $upid = shift;
1969
1970             syslog('info', "starting qemu termproxy $upid\n");
1971
1972             my $cmd = ['/usr/bin/termproxy', $port, '--path', $authpath,
1973                        '--perm', 'VM.Console', '--'];
1974             push @$cmd, @$remcmd, @$termcmd;
1975
1976             PVE::Tools::run_command($cmd);
1977         };
1978
1979         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1980
1981         PVE::Tools::wait_for_vnc_port($port);
1982
1983         return {
1984             user => $authuser,
1985             ticket => $ticket,
1986             port => $port,
1987             upid => $upid,
1988         };
1989     }});
1990
1991 __PACKAGE__->register_method({
1992     name => 'vncwebsocket',
1993     path => '{vmid}/vncwebsocket',
1994     method => 'GET',
1995     permissions => {
1996         description => "You also need to pass a valid ticket (vncticket).",
1997         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1998     },
1999     description => "Opens a weksocket for VNC traffic.",
2000     parameters => {
2001         additionalProperties => 0,
2002         properties => {
2003             node => get_standard_option('pve-node'),
2004             vmid => get_standard_option('pve-vmid'),
2005             vncticket => {
2006                 description => "Ticket from previous call to vncproxy.",
2007                 type => 'string',
2008                 maxLength => 512,
2009             },
2010             port => {
2011                 description => "Port number returned by previous vncproxy call.",
2012                 type => 'integer',
2013                 minimum => 5900,
2014                 maximum => 5999,
2015             },
2016         },
2017     },
2018     returns => {
2019         type => "object",
2020         properties => {
2021             port => { type => 'string' },
2022         },
2023     },
2024     code => sub {
2025         my ($param) = @_;
2026
2027         my $rpcenv = PVE::RPCEnvironment::get();
2028
2029         my $authuser = $rpcenv->get_user();
2030
2031         my $vmid = $param->{vmid};
2032         my $node = $param->{node};
2033
2034         my $authpath = "/vms/$vmid";
2035
2036         PVE::AccessControl::verify_vnc_ticket($param->{vncticket}, $authuser, $authpath);
2037
2038         my $conf = PVE::QemuConfig->load_config($vmid, $node); # VM exists ?
2039
2040         # Note: VNC ports are acessible from outside, so we do not gain any
2041         # security if we verify that $param->{port} belongs to VM $vmid. This
2042         # check is done by verifying the VNC ticket (inside VNC protocol).
2043
2044         my $port = $param->{port};
2045
2046         return { port => $port };
2047     }});
2048
2049 __PACKAGE__->register_method({
2050     name => 'spiceproxy',
2051     path => '{vmid}/spiceproxy',
2052     method => 'POST',
2053     protected => 1,
2054     proxyto => 'node',
2055     permissions => {
2056         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
2057     },
2058     description => "Returns a SPICE configuration to connect to the VM.",
2059     parameters => {
2060         additionalProperties => 0,
2061         properties => {
2062             node => get_standard_option('pve-node'),
2063             vmid => get_standard_option('pve-vmid'),
2064             proxy => get_standard_option('spice-proxy', { optional => 1 }),
2065         },
2066     },
2067     returns => get_standard_option('remote-viewer-config'),
2068     code => sub {
2069         my ($param) = @_;
2070
2071         my $rpcenv = PVE::RPCEnvironment::get();
2072
2073         my $authuser = $rpcenv->get_user();
2074
2075         my $vmid = $param->{vmid};
2076         my $node = $param->{node};
2077         my $proxy = $param->{proxy};
2078
2079         my $conf = PVE::QemuConfig->load_config($vmid, $node);
2080         my $title = "VM $vmid";
2081         $title .= " - ". $conf->{name} if $conf->{name};
2082
2083         my $port = PVE::QemuServer::spice_port($vmid);
2084
2085         my ($ticket, undef, $remote_viewer_config) =
2086             PVE::AccessControl::remote_viewer_config($authuser, $vmid, $node, $proxy, $title, $port);
2087
2088         mon_cmd($vmid, "set_password", protocol => 'spice', password => $ticket);
2089         mon_cmd($vmid, "expire_password", protocol => 'spice', time => "+30");
2090
2091         return $remote_viewer_config;
2092     }});
2093
2094 __PACKAGE__->register_method({
2095     name => 'vmcmdidx',
2096     path => '{vmid}/status',
2097     method => 'GET',
2098     proxyto => 'node',
2099     description => "Directory index",
2100     permissions => {
2101         user => 'all',
2102     },
2103     parameters => {
2104         additionalProperties => 0,
2105         properties => {
2106             node => get_standard_option('pve-node'),
2107             vmid => get_standard_option('pve-vmid'),
2108         },
2109     },
2110     returns => {
2111         type => 'array',
2112         items => {
2113             type => "object",
2114             properties => {
2115                 subdir => { type => 'string' },
2116             },
2117         },
2118         links => [ { rel => 'child', href => "{subdir}" } ],
2119     },
2120     code => sub {
2121         my ($param) = @_;
2122
2123         # test if VM exists
2124         my $conf = PVE::QemuConfig->load_config($param->{vmid});
2125
2126         my $res = [
2127             { subdir => 'current' },
2128             { subdir => 'start' },
2129             { subdir => 'stop' },
2130             { subdir => 'reset' },
2131             { subdir => 'shutdown' },
2132             { subdir => 'suspend' },
2133             { subdir => 'reboot' },
2134             ];
2135
2136         return $res;
2137     }});
2138
2139 __PACKAGE__->register_method({
2140     name => 'vm_status',
2141     path => '{vmid}/status/current',
2142     method => 'GET',
2143     proxyto => 'node',
2144     protected => 1, # qemu pid files are only readable by root
2145     description => "Get virtual machine status.",
2146     permissions => {
2147         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
2148     },
2149     parameters => {
2150         additionalProperties => 0,
2151         properties => {
2152             node => get_standard_option('pve-node'),
2153             vmid => get_standard_option('pve-vmid'),
2154         },
2155     },
2156     returns => {
2157         type => 'object',
2158         properties => {
2159             %$PVE::QemuServer::vmstatus_return_properties,
2160             ha => {
2161                 description => "HA manager service status.",
2162                 type => 'object',
2163             },
2164             spice => {
2165                 description => "Qemu VGA configuration supports spice.",
2166                 type => 'boolean',
2167                 optional => 1,
2168             },
2169             agent => {
2170                 description => "Qemu GuestAgent enabled in config.",
2171                 type => 'boolean',
2172                 optional => 1,
2173             },
2174         },
2175     },
2176     code => sub {
2177         my ($param) = @_;
2178
2179         # test if VM exists
2180         my $conf = PVE::QemuConfig->load_config($param->{vmid});
2181
2182         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid}, 1);
2183         my $status = $vmstatus->{$param->{vmid}};
2184
2185         $status->{ha} = PVE::HA::Config::get_service_status("vm:$param->{vmid}");
2186
2187         $status->{spice} = 1 if PVE::QemuServer::vga_conf_has_spice($conf->{vga});
2188         $status->{agent} = 1 if PVE::QemuServer::get_qga_key($conf, 'enabled');
2189
2190         return $status;
2191     }});
2192
2193 __PACKAGE__->register_method({
2194     name => 'vm_start',
2195     path => '{vmid}/status/start',
2196     method => 'POST',
2197     protected => 1,
2198     proxyto => 'node',
2199     description => "Start virtual machine.",
2200     permissions => {
2201         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2202     },
2203     parameters => {
2204         additionalProperties => 0,
2205         properties => {
2206             node => get_standard_option('pve-node'),
2207             vmid => get_standard_option('pve-vmid',
2208                                         { completion => \&PVE::QemuServer::complete_vmid_stopped }),
2209             skiplock => get_standard_option('skiplock'),
2210             stateuri => get_standard_option('pve-qm-stateuri'),
2211             migratedfrom => get_standard_option('pve-node',{ optional => 1 }),
2212             migration_type => {
2213                 type => 'string',
2214                 enum => ['secure', 'insecure'],
2215                 description => "Migration traffic is encrypted using an SSH " .
2216                   "tunnel by default. On secure, completely private networks " .
2217                   "this can be disabled to increase performance.",
2218                 optional => 1,
2219             },
2220             migration_network => {
2221                 type => 'string', format => 'CIDR',
2222                 description => "CIDR of the (sub) network that is used for migration.",
2223                 optional => 1,
2224             },
2225             machine => get_standard_option('pve-qemu-machine'),
2226             'force-cpu' => {
2227                 description => "Override QEMU's -cpu argument with the given string.",
2228                 type => 'string',
2229                 optional => 1,
2230             },
2231             targetstorage => get_standard_option('pve-targetstorage'),
2232             timeout => {
2233                 description => "Wait maximal timeout seconds.",
2234                 type => 'integer',
2235                 minimum => 0,
2236                 default => 'max(30, vm memory in GiB)',
2237                 optional => 1,
2238             },
2239         },
2240     },
2241     returns => {
2242         type => 'string',
2243     },
2244     code => sub {
2245         my ($param) = @_;
2246
2247         my $rpcenv = PVE::RPCEnvironment::get();
2248         my $authuser = $rpcenv->get_user();
2249
2250         my $node = extract_param($param, 'node');
2251         my $vmid = extract_param($param, 'vmid');
2252         my $timeout = extract_param($param, 'timeout');
2253
2254         my $machine = extract_param($param, 'machine');
2255         my $force_cpu = extract_param($param, 'force-cpu');
2256
2257         my $get_root_param = sub {
2258             my $value = extract_param($param, $_[0]);
2259             raise_param_exc({ "$_[0]" => "Only root may use this option." })
2260                 if $value && $authuser ne 'root@pam';
2261             return $value;
2262         };
2263
2264         my $stateuri = $get_root_param->('stateuri');
2265         my $skiplock = $get_root_param->('skiplock');
2266         my $migratedfrom = $get_root_param->('migratedfrom');
2267         my $migration_type = $get_root_param->('migration_type');
2268         my $migration_network = $get_root_param->('migration_network');
2269         my $targetstorage = $get_root_param->('targetstorage');
2270
2271         my $storagemap;
2272
2273         if ($targetstorage) {
2274             raise_param_exc({ targetstorage => "targetstorage can only by used with migratedfrom." })
2275                 if !$migratedfrom;
2276             $storagemap = eval { PVE::JSONSchema::parse_idmap($targetstorage, 'pve-storage-id') };
2277             raise_param_exc({ targetstorage => "failed to parse storage map: $@" })
2278                 if $@;
2279         }
2280
2281         # read spice ticket from STDIN
2282         my $spice_ticket;
2283         my $nbd_protocol_version = 0;
2284         my $replicated_volumes = {};
2285         if ($stateuri && ($stateuri eq 'tcp' || $stateuri eq 'unix') && $migratedfrom && ($rpcenv->{type} eq 'cli')) {
2286             while (defined(my $line = <STDIN>)) {
2287                 chomp $line;
2288                 if ($line =~ m/^spice_ticket: (.+)$/) {
2289                     $spice_ticket = $1;
2290                 } elsif ($line =~ m/^nbd_protocol_version: (\d+)$/) {
2291                     $nbd_protocol_version = $1;
2292                 } elsif ($line =~ m/^replicated_volume: (.*)$/) {
2293                     $replicated_volumes->{$1} = 1;
2294                 } else {
2295                     # fallback for old source node
2296                     $spice_ticket = $line;
2297                 }
2298             }
2299         }
2300
2301         PVE::Cluster::check_cfs_quorum();
2302
2303         my $storecfg = PVE::Storage::config();
2304
2305         if (PVE::HA::Config::vm_is_ha_managed($vmid) && !$stateuri &&  $rpcenv->{type} ne 'ha') {
2306             my $hacmd = sub {
2307                 my $upid = shift;
2308
2309                 print "Requesting HA start for VM $vmid\n";
2310
2311                 my $cmd = ['ha-manager', 'set',  "vm:$vmid", '--state', 'started'];
2312                 PVE::Tools::run_command($cmd);
2313                 return;
2314             };
2315
2316             return $rpcenv->fork_worker('hastart', $vmid, $authuser, $hacmd);
2317
2318         } else {
2319
2320             my $realcmd = sub {
2321                 my $upid = shift;
2322
2323                 syslog('info', "start VM $vmid: $upid\n");
2324
2325                 my $migrate_opts = {
2326                     migratedfrom => $migratedfrom,
2327                     spice_ticket => $spice_ticket,
2328                     network => $migration_network,
2329                     type => $migration_type,
2330                     storagemap => $storagemap,
2331                     nbd_proto_version => $nbd_protocol_version,
2332                     replicated_volumes => $replicated_volumes,
2333                 };
2334
2335                 my $params = {
2336                     statefile => $stateuri,
2337                     skiplock => $skiplock,
2338                     forcemachine => $machine,
2339                     timeout => $timeout,
2340                     forcecpu => $force_cpu,
2341                 };
2342
2343                 PVE::QemuServer::vm_start($storecfg, $vmid, $params, $migrate_opts);
2344                 return;
2345             };
2346
2347             return $rpcenv->fork_worker('qmstart', $vmid, $authuser, $realcmd);
2348         }
2349     }});
2350
2351 __PACKAGE__->register_method({
2352     name => 'vm_stop',
2353     path => '{vmid}/status/stop',
2354     method => 'POST',
2355     protected => 1,
2356     proxyto => 'node',
2357     description => "Stop virtual machine. The qemu process will exit immediately. This" .
2358         "is akin to pulling the power plug of a running computer and may damage the VM data",
2359     permissions => {
2360         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2361     },
2362     parameters => {
2363         additionalProperties => 0,
2364         properties => {
2365             node => get_standard_option('pve-node'),
2366             vmid => get_standard_option('pve-vmid',
2367                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2368             skiplock => get_standard_option('skiplock'),
2369             migratedfrom => get_standard_option('pve-node', { optional => 1 }),
2370             timeout => {
2371                 description => "Wait maximal timeout seconds.",
2372                 type => 'integer',
2373                 minimum => 0,
2374                 optional => 1,
2375             },
2376             keepActive => {
2377                 description => "Do not deactivate storage volumes.",
2378                 type => 'boolean',
2379                 optional => 1,
2380                 default => 0,
2381             }
2382         },
2383     },
2384     returns => {
2385         type => 'string',
2386     },
2387     code => sub {
2388         my ($param) = @_;
2389
2390         my $rpcenv = PVE::RPCEnvironment::get();
2391         my $authuser = $rpcenv->get_user();
2392
2393         my $node = extract_param($param, 'node');
2394         my $vmid = extract_param($param, 'vmid');
2395
2396         my $skiplock = extract_param($param, 'skiplock');
2397         raise_param_exc({ skiplock => "Only root may use this option." })
2398             if $skiplock && $authuser ne 'root@pam';
2399
2400         my $keepActive = extract_param($param, 'keepActive');
2401         raise_param_exc({ keepActive => "Only root may use this option." })
2402             if $keepActive && $authuser ne 'root@pam';
2403
2404         my $migratedfrom = extract_param($param, 'migratedfrom');
2405         raise_param_exc({ migratedfrom => "Only root may use this option." })
2406             if $migratedfrom && $authuser ne 'root@pam';
2407
2408
2409         my $storecfg = PVE::Storage::config();
2410
2411         if (PVE::HA::Config::vm_is_ha_managed($vmid) && ($rpcenv->{type} ne 'ha') && !defined($migratedfrom)) {
2412
2413             my $hacmd = sub {
2414                 my $upid = shift;
2415
2416                 print "Requesting HA stop for VM $vmid\n";
2417
2418                 my $cmd = ['ha-manager', 'crm-command', 'stop',  "vm:$vmid", '0'];
2419                 PVE::Tools::run_command($cmd);
2420                 return;
2421             };
2422
2423             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2424
2425         } else {
2426             my $realcmd = sub {
2427                 my $upid = shift;
2428
2429                 syslog('info', "stop VM $vmid: $upid\n");
2430
2431                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0,
2432                                          $param->{timeout}, 0, 1, $keepActive, $migratedfrom);
2433                 return;
2434             };
2435
2436             return $rpcenv->fork_worker('qmstop', $vmid, $authuser, $realcmd);
2437         }
2438     }});
2439
2440 __PACKAGE__->register_method({
2441     name => 'vm_reset',
2442     path => '{vmid}/status/reset',
2443     method => 'POST',
2444     protected => 1,
2445     proxyto => 'node',
2446     description => "Reset virtual machine.",
2447     permissions => {
2448         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2449     },
2450     parameters => {
2451         additionalProperties => 0,
2452         properties => {
2453             node => get_standard_option('pve-node'),
2454             vmid => get_standard_option('pve-vmid',
2455                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2456             skiplock => get_standard_option('skiplock'),
2457         },
2458     },
2459     returns => {
2460         type => 'string',
2461     },
2462     code => sub {
2463         my ($param) = @_;
2464
2465         my $rpcenv = PVE::RPCEnvironment::get();
2466
2467         my $authuser = $rpcenv->get_user();
2468
2469         my $node = extract_param($param, 'node');
2470
2471         my $vmid = extract_param($param, 'vmid');
2472
2473         my $skiplock = extract_param($param, 'skiplock');
2474         raise_param_exc({ skiplock => "Only root may use this option." })
2475             if $skiplock && $authuser ne 'root@pam';
2476
2477         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2478
2479         my $realcmd = sub {
2480             my $upid = shift;
2481
2482             PVE::QemuServer::vm_reset($vmid, $skiplock);
2483
2484             return;
2485         };
2486
2487         return $rpcenv->fork_worker('qmreset', $vmid, $authuser, $realcmd);
2488     }});
2489
2490 __PACKAGE__->register_method({
2491     name => 'vm_shutdown',
2492     path => '{vmid}/status/shutdown',
2493     method => 'POST',
2494     protected => 1,
2495     proxyto => 'node',
2496     description => "Shutdown virtual machine. This is similar to pressing the power button on a physical machine." .
2497         "This will send an ACPI event for the guest OS, which should then proceed to a clean shutdown.",
2498     permissions => {
2499         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2500     },
2501     parameters => {
2502         additionalProperties => 0,
2503         properties => {
2504             node => get_standard_option('pve-node'),
2505             vmid => get_standard_option('pve-vmid',
2506                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2507             skiplock => get_standard_option('skiplock'),
2508             timeout => {
2509                 description => "Wait maximal timeout seconds.",
2510                 type => 'integer',
2511                 minimum => 0,
2512                 optional => 1,
2513             },
2514             forceStop => {
2515                 description => "Make sure the VM stops.",
2516                 type => 'boolean',
2517                 optional => 1,
2518                 default => 0,
2519             },
2520             keepActive => {
2521                 description => "Do not deactivate storage volumes.",
2522                 type => 'boolean',
2523                 optional => 1,
2524                 default => 0,
2525             }
2526         },
2527     },
2528     returns => {
2529         type => 'string',
2530     },
2531     code => sub {
2532         my ($param) = @_;
2533
2534         my $rpcenv = PVE::RPCEnvironment::get();
2535         my $authuser = $rpcenv->get_user();
2536
2537         my $node = extract_param($param, 'node');
2538         my $vmid = extract_param($param, 'vmid');
2539
2540         my $skiplock = extract_param($param, 'skiplock');
2541         raise_param_exc({ skiplock => "Only root may use this option." })
2542             if $skiplock && $authuser ne 'root@pam';
2543
2544         my $keepActive = extract_param($param, 'keepActive');
2545         raise_param_exc({ keepActive => "Only root may use this option." })
2546             if $keepActive && $authuser ne 'root@pam';
2547
2548         my $storecfg = PVE::Storage::config();
2549
2550         my $shutdown = 1;
2551
2552         # if vm is paused, do not shutdown (but stop if forceStop = 1)
2553         # otherwise, we will infer a shutdown command, but run into the timeout,
2554         # then when the vm is resumed, it will instantly shutdown
2555         #
2556         # checking the qmp status here to get feedback to the gui/cli/api
2557         # and the status query should not take too long
2558         if (PVE::QemuServer::vm_is_paused($vmid)) {
2559             if ($param->{forceStop}) {
2560                 warn "VM is paused - stop instead of shutdown\n";
2561                 $shutdown = 0;
2562             } else {
2563                 die "VM is paused - cannot shutdown\n";
2564             }
2565         }
2566
2567         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
2568
2569             my $timeout = $param->{timeout} // 60;
2570             my $hacmd = sub {
2571                 my $upid = shift;
2572
2573                 print "Requesting HA stop for VM $vmid\n";
2574
2575                 my $cmd = ['ha-manager', 'crm-command', 'stop', "vm:$vmid", "$timeout"];
2576                 PVE::Tools::run_command($cmd);
2577                 return;
2578             };
2579
2580             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2581
2582         } else {
2583
2584             my $realcmd = sub {
2585                 my $upid = shift;
2586
2587                 syslog('info', "shutdown VM $vmid: $upid\n");
2588
2589                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0, $param->{timeout},
2590                                          $shutdown, $param->{forceStop}, $keepActive);
2591                 return;
2592             };
2593
2594             return $rpcenv->fork_worker('qmshutdown', $vmid, $authuser, $realcmd);
2595         }
2596     }});
2597
2598 __PACKAGE__->register_method({
2599     name => 'vm_reboot',
2600     path => '{vmid}/status/reboot',
2601     method => 'POST',
2602     protected => 1,
2603     proxyto => 'node',
2604     description => "Reboot the VM by shutting it down, and starting it again. Applies pending changes.",
2605     permissions => {
2606         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2607     },
2608     parameters => {
2609         additionalProperties => 0,
2610         properties => {
2611             node => get_standard_option('pve-node'),
2612             vmid => get_standard_option('pve-vmid',
2613                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2614             timeout => {
2615                 description => "Wait maximal timeout seconds for the shutdown.",
2616                 type => 'integer',
2617                 minimum => 0,
2618                 optional => 1,
2619             },
2620         },
2621     },
2622     returns => {
2623         type => 'string',
2624     },
2625     code => sub {
2626         my ($param) = @_;
2627
2628         my $rpcenv = PVE::RPCEnvironment::get();
2629         my $authuser = $rpcenv->get_user();
2630
2631         my $node = extract_param($param, 'node');
2632         my $vmid = extract_param($param, 'vmid');
2633
2634         die "VM is paused - cannot shutdown\n" if PVE::QemuServer::vm_is_paused($vmid);
2635
2636         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2637
2638         my $realcmd = sub {
2639             my $upid = shift;
2640
2641             syslog('info', "requesting reboot of VM $vmid: $upid\n");
2642             PVE::QemuServer::vm_reboot($vmid, $param->{timeout});
2643             return;
2644         };
2645
2646         return $rpcenv->fork_worker('qmreboot', $vmid, $authuser, $realcmd);
2647     }});
2648
2649 __PACKAGE__->register_method({
2650     name => 'vm_suspend',
2651     path => '{vmid}/status/suspend',
2652     method => 'POST',
2653     protected => 1,
2654     proxyto => 'node',
2655     description => "Suspend virtual machine.",
2656     permissions => {
2657         description => "You need 'VM.PowerMgmt' on /vms/{vmid}, and if you have set 'todisk',".
2658             " you need also 'VM.Config.Disk' on /vms/{vmid} and 'Datastore.AllocateSpace'".
2659             " on the storage for the vmstate.",
2660         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2661     },
2662     parameters => {
2663         additionalProperties => 0,
2664         properties => {
2665             node => get_standard_option('pve-node'),
2666             vmid => get_standard_option('pve-vmid',
2667                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2668             skiplock => get_standard_option('skiplock'),
2669             todisk => {
2670                 type => 'boolean',
2671                 default => 0,
2672                 optional => 1,
2673                 description => 'If set, suspends the VM to disk. Will be resumed on next VM start.',
2674             },
2675             statestorage => get_standard_option('pve-storage-id', {
2676                 description => "The storage for the VM state",
2677                 requires => 'todisk',
2678                 optional => 1,
2679                 completion => \&PVE::Storage::complete_storage_enabled,
2680             }),
2681         },
2682     },
2683     returns => {
2684         type => 'string',
2685     },
2686     code => sub {
2687         my ($param) = @_;
2688
2689         my $rpcenv = PVE::RPCEnvironment::get();
2690         my $authuser = $rpcenv->get_user();
2691
2692         my $node = extract_param($param, 'node');
2693         my $vmid = extract_param($param, 'vmid');
2694
2695         my $todisk = extract_param($param, 'todisk') // 0;
2696
2697         my $statestorage = extract_param($param, 'statestorage');
2698
2699         my $skiplock = extract_param($param, 'skiplock');
2700         raise_param_exc({ skiplock => "Only root may use this option." })
2701             if $skiplock && $authuser ne 'root@pam';
2702
2703         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2704
2705         die "Cannot suspend HA managed VM to disk\n"
2706             if $todisk && PVE::HA::Config::vm_is_ha_managed($vmid);
2707
2708         # early check for storage permission, for better user feedback
2709         if ($todisk) {
2710             $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
2711
2712             if (!$statestorage) {
2713                 # get statestorage from config if none is given
2714                 my $conf = PVE::QemuConfig->load_config($vmid);
2715                 my $storecfg = PVE::Storage::config();
2716                 $statestorage = PVE::QemuServer::find_vmstate_storage($conf, $storecfg);
2717             }
2718
2719             $rpcenv->check($authuser, "/storage/$statestorage", ['Datastore.AllocateSpace']);
2720         }
2721
2722         my $realcmd = sub {
2723             my $upid = shift;
2724
2725             syslog('info', "suspend VM $vmid: $upid\n");
2726
2727             PVE::QemuServer::vm_suspend($vmid, $skiplock, $todisk, $statestorage);
2728
2729             return;
2730         };
2731
2732         my $taskname = $todisk ? 'qmsuspend' : 'qmpause';
2733         return $rpcenv->fork_worker($taskname, $vmid, $authuser, $realcmd);
2734     }});
2735
2736 __PACKAGE__->register_method({
2737     name => 'vm_resume',
2738     path => '{vmid}/status/resume',
2739     method => 'POST',
2740     protected => 1,
2741     proxyto => 'node',
2742     description => "Resume virtual machine.",
2743     permissions => {
2744         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2745     },
2746     parameters => {
2747         additionalProperties => 0,
2748         properties => {
2749             node => get_standard_option('pve-node'),
2750             vmid => get_standard_option('pve-vmid',
2751                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2752             skiplock => get_standard_option('skiplock'),
2753             nocheck => { type => 'boolean', optional => 1 },
2754
2755         },
2756     },
2757     returns => {
2758         type => 'string',
2759     },
2760     code => sub {
2761         my ($param) = @_;
2762
2763         my $rpcenv = PVE::RPCEnvironment::get();
2764
2765         my $authuser = $rpcenv->get_user();
2766
2767         my $node = extract_param($param, 'node');
2768
2769         my $vmid = extract_param($param, 'vmid');
2770
2771         my $skiplock = extract_param($param, 'skiplock');
2772         raise_param_exc({ skiplock => "Only root may use this option." })
2773             if $skiplock && $authuser ne 'root@pam';
2774
2775         my $nocheck = extract_param($param, 'nocheck');
2776         raise_param_exc({ nocheck => "Only root may use this option." })
2777             if $nocheck && $authuser ne 'root@pam';
2778
2779         my $to_disk_suspended;
2780         eval {
2781             PVE::QemuConfig->lock_config($vmid, sub {
2782                 my $conf = PVE::QemuConfig->load_config($vmid);
2783                 $to_disk_suspended = PVE::QemuConfig->has_lock($conf, 'suspended');
2784             });
2785         };
2786
2787         die "VM $vmid not running\n"
2788             if !$to_disk_suspended && !PVE::QemuServer::check_running($vmid, $nocheck);
2789
2790         my $realcmd = sub {
2791             my $upid = shift;
2792
2793             syslog('info', "resume VM $vmid: $upid\n");
2794
2795             if (!$to_disk_suspended) {
2796                 PVE::QemuServer::vm_resume($vmid, $skiplock, $nocheck);
2797             } else {
2798                 my $storecfg = PVE::Storage::config();
2799                 PVE::QemuServer::vm_start($storecfg, $vmid, { skiplock => $skiplock });
2800             }
2801
2802             return;
2803         };
2804
2805         return $rpcenv->fork_worker('qmresume', $vmid, $authuser, $realcmd);
2806     }});
2807
2808 __PACKAGE__->register_method({
2809     name => 'vm_sendkey',
2810     path => '{vmid}/sendkey',
2811     method => 'PUT',
2812     protected => 1,
2813     proxyto => 'node',
2814     description => "Send key event to virtual machine.",
2815     permissions => {
2816         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
2817     },
2818     parameters => {
2819         additionalProperties => 0,
2820         properties => {
2821             node => get_standard_option('pve-node'),
2822             vmid => get_standard_option('pve-vmid',
2823                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2824             skiplock => get_standard_option('skiplock'),
2825             key => {
2826                 description => "The key (qemu monitor encoding).",
2827                 type => 'string'
2828             }
2829         },
2830     },
2831     returns => { type => 'null'},
2832     code => sub {
2833         my ($param) = @_;
2834
2835         my $rpcenv = PVE::RPCEnvironment::get();
2836
2837         my $authuser = $rpcenv->get_user();
2838
2839         my $node = extract_param($param, 'node');
2840
2841         my $vmid = extract_param($param, 'vmid');
2842
2843         my $skiplock = extract_param($param, 'skiplock');
2844         raise_param_exc({ skiplock => "Only root may use this option." })
2845             if $skiplock && $authuser ne 'root@pam';
2846
2847         PVE::QemuServer::vm_sendkey($vmid, $skiplock, $param->{key});
2848
2849         return;
2850     }});
2851
2852 __PACKAGE__->register_method({
2853     name => 'vm_feature',
2854     path => '{vmid}/feature',
2855     method => 'GET',
2856     proxyto => 'node',
2857     protected => 1,
2858     description => "Check if feature for virtual machine is available.",
2859     permissions => {
2860         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
2861     },
2862     parameters => {
2863         additionalProperties => 0,
2864         properties => {
2865             node => get_standard_option('pve-node'),
2866             vmid => get_standard_option('pve-vmid'),
2867             feature => {
2868                 description => "Feature to check.",
2869                 type => 'string',
2870                 enum => [ 'snapshot', 'clone', 'copy' ],
2871             },
2872             snapname => get_standard_option('pve-snapshot-name', {
2873                 optional => 1,
2874             }),
2875         },
2876     },
2877     returns => {
2878         type => "object",
2879         properties => {
2880             hasFeature => { type => 'boolean' },
2881             nodes => {
2882                 type => 'array',
2883                 items => { type => 'string' },
2884             }
2885         },
2886     },
2887     code => sub {
2888         my ($param) = @_;
2889
2890         my $node = extract_param($param, 'node');
2891
2892         my $vmid = extract_param($param, 'vmid');
2893
2894         my $snapname = extract_param($param, 'snapname');
2895
2896         my $feature = extract_param($param, 'feature');
2897
2898         my $running = PVE::QemuServer::check_running($vmid);
2899
2900         my $conf = PVE::QemuConfig->load_config($vmid);
2901
2902         if($snapname){
2903             my $snap = $conf->{snapshots}->{$snapname};
2904             die "snapshot '$snapname' does not exist\n" if !defined($snap);
2905             $conf = $snap;
2906         }
2907         my $storecfg = PVE::Storage::config();
2908
2909         my $nodelist = PVE::QemuServer::shared_nodes($conf, $storecfg);
2910         my $hasFeature = PVE::QemuConfig->has_feature($feature, $conf, $storecfg, $snapname, $running);
2911
2912         return {
2913             hasFeature => $hasFeature,
2914             nodes => [ keys %$nodelist ],
2915         };
2916     }});
2917
2918 __PACKAGE__->register_method({
2919     name => 'clone_vm',
2920     path => '{vmid}/clone',
2921     method => 'POST',
2922     protected => 1,
2923     proxyto => 'node',
2924     description => "Create a copy of virtual machine/template.",
2925     permissions => {
2926         description => "You need 'VM.Clone' permissions on /vms/{vmid}, and 'VM.Allocate' permissions " .
2927             "on /vms/{newid} (or on the VM pool /pool/{pool}). You also need " .
2928             "'Datastore.AllocateSpace' on any used storage.",
2929         check =>
2930         [ 'and',
2931           ['perm', '/vms/{vmid}', [ 'VM.Clone' ]],
2932           [ 'or',
2933             [ 'perm', '/vms/{newid}', ['VM.Allocate']],
2934             [ 'perm', '/pool/{pool}', ['VM.Allocate'], require_param => 'pool'],
2935           ],
2936         ]
2937     },
2938     parameters => {
2939         additionalProperties => 0,
2940         properties => {
2941             node => get_standard_option('pve-node'),
2942             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
2943             newid => get_standard_option('pve-vmid', {
2944                 completion => \&PVE::Cluster::complete_next_vmid,
2945                 description => 'VMID for the clone.' }),
2946             name => {
2947                 optional => 1,
2948                 type => 'string', format => 'dns-name',
2949                 description => "Set a name for the new VM.",
2950             },
2951             description => {
2952                 optional => 1,
2953                 type => 'string',
2954                 description => "Description for the new VM.",
2955             },
2956             pool => {
2957                 optional => 1,
2958                 type => 'string', format => 'pve-poolid',
2959                 description => "Add the new VM to the specified pool.",
2960             },
2961             snapname => get_standard_option('pve-snapshot-name', {
2962                 optional => 1,
2963             }),
2964             storage => get_standard_option('pve-storage-id', {
2965                 description => "Target storage for full clone.",
2966                 optional => 1,
2967             }),
2968             'format' => {
2969                 description => "Target format for file storage. Only valid for full clone.",
2970                 type => 'string',
2971                 optional => 1,
2972                 enum => [ 'raw', 'qcow2', 'vmdk'],
2973             },
2974             full => {
2975                 optional => 1,
2976                 type => 'boolean',
2977                 description => "Create a full copy of all disks. This is always done when " .
2978                     "you clone a normal VM. For VM templates, we try to create a linked clone by default.",
2979             },
2980             target => get_standard_option('pve-node', {
2981                 description => "Target node. Only allowed if the original VM is on shared storage.",
2982                 optional => 1,
2983             }),
2984             bwlimit => {
2985                 description => "Override I/O bandwidth limit (in KiB/s).",
2986                 optional => 1,
2987                 type => 'integer',
2988                 minimum => '0',
2989                 default => 'clone limit from datacenter or storage config',
2990             },
2991         },
2992     },
2993     returns => {
2994         type => 'string',
2995     },
2996     code => sub {
2997         my ($param) = @_;
2998
2999         my $rpcenv = PVE::RPCEnvironment::get();
3000         my $authuser = $rpcenv->get_user();
3001
3002         my $node = extract_param($param, 'node');
3003         my $vmid = extract_param($param, 'vmid');
3004         my $newid = extract_param($param, 'newid');
3005         my $pool = extract_param($param, 'pool');
3006         $rpcenv->check_pool_exist($pool) if defined($pool);
3007
3008         my $snapname = extract_param($param, 'snapname');
3009         my $storage = extract_param($param, 'storage');
3010         my $format = extract_param($param, 'format');
3011         my $target = extract_param($param, 'target');
3012
3013         my $localnode = PVE::INotify::nodename();
3014
3015         if ($target && ($target eq $localnode || $target eq 'localhost')) {
3016             undef $target;
3017         }
3018
3019         PVE::Cluster::check_node_exists($target) if $target;
3020
3021         my $storecfg = PVE::Storage::config();
3022
3023         if ($storage) {
3024             # check if storage is enabled on local node
3025             PVE::Storage::storage_check_enabled($storecfg, $storage);
3026             if ($target) {
3027                 # check if storage is available on target node
3028                 PVE::Storage::storage_check_node($storecfg, $storage, $target);
3029                 # clone only works if target storage is shared
3030                 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
3031                 die "can't clone to non-shared storage '$storage'\n" if !$scfg->{shared};
3032             }
3033         }
3034
3035         PVE::Cluster::check_cfs_quorum();
3036
3037         my $running = PVE::QemuServer::check_running($vmid) || 0;
3038
3039         my $clonefn = sub {
3040             # do all tests after lock but before forking worker - if possible
3041
3042             my $conf = PVE::QemuConfig->load_config($vmid);
3043             PVE::QemuConfig->check_lock($conf);
3044
3045             my $verify_running = PVE::QemuServer::check_running($vmid) || 0;
3046             die "unexpected state change\n" if $verify_running != $running;
3047
3048             die "snapshot '$snapname' does not exist\n"
3049                 if $snapname && !defined( $conf->{snapshots}->{$snapname});
3050
3051             my $full = extract_param($param, 'full') // !PVE::QemuConfig->is_template($conf);
3052
3053             die "parameter 'storage' not allowed for linked clones\n"
3054                 if defined($storage) && !$full;
3055
3056             die "parameter 'format' not allowed for linked clones\n"
3057                 if defined($format) && !$full;
3058
3059             my $oldconf = $snapname ? $conf->{snapshots}->{$snapname} : $conf;
3060
3061             my $sharedvm = &$check_storage_access_clone($rpcenv, $authuser, $storecfg, $oldconf, $storage);
3062
3063             die "can't clone VM to node '$target' (VM uses local storage)\n"
3064                 if $target && !$sharedvm;
3065
3066             my $conffile = PVE::QemuConfig->config_file($newid);
3067             die "unable to create VM $newid: config file already exists\n"
3068                 if -f $conffile;
3069
3070             my $newconf = { lock => 'clone' };
3071             my $drives = {};
3072             my $fullclone = {};
3073             my $vollist = [];
3074
3075             foreach my $opt (keys %$oldconf) {
3076                 my $value = $oldconf->{$opt};
3077
3078                 # do not copy snapshot related info
3079                 next if $opt eq 'snapshots' ||  $opt eq 'parent' || $opt eq 'snaptime' ||
3080                     $opt eq 'vmstate' || $opt eq 'snapstate';
3081
3082                 # no need to copy unused images, because VMID(owner) changes anyways
3083                 next if $opt =~ m/^unused\d+$/;
3084
3085                 # always change MAC! address
3086                 if ($opt =~ m/^net(\d+)$/) {
3087                     my $net = PVE::QemuServer::parse_net($value);
3088                     my $dc = PVE::Cluster::cfs_read_file('datacenter.cfg');
3089                     $net->{macaddr} =  PVE::Tools::random_ether_addr($dc->{mac_prefix});
3090                     $newconf->{$opt} = PVE::QemuServer::print_net($net);
3091                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
3092                     my $drive = PVE::QemuServer::parse_drive($opt, $value);
3093                     die "unable to parse drive options for '$opt'\n" if !$drive;
3094                     if (PVE::QemuServer::drive_is_cdrom($drive, 1)) {
3095                         $newconf->{$opt} = $value; # simply copy configuration
3096                     } else {
3097                         if ($full || PVE::QemuServer::drive_is_cloudinit($drive)) {
3098                             die "Full clone feature is not supported for drive '$opt'\n"
3099                                 if !PVE::Storage::volume_has_feature($storecfg, 'copy', $drive->{file}, $snapname, $running);
3100                             $fullclone->{$opt} = 1;
3101                         } else {
3102                             # not full means clone instead of copy
3103                             die "Linked clone feature is not supported for drive '$opt'\n"
3104                                 if !PVE::Storage::volume_has_feature($storecfg, 'clone', $drive->{file}, $snapname, $running);
3105                         }
3106                         $drives->{$opt} = $drive;
3107                         next if PVE::QemuServer::drive_is_cloudinit($drive);
3108                         push @$vollist, $drive->{file};
3109                     }
3110                 } else {
3111                     # copy everything else
3112                     $newconf->{$opt} = $value;
3113                 }
3114             }
3115
3116             # auto generate a new uuid
3117             my $smbios1 = PVE::QemuServer::parse_smbios1($newconf->{smbios1} || '');
3118             $smbios1->{uuid} = PVE::QemuServer::generate_uuid();
3119             $newconf->{smbios1} = PVE::QemuServer::print_smbios1($smbios1);
3120             # auto generate a new vmgenid only if the option was set for template
3121             if ($newconf->{vmgenid}) {
3122                 $newconf->{vmgenid} = PVE::QemuServer::generate_uuid();
3123             }
3124
3125             delete $newconf->{template};
3126
3127             if ($param->{name}) {
3128                 $newconf->{name} = $param->{name};
3129             } else {
3130                 $newconf->{name} = "Copy-of-VM-" . ($oldconf->{name} // $vmid);
3131             }
3132
3133             if ($param->{description}) {
3134                 $newconf->{description} = $param->{description};
3135             }
3136
3137             # create empty/temp config - this fails if VM already exists on other node
3138             # FIXME use PVE::QemuConfig->create_and_lock_config and adapt code
3139             PVE::Tools::file_set_contents($conffile, "# qmclone temporary file\nlock: clone\n");
3140
3141             my $realcmd = sub {
3142                 my $upid = shift;
3143
3144                 my $newvollist = [];
3145                 my $jobs = {};
3146
3147                 eval {
3148                     local $SIG{INT} =
3149                         local $SIG{TERM} =
3150                         local $SIG{QUIT} =
3151                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
3152
3153                     PVE::Storage::activate_volumes($storecfg, $vollist, $snapname);
3154
3155                     my $bwlimit = extract_param($param, 'bwlimit');
3156
3157                     my $total_jobs = scalar(keys %{$drives});
3158                     my $i = 1;
3159
3160                     foreach my $opt (keys %$drives) {
3161                         my $drive = $drives->{$opt};
3162                         my $skipcomplete = ($total_jobs != $i); # finish after last drive
3163                         my $completion = $skipcomplete ? 'skip' : 'complete';
3164
3165                         my $src_sid = PVE::Storage::parse_volume_id($drive->{file});
3166                         my $storage_list = [ $src_sid ];
3167                         push @$storage_list, $storage if defined($storage);
3168                         my $clonelimit = PVE::Storage::get_bandwidth_limit('clone', $storage_list, $bwlimit);
3169
3170                         my $newdrive = PVE::QemuServer::clone_disk(
3171                             $storecfg,
3172                             $vmid,
3173                             $running,
3174                             $opt,
3175                             $drive,
3176                             $snapname,
3177                             $newid,
3178                             $storage,
3179                             $format,
3180                             $fullclone->{$opt},
3181                             $newvollist,
3182                             $jobs,
3183                             $completion,
3184                             $oldconf->{agent},
3185                             $clonelimit,
3186                             $oldconf
3187                         );
3188
3189                         $newconf->{$opt} = PVE::QemuServer::print_drive($newdrive);
3190
3191                         PVE::QemuConfig->write_config($newid, $newconf);
3192                         $i++;
3193                     }
3194
3195                     delete $newconf->{lock};
3196
3197                     # do not write pending changes
3198                     if (my @changes = keys %{$newconf->{pending}}) {
3199                         my $pending = join(',', @changes);
3200                         warn "found pending changes for '$pending', discarding for clone\n";
3201                         delete $newconf->{pending};
3202                     }
3203
3204                     PVE::QemuConfig->write_config($newid, $newconf);
3205
3206                     if ($target) {
3207                         # always deactivate volumes - avoid lvm LVs to be active on several nodes
3208                         PVE::Storage::deactivate_volumes($storecfg, $vollist, $snapname) if !$running;
3209                         PVE::Storage::deactivate_volumes($storecfg, $newvollist);
3210
3211                         my $newconffile = PVE::QemuConfig->config_file($newid, $target);
3212                         die "Failed to move config to node '$target' - rename failed: $!\n"
3213                             if !rename($conffile, $newconffile);
3214                     }
3215
3216                     PVE::AccessControl::add_vm_to_pool($newid, $pool) if $pool;
3217                 };
3218                 if (my $err = $@) {
3219                     eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $jobs) };
3220                     sleep 1; # some storage like rbd need to wait before release volume - really?
3221
3222                     foreach my $volid (@$newvollist) {
3223                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
3224                         warn $@ if $@;
3225                     }
3226
3227                     PVE::Firewall::remove_vmfw_conf($newid);
3228
3229                     unlink $conffile; # avoid races -> last thing before die
3230
3231                     die "clone failed: $err";
3232                 }
3233
3234                 return;
3235             };
3236
3237             PVE::Firewall::clone_vmfw_conf($vmid, $newid);
3238
3239             return $rpcenv->fork_worker('qmclone', $vmid, $authuser, $realcmd);
3240         };
3241
3242         # Aquire exclusive lock lock for $newid
3243         my $lock_target_vm = sub {
3244             return PVE::QemuConfig->lock_config_full($newid, 1, $clonefn);
3245         };
3246
3247         # exclusive lock if VM is running - else shared lock is enough;
3248         if ($running) {
3249             return PVE::QemuConfig->lock_config_full($vmid, 1, $lock_target_vm);
3250         } else {
3251             return PVE::QemuConfig->lock_config_shared($vmid, 1, $lock_target_vm);
3252         }
3253     }});
3254
3255 __PACKAGE__->register_method({
3256     name => 'move_vm_disk',
3257     path => '{vmid}/move_disk',
3258     method => 'POST',
3259     protected => 1,
3260     proxyto => 'node',
3261     description => "Move volume to different storage.",
3262     permissions => {
3263         description => "You need 'VM.Config.Disk' permissions on /vms/{vmid}, and 'Datastore.AllocateSpace' permissions on the storage.",
3264         check => [ 'and',
3265                    ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
3266                    ['perm', '/storage/{storage}', [ 'Datastore.AllocateSpace' ]],
3267             ],
3268     },
3269     parameters => {
3270         additionalProperties => 0,
3271         properties => {
3272             node => get_standard_option('pve-node'),
3273             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3274             disk => {
3275                 type => 'string',
3276                 description => "The disk you want to move.",
3277                 enum => [PVE::QemuServer::Drive::valid_drive_names()],
3278             },
3279             storage => get_standard_option('pve-storage-id', {
3280                 description => "Target storage.",
3281                 completion => \&PVE::QemuServer::complete_storage,
3282             }),
3283             'format' => {
3284                 type => 'string',
3285                 description => "Target Format.",
3286                 enum => [ 'raw', 'qcow2', 'vmdk' ],
3287                 optional => 1,
3288             },
3289             delete => {
3290                 type => 'boolean',
3291                 description => "Delete the original disk after successful copy. By default the original disk is kept as unused disk.",
3292                 optional => 1,
3293                 default => 0,
3294             },
3295             digest => {
3296                 type => 'string',
3297                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
3298                 maxLength => 40,
3299                 optional => 1,
3300             },
3301             bwlimit => {
3302                 description => "Override I/O bandwidth limit (in KiB/s).",
3303                 optional => 1,
3304                 type => 'integer',
3305                 minimum => '0',
3306                 default => 'move limit from datacenter or storage config',
3307             },
3308         },
3309     },
3310     returns => {
3311         type => 'string',
3312         description => "the task ID.",
3313     },
3314     code => sub {
3315         my ($param) = @_;
3316
3317         my $rpcenv = PVE::RPCEnvironment::get();
3318         my $authuser = $rpcenv->get_user();
3319
3320         my $node = extract_param($param, 'node');
3321         my $vmid = extract_param($param, 'vmid');
3322         my $digest = extract_param($param, 'digest');
3323         my $disk = extract_param($param, 'disk');
3324         my $storeid = extract_param($param, 'storage');
3325         my $format = extract_param($param, 'format');
3326
3327         my $storecfg = PVE::Storage::config();
3328
3329         my $updatefn =  sub {
3330             my $conf = PVE::QemuConfig->load_config($vmid);
3331             PVE::QemuConfig->check_lock($conf);
3332
3333             die "VM config checksum missmatch (file change by other user?)\n"
3334                 if $digest && $digest ne $conf->{digest};
3335
3336             die "disk '$disk' does not exist\n" if !$conf->{$disk};
3337
3338             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
3339
3340             die "disk '$disk' has no associated volume\n" if !$drive->{file};
3341             die "you can't move a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive, 1);
3342
3343             my $old_volid = $drive->{file};
3344             my $oldfmt;
3345             my ($oldstoreid, $oldvolname) = PVE::Storage::parse_volume_id($old_volid);
3346             if ($oldvolname =~ m/\.(raw|qcow2|vmdk)$/){
3347                 $oldfmt = $1;
3348             }
3349
3350             die "you can't move to the same storage with same format\n" if $oldstoreid eq $storeid &&
3351                 (!$format || !$oldfmt || $oldfmt eq $format);
3352
3353             # this only checks snapshots because $disk is passed!
3354             my $snapshotted = PVE::QemuServer::Drive::is_volume_in_use($storecfg, $conf, $disk, $old_volid);
3355             die "you can't move a disk with snapshots and delete the source\n"
3356                 if $snapshotted && $param->{delete};
3357
3358             PVE::Cluster::log_msg('info', $authuser, "move disk VM $vmid: move --disk $disk --storage $storeid");
3359
3360             my $running = PVE::QemuServer::check_running($vmid);
3361
3362             PVE::Storage::activate_volumes($storecfg, [ $drive->{file} ]);
3363
3364             my $realcmd = sub {
3365                 my $newvollist = [];
3366
3367                 eval {
3368                     local $SIG{INT} =
3369                         local $SIG{TERM} =
3370                         local $SIG{QUIT} =
3371                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
3372
3373                     warn "moving disk with snapshots, snapshots will not be moved!\n"
3374                         if $snapshotted;
3375
3376                     my $bwlimit = extract_param($param, 'bwlimit');
3377                     my $movelimit = PVE::Storage::get_bandwidth_limit('move', [$oldstoreid, $storeid], $bwlimit);
3378
3379                     my $newdrive = PVE::QemuServer::clone_disk(
3380                         $storecfg,
3381                         $vmid,
3382                         $running,
3383                         $disk,
3384                         $drive,
3385                         undef,
3386                         $vmid,
3387                         $storeid,
3388                         $format,
3389                         1,
3390                         $newvollist,
3391                         undef,
3392                         undef,
3393                         undef,
3394                         $movelimit,
3395                         $conf,
3396                     );
3397                     $conf->{$disk} = PVE::QemuServer::print_drive($newdrive);
3398
3399                     PVE::QemuConfig->add_unused_volume($conf, $old_volid) if !$param->{delete};
3400
3401                     # convert moved disk to base if part of template
3402                     PVE::QemuServer::template_create($vmid, $conf, $disk)
3403                         if PVE::QemuConfig->is_template($conf);
3404
3405                     PVE::QemuConfig->write_config($vmid, $conf);
3406
3407                     my $do_trim = PVE::QemuServer::get_qga_key($conf, 'fstrim_cloned_disks');
3408                     if ($running && $do_trim && PVE::QemuServer::qga_check_running($vmid)) {
3409                         eval { mon_cmd($vmid, "guest-fstrim") };
3410                     }
3411
3412                     eval {
3413                         # try to deactivate volumes - avoid lvm LVs to be active on several nodes
3414                         PVE::Storage::deactivate_volumes($storecfg, [ $newdrive->{file} ])
3415                             if !$running;
3416                     };
3417                     warn $@ if $@;
3418                 };
3419                 if (my $err = $@) {
3420                     foreach my $volid (@$newvollist) {
3421                         eval { PVE::Storage::vdisk_free($storecfg, $volid) };
3422                         warn $@ if $@;
3423                     }
3424                     die "storage migration failed: $err";
3425                 }
3426
3427                 if ($param->{delete}) {
3428                     eval {
3429                         PVE::Storage::deactivate_volumes($storecfg, [$old_volid]);
3430                         PVE::Storage::vdisk_free($storecfg, $old_volid);
3431                     };
3432                     warn $@ if $@;
3433                 }
3434             };
3435
3436             return $rpcenv->fork_worker('qmmove', $vmid, $authuser, $realcmd);
3437         };
3438
3439         return PVE::QemuConfig->lock_config($vmid, $updatefn);
3440     }});
3441
3442 my $check_vm_disks_local = sub {
3443     my ($storecfg, $vmconf, $vmid) = @_;
3444
3445     my $local_disks = {};
3446
3447     # add some more information to the disks e.g. cdrom
3448     PVE::QemuServer::foreach_volid($vmconf, sub {
3449         my ($volid, $attr) = @_;
3450
3451         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
3452         if ($storeid) {
3453             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
3454             return if $scfg->{shared};
3455         }
3456         # The shared attr here is just a special case where the vdisk
3457         # is marked as shared manually
3458         return if $attr->{shared};
3459         return if $attr->{cdrom} and $volid eq "none";
3460
3461         if (exists $local_disks->{$volid}) {
3462             @{$local_disks->{$volid}}{keys %$attr} = values %$attr
3463         } else {
3464             $local_disks->{$volid} = $attr;
3465             # ensure volid is present in case it's needed
3466             $local_disks->{$volid}->{volid} = $volid;
3467         }
3468     });
3469
3470     return $local_disks;
3471 };
3472
3473 __PACKAGE__->register_method({
3474     name => 'migrate_vm_precondition',
3475     path => '{vmid}/migrate',
3476     method => 'GET',
3477     protected => 1,
3478     proxyto => 'node',
3479     description => "Get preconditions for migration.",
3480     permissions => {
3481         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
3482     },
3483     parameters => {
3484         additionalProperties => 0,
3485         properties => {
3486             node => get_standard_option('pve-node'),
3487             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3488             target => get_standard_option('pve-node', {
3489                 description => "Target node.",
3490                 completion =>  \&PVE::Cluster::complete_migration_target,
3491                 optional => 1,
3492             }),
3493         },
3494     },
3495     returns => {
3496         type => "object",
3497         properties => {
3498             running => { type => 'boolean' },
3499             allowed_nodes => {
3500                 type => 'array',
3501                 optional => 1,
3502                 description => "List nodes allowed for offline migration, only passed if VM is offline"
3503             },
3504             not_allowed_nodes => {
3505                 type => 'object',
3506                 optional => 1,
3507                 description => "List not allowed nodes with additional informations, only passed if VM is offline"
3508             },
3509             local_disks => {
3510                 type => 'array',
3511                 description => "List local disks including CD-Rom, unsused and not referenced disks"
3512             },
3513             local_resources => {
3514                 type => 'array',
3515                 description => "List local resources e.g. pci, usb"
3516             }
3517         },
3518     },
3519     code => sub {
3520         my ($param) = @_;
3521
3522         my $rpcenv = PVE::RPCEnvironment::get();
3523
3524         my $authuser = $rpcenv->get_user();
3525
3526         PVE::Cluster::check_cfs_quorum();
3527
3528         my $res = {};
3529
3530         my $vmid = extract_param($param, 'vmid');
3531         my $target = extract_param($param, 'target');
3532         my $localnode = PVE::INotify::nodename();
3533
3534
3535         # test if VM exists
3536         my $vmconf = PVE::QemuConfig->load_config($vmid);
3537         my $storecfg = PVE::Storage::config();
3538
3539
3540         # try to detect errors early
3541         PVE::QemuConfig->check_lock($vmconf);
3542
3543         $res->{running} = PVE::QemuServer::check_running($vmid) ? 1:0;
3544
3545         # if vm is not running, return target nodes where local storage is available
3546         # for offline migration
3547         if (!$res->{running}) {
3548             $res->{allowed_nodes} = [];
3549             my $checked_nodes = PVE::QemuServer::check_local_storage_availability($vmconf, $storecfg);
3550             delete $checked_nodes->{$localnode};
3551
3552             foreach my $node (keys %$checked_nodes) {
3553                 if (!defined $checked_nodes->{$node}->{unavailable_storages}) {
3554                     push @{$res->{allowed_nodes}}, $node;
3555                 }
3556
3557             }
3558             $res->{not_allowed_nodes} = $checked_nodes;
3559         }
3560
3561
3562         my $local_disks = &$check_vm_disks_local($storecfg, $vmconf, $vmid);
3563         $res->{local_disks} = [ values %$local_disks ];;
3564
3565         my $local_resources =  PVE::QemuServer::check_local_resources($vmconf, 1);
3566
3567         $res->{local_resources} = $local_resources;
3568
3569         return $res;
3570
3571
3572     }});
3573
3574 __PACKAGE__->register_method({
3575     name => 'migrate_vm',
3576     path => '{vmid}/migrate',
3577     method => 'POST',
3578     protected => 1,
3579     proxyto => 'node',
3580     description => "Migrate virtual machine. Creates a new migration task.",
3581     permissions => {
3582         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
3583     },
3584     parameters => {
3585         additionalProperties => 0,
3586         properties => {
3587             node => get_standard_option('pve-node'),
3588             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3589             target => get_standard_option('pve-node', {
3590                 description => "Target node.",
3591                 completion =>  \&PVE::Cluster::complete_migration_target,
3592             }),
3593             online => {
3594                 type => 'boolean',
3595                 description => "Use online/live migration if VM is running. Ignored if VM is stopped.",
3596                 optional => 1,
3597             },
3598             force => {
3599                 type => 'boolean',
3600                 description => "Allow to migrate VMs which use local devices. Only root may use this option.",
3601                 optional => 1,
3602             },
3603             migration_type => {
3604                 type => 'string',
3605                 enum => ['secure', 'insecure'],
3606                 description => "Migration traffic is encrypted using an SSH tunnel by default. On secure, completely private networks this can be disabled to increase performance.",
3607                 optional => 1,
3608             },
3609             migration_network => {
3610                 type => 'string', format => 'CIDR',
3611                 description => "CIDR of the (sub) network that is used for migration.",
3612                 optional => 1,
3613             },
3614             "with-local-disks" => {
3615                 type => 'boolean',
3616                 description => "Enable live storage migration for local disk",
3617                 optional => 1,
3618             },
3619             targetstorage => get_standard_option('pve-targetstorage', {
3620                 completion => \&PVE::QemuServer::complete_migration_storage,
3621             }),
3622             bwlimit => {
3623                 description => "Override I/O bandwidth limit (in KiB/s).",
3624                 optional => 1,
3625                 type => 'integer',
3626                 minimum => '0',
3627                 default => 'migrate limit from datacenter or storage config',
3628             },
3629         },
3630     },
3631     returns => {
3632         type => 'string',
3633         description => "the task ID.",
3634     },
3635     code => sub {
3636         my ($param) = @_;
3637
3638         my $rpcenv = PVE::RPCEnvironment::get();
3639         my $authuser = $rpcenv->get_user();
3640
3641         my $target = extract_param($param, 'target');
3642
3643         my $localnode = PVE::INotify::nodename();
3644         raise_param_exc({ target => "target is local node."}) if $target eq $localnode;
3645
3646         PVE::Cluster::check_cfs_quorum();
3647
3648         PVE::Cluster::check_node_exists($target);
3649
3650         my $targetip = PVE::Cluster::remote_node_ip($target);
3651
3652         my $vmid = extract_param($param, 'vmid');
3653
3654         raise_param_exc({ force => "Only root may use this option." })
3655             if $param->{force} && $authuser ne 'root@pam';
3656
3657         raise_param_exc({ migration_type => "Only root may use this option." })
3658             if $param->{migration_type} && $authuser ne 'root@pam';
3659
3660         # allow root only until better network permissions are available
3661         raise_param_exc({ migration_network => "Only root may use this option." })
3662             if $param->{migration_network} && $authuser ne 'root@pam';
3663
3664         # test if VM exists
3665         my $conf = PVE::QemuConfig->load_config($vmid);
3666
3667         # try to detect errors early
3668
3669         PVE::QemuConfig->check_lock($conf);
3670
3671         if (PVE::QemuServer::check_running($vmid)) {
3672             die "can't migrate running VM without --online\n" if !$param->{online};
3673
3674             my $repl_conf = PVE::ReplicationConfig->new();
3675             my $is_replicated = $repl_conf->check_for_existing_jobs($vmid, 1);
3676             my $is_replicated_to_target = defined($repl_conf->find_local_replication_job($vmid, $target));
3677             if (!$param->{force} && $is_replicated && !$is_replicated_to_target) {
3678                 die "Cannot live-migrate replicated VM to node '$target' - not a replication " .
3679                     "target. Use 'force' to override.\n";
3680             }
3681         } else {
3682             warn "VM isn't running. Doing offline migration instead.\n" if $param->{online};
3683             $param->{online} = 0;
3684         }
3685
3686         my $storecfg = PVE::Storage::config();
3687
3688         if (my $targetstorage = $param->{targetstorage}) {
3689             my $check_storage = sub {
3690                 my ($target_sid) = @_;
3691                 PVE::Storage::storage_check_node($storecfg, $target_sid, $target);
3692                 $rpcenv->check($authuser, "/storage/$target_sid", ['Datastore.AllocateSpace']);
3693                 my $scfg = PVE::Storage::storage_config($storecfg, $target_sid);
3694                 raise_param_exc({ targetstorage => "storage '$target_sid' does not support vm images"})
3695                     if !$scfg->{content}->{images};
3696             };
3697
3698             my $storagemap = eval { PVE::JSONSchema::parse_idmap($targetstorage, 'pve-storage-id') };
3699             raise_param_exc({ targetstorage => "failed to parse storage map: $@" })
3700                 if $@;
3701
3702             $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk'])
3703                 if !defined($storagemap->{identity});
3704
3705             foreach my $target_sid (values %{$storagemap->{entries}}) {
3706                 $check_storage->($target_sid);
3707             }
3708
3709             $check_storage->($storagemap->{default})
3710                 if $storagemap->{default};
3711
3712             PVE::QemuServer::check_storage_availability($storecfg, $conf, $target)
3713                 if $storagemap->{identity};
3714
3715             $param->{storagemap} = $storagemap;
3716         } else {
3717             PVE::QemuServer::check_storage_availability($storecfg, $conf, $target);
3718         }
3719
3720         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
3721
3722             my $hacmd = sub {
3723                 my $upid = shift;
3724
3725                 print "Requesting HA migration for VM $vmid to node $target\n";
3726
3727                 my $cmd = ['ha-manager', 'migrate', "vm:$vmid", $target];
3728                 PVE::Tools::run_command($cmd);
3729                 return;
3730             };
3731
3732             return $rpcenv->fork_worker('hamigrate', $vmid, $authuser, $hacmd);
3733
3734         } else {
3735
3736             my $realcmd = sub {
3737                 PVE::QemuMigrate->migrate($target, $targetip, $vmid, $param);
3738             };
3739
3740             my $worker = sub {
3741                 return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
3742             };
3743
3744             return $rpcenv->fork_worker('qmigrate', $vmid, $authuser, $worker);
3745         }
3746
3747     }});
3748
3749 __PACKAGE__->register_method({
3750     name => 'monitor',
3751     path => '{vmid}/monitor',
3752     method => 'POST',
3753     protected => 1,
3754     proxyto => 'node',
3755     description => "Execute Qemu monitor commands.",
3756     permissions => {
3757         description => "Sys.Modify is required for (sub)commands which are not read-only ('info *' and 'help')",
3758         check => ['perm', '/vms/{vmid}', [ 'VM.Monitor' ]],
3759     },
3760     parameters => {
3761         additionalProperties => 0,
3762         properties => {
3763             node => get_standard_option('pve-node'),
3764             vmid => get_standard_option('pve-vmid'),
3765             command => {
3766                 type => 'string',
3767                 description => "The monitor command.",
3768             }
3769         },
3770     },
3771     returns => { type => 'string'},
3772     code => sub {
3773         my ($param) = @_;
3774
3775         my $rpcenv = PVE::RPCEnvironment::get();
3776         my $authuser = $rpcenv->get_user();
3777
3778         my $is_ro = sub {
3779             my $command = shift;
3780             return $command =~ m/^\s*info(\s+|$)/
3781                 || $command =~ m/^\s*help\s*$/;
3782         };
3783
3784         $rpcenv->check_full($authuser, "/", ['Sys.Modify'])
3785             if !&$is_ro($param->{command});
3786
3787         my $vmid = $param->{vmid};
3788
3789         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
3790
3791         my $res = '';
3792         eval {
3793             $res = PVE::QemuServer::Monitor::hmp_cmd($vmid, $param->{command});
3794         };
3795         $res = "ERROR: $@" if $@;
3796
3797         return $res;
3798     }});
3799
3800 __PACKAGE__->register_method({
3801     name => 'resize_vm',
3802     path => '{vmid}/resize',
3803     method => 'PUT',
3804     protected => 1,
3805     proxyto => 'node',
3806     description => "Extend volume size.",
3807     permissions => {
3808         check => ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
3809     },
3810     parameters => {
3811         additionalProperties => 0,
3812         properties => {
3813             node => get_standard_option('pve-node'),
3814             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3815             skiplock => get_standard_option('skiplock'),
3816             disk => {
3817                 type => 'string',
3818                 description => "The disk you want to resize.",
3819                 enum => [PVE::QemuServer::Drive::valid_drive_names()],
3820             },
3821             size => {
3822                 type => 'string',
3823                 pattern => '\+?\d+(\.\d+)?[KMGT]?',
3824                 description => "The new size. With the `+` sign the value is added to the actual size of the volume and without it, the value is taken as an absolute one. Shrinking disk size is not supported.",
3825             },
3826             digest => {
3827                 type => 'string',
3828                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
3829                 maxLength => 40,
3830                 optional => 1,
3831             },
3832         },
3833     },
3834     returns => { type => 'null'},
3835     code => sub {
3836         my ($param) = @_;
3837
3838         my $rpcenv = PVE::RPCEnvironment::get();
3839
3840         my $authuser = $rpcenv->get_user();
3841
3842         my $node = extract_param($param, 'node');
3843
3844         my $vmid = extract_param($param, 'vmid');
3845
3846         my $digest = extract_param($param, 'digest');
3847
3848         my $disk = extract_param($param, 'disk');
3849
3850         my $sizestr = extract_param($param, 'size');
3851
3852         my $skiplock = extract_param($param, 'skiplock');
3853         raise_param_exc({ skiplock => "Only root may use this option." })
3854             if $skiplock && $authuser ne 'root@pam';
3855
3856         my $storecfg = PVE::Storage::config();
3857
3858         my $updatefn =  sub {
3859
3860             my $conf = PVE::QemuConfig->load_config($vmid);
3861
3862             die "checksum missmatch (file change by other user?)\n"
3863                 if $digest && $digest ne $conf->{digest};
3864             PVE::QemuConfig->check_lock($conf) if !$skiplock;
3865
3866             die "disk '$disk' does not exist\n" if !$conf->{$disk};
3867
3868             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
3869
3870             my (undef, undef, undef, undef, undef, undef, $format) =
3871                 PVE::Storage::parse_volname($storecfg, $drive->{file});
3872
3873             die "can't resize volume: $disk if snapshot exists\n"
3874                 if %{$conf->{snapshots}} && $format eq 'qcow2';
3875
3876             my $volid = $drive->{file};
3877
3878             die "disk '$disk' has no associated volume\n" if !$volid;
3879
3880             die "you can't resize a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive);
3881
3882             my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid);
3883
3884             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
3885
3886             PVE::Storage::activate_volumes($storecfg, [$volid]);
3887             my $size = PVE::Storage::volume_size_info($storecfg, $volid, 5);
3888
3889             die "Could not determine current size of volume '$volid'\n" if !defined($size);
3890
3891             die "internal error" if $sizestr !~ m/^(\+)?(\d+(\.\d+)?)([KMGT])?$/;
3892             my ($ext, $newsize, $unit) = ($1, $2, $4);
3893             if ($unit) {
3894                 if ($unit eq 'K') {
3895                     $newsize = $newsize * 1024;
3896                 } elsif ($unit eq 'M') {
3897                     $newsize = $newsize * 1024 * 1024;
3898                 } elsif ($unit eq 'G') {
3899                     $newsize = $newsize * 1024 * 1024 * 1024;
3900                 } elsif ($unit eq 'T') {
3901                     $newsize = $newsize * 1024 * 1024 * 1024 * 1024;
3902                 }
3903             }
3904             $newsize += $size if $ext;
3905             $newsize = int($newsize);
3906
3907             die "shrinking disks is not supported\n" if $newsize < $size;
3908
3909             return if $size == $newsize;
3910
3911             PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: resize --disk $disk --size $sizestr");
3912
3913             PVE::QemuServer::qemu_block_resize($vmid, "drive-$disk", $storecfg, $volid, $newsize);
3914
3915             $drive->{size} = $newsize;
3916             $conf->{$disk} = PVE::QemuServer::print_drive($drive);
3917
3918             PVE::QemuConfig->write_config($vmid, $conf);
3919         };
3920
3921         PVE::QemuConfig->lock_config($vmid, $updatefn);
3922         return;
3923     }});
3924
3925 __PACKAGE__->register_method({
3926     name => 'snapshot_list',
3927     path => '{vmid}/snapshot',
3928     method => 'GET',
3929     description => "List all snapshots.",
3930     permissions => {
3931         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
3932     },
3933     proxyto => 'node',
3934     protected => 1, # qemu pid files are only readable by root
3935     parameters => {
3936         additionalProperties => 0,
3937         properties => {
3938             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3939             node => get_standard_option('pve-node'),
3940         },
3941     },
3942     returns => {
3943         type => 'array',
3944         items => {
3945             type => "object",
3946             properties => {
3947                 name => {
3948                     description => "Snapshot identifier. Value 'current' identifies the current VM.",
3949                     type => 'string',
3950                 },
3951                 vmstate => {
3952                     description => "Snapshot includes RAM.",
3953                     type => 'boolean',
3954                     optional => 1,
3955                 },
3956                 description => {
3957                     description => "Snapshot description.",
3958                     type => 'string',
3959                 },
3960                 snaptime => {
3961                     description => "Snapshot creation time",
3962                     type => 'integer',
3963                     renderer => 'timestamp',
3964                     optional => 1,
3965                 },
3966                 parent => {
3967                     description => "Parent snapshot identifier.",
3968                     type => 'string',
3969                     optional => 1,
3970                 },
3971             },
3972         },
3973         links => [ { rel => 'child', href => "{name}" } ],
3974     },
3975     code => sub {
3976         my ($param) = @_;
3977
3978         my $vmid = $param->{vmid};
3979
3980         my $conf = PVE::QemuConfig->load_config($vmid);
3981         my $snaphash = $conf->{snapshots} || {};
3982
3983         my $res = [];
3984
3985         foreach my $name (keys %$snaphash) {
3986             my $d = $snaphash->{$name};
3987             my $item = {
3988                 name => $name,
3989                 snaptime => $d->{snaptime} || 0,
3990                 vmstate => $d->{vmstate} ? 1 : 0,
3991                 description => $d->{description} || '',
3992             };
3993             $item->{parent} = $d->{parent} if $d->{parent};
3994             $item->{snapstate} = $d->{snapstate} if $d->{snapstate};
3995             push @$res, $item;
3996         }
3997
3998         my $running = PVE::QemuServer::check_running($vmid, 1) ? 1 : 0;
3999         my $current = {
4000             name => 'current',
4001             digest => $conf->{digest},
4002             running => $running,
4003             description => "You are here!",
4004         };
4005         $current->{parent} = $conf->{parent} if $conf->{parent};
4006
4007         push @$res, $current;
4008
4009         return $res;
4010     }});
4011
4012 __PACKAGE__->register_method({
4013     name => 'snapshot',
4014     path => '{vmid}/snapshot',
4015     method => 'POST',
4016     protected => 1,
4017     proxyto => 'node',
4018     description => "Snapshot a VM.",
4019     permissions => {
4020         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
4021     },
4022     parameters => {
4023         additionalProperties => 0,
4024         properties => {
4025             node => get_standard_option('pve-node'),
4026             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
4027             snapname => get_standard_option('pve-snapshot-name'),
4028             vmstate => {
4029                 optional => 1,
4030                 type => 'boolean',
4031                 description => "Save the vmstate",
4032             },
4033             description => {
4034                 optional => 1,
4035                 type => 'string',
4036                 description => "A textual description or comment.",
4037             },
4038         },
4039     },
4040     returns => {
4041         type => 'string',
4042         description => "the task ID.",
4043     },
4044     code => sub {
4045         my ($param) = @_;
4046
4047         my $rpcenv = PVE::RPCEnvironment::get();
4048
4049         my $authuser = $rpcenv->get_user();
4050
4051         my $node = extract_param($param, 'node');
4052
4053         my $vmid = extract_param($param, 'vmid');
4054
4055         my $snapname = extract_param($param, 'snapname');
4056
4057         die "unable to use snapshot name 'current' (reserved name)\n"
4058             if $snapname eq 'current';
4059
4060         die "unable to use snapshot name 'pending' (reserved name)\n"
4061             if lc($snapname) eq 'pending';
4062
4063         my $realcmd = sub {
4064             PVE::Cluster::log_msg('info', $authuser, "snapshot VM $vmid: $snapname");
4065             PVE::QemuConfig->snapshot_create($vmid, $snapname, $param->{vmstate},
4066                                              $param->{description});
4067         };
4068
4069         return $rpcenv->fork_worker('qmsnapshot', $vmid, $authuser, $realcmd);
4070     }});
4071
4072 __PACKAGE__->register_method({
4073     name => 'snapshot_cmd_idx',
4074     path => '{vmid}/snapshot/{snapname}',
4075     description => '',
4076     method => 'GET',
4077     permissions => {
4078         user => 'all',
4079     },
4080     parameters => {
4081         additionalProperties => 0,
4082         properties => {
4083             vmid => get_standard_option('pve-vmid'),
4084             node => get_standard_option('pve-node'),
4085             snapname => get_standard_option('pve-snapshot-name'),
4086         },
4087     },
4088     returns => {
4089         type => 'array',
4090         items => {
4091             type => "object",
4092             properties => {},
4093         },
4094         links => [ { rel => 'child', href => "{cmd}" } ],
4095     },
4096     code => sub {
4097         my ($param) = @_;
4098
4099         my $res = [];
4100
4101         push @$res, { cmd => 'rollback' };
4102         push @$res, { cmd => 'config' };
4103
4104         return $res;
4105     }});
4106
4107 __PACKAGE__->register_method({
4108     name => 'update_snapshot_config',
4109     path => '{vmid}/snapshot/{snapname}/config',
4110     method => 'PUT',
4111     protected => 1,
4112     proxyto => 'node',
4113     description => "Update snapshot metadata.",
4114     permissions => {
4115         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
4116     },
4117     parameters => {
4118         additionalProperties => 0,
4119         properties => {
4120             node => get_standard_option('pve-node'),
4121             vmid => get_standard_option('pve-vmid'),
4122             snapname => get_standard_option('pve-snapshot-name'),
4123             description => {
4124                 optional => 1,
4125                 type => 'string',
4126                 description => "A textual description or comment.",
4127             },
4128         },
4129     },
4130     returns => { type => 'null' },
4131     code => sub {
4132         my ($param) = @_;
4133
4134         my $rpcenv = PVE::RPCEnvironment::get();
4135
4136         my $authuser = $rpcenv->get_user();
4137
4138         my $vmid = extract_param($param, 'vmid');
4139
4140         my $snapname = extract_param($param, 'snapname');
4141
4142         return if !defined($param->{description});
4143
4144         my $updatefn =  sub {
4145
4146             my $conf = PVE::QemuConfig->load_config($vmid);
4147
4148             PVE::QemuConfig->check_lock($conf);
4149
4150             my $snap = $conf->{snapshots}->{$snapname};
4151
4152             die "snapshot '$snapname' does not exist\n" if !defined($snap);
4153
4154             $snap->{description} = $param->{description} if defined($param->{description});
4155
4156              PVE::QemuConfig->write_config($vmid, $conf);
4157         };
4158
4159         PVE::QemuConfig->lock_config($vmid, $updatefn);
4160
4161         return;
4162     }});
4163
4164 __PACKAGE__->register_method({
4165     name => 'get_snapshot_config',
4166     path => '{vmid}/snapshot/{snapname}/config',
4167     method => 'GET',
4168     proxyto => 'node',
4169     description => "Get snapshot configuration",
4170     permissions => {
4171         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback', 'VM.Audit' ], any => 1],
4172     },
4173     parameters => {
4174         additionalProperties => 0,
4175         properties => {
4176             node => get_standard_option('pve-node'),
4177             vmid => get_standard_option('pve-vmid'),
4178             snapname => get_standard_option('pve-snapshot-name'),
4179         },
4180     },
4181     returns => { type => "object" },
4182     code => sub {
4183         my ($param) = @_;
4184
4185         my $rpcenv = PVE::RPCEnvironment::get();
4186
4187         my $authuser = $rpcenv->get_user();
4188
4189         my $vmid = extract_param($param, 'vmid');
4190
4191         my $snapname = extract_param($param, 'snapname');
4192
4193         my $conf = PVE::QemuConfig->load_config($vmid);
4194
4195         my $snap = $conf->{snapshots}->{$snapname};
4196
4197         die "snapshot '$snapname' does not exist\n" if !defined($snap);
4198
4199         return $snap;
4200     }});
4201
4202 __PACKAGE__->register_method({
4203     name => 'rollback',
4204     path => '{vmid}/snapshot/{snapname}/rollback',
4205     method => 'POST',
4206     protected => 1,
4207     proxyto => 'node',
4208     description => "Rollback VM state to specified snapshot.",
4209     permissions => {
4210         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback' ], any => 1],
4211     },
4212     parameters => {
4213         additionalProperties => 0,
4214         properties => {
4215             node => get_standard_option('pve-node'),
4216             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
4217             snapname => get_standard_option('pve-snapshot-name'),
4218         },
4219     },
4220     returns => {
4221         type => 'string',
4222         description => "the task ID.",
4223     },
4224     code => sub {
4225         my ($param) = @_;
4226
4227         my $rpcenv = PVE::RPCEnvironment::get();
4228
4229         my $authuser = $rpcenv->get_user();
4230
4231         my $node = extract_param($param, 'node');
4232
4233         my $vmid = extract_param($param, 'vmid');
4234
4235         my $snapname = extract_param($param, 'snapname');
4236
4237         my $realcmd = sub {
4238             PVE::Cluster::log_msg('info', $authuser, "rollback snapshot VM $vmid: $snapname");
4239             PVE::QemuConfig->snapshot_rollback($vmid, $snapname);
4240         };
4241
4242         my $worker = sub {
4243             # hold migration lock, this makes sure that nobody create replication snapshots
4244             return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
4245         };
4246
4247         return $rpcenv->fork_worker('qmrollback', $vmid, $authuser, $worker);
4248     }});
4249
4250 __PACKAGE__->register_method({
4251     name => 'delsnapshot',
4252     path => '{vmid}/snapshot/{snapname}',
4253     method => 'DELETE',
4254     protected => 1,
4255     proxyto => 'node',
4256     description => "Delete a VM snapshot.",
4257     permissions => {
4258         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
4259     },
4260     parameters => {
4261         additionalProperties => 0,
4262         properties => {
4263             node => get_standard_option('pve-node'),
4264             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
4265             snapname => get_standard_option('pve-snapshot-name'),
4266             force => {
4267                 optional => 1,
4268                 type => 'boolean',
4269                 description => "For removal from config file, even if removing disk snapshots fails.",
4270             },
4271         },
4272     },
4273     returns => {
4274         type => 'string',
4275         description => "the task ID.",
4276     },
4277     code => sub {
4278         my ($param) = @_;
4279
4280         my $rpcenv = PVE::RPCEnvironment::get();
4281
4282         my $authuser = $rpcenv->get_user();
4283
4284         my $node = extract_param($param, 'node');
4285
4286         my $vmid = extract_param($param, 'vmid');
4287
4288         my $snapname = extract_param($param, 'snapname');
4289
4290         my $realcmd = sub {
4291             PVE::Cluster::log_msg('info', $authuser, "delete snapshot VM $vmid: $snapname");
4292             PVE::QemuConfig->snapshot_delete($vmid, $snapname, $param->{force});
4293         };
4294
4295         return $rpcenv->fork_worker('qmdelsnapshot', $vmid, $authuser, $realcmd);
4296     }});
4297
4298 __PACKAGE__->register_method({
4299     name => 'template',
4300     path => '{vmid}/template',
4301     method => 'POST',
4302     protected => 1,
4303     proxyto => 'node',
4304     description => "Create a Template.",
4305     permissions => {
4306         description => "You need 'VM.Allocate' permissions on /vms/{vmid}",
4307         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
4308     },
4309     parameters => {
4310         additionalProperties => 0,
4311         properties => {
4312             node => get_standard_option('pve-node'),
4313             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
4314             disk => {
4315                 optional => 1,
4316                 type => 'string',
4317                 description => "If you want to convert only 1 disk to base image.",
4318                 enum => [PVE::QemuServer::Drive::valid_drive_names()],
4319             },
4320
4321         },
4322     },
4323     returns => { type => 'null'},
4324     code => sub {
4325         my ($param) = @_;
4326
4327         my $rpcenv = PVE::RPCEnvironment::get();
4328
4329         my $authuser = $rpcenv->get_user();
4330
4331         my $node = extract_param($param, 'node');
4332
4333         my $vmid = extract_param($param, 'vmid');
4334
4335         my $disk = extract_param($param, 'disk');
4336
4337         my $updatefn =  sub {
4338
4339             my $conf = PVE::QemuConfig->load_config($vmid);
4340
4341             PVE::QemuConfig->check_lock($conf);
4342
4343             die "unable to create template, because VM contains snapshots\n"
4344                 if $conf->{snapshots} && scalar(keys %{$conf->{snapshots}});
4345
4346             die "you can't convert a template to a template\n"
4347                 if PVE::QemuConfig->is_template($conf) && !$disk;
4348
4349             die "you can't convert a VM to template if VM is running\n"
4350                 if PVE::QemuServer::check_running($vmid);
4351
4352             my $realcmd = sub {
4353                 PVE::QemuServer::template_create($vmid, $conf, $disk);
4354             };
4355
4356             $conf->{template} = 1;
4357             PVE::QemuConfig->write_config($vmid, $conf);
4358
4359             return $rpcenv->fork_worker('qmtemplate', $vmid, $authuser, $realcmd);
4360         };
4361
4362         PVE::QemuConfig->lock_config($vmid, $updatefn);
4363         return;
4364     }});
4365
4366 __PACKAGE__->register_method({
4367     name => 'cloudinit_generated_config_dump',
4368     path => '{vmid}/cloudinit/dump',
4369     method => 'GET',
4370     proxyto => 'node',
4371     description => "Get automatically generated cloudinit config.",
4372     permissions => {
4373         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
4374     },
4375     parameters => {
4376         additionalProperties => 0,
4377         properties => {
4378             node => get_standard_option('pve-node'),
4379             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
4380             type => {
4381                 description => 'Config type.',
4382                 type => 'string',
4383                 enum => ['user', 'network', 'meta'],
4384             },
4385         },
4386     },
4387     returns => {
4388         type => 'string',
4389     },
4390     code => sub {
4391         my ($param) = @_;
4392
4393         my $conf = PVE::QemuConfig->load_config($param->{vmid});
4394
4395         return PVE::QemuServer::Cloudinit::dump_cloudinit_config($conf, $param->{vmid}, $param->{type});
4396     }});
4397
4398 1;