PVE/CLI/qm.pm

   1 package PVE::CLI::qm;
   2
   3 use strict;
   4 use warnings;
   5
   6 # Note: disable '+' prefix for Getopt::Long (for resize command)
   7 use Getopt::Long qw(:config no_getopt_compat);
   8
   9 use Fcntl ':flock';
  10 use File::Path;
  11 use IO::Socket::UNIX;
  12 use IO::Select;
  13
  14 use PVE::Tools qw(extract_param);
  15 use PVE::Cluster;
  16 use PVE::SafeSyslog;
  17 use PVE::INotify;
  18 use PVE::RPCEnvironment;
  19 use PVE::QemuServer;
  20 use PVE::QemuServer::ImportDisk;
  21 use PVE::API2::Qemu;
  22 use JSON;
  23 use PVE::JSONSchema qw(get_standard_option);
  24 use Term::ReadLine;
  25
  26 use PVE::CLIHandler;
  27
  28 use base qw(PVE::CLIHandler);
  29
  30 my $upid_exit = sub {
  31     my $upid = shift;
  32     my $status = PVE::Tools::upid_read_status($upid);
  33     exit($status eq 'OK' ? 0 : -1);
  34 };
  35
  36 my $nodename = PVE::INotify::nodename();
  37
  38 sub setup_environment {
  39     PVE::RPCEnvironment->setup_default_cli_env();
  40 }
  41
  42 sub run_vnc_proxy {
  43     my ($path) = @_;
  44
  45     my $c;
  46     while ( ++$c < 10 && !-e $path ) { sleep(1); }
  47
  48     my $s = IO::Socket::UNIX->new(Peer => $path, Timeout => 120);
  49
  50     die "unable to connect to socket '$path' - $!" if !$s;
  51
  52     my $select = new IO::Select;
  53
  54     $select->add(\*STDIN);
  55     $select->add($s);
  56
  57     my $timeout = 60*15; # 15 minutes
  58
  59     my @handles;
  60     while ($select->count &&
  61            scalar(@handles = $select->can_read ($timeout))) {
  62         foreach my $h (@handles) {
  63             my $buf;
  64             my $n = $h->sysread($buf, 4096);
  65
  66             if ($h == \*STDIN) {
  67                 if ($n) {
  68                     syswrite($s, $buf);
  69                 } else {
  70                     exit(0);
  71                 }
  72             } elsif ($h == $s) {
  73                 if ($n) {
  74                     syswrite(\*STDOUT, $buf);
  75                 } else {
  76                     exit(0);
  77                 }
  78             }
  79         }
  80     }
  81     exit(0);
  82 }
  83
  84 sub print_recursive_hash {
  85     my ($prefix, $hash, $key) = @_;
  86
  87     if (ref($hash) eq 'HASH') {
  88         if (defined($key)) {
  89             print "$prefix$key:\n";
  90         }
  91         foreach my $itemkey (keys %$hash) {
  92             print_recursive_hash("\t$prefix", $hash->{$itemkey}, $itemkey);
  93         }
  94     } elsif (ref($hash) eq 'ARRAY') {
  95         if (defined($key)) {
  96             print "$prefix$key:\n";
  97         }
  98         foreach my $item (@$hash) {
  99             print_recursive_hash("\t$prefix", $item);
 100         }
 101     } elsif (!ref($hash) && defined($hash)) {
 102         if (defined($key)) {
 103             print "$prefix$key: $hash\n";
 104         } else {
 105             print "$prefix$hash\n";
 106         }
 107     }
 108 }
 109
 110 __PACKAGE__->register_method ({
 111     name => 'showcmd',
 112     path => 'showcmd',
 113     method => 'GET',
 114     description => "Show command line which is used to start the VM (debug info).",
 115     parameters => {
 116         additionalProperties => 0,
 117         properties => {
 118             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 119         },
 120     },
 121     returns => { type => 'null'},
 122     code => sub {
 123         my ($param) = @_;
 124
 125         my $storecfg = PVE::Storage::config();
 126         print PVE::QemuServer::vm_commandline($storecfg, $param->{vmid}) . "\n";
 127
 128         return undef;
 129     }});
 130
 131 __PACKAGE__->register_method ({
 132     name => 'status',
 133     path => 'status',
 134     method => 'GET',
 135     description => "Show VM status.",
 136     parameters => {
 137         additionalProperties => 0,
 138         properties => {
 139             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 140             verbose => {
 141                 description => "Verbose output format",
 142                 type => 'boolean',
 143                 optional => 1,
 144             }
 145         },
 146     },
 147     returns => { type => 'null'},
 148     code => sub {
 149         my ($param) = @_;
 150
 151         # test if VM exists
 152         my $conf = PVE::QemuConfig->load_config ($param->{vmid});
 153
 154         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid}, 1);
 155         my $stat = $vmstatus->{$param->{vmid}};
 156         if ($param->{verbose}) {
 157             foreach my $k (sort (keys %$stat)) {
 158                 next if $k eq 'cpu' || $k eq 'relcpu'; # always 0
 159                 my $v = $stat->{$k};
 160                 print_recursive_hash("", $v, $k);
 161             }
 162         } else {
 163             my $status = $stat->{qmpstatus} || 'unknown';
 164             print "status: $status\n";
 165         }
 166
 167         return undef;
 168     }});
 169
 170 __PACKAGE__->register_method ({
 171     name => 'vncproxy',
 172     path => 'vncproxy',
 173     method => 'PUT',
 174     description => "Proxy VM VNC traffic to stdin/stdout",
 175     parameters => {
 176         additionalProperties => 0,
 177         properties => {
 178             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 179         },
 180     },
 181     returns => { type => 'null'},
 182     code => sub {
 183         my ($param) = @_;
 184
 185         my $vmid = $param->{vmid};
 186         my $vnc_socket = PVE::QemuServer::vnc_socket($vmid);
 187
 188         if (my $ticket = $ENV{LC_PVE_TICKET}) {  # NOTE: ssh on debian only pass LC_* variables
 189             PVE::QemuServer::vm_mon_cmd($vmid, "change", device => 'vnc', target => "unix:$vnc_socket,password");
 190             PVE::QemuServer::vm_mon_cmd($vmid, "set_password", protocol => 'vnc', password => $ticket);
 191             PVE::QemuServer::vm_mon_cmd($vmid, "expire_password", protocol => 'vnc', time => "+30");
 192         } else {
 193             PVE::QemuServer::vm_mon_cmd($vmid, "change", device => 'vnc', target => "unix:$vnc_socket,x509,password");
 194         }
 195
 196         run_vnc_proxy($vnc_socket);
 197
 198         return undef;
 199     }});
 200
 201 __PACKAGE__->register_method ({
 202     name => 'unlock',
 203     path => 'unlock',
 204     method => 'PUT',
 205     description => "Unlock the VM.",
 206     parameters => {
 207         additionalProperties => 0,
 208         properties => {
 209             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 210         },
 211     },
 212     returns => { type => 'null'},
 213     code => sub {
 214         my ($param) = @_;
 215
 216         my $vmid = $param->{vmid};
 217
 218         PVE::QemuConfig->lock_config ($vmid, sub {
 219             my $conf = PVE::QemuConfig->load_config($vmid);
 220             delete $conf->{lock};
 221             delete $conf->{pending}->{lock} if $conf->{pending}; # just to be sure
 222             PVE::QemuConfig->write_config($vmid, $conf);
 223         });
 224
 225         return undef;
 226     }});
 227
 228 __PACKAGE__->register_method ({
 229     name => 'nbdstop',
 230     path => 'nbdstop',
 231     method => 'PUT',
 232     description => "Stop embedded nbd server.",
 233     parameters => {
 234         additionalProperties => 0,
 235         properties => {
 236             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 237         },
 238     },
 239     returns => { type => 'null'},
 240     code => sub {
 241         my ($param) = @_;
 242
 243         my $vmid = $param->{vmid};
 244
 245         PVE::QemuServer::nbd_stop($vmid);
 246
 247         return undef;
 248     }});
 249
 250 __PACKAGE__->register_method ({
 251     name => 'mtunnel',
 252     path => 'mtunnel',
 253     method => 'POST',
 254     description => "Used by qmigrate - do not use manually.",
 255     parameters => {
 256         additionalProperties => 0,
 257         properties => {},
 258     },
 259     returns => { type => 'null'},
 260     code => sub {
 261         my ($param) = @_;
 262
 263         if (!PVE::Cluster::check_cfs_quorum(1)) {
 264             print "no quorum\n";
 265             return undef;
 266         }
 267
 268         print "tunnel online\n";
 269         *STDOUT->flush();
 270
 271         while (my $line = <>) {
 272             chomp $line;
 273             last if $line =~ m/^quit$/;
 274         }
 275
 276         return undef;
 277     }});
 278
 279 __PACKAGE__->register_method ({
 280     name => 'wait',
 281     path => 'wait',
 282     method => 'GET',
 283     description => "Wait until the VM is stopped.",
 284     parameters => {
 285         additionalProperties => 0,
 286         properties => {
 287             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 288             timeout => {
 289                 description => "Timeout in seconds. Default is to wait forever.",
 290                 type => 'integer',
 291                 minimum => 1,
 292                 optional => 1,
 293             }
 294         },
 295     },
 296     returns => { type => 'null'},
 297     code => sub {
 298         my ($param) = @_;
 299
 300         my $vmid = $param->{vmid};
 301         my $timeout = $param->{timeout};
 302
 303         my $pid = PVE::QemuServer::check_running ($vmid);
 304         return if !$pid;
 305
 306         print "waiting until VM $vmid stopps (PID $pid)\n";
 307
 308         my $count = 0;
 309         while ((!$timeout || ($count < $timeout)) && PVE::QemuServer::check_running ($vmid)) {
 310             $count++;
 311             sleep 1;
 312         }
 313
 314         die "wait failed - got timeout\n" if PVE::QemuServer::check_running ($vmid);
 315
 316         return undef;
 317     }});
 318
 319 __PACKAGE__->register_method ({
 320     name => 'monitor',
 321     path => 'monitor',
 322     method => 'POST',
 323     description => "Enter Qemu Monitor interface.",
 324     parameters => {
 325         additionalProperties => 0,
 326         properties => {
 327             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 328         },
 329     },
 330     returns => { type => 'null'},
 331     code => sub {
 332         my ($param) = @_;
 333
 334         my $vmid = $param->{vmid};
 335
 336         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
 337
 338         print "Entering Qemu Monitor for VM $vmid - type 'help' for help\n";
 339
 340         my $term = new Term::ReadLine ('qm');
 341
 342         my $input;
 343         while (defined ($input = $term->readline('qm> '))) {
 344             chomp $input;
 345
 346             next if $input =~ m/^\s*$/;
 347
 348             last if $input =~ m/^\s*q(uit)?\s*$/;
 349
 350             eval {
 351                 print PVE::QemuServer::vm_human_monitor_command ($vmid, $input);
 352             };
 353             print "ERROR: $@" if $@;
 354         }
 355
 356         return undef;
 357
 358     }});
 359
 360 __PACKAGE__->register_method ({
 361     name => 'rescan',
 362     path => 'rescan',
 363     method => 'POST',
 364     description => "Rescan all storages and update disk sizes and unused disk images.",
 365     parameters => {
 366         additionalProperties => 0,
 367         properties => {
 368             vmid => get_standard_option('pve-vmid', {
 369                 optional => 1,
 370                 completion => \&PVE::QemuServer::complete_vmid,
 371             }),
 372         },
 373     },
 374     returns => { type => 'null'},
 375     code => sub {
 376         my ($param) = @_;
 377
 378         PVE::QemuServer::rescan($param->{vmid});
 379
 380         return undef;
 381     }});
 382
 383 __PACKAGE__->register_method ({
 384     name => 'importdisk',
 385     path => 'importdisk',
 386     method => 'POST',
 387     description => "Import an external disk image as an unused disk in a VM. The
 388  image format has to be supported by qemu-img(1).",
 389     parameters => {
 390         additionalProperties => 0,
 391         properties => {
 392             vmid => get_standard_option('pve-vmid', {completion => \&PVE::QemuServer::complete_vmid}),
 393             source => {
 394                 description => 'Path to the disk image to import',
 395                 type => 'string',
 396                 optional => 0,
 397             },
 398             storage => get_standard_option('pve-storage-id', {
 399                 description => 'Target storage ID',
 400                 completion => \&PVE::QemuServer::complete_storage,
 401                 optional => 0,
 402             }),
 403             format => {
 404                 type => 'string',
 405                 description => 'Target format',
 406                 enum => [ 'raw', 'qcow2', 'vmdk' ],
 407                 optional => 1,
 408             },
 409         },
 410     },
 411     returns => { type => 'null'},
 412     code => sub {
 413         my ($param) = @_;
 414
 415         my $vmid = extract_param($param, 'vmid');
 416         my $source = extract_param($param, 'source');
 417         my $storeid = extract_param($param, 'storage');
 418         my $format = extract_param($param, 'format');
 419
 420         my $vm_conf = PVE::QemuConfig->load_config($vmid);
 421         PVE::QemuConfig->check_lock($vm_conf);
 422         die "$source: non-existent or non-regular file\n" if (! -f $source);
 423
 424         my $storecfg = PVE::Storage::config();
 425         PVE::Storage::storage_check_enabled($storecfg, $storeid);
 426
 427         my $target_storage_config =
 428             PVE::Storage::storage_config($storecfg, $storeid);
 429         die "storage $storeid does not support vm images\n"
 430             if !$target_storage_config->{content}->{images};
 431
 432         PVE::QemuServer::ImportDisk::do_import($source, $vmid, $storeid, { format => $format });
 433
 434         return undef;
 435     }});
 436
 437 __PACKAGE__->register_method ({
 438     name => 'terminal',
 439     path => 'terminal',
 440     method => 'POST',
 441     description => "Open a terminal using a serial device (The VM need to have a serial device configured, for example 'serial0: socket')",
 442     parameters => {
 443         additionalProperties => 0,
 444         properties => {
 445             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 446             iface => {
 447                 description => "Select the serial device. By default we simply use the first suitable device.",
 448                 type => 'string',
 449                 optional => 1,
 450                 enum => [qw(serial0 serial1 serial2 serial3)],
 451             }
 452         },
 453     },
 454     returns => { type => 'null'},
 455     code => sub {
 456         my ($param) = @_;
 457
 458         my $vmid = $param->{vmid};
 459
 460         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
 461
 462         my $iface = $param->{iface};
 463
 464         if ($iface) {
 465             die "serial interface '$iface' is not configured\n" if !$conf->{$iface};
 466             die "wrong serial type on interface '$iface'\n" if $conf->{$iface} ne 'socket';
 467         } else {
 468             foreach my $opt (qw(serial0 serial1 serial2 serial3)) {
 469                 if ($conf->{$opt} && ($conf->{$opt} eq 'socket')) {
 470                     $iface = $opt;
 471                     last;
 472                 }
 473             }
 474             die "unable to find a serial interface\n" if !$iface;
 475         }
 476
 477         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
 478
 479         my $socket = "/var/run/qemu-server/${vmid}.$iface";
 480
 481         my $cmd = "socat UNIX-CONNECT:$socket STDIO,raw,echo=0,escape=0x0f";
 482
 483         print "starting serial terminal on interface $iface (press control-O to exit)\n";
 484
 485         system($cmd);
 486
 487         return undef;
 488     }});
 489
 490
 491 my $print_agent_result = sub {
 492     my ($data) = @_;
 493
 494     my $result = $data->{result};
 495     return if !defined($result);
 496
 497     my $class = ref($result);
 498
 499     if (!$class) {
 500         chomp $result;
 501         return if $result =~ m/^\s*$/;
 502         print "$result\n";
 503         return;
 504     }
 505
 506     if (($class eq 'HASH') && !scalar(keys %$result)) { # empty hash
 507         return;
 508     }
 509
 510     print to_json($result, { pretty => 1, canonical => 1});
 511 };
 512
 513 our $cmddef = {
 514     list => [ "PVE::API2::Qemu", 'vmlist', [],
 515              { node => $nodename }, sub {
 516                  my $vmlist = shift;
 517
 518                  exit 0 if (!scalar(@$vmlist));
 519
 520                  printf "%10s %-20s %-10s %-10s %12s %-10s\n",
 521                  qw(VMID NAME STATUS MEM(MB) BOOTDISK(GB) PID);
 522
 523                  foreach my $rec (sort { $a->{vmid} <=> $b->{vmid} } @$vmlist) {
 524                      printf "%10s %-20s %-10s %-10s %12.2f %-10s\n", $rec->{vmid}, $rec->{name},
 525                      $rec->{qmpstatus} || $rec->{status},
 526                      ($rec->{maxmem} || 0)/(1024*1024),
 527                      ($rec->{maxdisk} || 0)/(1024*1024*1024),
 528                      $rec->{pid}||0;
 529                  }
 530
 531
 532               } ],
 533
 534     create => [ "PVE::API2::Qemu", 'create_vm', ['vmid'], { node => $nodename }, $upid_exit ],
 535
 536     destroy => [ "PVE::API2::Qemu", 'destroy_vm', ['vmid'], { node => $nodename }, $upid_exit ],
 537
 538     clone => [ "PVE::API2::Qemu", 'clone_vm', ['vmid', 'newid'], { node => $nodename }, $upid_exit ],
 539
 540     migrate => [ "PVE::API2::Qemu", 'migrate_vm', ['vmid', 'target'], { node => $nodename }, $upid_exit ],
 541
 542     set => [ "PVE::API2::Qemu", 'update_vm', ['vmid'], { node => $nodename } ],
 543
 544     resize => [ "PVE::API2::Qemu", 'resize_vm', ['vmid', 'disk', 'size'], { node => $nodename } ],
 545
 546     move_disk => [ "PVE::API2::Qemu", 'move_vm_disk', ['vmid', 'disk', 'storage'], { node => $nodename }, $upid_exit ],
 547
 548     unlink => [ "PVE::API2::Qemu", 'unlink', ['vmid'], { node => $nodename } ],
 549
 550     config => [ "PVE::API2::Qemu", 'vm_config', ['vmid'],
 551                 { node => $nodename }, sub {
 552                     my $config = shift;
 553                     foreach my $k (sort (keys %$config)) {
 554                         next if $k eq 'digest';
 555                         my $v = $config->{$k};
 556                         if ($k eq 'description') {
 557                             $v = PVE::Tools::encode_text($v);
 558                         }
 559                         print "$k: $v\n";
 560                     }
 561                 }],
 562
 563     pending => [ "PVE::API2::Qemu", 'vm_pending', ['vmid'],
 564                 { node => $nodename }, sub {
 565                     my $data = shift;
 566                     foreach my $item (sort { $a->{key} cmp $b->{key}} @$data) {
 567                         my $k = $item->{key};
 568                         next if $k eq 'digest';
 569                         my $v = $item->{value};
 570                         my $p = $item->{pending};
 571                         if ($k eq 'description') {
 572                             $v = PVE::Tools::encode_text($v) if defined($v);
 573                             $p = PVE::Tools::encode_text($p) if defined($p);
 574                         }
 575                         if (defined($v)) {
 576                             if ($item->{delete}) {
 577                                 print "del $k: $v\n";
 578                             } elsif (defined($p)) {
 579                                 print "cur $k: $v\n";
 580                                 print "new $k: $p\n";
 581                             } else {
 582                                 print "cur $k: $v\n";
 583                             }
 584                         } elsif (defined($p)) {
 585                             print "new $k: $p\n";
 586                         }
 587                     }
 588                 }],
 589
 590     showcmd => [ __PACKAGE__, 'showcmd', ['vmid']],
 591
 592     status => [ __PACKAGE__, 'status', ['vmid']],
 593
 594     snapshot => [ "PVE::API2::Qemu", 'snapshot', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 595
 596     delsnapshot => [ "PVE::API2::Qemu", 'delsnapshot', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 597
 598     listsnapshot => [ "PVE::API2::Qemu", 'snapshot_list', ['vmid'], { node => $nodename },
 599                     sub {
 600                         my $res = shift;
 601                         foreach my $e (@$res) {
 602                             my $headline = $e->{description} || 'no-description';
 603                             $headline =~ s/\n.*//sg;
 604                             my $parent = $e->{parent} // 'no-parent';
 605                             printf("%-20s %-20s %s\n", $e->{name}, $parent, $headline);
 606                         }
 607                     }],
 608
 609     rollback => [ "PVE::API2::Qemu", 'rollback', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 610
 611     template => [ "PVE::API2::Qemu", 'template', ['vmid'], { node => $nodename }],
 612
 613     start => [ "PVE::API2::Qemu", 'vm_start', ['vmid'], { node => $nodename } , $upid_exit ],
 614
 615     stop => [ "PVE::API2::Qemu", 'vm_stop', ['vmid'], { node => $nodename }, $upid_exit ],
 616
 617     reset => [ "PVE::API2::Qemu", 'vm_reset', ['vmid'], { node => $nodename }, $upid_exit ],
 618
 619     shutdown => [ "PVE::API2::Qemu", 'vm_shutdown', ['vmid'], { node => $nodename }, $upid_exit ],
 620
 621     suspend => [ "PVE::API2::Qemu", 'vm_suspend', ['vmid'], { node => $nodename }, $upid_exit ],
 622
 623     resume => [ "PVE::API2::Qemu", 'vm_resume', ['vmid'], { node => $nodename }, $upid_exit ],
 624
 625     sendkey => [ "PVE::API2::Qemu", 'vm_sendkey', ['vmid', 'key'], { node => $nodename } ],
 626
 627     vncproxy => [ __PACKAGE__, 'vncproxy', ['vmid']],
 628
 629     wait => [ __PACKAGE__, 'wait', ['vmid']],
 630
 631     unlock => [ __PACKAGE__, 'unlock', ['vmid']],
 632
 633     rescan  => [ __PACKAGE__, 'rescan', []],
 634
 635     monitor  => [ __PACKAGE__, 'monitor', ['vmid']],
 636
 637     agent  => [ "PVE::API2::Qemu", 'agent', ['vmid', 'command'],
 638                 { node => $nodename }, $print_agent_result ],
 639
 640     mtunnel => [ __PACKAGE__, 'mtunnel', []],
 641
 642     nbdstop => [ __PACKAGE__, 'nbdstop', ['vmid']],
 643
 644     terminal => [ __PACKAGE__, 'terminal', ['vmid']],
 645
 646     importdisk => [ __PACKAGE__, 'importdisk', ['vmid', 'source', 'storage']],
 647 };
 648
 649 1;