PVE/QemuConfig.pm

   1 package PVE::QemuConfig;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::AbstractConfig;
   7 use PVE::INotify;
   8 use PVE::JSONSchema;
   9 use PVE::QemuServer::CPUConfig;
  10 use PVE::QemuServer::Drive;
  11 use PVE::QemuServer::Helpers;
  12 use PVE::QemuServer::Monitor qw(mon_cmd);
  13 use PVE::QemuServer;
  14 use PVE::QemuServer::Machine;
  15 use PVE::QemuServer::Memory qw(get_current_memory);
  16 use PVE::Storage;
  17 use PVE::Tools;
  18 use PVE::Format qw(render_bytes render_duration);
  19
  20 use base qw(PVE::AbstractConfig);
  21
  22 my $nodename = PVE::INotify::nodename();
  23
  24 mkdir "/etc/pve/nodes/$nodename";
  25 mkdir "/etc/pve/nodes/$nodename/qemu-server";
  26
  27 my $lock_dir = "/var/lock/qemu-server";
  28 mkdir $lock_dir;
  29
  30 sub assert_config_exists_on_node {
  31     my ($vmid, $node) = @_;
  32
  33     $node //= $nodename;
  34
  35     my $filename = __PACKAGE__->config_file($vmid, $node);
  36     my $exists = -f $filename;
  37
  38     my $type = guest_type();
  39     die "unable to find configuration file for $type $vmid on node '$node'\n"
  40         if !$exists;
  41 }
  42
  43 # BEGIN implemented abstract methods from PVE::AbstractConfig
  44
  45 sub guest_type {
  46     return "VM";
  47 }
  48
  49 sub __config_max_unused_disks {
  50     my ($class) = @_;
  51
  52     return $PVE::QemuServer::Drive::MAX_UNUSED_DISKS;
  53 }
  54
  55 sub config_file_lock {
  56     my ($class, $vmid) = @_;
  57
  58     return "$lock_dir/lock-$vmid.conf";
  59 }
  60
  61 sub cfs_config_path {
  62     my ($class, $vmid, $node) = @_;
  63
  64     $node = $nodename if !$node;
  65     return "nodes/$node/qemu-server/$vmid.conf";
  66 }
  67
  68 sub has_feature {
  69     my ($class, $feature, $conf, $storecfg, $snapname, $running, $backup_only) = @_;
  70
  71     my $err;
  72     $class->foreach_volume($conf, sub {
  73         my ($ds, $drive) = @_;
  74
  75         return if PVE::QemuServer::drive_is_cdrom($drive);
  76         return if $backup_only && defined($drive->{backup}) && !$drive->{backup};
  77         my $volid = $drive->{file};
  78         $err = 1 if !PVE::Storage::volume_has_feature($storecfg, $feature, $volid, $snapname, $running);
  79    });
  80
  81     return $err ? 0 : 1;
  82 }
  83
  84 sub valid_volume_keys {
  85     my ($class, $reverse) = @_;
  86
  87     my @keys = PVE::QemuServer::Drive::valid_drive_names();
  88
  89     return $reverse ? reverse @keys : @keys;
  90 }
  91
  92 # FIXME: adapt parse_drive to use $noerr for better error messages
  93 sub parse_volume {
  94     my ($class, $key, $volume_string, $noerr) = @_;
  95
  96     my $volume;
  97     if ($key eq 'vmstate') {
  98         eval { PVE::JSONSchema::check_format('pve-volume-id', $volume_string) };
  99         if (my $err = $@) {
 100             return if $noerr;
 101             die $err;
 102         }
 103         $volume = { 'file' => $volume_string };
 104     } else {
 105         $volume = PVE::QemuServer::Drive::parse_drive($key, $volume_string);
 106     }
 107
 108     die "unable to parse volume\n" if !defined($volume) && !$noerr;
 109
 110     return $volume;
 111 }
 112
 113 sub print_volume {
 114     my ($class, $key, $volume) = @_;
 115
 116     return PVE::QemuServer::Drive::print_drive($volume);
 117 }
 118
 119 sub volid_key {
 120     my ($class) = @_;
 121
 122     return 'file';
 123 }
 124
 125 sub get_replicatable_volumes {
 126     my ($class, $storecfg, $vmid, $conf, $cleanup, $noerr) = @_;
 127
 128     my $volhash = {};
 129
 130     my $test_volid = sub {
 131         my ($volid, $attr) = @_;
 132
 133         return if $attr->{cdrom};
 134
 135         return if !$cleanup && !$attr->{replicate};
 136
 137         if ($volid =~ m|^/|) {
 138             return if !$attr->{replicate};
 139             return if $cleanup || $noerr;
 140             die "unable to replicate local file/device '$volid'\n";
 141         }
 142
 143         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, $noerr);
 144         return if !$storeid;
 145
 146         my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 147         return if $scfg->{shared};
 148
 149         my ($path, $owner, $vtype) = PVE::Storage::path($storecfg, $volid);
 150         return if !$owner || ($owner != $vmid);
 151
 152         if ($vtype ne 'images') {
 153             return if $cleanup || $noerr;
 154             die "unable to replicate volume '$volid', type '$vtype'\n";
 155         }
 156
 157         if (!PVE::Storage::volume_has_feature($storecfg, 'replicate', $volid)) {
 158             return if $cleanup || $noerr;
 159             die "missing replicate feature on volume '$volid'\n";
 160         }
 161
 162         $volhash->{$volid} = 1;
 163     };
 164
 165     PVE::QemuServer::foreach_volid($conf, $test_volid);
 166
 167     return $volhash;
 168 }
 169
 170 sub get_backup_volumes {
 171     my ($class, $conf) = @_;
 172
 173     my $return_volumes = [];
 174
 175     my $test_volume = sub {
 176         my ($key, $drive) = @_;
 177
 178         return if PVE::QemuServer::drive_is_cdrom($drive);
 179
 180         my $included = $drive->{backup} // 1;
 181         my $reason = "backup=";
 182         $reason .= defined($drive->{backup}) ? 'no' : 'yes';
 183
 184         if ($key =~ m/^efidisk/ && (!defined($conf->{bios}) || $conf->{bios} ne 'ovmf')) {
 185             $included = 0;
 186             $reason = "efidisk but no OMVF BIOS";
 187         }
 188
 189         push @$return_volumes, {
 190             key => $key,
 191             included => $included,
 192             reason => $reason,
 193             volume_config => $drive,
 194         };
 195     };
 196
 197     PVE::QemuConfig->foreach_volume($conf, $test_volume);
 198
 199     return $return_volumes;
 200 }
 201
 202 sub __snapshot_save_vmstate {
 203     my ($class, $vmid, $conf, $snapname, $storecfg, $statestorage, $suspend) = @_;
 204
 205     # use given storage or search for one from the config
 206     my $target = $statestorage;
 207
 208     if (!$target) {
 209         $target = PVE::QemuServer::find_vmstate_storage($conf, $storecfg);
 210     }
 211
 212     my $mem_size = get_current_memory($conf->{memory});
 213     my $driver_state_size = 500; # assume 500MB is enough to safe all driver state;
 214     # our savevm-start does live-save of the memory until the space left in the
 215     # volume is just enough for the remaining memory content + internal state
 216     # then it stops the vm and copies the rest so we reserve twice the
 217     # memory content + state to minimize vm downtime
 218     my $size = $mem_size*2 + $driver_state_size;
 219     my $scfg = PVE::Storage::storage_config($storecfg, $target);
 220
 221     my $name = "vm-$vmid-state-$snapname";
 222     $name .= ".raw" if $scfg->{path}; # add filename extension for file base storage
 223
 224     my $statefile = PVE::Storage::vdisk_alloc($storecfg, $target, $vmid, 'raw', $name, $size*1024);
 225     my $runningmachine = PVE::QemuServer::Machine::get_current_qemu_machine($vmid);
 226
 227     # get current QEMU -cpu argument to ensure consistency of custom CPU models
 228     my $runningcpu;
 229     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 230         $runningcpu = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 231     }
 232
 233     if (!$suspend) {
 234         $conf = $conf->{snapshots}->{$snapname};
 235     }
 236
 237     $conf->{vmstate} = $statefile;
 238     $conf->{runningmachine} = $runningmachine;
 239     $conf->{runningcpu} = $runningcpu;
 240
 241     return $statefile;
 242 }
 243
 244 sub __snapshot_activate_storages {
 245     my ($class, $conf, $include_vmstate) = @_;
 246
 247     my $storecfg = PVE::Storage::config();
 248     my $opts = $include_vmstate ? { 'extra_keys' => ['vmstate'] } : {};
 249     my $storage_hash = {};
 250
 251     $class->foreach_volume_full($conf, $opts, sub {
 252         my ($key, $drive) = @_;
 253
 254         return if PVE::QemuServer::drive_is_cdrom($drive);
 255
 256         my ($storeid) = PVE::Storage::parse_volume_id($drive->{file});
 257         $storage_hash->{$storeid} = 1;
 258     });
 259
 260     PVE::Storage::activate_storage_list($storecfg, [ sort keys $storage_hash->%* ]);
 261 }
 262
 263 sub __snapshot_check_running {
 264     my ($class, $vmid) = @_;
 265     return PVE::QemuServer::Helpers::vm_running_locally($vmid);
 266 }
 267
 268 sub __snapshot_check_freeze_needed {
 269     my ($class, $vmid, $config, $save_vmstate) = @_;
 270
 271     my $running = $class->__snapshot_check_running($vmid);
 272     if (!$save_vmstate) {
 273         return ($running, $running && PVE::QemuServer::parse_guest_agent($config)->{enabled} && PVE::QemuServer::qga_check_running($vmid));
 274     } else {
 275         return ($running, 0);
 276     }
 277 }
 278
 279 sub __snapshot_freeze {
 280     my ($class, $vmid, $unfreeze) = @_;
 281
 282     if ($unfreeze) {
 283         eval { mon_cmd($vmid, "guest-fsfreeze-thaw"); };
 284         warn "guest-fsfreeze-thaw problems - $@" if $@;
 285     } else {
 286         eval { mon_cmd($vmid, "guest-fsfreeze-freeze"); };
 287         warn "guest-fsfreeze-freeze problems - $@" if $@;
 288     }
 289 }
 290
 291 sub __snapshot_create_vol_snapshots_hook {
 292     my ($class, $vmid, $snap, $running, $hook) = @_;
 293
 294     if ($running) {
 295         my $storecfg = PVE::Storage::config();
 296
 297         if ($hook eq "before") {
 298             if ($snap->{vmstate}) {
 299                 my $path = PVE::Storage::path($storecfg, $snap->{vmstate});
 300                 PVE::Storage::activate_volumes($storecfg, [$snap->{vmstate}]);
 301                 my $state_storage_id = PVE::Storage::parse_volume_id($snap->{vmstate});
 302
 303                 PVE::QemuServer::set_migration_caps($vmid, 1);
 304                 mon_cmd($vmid, "savevm-start", statefile => $path);
 305                 print "saving VM state and RAM using storage '$state_storage_id'\n";
 306                 my $render_state = sub {
 307                     my ($stat) = @_;
 308                     my $b = render_bytes($stat->{bytes});
 309                     my $t = render_duration($stat->{'total-time'} / 1000);
 310                     return ($b, $t);
 311                 };
 312                 my $round = 0;
 313                 for(;;) {
 314                     $round++;
 315                     my $stat = mon_cmd($vmid, "query-savevm");
 316                     if (!$stat->{status}) {
 317                         die "savevm not active\n";
 318                     } elsif ($stat->{status} eq 'active') {
 319                         if ($round < 60 || $round % 10 == 0) {
 320                             my ($b, $t) = $render_state->($stat);
 321                             print "$b in $t\n";
 322                         }
 323                         print "reducing reporting rate to every 10s\n" if $round == 60;
 324                         sleep(1);
 325                         next;
 326                     } elsif ($stat->{status} eq 'completed') {
 327                         my ($b, $t) = $render_state->($stat);
 328                         print "completed saving the VM state in $t, saved $b\n";
 329                         last;
 330                     } elsif ($stat->{status} eq 'failed') {
 331                         my $err = $stat->{error} || 'unknown error';
 332                         die "unable to save VM state and RAM - $err\n";
 333                     } else {
 334                         die "query-savevm returned unexpected status '$stat->{status}'\n";
 335                     }
 336                 }
 337             } else {
 338                 mon_cmd($vmid, "savevm-start");
 339             }
 340         } elsif ($hook eq "after") {
 341             eval {
 342                 mon_cmd($vmid, "savevm-end");
 343                 PVE::Storage::deactivate_volumes($storecfg, [$snap->{vmstate}]) if $snap->{vmstate};
 344             };
 345             warn $@ if $@;
 346         } elsif ($hook eq "after-freeze") {
 347             # savevm-end is async, we need to wait
 348             for (;;) {
 349                 my $stat = mon_cmd($vmid, "query-savevm");
 350                 if (!$stat->{bytes}) {
 351                     last;
 352                 } else {
 353                     print "savevm not yet finished\n";
 354                     sleep(1);
 355                     next;
 356                 }
 357             }
 358         }
 359     }
 360 }
 361
 362 sub __snapshot_create_vol_snapshot {
 363     my ($class, $vmid, $ds, $drive, $snapname) = @_;
 364
 365     return if PVE::QemuServer::drive_is_cdrom($drive);
 366
 367     my $volid = $drive->{file};
 368     my $device = "drive-$ds";
 369     my $storecfg = PVE::Storage::config();
 370
 371     print "snapshotting '$device' ($drive->{file})\n";
 372
 373     PVE::QemuServer::qemu_volume_snapshot($vmid, $device, $storecfg, $volid, $snapname);
 374 }
 375
 376 sub __snapshot_delete_remove_drive {
 377     my ($class, $snap, $remove_drive) = @_;
 378
 379     if ($remove_drive eq 'vmstate') {
 380         delete $snap->{$remove_drive};
 381     } else {
 382         my $drive = PVE::QemuServer::parse_drive($remove_drive, $snap->{$remove_drive});
 383         return if PVE::QemuServer::drive_is_cdrom($drive);
 384
 385         my $volid = $drive->{file};
 386         delete $snap->{$remove_drive};
 387         $class->add_unused_volume($snap, $volid);
 388     }
 389 }
 390
 391 sub __snapshot_delete_vmstate_file {
 392     my ($class, $snap, $force) = @_;
 393
 394     my $storecfg = PVE::Storage::config();
 395
 396     eval {  PVE::Storage::vdisk_free($storecfg, $snap->{vmstate}); };
 397     if (my $err = $@) {
 398         die $err if !$force;
 399         warn $err;
 400     }
 401 }
 402
 403 sub __snapshot_delete_vol_snapshot {
 404     my ($class, $vmid, $ds, $drive, $snapname, $unused) = @_;
 405
 406     return if PVE::QemuServer::drive_is_cdrom($drive);
 407     my $storecfg = PVE::Storage::config();
 408     my $volid = $drive->{file};
 409
 410     PVE::QemuServer::qemu_volume_snapshot_delete($vmid, $storecfg, $volid, $snapname);
 411
 412     push @$unused, $volid;
 413 }
 414
 415 sub __snapshot_rollback_hook {
 416     my ($class, $vmid, $conf, $snap, $prepare, $data) = @_;
 417
 418     if ($prepare) {
 419         # we save the machine of the current config
 420         $data->{oldmachine} = $conf->{machine};
 421     } else {
 422         # if we have a 'runningmachine' entry in the snapshot we use that
 423         # for the forcemachine parameter, else we use the old logic
 424         if (defined($conf->{runningmachine})) {
 425             $data->{forcemachine} = $conf->{runningmachine};
 426             delete $conf->{runningmachine};
 427
 428             # runningcpu is newer than runningmachine, so assume it only exists
 429             # here, if at all
 430             $data->{forcecpu} = delete $conf->{runningcpu}
 431                 if defined($conf->{runningcpu});
 432         } else {
 433             # Note: old code did not store 'machine', so we try to be smart
 434             # and guess the snapshot was generated with kvm 1.4 (pc-i440fx-1.4).
 435             my $machine_conf = PVE::QemuServer::Machine::parse_machine($conf->{machine});
 436             $data->{forcemachine} = $machine_conf->{type} || 'pc-i440fx-1.4';
 437
 438             # we remove the 'machine' configuration if not explicitly specified
 439             # in the original config.
 440             delete $conf->{machine} if $snap->{vmstate} && !defined($data->{oldmachine});
 441         }
 442
 443         if ($conf->{vmgenid}) {
 444             # tell the VM that it's another generation, so it can react
 445             # appropriately, e.g. dirty-mark copies of distributed databases or
 446             # re-initializing its random number generator
 447             $conf->{vmgenid} = PVE::QemuServer::generate_uuid();
 448         }
 449     }
 450
 451     return;
 452 }
 453
 454 sub __snapshot_rollback_vol_possible {
 455     my ($class, $drive, $snapname, $blockers) = @_;
 456
 457     return if PVE::QemuServer::drive_is_cdrom($drive);
 458
 459     my $storecfg = PVE::Storage::config();
 460     my $volid = $drive->{file};
 461
 462     PVE::Storage::volume_rollback_is_possible($storecfg, $volid, $snapname, $blockers);
 463 }
 464
 465 sub __snapshot_rollback_vol_rollback {
 466     my ($class, $drive, $snapname) = @_;
 467
 468     return if PVE::QemuServer::drive_is_cdrom($drive);
 469
 470     my $storecfg = PVE::Storage::config();
 471     PVE::Storage::volume_snapshot_rollback($storecfg, $drive->{file}, $snapname);
 472 }
 473
 474 sub __snapshot_rollback_vm_stop {
 475     my ($class, $vmid) = @_;
 476
 477     my $storecfg = PVE::Storage::config();
 478     PVE::QemuServer::vm_stop($storecfg, $vmid, undef, undef, 5, undef, undef);
 479 }
 480
 481 sub __snapshot_rollback_vm_start {
 482     my ($class, $vmid, $vmstate, $data) = @_;
 483
 484     my $storecfg = PVE::Storage::config();
 485     my $params = {
 486         statefile => $vmstate,
 487         forcemachine => $data->{forcemachine},
 488         forcecpu => $data->{forcecpu},
 489     };
 490     PVE::QemuServer::vm_start($storecfg, $vmid, $params);
 491 }
 492
 493 sub __snapshot_rollback_get_unused {
 494     my ($class, $conf, $snap) = @_;
 495
 496     my $unused = [];
 497
 498     $class->foreach_volume($conf, sub {
 499         my ($vs, $volume) = @_;
 500
 501         return if PVE::QemuServer::drive_is_cdrom($volume, 1);
 502
 503         my $found = 0;
 504         my $volid = $volume->{file};
 505
 506         $class->foreach_volume($snap, sub {
 507             my ($ds, $drive) = @_;
 508
 509             return if $found;
 510             return if PVE::QemuServer::drive_is_cdrom($drive, 1);
 511
 512             $found = 1
 513                 if ($drive->{file} && $drive->{file} eq $volid);
 514         });
 515
 516         push @$unused, $volid if !$found;
 517     });
 518
 519     return $unused;
 520 }
 521
 522 sub add_unused_volume {
 523     my ($class, $config, $volid) = @_;
 524
 525     if ($volid =~ m/vm-\d+-cloudinit/) {
 526         print "found unused cloudinit disk '$volid', removing it\n";
 527         my $storecfg = PVE::Storage::config();
 528         PVE::Storage::vdisk_free($storecfg, $volid);
 529         return undef;
 530     } else {
 531         return $class->SUPER::add_unused_volume($config, $volid);
 532     }
 533 }
 534
 535 sub load_current_config {
 536     my ($class, $vmid, $current) = @_;
 537
 538     my $conf = $class->SUPER::load_current_config($vmid, $current);
 539     delete $conf->{cloudinit};
 540     return $conf;
 541 }
 542
 543 sub get_derived_property {
 544     my ($class, $conf, $name) = @_;
 545
 546     my $defaults = PVE::QemuServer::load_defaults();
 547
 548     if ($name eq 'max-cpu') {
 549         my $cpus =
 550             ($conf->{sockets} || $defaults->{sockets}) * ($conf->{cores} || $defaults->{cores});
 551         return $conf->{vcpus} || $cpus;
 552     } elsif ($name eq 'max-memory') { # current usage maximum, not maximum hotpluggable
 553         return get_current_memory($conf->{memory}) * 1024 * 1024;
 554     } else {
 555         die "unknown derived property - $name\n";
 556     }
 557 }
 558
 559 # END implemented abstract methods from PVE::AbstractConfig
 560
 561 sub has_cloudinit {
 562     my ($class, $conf, $skip) = @_;
 563
 564     my $found;
 565
 566     $class->foreach_volume($conf, sub {
 567         my ($key, $volume) = @_;
 568
 569         return if ($skip && $skip eq $key) || $found;
 570         $found = $key if PVE::QemuServer::Drive::drive_is_cloudinit($volume);
 571     });
 572
 573     return $found;
 574 }
 575
 576 1;