PVE/API2/Qemu.pm

   1 package PVE::API2::Qemu;
   2
   3 use strict;
   4 use warnings;
   5 use Cwd 'abs_path';
   6 use Net::SSLeay;
   7 use POSIX;
   8 use IO::Socket::IP;
   9 use URI::Escape;
  10 use Crypt::OpenSSL::Random;
  11
  12 use PVE::Cluster qw (cfs_read_file cfs_write_file);;
  13 use PVE::RRD;
  14 use PVE::SafeSyslog;
  15 use PVE::Tools qw(extract_param);
  16 use PVE::Exception qw(raise raise_param_exc raise_perm_exc);
  17 use PVE::Storage;
  18 use PVE::JSONSchema qw(get_standard_option);
  19 use PVE::RESTHandler;
  20 use PVE::ReplicationConfig;
  21 use PVE::GuestHelpers;
  22 use PVE::QemuConfig;
  23 use PVE::QemuServer;
  24 use PVE::QemuServer::Drive;
  25 use PVE::QemuServer::CPUConfig;
  26 use PVE::QemuServer::Monitor qw(mon_cmd);
  27 use PVE::QemuMigrate;
  28 use PVE::RPCEnvironment;
  29 use PVE::AccessControl;
  30 use PVE::INotify;
  31 use PVE::Network;
  32 use PVE::Firewall;
  33 use PVE::API2::Firewall::VM;
  34 use PVE::API2::Qemu::Agent;
  35 use PVE::VZDump::Plugin;
  36 use PVE::DataCenterConfig;
  37 use PVE::SSHInfo;
  38
  39 BEGIN {
  40     if (!$ENV{PVE_GENERATING_DOCS}) {
  41         require PVE::HA::Env::PVE2;
  42         import PVE::HA::Env::PVE2;
  43         require PVE::HA::Config;
  44         import PVE::HA::Config;
  45     }
  46 }
  47
  48 use Data::Dumper; # fixme: remove
  49
  50 use base qw(PVE::RESTHandler);
  51
  52 my $opt_force_description = "Force physical removal. Without this, we simple remove the disk from the config file and create an additional configuration entry called 'unused[n]', which contains the volume ID. Unlink of unused[n] always cause physical removal.";
  53
  54 my $resolve_cdrom_alias = sub {
  55     my $param = shift;
  56
  57     if (my $value = $param->{cdrom}) {
  58         $value .= ",media=cdrom" if $value !~ m/media=/;
  59         $param->{ide2} = $value;
  60         delete $param->{cdrom};
  61     }
  62 };
  63
  64 my $NEW_DISK_RE = qr!^(([^/:\s]+):)?(\d+(\.\d+)?)$!;
  65 my $check_storage_access = sub {
  66    my ($rpcenv, $authuser, $storecfg, $vmid, $settings, $default_storage) = @_;
  67
  68    PVE::QemuConfig->foreach_volume($settings, sub {
  69         my ($ds, $drive) = @_;
  70
  71         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
  72
  73         my $volid = $drive->{file};
  74         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
  75
  76         if (!$volid || ($volid eq 'none' || $volid eq 'cloudinit' || (defined($volname) && $volname eq 'cloudinit'))) {
  77             # nothing to check
  78         } elsif ($isCDROM && ($volid eq 'cdrom')) {
  79             $rpcenv->check($authuser, "/", ['Sys.Console']);
  80         } elsif (!$isCDROM && ($volid =~ $NEW_DISK_RE)) {
  81             my ($storeid, $size) = ($2 || $default_storage, $3);
  82             die "no storage ID specified (and no default storage)\n" if !$storeid;
  83             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
  84             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
  85             raise_param_exc({ storage => "storage '$storeid' does not support vm images"})
  86                 if !$scfg->{content}->{images};
  87         } else {
  88             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
  89         }
  90     });
  91
  92    $rpcenv->check($authuser, "/storage/$settings->{vmstatestorage}", ['Datastore.AllocateSpace'])
  93        if defined($settings->{vmstatestorage});
  94 };
  95
  96 my $check_storage_access_clone = sub {
  97    my ($rpcenv, $authuser, $storecfg, $conf, $storage) = @_;
  98
  99    my $sharedvm = 1;
 100
 101    PVE::QemuConfig->foreach_volume($conf, sub {
 102         my ($ds, $drive) = @_;
 103
 104         my $isCDROM = PVE::QemuServer::drive_is_cdrom($drive);
 105
 106         my $volid = $drive->{file};
 107
 108         return if !$volid || $volid eq 'none';
 109
 110         if ($isCDROM) {
 111             if ($volid eq 'cdrom') {
 112                 $rpcenv->check($authuser, "/", ['Sys.Console']);
 113             } else {
 114                 # we simply allow access
 115                 my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 116                 my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 117                 $sharedvm = 0 if !$scfg->{shared};
 118
 119             }
 120         } else {
 121             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 122             my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 123             $sharedvm = 0 if !$scfg->{shared};
 124
 125             $sid = $storage if $storage;
 126             $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
 127         }
 128     });
 129
 130    $rpcenv->check($authuser, "/storage/$conf->{vmstatestorage}", ['Datastore.AllocateSpace'])
 131        if defined($conf->{vmstatestorage});
 132
 133    return $sharedvm;
 134 };
 135
 136 # Note: $pool is only needed when creating a VM, because pool permissions
 137 # are automatically inherited if VM already exists inside a pool.
 138 my $create_disks = sub {
 139     my ($rpcenv, $authuser, $conf, $arch, $storecfg, $vmid, $pool, $settings, $default_storage) = @_;
 140
 141     my $vollist = [];
 142
 143     my $res = {};
 144
 145     my $code = sub {
 146         my ($ds, $disk) = @_;
 147
 148         my $volid = $disk->{file};
 149         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 150
 151         if (!$volid || $volid eq 'none' || $volid eq 'cdrom') {
 152             delete $disk->{size};
 153             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 154         } elsif (defined($volname) && $volname eq 'cloudinit') {
 155             $storeid = $storeid // $default_storage;
 156             die "no storage ID specified (and no default storage)\n" if !$storeid;
 157             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 158             my $name = "vm-$vmid-cloudinit";
 159
 160             my $fmt = undef;
 161             if ($scfg->{path}) {
 162                 $fmt = $disk->{format} // "qcow2";
 163                 $name .= ".$fmt";
 164             } else {
 165                 $fmt = $disk->{format} // "raw";
 166             }
 167
 168             # Initial disk created with 4 MB and aligned to 4MB on regeneration
 169             my $ci_size = PVE::QemuServer::Cloudinit::CLOUDINIT_DISK_SIZE;
 170             my $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $fmt, $name, $ci_size/1024);
 171             $disk->{file} = $volid;
 172             $disk->{media} = 'cdrom';
 173             push @$vollist, $volid;
 174             delete $disk->{format}; # no longer needed
 175             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 176         } elsif ($volid =~ $NEW_DISK_RE) {
 177             my ($storeid, $size) = ($2 || $default_storage, $3);
 178             die "no storage ID specified (and no default storage)\n" if !$storeid;
 179             my $defformat = PVE::Storage::storage_default_format($storecfg, $storeid);
 180             my $fmt = $disk->{format} || $defformat;
 181
 182             $size = PVE::Tools::convert_size($size, 'gb' => 'kb'); # vdisk_alloc uses kb
 183
 184             my $volid;
 185             if ($ds eq 'efidisk0') {
 186                 ($volid, $size) = PVE::QemuServer::create_efidisk($storecfg, $storeid, $vmid, $fmt, $arch);
 187             } else {
 188                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storeid, $vmid, $fmt, undef, $size);
 189             }
 190             push @$vollist, $volid;
 191             $disk->{file} = $volid;
 192             $disk->{size} = PVE::Tools::convert_size($size, 'kb' => 'b');
 193             delete $disk->{format}; # no longer needed
 194             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 195         } else {
 196
 197             PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $volid);
 198
 199             my $volid_is_new = 1;
 200
 201             if ($conf->{$ds}) {
 202                 my $olddrive = PVE::QemuServer::parse_drive($ds, $conf->{$ds});
 203                 $volid_is_new = undef if $olddrive->{file} && $olddrive->{file} eq $volid;
 204             }
 205
 206             if ($volid_is_new) {
 207
 208                 PVE::Storage::activate_volumes($storecfg, [ $volid ]) if $storeid;
 209
 210                 my $size = PVE::Storage::volume_size_info($storecfg, $volid);
 211
 212                 die "volume $volid does not exist\n" if !$size;
 213
 214                 $disk->{size} = $size;
 215             }
 216
 217             $res->{$ds} = PVE::QemuServer::print_drive($disk);
 218         }
 219     };
 220
 221     eval { PVE::QemuConfig->foreach_volume($settings, $code); };
 222
 223     # free allocated images on error
 224     if (my $err = $@) {
 225         syslog('err', "VM $vmid creating disks failed");
 226         foreach my $volid (@$vollist) {
 227             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 228             warn $@ if $@;
 229         }
 230         die $err;
 231     }
 232
 233     # modify vm config if everything went well
 234     foreach my $ds (keys %$res) {
 235         $conf->{$ds} = $res->{$ds};
 236     }
 237
 238     return $vollist;
 239 };
 240
 241 my $check_cpu_model_access = sub {
 242     my ($rpcenv, $authuser, $new, $existing) = @_;
 243
 244     return if !defined($new->{cpu});
 245
 246     my $cpu = PVE::JSONSchema::check_format('pve-vm-cpu-conf', $new->{cpu});
 247     return if !$cpu || !$cpu->{cputype}; # always allow default
 248     my $cputype = $cpu->{cputype};
 249
 250     if ($existing && $existing->{cpu}) {
 251         # changing only other settings doesn't require permissions for CPU model
 252         my $existingCpu = PVE::JSONSchema::check_format('pve-vm-cpu-conf', $existing->{cpu});
 253         return if $existingCpu->{cputype} eq $cputype;
 254     }
 255
 256     if (PVE::QemuServer::CPUConfig::is_custom_model($cputype)) {
 257         $rpcenv->check($authuser, "/nodes", ['Sys.Audit']);
 258     }
 259 };
 260
 261 my $cpuoptions = {
 262     'cores' => 1,
 263     'cpu' => 1,
 264     'cpulimit' => 1,
 265     'cpuunits' => 1,
 266     'numa' => 1,
 267     'smp' => 1,
 268     'sockets' => 1,
 269     'vcpus' => 1,
 270 };
 271
 272 my $memoryoptions = {
 273     'memory' => 1,
 274     'balloon' => 1,
 275     'shares' => 1,
 276 };
 277
 278 my $hwtypeoptions = {
 279     'acpi' => 1,
 280     'hotplug' => 1,
 281     'kvm' => 1,
 282     'machine' => 1,
 283     'scsihw' => 1,
 284     'smbios1' => 1,
 285     'tablet' => 1,
 286     'vga' => 1,
 287     'watchdog' => 1,
 288     'audio0' => 1,
 289 };
 290
 291 my $generaloptions = {
 292     'agent' => 1,
 293     'autostart' => 1,
 294     'bios' => 1,
 295     'description' => 1,
 296     'keyboard' => 1,
 297     'localtime' => 1,
 298     'migrate_downtime' => 1,
 299     'migrate_speed' => 1,
 300     'name' => 1,
 301     'onboot' => 1,
 302     'ostype' => 1,
 303     'protection' => 1,
 304     'reboot' => 1,
 305     'startdate' => 1,
 306     'startup' => 1,
 307     'tdf' => 1,
 308     'template' => 1,
 309     'tags' => 1,
 310 };
 311
 312 my $vmpoweroptions = {
 313     'freeze' => 1,
 314 };
 315
 316 my $diskoptions = {
 317     'boot' => 1,
 318     'bootdisk' => 1,
 319     'vmstatestorage' => 1,
 320 };
 321
 322 my $cloudinitoptions = {
 323     cicustom => 1,
 324     cipassword => 1,
 325     citype => 1,
 326     ciuser => 1,
 327     nameserver => 1,
 328     searchdomain => 1,
 329     sshkeys => 1,
 330 };
 331
 332 my $check_vm_modify_config_perm = sub {
 333     my ($rpcenv, $authuser, $vmid, $pool, $key_list) = @_;
 334
 335     return 1 if $authuser eq 'root@pam';
 336
 337     foreach my $opt (@$key_list) {
 338         # some checks (e.g., disk, serial port, usb) need to be done somewhere
 339         # else, as there the permission can be value dependend
 340         next if PVE::QemuServer::is_valid_drivename($opt);
 341         next if $opt eq 'cdrom';
 342         next if $opt =~ m/^(?:unused|serial|usb)\d+$/;
 343
 344
 345         if ($cpuoptions->{$opt} || $opt =~ m/^numa\d+$/) {
 346             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
 347         } elsif ($memoryoptions->{$opt}) {
 348             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
 349         } elsif ($hwtypeoptions->{$opt}) {
 350             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.HWType']);
 351         } elsif ($generaloptions->{$opt}) {
 352             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
 353             # special case for startup since it changes host behaviour
 354             if ($opt eq 'startup') {
 355                 $rpcenv->check_full($authuser, "/", ['Sys.Modify']);
 356             }
 357         } elsif ($vmpoweroptions->{$opt}) {
 358             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.PowerMgmt']);
 359         } elsif ($diskoptions->{$opt}) {
 360             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
 361         } elsif ($opt =~ m/^(?:net|ipconfig)\d+$/) {
 362             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
 363         } elsif ($cloudinitoptions->{$opt}) {
 364             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Cloudinit', 'VM.Config.Network'], 1);
 365         } elsif ($opt eq 'vmstate') {
 366             # the user needs Disk and PowerMgmt privileges to change the vmstate
 367             # also needs privileges on the storage, that will be checked later
 368             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk', 'VM.PowerMgmt' ]);
 369         } else {
 370             # catches hostpci\d+, args, lock, etc.
 371             # new options will be checked here
 372             die "only root can set '$opt' config\n";
 373         }
 374     }
 375
 376     return 1;
 377 };
 378
 379 __PACKAGE__->register_method({
 380     name => 'vmlist',
 381     path => '',
 382     method => 'GET',
 383     description => "Virtual machine index (per node).",
 384     permissions => {
 385         description => "Only list VMs where you have VM.Audit permissons on /vms/<vmid>.",
 386         user => 'all',
 387     },
 388     proxyto => 'node',
 389     protected => 1, # qemu pid files are only readable by root
 390     parameters => {
 391         additionalProperties => 0,
 392         properties => {
 393             node => get_standard_option('pve-node'),
 394             full => {
 395                 type => 'boolean',
 396                 optional => 1,
 397                 description => "Determine the full status of active VMs.",
 398             },
 399         },
 400     },
 401     returns => {
 402         type => 'array',
 403         items => {
 404             type => "object",
 405             properties => $PVE::QemuServer::vmstatus_return_properties,
 406         },
 407         links => [ { rel => 'child', href => "{vmid}" } ],
 408     },
 409     code => sub {
 410         my ($param) = @_;
 411
 412         my $rpcenv = PVE::RPCEnvironment::get();
 413         my $authuser = $rpcenv->get_user();
 414
 415         my $vmstatus = PVE::QemuServer::vmstatus(undef, $param->{full});
 416
 417         my $res = [];
 418         foreach my $vmid (keys %$vmstatus) {
 419             next if !$rpcenv->check($authuser, "/vms/$vmid", [ 'VM.Audit' ], 1);
 420
 421             my $data = $vmstatus->{$vmid};
 422             push @$res, $data;
 423         }
 424
 425         return $res;
 426     }});
 427
 428 my $parse_restore_archive = sub {
 429     my ($storecfg, $archive) = @_;
 430
 431     my ($archive_storeid, $archive_volname) = PVE::Storage::parse_volume_id($archive, 1);
 432
 433     if (defined($archive_storeid)) {
 434         my $scfg =  PVE::Storage::storage_config($storecfg, $archive_storeid);
 435         if ($scfg->{type} eq 'pbs') {
 436             return {
 437                 type => 'pbs',
 438                 volid => $archive,
 439             };
 440         }
 441     }
 442     my $path = PVE::Storage::abs_filesystem_path($storecfg, $archive);
 443     return {
 444         type => 'file',
 445         path => $path,
 446     };
 447 };
 448
 449
 450 __PACKAGE__->register_method({
 451     name => 'create_vm',
 452     path => '',
 453     method => 'POST',
 454     description => "Create or restore a virtual machine.",
 455     permissions => {
 456         description => "You need 'VM.Allocate' permissions on /vms/{vmid} or on the VM pool /pool/{pool}. " .
 457             "For restore (option 'archive'), it is enough if the user has 'VM.Backup' permission and the VM already exists. " .
 458             "If you create disks you need 'Datastore.AllocateSpace' on any used storage.",
 459         user => 'all', # check inside
 460     },
 461     protected => 1,
 462     proxyto => 'node',
 463     parameters => {
 464         additionalProperties => 0,
 465         properties => PVE::QemuServer::json_config_properties(
 466             {
 467                 node => get_standard_option('pve-node'),
 468                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::Cluster::complete_next_vmid }),
 469                 archive => {
 470                     description => "The backup archive. Either the file system path to a .tar or .vma file (use '-' to pipe data from stdin) or a proxmox storage backup volume identifier.",
 471                     type => 'string',
 472                     optional => 1,
 473                     maxLength => 255,
 474                     completion => \&PVE::QemuServer::complete_backup_archives,
 475                 },
 476                 storage => get_standard_option('pve-storage-id', {
 477                     description => "Default storage.",
 478                     optional => 1,
 479                     completion => \&PVE::QemuServer::complete_storage,
 480                 }),
 481                 force => {
 482                     optional => 1,
 483                     type => 'boolean',
 484                     description => "Allow to overwrite existing VM.",
 485                     requires => 'archive',
 486                 },
 487                 unique => {
 488                     optional => 1,
 489                     type => 'boolean',
 490                     description => "Assign a unique random ethernet address.",
 491                     requires => 'archive',
 492                 },
 493                 pool => {
 494                     optional => 1,
 495                     type => 'string', format => 'pve-poolid',
 496                     description => "Add the VM to the specified pool.",
 497                 },
 498                 bwlimit => {
 499                     description => "Override I/O bandwidth limit (in KiB/s).",
 500                     optional => 1,
 501                     type => 'integer',
 502                     minimum => '0',
 503                     default => 'restore limit from datacenter or storage config',
 504                 },
 505                 start => {
 506                     optional => 1,
 507                     type => 'boolean',
 508                     default => 0,
 509                     description => "Start VM after it was created successfully.",
 510                 },
 511             }),
 512     },
 513     returns => {
 514         type => 'string',
 515     },
 516     code => sub {
 517         my ($param) = @_;
 518
 519         my $rpcenv = PVE::RPCEnvironment::get();
 520         my $authuser = $rpcenv->get_user();
 521
 522         my $node = extract_param($param, 'node');
 523         my $vmid = extract_param($param, 'vmid');
 524
 525         my $archive = extract_param($param, 'archive');
 526         my $is_restore = !!$archive;
 527
 528         my $bwlimit = extract_param($param, 'bwlimit');
 529         my $force = extract_param($param, 'force');
 530         my $pool = extract_param($param, 'pool');
 531         my $start_after_create = extract_param($param, 'start');
 532         my $storage = extract_param($param, 'storage');
 533         my $unique = extract_param($param, 'unique');
 534
 535         if (defined(my $ssh_keys = $param->{sshkeys})) {
 536                 $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
 537                 PVE::Tools::validate_ssh_public_keys($ssh_keys);
 538         }
 539
 540         PVE::Cluster::check_cfs_quorum();
 541
 542         my $filename = PVE::QemuConfig->config_file($vmid);
 543         my $storecfg = PVE::Storage::config();
 544
 545         if (defined($pool)) {
 546             $rpcenv->check_pool_exist($pool);
 547         }
 548
 549         $rpcenv->check($authuser, "/storage/$storage", ['Datastore.AllocateSpace'])
 550             if defined($storage);
 551
 552         if ($rpcenv->check($authuser, "/vms/$vmid", ['VM.Allocate'], 1)) {
 553             # OK
 554         } elsif ($pool && $rpcenv->check($authuser, "/pool/$pool", ['VM.Allocate'], 1)) {
 555             # OK
 556         } elsif ($archive && $force && (-f $filename) &&
 557                  $rpcenv->check($authuser, "/vms/$vmid", ['VM.Backup'], 1)) {
 558             # OK: user has VM.Backup permissions, and want to restore an existing VM
 559         } else {
 560             raise_perm_exc();
 561         }
 562
 563         if (!$archive) {
 564             &$resolve_cdrom_alias($param);
 565
 566             &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param, $storage);
 567
 568             &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, $pool, [ keys %$param]);
 569
 570             &$check_cpu_model_access($rpcenv, $authuser, $param);
 571
 572             foreach my $opt (keys %$param) {
 573                 if (PVE::QemuServer::is_valid_drivename($opt)) {
 574                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
 575                     raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
 576
 577                     PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
 578                     $param->{$opt} = PVE::QemuServer::print_drive($drive);
 579                 }
 580             }
 581
 582             PVE::QemuServer::add_random_macs($param);
 583         } else {
 584             my $keystr = join(' ', keys %$param);
 585             raise_param_exc({ archive => "option conflicts with other options ($keystr)"}) if $keystr;
 586
 587             if ($archive eq '-') {
 588                 die "pipe requires cli environment\n"
 589                     if $rpcenv->{type} ne 'cli';
 590                 $archive = { type => 'pipe' };
 591             } else {
 592                 PVE::Storage::check_volume_access($rpcenv, $authuser, $storecfg, $vmid, $archive);
 593
 594                 $archive = $parse_restore_archive->($storecfg, $archive);
 595             }
 596         }
 597
 598         my $emsg = $is_restore ? "unable to restore VM $vmid -" : "unable to create VM $vmid -";
 599
 600         eval { PVE::QemuConfig->create_and_lock_config($vmid, $force) };
 601         die "$emsg $@" if $@;
 602
 603         my $restorefn = sub {
 604             my $conf = PVE::QemuConfig->load_config($vmid);
 605
 606             PVE::QemuConfig->check_protection($conf, $emsg);
 607
 608             die "$emsg vm is running\n" if PVE::QemuServer::check_running($vmid);
 609
 610             my $realcmd = sub {
 611                 my $restore_options = {
 612                     storage => $storage,
 613                     pool => $pool,
 614                     unique => $unique,
 615                     bwlimit => $bwlimit,
 616                 };
 617                 if ($archive->{type} eq 'file' || $archive->{type} eq 'pipe') {
 618                     PVE::QemuServer::restore_file_archive($archive->{path} // '-', $vmid, $authuser, $restore_options);
 619                 } elsif ($archive->{type} eq 'pbs') {
 620                     PVE::QemuServer::restore_proxmox_backup_archive($archive->{volid}, $vmid, $authuser, $restore_options);
 621                 } else {
 622                     die "unknown backup archive type\n";
 623                 }
 624                 my $restored_conf = PVE::QemuConfig->load_config($vmid);
 625                 # Convert restored VM to template if backup was VM template
 626                 if (PVE::QemuConfig->is_template($restored_conf)) {
 627                     warn "Convert to template.\n";
 628                     eval { PVE::QemuServer::template_create($vmid, $restored_conf) };
 629                     warn $@ if $@;
 630                 }
 631
 632                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 633             };
 634
 635             # ensure no old replication state are exists
 636             PVE::ReplicationState::delete_guest_states($vmid);
 637
 638             PVE::QemuConfig->lock_config_full($vmid, 1, $realcmd);
 639
 640             if ($start_after_create) {
 641                 print "Execute autostart\n";
 642                 eval { PVE::API2::Qemu->vm_start({ vmid => $vmid, node => $node }) };
 643                 warn $@ if $@;
 644             }
 645         };
 646
 647         my $createfn = sub {
 648             # ensure no old replication state are exists
 649             PVE::ReplicationState::delete_guest_states($vmid);
 650
 651             my $realcmd = sub {
 652                 my $conf = $param;
 653                 my $arch = PVE::QemuServer::get_vm_arch($conf);
 654
 655                 my $vollist = [];
 656                 eval {
 657                     $vollist = &$create_disks($rpcenv, $authuser, $conf, $arch, $storecfg, $vmid, $pool, $param, $storage);
 658
 659                     if (!$conf->{boot}) {
 660                         my $devs = PVE::QemuServer::get_default_bootdevices($conf);
 661                         $conf->{boot} = PVE::QemuServer::print_bootorder($devs);
 662                     }
 663
 664                     # auto generate uuid if user did not specify smbios1 option
 665                     if (!$conf->{smbios1}) {
 666                         $conf->{smbios1} = PVE::QemuServer::generate_smbios1_uuid();
 667                     }
 668
 669                     if ((!defined($conf->{vmgenid}) || $conf->{vmgenid} eq '1') && $arch ne 'aarch64') {
 670                         $conf->{vmgenid} = PVE::QemuServer::generate_uuid();
 671                     }
 672
 673                     PVE::QemuConfig->write_config($vmid, $conf);
 674
 675                 };
 676                 my $err = $@;
 677
 678                 if ($err) {
 679                     foreach my $volid (@$vollist) {
 680                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
 681                         warn $@ if $@;
 682                     }
 683                     die "$emsg $err";
 684                 }
 685
 686                 PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 687             };
 688
 689             PVE::QemuConfig->lock_config_full($vmid, 1, $realcmd);
 690
 691             if ($start_after_create) {
 692                 print "Execute autostart\n";
 693                 eval { PVE::API2::Qemu->vm_start({vmid => $vmid, node => $node}) };
 694                 warn $@ if $@;
 695             }
 696         };
 697
 698         my ($code, $worker_name);
 699         if ($is_restore) {
 700             $worker_name = 'qmrestore';
 701             $code = sub {
 702                 eval { $restorefn->() };
 703                 if (my $err = $@) {
 704                     eval { PVE::QemuConfig->remove_lock($vmid, 'create') };
 705                     warn $@ if $@;
 706                     die $err;
 707                 }
 708             };
 709         } else {
 710             $worker_name = 'qmcreate';
 711             $code = sub {
 712                 eval { $createfn->() };
 713                 if (my $err = $@) {
 714                     eval {
 715                         my $conffile = PVE::QemuConfig->config_file($vmid);
 716                         unlink($conffile) or die "failed to remove config file: $!\n";
 717                     };
 718                     warn $@ if $@;
 719                     die $err;
 720                 }
 721             };
 722         }
 723
 724         return $rpcenv->fork_worker($worker_name, $vmid, $authuser, $code);
 725     }});
 726
 727 __PACKAGE__->register_method({
 728     name => 'vmdiridx',
 729     path => '{vmid}',
 730     method => 'GET',
 731     proxyto => 'node',
 732     description => "Directory index",
 733     permissions => {
 734         user => 'all',
 735     },
 736     parameters => {
 737         additionalProperties => 0,
 738         properties => {
 739             node => get_standard_option('pve-node'),
 740             vmid => get_standard_option('pve-vmid'),
 741         },
 742     },
 743     returns => {
 744         type => 'array',
 745         items => {
 746             type => "object",
 747             properties => {
 748                 subdir => { type => 'string' },
 749             },
 750         },
 751         links => [ { rel => 'child', href => "{subdir}" } ],
 752     },
 753     code => sub {
 754         my ($param) = @_;
 755
 756         my $res = [
 757             { subdir => 'config' },
 758             { subdir => 'pending' },
 759             { subdir => 'status' },
 760             { subdir => 'unlink' },
 761             { subdir => 'vncproxy' },
 762             { subdir => 'termproxy' },
 763             { subdir => 'migrate' },
 764             { subdir => 'resize' },
 765             { subdir => 'move' },
 766             { subdir => 'rrd' },
 767             { subdir => 'rrddata' },
 768             { subdir => 'monitor' },
 769             { subdir => 'agent' },
 770             { subdir => 'snapshot' },
 771             { subdir => 'spiceproxy' },
 772             { subdir => 'sendkey' },
 773             { subdir => 'firewall' },
 774             ];
 775
 776         return $res;
 777     }});
 778
 779 __PACKAGE__->register_method ({
 780     subclass => "PVE::API2::Firewall::VM",
 781     path => '{vmid}/firewall',
 782 });
 783
 784 __PACKAGE__->register_method ({
 785     subclass => "PVE::API2::Qemu::Agent",
 786     path => '{vmid}/agent',
 787 });
 788
 789 __PACKAGE__->register_method({
 790     name => 'rrd',
 791     path => '{vmid}/rrd',
 792     method => 'GET',
 793     protected => 1, # fixme: can we avoid that?
 794     permissions => {
 795         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 796     },
 797     description => "Read VM RRD statistics (returns PNG)",
 798     parameters => {
 799         additionalProperties => 0,
 800         properties => {
 801             node => get_standard_option('pve-node'),
 802             vmid => get_standard_option('pve-vmid'),
 803             timeframe => {
 804                 description => "Specify the time frame you are interested in.",
 805                 type => 'string',
 806                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 807             },
 808             ds => {
 809                 description => "The list of datasources you want to display.",
 810                 type => 'string', format => 'pve-configid-list',
 811             },
 812             cf => {
 813                 description => "The RRD consolidation function",
 814                 type => 'string',
 815                 enum => [ 'AVERAGE', 'MAX' ],
 816                 optional => 1,
 817             },
 818         },
 819     },
 820     returns => {
 821         type => "object",
 822         properties => {
 823             filename => { type => 'string' },
 824         },
 825     },
 826     code => sub {
 827         my ($param) = @_;
 828
 829         return PVE::RRD::create_rrd_graph(
 830             "pve2-vm/$param->{vmid}", $param->{timeframe},
 831             $param->{ds}, $param->{cf});
 832
 833     }});
 834
 835 __PACKAGE__->register_method({
 836     name => 'rrddata',
 837     path => '{vmid}/rrddata',
 838     method => 'GET',
 839     protected => 1, # fixme: can we avoid that?
 840     permissions => {
 841         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 842     },
 843     description => "Read VM RRD statistics",
 844     parameters => {
 845         additionalProperties => 0,
 846         properties => {
 847             node => get_standard_option('pve-node'),
 848             vmid => get_standard_option('pve-vmid'),
 849             timeframe => {
 850                 description => "Specify the time frame you are interested in.",
 851                 type => 'string',
 852                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 853             },
 854             cf => {
 855                 description => "The RRD consolidation function",
 856                 type => 'string',
 857                 enum => [ 'AVERAGE', 'MAX' ],
 858                 optional => 1,
 859             },
 860         },
 861     },
 862     returns => {
 863         type => "array",
 864         items => {
 865             type => "object",
 866             properties => {},
 867         },
 868     },
 869     code => sub {
 870         my ($param) = @_;
 871
 872         return PVE::RRD::create_rrd_data(
 873             "pve2-vm/$param->{vmid}", $param->{timeframe}, $param->{cf});
 874     }});
 875
 876
 877 __PACKAGE__->register_method({
 878     name => 'vm_config',
 879     path => '{vmid}/config',
 880     method => 'GET',
 881     proxyto => 'node',
 882     description => "Get the virtual machine configuration with pending configuration " .
 883         "changes applied. Set the 'current' parameter to get the current configuration instead.",
 884     permissions => {
 885         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 886     },
 887     parameters => {
 888         additionalProperties => 0,
 889         properties => {
 890             node => get_standard_option('pve-node'),
 891             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 892             current => {
 893                 description => "Get current values (instead of pending values).",
 894                 optional => 1,
 895                 default => 0,
 896                 type => 'boolean',
 897             },
 898             snapshot => get_standard_option('pve-snapshot-name', {
 899                 description => "Fetch config values from given snapshot.",
 900                 optional => 1,
 901                 completion => sub {
 902                     my ($cmd, $pname, $cur, $args) = @_;
 903                     PVE::QemuConfig->snapshot_list($args->[0]);
 904                 },
 905             }),
 906         },
 907     },
 908     returns => {
 909         description => "The VM configuration.",
 910         type => "object",
 911         properties => PVE::QemuServer::json_config_properties({
 912             digest => {
 913                 type => 'string',
 914                 description => 'SHA1 digest of configuration file. This can be used to prevent concurrent modifications.',
 915             }
 916         }),
 917     },
 918     code => sub {
 919         my ($param) = @_;
 920
 921         raise_param_exc({ snapshot => "cannot use 'snapshot' parameter with 'current'",
 922                           current => "cannot use 'snapshot' parameter with 'current'"})
 923             if ($param->{snapshot} && $param->{current});
 924
 925         my $conf;
 926         if ($param->{snapshot}) {
 927             $conf = PVE::QemuConfig->load_snapshot_config($param->{vmid}, $param->{snapshot});
 928         } else {
 929             $conf = PVE::QemuConfig->load_current_config($param->{vmid}, $param->{current});
 930         }
 931         $conf->{cipassword} = '**********' if $conf->{cipassword};
 932         return $conf;
 933
 934     }});
 935
 936 __PACKAGE__->register_method({
 937     name => 'vm_pending',
 938     path => '{vmid}/pending',
 939     method => 'GET',
 940     proxyto => 'node',
 941     description => "Get the virtual machine configuration with both current and pending values.",
 942     permissions => {
 943         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 944     },
 945     parameters => {
 946         additionalProperties => 0,
 947         properties => {
 948             node => get_standard_option('pve-node'),
 949             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 950         },
 951     },
 952     returns => {
 953         type => "array",
 954         items => {
 955             type => "object",
 956             properties => {
 957                 key => {
 958                     description => "Configuration option name.",
 959                     type => 'string',
 960                 },
 961                 value => {
 962                     description => "Current value.",
 963                     type => 'string',
 964                     optional => 1,
 965                 },
 966                 pending => {
 967                     description => "Pending value.",
 968                     type => 'string',
 969                     optional => 1,
 970                 },
 971                 delete => {
 972                     description => "Indicates a pending delete request if present and not 0. " .
 973                                    "The value 2 indicates a force-delete request.",
 974                     type => 'integer',
 975                     minimum => 0,
 976                     maximum => 2,
 977                     optional => 1,
 978                 },
 979             },
 980         },
 981     },
 982     code => sub {
 983         my ($param) = @_;
 984
 985         my $conf = PVE::QemuConfig->load_config($param->{vmid});
 986
 987         my $pending_delete_hash = PVE::QemuConfig->parse_pending_delete($conf->{pending}->{delete});
 988
 989         $conf->{cipassword} = '**********' if defined($conf->{cipassword});
 990         $conf->{pending}->{cipassword} = '********** ' if defined($conf->{pending}->{cipassword});
 991
 992         return PVE::GuestHelpers::config_with_pending_array($conf, $pending_delete_hash);
 993    }});
 994
 995 # POST/PUT {vmid}/config implementation
 996 #
 997 # The original API used PUT (idempotent) an we assumed that all operations
 998 # are fast. But it turned out that almost any configuration change can
 999 # involve hot-plug actions, or disk alloc/free. Such actions can take long
1000 # time to complete and have side effects (not idempotent).
1001 #
1002 # The new implementation uses POST and forks a worker process. We added
1003 # a new option 'background_delay'. If specified we wait up to
1004 # 'background_delay' second for the worker task to complete. It returns null
1005 # if the task is finished within that time, else we return the UPID.
1006
1007 my $update_vm_api  = sub {
1008     my ($param, $sync) = @_;
1009
1010     my $rpcenv = PVE::RPCEnvironment::get();
1011
1012     my $authuser = $rpcenv->get_user();
1013
1014     my $node = extract_param($param, 'node');
1015
1016     my $vmid = extract_param($param, 'vmid');
1017
1018     my $digest = extract_param($param, 'digest');
1019
1020     my $background_delay = extract_param($param, 'background_delay');
1021
1022     if (defined(my $cipassword = $param->{cipassword})) {
1023         # Same logic as in cloud-init (but with the regex fixed...)
1024         $param->{cipassword} = PVE::Tools::encrypt_pw($cipassword)
1025             if $cipassword !~ /^\$(?:[156]|2[ay])(\$.+){2}/;
1026     }
1027
1028     my @paramarr = (); # used for log message
1029     foreach my $key (sort keys %$param) {
1030         my $value = $key eq 'cipassword' ? '<hidden>' : $param->{$key};
1031         push @paramarr, "-$key", $value;
1032     }
1033
1034     my $skiplock = extract_param($param, 'skiplock');
1035     raise_param_exc({ skiplock => "Only root may use this option." })
1036         if $skiplock && $authuser ne 'root@pam';
1037
1038     my $delete_str = extract_param($param, 'delete');
1039
1040     my $revert_str = extract_param($param, 'revert');
1041
1042     my $force = extract_param($param, 'force');
1043
1044     if (defined(my $ssh_keys = $param->{sshkeys})) {
1045         $ssh_keys = URI::Escape::uri_unescape($ssh_keys);
1046         PVE::Tools::validate_ssh_public_keys($ssh_keys);
1047     }
1048
1049     die "no options specified\n" if !$delete_str && !$revert_str && !scalar(keys %$param);
1050
1051     my $storecfg = PVE::Storage::config();
1052
1053     my $defaults = PVE::QemuServer::load_defaults();
1054
1055     &$resolve_cdrom_alias($param);
1056
1057     # now try to verify all parameters
1058
1059     my $revert = {};
1060     foreach my $opt (PVE::Tools::split_list($revert_str)) {
1061         if (!PVE::QemuServer::option_exists($opt)) {
1062             raise_param_exc({ revert => "unknown option '$opt'" });
1063         }
1064
1065         raise_param_exc({ delete => "you can't use '-$opt' and " .
1066                               "-revert $opt' at the same time" })
1067             if defined($param->{$opt});
1068
1069         $revert->{$opt} = 1;
1070     }
1071
1072     my @delete = ();
1073     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1074         $opt = 'ide2' if $opt eq 'cdrom';
1075
1076         raise_param_exc({ delete => "you can't use '-$opt' and " .
1077                               "-delete $opt' at the same time" })
1078             if defined($param->{$opt});
1079
1080         raise_param_exc({ revert => "you can't use '-delete $opt' and " .
1081                               "-revert $opt' at the same time" })
1082             if $revert->{$opt};
1083
1084         if (!PVE::QemuServer::option_exists($opt)) {
1085             raise_param_exc({ delete => "unknown option '$opt'" });
1086         }
1087
1088         push @delete, $opt;
1089     }
1090
1091     my $repl_conf = PVE::ReplicationConfig->new();
1092     my $is_replicated = $repl_conf->check_for_existing_jobs($vmid, 1);
1093     my $check_replication = sub {
1094         my ($drive) = @_;
1095         return if !$is_replicated;
1096         my $volid = $drive->{file};
1097         return if !$volid || !($drive->{replicate}//1);
1098         return if PVE::QemuServer::drive_is_cdrom($drive);
1099
1100         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1101         die "cannot add non-managed/pass-through volume to a replicated VM\n"
1102             if !defined($storeid);
1103
1104         return if defined($volname) && $volname eq 'cloudinit';
1105
1106         my $format;
1107         if ($volid =~ $NEW_DISK_RE) {
1108             $storeid = $2;
1109             $format = $drive->{format} || PVE::Storage::storage_default_format($storecfg, $storeid);
1110         } else {
1111             $format = (PVE::Storage::parse_volname($storecfg, $volid))[6];
1112         }
1113         return if PVE::Storage::storage_can_replicate($storecfg, $storeid, $format);
1114         my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
1115         return if $scfg->{shared};
1116         die "cannot add non-replicatable volume to a replicated VM\n";
1117     };
1118
1119     foreach my $opt (keys %$param) {
1120         if (PVE::QemuServer::is_valid_drivename($opt)) {
1121             # cleanup drive path
1122             my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1123             raise_param_exc({ $opt => "unable to parse drive options" }) if !$drive;
1124             PVE::QemuServer::cleanup_drive_path($opt, $storecfg, $drive);
1125             $check_replication->($drive);
1126             $param->{$opt} = PVE::QemuServer::print_drive($drive);
1127         } elsif ($opt =~ m/^net(\d+)$/) {
1128             # add macaddr
1129             my $net = PVE::QemuServer::parse_net($param->{$opt});
1130             $param->{$opt} = PVE::QemuServer::print_net($net);
1131         } elsif ($opt eq 'vmgenid') {
1132             if ($param->{$opt} eq '1') {
1133                 $param->{$opt} = PVE::QemuServer::generate_uuid();
1134             }
1135         } elsif ($opt eq 'hookscript') {
1136             eval { PVE::GuestHelpers::check_hookscript($param->{$opt}, $storecfg); };
1137             raise_param_exc({ $opt => $@ }) if $@;
1138         }
1139     }
1140
1141     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [@delete]);
1142
1143     &$check_vm_modify_config_perm($rpcenv, $authuser, $vmid, undef, [keys %$param]);
1144
1145     &$check_storage_access($rpcenv, $authuser, $storecfg, $vmid, $param);
1146
1147     my $updatefn =  sub {
1148
1149         my $conf = PVE::QemuConfig->load_config($vmid);
1150
1151         die "checksum missmatch (file change by other user?)\n"
1152             if $digest && $digest ne $conf->{digest};
1153
1154         &$check_cpu_model_access($rpcenv, $authuser, $param, $conf);
1155
1156         # FIXME: 'suspended' lock should probabyl be a state or "weak" lock?!
1157         if (scalar(@delete) && grep { $_ eq 'vmstate'} @delete) {
1158             if (defined($conf->{lock}) && $conf->{lock} eq 'suspended') {
1159                 delete $conf->{lock}; # for check lock check, not written out
1160                 push @delete, 'lock'; # this is the real deal to write it out
1161             }
1162             push @delete, 'runningmachine' if $conf->{runningmachine};
1163             push @delete, 'runningcpu' if $conf->{runningcpu};
1164         }
1165
1166         PVE::QemuConfig->check_lock($conf) if !$skiplock;
1167
1168         foreach my $opt (keys %$revert) {
1169             if (defined($conf->{$opt})) {
1170                 $param->{$opt} = $conf->{$opt};
1171             } elsif (defined($conf->{pending}->{$opt})) {
1172                 push @delete, $opt;
1173             }
1174         }
1175
1176         if ($param->{memory} || defined($param->{balloon})) {
1177             my $maxmem = $param->{memory} || $conf->{pending}->{memory} || $conf->{memory} || $defaults->{memory};
1178             my $balloon = defined($param->{balloon}) ? $param->{balloon} : $conf->{pending}->{balloon} || $conf->{balloon};
1179
1180             die "balloon value too large (must be smaller than assigned memory)\n"
1181                 if $balloon && $balloon > $maxmem;
1182         }
1183
1184         PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: " . join (' ', @paramarr));
1185
1186         my $worker = sub {
1187
1188             print "update VM $vmid: " . join (' ', @paramarr) . "\n";
1189
1190             # write updates to pending section
1191
1192             my $modified = {}; # record what $option we modify
1193
1194             my @bootorder;
1195             if (my $boot = $conf->{boot}) {
1196                 my $bootcfg = PVE::JSONSchema::parse_property_string('pve-qm-boot', $boot);
1197                 @bootorder = PVE::Tools::split_list($bootcfg->{order}) if $bootcfg && $bootcfg->{order};
1198             }
1199             my $bootorder_deleted = grep {$_ eq 'bootorder'} @delete;
1200
1201             foreach my $opt (@delete) {
1202                 $modified->{$opt} = 1;
1203                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1204
1205                 # value of what we want to delete, independent if pending or not
1206                 my $val = $conf->{$opt} // $conf->{pending}->{$opt};
1207                 if (!defined($val)) {
1208                     warn "cannot delete '$opt' - not set in current configuration!\n";
1209                     $modified->{$opt} = 0;
1210                     next;
1211                 }
1212                 my $is_pending_val = defined($conf->{pending}->{$opt});
1213                 delete $conf->{pending}->{$opt};
1214
1215                 # remove from bootorder if necessary
1216                 if (!$bootorder_deleted && @bootorder && grep {$_ eq $opt} @bootorder) {
1217                     @bootorder = grep {$_ ne $opt} @bootorder;
1218                     $conf->{pending}->{boot} = PVE::QemuServer::print_bootorder(\@bootorder);
1219                     $modified->{boot} = 1;
1220                 }
1221
1222                 if ($opt =~ m/^unused/) {
1223                     my $drive = PVE::QemuServer::parse_drive($opt, $val);
1224                     PVE::QemuConfig->check_protection($conf, "can't remove unused disk '$drive->{file}'");
1225                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1226                     if (PVE::QemuServer::try_deallocate_drive($storecfg, $vmid, $conf, $opt, $drive, $rpcenv, $authuser)) {
1227                         delete $conf->{$opt};
1228                         PVE::QemuConfig->write_config($vmid, $conf);
1229                     }
1230                 } elsif ($opt eq 'vmstate') {
1231                     PVE::QemuConfig->check_protection($conf, "can't remove vmstate '$val'");
1232                     if (PVE::QemuServer::try_deallocate_drive($storecfg, $vmid, $conf, $opt, { file => $val }, $rpcenv, $authuser, 1)) {
1233                         delete $conf->{$opt};
1234                         PVE::QemuConfig->write_config($vmid, $conf);
1235                     }
1236                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
1237                     PVE::QemuConfig->check_protection($conf, "can't remove drive '$opt'");
1238                     $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1239                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $val))
1240                         if $is_pending_val;
1241                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1242                     PVE::QemuConfig->write_config($vmid, $conf);
1243                 } elsif ($opt =~ m/^serial\d+$/) {
1244                     if ($val eq 'socket') {
1245                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1246                     } elsif ($authuser ne 'root@pam') {
1247                         die "only root can delete '$opt' config for real devices\n";
1248                     }
1249                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1250                     PVE::QemuConfig->write_config($vmid, $conf);
1251                 } elsif ($opt =~ m/^usb\d+$/) {
1252                     if ($val =~ m/spice/) {
1253                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1254                     } elsif ($authuser ne 'root@pam') {
1255                         die "only root can delete '$opt' config for real devices\n";
1256                     }
1257                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1258                     PVE::QemuConfig->write_config($vmid, $conf);
1259                 } else {
1260                     PVE::QemuConfig->add_to_pending_delete($conf, $opt, $force);
1261                     PVE::QemuConfig->write_config($vmid, $conf);
1262                 }
1263             }
1264
1265             foreach my $opt (keys %$param) { # add/change
1266                 $modified->{$opt} = 1;
1267                 $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1268                 next if defined($conf->{pending}->{$opt}) && ($param->{$opt} eq $conf->{pending}->{$opt}); # skip if nothing changed
1269
1270                 my $arch = PVE::QemuServer::get_vm_arch($conf);
1271
1272                 if (PVE::QemuServer::is_valid_drivename($opt)) {
1273                     my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt});
1274                     # FIXME: cloudinit: CDROM or Disk?
1275                     if (PVE::QemuServer::drive_is_cdrom($drive)) { # CDROM
1276                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.CDROM']);
1277                     } else {
1278                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
1279                     }
1280                     PVE::QemuServer::vmconfig_register_unused_drive($storecfg, $vmid, $conf, PVE::QemuServer::parse_drive($opt, $conf->{pending}->{$opt}))
1281                         if defined($conf->{pending}->{$opt});
1282
1283                     &$create_disks($rpcenv, $authuser, $conf->{pending}, $arch, $storecfg, $vmid, undef, {$opt => $param->{$opt}});
1284                 } elsif ($opt =~ m/^serial\d+/) {
1285                     if ((!defined($conf->{$opt}) || $conf->{$opt} eq 'socket') && $param->{$opt} eq 'socket') {
1286                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1287                     } elsif ($authuser ne 'root@pam') {
1288                         die "only root can modify '$opt' config for real devices\n";
1289                     }
1290                     $conf->{pending}->{$opt} = $param->{$opt};
1291                 } elsif ($opt =~ m/^usb\d+/) {
1292                     if ((!defined($conf->{$opt}) || $conf->{$opt} =~ m/spice/) && $param->{$opt} =~ m/spice/) {
1293                         $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.HWType']);
1294                     } elsif ($authuser ne 'root@pam') {
1295                         die "only root can modify '$opt' config for real devices\n";
1296                     }
1297                     $conf->{pending}->{$opt} = $param->{$opt};
1298                 } else {
1299                     $conf->{pending}->{$opt} = $param->{$opt};
1300
1301                     if ($opt eq 'boot') {
1302                         my $new_bootcfg = PVE::JSONSchema::parse_property_string('pve-qm-boot', $param->{$opt});
1303                         if ($new_bootcfg->{order}) {
1304                             my @devs = PVE::Tools::split_list($new_bootcfg->{order});
1305                             for my $dev (@devs) {
1306                                 my $exists = $conf->{$dev} || $conf->{pending}->{$dev};
1307                                 my $deleted = grep {$_ eq $dev} @delete;
1308                                 die "invalid bootorder: device '$dev' does not exist'\n"
1309                                     if !$exists || $deleted;
1310                             }
1311
1312                             # remove legacy boot order settings if new one set
1313                             $conf->{pending}->{$opt} = PVE::QemuServer::print_bootorder(\@devs);
1314                             PVE::QemuConfig->add_to_pending_delete($conf, "bootdisk")
1315                                 if $conf->{bootdisk};
1316                         }
1317                     }
1318                 }
1319                 PVE::QemuConfig->remove_from_pending_delete($conf, $opt);
1320                 PVE::QemuConfig->write_config($vmid, $conf);
1321             }
1322
1323             # remove pending changes when nothing changed
1324             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1325             my $changes = PVE::QemuConfig->cleanup_pending($conf);
1326             PVE::QemuConfig->write_config($vmid, $conf) if $changes;
1327
1328             return if !scalar(keys %{$conf->{pending}});
1329
1330             my $running = PVE::QemuServer::check_running($vmid);
1331
1332             # apply pending changes
1333
1334             $conf = PVE::QemuConfig->load_config($vmid); # update/reload
1335
1336             my $errors = {};
1337             if ($running) {
1338                 PVE::QemuServer::vmconfig_hotplug_pending($vmid, $conf, $storecfg, $modified, $errors);
1339             } else {
1340                 PVE::QemuServer::vmconfig_apply_pending($vmid, $conf, $storecfg, $running, $errors);
1341             }
1342             raise_param_exc($errors) if scalar(keys %$errors);
1343
1344             return;
1345         };
1346
1347         if ($sync) {
1348             &$worker();
1349             return;
1350         } else {
1351             my $upid = $rpcenv->fork_worker('qmconfig', $vmid, $authuser, $worker);
1352
1353             if ($background_delay) {
1354
1355                 # Note: It would be better to do that in the Event based HTTPServer
1356                 # to avoid blocking call to sleep.
1357
1358                 my $end_time = time() + $background_delay;
1359
1360                 my $task = PVE::Tools::upid_decode($upid);
1361
1362                 my $running = 1;
1363                 while (time() < $end_time) {
1364                     $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
1365                     last if !$running;
1366                     sleep(1); # this gets interrupted when child process ends
1367                 }
1368
1369                 if (!$running) {
1370                     my $status = PVE::Tools::upid_read_status($upid);
1371                     return if $status eq 'OK';
1372                     die $status;
1373                 }
1374             }
1375
1376             return $upid;
1377         }
1378     };
1379
1380     return PVE::QemuConfig->lock_config($vmid, $updatefn);
1381 };
1382
1383 my $vm_config_perm_list = [
1384             'VM.Config.Disk',
1385             'VM.Config.CDROM',
1386             'VM.Config.CPU',
1387             'VM.Config.Memory',
1388             'VM.Config.Network',
1389             'VM.Config.HWType',
1390             'VM.Config.Options',
1391             'VM.Config.Cloudinit',
1392     ];
1393
1394 __PACKAGE__->register_method({
1395     name => 'update_vm_async',
1396     path => '{vmid}/config',
1397     method => 'POST',
1398     protected => 1,
1399     proxyto => 'node',
1400     description => "Set virtual machine options (asynchrounous API).",
1401     permissions => {
1402         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1403     },
1404     parameters => {
1405         additionalProperties => 0,
1406         properties => PVE::QemuServer::json_config_properties(
1407             {
1408                 node => get_standard_option('pve-node'),
1409                 vmid => get_standard_option('pve-vmid'),
1410                 skiplock => get_standard_option('skiplock'),
1411                 delete => {
1412                     type => 'string', format => 'pve-configid-list',
1413                     description => "A list of settings you want to delete.",
1414                     optional => 1,
1415                 },
1416                 revert => {
1417                     type => 'string', format => 'pve-configid-list',
1418                     description => "Revert a pending change.",
1419                     optional => 1,
1420                 },
1421                 force => {
1422                     type => 'boolean',
1423                     description => $opt_force_description,
1424                     optional => 1,
1425                     requires => 'delete',
1426                 },
1427                 digest => {
1428                     type => 'string',
1429                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1430                     maxLength => 40,
1431                     optional => 1,
1432                 },
1433                 background_delay => {
1434                     type => 'integer',
1435                     description => "Time to wait for the task to finish. We return 'null' if the task finish within that time.",
1436                     minimum => 1,
1437                     maximum => 30,
1438                     optional => 1,
1439                 },
1440             }),
1441     },
1442     returns => {
1443         type => 'string',
1444         optional => 1,
1445     },
1446     code => $update_vm_api,
1447 });
1448
1449 __PACKAGE__->register_method({
1450     name => 'update_vm',
1451     path => '{vmid}/config',
1452     method => 'PUT',
1453     protected => 1,
1454     proxyto => 'node',
1455     description => "Set virtual machine options (synchrounous API) - You should consider using the POST method instead for any actions involving hotplug or storage allocation.",
1456     permissions => {
1457         check => ['perm', '/vms/{vmid}', $vm_config_perm_list, any => 1],
1458     },
1459     parameters => {
1460         additionalProperties => 0,
1461         properties => PVE::QemuServer::json_config_properties(
1462             {
1463                 node => get_standard_option('pve-node'),
1464                 vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1465                 skiplock => get_standard_option('skiplock'),
1466                 delete => {
1467                     type => 'string', format => 'pve-configid-list',
1468                     description => "A list of settings you want to delete.",
1469                     optional => 1,
1470                 },
1471                 revert => {
1472                     type => 'string', format => 'pve-configid-list',
1473                     description => "Revert a pending change.",
1474                     optional => 1,
1475                 },
1476                 force => {
1477                     type => 'boolean',
1478                     description => $opt_force_description,
1479                     optional => 1,
1480                     requires => 'delete',
1481                 },
1482                 digest => {
1483                     type => 'string',
1484                     description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1485                     maxLength => 40,
1486                     optional => 1,
1487                 },
1488             }),
1489     },
1490     returns => { type => 'null' },
1491     code => sub {
1492         my ($param) = @_;
1493         &$update_vm_api($param, 1);
1494         return;
1495     }
1496 });
1497
1498 __PACKAGE__->register_method({
1499     name => 'destroy_vm',
1500     path => '{vmid}',
1501     method => 'DELETE',
1502     protected => 1,
1503     proxyto => 'node',
1504     description => "Destroy the VM and  all used/owned volumes. Removes any VM specific permissions"
1505         ." and firewall rules",
1506     permissions => {
1507         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
1508     },
1509     parameters => {
1510         additionalProperties => 0,
1511         properties => {
1512             node => get_standard_option('pve-node'),
1513             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
1514             skiplock => get_standard_option('skiplock'),
1515             purge => {
1516                 type => 'boolean',
1517                 description => "Remove VMID from configurations, like backup & replication jobs and HA.",
1518                 optional => 1,
1519             },
1520         },
1521     },
1522     returns => {
1523         type => 'string',
1524     },
1525     code => sub {
1526         my ($param) = @_;
1527
1528         my $rpcenv = PVE::RPCEnvironment::get();
1529         my $authuser = $rpcenv->get_user();
1530         my $vmid = $param->{vmid};
1531
1532         my $skiplock = $param->{skiplock};
1533         raise_param_exc({ skiplock => "Only root may use this option." })
1534             if $skiplock && $authuser ne 'root@pam';
1535
1536         my $early_checks = sub {
1537             # test if VM exists
1538             my $conf = PVE::QemuConfig->load_config($vmid);
1539             PVE::QemuConfig->check_protection($conf, "can't remove VM $vmid");
1540
1541             my $ha_managed = PVE::HA::Config::service_is_configured("vm:$vmid");
1542
1543             if (!$param->{purge}) {
1544                 die "unable to remove VM $vmid - used in HA resources and purge parameter not set.\n"
1545                     if $ha_managed;
1546                 # don't allow destroy if with replication jobs but no purge param
1547                 my $repl_conf = PVE::ReplicationConfig->new();
1548                 $repl_conf->check_for_existing_jobs($vmid);
1549             }
1550
1551             die "VM $vmid is running - destroy failed\n"
1552                 if PVE::QemuServer::check_running($vmid);
1553
1554             return $ha_managed;
1555         };
1556
1557         $early_checks->();
1558
1559         my $realcmd = sub {
1560             my $upid = shift;
1561
1562             my $storecfg = PVE::Storage::config();
1563
1564             syslog('info', "destroy VM $vmid: $upid\n");
1565             PVE::QemuConfig->lock_config($vmid, sub {
1566                 # repeat, config might have changed
1567                 my $ha_managed = $early_checks->();
1568
1569                 PVE::QemuServer::destroy_vm($storecfg, $vmid, $skiplock, { lock => 'destroyed' });
1570
1571                 PVE::AccessControl::remove_vm_access($vmid);
1572                 PVE::Firewall::remove_vmfw_conf($vmid);
1573                 if ($param->{purge}) {
1574                     print "purging VM $vmid from related configurations..\n";
1575                     PVE::ReplicationConfig::remove_vmid_jobs($vmid);
1576                     PVE::VZDump::Plugin::remove_vmid_from_backup_jobs($vmid);
1577
1578                     if ($ha_managed) {
1579                         PVE::HA::Config::delete_service_from_config("vm:$vmid");
1580                         print "NOTE: removed VM $vmid from HA resource configuration.\n";
1581                     }
1582                 }
1583
1584                 # only now remove the zombie config, else we can have reuse race
1585                 PVE::QemuConfig->destroy_config($vmid);
1586             });
1587         };
1588
1589         return $rpcenv->fork_worker('qmdestroy', $vmid, $authuser, $realcmd);
1590     }});
1591
1592 __PACKAGE__->register_method({
1593     name => 'unlink',
1594     path => '{vmid}/unlink',
1595     method => 'PUT',
1596     protected => 1,
1597     proxyto => 'node',
1598     description => "Unlink/delete disk images.",
1599     permissions => {
1600         check => [ 'perm', '/vms/{vmid}', ['VM.Config.Disk']],
1601     },
1602     parameters => {
1603         additionalProperties => 0,
1604         properties => {
1605             node => get_standard_option('pve-node'),
1606             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
1607             idlist => {
1608                 type => 'string', format => 'pve-configid-list',
1609                 description => "A list of disk IDs you want to delete.",
1610             },
1611             force => {
1612                 type => 'boolean',
1613                 description => $opt_force_description,
1614                 optional => 1,
1615             },
1616         },
1617     },
1618     returns => { type => 'null'},
1619     code => sub {
1620         my ($param) = @_;
1621
1622         $param->{delete} = extract_param($param, 'idlist');
1623
1624         __PACKAGE__->update_vm($param);
1625
1626         return;
1627     }});
1628
1629 # uses good entropy, each char is limited to 6 bit to get printable chars simply
1630 my $gen_rand_chars = sub {
1631     my ($length) = @_;
1632
1633     die "invalid length $length" if $length < 1;
1634
1635     my $min = ord('!'); # first printable ascii
1636
1637     my $rand_bytes = Crypt::OpenSSL::Random::random_bytes($length);
1638     die "failed to generate random bytes!\n"
1639       if !$rand_bytes;
1640
1641     my $str = join('', map { chr((ord($_) & 0x3F) + $min) } split('', $rand_bytes));
1642
1643     return $str;
1644 };
1645
1646 my $sslcert;
1647
1648 __PACKAGE__->register_method({
1649     name => 'vncproxy',
1650     path => '{vmid}/vncproxy',
1651     method => 'POST',
1652     protected => 1,
1653     permissions => {
1654         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1655     },
1656     description => "Creates a TCP VNC proxy connections.",
1657     parameters => {
1658         additionalProperties => 0,
1659         properties => {
1660             node => get_standard_option('pve-node'),
1661             vmid => get_standard_option('pve-vmid'),
1662             websocket => {
1663                 optional => 1,
1664                 type => 'boolean',
1665                 description => "starts websockify instead of vncproxy",
1666             },
1667             'generate-password' => {
1668                 optional => 1,
1669                 type => 'boolean',
1670                 default => 0,
1671                 description => "Generates a random password to be used as ticket instead of the API ticket.",
1672             },
1673         },
1674     },
1675     returns => {
1676         additionalProperties => 0,
1677         properties => {
1678             user => { type => 'string' },
1679             ticket => { type => 'string' },
1680             password => {
1681                 optional => 1,
1682                 description => "Returned if requested with 'generate-password' param."
1683                     ." Consists of printable ASCII characters ('!' .. '~').",
1684                 type => 'string',
1685             },
1686             cert => { type => 'string' },
1687             port => { type => 'integer' },
1688             upid => { type => 'string' },
1689         },
1690     },
1691     code => sub {
1692         my ($param) = @_;
1693
1694         my $rpcenv = PVE::RPCEnvironment::get();
1695
1696         my $authuser = $rpcenv->get_user();
1697
1698         my $vmid = $param->{vmid};
1699         my $node = $param->{node};
1700         my $websocket = $param->{websocket};
1701
1702         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1703
1704         my $serial;
1705         if ($conf->{vga}) {
1706             my $vga = PVE::QemuServer::parse_vga($conf->{vga});
1707             $serial = $vga->{type} if $vga->{type} =~ m/^serial\d+$/;
1708         }
1709
1710         my $authpath = "/vms/$vmid";
1711
1712         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1713         my $password = $ticket;
1714         if ($param->{'generate-password'}) {
1715             $password = $gen_rand_chars->(8);
1716         }
1717
1718         $sslcert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192)
1719             if !$sslcert;
1720
1721         my $family;
1722         my $remcmd = [];
1723
1724         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1725             (undef, $family) = PVE::Cluster::remote_node_ip($node);
1726             my $sshinfo = PVE::SSHInfo::get_ssh_info($node);
1727             # NOTE: kvm VNC traffic is already TLS encrypted or is known unsecure
1728             $remcmd = PVE::SSHInfo::ssh_info_to_command($sshinfo, defined($serial) ? '-t' : '-T');
1729         } else {
1730             $family = PVE::Tools::get_host_address_family($node);
1731         }
1732
1733         my $port = PVE::Tools::next_vnc_port($family);
1734
1735         my $timeout = 10;
1736
1737         my $realcmd = sub {
1738             my $upid = shift;
1739
1740             syslog('info', "starting vnc proxy $upid\n");
1741
1742             my $cmd;
1743
1744             if (defined($serial)) {
1745
1746                 my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-iface', $serial, '-escape', '0' ];
1747
1748                 $cmd = ['/usr/bin/vncterm', '-rfbport', $port,
1749                         '-timeout', $timeout, '-authpath', $authpath,
1750                         '-perm', 'Sys.Console'];
1751
1752                 if ($param->{websocket}) {
1753                     $ENV{PVE_VNC_TICKET} = $password; # pass ticket to vncterm
1754                     push @$cmd, '-notls', '-listen', 'localhost';
1755                 }
1756
1757                 push @$cmd, '-c', @$remcmd, @$termcmd;
1758
1759                 PVE::Tools::run_command($cmd);
1760
1761             } else {
1762
1763                 $ENV{LC_PVE_TICKET} = $password if $websocket; # set ticket with "qm vncproxy"
1764
1765                 $cmd = [@$remcmd, "/usr/sbin/qm", 'vncproxy', $vmid];
1766
1767                 my $sock = IO::Socket::IP->new(
1768                     ReuseAddr => 1,
1769                     Listen => 1,
1770                     LocalPort => $port,
1771                     Proto => 'tcp',
1772                     GetAddrInfoFlags => 0,
1773                 ) or die "failed to create socket: $!\n";
1774                 # Inside the worker we shouldn't have any previous alarms
1775                 # running anyway...:
1776                 alarm(0);
1777                 local $SIG{ALRM} = sub { die "connection timed out\n" };
1778                 alarm $timeout;
1779                 accept(my $cli, $sock) or die "connection failed: $!\n";
1780                 alarm(0);
1781                 close($sock);
1782                 if (PVE::Tools::run_command($cmd,
1783                     output => '>&'.fileno($cli),
1784                     input => '<&'.fileno($cli),
1785                     noerr => 1) != 0)
1786                 {
1787                     die "Failed to run vncproxy.\n";
1788                 }
1789             }
1790
1791             return;
1792         };
1793
1794         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1795
1796         PVE::Tools::wait_for_vnc_port($port);
1797
1798         my $res = {
1799             user => $authuser,
1800             ticket => $ticket,
1801             port => $port,
1802             upid => $upid,
1803             cert => $sslcert,
1804         };
1805         $res->{password} = $password if $param->{'generate-password'};
1806
1807         return $res;
1808     }});
1809
1810 __PACKAGE__->register_method({
1811     name => 'termproxy',
1812     path => '{vmid}/termproxy',
1813     method => 'POST',
1814     protected => 1,
1815     permissions => {
1816         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1817     },
1818     description => "Creates a TCP proxy connections.",
1819     parameters => {
1820         additionalProperties => 0,
1821         properties => {
1822             node => get_standard_option('pve-node'),
1823             vmid => get_standard_option('pve-vmid'),
1824             serial=> {
1825                 optional => 1,
1826                 type => 'string',
1827                 enum => [qw(serial0 serial1 serial2 serial3)],
1828                 description => "opens a serial terminal (defaults to display)",
1829             },
1830         },
1831     },
1832     returns => {
1833         additionalProperties => 0,
1834         properties => {
1835             user => { type => 'string' },
1836             ticket => { type => 'string' },
1837             port => { type => 'integer' },
1838             upid => { type => 'string' },
1839         },
1840     },
1841     code => sub {
1842         my ($param) = @_;
1843
1844         my $rpcenv = PVE::RPCEnvironment::get();
1845
1846         my $authuser = $rpcenv->get_user();
1847
1848         my $vmid = $param->{vmid};
1849         my $node = $param->{node};
1850         my $serial = $param->{serial};
1851
1852         my $conf = PVE::QemuConfig->load_config($vmid, $node); # check if VM exists
1853
1854         if (!defined($serial)) {
1855             if ($conf->{vga}) {
1856                 my $vga = PVE::QemuServer::parse_vga($conf->{vga});
1857                 $serial = $vga->{type} if $vga->{type} =~ m/^serial\d+$/;
1858             }
1859         }
1860
1861         my $authpath = "/vms/$vmid";
1862
1863         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
1864
1865         my $family;
1866         my $remcmd = [];
1867
1868         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
1869             (undef, $family) = PVE::Cluster::remote_node_ip($node);
1870             my $sshinfo = PVE::SSHInfo::get_ssh_info($node);
1871             $remcmd = PVE::SSHInfo::ssh_info_to_command($sshinfo, '-t');
1872             push @$remcmd, '--';
1873         } else {
1874             $family = PVE::Tools::get_host_address_family($node);
1875         }
1876
1877         my $port = PVE::Tools::next_vnc_port($family);
1878
1879         my $termcmd = [ '/usr/sbin/qm', 'terminal', $vmid, '-escape', '0'];
1880         push @$termcmd, '-iface', $serial if $serial;
1881
1882         my $realcmd = sub {
1883             my $upid = shift;
1884
1885             syslog('info', "starting qemu termproxy $upid\n");
1886
1887             my $cmd = ['/usr/bin/termproxy', $port, '--path', $authpath,
1888                        '--perm', 'VM.Console', '--'];
1889             push @$cmd, @$remcmd, @$termcmd;
1890
1891             PVE::Tools::run_command($cmd);
1892         };
1893
1894         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
1895
1896         PVE::Tools::wait_for_vnc_port($port);
1897
1898         return {
1899             user => $authuser,
1900             ticket => $ticket,
1901             port => $port,
1902             upid => $upid,
1903         };
1904     }});
1905
1906 __PACKAGE__->register_method({
1907     name => 'vncwebsocket',
1908     path => '{vmid}/vncwebsocket',
1909     method => 'GET',
1910     permissions => {
1911         description => "You also need to pass a valid ticket (vncticket).",
1912         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1913     },
1914     description => "Opens a weksocket for VNC traffic.",
1915     parameters => {
1916         additionalProperties => 0,
1917         properties => {
1918             node => get_standard_option('pve-node'),
1919             vmid => get_standard_option('pve-vmid'),
1920             vncticket => {
1921                 description => "Ticket from previous call to vncproxy.",
1922                 type => 'string',
1923                 maxLength => 512,
1924             },
1925             port => {
1926                 description => "Port number returned by previous vncproxy call.",
1927                 type => 'integer',
1928                 minimum => 5900,
1929                 maximum => 5999,
1930             },
1931         },
1932     },
1933     returns => {
1934         type => "object",
1935         properties => {
1936             port => { type => 'string' },
1937         },
1938     },
1939     code => sub {
1940         my ($param) = @_;
1941
1942         my $rpcenv = PVE::RPCEnvironment::get();
1943
1944         my $authuser = $rpcenv->get_user();
1945
1946         my $vmid = $param->{vmid};
1947         my $node = $param->{node};
1948
1949         my $authpath = "/vms/$vmid";
1950
1951         PVE::AccessControl::verify_vnc_ticket($param->{vncticket}, $authuser, $authpath);
1952
1953         my $conf = PVE::QemuConfig->load_config($vmid, $node); # VM exists ?
1954
1955         # Note: VNC ports are acessible from outside, so we do not gain any
1956         # security if we verify that $param->{port} belongs to VM $vmid. This
1957         # check is done by verifying the VNC ticket (inside VNC protocol).
1958
1959         my $port = $param->{port};
1960
1961         return { port => $port };
1962     }});
1963
1964 __PACKAGE__->register_method({
1965     name => 'spiceproxy',
1966     path => '{vmid}/spiceproxy',
1967     method => 'POST',
1968     protected => 1,
1969     proxyto => 'node',
1970     permissions => {
1971         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
1972     },
1973     description => "Returns a SPICE configuration to connect to the VM.",
1974     parameters => {
1975         additionalProperties => 0,
1976         properties => {
1977             node => get_standard_option('pve-node'),
1978             vmid => get_standard_option('pve-vmid'),
1979             proxy => get_standard_option('spice-proxy', { optional => 1 }),
1980         },
1981     },
1982     returns => get_standard_option('remote-viewer-config'),
1983     code => sub {
1984         my ($param) = @_;
1985
1986         my $rpcenv = PVE::RPCEnvironment::get();
1987
1988         my $authuser = $rpcenv->get_user();
1989
1990         my $vmid = $param->{vmid};
1991         my $node = $param->{node};
1992         my $proxy = $param->{proxy};
1993
1994         my $conf = PVE::QemuConfig->load_config($vmid, $node);
1995         my $title = "VM $vmid";
1996         $title .= " - ". $conf->{name} if $conf->{name};
1997
1998         my $port = PVE::QemuServer::spice_port($vmid);
1999
2000         my ($ticket, undef, $remote_viewer_config) =
2001             PVE::AccessControl::remote_viewer_config($authuser, $vmid, $node, $proxy, $title, $port);
2002
2003         mon_cmd($vmid, "set_password", protocol => 'spice', password => $ticket);
2004         mon_cmd($vmid, "expire_password", protocol => 'spice', time => "+30");
2005
2006         return $remote_viewer_config;
2007     }});
2008
2009 __PACKAGE__->register_method({
2010     name => 'vmcmdidx',
2011     path => '{vmid}/status',
2012     method => 'GET',
2013     proxyto => 'node',
2014     description => "Directory index",
2015     permissions => {
2016         user => 'all',
2017     },
2018     parameters => {
2019         additionalProperties => 0,
2020         properties => {
2021             node => get_standard_option('pve-node'),
2022             vmid => get_standard_option('pve-vmid'),
2023         },
2024     },
2025     returns => {
2026         type => 'array',
2027         items => {
2028             type => "object",
2029             properties => {
2030                 subdir => { type => 'string' },
2031             },
2032         },
2033         links => [ { rel => 'child', href => "{subdir}" } ],
2034     },
2035     code => sub {
2036         my ($param) = @_;
2037
2038         # test if VM exists
2039         my $conf = PVE::QemuConfig->load_config($param->{vmid});
2040
2041         my $res = [
2042             { subdir => 'current' },
2043             { subdir => 'start' },
2044             { subdir => 'stop' },
2045             { subdir => 'reset' },
2046             { subdir => 'shutdown' },
2047             { subdir => 'suspend' },
2048             { subdir => 'reboot' },
2049             ];
2050
2051         return $res;
2052     }});
2053
2054 __PACKAGE__->register_method({
2055     name => 'vm_status',
2056     path => '{vmid}/status/current',
2057     method => 'GET',
2058     proxyto => 'node',
2059     protected => 1, # qemu pid files are only readable by root
2060     description => "Get virtual machine status.",
2061     permissions => {
2062         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
2063     },
2064     parameters => {
2065         additionalProperties => 0,
2066         properties => {
2067             node => get_standard_option('pve-node'),
2068             vmid => get_standard_option('pve-vmid'),
2069         },
2070     },
2071     returns => {
2072         type => 'object',
2073         properties => {
2074             %$PVE::QemuServer::vmstatus_return_properties,
2075             ha => {
2076                 description => "HA manager service status.",
2077                 type => 'object',
2078             },
2079             spice => {
2080                 description => "Qemu VGA configuration supports spice.",
2081                 type => 'boolean',
2082                 optional => 1,
2083             },
2084             agent => {
2085                 description => "Qemu GuestAgent enabled in config.",
2086                 type => 'boolean',
2087                 optional => 1,
2088             },
2089         },
2090     },
2091     code => sub {
2092         my ($param) = @_;
2093
2094         # test if VM exists
2095         my $conf = PVE::QemuConfig->load_config($param->{vmid});
2096
2097         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid}, 1);
2098         my $status = $vmstatus->{$param->{vmid}};
2099
2100         $status->{ha} = PVE::HA::Config::get_service_status("vm:$param->{vmid}");
2101
2102         $status->{spice} = 1 if PVE::QemuServer::vga_conf_has_spice($conf->{vga});
2103         $status->{agent} = 1 if PVE::QemuServer::get_qga_key($conf, 'enabled');
2104
2105         return $status;
2106     }});
2107
2108 __PACKAGE__->register_method({
2109     name => 'vm_start',
2110     path => '{vmid}/status/start',
2111     method => 'POST',
2112     protected => 1,
2113     proxyto => 'node',
2114     description => "Start virtual machine.",
2115     permissions => {
2116         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2117     },
2118     parameters => {
2119         additionalProperties => 0,
2120         properties => {
2121             node => get_standard_option('pve-node'),
2122             vmid => get_standard_option('pve-vmid',
2123                                         { completion => \&PVE::QemuServer::complete_vmid_stopped }),
2124             skiplock => get_standard_option('skiplock'),
2125             stateuri => get_standard_option('pve-qm-stateuri'),
2126             migratedfrom => get_standard_option('pve-node',{ optional => 1 }),
2127             migration_type => {
2128                 type => 'string',
2129                 enum => ['secure', 'insecure'],
2130                 description => "Migration traffic is encrypted using an SSH " .
2131                   "tunnel by default. On secure, completely private networks " .
2132                   "this can be disabled to increase performance.",
2133                 optional => 1,
2134             },
2135             migration_network => {
2136                 type => 'string', format => 'CIDR',
2137                 description => "CIDR of the (sub) network that is used for migration.",
2138                 optional => 1,
2139             },
2140             machine => get_standard_option('pve-qemu-machine'),
2141             'force-cpu' => {
2142                 description => "Override QEMU's -cpu argument with the given string.",
2143                 type => 'string',
2144                 optional => 1,
2145             },
2146             targetstorage => get_standard_option('pve-targetstorage'),
2147             timeout => {
2148                 description => "Wait maximal timeout seconds.",
2149                 type => 'integer',
2150                 minimum => 0,
2151                 default => 'max(30, vm memory in GiB)',
2152                 optional => 1,
2153             },
2154         },
2155     },
2156     returns => {
2157         type => 'string',
2158     },
2159     code => sub {
2160         my ($param) = @_;
2161
2162         my $rpcenv = PVE::RPCEnvironment::get();
2163         my $authuser = $rpcenv->get_user();
2164
2165         my $node = extract_param($param, 'node');
2166         my $vmid = extract_param($param, 'vmid');
2167         my $timeout = extract_param($param, 'timeout');
2168
2169         my $machine = extract_param($param, 'machine');
2170         my $force_cpu = extract_param($param, 'force-cpu');
2171
2172         my $get_root_param = sub {
2173             my $value = extract_param($param, $_[0]);
2174             raise_param_exc({ "$_[0]" => "Only root may use this option." })
2175                 if $value && $authuser ne 'root@pam';
2176             return $value;
2177         };
2178
2179         my $stateuri = $get_root_param->('stateuri');
2180         my $skiplock = $get_root_param->('skiplock');
2181         my $migratedfrom = $get_root_param->('migratedfrom');
2182         my $migration_type = $get_root_param->('migration_type');
2183         my $migration_network = $get_root_param->('migration_network');
2184         my $targetstorage = $get_root_param->('targetstorage');
2185
2186         my $storagemap;
2187
2188         if ($targetstorage) {
2189             raise_param_exc({ targetstorage => "targetstorage can only by used with migratedfrom." })
2190                 if !$migratedfrom;
2191             $storagemap = eval { PVE::JSONSchema::parse_idmap($targetstorage, 'pve-storage-id') };
2192             raise_param_exc({ targetstorage => "failed to parse storage map: $@" })
2193                 if $@;
2194         }
2195
2196         # read spice ticket from STDIN
2197         my $spice_ticket;
2198         my $nbd_protocol_version = 0;
2199         my $replicated_volumes = {};
2200         if ($stateuri && ($stateuri eq 'tcp' || $stateuri eq 'unix') && $migratedfrom && ($rpcenv->{type} eq 'cli')) {
2201             while (defined(my $line = <STDIN>)) {
2202                 chomp $line;
2203                 if ($line =~ m/^spice_ticket: (.+)$/) {
2204                     $spice_ticket = $1;
2205                 } elsif ($line =~ m/^nbd_protocol_version: (\d+)$/) {
2206                     $nbd_protocol_version = $1;
2207                 } elsif ($line =~ m/^replicated_volume: (.*)$/) {
2208                     $replicated_volumes->{$1} = 1;
2209                 } else {
2210                     # fallback for old source node
2211                     $spice_ticket = $line;
2212                 }
2213             }
2214         }
2215
2216         PVE::Cluster::check_cfs_quorum();
2217
2218         my $storecfg = PVE::Storage::config();
2219
2220         if (PVE::HA::Config::vm_is_ha_managed($vmid) && !$stateuri &&  $rpcenv->{type} ne 'ha') {
2221             my $hacmd = sub {
2222                 my $upid = shift;
2223
2224                 print "Requesting HA start for VM $vmid\n";
2225
2226                 my $cmd = ['ha-manager', 'set',  "vm:$vmid", '--state', 'started'];
2227                 PVE::Tools::run_command($cmd);
2228                 return;
2229             };
2230
2231             return $rpcenv->fork_worker('hastart', $vmid, $authuser, $hacmd);
2232
2233         } else {
2234
2235             my $realcmd = sub {
2236                 my $upid = shift;
2237
2238                 syslog('info', "start VM $vmid: $upid\n");
2239
2240                 my $migrate_opts = {
2241                     migratedfrom => $migratedfrom,
2242                     spice_ticket => $spice_ticket,
2243                     network => $migration_network,
2244                     type => $migration_type,
2245                     storagemap => $storagemap,
2246                     nbd_proto_version => $nbd_protocol_version,
2247                     replicated_volumes => $replicated_volumes,
2248                 };
2249
2250                 my $params = {
2251                     statefile => $stateuri,
2252                     skiplock => $skiplock,
2253                     forcemachine => $machine,
2254                     timeout => $timeout,
2255                     forcecpu => $force_cpu,
2256                 };
2257
2258                 PVE::QemuServer::vm_start($storecfg, $vmid, $params, $migrate_opts);
2259                 return;
2260             };
2261
2262             return $rpcenv->fork_worker('qmstart', $vmid, $authuser, $realcmd);
2263         }
2264     }});
2265
2266 __PACKAGE__->register_method({
2267     name => 'vm_stop',
2268     path => '{vmid}/status/stop',
2269     method => 'POST',
2270     protected => 1,
2271     proxyto => 'node',
2272     description => "Stop virtual machine. The qemu process will exit immediately. This" .
2273         "is akin to pulling the power plug of a running computer and may damage the VM data",
2274     permissions => {
2275         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2276     },
2277     parameters => {
2278         additionalProperties => 0,
2279         properties => {
2280             node => get_standard_option('pve-node'),
2281             vmid => get_standard_option('pve-vmid',
2282                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2283             skiplock => get_standard_option('skiplock'),
2284             migratedfrom => get_standard_option('pve-node', { optional => 1 }),
2285             timeout => {
2286                 description => "Wait maximal timeout seconds.",
2287                 type => 'integer',
2288                 minimum => 0,
2289                 optional => 1,
2290             },
2291             keepActive => {
2292                 description => "Do not deactivate storage volumes.",
2293                 type => 'boolean',
2294                 optional => 1,
2295                 default => 0,
2296             }
2297         },
2298     },
2299     returns => {
2300         type => 'string',
2301     },
2302     code => sub {
2303         my ($param) = @_;
2304
2305         my $rpcenv = PVE::RPCEnvironment::get();
2306         my $authuser = $rpcenv->get_user();
2307
2308         my $node = extract_param($param, 'node');
2309         my $vmid = extract_param($param, 'vmid');
2310
2311         my $skiplock = extract_param($param, 'skiplock');
2312         raise_param_exc({ skiplock => "Only root may use this option." })
2313             if $skiplock && $authuser ne 'root@pam';
2314
2315         my $keepActive = extract_param($param, 'keepActive');
2316         raise_param_exc({ keepActive => "Only root may use this option." })
2317             if $keepActive && $authuser ne 'root@pam';
2318
2319         my $migratedfrom = extract_param($param, 'migratedfrom');
2320         raise_param_exc({ migratedfrom => "Only root may use this option." })
2321             if $migratedfrom && $authuser ne 'root@pam';
2322
2323
2324         my $storecfg = PVE::Storage::config();
2325
2326         if (PVE::HA::Config::vm_is_ha_managed($vmid) && ($rpcenv->{type} ne 'ha') && !defined($migratedfrom)) {
2327
2328             my $hacmd = sub {
2329                 my $upid = shift;
2330
2331                 print "Requesting HA stop for VM $vmid\n";
2332
2333                 my $cmd = ['ha-manager', 'crm-command', 'stop',  "vm:$vmid", '0'];
2334                 PVE::Tools::run_command($cmd);
2335                 return;
2336             };
2337
2338             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2339
2340         } else {
2341             my $realcmd = sub {
2342                 my $upid = shift;
2343
2344                 syslog('info', "stop VM $vmid: $upid\n");
2345
2346                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0,
2347                                          $param->{timeout}, 0, 1, $keepActive, $migratedfrom);
2348                 return;
2349             };
2350
2351             return $rpcenv->fork_worker('qmstop', $vmid, $authuser, $realcmd);
2352         }
2353     }});
2354
2355 __PACKAGE__->register_method({
2356     name => 'vm_reset',
2357     path => '{vmid}/status/reset',
2358     method => 'POST',
2359     protected => 1,
2360     proxyto => 'node',
2361     description => "Reset virtual machine.",
2362     permissions => {
2363         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2364     },
2365     parameters => {
2366         additionalProperties => 0,
2367         properties => {
2368             node => get_standard_option('pve-node'),
2369             vmid => get_standard_option('pve-vmid',
2370                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2371             skiplock => get_standard_option('skiplock'),
2372         },
2373     },
2374     returns => {
2375         type => 'string',
2376     },
2377     code => sub {
2378         my ($param) = @_;
2379
2380         my $rpcenv = PVE::RPCEnvironment::get();
2381
2382         my $authuser = $rpcenv->get_user();
2383
2384         my $node = extract_param($param, 'node');
2385
2386         my $vmid = extract_param($param, 'vmid');
2387
2388         my $skiplock = extract_param($param, 'skiplock');
2389         raise_param_exc({ skiplock => "Only root may use this option." })
2390             if $skiplock && $authuser ne 'root@pam';
2391
2392         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2393
2394         my $realcmd = sub {
2395             my $upid = shift;
2396
2397             PVE::QemuServer::vm_reset($vmid, $skiplock);
2398
2399             return;
2400         };
2401
2402         return $rpcenv->fork_worker('qmreset', $vmid, $authuser, $realcmd);
2403     }});
2404
2405 my sub vm_is_paused {
2406     my ($vmid) = @_;
2407     my $qmpstatus = eval {
2408         PVE::QemuConfig::assert_config_exists_on_node($vmid);
2409         mon_cmd($vmid, "query-status");
2410     };
2411     warn "$@\n" if $@;
2412     return $qmpstatus && $qmpstatus->{status} eq "paused";
2413 }
2414
2415 __PACKAGE__->register_method({
2416     name => 'vm_shutdown',
2417     path => '{vmid}/status/shutdown',
2418     method => 'POST',
2419     protected => 1,
2420     proxyto => 'node',
2421     description => "Shutdown virtual machine. This is similar to pressing the power button on a physical machine." .
2422         "This will send an ACPI event for the guest OS, which should then proceed to a clean shutdown.",
2423     permissions => {
2424         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2425     },
2426     parameters => {
2427         additionalProperties => 0,
2428         properties => {
2429             node => get_standard_option('pve-node'),
2430             vmid => get_standard_option('pve-vmid',
2431                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2432             skiplock => get_standard_option('skiplock'),
2433             timeout => {
2434                 description => "Wait maximal timeout seconds.",
2435                 type => 'integer',
2436                 minimum => 0,
2437                 optional => 1,
2438             },
2439             forceStop => {
2440                 description => "Make sure the VM stops.",
2441                 type => 'boolean',
2442                 optional => 1,
2443                 default => 0,
2444             },
2445             keepActive => {
2446                 description => "Do not deactivate storage volumes.",
2447                 type => 'boolean',
2448                 optional => 1,
2449                 default => 0,
2450             }
2451         },
2452     },
2453     returns => {
2454         type => 'string',
2455     },
2456     code => sub {
2457         my ($param) = @_;
2458
2459         my $rpcenv = PVE::RPCEnvironment::get();
2460         my $authuser = $rpcenv->get_user();
2461
2462         my $node = extract_param($param, 'node');
2463         my $vmid = extract_param($param, 'vmid');
2464
2465         my $skiplock = extract_param($param, 'skiplock');
2466         raise_param_exc({ skiplock => "Only root may use this option." })
2467             if $skiplock && $authuser ne 'root@pam';
2468
2469         my $keepActive = extract_param($param, 'keepActive');
2470         raise_param_exc({ keepActive => "Only root may use this option." })
2471             if $keepActive && $authuser ne 'root@pam';
2472
2473         my $storecfg = PVE::Storage::config();
2474
2475         my $shutdown = 1;
2476
2477         # if vm is paused, do not shutdown (but stop if forceStop = 1)
2478         # otherwise, we will infer a shutdown command, but run into the timeout,
2479         # then when the vm is resumed, it will instantly shutdown
2480         #
2481         # checking the qmp status here to get feedback to the gui/cli/api
2482         # and the status query should not take too long
2483         if (vm_is_paused($vmid)) {
2484             if ($param->{forceStop}) {
2485                 warn "VM is paused - stop instead of shutdown\n";
2486                 $shutdown = 0;
2487             } else {
2488                 die "VM is paused - cannot shutdown\n";
2489             }
2490         }
2491
2492         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
2493
2494             my $timeout = $param->{timeout} // 60;
2495             my $hacmd = sub {
2496                 my $upid = shift;
2497
2498                 print "Requesting HA stop for VM $vmid\n";
2499
2500                 my $cmd = ['ha-manager', 'crm-command', 'stop', "vm:$vmid", "$timeout"];
2501                 PVE::Tools::run_command($cmd);
2502                 return;
2503             };
2504
2505             return $rpcenv->fork_worker('hastop', $vmid, $authuser, $hacmd);
2506
2507         } else {
2508
2509             my $realcmd = sub {
2510                 my $upid = shift;
2511
2512                 syslog('info', "shutdown VM $vmid: $upid\n");
2513
2514                 PVE::QemuServer::vm_stop($storecfg, $vmid, $skiplock, 0, $param->{timeout},
2515                                          $shutdown, $param->{forceStop}, $keepActive);
2516                 return;
2517             };
2518
2519             return $rpcenv->fork_worker('qmshutdown', $vmid, $authuser, $realcmd);
2520         }
2521     }});
2522
2523 __PACKAGE__->register_method({
2524     name => 'vm_reboot',
2525     path => '{vmid}/status/reboot',
2526     method => 'POST',
2527     protected => 1,
2528     proxyto => 'node',
2529     description => "Reboot the VM by shutting it down, and starting it again. Applies pending changes.",
2530     permissions => {
2531         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2532     },
2533     parameters => {
2534         additionalProperties => 0,
2535         properties => {
2536             node => get_standard_option('pve-node'),
2537             vmid => get_standard_option('pve-vmid',
2538                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2539             timeout => {
2540                 description => "Wait maximal timeout seconds for the shutdown.",
2541                 type => 'integer',
2542                 minimum => 0,
2543                 optional => 1,
2544             },
2545         },
2546     },
2547     returns => {
2548         type => 'string',
2549     },
2550     code => sub {
2551         my ($param) = @_;
2552
2553         my $rpcenv = PVE::RPCEnvironment::get();
2554         my $authuser = $rpcenv->get_user();
2555
2556         my $node = extract_param($param, 'node');
2557         my $vmid = extract_param($param, 'vmid');
2558
2559         die "VM is paused - cannot shutdown\n" if vm_is_paused($vmid);
2560
2561         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2562
2563         my $realcmd = sub {
2564             my $upid = shift;
2565
2566             syslog('info', "requesting reboot of VM $vmid: $upid\n");
2567             PVE::QemuServer::vm_reboot($vmid, $param->{timeout});
2568             return;
2569         };
2570
2571         return $rpcenv->fork_worker('qmreboot', $vmid, $authuser, $realcmd);
2572     }});
2573
2574 __PACKAGE__->register_method({
2575     name => 'vm_suspend',
2576     path => '{vmid}/status/suspend',
2577     method => 'POST',
2578     protected => 1,
2579     proxyto => 'node',
2580     description => "Suspend virtual machine.",
2581     permissions => {
2582         description => "You need 'VM.PowerMgmt' on /vms/{vmid}, and if you have set 'todisk',".
2583             " you need also 'VM.Config.Disk' on /vms/{vmid} and 'Datastore.AllocateSpace'".
2584             " on the storage for the vmstate.",
2585         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2586     },
2587     parameters => {
2588         additionalProperties => 0,
2589         properties => {
2590             node => get_standard_option('pve-node'),
2591             vmid => get_standard_option('pve-vmid',
2592                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2593             skiplock => get_standard_option('skiplock'),
2594             todisk => {
2595                 type => 'boolean',
2596                 default => 0,
2597                 optional => 1,
2598                 description => 'If set, suspends the VM to disk. Will be resumed on next VM start.',
2599             },
2600             statestorage => get_standard_option('pve-storage-id', {
2601                 description => "The storage for the VM state",
2602                 requires => 'todisk',
2603                 optional => 1,
2604                 completion => \&PVE::Storage::complete_storage_enabled,
2605             }),
2606         },
2607     },
2608     returns => {
2609         type => 'string',
2610     },
2611     code => sub {
2612         my ($param) = @_;
2613
2614         my $rpcenv = PVE::RPCEnvironment::get();
2615         my $authuser = $rpcenv->get_user();
2616
2617         my $node = extract_param($param, 'node');
2618         my $vmid = extract_param($param, 'vmid');
2619
2620         my $todisk = extract_param($param, 'todisk') // 0;
2621
2622         my $statestorage = extract_param($param, 'statestorage');
2623
2624         my $skiplock = extract_param($param, 'skiplock');
2625         raise_param_exc({ skiplock => "Only root may use this option." })
2626             if $skiplock && $authuser ne 'root@pam';
2627
2628         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
2629
2630         die "Cannot suspend HA managed VM to disk\n"
2631             if $todisk && PVE::HA::Config::vm_is_ha_managed($vmid);
2632
2633         # early check for storage permission, for better user feedback
2634         if ($todisk) {
2635             $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk']);
2636
2637             if (!$statestorage) {
2638                 # get statestorage from config if none is given
2639                 my $conf = PVE::QemuConfig->load_config($vmid);
2640                 my $storecfg = PVE::Storage::config();
2641                 $statestorage = PVE::QemuServer::find_vmstate_storage($conf, $storecfg);
2642             }
2643
2644             $rpcenv->check($authuser, "/storage/$statestorage", ['Datastore.AllocateSpace']);
2645         }
2646
2647         my $realcmd = sub {
2648             my $upid = shift;
2649
2650             syslog('info', "suspend VM $vmid: $upid\n");
2651
2652             PVE::QemuServer::vm_suspend($vmid, $skiplock, $todisk, $statestorage);
2653
2654             return;
2655         };
2656
2657         my $taskname = $todisk ? 'qmsuspend' : 'qmpause';
2658         return $rpcenv->fork_worker($taskname, $vmid, $authuser, $realcmd);
2659     }});
2660
2661 __PACKAGE__->register_method({
2662     name => 'vm_resume',
2663     path => '{vmid}/status/resume',
2664     method => 'POST',
2665     protected => 1,
2666     proxyto => 'node',
2667     description => "Resume virtual machine.",
2668     permissions => {
2669         check => ['perm', '/vms/{vmid}', [ 'VM.PowerMgmt' ]],
2670     },
2671     parameters => {
2672         additionalProperties => 0,
2673         properties => {
2674             node => get_standard_option('pve-node'),
2675             vmid => get_standard_option('pve-vmid',
2676                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2677             skiplock => get_standard_option('skiplock'),
2678             nocheck => { type => 'boolean', optional => 1 },
2679
2680         },
2681     },
2682     returns => {
2683         type => 'string',
2684     },
2685     code => sub {
2686         my ($param) = @_;
2687
2688         my $rpcenv = PVE::RPCEnvironment::get();
2689
2690         my $authuser = $rpcenv->get_user();
2691
2692         my $node = extract_param($param, 'node');
2693
2694         my $vmid = extract_param($param, 'vmid');
2695
2696         my $skiplock = extract_param($param, 'skiplock');
2697         raise_param_exc({ skiplock => "Only root may use this option." })
2698             if $skiplock && $authuser ne 'root@pam';
2699
2700         my $nocheck = extract_param($param, 'nocheck');
2701         raise_param_exc({ nocheck => "Only root may use this option." })
2702             if $nocheck && $authuser ne 'root@pam';
2703
2704         my $to_disk_suspended;
2705         eval {
2706             PVE::QemuConfig->lock_config($vmid, sub {
2707                 my $conf = PVE::QemuConfig->load_config($vmid);
2708                 $to_disk_suspended = PVE::QemuConfig->has_lock($conf, 'suspended');
2709             });
2710         };
2711
2712         die "VM $vmid not running\n"
2713             if !$to_disk_suspended && !PVE::QemuServer::check_running($vmid, $nocheck);
2714
2715         my $realcmd = sub {
2716             my $upid = shift;
2717
2718             syslog('info', "resume VM $vmid: $upid\n");
2719
2720             if (!$to_disk_suspended) {
2721                 PVE::QemuServer::vm_resume($vmid, $skiplock, $nocheck);
2722             } else {
2723                 my $storecfg = PVE::Storage::config();
2724                 PVE::QemuServer::vm_start($storecfg, $vmid, { skiplock => $skiplock });
2725             }
2726
2727             return;
2728         };
2729
2730         return $rpcenv->fork_worker('qmresume', $vmid, $authuser, $realcmd);
2731     }});
2732
2733 __PACKAGE__->register_method({
2734     name => 'vm_sendkey',
2735     path => '{vmid}/sendkey',
2736     method => 'PUT',
2737     protected => 1,
2738     proxyto => 'node',
2739     description => "Send key event to virtual machine.",
2740     permissions => {
2741         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
2742     },
2743     parameters => {
2744         additionalProperties => 0,
2745         properties => {
2746             node => get_standard_option('pve-node'),
2747             vmid => get_standard_option('pve-vmid',
2748                                         { completion => \&PVE::QemuServer::complete_vmid_running }),
2749             skiplock => get_standard_option('skiplock'),
2750             key => {
2751                 description => "The key (qemu monitor encoding).",
2752                 type => 'string'
2753             }
2754         },
2755     },
2756     returns => { type => 'null'},
2757     code => sub {
2758         my ($param) = @_;
2759
2760         my $rpcenv = PVE::RPCEnvironment::get();
2761
2762         my $authuser = $rpcenv->get_user();
2763
2764         my $node = extract_param($param, 'node');
2765
2766         my $vmid = extract_param($param, 'vmid');
2767
2768         my $skiplock = extract_param($param, 'skiplock');
2769         raise_param_exc({ skiplock => "Only root may use this option." })
2770             if $skiplock && $authuser ne 'root@pam';
2771
2772         PVE::QemuServer::vm_sendkey($vmid, $skiplock, $param->{key});
2773
2774         return;
2775     }});
2776
2777 __PACKAGE__->register_method({
2778     name => 'vm_feature',
2779     path => '{vmid}/feature',
2780     method => 'GET',
2781     proxyto => 'node',
2782     protected => 1,
2783     description => "Check if feature for virtual machine is available.",
2784     permissions => {
2785         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
2786     },
2787     parameters => {
2788         additionalProperties => 0,
2789         properties => {
2790             node => get_standard_option('pve-node'),
2791             vmid => get_standard_option('pve-vmid'),
2792             feature => {
2793                 description => "Feature to check.",
2794                 type => 'string',
2795                 enum => [ 'snapshot', 'clone', 'copy' ],
2796             },
2797             snapname => get_standard_option('pve-snapshot-name', {
2798                 optional => 1,
2799             }),
2800         },
2801     },
2802     returns => {
2803         type => "object",
2804         properties => {
2805             hasFeature => { type => 'boolean' },
2806             nodes => {
2807                 type => 'array',
2808                 items => { type => 'string' },
2809             }
2810         },
2811     },
2812     code => sub {
2813         my ($param) = @_;
2814
2815         my $node = extract_param($param, 'node');
2816
2817         my $vmid = extract_param($param, 'vmid');
2818
2819         my $snapname = extract_param($param, 'snapname');
2820
2821         my $feature = extract_param($param, 'feature');
2822
2823         my $running = PVE::QemuServer::check_running($vmid);
2824
2825         my $conf = PVE::QemuConfig->load_config($vmid);
2826
2827         if($snapname){
2828             my $snap = $conf->{snapshots}->{$snapname};
2829             die "snapshot '$snapname' does not exist\n" if !defined($snap);
2830             $conf = $snap;
2831         }
2832         my $storecfg = PVE::Storage::config();
2833
2834         my $nodelist = PVE::QemuServer::shared_nodes($conf, $storecfg);
2835         my $hasFeature = PVE::QemuConfig->has_feature($feature, $conf, $storecfg, $snapname, $running);
2836
2837         return {
2838             hasFeature => $hasFeature,
2839             nodes => [ keys %$nodelist ],
2840         };
2841     }});
2842
2843 __PACKAGE__->register_method({
2844     name => 'clone_vm',
2845     path => '{vmid}/clone',
2846     method => 'POST',
2847     protected => 1,
2848     proxyto => 'node',
2849     description => "Create a copy of virtual machine/template.",
2850     permissions => {
2851         description => "You need 'VM.Clone' permissions on /vms/{vmid}, and 'VM.Allocate' permissions " .
2852             "on /vms/{newid} (or on the VM pool /pool/{pool}). You also need " .
2853             "'Datastore.AllocateSpace' on any used storage.",
2854         check =>
2855         [ 'and',
2856           ['perm', '/vms/{vmid}', [ 'VM.Clone' ]],
2857           [ 'or',
2858             [ 'perm', '/vms/{newid}', ['VM.Allocate']],
2859             [ 'perm', '/pool/{pool}', ['VM.Allocate'], require_param => 'pool'],
2860           ],
2861         ]
2862     },
2863     parameters => {
2864         additionalProperties => 0,
2865         properties => {
2866             node => get_standard_option('pve-node'),
2867             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
2868             newid => get_standard_option('pve-vmid', {
2869                 completion => \&PVE::Cluster::complete_next_vmid,
2870                 description => 'VMID for the clone.' }),
2871             name => {
2872                 optional => 1,
2873                 type => 'string', format => 'dns-name',
2874                 description => "Set a name for the new VM.",
2875             },
2876             description => {
2877                 optional => 1,
2878                 type => 'string',
2879                 description => "Description for the new VM.",
2880             },
2881             pool => {
2882                 optional => 1,
2883                 type => 'string', format => 'pve-poolid',
2884                 description => "Add the new VM to the specified pool.",
2885             },
2886             snapname => get_standard_option('pve-snapshot-name', {
2887                 optional => 1,
2888             }),
2889             storage => get_standard_option('pve-storage-id', {
2890                 description => "Target storage for full clone.",
2891                 optional => 1,
2892             }),
2893             'format' => {
2894                 description => "Target format for file storage. Only valid for full clone.",
2895                 type => 'string',
2896                 optional => 1,
2897                 enum => [ 'raw', 'qcow2', 'vmdk'],
2898             },
2899             full => {
2900                 optional => 1,
2901                 type => 'boolean',
2902                 description => "Create a full copy of all disks. This is always done when " .
2903                     "you clone a normal VM. For VM templates, we try to create a linked clone by default.",
2904             },
2905             target => get_standard_option('pve-node', {
2906                 description => "Target node. Only allowed if the original VM is on shared storage.",
2907                 optional => 1,
2908             }),
2909             bwlimit => {
2910                 description => "Override I/O bandwidth limit (in KiB/s).",
2911                 optional => 1,
2912                 type => 'integer',
2913                 minimum => '0',
2914                 default => 'clone limit from datacenter or storage config',
2915             },
2916         },
2917     },
2918     returns => {
2919         type => 'string',
2920     },
2921     code => sub {
2922         my ($param) = @_;
2923
2924         my $rpcenv = PVE::RPCEnvironment::get();
2925         my $authuser = $rpcenv->get_user();
2926
2927         my $node = extract_param($param, 'node');
2928         my $vmid = extract_param($param, 'vmid');
2929         my $newid = extract_param($param, 'newid');
2930         my $pool = extract_param($param, 'pool');
2931         $rpcenv->check_pool_exist($pool) if defined($pool);
2932
2933         my $snapname = extract_param($param, 'snapname');
2934         my $storage = extract_param($param, 'storage');
2935         my $format = extract_param($param, 'format');
2936         my $target = extract_param($param, 'target');
2937
2938         my $localnode = PVE::INotify::nodename();
2939
2940         if ($target && ($target eq $localnode || $target eq 'localhost')) {
2941             undef $target;
2942         }
2943
2944         PVE::Cluster::check_node_exists($target) if $target;
2945
2946         my $storecfg = PVE::Storage::config();
2947
2948         if ($storage) {
2949             # check if storage is enabled on local node
2950             PVE::Storage::storage_check_enabled($storecfg, $storage);
2951             if ($target) {
2952                 # check if storage is available on target node
2953                 PVE::Storage::storage_check_node($storecfg, $storage, $target);
2954                 # clone only works if target storage is shared
2955                 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2956                 die "can't clone to non-shared storage '$storage'\n" if !$scfg->{shared};
2957             }
2958         }
2959
2960         PVE::Cluster::check_cfs_quorum();
2961
2962         my $running = PVE::QemuServer::check_running($vmid) || 0;
2963
2964         my $clonefn = sub {
2965             # do all tests after lock but before forking worker - if possible
2966
2967             my $conf = PVE::QemuConfig->load_config($vmid);
2968             PVE::QemuConfig->check_lock($conf);
2969
2970             my $verify_running = PVE::QemuServer::check_running($vmid) || 0;
2971             die "unexpected state change\n" if $verify_running != $running;
2972
2973             die "snapshot '$snapname' does not exist\n"
2974                 if $snapname && !defined( $conf->{snapshots}->{$snapname});
2975
2976             my $full = extract_param($param, 'full') // !PVE::QemuConfig->is_template($conf);
2977
2978             die "parameter 'storage' not allowed for linked clones\n"
2979                 if defined($storage) && !$full;
2980
2981             die "parameter 'format' not allowed for linked clones\n"
2982                 if defined($format) && !$full;
2983
2984             my $oldconf = $snapname ? $conf->{snapshots}->{$snapname} : $conf;
2985
2986             my $sharedvm = &$check_storage_access_clone($rpcenv, $authuser, $storecfg, $oldconf, $storage);
2987
2988             die "can't clone VM to node '$target' (VM uses local storage)\n"
2989                 if $target && !$sharedvm;
2990
2991             my $conffile = PVE::QemuConfig->config_file($newid);
2992             die "unable to create VM $newid: config file already exists\n"
2993                 if -f $conffile;
2994
2995             my $newconf = { lock => 'clone' };
2996             my $drives = {};
2997             my $fullclone = {};
2998             my $vollist = [];
2999
3000             foreach my $opt (keys %$oldconf) {
3001                 my $value = $oldconf->{$opt};
3002
3003                 # do not copy snapshot related info
3004                 next if $opt eq 'snapshots' ||  $opt eq 'parent' || $opt eq 'snaptime' ||
3005                     $opt eq 'vmstate' || $opt eq 'snapstate';
3006
3007                 # no need to copy unused images, because VMID(owner) changes anyways
3008                 next if $opt =~ m/^unused\d+$/;
3009
3010                 # always change MAC! address
3011                 if ($opt =~ m/^net(\d+)$/) {
3012                     my $net = PVE::QemuServer::parse_net($value);
3013                     my $dc = PVE::Cluster::cfs_read_file('datacenter.cfg');
3014                     $net->{macaddr} =  PVE::Tools::random_ether_addr($dc->{mac_prefix});
3015                     $newconf->{$opt} = PVE::QemuServer::print_net($net);
3016                 } elsif (PVE::QemuServer::is_valid_drivename($opt)) {
3017                     my $drive = PVE::QemuServer::parse_drive($opt, $value);
3018                     die "unable to parse drive options for '$opt'\n" if !$drive;
3019                     if (PVE::QemuServer::drive_is_cdrom($drive, 1)) {
3020                         $newconf->{$opt} = $value; # simply copy configuration
3021                     } else {
3022                         if ($full || PVE::QemuServer::drive_is_cloudinit($drive)) {
3023                             die "Full clone feature is not supported for drive '$opt'\n"
3024                                 if !PVE::Storage::volume_has_feature($storecfg, 'copy', $drive->{file}, $snapname, $running);
3025                             $fullclone->{$opt} = 1;
3026                         } else {
3027                             # not full means clone instead of copy
3028                             die "Linked clone feature is not supported for drive '$opt'\n"
3029                                 if !PVE::Storage::volume_has_feature($storecfg, 'clone', $drive->{file}, $snapname, $running);
3030                         }
3031                         $drives->{$opt} = $drive;
3032                         next if PVE::QemuServer::drive_is_cloudinit($drive);
3033                         push @$vollist, $drive->{file};
3034                     }
3035                 } else {
3036                     # copy everything else
3037                     $newconf->{$opt} = $value;
3038                 }
3039             }
3040
3041             # auto generate a new uuid
3042             my $smbios1 = PVE::QemuServer::parse_smbios1($newconf->{smbios1} || '');
3043             $smbios1->{uuid} = PVE::QemuServer::generate_uuid();
3044             $newconf->{smbios1} = PVE::QemuServer::print_smbios1($smbios1);
3045             # auto generate a new vmgenid only if the option was set for template
3046             if ($newconf->{vmgenid}) {
3047                 $newconf->{vmgenid} = PVE::QemuServer::generate_uuid();
3048             }
3049
3050             delete $newconf->{template};
3051
3052             if ($param->{name}) {
3053                 $newconf->{name} = $param->{name};
3054             } else {
3055                 $newconf->{name} = "Copy-of-VM-" . ($oldconf->{name} // $vmid);
3056             }
3057
3058             if ($param->{description}) {
3059                 $newconf->{description} = $param->{description};
3060             }
3061
3062             # create empty/temp config - this fails if VM already exists on other node
3063             # FIXME use PVE::QemuConfig->create_and_lock_config and adapt code
3064             PVE::Tools::file_set_contents($conffile, "# qmclone temporary file\nlock: clone\n");
3065
3066             my $realcmd = sub {
3067                 my $upid = shift;
3068
3069                 my $newvollist = [];
3070                 my $jobs = {};
3071
3072                 eval {
3073                     local $SIG{INT} =
3074                         local $SIG{TERM} =
3075                         local $SIG{QUIT} =
3076                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
3077
3078                     PVE::Storage::activate_volumes($storecfg, $vollist, $snapname);
3079
3080                     my $bwlimit = extract_param($param, 'bwlimit');
3081
3082                     my $total_jobs = scalar(keys %{$drives});
3083                     my $i = 1;
3084
3085                     foreach my $opt (keys %$drives) {
3086                         my $drive = $drives->{$opt};
3087                         my $skipcomplete = ($total_jobs != $i); # finish after last drive
3088                         my $completion = $skipcomplete ? 'skip' : 'complete';
3089
3090                         my $src_sid = PVE::Storage::parse_volume_id($drive->{file});
3091                         my $storage_list = [ $src_sid ];
3092                         push @$storage_list, $storage if defined($storage);
3093                         my $clonelimit = PVE::Storage::get_bandwidth_limit('clone', $storage_list, $bwlimit);
3094
3095                         my $newdrive = PVE::QemuServer::clone_disk(
3096                             $storecfg,
3097                             $vmid,
3098                             $running,
3099                             $opt,
3100                             $drive,
3101                             $snapname,
3102                             $newid,
3103                             $storage,
3104                             $format,
3105                             $fullclone->{$opt},
3106                             $newvollist,
3107                             $jobs,
3108                             $completion,
3109                             $oldconf->{agent},
3110                             $clonelimit,
3111                             $oldconf
3112                         );
3113
3114                         $newconf->{$opt} = PVE::QemuServer::print_drive($newdrive);
3115
3116                         PVE::QemuConfig->write_config($newid, $newconf);
3117                         $i++;
3118                     }
3119
3120                     delete $newconf->{lock};
3121
3122                     # do not write pending changes
3123                     if (my @changes = keys %{$newconf->{pending}}) {
3124                         my $pending = join(',', @changes);
3125                         warn "found pending changes for '$pending', discarding for clone\n";
3126                         delete $newconf->{pending};
3127                     }
3128
3129                     PVE::QemuConfig->write_config($newid, $newconf);
3130
3131                     if ($target) {
3132                         # always deactivate volumes - avoid lvm LVs to be active on several nodes
3133                         PVE::Storage::deactivate_volumes($storecfg, $vollist, $snapname) if !$running;
3134                         PVE::Storage::deactivate_volumes($storecfg, $newvollist);
3135
3136                         my $newconffile = PVE::QemuConfig->config_file($newid, $target);
3137                         die "Failed to move config to node '$target' - rename failed: $!\n"
3138                             if !rename($conffile, $newconffile);
3139                     }
3140
3141                     PVE::AccessControl::add_vm_to_pool($newid, $pool) if $pool;
3142                 };
3143                 if (my $err = $@) {
3144                     eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $jobs) };
3145                     sleep 1; # some storage like rbd need to wait before release volume - really?
3146
3147                     foreach my $volid (@$newvollist) {
3148                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
3149                         warn $@ if $@;
3150                     }
3151
3152                     PVE::Firewall::remove_vmfw_conf($newid);
3153
3154                     unlink $conffile; # avoid races -> last thing before die
3155
3156                     die "clone failed: $err";
3157                 }
3158
3159                 return;
3160             };
3161
3162             PVE::Firewall::clone_vmfw_conf($vmid, $newid);
3163
3164             return $rpcenv->fork_worker('qmclone', $vmid, $authuser, $realcmd);
3165         };
3166
3167         # Aquire exclusive lock lock for $newid
3168         my $lock_target_vm = sub {
3169             return PVE::QemuConfig->lock_config_full($newid, 1, $clonefn);
3170         };
3171
3172         # exclusive lock if VM is running - else shared lock is enough;
3173         if ($running) {
3174             return PVE::QemuConfig->lock_config_full($vmid, 1, $lock_target_vm);
3175         } else {
3176             return PVE::QemuConfig->lock_config_shared($vmid, 1, $lock_target_vm);
3177         }
3178     }});
3179
3180 __PACKAGE__->register_method({
3181     name => 'move_vm_disk',
3182     path => '{vmid}/move_disk',
3183     method => 'POST',
3184     protected => 1,
3185     proxyto => 'node',
3186     description => "Move volume to different storage.",
3187     permissions => {
3188         description => "You need 'VM.Config.Disk' permissions on /vms/{vmid}, and 'Datastore.AllocateSpace' permissions on the storage.",
3189         check => [ 'and',
3190                    ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
3191                    ['perm', '/storage/{storage}', [ 'Datastore.AllocateSpace' ]],
3192             ],
3193     },
3194     parameters => {
3195         additionalProperties => 0,
3196         properties => {
3197             node => get_standard_option('pve-node'),
3198             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3199             disk => {
3200                 type => 'string',
3201                 description => "The disk you want to move.",
3202                 enum => [PVE::QemuServer::Drive::valid_drive_names()],
3203             },
3204             storage => get_standard_option('pve-storage-id', {
3205                 description => "Target storage.",
3206                 completion => \&PVE::QemuServer::complete_storage,
3207             }),
3208             'format' => {
3209                 type => 'string',
3210                 description => "Target Format.",
3211                 enum => [ 'raw', 'qcow2', 'vmdk' ],
3212                 optional => 1,
3213             },
3214             delete => {
3215                 type => 'boolean',
3216                 description => "Delete the original disk after successful copy. By default the original disk is kept as unused disk.",
3217                 optional => 1,
3218                 default => 0,
3219             },
3220             digest => {
3221                 type => 'string',
3222                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
3223                 maxLength => 40,
3224                 optional => 1,
3225             },
3226             bwlimit => {
3227                 description => "Override I/O bandwidth limit (in KiB/s).",
3228                 optional => 1,
3229                 type => 'integer',
3230                 minimum => '0',
3231                 default => 'move limit from datacenter or storage config',
3232             },
3233         },
3234     },
3235     returns => {
3236         type => 'string',
3237         description => "the task ID.",
3238     },
3239     code => sub {
3240         my ($param) = @_;
3241
3242         my $rpcenv = PVE::RPCEnvironment::get();
3243         my $authuser = $rpcenv->get_user();
3244
3245         my $node = extract_param($param, 'node');
3246         my $vmid = extract_param($param, 'vmid');
3247         my $digest = extract_param($param, 'digest');
3248         my $disk = extract_param($param, 'disk');
3249         my $storeid = extract_param($param, 'storage');
3250         my $format = extract_param($param, 'format');
3251
3252         my $storecfg = PVE::Storage::config();
3253
3254         my $updatefn =  sub {
3255             my $conf = PVE::QemuConfig->load_config($vmid);
3256             PVE::QemuConfig->check_lock($conf);
3257
3258             die "VM config checksum missmatch (file change by other user?)\n"
3259                 if $digest && $digest ne $conf->{digest};
3260
3261             die "disk '$disk' does not exist\n" if !$conf->{$disk};
3262
3263             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
3264
3265             die "disk '$disk' has no associated volume\n" if !$drive->{file};
3266             die "you can't move a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive, 1);
3267
3268             my $old_volid = $drive->{file};
3269             my $oldfmt;
3270             my ($oldstoreid, $oldvolname) = PVE::Storage::parse_volume_id($old_volid);
3271             if ($oldvolname =~ m/\.(raw|qcow2|vmdk)$/){
3272                 $oldfmt = $1;
3273             }
3274
3275             die "you can't move to the same storage with same format\n" if $oldstoreid eq $storeid &&
3276                 (!$format || !$oldfmt || $oldfmt eq $format);
3277
3278             # this only checks snapshots because $disk is passed!
3279             my $snapshotted = PVE::QemuServer::Drive::is_volume_in_use($storecfg, $conf, $disk, $old_volid);
3280             die "you can't move a disk with snapshots and delete the source\n"
3281                 if $snapshotted && $param->{delete};
3282
3283             PVE::Cluster::log_msg('info', $authuser, "move disk VM $vmid: move --disk $disk --storage $storeid");
3284
3285             my $running = PVE::QemuServer::check_running($vmid);
3286
3287             PVE::Storage::activate_volumes($storecfg, [ $drive->{file} ]);
3288
3289             my $realcmd = sub {
3290                 my $newvollist = [];
3291
3292                 eval {
3293                     local $SIG{INT} =
3294                         local $SIG{TERM} =
3295                         local $SIG{QUIT} =
3296                         local $SIG{HUP} = sub { die "interrupted by signal\n"; };
3297
3298                     warn "moving disk with snapshots, snapshots will not be moved!\n"
3299                         if $snapshotted;
3300
3301                     my $bwlimit = extract_param($param, 'bwlimit');
3302                     my $movelimit = PVE::Storage::get_bandwidth_limit('move', [$oldstoreid, $storeid], $bwlimit);
3303
3304                     my $newdrive = PVE::QemuServer::clone_disk(
3305                         $storecfg,
3306                         $vmid,
3307                         $running,
3308                         $disk,
3309                         $drive,
3310                         undef,
3311                         $vmid,
3312                         $storeid,
3313                         $format,
3314                         1,
3315                         $newvollist,
3316                         undef,
3317                         undef,
3318                         undef,
3319                         $movelimit,
3320                         $conf,
3321                     );
3322                     $conf->{$disk} = PVE::QemuServer::print_drive($newdrive);
3323
3324                     PVE::QemuConfig->add_unused_volume($conf, $old_volid) if !$param->{delete};
3325
3326                     # convert moved disk to base if part of template
3327                     PVE::QemuServer::template_create($vmid, $conf, $disk)
3328                         if PVE::QemuConfig->is_template($conf);
3329
3330                     PVE::QemuConfig->write_config($vmid, $conf);
3331
3332                     my $do_trim = PVE::QemuServer::get_qga_key($conf, 'fstrim_cloned_disks');
3333                     if ($running && $do_trim && PVE::QemuServer::qga_check_running($vmid)) {
3334                         eval { mon_cmd($vmid, "guest-fstrim") };
3335                     }
3336
3337                     eval {
3338                         # try to deactivate volumes - avoid lvm LVs to be active on several nodes
3339                         PVE::Storage::deactivate_volumes($storecfg, [ $newdrive->{file} ])
3340                             if !$running;
3341                     };
3342                     warn $@ if $@;
3343                 };
3344                 if (my $err = $@) {
3345                     foreach my $volid (@$newvollist) {
3346                         eval { PVE::Storage::vdisk_free($storecfg, $volid) };
3347                         warn $@ if $@;
3348                     }
3349                     die "storage migration failed: $err";
3350                 }
3351
3352                 if ($param->{delete}) {
3353                     eval {
3354                         PVE::Storage::deactivate_volumes($storecfg, [$old_volid]);
3355                         PVE::Storage::vdisk_free($storecfg, $old_volid);
3356                     };
3357                     warn $@ if $@;
3358                 }
3359             };
3360
3361             return $rpcenv->fork_worker('qmmove', $vmid, $authuser, $realcmd);
3362         };
3363
3364         return PVE::QemuConfig->lock_config($vmid, $updatefn);
3365     }});
3366
3367 my $check_vm_disks_local = sub {
3368     my ($storecfg, $vmconf, $vmid) = @_;
3369
3370     my $local_disks = {};
3371
3372     # add some more information to the disks e.g. cdrom
3373     PVE::QemuServer::foreach_volid($vmconf, sub {
3374         my ($volid, $attr) = @_;
3375
3376         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
3377         if ($storeid) {
3378             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
3379             return if $scfg->{shared};
3380         }
3381         # The shared attr here is just a special case where the vdisk
3382         # is marked as shared manually
3383         return if $attr->{shared};
3384         return if $attr->{cdrom} and $volid eq "none";
3385
3386         if (exists $local_disks->{$volid}) {
3387             @{$local_disks->{$volid}}{keys %$attr} = values %$attr
3388         } else {
3389             $local_disks->{$volid} = $attr;
3390             # ensure volid is present in case it's needed
3391             $local_disks->{$volid}->{volid} = $volid;
3392         }
3393     });
3394
3395     return $local_disks;
3396 };
3397
3398 __PACKAGE__->register_method({
3399     name => 'migrate_vm_precondition',
3400     path => '{vmid}/migrate',
3401     method => 'GET',
3402     protected => 1,
3403     proxyto => 'node',
3404     description => "Get preconditions for migration.",
3405     permissions => {
3406         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
3407     },
3408     parameters => {
3409         additionalProperties => 0,
3410         properties => {
3411             node => get_standard_option('pve-node'),
3412             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3413             target => get_standard_option('pve-node', {
3414                 description => "Target node.",
3415                 completion =>  \&PVE::Cluster::complete_migration_target,
3416                 optional => 1,
3417             }),
3418         },
3419     },
3420     returns => {
3421         type => "object",
3422         properties => {
3423             running => { type => 'boolean' },
3424             allowed_nodes => {
3425                 type => 'array',
3426                 optional => 1,
3427                 description => "List nodes allowed for offline migration, only passed if VM is offline"
3428             },
3429             not_allowed_nodes => {
3430                 type => 'object',
3431                 optional => 1,
3432                 description => "List not allowed nodes with additional informations, only passed if VM is offline"
3433             },
3434             local_disks => {
3435                 type => 'array',
3436                 description => "List local disks including CD-Rom, unsused and not referenced disks"
3437             },
3438             local_resources => {
3439                 type => 'array',
3440                 description => "List local resources e.g. pci, usb"
3441             }
3442         },
3443     },
3444     code => sub {
3445         my ($param) = @_;
3446
3447         my $rpcenv = PVE::RPCEnvironment::get();
3448
3449         my $authuser = $rpcenv->get_user();
3450
3451         PVE::Cluster::check_cfs_quorum();
3452
3453         my $res = {};
3454
3455         my $vmid = extract_param($param, 'vmid');
3456         my $target = extract_param($param, 'target');
3457         my $localnode = PVE::INotify::nodename();
3458
3459
3460         # test if VM exists
3461         my $vmconf = PVE::QemuConfig->load_config($vmid);
3462         my $storecfg = PVE::Storage::config();
3463
3464
3465         # try to detect errors early
3466         PVE::QemuConfig->check_lock($vmconf);
3467
3468         $res->{running} = PVE::QemuServer::check_running($vmid) ? 1:0;
3469
3470         # if vm is not running, return target nodes where local storage is available
3471         # for offline migration
3472         if (!$res->{running}) {
3473             $res->{allowed_nodes} = [];
3474             my $checked_nodes = PVE::QemuServer::check_local_storage_availability($vmconf, $storecfg);
3475             delete $checked_nodes->{$localnode};
3476
3477             foreach my $node (keys %$checked_nodes) {
3478                 if (!defined $checked_nodes->{$node}->{unavailable_storages}) {
3479                     push @{$res->{allowed_nodes}}, $node;
3480                 }
3481
3482             }
3483             $res->{not_allowed_nodes} = $checked_nodes;
3484         }
3485
3486
3487         my $local_disks = &$check_vm_disks_local($storecfg, $vmconf, $vmid);
3488         $res->{local_disks} = [ values %$local_disks ];;
3489
3490         my $local_resources =  PVE::QemuServer::check_local_resources($vmconf, 1);
3491
3492         $res->{local_resources} = $local_resources;
3493
3494         return $res;
3495
3496
3497     }});
3498
3499 __PACKAGE__->register_method({
3500     name => 'migrate_vm',
3501     path => '{vmid}/migrate',
3502     method => 'POST',
3503     protected => 1,
3504     proxyto => 'node',
3505     description => "Migrate virtual machine. Creates a new migration task.",
3506     permissions => {
3507         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
3508     },
3509     parameters => {
3510         additionalProperties => 0,
3511         properties => {
3512             node => get_standard_option('pve-node'),
3513             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3514             target => get_standard_option('pve-node', {
3515                 description => "Target node.",
3516                 completion =>  \&PVE::Cluster::complete_migration_target,
3517             }),
3518             online => {
3519                 type => 'boolean',
3520                 description => "Use online/live migration if VM is running. Ignored if VM is stopped.",
3521                 optional => 1,
3522             },
3523             force => {
3524                 type => 'boolean',
3525                 description => "Allow to migrate VMs which use local devices. Only root may use this option.",
3526                 optional => 1,
3527             },
3528             migration_type => {
3529                 type => 'string',
3530                 enum => ['secure', 'insecure'],
3531                 description => "Migration traffic is encrypted using an SSH tunnel by default. On secure, completely private networks this can be disabled to increase performance.",
3532                 optional => 1,
3533             },
3534             migration_network => {
3535                 type => 'string', format => 'CIDR',
3536                 description => "CIDR of the (sub) network that is used for migration.",
3537                 optional => 1,
3538             },
3539             "with-local-disks" => {
3540                 type => 'boolean',
3541                 description => "Enable live storage migration for local disk",
3542                 optional => 1,
3543             },
3544             targetstorage => get_standard_option('pve-targetstorage', {
3545                 completion => \&PVE::QemuServer::complete_migration_storage,
3546             }),
3547             bwlimit => {
3548                 description => "Override I/O bandwidth limit (in KiB/s).",
3549                 optional => 1,
3550                 type => 'integer',
3551                 minimum => '0',
3552                 default => 'migrate limit from datacenter or storage config',
3553             },
3554         },
3555     },
3556     returns => {
3557         type => 'string',
3558         description => "the task ID.",
3559     },
3560     code => sub {
3561         my ($param) = @_;
3562
3563         my $rpcenv = PVE::RPCEnvironment::get();
3564         my $authuser = $rpcenv->get_user();
3565
3566         my $target = extract_param($param, 'target');
3567
3568         my $localnode = PVE::INotify::nodename();
3569         raise_param_exc({ target => "target is local node."}) if $target eq $localnode;
3570
3571         PVE::Cluster::check_cfs_quorum();
3572
3573         PVE::Cluster::check_node_exists($target);
3574
3575         my $targetip = PVE::Cluster::remote_node_ip($target);
3576
3577         my $vmid = extract_param($param, 'vmid');
3578
3579         raise_param_exc({ force => "Only root may use this option." })
3580             if $param->{force} && $authuser ne 'root@pam';
3581
3582         raise_param_exc({ migration_type => "Only root may use this option." })
3583             if $param->{migration_type} && $authuser ne 'root@pam';
3584
3585         # allow root only until better network permissions are available
3586         raise_param_exc({ migration_network => "Only root may use this option." })
3587             if $param->{migration_network} && $authuser ne 'root@pam';
3588
3589         # test if VM exists
3590         my $conf = PVE::QemuConfig->load_config($vmid);
3591
3592         # try to detect errors early
3593
3594         PVE::QemuConfig->check_lock($conf);
3595
3596         if (PVE::QemuServer::check_running($vmid)) {
3597             die "can't migrate running VM without --online\n" if !$param->{online};
3598
3599             my $repl_conf = PVE::ReplicationConfig->new();
3600             my $is_replicated = $repl_conf->check_for_existing_jobs($vmid, 1);
3601             my $is_replicated_to_target = defined($repl_conf->find_local_replication_job($vmid, $target));
3602             if (!$param->{force} && $is_replicated && !$is_replicated_to_target) {
3603                 die "Cannot live-migrate replicated VM to node '$target' - not a replication " .
3604                     "target. Use 'force' to override.\n";
3605             }
3606         } else {
3607             warn "VM isn't running. Doing offline migration instead.\n" if $param->{online};
3608             $param->{online} = 0;
3609         }
3610
3611         my $storecfg = PVE::Storage::config();
3612
3613         if (my $targetstorage = $param->{targetstorage}) {
3614             my $check_storage = sub {
3615                 my ($target_sid) = @_;
3616                 PVE::Storage::storage_check_node($storecfg, $target_sid, $target);
3617                 $rpcenv->check($authuser, "/storage/$target_sid", ['Datastore.AllocateSpace']);
3618                 my $scfg = PVE::Storage::storage_config($storecfg, $target_sid);
3619                 raise_param_exc({ targetstorage => "storage '$target_sid' does not support vm images"})
3620                     if !$scfg->{content}->{images};
3621             };
3622
3623             my $storagemap = eval { PVE::JSONSchema::parse_idmap($targetstorage, 'pve-storage-id') };
3624             raise_param_exc({ targetstorage => "failed to parse storage map: $@" })
3625                 if $@;
3626
3627             $rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Disk'])
3628                 if !defined($storagemap->{identity});
3629
3630             foreach my $source (values %{$storagemap->{entries}}) {
3631                 $check_storage->($source);
3632             }
3633
3634             $check_storage->($storagemap->{default})
3635                 if $storagemap->{default};
3636
3637             PVE::QemuServer::check_storage_availability($storecfg, $conf, $target)
3638                 if $storagemap->{identity};
3639
3640             $param->{storagemap} = $storagemap;
3641         } else {
3642             PVE::QemuServer::check_storage_availability($storecfg, $conf, $target);
3643         }
3644
3645         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
3646
3647             my $hacmd = sub {
3648                 my $upid = shift;
3649
3650                 print "Requesting HA migration for VM $vmid to node $target\n";
3651
3652                 my $cmd = ['ha-manager', 'migrate', "vm:$vmid", $target];
3653                 PVE::Tools::run_command($cmd);
3654                 return;
3655             };
3656
3657             return $rpcenv->fork_worker('hamigrate', $vmid, $authuser, $hacmd);
3658
3659         } else {
3660
3661             my $realcmd = sub {
3662                 PVE::QemuMigrate->migrate($target, $targetip, $vmid, $param);
3663             };
3664
3665             my $worker = sub {
3666                 return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
3667             };
3668
3669             return $rpcenv->fork_worker('qmigrate', $vmid, $authuser, $worker);
3670         }
3671
3672     }});
3673
3674 __PACKAGE__->register_method({
3675     name => 'monitor',
3676     path => '{vmid}/monitor',
3677     method => 'POST',
3678     protected => 1,
3679     proxyto => 'node',
3680     description => "Execute Qemu monitor commands.",
3681     permissions => {
3682         description => "Sys.Modify is required for (sub)commands which are not read-only ('info *' and 'help')",
3683         check => ['perm', '/vms/{vmid}', [ 'VM.Monitor' ]],
3684     },
3685     parameters => {
3686         additionalProperties => 0,
3687         properties => {
3688             node => get_standard_option('pve-node'),
3689             vmid => get_standard_option('pve-vmid'),
3690             command => {
3691                 type => 'string',
3692                 description => "The monitor command.",
3693             }
3694         },
3695     },
3696     returns => { type => 'string'},
3697     code => sub {
3698         my ($param) = @_;
3699
3700         my $rpcenv = PVE::RPCEnvironment::get();
3701         my $authuser = $rpcenv->get_user();
3702
3703         my $is_ro = sub {
3704             my $command = shift;
3705             return $command =~ m/^\s*info(\s+|$)/
3706                 || $command =~ m/^\s*help\s*$/;
3707         };
3708
3709         $rpcenv->check_full($authuser, "/", ['Sys.Modify'])
3710             if !&$is_ro($param->{command});
3711
3712         my $vmid = $param->{vmid};
3713
3714         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
3715
3716         my $res = '';
3717         eval {
3718             $res = PVE::QemuServer::Monitor::hmp_cmd($vmid, $param->{command});
3719         };
3720         $res = "ERROR: $@" if $@;
3721
3722         return $res;
3723     }});
3724
3725 __PACKAGE__->register_method({
3726     name => 'resize_vm',
3727     path => '{vmid}/resize',
3728     method => 'PUT',
3729     protected => 1,
3730     proxyto => 'node',
3731     description => "Extend volume size.",
3732     permissions => {
3733         check => ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
3734     },
3735     parameters => {
3736         additionalProperties => 0,
3737         properties => {
3738             node => get_standard_option('pve-node'),
3739             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3740             skiplock => get_standard_option('skiplock'),
3741             disk => {
3742                 type => 'string',
3743                 description => "The disk you want to resize.",
3744                 enum => [PVE::QemuServer::Drive::valid_drive_names()],
3745             },
3746             size => {
3747                 type => 'string',
3748                 pattern => '\+?\d+(\.\d+)?[KMGT]?',
3749                 description => "The new size. With the `+` sign the value is added to the actual size of the volume and without it, the value is taken as an absolute one. Shrinking disk size is not supported.",
3750             },
3751             digest => {
3752                 type => 'string',
3753                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
3754                 maxLength => 40,
3755                 optional => 1,
3756             },
3757         },
3758     },
3759     returns => { type => 'null'},
3760     code => sub {
3761         my ($param) = @_;
3762
3763         my $rpcenv = PVE::RPCEnvironment::get();
3764
3765         my $authuser = $rpcenv->get_user();
3766
3767         my $node = extract_param($param, 'node');
3768
3769         my $vmid = extract_param($param, 'vmid');
3770
3771         my $digest = extract_param($param, 'digest');
3772
3773         my $disk = extract_param($param, 'disk');
3774
3775         my $sizestr = extract_param($param, 'size');
3776
3777         my $skiplock = extract_param($param, 'skiplock');
3778         raise_param_exc({ skiplock => "Only root may use this option." })
3779             if $skiplock && $authuser ne 'root@pam';
3780
3781         my $storecfg = PVE::Storage::config();
3782
3783         my $updatefn =  sub {
3784
3785             my $conf = PVE::QemuConfig->load_config($vmid);
3786
3787             die "checksum missmatch (file change by other user?)\n"
3788                 if $digest && $digest ne $conf->{digest};
3789             PVE::QemuConfig->check_lock($conf) if !$skiplock;
3790
3791             die "disk '$disk' does not exist\n" if !$conf->{$disk};
3792
3793             my $drive = PVE::QemuServer::parse_drive($disk, $conf->{$disk});
3794
3795             my (undef, undef, undef, undef, undef, undef, $format) =
3796                 PVE::Storage::parse_volname($storecfg, $drive->{file});
3797
3798             die "can't resize volume: $disk if snapshot exists\n"
3799                 if %{$conf->{snapshots}} && $format eq 'qcow2';
3800
3801             my $volid = $drive->{file};
3802
3803             die "disk '$disk' has no associated volume\n" if !$volid;
3804
3805             die "you can't resize a cdrom\n" if PVE::QemuServer::drive_is_cdrom($drive);
3806
3807             my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid);
3808
3809             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
3810
3811             PVE::Storage::activate_volumes($storecfg, [$volid]);
3812             my $size = PVE::Storage::volume_size_info($storecfg, $volid, 5);
3813
3814             die "Could not determine current size of volume '$volid'\n" if !defined($size);
3815
3816             die "internal error" if $sizestr !~ m/^(\+)?(\d+(\.\d+)?)([KMGT])?$/;
3817             my ($ext, $newsize, $unit) = ($1, $2, $4);
3818             if ($unit) {
3819                 if ($unit eq 'K') {
3820                     $newsize = $newsize * 1024;
3821                 } elsif ($unit eq 'M') {
3822                     $newsize = $newsize * 1024 * 1024;
3823                 } elsif ($unit eq 'G') {
3824                     $newsize = $newsize * 1024 * 1024 * 1024;
3825                 } elsif ($unit eq 'T') {
3826                     $newsize = $newsize * 1024 * 1024 * 1024 * 1024;
3827                 }
3828             }
3829             $newsize += $size if $ext;
3830             $newsize = int($newsize);
3831
3832             die "shrinking disks is not supported\n" if $newsize < $size;
3833
3834             return if $size == $newsize;
3835
3836             PVE::Cluster::log_msg('info', $authuser, "update VM $vmid: resize --disk $disk --size $sizestr");
3837
3838             PVE::QemuServer::qemu_block_resize($vmid, "drive-$disk", $storecfg, $volid, $newsize);
3839
3840             $drive->{size} = $newsize;
3841             $conf->{$disk} = PVE::QemuServer::print_drive($drive);
3842
3843             PVE::QemuConfig->write_config($vmid, $conf);
3844         };
3845
3846         PVE::QemuConfig->lock_config($vmid, $updatefn);
3847         return;
3848     }});
3849
3850 __PACKAGE__->register_method({
3851     name => 'snapshot_list',
3852     path => '{vmid}/snapshot',
3853     method => 'GET',
3854     description => "List all snapshots.",
3855     permissions => {
3856         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
3857     },
3858     proxyto => 'node',
3859     protected => 1, # qemu pid files are only readable by root
3860     parameters => {
3861         additionalProperties => 0,
3862         properties => {
3863             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3864             node => get_standard_option('pve-node'),
3865         },
3866     },
3867     returns => {
3868         type => 'array',
3869         items => {
3870             type => "object",
3871             properties => {
3872                 name => {
3873                     description => "Snapshot identifier. Value 'current' identifies the current VM.",
3874                     type => 'string',
3875                 },
3876                 vmstate => {
3877                     description => "Snapshot includes RAM.",
3878                     type => 'boolean',
3879                     optional => 1,
3880                 },
3881                 description => {
3882                     description => "Snapshot description.",
3883                     type => 'string',
3884                 },
3885                 snaptime => {
3886                     description => "Snapshot creation time",
3887                     type => 'integer',
3888                     renderer => 'timestamp',
3889                     optional => 1,
3890                 },
3891                 parent => {
3892                     description => "Parent snapshot identifier.",
3893                     type => 'string',
3894                     optional => 1,
3895                 },
3896             },
3897         },
3898         links => [ { rel => 'child', href => "{name}" } ],
3899     },
3900     code => sub {
3901         my ($param) = @_;
3902
3903         my $vmid = $param->{vmid};
3904
3905         my $conf = PVE::QemuConfig->load_config($vmid);
3906         my $snaphash = $conf->{snapshots} || {};
3907
3908         my $res = [];
3909
3910         foreach my $name (keys %$snaphash) {
3911             my $d = $snaphash->{$name};
3912             my $item = {
3913                 name => $name,
3914                 snaptime => $d->{snaptime} || 0,
3915                 vmstate => $d->{vmstate} ? 1 : 0,
3916                 description => $d->{description} || '',
3917             };
3918             $item->{parent} = $d->{parent} if $d->{parent};
3919             $item->{snapstate} = $d->{snapstate} if $d->{snapstate};
3920             push @$res, $item;
3921         }
3922
3923         my $running = PVE::QemuServer::check_running($vmid, 1) ? 1 : 0;
3924         my $current = {
3925             name => 'current',
3926             digest => $conf->{digest},
3927             running => $running,
3928             description => "You are here!",
3929         };
3930         $current->{parent} = $conf->{parent} if $conf->{parent};
3931
3932         push @$res, $current;
3933
3934         return $res;
3935     }});
3936
3937 __PACKAGE__->register_method({
3938     name => 'snapshot',
3939     path => '{vmid}/snapshot',
3940     method => 'POST',
3941     protected => 1,
3942     proxyto => 'node',
3943     description => "Snapshot a VM.",
3944     permissions => {
3945         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
3946     },
3947     parameters => {
3948         additionalProperties => 0,
3949         properties => {
3950             node => get_standard_option('pve-node'),
3951             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
3952             snapname => get_standard_option('pve-snapshot-name'),
3953             vmstate => {
3954                 optional => 1,
3955                 type => 'boolean',
3956                 description => "Save the vmstate",
3957             },
3958             description => {
3959                 optional => 1,
3960                 type => 'string',
3961                 description => "A textual description or comment.",
3962             },
3963         },
3964     },
3965     returns => {
3966         type => 'string',
3967         description => "the task ID.",
3968     },
3969     code => sub {
3970         my ($param) = @_;
3971
3972         my $rpcenv = PVE::RPCEnvironment::get();
3973
3974         my $authuser = $rpcenv->get_user();
3975
3976         my $node = extract_param($param, 'node');
3977
3978         my $vmid = extract_param($param, 'vmid');
3979
3980         my $snapname = extract_param($param, 'snapname');
3981
3982         die "unable to use snapshot name 'current' (reserved name)\n"
3983             if $snapname eq 'current';
3984
3985         die "unable to use snapshot name 'pending' (reserved name)\n"
3986             if lc($snapname) eq 'pending';
3987
3988         my $realcmd = sub {
3989             PVE::Cluster::log_msg('info', $authuser, "snapshot VM $vmid: $snapname");
3990             PVE::QemuConfig->snapshot_create($vmid, $snapname, $param->{vmstate},
3991                                              $param->{description});
3992         };
3993
3994         return $rpcenv->fork_worker('qmsnapshot', $vmid, $authuser, $realcmd);
3995     }});
3996
3997 __PACKAGE__->register_method({
3998     name => 'snapshot_cmd_idx',
3999     path => '{vmid}/snapshot/{snapname}',
4000     description => '',
4001     method => 'GET',
4002     permissions => {
4003         user => 'all',
4004     },
4005     parameters => {
4006         additionalProperties => 0,
4007         properties => {
4008             vmid => get_standard_option('pve-vmid'),
4009             node => get_standard_option('pve-node'),
4010             snapname => get_standard_option('pve-snapshot-name'),
4011         },
4012     },
4013     returns => {
4014         type => 'array',
4015         items => {
4016             type => "object",
4017             properties => {},
4018         },
4019         links => [ { rel => 'child', href => "{cmd}" } ],
4020     },
4021     code => sub {
4022         my ($param) = @_;
4023
4024         my $res = [];
4025
4026         push @$res, { cmd => 'rollback' };
4027         push @$res, { cmd => 'config' };
4028
4029         return $res;
4030     }});
4031
4032 __PACKAGE__->register_method({
4033     name => 'update_snapshot_config',
4034     path => '{vmid}/snapshot/{snapname}/config',
4035     method => 'PUT',
4036     protected => 1,
4037     proxyto => 'node',
4038     description => "Update snapshot metadata.",
4039     permissions => {
4040         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
4041     },
4042     parameters => {
4043         additionalProperties => 0,
4044         properties => {
4045             node => get_standard_option('pve-node'),
4046             vmid => get_standard_option('pve-vmid'),
4047             snapname => get_standard_option('pve-snapshot-name'),
4048             description => {
4049                 optional => 1,
4050                 type => 'string',
4051                 description => "A textual description or comment.",
4052             },
4053         },
4054     },
4055     returns => { type => 'null' },
4056     code => sub {
4057         my ($param) = @_;
4058
4059         my $rpcenv = PVE::RPCEnvironment::get();
4060
4061         my $authuser = $rpcenv->get_user();
4062
4063         my $vmid = extract_param($param, 'vmid');
4064
4065         my $snapname = extract_param($param, 'snapname');
4066
4067         return if !defined($param->{description});
4068
4069         my $updatefn =  sub {
4070
4071             my $conf = PVE::QemuConfig->load_config($vmid);
4072
4073             PVE::QemuConfig->check_lock($conf);
4074
4075             my $snap = $conf->{snapshots}->{$snapname};
4076
4077             die "snapshot '$snapname' does not exist\n" if !defined($snap);
4078
4079             $snap->{description} = $param->{description} if defined($param->{description});
4080
4081              PVE::QemuConfig->write_config($vmid, $conf);
4082         };
4083
4084         PVE::QemuConfig->lock_config($vmid, $updatefn);
4085
4086         return;
4087     }});
4088
4089 __PACKAGE__->register_method({
4090     name => 'get_snapshot_config',
4091     path => '{vmid}/snapshot/{snapname}/config',
4092     method => 'GET',
4093     proxyto => 'node',
4094     description => "Get snapshot configuration",
4095     permissions => {
4096         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback', 'VM.Audit' ], any => 1],
4097     },
4098     parameters => {
4099         additionalProperties => 0,
4100         properties => {
4101             node => get_standard_option('pve-node'),
4102             vmid => get_standard_option('pve-vmid'),
4103             snapname => get_standard_option('pve-snapshot-name'),
4104         },
4105     },
4106     returns => { type => "object" },
4107     code => sub {
4108         my ($param) = @_;
4109
4110         my $rpcenv = PVE::RPCEnvironment::get();
4111
4112         my $authuser = $rpcenv->get_user();
4113
4114         my $vmid = extract_param($param, 'vmid');
4115
4116         my $snapname = extract_param($param, 'snapname');
4117
4118         my $conf = PVE::QemuConfig->load_config($vmid);
4119
4120         my $snap = $conf->{snapshots}->{$snapname};
4121
4122         die "snapshot '$snapname' does not exist\n" if !defined($snap);
4123
4124         return $snap;
4125     }});
4126
4127 __PACKAGE__->register_method({
4128     name => 'rollback',
4129     path => '{vmid}/snapshot/{snapname}/rollback',
4130     method => 'POST',
4131     protected => 1,
4132     proxyto => 'node',
4133     description => "Rollback VM state to specified snapshot.",
4134     permissions => {
4135         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot', 'VM.Snapshot.Rollback' ], any => 1],
4136     },
4137     parameters => {
4138         additionalProperties => 0,
4139         properties => {
4140             node => get_standard_option('pve-node'),
4141             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
4142             snapname => get_standard_option('pve-snapshot-name'),
4143         },
4144     },
4145     returns => {
4146         type => 'string',
4147         description => "the task ID.",
4148     },
4149     code => sub {
4150         my ($param) = @_;
4151
4152         my $rpcenv = PVE::RPCEnvironment::get();
4153
4154         my $authuser = $rpcenv->get_user();
4155
4156         my $node = extract_param($param, 'node');
4157
4158         my $vmid = extract_param($param, 'vmid');
4159
4160         my $snapname = extract_param($param, 'snapname');
4161
4162         my $realcmd = sub {
4163             PVE::Cluster::log_msg('info', $authuser, "rollback snapshot VM $vmid: $snapname");
4164             PVE::QemuConfig->snapshot_rollback($vmid, $snapname);
4165         };
4166
4167         my $worker = sub {
4168             # hold migration lock, this makes sure that nobody create replication snapshots
4169             return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
4170         };
4171
4172         return $rpcenv->fork_worker('qmrollback', $vmid, $authuser, $worker);
4173     }});
4174
4175 __PACKAGE__->register_method({
4176     name => 'delsnapshot',
4177     path => '{vmid}/snapshot/{snapname}',
4178     method => 'DELETE',
4179     protected => 1,
4180     proxyto => 'node',
4181     description => "Delete a VM snapshot.",
4182     permissions => {
4183         check => ['perm', '/vms/{vmid}', [ 'VM.Snapshot' ]],
4184     },
4185     parameters => {
4186         additionalProperties => 0,
4187         properties => {
4188             node => get_standard_option('pve-node'),
4189             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
4190             snapname => get_standard_option('pve-snapshot-name'),
4191             force => {
4192                 optional => 1,
4193                 type => 'boolean',
4194                 description => "For removal from config file, even if removing disk snapshots fails.",
4195             },
4196         },
4197     },
4198     returns => {
4199         type => 'string',
4200         description => "the task ID.",
4201     },
4202     code => sub {
4203         my ($param) = @_;
4204
4205         my $rpcenv = PVE::RPCEnvironment::get();
4206
4207         my $authuser = $rpcenv->get_user();
4208
4209         my $node = extract_param($param, 'node');
4210
4211         my $vmid = extract_param($param, 'vmid');
4212
4213         my $snapname = extract_param($param, 'snapname');
4214
4215         my $realcmd = sub {
4216             PVE::Cluster::log_msg('info', $authuser, "delete snapshot VM $vmid: $snapname");
4217             PVE::QemuConfig->snapshot_delete($vmid, $snapname, $param->{force});
4218         };
4219
4220         return $rpcenv->fork_worker('qmdelsnapshot', $vmid, $authuser, $realcmd);
4221     }});
4222
4223 __PACKAGE__->register_method({
4224     name => 'template',
4225     path => '{vmid}/template',
4226     method => 'POST',
4227     protected => 1,
4228     proxyto => 'node',
4229     description => "Create a Template.",
4230     permissions => {
4231         description => "You need 'VM.Allocate' permissions on /vms/{vmid}",
4232         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
4233     },
4234     parameters => {
4235         additionalProperties => 0,
4236         properties => {
4237             node => get_standard_option('pve-node'),
4238             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_stopped }),
4239             disk => {
4240                 optional => 1,
4241                 type => 'string',
4242                 description => "If you want to convert only 1 disk to base image.",
4243                 enum => [PVE::QemuServer::Drive::valid_drive_names()],
4244             },
4245
4246         },
4247     },
4248     returns => { type => 'null'},
4249     code => sub {
4250         my ($param) = @_;
4251
4252         my $rpcenv = PVE::RPCEnvironment::get();
4253
4254         my $authuser = $rpcenv->get_user();
4255
4256         my $node = extract_param($param, 'node');
4257
4258         my $vmid = extract_param($param, 'vmid');
4259
4260         my $disk = extract_param($param, 'disk');
4261
4262         my $updatefn =  sub {
4263
4264             my $conf = PVE::QemuConfig->load_config($vmid);
4265
4266             PVE::QemuConfig->check_lock($conf);
4267
4268             die "unable to create template, because VM contains snapshots\n"
4269                 if $conf->{snapshots} && scalar(keys %{$conf->{snapshots}});
4270
4271             die "you can't convert a template to a template\n"
4272                 if PVE::QemuConfig->is_template($conf) && !$disk;
4273
4274             die "you can't convert a VM to template if VM is running\n"
4275                 if PVE::QemuServer::check_running($vmid);
4276
4277             my $realcmd = sub {
4278                 PVE::QemuServer::template_create($vmid, $conf, $disk);
4279             };
4280
4281             $conf->{template} = 1;
4282             PVE::QemuConfig->write_config($vmid, $conf);
4283
4284             return $rpcenv->fork_worker('qmtemplate', $vmid, $authuser, $realcmd);
4285         };
4286
4287         PVE::QemuConfig->lock_config($vmid, $updatefn);
4288         return;
4289     }});
4290
4291 __PACKAGE__->register_method({
4292     name => 'cloudinit_generated_config_dump',
4293     path => '{vmid}/cloudinit/dump',
4294     method => 'GET',
4295     proxyto => 'node',
4296     description => "Get automatically generated cloudinit config.",
4297     permissions => {
4298         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
4299     },
4300     parameters => {
4301         additionalProperties => 0,
4302         properties => {
4303             node => get_standard_option('pve-node'),
4304             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
4305             type => {
4306                 description => 'Config type.',
4307                 type => 'string',
4308                 enum => ['user', 'network', 'meta'],
4309             },
4310         },
4311     },
4312     returns => {
4313         type => 'string',
4314     },
4315     code => sub {
4316         my ($param) = @_;
4317
4318         my $conf = PVE::QemuConfig->load_config($param->{vmid});
4319
4320         return PVE::QemuServer::Cloudinit::dump_cloudinit_config($conf, $param->{vmid}, $param->{type});
4321     }});
4322
4323 1;