PVE/QemuConfig.pm

   1 package PVE::QemuConfig;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::AbstractConfig;
   7 use PVE::INotify;
   8 use PVE::QemuServer;
   9 use PVE::Storage;
  10 use PVE::Tools;
  11
  12 use base qw(PVE::AbstractConfig);
  13
  14 my $nodename = PVE::INotify::nodename();
  15
  16 mkdir "/etc/pve/nodes/$nodename";
  17 my $confdir = "/etc/pve/nodes/$nodename/qemu-server";
  18 mkdir $confdir;
  19
  20 my $lock_dir = "/var/lock/qemu-server";
  21 mkdir $lock_dir;
  22
  23 my $MAX_UNUSED_DISKS = 256;
  24
  25 # BEGIN implemented abstract methods from PVE::AbstractConfig
  26
  27 sub guest_type {
  28     return "VM";
  29 }
  30
  31 sub __config_max_unused_disks {
  32     my ($class) = @_;
  33
  34     return $MAX_UNUSED_DISKS;
  35 }
  36
  37 sub config_file_lock {
  38     my ($class, $vmid) = @_;
  39
  40     return "$lock_dir/lock-$vmid.conf";
  41 }
  42
  43 sub cfs_config_path {
  44     my ($class, $vmid, $node) = @_;
  45
  46     $node = $nodename if !$node;
  47     return "nodes/$node/qemu-server/$vmid.conf";
  48 }
  49
  50 sub has_feature {
  51     my ($class, $feature, $conf, $storecfg, $snapname, $running, $backup_only) = @_;
  52
  53     my $err;
  54     PVE::QemuServer::foreach_drive($conf, sub {
  55         my ($ds, $drive) = @_;
  56
  57         return if PVE::QemuServer::drive_is_cdrom($drive);
  58         return if $backup_only && defined($drive->{backup}) && !$drive->{backup};
  59         my $volid = $drive->{file};
  60         $err = 1 if !PVE::Storage::volume_has_feature($storecfg, $feature, $volid, $snapname, $running);
  61    });
  62
  63     return $err ? 0 : 1;
  64 }
  65
  66 sub get_replicatable_volumes {
  67     my ($class, $storecfg, $vmid, $conf, $cleanup, $noerr) = @_;
  68
  69     my $volhash = {};
  70
  71     my $test_volid = sub {
  72         my ($volid, $attr) = @_;
  73
  74         return if $attr->{cdrom};
  75
  76         return if !$cleanup && !$attr->{replicate};
  77
  78         if ($volid =~ m|^/|) {
  79             return if !$attr->{replicate};
  80             return if $cleanup || $noerr;
  81             die "unable to replicate local file/device '$volid'\n";
  82         }
  83
  84         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, $noerr);
  85         return if !$storeid;
  86
  87         my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
  88         return if $scfg->{shared};
  89
  90         my ($path, $owner, $vtype) = PVE::Storage::path($storecfg, $volid);
  91         return if !$owner || ($owner != $vmid);
  92
  93         if ($vtype ne 'images') {
  94             return if $cleanup || $noerr;
  95             die "unable to replicate volume '$volid', type '$vtype'\n";
  96         }
  97
  98         if (!PVE::Storage::volume_has_feature($storecfg, 'replicate', $volid)) {
  99             return if $cleanup || $noerr;
 100             die "missing replicate feature on volume '$volid'\n";
 101         }
 102
 103         $volhash->{$volid} = 1;
 104     };
 105
 106     PVE::QemuServer::foreach_volid($conf, $test_volid);
 107
 108     # add 'unusedX' volumes to volhash
 109     foreach my $key (keys %$conf) {
 110         if ($key =~ m/^unused/) {
 111             $test_volid->($conf->{$key}, { replicate => 1 });
 112         }
 113     }
 114
 115     return $volhash;
 116 }
 117
 118 sub __snapshot_save_vmstate {
 119     my ($class, $vmid, $conf, $snapname, $storecfg) = @_;
 120
 121     my $snap = $conf->{snapshots}->{$snapname};
 122
 123     # first, use explicitly configured storage
 124     my $target = $conf->{vmstatestorage};
 125
 126     if (!$target) {
 127         my ($shared, $local);
 128         PVE::QemuServer::foreach_storage_used_by_vm($conf, sub {
 129             my ($sid) = @_;
 130             my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 131             my $dst = $scfg->{shared} ? \$shared : \$local;
 132             $$dst = $sid if !$$dst || $scfg->{path}; # prefer file based storage
 133         });
 134
 135         # second, use shared storage where VM has at least one disk
 136         # third, use local storage where VM has at least one disk
 137         # fall back to local storage
 138         $target = $shared // $local // 'local';
 139     }
 140
 141     my $driver_state_size = 500; # assume 500MB is enough to safe all driver state;
 142     my $size = $conf->{memory}*2 + $driver_state_size;
 143
 144     my $name = "vm-$vmid-state-$snapname";
 145     my $scfg = PVE::Storage::storage_config($storecfg, $target);
 146     $name .= ".raw" if $scfg->{path}; # add filename extension for file base storage
 147     $snap->{vmstate} = PVE::Storage::vdisk_alloc($storecfg, $target, $vmid, 'raw', $name, $size*1024);
 148     $snap->{runningmachine} = PVE::QemuServer::get_current_qemu_machine($vmid);
 149 }
 150
 151 sub __snapshot_check_running {
 152     my ($class, $vmid) = @_;
 153     return PVE::QemuServer::check_running($vmid);
 154 }
 155
 156 sub __snapshot_check_freeze_needed {
 157     my ($class, $vmid, $config, $save_vmstate) = @_;
 158
 159     my $running = $class->__snapshot_check_running($vmid);
 160     if (!$save_vmstate) {
 161         return ($running, $running && PVE::QemuServer::parse_guest_agent($config)->{enabled} && PVE::QemuServer::qga_check_running($vmid));
 162     } else {
 163         return ($running, 0);
 164     }
 165 }
 166
 167 sub __snapshot_freeze {
 168     my ($class, $vmid, $unfreeze) = @_;
 169
 170     if ($unfreeze) {
 171         eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-thaw"); };
 172         warn "guest-fsfreeze-thaw problems - $@" if $@;
 173     } else {
 174         eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-freeze"); };
 175         warn "guest-fsfreeze-freeze problems - $@" if $@;
 176     }
 177 }
 178
 179 sub __snapshot_create_vol_snapshots_hook {
 180     my ($class, $vmid, $snap, $running, $hook) = @_;
 181
 182     if ($running) {
 183         my $storecfg = PVE::Storage::config();
 184
 185         if ($hook eq "before") {
 186             if ($snap->{vmstate}) {
 187                 my $path = PVE::Storage::path($storecfg, $snap->{vmstate});
 188                 PVE::Storage::activate_volumes($storecfg, [$snap->{vmstate}]);
 189
 190                 PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start", statefile => $path);
 191                 for(;;) {
 192                     my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
 193                     if (!$stat->{status}) {
 194                         die "savevm not active\n";
 195                     } elsif ($stat->{status} eq 'active') {
 196                         sleep(1);
 197                         next;
 198                     } elsif ($stat->{status} eq 'completed') {
 199                         last;
 200                     } else {
 201                         die "query-savevm returned status '$stat->{status}'\n";
 202                     }
 203                 }
 204             } else {
 205                 PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start");
 206             }
 207         } elsif ($hook eq "after") {
 208             eval {
 209                 PVE::QemuServer::vm_mon_cmd($vmid, "savevm-end");
 210                 PVE::Storage::deactivate_volumes($storecfg, [$snap->{vmstate}]) if $snap->{vmstate};
 211             };
 212             warn $@ if $@;
 213         } elsif ($hook eq "after-freeze") {
 214             # savevm-end is async, we need to wait
 215             for (;;) {
 216                 my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
 217                 if (!$stat->{bytes}) {
 218                     last;
 219                 } else {
 220                     print "savevm not yet finished\n";
 221                     sleep(1);
 222                     next;
 223                 }
 224             }
 225         }
 226     }
 227 }
 228
 229 sub __snapshot_create_vol_snapshot {
 230     my ($class, $vmid, $ds, $drive, $snapname) = @_;
 231
 232     return if PVE::QemuServer::drive_is_cdrom($drive);
 233
 234     my $volid = $drive->{file};
 235     my $device = "drive-$ds";
 236     my $storecfg = PVE::Storage::config();
 237
 238     PVE::QemuServer::qemu_volume_snapshot($vmid, $device, $storecfg, $volid, $snapname);
 239 }
 240
 241 sub __snapshot_delete_remove_drive {
 242     my ($class, $snap, $remove_drive) = @_;
 243
 244     if ($remove_drive eq 'vmstate') {
 245         delete $snap->{$remove_drive};
 246     } else {
 247         my $drive = PVE::QemuServer::parse_drive($remove_drive, $snap->{$remove_drive});
 248         return if PVE::QemuServer::drive_is_cdrom($drive);
 249
 250         my $volid = $drive->{file};
 251         delete $snap->{$remove_drive};
 252         $class->add_unused_volume($snap, $volid);
 253     }
 254 }
 255
 256 sub __snapshot_delete_vmstate_file {
 257     my ($class, $snap, $force) = @_;
 258
 259     my $storecfg = PVE::Storage::config();
 260
 261     eval {  PVE::Storage::vdisk_free($storecfg, $snap->{vmstate}); };
 262     if (my $err = $@) {
 263         die $err if !$force;
 264         warn $err;
 265     }
 266 }
 267
 268 sub __snapshot_delete_vol_snapshot {
 269     my ($class, $vmid, $ds, $drive, $snapname, $unused) = @_;
 270
 271     return if PVE::QemuServer::drive_is_cdrom($drive);
 272     my $storecfg = PVE::Storage::config();
 273     my $volid = $drive->{file};
 274     my $device = "drive-$ds";
 275
 276     PVE::QemuServer::qemu_volume_snapshot_delete($vmid, $device, $storecfg, $volid, $snapname);
 277
 278     push @$unused, $volid;
 279 }
 280
 281 sub __snapshot_rollback_hook {
 282     my ($class, $vmid, $conf, $snap, $prepare, $data) = @_;
 283
 284     if ($prepare) {
 285         # we save the machine of the current config
 286         $data->{oldmachine} = $conf->{machine};
 287     } else {
 288         # if we have a 'runningmachine' entry in the snapshot we use that
 289         # for the forcemachine parameter, else we use the old logic
 290         if (defined($conf->{runningmachine})) {
 291             $data->{forcemachine} = $conf->{runningmachine};
 292             delete $conf->{runningmachine};
 293         } else {
 294             # Note: old code did not store 'machine', so we try to be smart
 295             # and guess the snapshot was generated with kvm 1.4 (pc-i440fx-1.4).
 296             $data->{forcemachine} = $conf->{machine} || 'pc-i440fx-1.4';
 297
 298             # we remove the 'machine' configuration if not explicitly specified
 299             # in the original config.
 300             delete $conf->{machine} if $snap->{vmstate} && !defined($data->{oldmachine});
 301         }
 302
 303         if ($conf->{vmgenid}) {
 304             # tell the VM that it's another generation, so it can react
 305             # appropriately, e.g. dirty-mark copies of distributed databases or
 306             # re-initializing its random number generator
 307             $conf->{vmgenid} = PVE::QemuServer::generate_uuid();
 308         }
 309     }
 310
 311     return;
 312 }
 313
 314 sub __snapshot_rollback_vol_possible {
 315     my ($class, $drive, $snapname) = @_;
 316
 317     return if PVE::QemuServer::drive_is_cdrom($drive);
 318
 319     my $storecfg = PVE::Storage::config();
 320     my $volid = $drive->{file};
 321
 322     PVE::Storage::volume_rollback_is_possible($storecfg, $volid, $snapname);
 323 }
 324
 325 sub __snapshot_rollback_vol_rollback {
 326     my ($class, $drive, $snapname) = @_;
 327
 328     return if PVE::QemuServer::drive_is_cdrom($drive);
 329
 330     my $storecfg = PVE::Storage::config();
 331     PVE::Storage::volume_snapshot_rollback($storecfg, $drive->{file}, $snapname);
 332 }
 333
 334 sub __snapshot_rollback_vm_stop {
 335     my ($class, $vmid) = @_;
 336
 337     my $storecfg = PVE::Storage::config();
 338     PVE::QemuServer::vm_stop($storecfg, $vmid, undef, undef, 5, undef, undef);
 339 }
 340
 341 sub __snapshot_rollback_vm_start {
 342     my ($class, $vmid, $vmstate, $data) = @_;
 343
 344     my $storecfg = PVE::Storage::config();
 345     my $statefile = PVE::Storage::path($storecfg, $vmstate);
 346     PVE::QemuServer::vm_start($storecfg, $vmid, $statefile, undef, undef, undef, $data->{forcemachine});
 347 }
 348
 349 sub __snapshot_rollback_get_unused {
 350     my ($class, $conf, $snap) = @_;
 351
 352     my $unused = [];
 353
 354     $class->__snapshot_foreach_volume($conf, sub {
 355         my ($vs, $volume) = @_;
 356
 357         return if PVE::QemuServer::drive_is_cdrom($volume);
 358
 359         my $found = 0;
 360         my $volid = $volume->{file};
 361
 362         $class->__snapshot_foreach_volume($snap, sub {
 363             my ($ds, $drive) = @_;
 364
 365             return if $found;
 366             return if PVE::QemuServer::drive_is_cdrom($drive);
 367
 368             $found = 1
 369                 if ($drive->{file} && $drive->{file} eq $volid);
 370         });
 371
 372         push @$unused, $volid if !$found;
 373     });
 374
 375     return $unused;
 376 }
 377
 378 sub __snapshot_foreach_volume {
 379     my ($class, $conf, $func) = @_;
 380
 381     PVE::QemuServer::foreach_drive($conf, $func);
 382 }
 383 # END implemented abstract methods from PVE::AbstractConfig
 384
 385 1;