PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::INotify;
  13 use PVE::RPCEnvironment;
  14 use PVE::Replication;
  15 use PVE::ReplicationConfig;
  16 use PVE::ReplicationState;
  17 use PVE::Storage;
  18 use PVE::Tools;
  19
  20 use PVE::QemuConfig;
  21 use PVE::QemuServer::CPUConfig;
  22 use PVE::QemuServer::Drive;
  23 use PVE::QemuServer::Helpers qw(min_version);
  24 use PVE::QemuServer::Machine;
  25 use PVE::QemuServer::Monitor qw(mon_cmd);
  26 use PVE::QemuServer;
  27
  28 use PVE::AbstractMigrate;
  29 use base qw(PVE::AbstractMigrate);
  30
  31 sub fork_command_pipe {
  32     my ($self, $cmd) = @_;
  33
  34     my $reader = IO::File->new();
  35     my $writer = IO::File->new();
  36
  37     my $orig_pid = $$;
  38
  39     my $cpid;
  40
  41     eval { $cpid = open2($reader, $writer, @$cmd); };
  42
  43     my $err = $@;
  44
  45     # catch exec errors
  46     if ($orig_pid != $$) {
  47         $self->log('err', "can't fork command pipe\n");
  48         POSIX::_exit(1);
  49         kill('KILL', $$);
  50     }
  51
  52     die $err if $err;
  53
  54     return { writer => $writer, reader => $reader, pid => $cpid };
  55 }
  56
  57 sub finish_command_pipe {
  58     my ($self, $cmdpipe, $timeout) = @_;
  59
  60     my $cpid = $cmdpipe->{pid};
  61     return if !defined($cpid);
  62
  63     my $writer = $cmdpipe->{writer};
  64     my $reader = $cmdpipe->{reader};
  65
  66     $writer->close();
  67     $reader->close();
  68
  69     my $collect_child_process = sub {
  70         my $res = waitpid($cpid, WNOHANG);
  71         if (defined($res) && ($res == $cpid)) {
  72             delete $cmdpipe->{cpid};
  73             return 1;
  74         } else {
  75             return 0;
  76         }
  77      };
  78
  79     if ($timeout) {
  80         for (my $i = 0; $i < $timeout; $i++) {
  81             return if &$collect_child_process();
  82             sleep(1);
  83         }
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  87     kill(15, $cpid);
  88
  89     # wait again
  90     for (my $i = 0; $i < 10; $i++) {
  91         return if &$collect_child_process();
  92         sleep(1);
  93     }
  94
  95     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  96     kill 9, $cpid;
  97     sleep 1;
  98
  99     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
 100         if !&$collect_child_process();
 101 }
 102
 103 sub read_tunnel {
 104     my ($self, $tunnel, $timeout) = @_;
 105
 106     $timeout = 60 if !defined($timeout);
 107
 108     my $reader = $tunnel->{reader};
 109
 110     my $output;
 111     eval {
 112         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 113     };
 114     die "reading from tunnel failed: $@\n" if $@;
 115
 116     chomp $output;
 117
 118     return $output;
 119 }
 120
 121 sub write_tunnel {
 122     my ($self, $tunnel, $timeout, $command) = @_;
 123
 124     $timeout = 60 if !defined($timeout);
 125
 126     my $writer = $tunnel->{writer};
 127
 128     eval {
 129         PVE::Tools::run_with_timeout($timeout, sub {
 130             print $writer "$command\n";
 131             $writer->flush();
 132         });
 133     };
 134     die "writing to tunnel failed: $@\n" if $@;
 135
 136     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 137         my $res = eval { $self->read_tunnel($tunnel, 10); };
 138         die "no reply to command '$command': $@\n" if $@;
 139
 140         if ($res eq 'OK') {
 141             return;
 142         } else {
 143             die "tunnel replied '$res' to command '$command'\n";
 144         }
 145     }
 146 }
 147
 148 sub fork_tunnel {
 149     my ($self, $tunnel_addr) = @_;
 150
 151     my @localtunnelinfo = ();
 152     foreach my $addr (@$tunnel_addr) {
 153         push @localtunnelinfo, '-L', $addr;
 154     }
 155
 156     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 157
 158     my $tunnel = $self->fork_command_pipe($cmd);
 159
 160     eval {
 161         my $helo = $self->read_tunnel($tunnel, 60);
 162         die "no reply\n" if !$helo;
 163         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 164         die "got strange reply from mtunnel ('$helo')\n"
 165             if $helo !~ m/^tunnel online$/;
 166     };
 167     my $err = $@;
 168
 169     eval {
 170         my $ver = $self->read_tunnel($tunnel, 10);
 171         if ($ver =~ /^ver (\d+)$/) {
 172             $tunnel->{version} = $1;
 173             $self->log('info', "ssh tunnel $ver\n");
 174         } else {
 175             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 176         }
 177     };
 178
 179     if ($err) {
 180         $self->finish_command_pipe($tunnel);
 181         die "can't open migration tunnel - $err";
 182     }
 183     return $tunnel;
 184 }
 185
 186 sub finish_tunnel {
 187     my ($self, $tunnel) = @_;
 188
 189     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 190     my $err = $@;
 191
 192     $self->finish_command_pipe($tunnel, 30);
 193
 194     if ($tunnel->{sock_addr}) {
 195         # ssh does not clean up on local host
 196         my $cmd = ['rm', '-f', @{$tunnel->{sock_addr}}]; #
 197         PVE::Tools::run_command($cmd);
 198
 199         # .. and just to be sure check on remote side
 200         unshift @{$cmd}, @{$self->{rem_ssh}};
 201         PVE::Tools::run_command($cmd);
 202     }
 203
 204     die $err if $err;
 205 }
 206
 207 sub lock_vm {
 208     my ($self, $vmid, $code, @param) = @_;
 209
 210     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 211 }
 212
 213 sub prepare {
 214     my ($self, $vmid) = @_;
 215
 216     my $online = $self->{opts}->{online};
 217
 218     $self->{storecfg} = PVE::Storage::config();
 219
 220     # test if VM exists
 221     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 222
 223     PVE::QemuConfig->check_lock($conf);
 224
 225     my $running = 0;
 226     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 227         die "can't migrate running VM without --online\n" if !$online;
 228         $running = $pid;
 229
 230         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 231
 232         # To support custom CPU types, we keep QEMU's "-cpu" parameter intact.
 233         # Since the parameter itself contains no reference to a custom model,
 234         # this makes migration independent of changes to "cpu-models.conf".
 235         if ($conf->{cpu}) {
 236             my $cpuconf = PVE::QemuServer::CPUConfig::parse_cpu_conf_basic($conf->{cpu});
 237             if ($cpuconf && PVE::QemuServer::CPUConfig::is_custom_model($cpuconf->{cputype})) {
 238                 $self->{forcecpu} = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 239             }
 240         }
 241     }
 242
 243     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 244     if (scalar @$loc_res) {
 245         if ($self->{running} || !$self->{opts}->{force}) {
 246             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 247         } else {
 248             $self->log('info', "migrating VM which uses local devices");
 249         }
 250     }
 251
 252     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 253
 254     my $need_activate = [];
 255     foreach my $volid (@$vollist) {
 256         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 257
 258         # check if storage is available on both nodes
 259         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 260
 261         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 262         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 263
 264         if ($scfg->{shared}) {
 265             # PVE::Storage::activate_storage checks this for non-shared storages
 266             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 267             warn "Used shared storage '$sid' is not online on source node!\n"
 268                 if !$plugin->check_connection($sid, $scfg);
 269         } else {
 270             # only activate if not shared
 271             next if ($volid =~ m/vm-\d+-cloudinit/);
 272             push @$need_activate, $volid;
 273         }
 274     }
 275
 276     # activate volumes
 277     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 278
 279     # test ssh connection
 280     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 281     eval { $self->cmd_quiet($cmd); };
 282     die "Can't connect to destination address using public key\n" if $@;
 283
 284     return $running;
 285 }
 286
 287 sub sync_disks {
 288     my ($self, $vmid) = @_;
 289
 290     my $conf = $self->{vmconf};
 291
 292     # local volumes which have been copied
 293     # and their old_id => new_id pairs
 294     $self->{volumes} = [];
 295     $self->{volume_map} = {};
 296
 297     my $storecfg = $self->{storecfg};
 298     eval {
 299
 300         # found local volumes and their origin
 301         my $local_volumes = {};
 302         my $local_volumes_errors = {};
 303         my $other_errors = [];
 304         my $abort = 0;
 305
 306         my $log_error = sub {
 307             my ($msg, $volid) = @_;
 308
 309             if (defined($volid)) {
 310                 $local_volumes_errors->{$volid} = $msg;
 311             } else {
 312                 push @$other_errors, $msg;
 313             }
 314             $abort = 1;
 315         };
 316
 317         my @sids = PVE::Storage::storage_ids($storecfg);
 318         foreach my $storeid (@sids) {
 319             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 320             next if $scfg->{shared};
 321             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 322
 323             # get list from PVE::Storage (for unused volumes)
 324             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 325
 326             next if @{$dl->{$storeid}} == 0;
 327
 328             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $storeid);
 329             # check if storage is available on target node
 330             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 331
 332             # grandfather in existing mismatches
 333             if ($targetsid ne $storeid) {
 334                 my $target_scfg = PVE::Storage::storage_config($storecfg, $targetsid);
 335                 die "content type 'images' is not available on storage '$targetsid'\n"
 336                     if !$target_scfg->{content}->{images};
 337             }
 338
 339             PVE::Storage::foreach_volid($dl, sub {
 340                 my ($volid, $sid, $volinfo) = @_;
 341
 342                 $local_volumes->{$volid}->{ref} = 'storage';
 343
 344                 # If with_snapshots is not set for storage migrate, it tries to use
 345                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 346                 # back to qcow2 is currently not possible.
 347                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 348                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 349             });
 350         }
 351
 352         my $rep_cfg = PVE::ReplicationConfig->new();
 353         my $replication_jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node});
 354         my $replicatable_volumes = !$replication_jobcfg ? {}
 355             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 356
 357         my $test_volid = sub {
 358             my ($volid, $attr) = @_;
 359
 360             if ($volid =~ m|^/|) {
 361                 return if $attr->{shared};
 362                 $local_volumes->{$volid}->{ref} = 'config';
 363                 die "local file/device\n";
 364             }
 365
 366             my $snaprefs = $attr->{referenced_in_snapshot};
 367
 368             if ($attr->{cdrom}) {
 369                 if ($volid eq 'cdrom') {
 370                     my $msg = "can't migrate local cdrom drive";
 371                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 372                         my $snapnames = join(', ', sort keys %$snaprefs);
 373                         $msg .= " (referenced in snapshot - $snapnames)";
 374                     }
 375                     &$log_error("$msg\n");
 376                     return;
 377                 }
 378                 return if $volid eq 'none';
 379             }
 380
 381             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 382
 383             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 384             # check if storage is available on both nodes
 385             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 386             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 387
 388             return if $scfg->{shared};
 389
 390             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 391             $local_volumes->{$volid}->{ref} = 'storage' if $attr->{is_unused};
 392
 393             $local_volumes->{$volid}->{is_vmstate} = $attr->{is_vmstate} ? 1 : 0;
 394
 395             if ($attr->{cdrom}) {
 396                 if ($volid =~ /vm-\d+-cloudinit/) {
 397                     $local_volumes->{$volid}->{ref} = 'generated';
 398                     return;
 399                 }
 400                 die "local cdrom image\n";
 401             }
 402
 403             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 404
 405             die "owned by other VM (owner = VM $owner)\n"
 406                 if !$owner || ($owner != $vmid);
 407
 408             return if $attr->{is_vmstate};
 409
 410             if (defined($snaprefs)) {
 411                 $local_volumes->{$volid}->{snapshots} = 1;
 412
 413                 # we cannot migrate shapshots on local storage
 414                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 415
 416                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 417                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 418                     die "non-migratable snapshot exists\n";
 419                 }
 420             }
 421
 422             die "referenced by linked clone(s)\n"
 423                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 424         };
 425
 426         PVE::QemuServer::foreach_volid($conf, sub {
 427             my ($volid, $attr) = @_;
 428             eval { $test_volid->($volid, $attr); };
 429             if (my $err = $@) {
 430                 &$log_error($err, $volid);
 431             }
 432         });
 433
 434         foreach my $vol (sort keys %$local_volumes) {
 435             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 436             my $ref = $local_volumes->{$vol}->{ref};
 437             if ($ref eq 'storage') {
 438                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 439             } elsif ($ref eq 'config') {
 440                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 441                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 442                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 443             } elsif ($ref eq 'snapshot') {
 444                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 445             } elsif ($ref eq 'generated') {
 446                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 447             } else {
 448                 $self->log('info', "found $type disk '$vol'\n");
 449             }
 450         }
 451
 452         foreach my $vol (sort keys %$local_volumes_errors) {
 453             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 454         }
 455         foreach my $err (@$other_errors) {
 456             $self->log('warn', "$err");
 457         }
 458
 459         if ($abort) {
 460             die "can't migrate VM - check log\n";
 461         }
 462
 463         # additional checks for local storage
 464         foreach my $volid (keys %$local_volumes) {
 465             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 466             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 467
 468             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 469
 470             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 471                 if !$migratable;
 472
 473             # image is a linked clone on local storage, se we can't migrate.
 474             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 475                 die "can't migrate '$volid' as it's a clone of '$basename'";
 476             }
 477         }
 478
 479         if ($replication_jobcfg) {
 480             if ($self->{running}) {
 481
 482                 my $version = PVE::QemuServer::kvm_user_version();
 483                 if (!min_version($version, 4, 2)) {
 484                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 485                 }
 486
 487                 my $live_replicatable_volumes = {};
 488                 PVE::QemuConfig->foreach_volume($conf, sub {
 489                     my ($ds, $drive) = @_;
 490
 491                     my $volid = $drive->{file};
 492                     $live_replicatable_volumes->{$ds} = $volid
 493                         if defined($replicatable_volumes->{$volid});
 494                 });
 495                 foreach my $drive (keys %$live_replicatable_volumes) {
 496                     my $volid = $live_replicatable_volumes->{$drive};
 497
 498                     my $bitmap = "repl_$drive";
 499
 500                     # start tracking before replication to get full delta + a few duplicates
 501                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 502                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 503
 504                     # other info comes from target node in phase 2
 505                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 506                 }
 507             }
 508             $self->log('info', "replicating disk images");
 509
 510             my $start_time = time();
 511             my $logfunc = sub { $self->log('info', shift) };
 512             $self->{replicated_volumes} = PVE::Replication::run_replication(
 513                'PVE::QemuConfig', $replication_jobcfg, $start_time, $start_time, $logfunc);
 514         }
 515
 516         # sizes in config have to be accurate for remote node to correctly
 517         # allocate disks, rescan to be sure
 518         my $volid_hash = PVE::QemuServer::scan_volids($storecfg, $vmid);
 519         PVE::QemuConfig->foreach_volume($conf, sub {
 520             my ($key, $drive) = @_;
 521             my ($updated, $old_size, $new_size) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash);
 522             if (defined($updated)) {
 523                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 524                 $self->log('info', "size of disk '$updated->{file}' ($key) updated from $old_size to $new_size\n");
 525             }
 526         });
 527
 528         # we want to set the efidisk size in the config to the size of the
 529         # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 530         if (defined($conf->{efidisk0})) {
 531             PVE::QemuServer::update_efidisk_size($conf);
 532         }
 533
 534         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 535
 536         foreach my $volid (keys %$local_volumes) {
 537             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 538             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 539             my $ref = $local_volumes->{$volid}->{ref};
 540             if ($self->{running} && $ref eq 'config') {
 541                 push @{$self->{online_local_volumes}}, $volid;
 542             } elsif ($ref eq 'generated') {
 543                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 544                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 545                 push @{$self->{volumes}}, $volid;
 546                 next;
 547             } else {
 548                 next if $self->{replicated_volumes}->{$volid};
 549                 push @{$self->{volumes}}, $volid;
 550                 my $opts = $self->{opts};
 551                 # use 'migrate' limit for transfer to other node
 552                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 553                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 554                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 555
 556                 my $storage_migrate_opts = {
 557                     'bwlimit' => $bwlimit,
 558                     'insecure' => $opts->{migration_type} eq 'insecure',
 559                     'with_snapshots' => $local_volumes->{$volid}->{snapshots},
 560                     'allow_rename' => !$local_volumes->{$volid}->{is_vmstate},
 561                 };
 562
 563                 my $logfunc = sub { $self->log('info', $_[0]); };
 564                 my $new_volid = eval {
 565                     PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info},
 566                                                   $targetsid, $storage_migrate_opts, $logfunc);
 567                 };
 568                 if (my $err = $@) {
 569                     die "storage migration for '$volid' to storage '$targetsid' failed - $err\n";
 570                 }
 571
 572                 $self->{volume_map}->{$volid} = $new_volid;
 573                 $self->log('info', "volume '$volid' is '$new_volid' on the target\n");
 574             }
 575         }
 576     };
 577     die "Failed to sync data - $@" if $@;
 578 }
 579
 580 sub cleanup_remotedisks {
 581     my ($self) = @_;
 582
 583     foreach my $target_drive (keys %{$self->{target_drive}}) {
 584         my $drivestr = $self->{target_drive}->{$target_drive}->{drivestr};
 585         next if !defined($drivestr);
 586
 587         my $drive = PVE::QemuServer::parse_drive($target_drive, $drivestr);
 588
 589         # don't clean up replicated disks!
 590         next if defined($self->{replicated_volumes}->{$drive->{file}});
 591
 592         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 593
 594         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 595
 596         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 597         if (my $err = $@) {
 598             $self->log('err', $err);
 599             $self->{errors} = 1;
 600         }
 601     }
 602 }
 603
 604 sub cleanup_bitmaps {
 605     my ($self) = @_;
 606     foreach my $drive (keys %{$self->{target_drive}}) {
 607         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 608         next if !$bitmap;
 609         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 610         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 611     }
 612 }
 613
 614 sub phase1 {
 615     my ($self, $vmid) = @_;
 616
 617     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 618
 619     my $conf = $self->{vmconf};
 620
 621     # set migrate lock in config file
 622     $conf->{lock} = 'migrate';
 623     PVE::QemuConfig->write_config($vmid, $conf);
 624
 625     sync_disks($self, $vmid);
 626
 627     # sync_disks fixes disk sizes to match their actual size, write changes so
 628     # target allocates correct volumes
 629     PVE::QemuConfig->write_config($vmid, $conf);
 630 };
 631
 632 sub phase1_cleanup {
 633     my ($self, $vmid, $err) = @_;
 634
 635     $self->log('info', "aborting phase 1 - cleanup resources");
 636
 637     my $conf = $self->{vmconf};
 638     delete $conf->{lock};
 639     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 640     if (my $err = $@) {
 641         $self->log('err', $err);
 642     }
 643
 644     if ($self->{volumes}) {
 645         foreach my $volid (@{$self->{volumes}}) {
 646             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 647             # fixme: try to remove ?
 648         }
 649     }
 650
 651     eval { $self->cleanup_bitmaps() };
 652     if (my $err =$@) {
 653         $self->log('err', $err);
 654     }
 655
 656 }
 657
 658 sub phase2 {
 659     my ($self, $vmid) = @_;
 660
 661     my $conf = $self->{vmconf};
 662
 663     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 664
 665     my $raddr;
 666     my $rport;
 667     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 668     my $nodename = PVE::INotify::nodename();
 669
 670     ## start on remote node
 671     my $cmd = [@{$self->{rem_ssh}}];
 672
 673     my $spice_ticket;
 674     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 675         my $res = mon_cmd($vmid, 'query-spice');
 676         $spice_ticket = $res->{ticket};
 677     }
 678
 679     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 680
 681     my $migration_type = $self->{opts}->{migration_type};
 682
 683     push @$cmd, '--migration_type', $migration_type;
 684
 685     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 686       if $self->{opts}->{migration_network};
 687
 688     if ($migration_type eq 'insecure') {
 689         push @$cmd, '--stateuri', 'tcp';
 690     } else {
 691         push @$cmd, '--stateuri', 'unix';
 692     }
 693
 694     if ($self->{forcemachine}) {
 695         push @$cmd, '--machine', $self->{forcemachine};
 696     }
 697
 698     if ($self->{forcecpu}) {
 699         push @$cmd, '--force-cpu', $self->{forcecpu};
 700     }
 701
 702     if ($self->{online_local_volumes}) {
 703         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 704     }
 705
 706     my $spice_port;
 707     my $tunnel_addr = [];
 708     my $sock_addr = [];
 709     # version > 0 for unix socket support
 710     my $nbd_protocol_version = 1;
 711     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 712     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 713     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 714
 715     my $number_of_online_replicated_volumes = 0;
 716     foreach my $volid (@{$self->{online_local_volumes}}) {
 717         next if !$self->{replicated_volumes}->{$volid};
 718         $number_of_online_replicated_volumes++;
 719         $input .= "replicated_volume: $volid\n";
 720     }
 721
 722     my $target_replicated_volumes = {};
 723
 724     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 725     # instead we pipe it through STDIN
 726     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 727         my $line = shift;
 728
 729         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 730             $raddr = $1;
 731             $rport = int($2);
 732             $ruri = "tcp:$raddr:$rport";
 733         }
 734         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 735             $raddr = $1;
 736             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 737             $ruri = "unix:$raddr";
 738         }
 739         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 740             $raddr = "localhost";
 741             $rport = int($1);
 742             $ruri = "tcp:$raddr:$rport";
 743         }
 744         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 745             $spice_port = int($1);
 746         }
 747         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 748             my $drivestr = $4;
 749             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 750             my $targetdrive = $3;
 751             $targetdrive =~ s/drive-//g;
 752
 753             $self->{stopnbd} = 1;
 754             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 755             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 756         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 757             my $drivestr = $4;
 758             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 759             my $nbd_unix_addr = $1;
 760             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 761             my $targetdrive = $3;
 762             $targetdrive =~ s/drive-//g;
 763
 764             $self->{stopnbd} = 1;
 765             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 766             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 767             push @$tunnel_addr, "$nbd_unix_addr:$nbd_unix_addr";
 768             push @$sock_addr, $nbd_unix_addr;
 769         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 770             my $drive = $1;
 771             my $volid = $2;
 772             $target_replicated_volumes->{$volid} = $drive;
 773         } elsif ($line =~ m/^QEMU: (.*)$/) {
 774             $self->log('info', "[$self->{node}] $1\n");
 775         }
 776     }, errfunc => sub {
 777         my $line = shift;
 778         $self->log('info', "[$self->{node}] $line");
 779     }, noerr => 1);
 780
 781     die "remote command failed with exit code $exitcode\n" if $exitcode;
 782
 783     die "unable to detect remote migration address\n" if !$raddr;
 784
 785     if (scalar(keys %$target_replicated_volumes) != $number_of_online_replicated_volumes) {
 786         die "number of replicated disks on source and target node do not match - target node too old?\n"
 787     }
 788
 789     $self->log('info', "start remote tunnel");
 790
 791     if ($migration_type eq 'secure') {
 792
 793         if ($ruri =~ /^unix:/) {
 794             unlink $raddr;
 795             push @$tunnel_addr, "$raddr:$raddr";
 796             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 797             push @$sock_addr, $raddr;
 798
 799             my $unix_socket_try = 0; # wait for the socket to become ready
 800             while ($unix_socket_try <= 100) {
 801                 $unix_socket_try++;
 802                 my $available = 0;
 803                 foreach my $sock (@$sock_addr) {
 804                     if (-S $sock) {
 805                         $available++;
 806                     }
 807                 }
 808
 809                 if ($available == @$sock_addr) {
 810                     last;
 811                 }
 812
 813                 usleep(50000);
 814             }
 815             if ($unix_socket_try > 100) {
 816                 $self->{errors} = 1;
 817                 $self->finish_tunnel($self->{tunnel});
 818                 die "Timeout, migration socket $ruri did not get ready";
 819             }
 820
 821         } elsif ($ruri =~ /^tcp:/) {
 822             my $tunnel_addr;
 823             if ($raddr eq "localhost") {
 824                 # for backwards compatibility with older qemu-server versions
 825                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 826                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 827                 $tunnel_addr = "$lport:localhost:$rport";
 828             }
 829
 830             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 831
 832         } else {
 833             die "unsupported protocol in migration URI: $ruri\n";
 834         }
 835     } else {
 836         #fork tunnel for insecure migration, to send faster commands like resume
 837         $self->{tunnel} = $self->fork_tunnel();
 838     }
 839     $self->{tunnel}->{sock_addr} = $sock_addr if (@$sock_addr);
 840
 841     my $start = time();
 842
 843     my $opt_bwlimit = $self->{opts}->{bwlimit};
 844
 845     if (defined($self->{online_local_volumes})) {
 846         $self->{storage_migration} = 1;
 847         $self->{storage_migration_jobs} = {};
 848         $self->log('info', "starting storage migration");
 849
 850         die "The number of local disks does not match between the source and the destination.\n"
 851             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 852         foreach my $drive (keys %{$self->{target_drive}}){
 853             my $target = $self->{target_drive}->{$drive};
 854             my $nbd_uri = $target->{nbd_uri};
 855
 856             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 857             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 858
 859             my $source_volid = $source_drive->{file};
 860             my $target_volid = $target_drive->{file};
 861
 862             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_volid);
 863             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_volid);
 864
 865             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 866             my $bitmap = $target->{bitmap};
 867
 868             $self->log('info', "$drive: start migration to $nbd_uri");
 869             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 870
 871             $self->{volume_map}->{$source_volid} = $target_volid;
 872             $self->log('info', "volume '$source_volid' is '$target_volid' on the target\n");
 873         }
 874     }
 875
 876     $self->log('info', "starting online/live migration on $ruri");
 877     $self->{livemigration} = 1;
 878
 879     # load_defaults
 880     my $defaults = PVE::QemuServer::load_defaults();
 881
 882     $self->log('info', "set migration_caps");
 883     eval {
 884         PVE::QemuServer::set_migration_caps($vmid);
 885     };
 886     warn $@ if $@;
 887
 888     my $qemu_migrate_params = {};
 889
 890     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 891     # migrate_speed parameter in qm.conf - take the lower of the two.
 892     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 893     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 894     # migrate_speed is in MB/s, bwlimit in KB/s
 895     $migrate_speed *= 1024;
 896
 897     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 898
 899     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 900     # default of 8192m which is basically unlimited
 901     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 902
 903     # qmp takes migrate_speed in B/s.
 904     $migrate_speed *= 1024;
 905     $self->log('info', "migration speed limit: $migrate_speed B/s");
 906     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 907
 908     my $migrate_downtime = $defaults->{migrate_downtime};
 909     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 910     # migrate-set-parameters expects limit in ms
 911     $migrate_downtime *= 1000;
 912     $self->log('info', "migration downtime limit: $migrate_downtime ms");
 913     $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 914
 915     # set cachesize to 10% of the total memory
 916     my $memory =  $conf->{memory} || $defaults->{memory};
 917     my $cachesize = int($memory * 1048576 / 10);
 918     $cachesize = round_powerof2($cachesize);
 919
 920     $self->log('info', "migration cachesize: $cachesize B");
 921     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 922
 923     $self->log('info', "set migration parameters");
 924     eval {
 925         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 926     };
 927     $self->log('info', "migrate-set-parameters error: $@") if $@;
 928
 929     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 930         my $rpcenv = PVE::RPCEnvironment::get();
 931         my $authuser = $rpcenv->get_user();
 932
 933         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 934
 935         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 936         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 937
 938         $self->log('info', "spice client_migrate_info");
 939
 940         eval {
 941             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 942                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 943                                                 'cert-subject' => $subject);
 944         };
 945         $self->log('info', "client_migrate_info error: $@") if $@;
 946
 947     }
 948
 949     $self->log('info', "start migrate command to $ruri");
 950     eval {
 951         mon_cmd($vmid, "migrate", uri => $ruri);
 952     };
 953     my $merr = $@;
 954     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 955
 956     my $lstat = 0;
 957     my $usleep = 1000000;
 958     my $i = 0;
 959     my $err_count = 0;
 960     my $lastrem = undef;
 961     my $downtimecounter = 0;
 962     while (1) {
 963         $i++;
 964         my $avglstat = $lstat/$i if $lstat;
 965
 966         usleep($usleep);
 967         my $stat;
 968         eval {
 969             $stat = mon_cmd($vmid, "query-migrate");
 970         };
 971         if (my $err = $@) {
 972             $err_count++;
 973             warn "query migrate failed: $err\n";
 974             $self->log('info', "query migrate failed: $err");
 975             if ($err_count <= 5) {
 976                 usleep(1000000);
 977                 next;
 978             }
 979             die "too many query migrate failures - aborting\n";
 980         }
 981
 982         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 983             sleep(1);
 984             next;
 985         }
 986
 987         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 988             $merr = undef;
 989             $err_count = 0;
 990             if ($stat->{status} eq 'completed') {
 991                 my $delay = time() - $start;
 992                 if ($delay > 0) {
 993                     my $mbps = sprintf "%.2f", $memory / $delay;
 994                     my $downtime = $stat->{downtime} || 0;
 995                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 996                 }
 997             }
 998
 999             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
1000                 $self->log('info', "migration status error: $stat->{status}");
1001                 die "aborting\n"
1002             }
1003
1004             if ($stat->{status} ne 'active') {
1005                 $self->log('info', "migration status: $stat->{status}");
1006                 last;
1007             }
1008
1009             if ($stat->{ram}->{transferred} ne $lstat) {
1010                 my $trans = $stat->{ram}->{transferred} || 0;
1011                 my $rem = $stat->{ram}->{remaining} || 0;
1012                 my $total = $stat->{ram}->{total} || 0;
1013                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
1014                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
1015                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
1016                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
1017                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
1018                 # reduce sleep if remainig memory is lower than the average transfer speed
1019                 $usleep = 100000 if $avglstat && $rem < $avglstat;
1020
1021                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
1022                            "remaining ${rem}), total ${total})");
1023
1024                 if (${xbzrlecachesize}) {
1025                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
1026                 }
1027
1028                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
1029                     $downtimecounter++;
1030                 }
1031                 $lastrem = $rem;
1032
1033                 if ($downtimecounter > 5) {
1034                     $downtimecounter = 0;
1035                     $migrate_downtime *= 2;
1036                     $self->log('info', "auto-increased downtime to continue migration: $migrate_downtime ms");
1037                     eval {
1038                         # migrate-set-parameters does not touch values not
1039                         # specified, so this only changes downtime-limit
1040                         mon_cmd($vmid, "migrate-set-parameters", 'downtime-limit' => int($migrate_downtime));
1041                     };
1042                     $self->log('info', "migrate-set-parameters error: $@") if $@;
1043                 }
1044
1045             }
1046
1047
1048             $lstat = $stat->{ram}->{transferred};
1049
1050         } else {
1051             die $merr if $merr;
1052             die "unable to parse migration status '$stat->{status}' - aborting\n";
1053         }
1054     }
1055 }
1056
1057 sub phase2_cleanup {
1058     my ($self, $vmid, $err) = @_;
1059
1060     return if !$self->{errors};
1061     $self->{phase2errors} = 1;
1062
1063     $self->log('info', "aborting phase 2 - cleanup resources");
1064
1065     $self->log('info', "migrate_cancel");
1066     eval {
1067         mon_cmd($vmid, "migrate_cancel");
1068     };
1069     $self->log('info', "migrate_cancel error: $@") if $@;
1070
1071     my $conf = $self->{vmconf};
1072     delete $conf->{lock};
1073     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1074     if (my $err = $@) {
1075         $self->log('err', $err);
1076     }
1077
1078     # cleanup ressources on target host
1079     if ($self->{storage_migration}) {
1080         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1081         if (my $err = $@) {
1082             $self->log('err', $err);
1083         }
1084     }
1085
1086     eval { $self->cleanup_bitmaps() };
1087     if (my $err =$@) {
1088         $self->log('err', $err);
1089     }
1090
1091     my $nodename = PVE::INotify::nodename();
1092
1093     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1094     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1095     if (my $err = $@) {
1096         $self->log('err', $err);
1097         $self->{errors} = 1;
1098     }
1099
1100     # cleanup after stopping, otherwise disks might be in-use by target VM!
1101     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1102     if (my $err = $@) {
1103         $self->log('err', $err);
1104     }
1105
1106
1107     if ($self->{tunnel}) {
1108         eval { finish_tunnel($self, $self->{tunnel});  };
1109         if (my $err = $@) {
1110             $self->log('err', $err);
1111             $self->{errors} = 1;
1112         }
1113     }
1114 }
1115
1116 sub phase3 {
1117     my ($self, $vmid) = @_;
1118
1119     my $volids = $self->{volumes};
1120     return if $self->{phase2errors};
1121
1122     # destroy local copies
1123     foreach my $volid (@$volids) {
1124         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1125         if (my $err = $@) {
1126             $self->log('err', "removing local copy of '$volid' failed - $err");
1127             $self->{errors} = 1;
1128             last if $err =~ /^interrupted by signal$/;
1129         }
1130     }
1131 }
1132
1133 sub phase3_cleanup {
1134     my ($self, $vmid, $err) = @_;
1135
1136     my $conf = $self->{vmconf};
1137     return if $self->{phase2errors};
1138
1139     my $tunnel = $self->{tunnel};
1140
1141     if ($self->{storage_migration}) {
1142         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1143         # to avoid it trying to re-establish it. We are in blockjob ready state,
1144         # thus, this command changes to it to blockjob complete (see qapi docs)
1145         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1146
1147         if (my $err = $@) {
1148             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1149             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1150             die "Failed to complete storage migration: $err\n";
1151         }
1152     }
1153
1154     if ($self->{volume_map}) {
1155         my $target_drives = $self->{target_drive};
1156
1157         # FIXME: for NBD storage migration we now only update the volid, and
1158         # not the full drivestr from the target node. Workaround that until we
1159         # got some real rescan, to avoid things like wrong format in the drive
1160         delete $conf->{$_} for keys %$target_drives;
1161         PVE::QemuConfig->update_volume_ids($conf, $self->{volume_map});
1162
1163         for my $drive (keys %$target_drives) {
1164             $conf->{$drive} = $target_drives->{$drive}->{drivestr};
1165         }
1166         PVE::QemuConfig->write_config($vmid, $conf);
1167     }
1168
1169     # transfer replication state before move config
1170     $self->transfer_replication_state() if $self->{replicated_volumes};
1171
1172     # move config to remote node
1173     my $conffile = PVE::QemuConfig->config_file($vmid);
1174     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1175
1176     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1177         if !rename($conffile, $newconffile);
1178
1179     $self->switch_replication_job_target() if $self->{replicated_volumes};
1180
1181     if ($self->{livemigration}) {
1182         if ($self->{stopnbd}) {
1183             $self->log('info', "stopping NBD storage migration server on target.");
1184             # stop nbd server on remote vm - requirement for resume since 2.9
1185             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1186
1187             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1188             if (my $err = $@) {
1189                 $self->log('err', $err);
1190                 $self->{errors} = 1;
1191             }
1192         }
1193
1194         # config moved and nbd server stopped - now we can resume vm on target
1195         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1196             eval {
1197                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1198             };
1199             if (my $err = $@) {
1200                 $self->log('err', $err);
1201                 $self->{errors} = 1;
1202             }
1203         } else {
1204             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1205             my $logf = sub {
1206                 my $line = shift;
1207                 $self->log('err', $line);
1208             };
1209             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1210             if (my $err = $@) {
1211                 $self->log('err', $err);
1212                 $self->{errors} = 1;
1213             }
1214         }
1215
1216         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1217             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1218             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1219         }
1220     }
1221
1222     # close tunnel on successful migration, on error phase2_cleanup closed it
1223     if ($tunnel) {
1224         eval { finish_tunnel($self, $tunnel);  };
1225         if (my $err = $@) {
1226             $self->log('err', $err);
1227             $self->{errors} = 1;
1228         }
1229     }
1230
1231     eval {
1232         my $timer = 0;
1233         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1234             $self->log('info', "Waiting for spice server migration");
1235             while (1) {
1236                 my $res = mon_cmd($vmid, 'query-spice');
1237                 last if int($res->{'migrated'}) == 1;
1238                 last if $timer > 50;
1239                 $timer ++;
1240                 usleep(200000);
1241             }
1242         }
1243     };
1244
1245     # always stop local VM
1246     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1247     if (my $err = $@) {
1248         $self->log('err', "stopping vm failed - $err");
1249         $self->{errors} = 1;
1250     }
1251
1252     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1253     eval {
1254         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1255         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1256     };
1257     if (my $err = $@) {
1258         $self->log('err', $err);
1259         $self->{errors} = 1;
1260     }
1261
1262     if($self->{storage_migration}) {
1263         # destroy local copies
1264         my $volids = $self->{online_local_volumes};
1265
1266         foreach my $volid (@$volids) {
1267             # keep replicated volumes!
1268             next if $self->{replicated_volumes}->{$volid};
1269
1270             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1271             if (my $err = $@) {
1272                 $self->log('err', "removing local copy of '$volid' failed - $err");
1273                 $self->{errors} = 1;
1274                 last if $err =~ /^interrupted by signal$/;
1275             }
1276         }
1277
1278     }
1279
1280     # clear migrate lock
1281     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1282     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1283 }
1284
1285 sub final_cleanup {
1286     my ($self, $vmid) = @_;
1287
1288     # nothing to do
1289 }
1290
1291 sub round_powerof2 {
1292     return 1 if $_[0] < 2;
1293     return 2 << int(log($_[0]-1)/log(2));
1294 }
1295
1296 1;