PVE/QemuConfig.pm

   1 package PVE::QemuConfig;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::AbstractConfig;
   7 use PVE::INotify;
   8 use PVE::QemuServer;
   9 use PVE::Storage;
  10 use PVE::Tools;
  11
  12 use base qw(PVE::AbstractConfig);
  13
  14 my $nodename = PVE::INotify::nodename();
  15
  16 mkdir "/etc/pve/nodes/$nodename";
  17 my $confdir = "/etc/pve/nodes/$nodename/qemu-server";
  18 mkdir $confdir;
  19
  20 my $lock_dir = "/var/lock/qemu-server";
  21 mkdir $lock_dir;
  22
  23 my $MAX_UNUSED_DISKS = 8;
  24
  25 # BEGIN implemented abstract methods from PVE::AbstractConfig
  26
  27 sub guest_type {
  28     return "VM";
  29 }
  30
  31 sub __config_max_unused_disks {
  32     my ($class) = @_;
  33
  34     return $MAX_UNUSED_DISKS;
  35 }
  36
  37 sub config_file_lock {
  38     my ($class, $vmid) = @_;
  39
  40     return "$lock_dir/lock-$vmid.conf";
  41 }
  42
  43 sub cfs_config_path {
  44     my ($class, $vmid, $node) = @_;
  45
  46     $node = $nodename if !$node;
  47     return "nodes/$node/qemu-server/$vmid.conf";
  48 }
  49
  50 sub has_feature {
  51     my ($class, $feature, $conf, $storecfg, $snapname, $running, $backup_only) = @_;
  52
  53     my $err;
  54     PVE::QemuServer::foreach_drive($conf, sub {
  55         my ($ds, $drive) = @_;
  56
  57         return if PVE::QemuServer::drive_is_cdrom($drive);
  58         return if $backup_only && defined($drive->{backup}) && !$drive->{backup};
  59         my $volid = $drive->{file};
  60         $err = 1 if !PVE::Storage::volume_has_feature($storecfg, $feature, $volid, $snapname, $running);
  61    });
  62
  63     return $err ? 0 : 1;
  64 }
  65
  66 sub get_replicatable_volumes {
  67     my ($class, $storecfg, $vmid, $conf, $cleanup, $noerr) = @_;
  68
  69     my $volhash = {};
  70
  71     my $test_volid = sub {
  72         my ($volid, $attr) = @_;
  73
  74         return if $attr->{cdrom};
  75
  76         return if !$cleanup && !$attr->{replicate};
  77
  78         if ($volid =~ m|^/|) {
  79             return if !$attr->{replicate};
  80             return if $cleanup || $noerr;
  81             die "unable to replicate local file/device '$volid'\n";
  82         }
  83
  84         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, $noerr);
  85         return if !$storeid;
  86
  87         my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
  88         return if $scfg->{shared};
  89
  90         my ($path, $owner, $vtype) = PVE::Storage::path($storecfg, $volid);
  91         return if !$owner || ($owner != $vmid);
  92
  93         if ($vtype ne 'images') {
  94             return if $cleanup || $noerr;
  95             die "unable to replicate volume '$volid', type '$vtype'\n";
  96         }
  97
  98         if (!PVE::Storage::volume_has_feature($storecfg, 'replicate', $volid)) {
  99             return if $cleanup || $noerr;
 100             die "missing replicate feature on volume '$volid'\n";
 101         }
 102
 103         $volhash->{$volid} = 1;
 104     };
 105
 106     PVE::QemuServer::foreach_volid($conf, $test_volid);
 107
 108     # add 'unusedX' volumes to volhash
 109     foreach my $key (keys %$conf) {
 110         if ($key =~ m/^unused/) {
 111             $test_volid->($conf->{$key}, { replicate => 1 });
 112         }
 113     }
 114
 115     return $volhash;
 116 }
 117
 118 sub __snapshot_save_vmstate {
 119     my ($class, $vmid, $conf, $snapname, $storecfg) = @_;
 120
 121     my $snap = $conf->{snapshots}->{$snapname};
 122
 123     # first, use explicitly configured storage
 124     my $target = $conf->{vmstatestorage};
 125
 126     if (!$target) {
 127         my ($shared, $local);
 128         PVE::QemuServer::foreach_storage_used_by_vm($conf, sub {
 129             my ($sid) = @_;
 130             my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 131             my $dst = $scfg->{shared} ? \$shared : \$local;
 132             $$dst = $sid if !$$dst || $scfg->{path}; # prefer file based storage
 133         });
 134
 135         # second, use shared storage where VM has at least one disk
 136         # third, use local storage where VM has at least one disk
 137         # fall back to local storage
 138         $target = $shared // $local // 'local';
 139     }
 140
 141     my $driver_state_size = 500; # assume 32MB is enough to safe all driver state;
 142     # we abort live save after $conf->{memory}, so we need at max twice that space
 143     my $size = $conf->{memory}*2 + $driver_state_size;
 144
 145     my $name = "vm-$vmid-state-$snapname";
 146     my $scfg = PVE::Storage::storage_config($storecfg, $target);
 147     $name .= ".raw" if $scfg->{path}; # add filename extension for file base storage
 148     $snap->{vmstate} = PVE::Storage::vdisk_alloc($storecfg, $target, $vmid, 'raw', $name, $size*1024);
 149     # always overwrite machine if we save vmstate. This makes sure we
 150     # can restore it later using correct machine type
 151     $snap->{machine} = PVE::QemuServer::get_current_qemu_machine($vmid);
 152 }
 153
 154 sub __snapshot_check_running {
 155     my ($class, $vmid) = @_;
 156     return PVE::QemuServer::check_running($vmid);
 157 }
 158
 159 sub __snapshot_check_freeze_needed {
 160     my ($class, $vmid, $config, $save_vmstate) = @_;
 161
 162     my $running = $class->__snapshot_check_running($vmid);
 163     if (!$save_vmstate) {
 164         return ($running, $running && PVE::QemuServer::parse_guest_agent($config)->{enabled} && PVE::QemuServer::qga_check_running($vmid));
 165     } else {
 166         return ($running, 0);
 167     }
 168 }
 169
 170 sub __snapshot_freeze {
 171     my ($class, $vmid, $unfreeze) = @_;
 172
 173     if ($unfreeze) {
 174         eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-thaw"); };
 175         warn "guest-fsfreeze-thaw problems - $@" if $@;
 176     } else {
 177         eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-freeze"); };
 178         warn "guest-fsfreeze-freeze problems - $@" if $@;
 179     }
 180 }
 181
 182 sub __snapshot_create_vol_snapshots_hook {
 183     my ($class, $vmid, $snap, $running, $hook) = @_;
 184
 185     if ($running) {
 186         my $storecfg = PVE::Storage::config();
 187
 188         if ($hook eq "before") {
 189             if ($snap->{vmstate}) {
 190                 my $path = PVE::Storage::path($storecfg, $snap->{vmstate});
 191                 PVE::Storage::activate_volumes($storecfg, [$snap->{vmstate}]);
 192
 193                 PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start", statefile => $path);
 194                 for(;;) {
 195                     my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
 196                     if (!$stat->{status}) {
 197                         die "savevm not active\n";
 198                     } elsif ($stat->{status} eq 'active') {
 199                         sleep(1);
 200                         next;
 201                     } elsif ($stat->{status} eq 'completed') {
 202                         last;
 203                     } else {
 204                         die "query-savevm returned status '$stat->{status}'\n";
 205                     }
 206                 }
 207             } else {
 208                 PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start");
 209             }
 210         } elsif ($hook eq "after") {
 211             eval {
 212                 PVE::QemuServer::vm_mon_cmd($vmid, "savevm-end");
 213                 PVE::Storage::deactivate_volumes($storecfg, [$snap->{vmstate}]) if $snap->{vmstate};
 214             };
 215             warn $@ if $@;
 216         } elsif ($hook eq "after-freeze") {
 217             # savevm-end is async, we need to wait
 218             for (;;) {
 219                 my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
 220                 if (!$stat->{bytes}) {
 221                     last;
 222                 } else {
 223                     print "savevm not yet finished\n";
 224                     sleep(1);
 225                     next;
 226                 }
 227             }
 228         }
 229     }
 230 }
 231
 232 sub __snapshot_create_vol_snapshot {
 233     my ($class, $vmid, $ds, $drive, $snapname) = @_;
 234
 235     return if PVE::QemuServer::drive_is_cdrom($drive);
 236
 237     my $volid = $drive->{file};
 238     my $device = "drive-$ds";
 239     my $storecfg = PVE::Storage::config();
 240
 241     PVE::QemuServer::qemu_volume_snapshot($vmid, $device, $storecfg, $volid, $snapname);
 242 }
 243
 244 sub __snapshot_delete_remove_drive {
 245     my ($class, $snap, $remove_drive) = @_;
 246
 247     if ($remove_drive eq 'vmstate') {
 248         delete $snap->{$remove_drive};
 249     } else {
 250         my $drive = PVE::QemuServer::parse_drive($remove_drive, $snap->{$remove_drive});
 251         return if PVE::QemuServer::drive_is_cdrom($drive);
 252
 253         my $volid = $drive->{file};
 254         delete $snap->{$remove_drive};
 255         $class->add_unused_volume($snap, $volid);
 256     }
 257 }
 258
 259 sub __snapshot_delete_vmstate_file {
 260     my ($class, $snap, $force) = @_;
 261
 262     my $storecfg = PVE::Storage::config();
 263
 264     eval {  PVE::Storage::vdisk_free($storecfg, $snap->{vmstate}); };
 265     if (my $err = $@) {
 266         die $err if !$force;
 267         warn $err;
 268     }
 269 }
 270
 271 sub __snapshot_delete_vol_snapshot {
 272     my ($class, $vmid, $ds, $drive, $snapname, $unused) = @_;
 273
 274     return if PVE::QemuServer::drive_is_cdrom($drive);
 275     my $storecfg = PVE::Storage::config();
 276     my $volid = $drive->{file};
 277     my $device = "drive-$ds";
 278
 279     PVE::QemuServer::qemu_volume_snapshot_delete($vmid, $device, $storecfg, $volid, $snapname);
 280
 281     push @$unused, $volid;
 282 }
 283
 284 sub __snapshot_rollback_vol_possible {
 285     my ($class, $drive, $snapname) = @_;
 286
 287     return if PVE::QemuServer::drive_is_cdrom($drive);
 288
 289     my $storecfg = PVE::Storage::config();
 290     my $volid = $drive->{file};
 291
 292     PVE::Storage::volume_rollback_is_possible($storecfg, $volid, $snapname);
 293 }
 294
 295 sub __snapshot_rollback_vol_rollback {
 296     my ($class, $drive, $snapname) = @_;
 297
 298     return if PVE::QemuServer::drive_is_cdrom($drive);
 299
 300     my $storecfg = PVE::Storage::config();
 301     PVE::Storage::volume_snapshot_rollback($storecfg, $drive->{file}, $snapname);
 302 }
 303
 304 sub __snapshot_rollback_vm_stop {
 305     my ($class, $vmid) = @_;
 306
 307     my $storecfg = PVE::Storage::config();
 308     PVE::QemuServer::vm_stop($storecfg, $vmid, undef, undef, 5, undef, undef);
 309 }
 310
 311 sub __snapshot_rollback_vm_start {
 312     my ($class, $vmid, $vmstate, $forcemachine) = @_;
 313
 314     my $storecfg = PVE::Storage::config();
 315     my $statefile = PVE::Storage::path($storecfg, $vmstate);
 316     PVE::QemuServer::vm_start($storecfg, $vmid, $statefile, undef, undef, undef, $forcemachine);
 317 }
 318
 319 sub __snapshot_rollback_get_unused {
 320     my ($class, $conf, $snap) = @_;
 321
 322     my $unused = [];
 323
 324     $class->__snapshot_foreach_volume($conf, sub {
 325         my ($vs, $volume) = @_;
 326
 327         return if PVE::QemuServer::drive_is_cdrom($volume);
 328
 329         my $found = 0;
 330         my $volid = $volume->{file};
 331
 332         $class->__snapshot_foreach_volume($snap, sub {
 333             my ($ds, $drive) = @_;
 334
 335             return if $found;
 336             return if PVE::QemuServer::drive_is_cdrom($drive);
 337
 338             $found = 1
 339                 if ($drive->{file} && $drive->{file} eq $volid);
 340         });
 341
 342         push @$unused, $volid if !$found;
 343     });
 344
 345     return $unused;
 346 }
 347
 348 sub __snapshot_foreach_volume {
 349     my ($class, $conf, $func) = @_;
 350
 351     PVE::QemuServer::foreach_drive($conf, $func);
 352 }
 353 # END implemented abstract methods from PVE::AbstractConfig
 354
 355 1;