PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16
  17 use base qw(PVE::AbstractMigrate);
  18
  19 sub fork_command_pipe {
  20     my ($self, $cmd) = @_;
  21
  22     my $reader = IO::File->new();
  23     my $writer = IO::File->new();
  24
  25     my $orig_pid = $$;
  26
  27     my $cpid;
  28
  29     eval { $cpid = open2($reader, $writer, @$cmd); };
  30
  31     my $err = $@;
  32
  33     # catch exec errors
  34     if ($orig_pid != $$) {
  35         $self->log('err', "can't fork command pipe\n");
  36         POSIX::_exit(1);
  37         kill('KILL', $$);
  38     }
  39
  40     die $err if $err;
  41
  42     return { writer => $writer, reader => $reader, pid => $cpid };
  43 }
  44
  45 sub finish_command_pipe {
  46     my ($self, $cmdpipe, $timeout) = @_;
  47
  48     my $cpid = $cmdpipe->{pid};
  49     return if !defined($cpid);
  50
  51     my $writer = $cmdpipe->{writer};
  52     my $reader = $cmdpipe->{reader};
  53
  54     $writer->close();
  55     $reader->close();
  56
  57     my $collect_child_process = sub {
  58         my $res = waitpid($cpid, WNOHANG);
  59         if (defined($res) && ($res == $cpid)) {
  60             delete $cmdpipe->{cpid};
  61             return 1;
  62         } else {
  63             return 0;
  64         }
  65      };
  66
  67     if ($timeout) {
  68         for (my $i = 0; $i < $timeout; $i++) {
  69             return if &$collect_child_process();
  70             sleep(1);
  71         }
  72     }
  73
  74     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  75     kill(15, $cpid);
  76
  77     # wait again
  78     for (my $i = 0; $i < 10; $i++) {
  79         return if &$collect_child_process();
  80         sleep(1);
  81     }
  82
  83     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  84     kill 9, $cpid;
  85     sleep 1;
  86
  87     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  88         if !&$collect_child_process();
  89 }
  90
  91 sub fork_tunnel {
  92     my ($self, $tunnel_addr) = @_;
  93
  94     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
  95
  96     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, 'qm', 'mtunnel' ];
  97
  98     my $tunnel = $self->fork_command_pipe($cmd);
  99
 100     my $reader = $tunnel->{reader};
 101
 102     my $helo;
 103     eval {
 104         PVE::Tools::run_with_timeout(60, sub { $helo = <$reader>; });
 105         die "no reply\n" if !$helo;
 106         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 107         die "got strange reply from mtunnel ('$helo')\n"
 108             if $helo !~ m/^tunnel online$/;
 109     };
 110     my $err = $@;
 111
 112     if ($err) {
 113         $self->finish_command_pipe($tunnel);
 114         die "can't open migration tunnel - $err";
 115     }
 116     return $tunnel;
 117 }
 118
 119 sub finish_tunnel {
 120     my ($self, $tunnel) = @_;
 121
 122     my $writer = $tunnel->{writer};
 123
 124     eval {
 125         PVE::Tools::run_with_timeout(30, sub {
 126             print $writer "quit\n";
 127             $writer->flush();
 128         });
 129     };
 130     my $err = $@;
 131
 132     $self->finish_command_pipe($tunnel, 30);
 133
 134     if ($tunnel->{sock_addr}) {
 135         # ssh does not clean up on local host
 136         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 137         PVE::Tools::run_command($cmd);
 138
 139         # .. and just to be sure check on remote side
 140         unshift @{$cmd}, @{$self->{rem_ssh}};
 141         PVE::Tools::run_command($cmd);
 142     }
 143
 144     die $err if $err;
 145 }
 146
 147 sub lock_vm {
 148     my ($self, $vmid, $code, @param) = @_;
 149
 150     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 151 }
 152
 153 sub prepare {
 154     my ($self, $vmid) = @_;
 155
 156     my $online = $self->{opts}->{online};
 157
 158     $self->{storecfg} = PVE::Storage::config();
 159
 160     # test if VM exists
 161     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 162
 163     PVE::QemuConfig->check_lock($conf);
 164
 165     my $running = 0;
 166     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 167         die "can't migrate running VM without --online\n" if !$online;
 168         $running = $pid;
 169
 170         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 171
 172     }
 173
 174     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 175         if ($self->{running} || !$self->{opts}->{force}) {
 176             die "can't migrate VM which uses local devices\n";
 177         } else {
 178             $self->log('info', "migrating VM which uses local devices");
 179         }
 180     }
 181
 182     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 183
 184     my $need_activate = [];
 185     foreach my $volid (@$vollist) {
 186         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 187
 188         # check if storage is available on both nodes
 189         my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 190
 191         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 192         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 193
 194         if ($scfg->{shared}) {
 195             # PVE::Storage::activate_storage checks this for non-shared storages
 196             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 197             warn "Used shared storage '$sid' is not online on source node!\n"
 198                 if !$plugin->check_connection($sid, $scfg);
 199         } else {
 200             # only activate if not shared
 201             push @$need_activate, $volid;
 202         }
 203     }
 204
 205     # activate volumes
 206     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 207
 208     # test ssh connection
 209     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 210     eval { $self->cmd_quiet($cmd); };
 211     die "Can't connect to destination address using public key\n" if $@;
 212
 213     return $running;
 214 }
 215
 216 sub sync_disks {
 217     my ($self, $vmid) = @_;
 218
 219     my $conf = $self->{vmconf};
 220
 221     # local volumes which have been copied
 222     $self->{volumes} = [];
 223
 224     my $res = [];
 225
 226     eval {
 227
 228         # found local volumes and their origin
 229         my $local_volumes = {};
 230         my $local_volumes_errors = {};
 231         my $other_errors = [];
 232         my $abort = 0;
 233
 234         my $sharedvm = 1;
 235
 236         my $log_error = sub {
 237             my ($msg, $volid) = @_;
 238
 239             if (defined($volid)) {
 240                 $local_volumes_errors->{$volid} = $msg;
 241             } else {
 242                 push @$other_errors, $msg;
 243             }
 244             $abort = 1;
 245         };
 246
 247         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 248         foreach my $storeid (@sids) {
 249             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 250             next if $scfg->{shared};
 251             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 252
 253             # get list from PVE::Storage (for unused volumes)
 254             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 255
 256             next if @{$dl->{$storeid}} == 0;
 257
 258             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $storeid;
 259
 260             # check if storage is available on target node
 261             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 262             $sharedvm = 0; # there is a non-shared disk
 263
 264             PVE::Storage::foreach_volid($dl, sub {
 265                 my ($volid, $sid, $volname) = @_;
 266
 267                 $local_volumes->{$volid} = 'storage';
 268             });
 269         }
 270
 271         my $test_volid = sub {
 272             my ($volid, $is_cdrom, $snapname) = @_;
 273
 274             return if !$volid;
 275
 276             if ($volid =~ m|^/|) {
 277                 $local_volumes->{$volid} = 'config';
 278                 die "local file/device\n";
 279             }
 280
 281             if ($is_cdrom) {
 282                 if ($volid eq 'cdrom') {
 283                     my $msg = "can't migrate local cdrom drive";
 284                     $msg .= " (referenced in snapshot '$snapname')"
 285                         if defined($snapname);
 286
 287                     &$log_error("$msg\n");
 288                     return;
 289                 }
 290                 return if $volid eq 'none';
 291             }
 292
 293             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 294
 295             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 296             # check if storage is available on both nodes
 297             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 298             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 299
 300             return if $scfg->{shared};
 301
 302             $sharedvm = 0;
 303
 304             $local_volumes->{$volid} = defined($snapname) ? 'snapshot' : 'config';
 305
 306             die "local cdrom image\n" if $is_cdrom;
 307
 308             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 309
 310             die "owned by other VM (owner = VM $owner)\n"
 311                 if !$owner || ($owner != $self->{vmid});
 312
 313             if (defined($snapname)) {
 314                 # we cannot migrate shapshots on local storage
 315                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 316
 317                 my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 318                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 319                 if (!($scfg->{type} eq 'zfspool' || $format eq 'qcow2')) {
 320                     die "non-migratable snapshot exists\n";
 321                 }
 322             }
 323
 324             die "referenced by linked clone(s)\n"
 325                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 326         };
 327
 328         my $test_drive = sub {
 329             my ($ds, $drive, $snapname) = @_;
 330
 331             eval {
 332                 &$test_volid($drive->{file}, PVE::QemuServer::drive_is_cdrom($drive), $snapname);
 333             };
 334
 335             &$log_error($@, $drive->{file}) if $@;
 336         };
 337
 338         foreach my $snapname (keys %{$conf->{snapshots}}) {
 339             eval {
 340                 &$test_volid($conf->{snapshots}->{$snapname}->{'vmstate'}, 0, undef)
 341                     if defined($conf->{snapshots}->{$snapname}->{'vmstate'});
 342             };
 343             &$log_error($@, $conf->{snapshots}->{$snapname}->{'vmstate'}) if $@;
 344
 345             PVE::QemuServer::foreach_drive($conf->{snapshots}->{$snapname}, $test_drive, $snapname);
 346         }
 347         PVE::QemuServer::foreach_drive($conf, $test_drive);
 348
 349         foreach my $vol (sort keys %$local_volumes) {
 350             if ($local_volumes->{$vol} eq 'storage') {
 351                 $self->log('info', "found local disk '$vol' (via storage)\n");
 352             } elsif ($local_volumes->{$vol} eq 'config') {
 353                 die "can't live migrate attached local disks without with-local-disks option\n" if $self->{running} && !$self->{opts}->{"with-local-disks"};
 354                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 355             } elsif ($local_volumes->{$vol} eq 'snapshot') {
 356                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 357             } else {
 358                 $self->log('info', "found local disk '$vol'\n");
 359             }
 360         }
 361
 362         foreach my $vol (sort keys %$local_volumes_errors) {
 363             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 364         }
 365         foreach my $err (@$other_errors) {
 366             $self->log('warn', "$err");
 367         }
 368
 369         if ($self->{running} && !$sharedvm && !$self->{opts}->{targetstorage}) {
 370             $self->{opts}->{targetstorage} = 1; #use same sid for remote local
 371         }
 372
 373         if ($abort) {
 374             die "can't migrate VM - check log\n";
 375         }
 376
 377         # additional checks for local storage
 378         foreach my $volid (keys %$local_volumes) {
 379             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 380             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 381
 382             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 383                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 384
 385             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 386                 if !$migratable;
 387
 388             # image is a linked clone on local storage, se we can't migrate.
 389             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 390                 die "can't migrate '$volid' as it's a clone of '$basename'";
 391             }
 392         }
 393
 394         $self->log('info', "copying disk images");
 395
 396         foreach my $volid (keys %$local_volumes) {
 397             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 398             if ($self->{running} && $self->{opts}->{targetstorage} && $local_volumes->{$volid} eq 'config') {
 399                 push @{$self->{online_local_volumes}}, $volid;
 400             } else {
 401                 push @{$self->{volumes}}, $volid;
 402                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{ssh_info}, $sid);
 403             }
 404         }
 405     };
 406     die "Failed to sync data - $@" if $@;
 407 }
 408
 409 sub cleanup_remotedisks {
 410     my ($self) = @_;
 411
 412     foreach my $target_drive (keys %{$self->{target_drive}}) {
 413
 414         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 415         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 416
 417         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 418
 419         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 420         if (my $err = $@) {
 421             $self->log('err', $err);
 422             $self->{errors} = 1;
 423         }
 424     }
 425 }
 426
 427 sub phase1 {
 428     my ($self, $vmid) = @_;
 429
 430     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 431
 432     my $conf = $self->{vmconf};
 433
 434     # set migrate lock in config file
 435     $conf->{lock} = 'migrate';
 436     PVE::QemuConfig->write_config($vmid, $conf);
 437
 438     sync_disks($self, $vmid);
 439
 440 };
 441
 442 sub phase1_cleanup {
 443     my ($self, $vmid, $err) = @_;
 444
 445     $self->log('info', "aborting phase 1 - cleanup resources");
 446
 447     my $conf = $self->{vmconf};
 448     delete $conf->{lock};
 449     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 450     if (my $err = $@) {
 451         $self->log('err', $err);
 452     }
 453
 454     if ($self->{volumes}) {
 455         foreach my $volid (@{$self->{volumes}}) {
 456             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 457             # fixme: try to remove ?
 458         }
 459     }
 460 }
 461
 462 sub phase2 {
 463     my ($self, $vmid) = @_;
 464
 465     my $conf = $self->{vmconf};
 466
 467     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 468
 469     my $raddr;
 470     my $rport;
 471     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 472     my $nodename = PVE::INotify::nodename();
 473
 474     ## start on remote node
 475     my $cmd = [@{$self->{rem_ssh}}];
 476
 477     my $spice_ticket;
 478     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 479         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 480         $spice_ticket = $res->{ticket};
 481     }
 482
 483     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 484
 485     # we use TCP only for unsecure migrations as TCP ssh forward tunnels often
 486     # did appeared to late (they are hard, if not impossible, to check for)
 487     # secure migration use UNIX sockets now, this *breaks* compatibilty when trying
 488     # to migrate from new to old but *not* from old to new.
 489     my $datacenterconf = PVE::Cluster::cfs_read_file('datacenter.cfg');
 490
 491     my $migration_type = 'secure';
 492     if (defined($self->{opts}->{migration_type})) {
 493         $migration_type = $self->{opts}->{migration_type};
 494     } elsif (defined($datacenterconf->{migration}->{type})) {
 495         $migration_type = $datacenterconf->{migration}->{type};
 496     }
 497
 498     push @$cmd, '--migration_type', $migration_type;
 499
 500     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 501       if $self->{opts}->{migration_network};
 502
 503     if ($migration_type eq 'insecure') {
 504         push @$cmd, '--stateuri', 'tcp';
 505     } else {
 506         push @$cmd, '--stateuri', 'unix';
 507     }
 508
 509     if ($self->{forcemachine}) {
 510         push @$cmd, '--machine', $self->{forcemachine};
 511     }
 512
 513     if ($self->{opts}->{targetstorage}) {
 514         push @$cmd, '--targetstorage', $self->{opts}->{targetstorage};
 515     }
 516
 517     my $spice_port;
 518
 519     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 520     # instead we pipe it through STDIN
 521     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 522         my $line = shift;
 523
 524         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 525             $raddr = $1;
 526             $rport = int($2);
 527             $ruri = "tcp:$raddr:$rport";
 528         }
 529         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 530             $raddr = $1;
 531             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 532             $ruri = "unix:$raddr";
 533         }
 534         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 535             $raddr = "localhost";
 536             $rport = int($1);
 537             $ruri = "tcp:$raddr:$rport";
 538         }
 539         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 540             $spice_port = int($1);
 541         }
 542         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 543             my $volid = $4;
 544             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 545             my $targetdrive = $3;
 546             $targetdrive =~ s/drive-//g;
 547
 548             $self->{target_drive}->{$targetdrive}->{volid} = $volid;
 549             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 550
 551         }
 552     }, errfunc => sub {
 553         my $line = shift;
 554         $self->log('info', $line);
 555     });
 556
 557     die "unable to detect remote migration address\n" if !$raddr;
 558
 559     if ($migration_type eq 'secure') {
 560         $self->log('info', "start remote tunnel");
 561
 562         if ($ruri =~ /^unix:/) {
 563             unlink $raddr;
 564             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 565             $self->{tunnel}->{sock_addr} = $raddr;
 566
 567             my $unix_socket_try = 0; # wait for the socket to become ready
 568             while (! -S $raddr) {
 569                 $unix_socket_try++;
 570                 if ($unix_socket_try > 100) {
 571                     $self->{errors} = 1;
 572                     $self->finish_tunnel($self->{tunnel});
 573                     die "Timeout, migration socket $ruri did not get ready";
 574                 }
 575
 576                 usleep(50000);
 577             }
 578
 579         } elsif ($ruri =~ /^tcp:/) {
 580             my $tunnel_addr;
 581             if ($raddr eq "localhost") {
 582                 # for backwards compatibility with older qemu-server versions
 583                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 584                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 585                 $tunnel_addr = "$lport:localhost:$rport";
 586             }
 587
 588             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 589
 590         } else {
 591             die "unsupported protocol in migration URI: $ruri\n";
 592         }
 593     }
 594
 595     my $start = time();
 596
 597     if ($self->{opts}->{targetstorage} && defined($self->{online_local_volumes})) {
 598         $self->{storage_migration} = 1;
 599         $self->{storage_migration_jobs} = {};
 600         $self->log('info', "starting storage migration");
 601
 602         die "The number of local disks does not match between the source and the destination.\n"
 603             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 604         foreach my $drive (keys %{$self->{target_drive}}){
 605             my $nbd_uri = $self->{target_drive}->{$drive}->{nbd_uri};
 606             $self->log('info', "$drive: start migration to to $nbd_uri");
 607             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 1);
 608         }
 609     }
 610
 611     $self->log('info', "starting online/live migration on $ruri");
 612     $self->{livemigration} = 1;
 613
 614     # load_defaults
 615     my $defaults = PVE::QemuServer::load_defaults();
 616
 617     # always set migrate speed (overwrite kvm default of 32m)
 618     # we set a very hight default of 8192m which is basically unlimited
 619     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 620     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 621     $migrate_speed = $migrate_speed * 1048576;
 622     $self->log('info', "migrate_set_speed: $migrate_speed");
 623     eval {
 624         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 625     };
 626     $self->log('info', "migrate_set_speed error: $@") if $@;
 627
 628     my $migrate_downtime = $defaults->{migrate_downtime};
 629     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 630     if (defined($migrate_downtime)) {
 631         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 632         eval {
 633             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 634         };
 635         $self->log('info', "migrate_set_downtime error: $@") if $@;
 636     }
 637
 638     $self->log('info', "set migration_caps");
 639     eval {
 640         PVE::QemuServer::set_migration_caps($vmid);
 641     };
 642     warn $@ if $@;
 643
 644     #set cachesize 10% of the total memory
 645     my $cachesize = int($conf->{memory}*1048576/10);
 646     $self->log('info', "set cachesize: $cachesize");
 647     eval {
 648         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 649     };
 650     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 651
 652     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 653         my $rpcenv = PVE::RPCEnvironment::get();
 654         my $authuser = $rpcenv->get_user();
 655
 656         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 657
 658         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 659         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 660
 661         $self->log('info', "spice client_migrate_info");
 662
 663         eval {
 664             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 665                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 666                                                 'cert-subject' => $subject);
 667         };
 668         $self->log('info', "client_migrate_info error: $@") if $@;
 669
 670     }
 671
 672     $self->log('info', "start migrate command to $ruri");
 673     eval {
 674         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 675     };
 676     my $merr = $@;
 677     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 678
 679     my $lstat = 0;
 680     my $usleep = 2000000;
 681     my $i = 0;
 682     my $err_count = 0;
 683     my $lastrem = undef;
 684     my $downtimecounter = 0;
 685     while (1) {
 686         $i++;
 687         my $avglstat = $lstat/$i if $lstat;
 688
 689         usleep($usleep);
 690         my $stat;
 691         eval {
 692             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 693         };
 694         if (my $err = $@) {
 695             $err_count++;
 696             warn "query migrate failed: $err\n";
 697             $self->log('info', "query migrate failed: $err");
 698             if ($err_count <= 5) {
 699                 usleep(1000000);
 700                 next;
 701             }
 702             die "too many query migrate failures - aborting\n";
 703         }
 704
 705         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 706             sleep(1);
 707             next;
 708         }
 709
 710         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 711             $merr = undef;
 712             $err_count = 0;
 713             if ($stat->{status} eq 'completed') {
 714                 my $delay = time() - $start;
 715                 if ($delay > 0) {
 716                     my $mbps = sprintf "%.2f", $conf->{memory}/$delay;
 717                     my $downtime = $stat->{downtime} || 0;
 718                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 719                 }
 720             }
 721
 722             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 723                 $self->log('info', "migration status error: $stat->{status}");
 724                 die "aborting\n"
 725             }
 726
 727             if ($stat->{status} ne 'active') {
 728                 $self->log('info', "migration status: $stat->{status}");
 729                 last;
 730             }
 731
 732             if ($stat->{ram}->{transferred} ne $lstat) {
 733                 my $trans = $stat->{ram}->{transferred} || 0;
 734                 my $rem = $stat->{ram}->{remaining} || 0;
 735                 my $total = $stat->{ram}->{total} || 0;
 736                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 737                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 738                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 739                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 740                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 741                 #reduce sleep if remainig memory if lower than the everage transfert
 742                 $usleep = 300000 if $avglstat && $rem < $avglstat;
 743
 744                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 745                            "remaining ${rem}), total ${total})");
 746
 747                 if (${xbzrlecachesize}) {
 748                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 749                 }
 750
 751                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 752                     $downtimecounter++;
 753                 }
 754                 $lastrem = $rem;
 755
 756                 if ($downtimecounter > 5) {
 757                     $downtimecounter = 0;
 758                     $migrate_downtime *= 2;
 759                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 760                     eval {
 761                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 762                     };
 763                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 764                 }
 765
 766             }
 767
 768
 769             $lstat = $stat->{ram}->{transferred};
 770
 771         } else {
 772             die $merr if $merr;
 773             die "unable to parse migration status '$stat->{status}' - aborting\n";
 774         }
 775     }
 776
 777     # just to be sure that the tunnel gets closed on successful migration, on error
 778     # phase2_cleanup closes it *after* stopping the remote waiting VM
 779     if (!$self->{errors} && $self->{tunnel}) {
 780         eval { finish_tunnel($self, $self->{tunnel});  };
 781         if (my $err = $@) {
 782             $self->log('err', $err);
 783             $self->{errors} = 1;
 784         }
 785     }
 786 }
 787
 788 sub phase2_cleanup {
 789     my ($self, $vmid, $err) = @_;
 790
 791     return if !$self->{errors};
 792     $self->{phase2errors} = 1;
 793
 794     $self->log('info', "aborting phase 2 - cleanup resources");
 795
 796     $self->log('info', "migrate_cancel");
 797     eval {
 798         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 799     };
 800     $self->log('info', "migrate_cancel error: $@") if $@;
 801
 802     my $conf = $self->{vmconf};
 803     delete $conf->{lock};
 804     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 805     if (my $err = $@) {
 806         $self->log('err', $err);
 807     }
 808
 809     # cleanup ressources on target host
 810     if ($self->{storage_migration}) {
 811
 812         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 813         if (my $err = $@) {
 814             $self->log('err', $err);
 815         }
 816
 817         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 818         if (my $err = $@) {
 819             $self->log('err', $err);
 820         }
 821     }
 822
 823     my $nodename = PVE::INotify::nodename();
 824
 825     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 826     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 827     if (my $err = $@) {
 828         $self->log('err', $err);
 829         $self->{errors} = 1;
 830     }
 831
 832     if ($self->{tunnel}) {
 833         eval { finish_tunnel($self, $self->{tunnel});  };
 834         if (my $err = $@) {
 835             $self->log('err', $err);
 836             $self->{errors} = 1;
 837         }
 838     }
 839 }
 840
 841 sub phase3 {
 842     my ($self, $vmid) = @_;
 843
 844     my $volids = $self->{volumes};
 845     return if $self->{phase2errors};
 846
 847     # destroy local copies
 848     foreach my $volid (@$volids) {
 849         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 850         if (my $err = $@) {
 851             $self->log('err', "removing local copy of '$volid' failed - $err");
 852             $self->{errors} = 1;
 853             last if $err =~ /^interrupted by signal$/;
 854         }
 855     }
 856 }
 857
 858 sub phase3_cleanup {
 859     my ($self, $vmid, $err) = @_;
 860
 861     my $conf = $self->{vmconf};
 862     return if $self->{phase2errors};
 863
 864     if ($self->{storage_migration}) {
 865         # finish block-job
 866         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}); };
 867
 868         if (my $err = $@) {
 869             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 870             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 871             die "Failed to completed storage migration\n";
 872         } else {
 873             foreach my $target_drive (keys %{$self->{target_drive}}) {
 874                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 875                 $conf->{$target_drive} = PVE::QemuServer::print_drive($vmid, $drive);
 876                 PVE::QemuConfig->write_config($vmid, $conf);
 877             }
 878         }
 879     }
 880
 881     # move config to remote node
 882     my $conffile = PVE::QemuConfig->config_file($vmid);
 883     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 884
 885     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 886         if !rename($conffile, $newconffile);
 887
 888     if ($self->{livemigration}) {
 889         if ($self->{storage_migration}) {
 890             # remove drives referencing the nbd server from source
 891             # otherwise vm_stop might hang later on
 892             foreach my $drive (keys %{$self->{target_drive}}){
 893                 PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "device_del", id => $drive);
 894             }
 895             # stop nbd server on remote vm - requirement for resume since 2.9
 896             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
 897
 898             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 899             if (my $err = $@) {
 900                 $self->log('err', $err);
 901                 $self->{errors} = 1;
 902             }
 903         }
 904         # config moved and nbd server stopped - now we can resume vm on target
 905         my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 906         eval{ PVE::Tools::run_command($cmd, outfunc => sub {},
 907                 errfunc => sub {
 908                     my $line = shift;
 909                     $self->log('err', $line);
 910                 });
 911         };
 912         if (my $err = $@) {
 913             $self->log('err', $err);
 914             $self->{errors} = 1;
 915         }
 916     }
 917
 918     eval {
 919         my $timer = 0;
 920         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
 921             $self->log('info', "Waiting for spice server migration");
 922             while (1) {
 923                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
 924                 last if int($res->{'migrated'}) == 1;
 925                 last if $timer > 50;
 926                 $timer ++;
 927                 usleep(200000);
 928             }
 929         }
 930     };
 931
 932     # always stop local VM
 933     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 934     if (my $err = $@) {
 935         $self->log('err', "stopping vm failed - $err");
 936         $self->{errors} = 1;
 937     }
 938
 939     # always deactivate volumes - avoid lvm LVs to be active on several nodes
 940     eval {
 941         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 942         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
 943     };
 944     if (my $err = $@) {
 945         $self->log('err', $err);
 946         $self->{errors} = 1;
 947     }
 948
 949     if($self->{storage_migration}) {
 950         # destroy local copies
 951         my $volids = $self->{online_local_volumes};
 952
 953         foreach my $volid (@$volids) {
 954             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 955             if (my $err = $@) {
 956                 $self->log('err', "removing local copy of '$volid' failed - $err");
 957                 $self->{errors} = 1;
 958                 last if $err =~ /^interrupted by signal$/;
 959             }
 960         }
 961
 962     }
 963
 964     # clear migrate lock
 965     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
 966     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
 967 }
 968
 969 sub final_cleanup {
 970     my ($self, $vmid) = @_;
 971
 972     # nothing to do
 973 }
 974
 975 1;