PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16
  17 use base qw(PVE::AbstractMigrate);
  18
  19 sub fork_command_pipe {
  20     my ($self, $cmd) = @_;
  21
  22     my $reader = IO::File->new();
  23     my $writer = IO::File->new();
  24
  25     my $orig_pid = $$;
  26
  27     my $cpid;
  28
  29     eval { $cpid = open2($reader, $writer, @$cmd); };
  30
  31     my $err = $@;
  32
  33     # catch exec errors
  34     if ($orig_pid != $$) {
  35         $self->log('err', "can't fork command pipe\n");
  36         POSIX::_exit(1);
  37         kill('KILL', $$);
  38     }
  39
  40     die $err if $err;
  41
  42     return { writer => $writer, reader => $reader, pid => $cpid };
  43 }
  44
  45 sub finish_command_pipe {
  46     my ($self, $cmdpipe, $timeout) = @_;
  47
  48     my $cpid = $cmdpipe->{pid};
  49     return if !defined($cpid);
  50
  51     my $writer = $cmdpipe->{writer};
  52     my $reader = $cmdpipe->{reader};
  53
  54     $writer->close();
  55     $reader->close();
  56
  57     my $collect_child_process = sub {
  58         my $res = waitpid($cpid, WNOHANG);
  59         if (defined($res) && ($res == $cpid)) {
  60             delete $cmdpipe->{cpid};
  61             return 1;
  62         } else {
  63             return 0;
  64         }
  65      };
  66
  67     if ($timeout) {
  68         for (my $i = 0; $i < $timeout; $i++) {
  69             return if &$collect_child_process();
  70             sleep(1);
  71         }
  72     }
  73
  74     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  75     kill(15, $cpid);
  76
  77     # wait again
  78     for (my $i = 0; $i < 10; $i++) {
  79         return if &$collect_child_process();
  80         sleep(1);
  81     }
  82
  83     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  84     kill 9, $cpid;
  85     sleep 1;
  86
  87     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  88         if !&$collect_child_process();
  89 }
  90
  91 sub fork_tunnel {
  92     my ($self, $tunnel_addr) = @_;
  93
  94     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
  95
  96     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, 'qm', 'mtunnel' ];
  97
  98     my $tunnel = $self->fork_command_pipe($cmd);
  99
 100     my $reader = $tunnel->{reader};
 101
 102     my $helo;
 103     eval {
 104         PVE::Tools::run_with_timeout(60, sub { $helo = <$reader>; });
 105         die "no reply\n" if !$helo;
 106         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 107         die "got strange reply from mtunnel ('$helo')\n"
 108             if $helo !~ m/^tunnel online$/;
 109     };
 110     my $err = $@;
 111
 112     if ($err) {
 113         $self->finish_command_pipe($tunnel);
 114         die "can't open migration tunnel - $err";
 115     }
 116     return $tunnel;
 117 }
 118
 119 sub finish_tunnel {
 120     my ($self, $tunnel) = @_;
 121
 122     my $writer = $tunnel->{writer};
 123
 124     eval {
 125         PVE::Tools::run_with_timeout(30, sub {
 126             print $writer "quit\n";
 127             $writer->flush();
 128         });
 129     };
 130     my $err = $@;
 131
 132     $self->finish_command_pipe($tunnel, 30);
 133
 134     if ($tunnel->{sock_addr}) {
 135         # ssh does not clean up on local host
 136         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 137         PVE::Tools::run_command($cmd);
 138
 139         # .. and just to be sure check on remote side
 140         unshift @{$cmd}, @{$self->{rem_ssh}};
 141         PVE::Tools::run_command($cmd);
 142     }
 143
 144     die $err if $err;
 145 }
 146
 147 sub lock_vm {
 148     my ($self, $vmid, $code, @param) = @_;
 149
 150     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 151 }
 152
 153 sub prepare {
 154     my ($self, $vmid) = @_;
 155
 156     my $online = $self->{opts}->{online};
 157
 158     $self->{storecfg} = PVE::Storage::config();
 159
 160     # test if VM exists
 161     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 162
 163     PVE::QemuConfig->check_lock($conf);
 164
 165     my $running = 0;
 166     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 167         die "can't migrate running VM without --online\n" if !$online;
 168         $running = $pid;
 169
 170         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 171
 172     }
 173
 174     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 175         if ($self->{running} || !$self->{opts}->{force}) {
 176             die "can't migrate VM which uses local devices\n";
 177         } else {
 178             $self->log('info', "migrating VM which uses local devices");
 179         }
 180     }
 181
 182     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 183
 184     my $need_activate = [];
 185     foreach my $volid (@$vollist) {
 186         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 187
 188         # check if storage is available on both nodes
 189         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 190         PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 191
 192         if ($scfg->{shared}) {
 193             # PVE::Storage::activate_storage checks this for non-shared storages
 194             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 195             warn "Used shared storage '$sid' is not online on source node!\n"
 196                 if !$plugin->check_connection($sid, $scfg);
 197         } else {
 198             # only activate if not shared
 199             push @$need_activate, $volid;
 200         }
 201     }
 202
 203     # activate volumes
 204     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 205
 206     # test ssh connection
 207     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 208     eval { $self->cmd_quiet($cmd); };
 209     die "Can't connect to destination address using public key\n" if $@;
 210
 211     return $running;
 212 }
 213
 214 sub sync_disks {
 215     my ($self, $vmid) = @_;
 216
 217     $self->log('info', "copying disk images");
 218
 219     my $conf = $self->{vmconf};
 220
 221     # local volumes which have been copied
 222     $self->{volumes} = [];
 223
 224     my $res = [];
 225
 226     eval {
 227
 228         # found local volumes and their origin
 229         my $local_volumes = {};
 230         my $local_volumes_errors = {};
 231         my $other_errors = [];
 232         my $abort = 0;
 233
 234         my $sharedvm = 1;
 235
 236         my $log_error = sub {
 237             my ($msg, $volid) = @_;
 238
 239             if (defined($volid)) {
 240                 $local_volumes_errors->{$volid} = $msg;
 241             } else {
 242                 push @$other_errors, $msg;
 243             }
 244             $abort = 1;
 245         };
 246
 247         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 248         foreach my $storeid (@sids) {
 249             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 250             next if $scfg->{shared};
 251             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 252
 253             # get list from PVE::Storage (for unused volumes)
 254             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 255
 256             next if @{$dl->{$storeid}} == 0;
 257
 258             # check if storage is available on target node
 259             PVE::Storage::storage_check_node($self->{storecfg}, $storeid, $self->{node});
 260             $sharedvm = 0; # there is a non-shared disk
 261
 262             PVE::Storage::foreach_volid($dl, sub {
 263                 my ($volid, $sid, $volname) = @_;
 264
 265                 $local_volumes->{$volid} = 'storage';
 266             });
 267         }
 268
 269         my $test_volid = sub {
 270             my ($volid, $is_cdrom, $snapname) = @_;
 271
 272             return if !$volid;
 273
 274             if ($volid =~ m|^/|) {
 275                 $local_volumes->{$volid} = 'config';
 276                 die "local file/device\n";
 277             }
 278
 279             if ($is_cdrom) {
 280                 if ($volid eq 'cdrom') {
 281                     my $msg = "can't migrate local cdrom drive";
 282                     $msg .= " (referenced in snapshot '$snapname')"
 283                         if defined($snapname);
 284
 285                     &$log_error("$msg\n");
 286                     return;
 287                 }
 288                 return if $volid eq 'none';
 289             }
 290
 291             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 292
 293             # check if storage is available on both nodes
 294             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 295             PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 296
 297             return if $scfg->{shared};
 298
 299             $sharedvm = 0;
 300
 301             $local_volumes->{$volid} = defined($snapname) ? 'snapshot' : 'config';
 302
 303             die "local cdrom image\n" if $is_cdrom;
 304
 305             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 306
 307             die "owned by other VM (owner = VM $owner)\n"
 308                 if !$owner || ($owner != $self->{vmid});
 309
 310             if (defined($snapname)) {
 311                 # we cannot migrate shapshots on local storage
 312                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 313
 314                 my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 315
 316                 if (!($scfg->{type} eq 'zfspool') || ($format eq 'qcow2')) {
 317                     die "non-migratable snapshot exists\n";
 318                 }
 319             }
 320
 321             die "referenced by linked clone(s)\n"
 322                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 323         };
 324
 325         my $test_drive = sub {
 326             my ($ds, $drive, $snapname) = @_;
 327
 328             eval {
 329                 &$test_volid($drive->{file}, PVE::QemuServer::drive_is_cdrom($drive), $snapname);
 330             };
 331
 332             &$log_error($@, $drive->{file}) if $@;
 333         };
 334
 335         foreach my $snapname (keys %{$conf->{snapshots}}) {
 336             eval {
 337                 &$test_volid($conf->{snapshots}->{$snapname}->{'vmstate'}, 0, undef)
 338                     if defined($conf->{snapshots}->{$snapname}->{'vmstate'});
 339             };
 340             &$log_error($@, $conf->{snapshots}->{$snapname}->{'vmstate'}) if $@;
 341
 342             PVE::QemuServer::foreach_drive($conf->{snapshots}->{$snapname}, $test_drive, $snapname);
 343         }
 344         PVE::QemuServer::foreach_drive($conf, $test_drive);
 345
 346         foreach my $vol (sort keys %$local_volumes) {
 347             if ($local_volumes->{$vol} eq 'storage') {
 348                 $self->log('info', "found local disk '$vol' (via storage)\n");
 349             } elsif ($local_volumes->{$vol} eq 'config') {
 350                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 351             } elsif ($local_volumes->{$vol} eq 'snapshot') {
 352                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 353             } else {
 354                 $self->log('info', "found local disk '$vol'\n");
 355             }
 356         }
 357
 358         foreach my $vol (sort keys %$local_volumes_errors) {
 359             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 360         }
 361         foreach my $err (@$other_errors) {
 362             $self->log('warn', "$err");
 363         }
 364
 365         if ($self->{running} && !$sharedvm) {
 366             die "can't do online migration - VM uses local disks\n";
 367         }
 368
 369         if ($abort) {
 370             die "can't migrate VM - check log\n";
 371         }
 372
 373         # additional checks for local storage
 374         foreach my $volid (keys %$local_volumes) {
 375             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 376             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 377
 378             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 379                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 380
 381             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 382                 if !$migratable;
 383
 384             # image is a linked clone on local storage, se we can't migrate.
 385             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 386                 die "can't migrate '$volid' as it's a clone of '$basename'";
 387             }
 388         }
 389
 390         foreach my $volid (keys %$local_volumes) {
 391             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 392             push @{$self->{volumes}}, $volid;
 393             PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{nodeip}, $sid);
 394         }
 395     };
 396     die "Failed to sync data - $@" if $@;
 397 }
 398
 399 sub phase1 {
 400     my ($self, $vmid) = @_;
 401
 402     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 403
 404     my $conf = $self->{vmconf};
 405
 406     # set migrate lock in config file
 407     $conf->{lock} = 'migrate';
 408     PVE::QemuConfig->write_config($vmid, $conf);
 409
 410     sync_disks($self, $vmid);
 411
 412 };
 413
 414 sub phase1_cleanup {
 415     my ($self, $vmid, $err) = @_;
 416
 417     $self->log('info', "aborting phase 1 - cleanup resources");
 418
 419     my $conf = $self->{vmconf};
 420     delete $conf->{lock};
 421     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 422     if (my $err = $@) {
 423         $self->log('err', $err);
 424     }
 425
 426     if ($self->{volumes}) {
 427         foreach my $volid (@{$self->{volumes}}) {
 428             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 429             # fixme: try to remove ?
 430         }
 431     }
 432 }
 433
 434 sub phase2 {
 435     my ($self, $vmid) = @_;
 436
 437     my $conf = $self->{vmconf};
 438
 439     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 440
 441     my $raddr;
 442     my $rport;
 443     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 444     my $nodename = PVE::INotify::nodename();
 445
 446     ## start on remote node
 447     my $cmd = [@{$self->{rem_ssh}}];
 448
 449     my $spice_ticket;
 450     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 451         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 452         $spice_ticket = $res->{ticket};
 453     }
 454
 455     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 456
 457     # we use TCP only for unsecure migrations as TCP ssh forward tunnels often
 458     # did appeared to late (they are hard, if not impossible, to check for)
 459     # secure migration use UNIX sockets now, this *breaks* compatibilty when trying
 460     # to migrate from new to old but *not* from old to new.
 461     my $datacenterconf = PVE::Cluster::cfs_read_file('datacenter.cfg');
 462     my $secure_migration = ($datacenterconf->{migration_unsecure}) ? 0 : 1;
 463
 464     if (!$secure_migration) {
 465         push @$cmd, '--stateuri', 'tcp';
 466     } else {
 467         push @$cmd, '--stateuri', 'unix';
 468     }
 469
 470     if ($self->{forcemachine}) {
 471         push @$cmd, '--machine', $self->{forcemachine};
 472     }
 473
 474     my $spice_port;
 475
 476     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 477     # instead we pipe it through STDIN
 478     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 479         my $line = shift;
 480
 481         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 482             $raddr = $1;
 483             $rport = int($2);
 484             $ruri = "tcp:$raddr:$rport";
 485         }
 486         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 487             $raddr = $1;
 488             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 489             $ruri = "unix:$raddr";
 490         }
 491         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 492             $raddr = "localhost";
 493             $rport = int($1);
 494             $ruri = "tcp:$raddr:$rport";
 495         }
 496         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 497             $spice_port = int($1);
 498         }
 499     }, errfunc => sub {
 500         my $line = shift;
 501         $self->log('info', $line);
 502     });
 503
 504     die "unable to detect remote migration address\n" if !$raddr;
 505
 506     if ($secure_migration) {
 507         $self->log('info', "start remote tunnel");
 508
 509         if ($ruri =~ /^unix:/) {
 510             unlink $raddr;
 511             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 512             $self->{tunnel}->{sock_addr} = $raddr;
 513
 514             my $unix_socket_try = 0; # wait for the socket to become ready
 515             while (! -S $raddr) {
 516                 $unix_socket_try++;
 517                 if ($unix_socket_try > 100) {
 518                     $self->{errors} = 1;
 519                     $self->finish_tunnel($self->{tunnel});
 520                     die "Timeout, migration socket $ruri did not get ready";
 521                 }
 522
 523                 usleep(50000);
 524             }
 525
 526         } elsif ($ruri =~ /^tcp:/) {
 527             my $tunnel_addr;
 528             if ($raddr eq "localhost") {
 529                 # for backwards compatibility with older qemu-server versions
 530                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 531                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 532                 $tunnel_addr = "$lport:localhost:$rport";
 533             }
 534
 535             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 536
 537         } else {
 538             die "unsupported protocol in migration URI: $ruri\n";
 539         }
 540     }
 541
 542     my $start = time();
 543     $self->log('info', "starting online/live migration on $ruri");
 544     $self->{livemigration} = 1;
 545
 546     # load_defaults
 547     my $defaults = PVE::QemuServer::load_defaults();
 548
 549     # always set migrate speed (overwrite kvm default of 32m)
 550     # we set a very hight default of 8192m which is basically unlimited
 551     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 552     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 553     $migrate_speed = $migrate_speed * 1048576;
 554     $self->log('info', "migrate_set_speed: $migrate_speed");
 555     eval {
 556         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 557     };
 558     $self->log('info', "migrate_set_speed error: $@") if $@;
 559
 560     my $migrate_downtime = $defaults->{migrate_downtime};
 561     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 562     if (defined($migrate_downtime)) {
 563         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 564         eval {
 565             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 566         };
 567         $self->log('info', "migrate_set_downtime error: $@") if $@;
 568     }
 569
 570     $self->log('info', "set migration_caps");
 571     eval {
 572         PVE::QemuServer::set_migration_caps($vmid);
 573     };
 574     warn $@ if $@;
 575
 576     #set cachesize 10% of the total memory
 577     my $cachesize = int($conf->{memory}*1048576/10);
 578     $self->log('info', "set cachesize: $cachesize");
 579     eval {
 580         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 581     };
 582     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 583
 584     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 585         my $rpcenv = PVE::RPCEnvironment::get();
 586         my $authuser = $rpcenv->get_user();
 587
 588         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 589
 590         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 591         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 592
 593         $self->log('info', "spice client_migrate_info");
 594
 595         eval {
 596             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 597                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 598                                                 'cert-subject' => $subject);
 599         };
 600         $self->log('info', "client_migrate_info error: $@") if $@;
 601
 602     }
 603
 604     $self->log('info', "start migrate command to $ruri");
 605     eval {
 606         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 607     };
 608     my $merr = $@;
 609     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 610
 611     my $lstat = 0;
 612     my $usleep = 2000000;
 613     my $i = 0;
 614     my $err_count = 0;
 615     my $lastrem = undef;
 616     my $downtimecounter = 0;
 617     while (1) {
 618         $i++;
 619         my $avglstat = $lstat/$i if $lstat;
 620
 621         usleep($usleep);
 622         my $stat;
 623         eval {
 624             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 625         };
 626         if (my $err = $@) {
 627             $err_count++;
 628             warn "query migrate failed: $err\n";
 629             $self->log('info', "query migrate failed: $err");
 630             if ($err_count <= 5) {
 631                 usleep(1000000);
 632                 next;
 633             }
 634             die "too many query migrate failures - aborting\n";
 635         }
 636
 637         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 638             sleep(1);
 639             next;
 640         }
 641
 642         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 643             $merr = undef;
 644             $err_count = 0;
 645             if ($stat->{status} eq 'completed') {
 646                 my $delay = time() - $start;
 647                 if ($delay > 0) {
 648                     my $mbps = sprintf "%.2f", $conf->{memory}/$delay;
 649                     my $downtime = $stat->{downtime} || 0;
 650                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 651                 }
 652             }
 653
 654             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 655                 $self->log('info', "migration status error: $stat->{status}");
 656                 die "aborting\n"
 657             }
 658
 659             if ($stat->{status} ne 'active') {
 660                 $self->log('info', "migration status: $stat->{status}");
 661                 last;
 662             }
 663
 664             if ($stat->{ram}->{transferred} ne $lstat) {
 665                 my $trans = $stat->{ram}->{transferred} || 0;
 666                 my $rem = $stat->{ram}->{remaining} || 0;
 667                 my $total = $stat->{ram}->{total} || 0;
 668                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 669                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 670                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 671                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 672                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 673                 #reduce sleep if remainig memory if lower than the everage transfert
 674                 $usleep = 300000 if $avglstat && $rem < $avglstat;
 675
 676                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 677                            "remaining ${rem}), total ${total})");
 678
 679                 if (${xbzrlecachesize}) {
 680                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 681                 }
 682
 683                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 684                     $downtimecounter++;
 685                 }
 686                 $lastrem = $rem;
 687
 688                 if ($downtimecounter > 5) {
 689                     $downtimecounter = 0;
 690                     $migrate_downtime *= 2;
 691                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 692                     eval {
 693                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 694                     };
 695                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 696                 }
 697
 698             }
 699
 700
 701             $lstat = $stat->{ram}->{transferred};
 702
 703         } else {
 704             die $merr if $merr;
 705             die "unable to parse migration status '$stat->{status}' - aborting\n";
 706         }
 707     }
 708
 709     # just to be sure that the tunnel gets closed on successful migration, on error
 710     # phase2_cleanup closes it *after* stopping the remote waiting VM
 711     if (!$self->{errors} && $self->{tunnel}) {
 712         eval { finish_tunnel($self, $self->{tunnel});  };
 713         if (my $err = $@) {
 714             $self->log('err', $err);
 715             $self->{errors} = 1;
 716         }
 717     }
 718 }
 719
 720 sub phase2_cleanup {
 721     my ($self, $vmid, $err) = @_;
 722
 723     return if !$self->{errors};
 724     $self->{phase2errors} = 1;
 725
 726     $self->log('info', "aborting phase 2 - cleanup resources");
 727
 728     $self->log('info', "migrate_cancel");
 729     eval {
 730         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 731     };
 732     $self->log('info', "migrate_cancel error: $@") if $@;
 733
 734     my $conf = $self->{vmconf};
 735     delete $conf->{lock};
 736     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 737     if (my $err = $@) {
 738         $self->log('err', $err);
 739     }
 740
 741     # cleanup ressources on target host
 742     my $nodename = PVE::INotify::nodename();
 743
 744     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 745     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 746     if (my $err = $@) {
 747         $self->log('err', $err);
 748         $self->{errors} = 1;
 749     }
 750
 751     if ($self->{tunnel}) {
 752         eval { finish_tunnel($self, $self->{tunnel});  };
 753         if (my $err = $@) {
 754             $self->log('err', $err);
 755             $self->{errors} = 1;
 756         }
 757     }
 758 }
 759
 760 sub phase3 {
 761     my ($self, $vmid) = @_;
 762
 763     my $volids = $self->{volumes};
 764     return if $self->{phase2errors};
 765
 766     # destroy local copies
 767     foreach my $volid (@$volids) {
 768         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 769         if (my $err = $@) {
 770             $self->log('err', "removing local copy of '$volid' failed - $err");
 771             $self->{errors} = 1;
 772             last if $err =~ /^interrupted by signal$/;
 773         }
 774     }
 775 }
 776
 777 sub phase3_cleanup {
 778     my ($self, $vmid, $err) = @_;
 779
 780     my $conf = $self->{vmconf};
 781     return if $self->{phase2errors};
 782
 783     # move config to remote node
 784     my $conffile = PVE::QemuConfig->config_file($vmid);
 785     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 786
 787     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 788         if !rename($conffile, $newconffile);
 789
 790     if ($self->{livemigration}) {
 791         # now that config file is move, we can resume vm on target if livemigrate
 792         my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 793         eval{ PVE::Tools::run_command($cmd, outfunc => sub {},
 794                 errfunc => sub {
 795                     my $line = shift;
 796                     $self->log('err', $line);
 797                 });
 798         };
 799         if (my $err = $@) {
 800             $self->log('err', $err);
 801             $self->{errors} = 1;
 802         }
 803     }
 804
 805     eval {
 806
 807         my $timer = 0;
 808         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
 809             $self->log('info', "Waiting for spice server migration");
 810             while (1) {
 811                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
 812                 last if int($res->{'migrated'}) == 1;
 813                 last if $timer > 50;
 814                 $timer ++;
 815                 usleep(200000);
 816             }
 817         }
 818     };
 819
 820     # always stop local VM
 821     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 822     if (my $err = $@) {
 823         $self->log('err', "stopping vm failed - $err");
 824         $self->{errors} = 1;
 825     }
 826
 827     # always deactivate volumes - avoid lvm LVs to be active on several nodes
 828     eval {
 829         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 830         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
 831     };
 832     if (my $err = $@) {
 833         $self->log('err', $err);
 834         $self->{errors} = 1;
 835     }
 836
 837     # clear migrate lock
 838     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
 839     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
 840 }
 841
 842 sub final_cleanup {
 843     my ($self, $vmid) = @_;
 844
 845     # nothing to do
 846 }
 847
 848 1;