PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16 use PVE::ReplicationConfig;
  17 use PVE::ReplicationState;
  18 use PVE::Replication;
  19
  20 use base qw(PVE::AbstractMigrate);
  21
  22 sub fork_command_pipe {
  23     my ($self, $cmd) = @_;
  24
  25     my $reader = IO::File->new();
  26     my $writer = IO::File->new();
  27
  28     my $orig_pid = $$;
  29
  30     my $cpid;
  31
  32     eval { $cpid = open2($reader, $writer, @$cmd); };
  33
  34     my $err = $@;
  35
  36     # catch exec errors
  37     if ($orig_pid != $$) {
  38         $self->log('err', "can't fork command pipe\n");
  39         POSIX::_exit(1);
  40         kill('KILL', $$);
  41     }
  42
  43     die $err if $err;
  44
  45     return { writer => $writer, reader => $reader, pid => $cpid };
  46 }
  47
  48 sub finish_command_pipe {
  49     my ($self, $cmdpipe, $timeout) = @_;
  50
  51     my $cpid = $cmdpipe->{pid};
  52     return if !defined($cpid);
  53
  54     my $writer = $cmdpipe->{writer};
  55     my $reader = $cmdpipe->{reader};
  56
  57     $writer->close();
  58     $reader->close();
  59
  60     my $collect_child_process = sub {
  61         my $res = waitpid($cpid, WNOHANG);
  62         if (defined($res) && ($res == $cpid)) {
  63             delete $cmdpipe->{cpid};
  64             return 1;
  65         } else {
  66             return 0;
  67         }
  68      };
  69
  70     if ($timeout) {
  71         for (my $i = 0; $i < $timeout; $i++) {
  72             return if &$collect_child_process();
  73             sleep(1);
  74         }
  75     }
  76
  77     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  78     kill(15, $cpid);
  79
  80     # wait again
  81     for (my $i = 0; $i < 10; $i++) {
  82         return if &$collect_child_process();
  83         sleep(1);
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  87     kill 9, $cpid;
  88     sleep 1;
  89
  90     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  91         if !&$collect_child_process();
  92 }
  93
  94 sub read_tunnel {
  95     my ($self, $tunnel, $timeout) = @_;
  96
  97     $timeout = 60 if !defined($timeout);
  98
  99     my $reader = $tunnel->{reader};
 100
 101     my $output;
 102     eval {
 103         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 104     };
 105     die "reading from tunnel failed: $@\n" if $@;
 106
 107     chomp $output;
 108
 109     return $output;
 110 }
 111
 112 sub write_tunnel {
 113     my ($self, $tunnel, $timeout, $command) = @_;
 114
 115     $timeout = 60 if !defined($timeout);
 116
 117     my $writer = $tunnel->{writer};
 118
 119     eval {
 120         PVE::Tools::run_with_timeout($timeout, sub {
 121             print $writer "$command\n";
 122             $writer->flush();
 123         });
 124     };
 125     die "writing to tunnel failed: $@\n" if $@;
 126
 127     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 128         my $res = eval { $self->read_tunnel($tunnel, 10); };
 129         die "no reply to command '$command': $@\n" if $@;
 130
 131         if ($res eq 'OK') {
 132             return;
 133         } else {
 134             die "tunnel replied '$res' to command '$command'\n";
 135         }
 136     }
 137 }
 138
 139 sub fork_tunnel {
 140     my ($self, $tunnel_addr) = @_;
 141
 142     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
 143
 144     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 145
 146     my $tunnel = $self->fork_command_pipe($cmd);
 147
 148     eval {
 149         my $helo = $self->read_tunnel($tunnel, 60);
 150         die "no reply\n" if !$helo;
 151         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 152         die "got strange reply from mtunnel ('$helo')\n"
 153             if $helo !~ m/^tunnel online$/;
 154     };
 155     my $err = $@;
 156
 157     eval {
 158         my $ver = $self->read_tunnel($tunnel, 10);
 159         if ($ver =~ /^ver (\d+)$/) {
 160             $tunnel->{version} = $1;
 161             $self->log('info', "ssh tunnel $ver\n");
 162         } else {
 163             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 164         }
 165     };
 166
 167     if ($err) {
 168         $self->finish_command_pipe($tunnel);
 169         die "can't open migration tunnel - $err";
 170     }
 171     return $tunnel;
 172 }
 173
 174 sub finish_tunnel {
 175     my ($self, $tunnel) = @_;
 176
 177     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 178     my $err = $@;
 179
 180     $self->finish_command_pipe($tunnel, 30);
 181
 182     if ($tunnel->{sock_addr}) {
 183         # ssh does not clean up on local host
 184         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 185         PVE::Tools::run_command($cmd);
 186
 187         # .. and just to be sure check on remote side
 188         unshift @{$cmd}, @{$self->{rem_ssh}};
 189         PVE::Tools::run_command($cmd);
 190     }
 191
 192     die $err if $err;
 193 }
 194
 195 sub lock_vm {
 196     my ($self, $vmid, $code, @param) = @_;
 197
 198     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 199 }
 200
 201 sub prepare {
 202     my ($self, $vmid) = @_;
 203
 204     my $online = $self->{opts}->{online};
 205
 206     $self->{storecfg} = PVE::Storage::config();
 207
 208     # test if VM exists
 209     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 210
 211     PVE::QemuConfig->check_lock($conf);
 212
 213     my $running = 0;
 214     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 215         die "can't migrate running VM without --online\n" if !$online;
 216         $running = $pid;
 217
 218         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 219
 220     }
 221
 222     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 223         if ($self->{running} || !$self->{opts}->{force}) {
 224             die "can't migrate VM which uses local devices\n";
 225         } else {
 226             $self->log('info', "migrating VM which uses local devices");
 227         }
 228     }
 229
 230     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 231
 232     my $need_activate = [];
 233     foreach my $volid (@$vollist) {
 234         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 235
 236         # check if storage is available on both nodes
 237         my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 238
 239         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 240         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 241
 242         if ($scfg->{shared}) {
 243             # PVE::Storage::activate_storage checks this for non-shared storages
 244             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 245             warn "Used shared storage '$sid' is not online on source node!\n"
 246                 if !$plugin->check_connection($sid, $scfg);
 247         } else {
 248             # only activate if not shared
 249             push @$need_activate, $volid;
 250         }
 251     }
 252
 253     # activate volumes
 254     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 255
 256     # test ssh connection
 257     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 258     eval { $self->cmd_quiet($cmd); };
 259     die "Can't connect to destination address using public key\n" if $@;
 260
 261     return $running;
 262 }
 263
 264 sub sync_disks {
 265     my ($self, $vmid) = @_;
 266
 267     my $conf = $self->{vmconf};
 268
 269     # local volumes which have been copied
 270     $self->{volumes} = [];
 271
 272     eval {
 273
 274         # found local volumes and their origin
 275         my $local_volumes = {};
 276         my $local_volumes_errors = {};
 277         my $other_errors = [];
 278         my $abort = 0;
 279
 280         my $sharedvm = 1;
 281
 282         my $log_error = sub {
 283             my ($msg, $volid) = @_;
 284
 285             if (defined($volid)) {
 286                 $local_volumes_errors->{$volid} = $msg;
 287             } else {
 288                 push @$other_errors, $msg;
 289             }
 290             $abort = 1;
 291         };
 292
 293         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 294         foreach my $storeid (@sids) {
 295             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 296             next if $scfg->{shared};
 297             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 298
 299             # get list from PVE::Storage (for unused volumes)
 300             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 301
 302             next if @{$dl->{$storeid}} == 0;
 303
 304             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $storeid;
 305
 306             # check if storage is available on target node
 307             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 308             $sharedvm = 0; # there is a non-shared disk
 309
 310             PVE::Storage::foreach_volid($dl, sub {
 311                 my ($volid, $sid, $volname) = @_;
 312
 313                 $local_volumes->{$volid}->{ref} = 'storage';
 314             });
 315         }
 316
 317         my $test_volid = sub {
 318             my ($volid, $attr) = @_;
 319
 320             if ($volid =~ m|^/|) {
 321                 $local_volumes->{$volid}->{ref} = 'config';
 322                 die "local file/device\n";
 323             }
 324
 325             my $snaprefs = $attr->{referenced_in_snapshot};
 326
 327             if ($attr->{cdrom}) {
 328                 if ($volid eq 'cdrom') {
 329                     my $msg = "can't migrate local cdrom drive";
 330                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 331                         my $snapnames = join(', ', sort keys %$snaprefs);
 332                         $msg .= " (referenced in snapshot - $snapnames)";
 333                     }
 334                     &$log_error("$msg\n");
 335                     return;
 336                 }
 337                 return if $volid eq 'none';
 338             }
 339
 340             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 341
 342             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 343             # check if storage is available on both nodes
 344             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 345             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 346
 347             return if $scfg->{shared};
 348
 349             $sharedvm = 0;
 350
 351             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 352
 353             die "local cdrom image\n" if $attr->{cdrom};
 354
 355             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 356
 357             die "owned by other VM (owner = VM $owner)\n"
 358                 if !$owner || ($owner != $self->{vmid});
 359
 360             my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 361             $local_volumes->{$volid}->{snapshots} = defined($snaprefs) || ($format =~ /^(?:qcow2|vmdk)$/);
 362             if (defined($snaprefs)) {
 363                 # we cannot migrate shapshots on local storage
 364                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 365
 366                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 367                 if (!($scfg->{type} eq 'zfspool' || $format eq 'qcow2')) {
 368                     die "non-migratable snapshot exists\n";
 369                 }
 370             }
 371
 372             die "referenced by linked clone(s)\n"
 373                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 374         };
 375
 376         PVE::QemuServer::foreach_volid($conf, sub {
 377             my ($volid, $attr) = @_;
 378             eval { $test_volid->($volid, $attr); };
 379             if (my $err = $@) {
 380                 &$log_error($err, $volid);
 381             }
 382         });
 383
 384         foreach my $vol (sort keys %$local_volumes) {
 385             my $ref = $local_volumes->{$vol}->{ref};
 386             if ($ref eq 'storage') {
 387                 $self->log('info', "found local disk '$vol' (via storage)\n");
 388             } elsif ($ref eq 'config') {
 389                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 390                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 391                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 392             } elsif ($ref eq 'snapshot') {
 393                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 394             } else {
 395                 $self->log('info', "found local disk '$vol'\n");
 396             }
 397         }
 398
 399         foreach my $vol (sort keys %$local_volumes_errors) {
 400             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 401         }
 402         foreach my $err (@$other_errors) {
 403             $self->log('warn', "$err");
 404         }
 405
 406         if ($self->{running} && !$sharedvm && !$self->{opts}->{targetstorage}) {
 407             $self->{opts}->{targetstorage} = 1; #use same sid for remote local
 408         }
 409
 410         if ($abort) {
 411             die "can't migrate VM - check log\n";
 412         }
 413
 414         # additional checks for local storage
 415         foreach my $volid (keys %$local_volumes) {
 416             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 417             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 418
 419             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 420                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 421
 422             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 423                 if !$migratable;
 424
 425             # image is a linked clone on local storage, se we can't migrate.
 426             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 427                 die "can't migrate '$volid' as it's a clone of '$basename'";
 428             }
 429         }
 430
 431         my $rep_volumes;
 432
 433         $self->log('info', "copying disk images");
 434
 435         my $rep_cfg = PVE::ReplicationConfig->new();
 436
 437         if (my $jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node})) {
 438             die "can't live migrate VM with replicated volumes\n" if $self->{running};
 439             my $start_time = time();
 440             my $logfunc = sub { my ($msg) = @_;  $self->log('info', $msg); };
 441             $rep_volumes = PVE::Replication::run_replication(
 442                'PVE::QemuConfig', $jobcfg, $start_time, $start_time, $logfunc);
 443             $self->{replicated_volumes} = $rep_volumes;
 444         }
 445
 446         foreach my $volid (keys %$local_volumes) {
 447             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 448             if ($self->{running} && $self->{opts}->{targetstorage} && $local_volumes->{$volid}->{ref} eq 'config') {
 449                 push @{$self->{online_local_volumes}}, $volid;
 450             } else {
 451                 next if $rep_volumes->{$volid};
 452                 push @{$self->{volumes}}, $volid;
 453                 my $insecure = $self->{opts}->{migration_type} eq 'insecure';
 454                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 455                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{ssh_info}, $sid,
 456                                               undef, undef, undef, undef, $insecure, $with_snapshots);
 457             }
 458         }
 459     };
 460     die "Failed to sync data - $@" if $@;
 461 }
 462
 463 sub cleanup_remotedisks {
 464     my ($self) = @_;
 465
 466     foreach my $target_drive (keys %{$self->{target_drive}}) {
 467
 468         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 469         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 470
 471         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 472
 473         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 474         if (my $err = $@) {
 475             $self->log('err', $err);
 476             $self->{errors} = 1;
 477         }
 478     }
 479 }
 480
 481 sub phase1 {
 482     my ($self, $vmid) = @_;
 483
 484     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 485
 486     my $conf = $self->{vmconf};
 487
 488     # set migrate lock in config file
 489     $conf->{lock} = 'migrate';
 490     PVE::QemuConfig->write_config($vmid, $conf);
 491
 492     sync_disks($self, $vmid);
 493
 494 };
 495
 496 sub phase1_cleanup {
 497     my ($self, $vmid, $err) = @_;
 498
 499     $self->log('info', "aborting phase 1 - cleanup resources");
 500
 501     my $conf = $self->{vmconf};
 502     delete $conf->{lock};
 503     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 504     if (my $err = $@) {
 505         $self->log('err', $err);
 506     }
 507
 508     if ($self->{volumes}) {
 509         foreach my $volid (@{$self->{volumes}}) {
 510             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 511             # fixme: try to remove ?
 512         }
 513     }
 514 }
 515
 516 sub phase2 {
 517     my ($self, $vmid) = @_;
 518
 519     my $conf = $self->{vmconf};
 520
 521     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 522
 523     my $raddr;
 524     my $rport;
 525     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 526     my $nodename = PVE::INotify::nodename();
 527
 528     ## start on remote node
 529     my $cmd = [@{$self->{rem_ssh}}];
 530
 531     my $spice_ticket;
 532     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 533         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 534         $spice_ticket = $res->{ticket};
 535     }
 536
 537     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 538
 539     my $migration_type = $self->{opts}->{migration_type};
 540
 541     push @$cmd, '--migration_type', $migration_type;
 542
 543     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 544       if $self->{opts}->{migration_network};
 545
 546     if ($migration_type eq 'insecure') {
 547         push @$cmd, '--stateuri', 'tcp';
 548     } else {
 549         push @$cmd, '--stateuri', 'unix';
 550     }
 551
 552     if ($self->{forcemachine}) {
 553         push @$cmd, '--machine', $self->{forcemachine};
 554     }
 555
 556     if ($self->{opts}->{targetstorage}) {
 557         push @$cmd, '--targetstorage', $self->{opts}->{targetstorage};
 558     }
 559
 560     my $spice_port;
 561
 562     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 563     # instead we pipe it through STDIN
 564     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 565         my $line = shift;
 566
 567         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 568             $raddr = $1;
 569             $rport = int($2);
 570             $ruri = "tcp:$raddr:$rport";
 571         }
 572         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 573             $raddr = $1;
 574             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 575             $ruri = "unix:$raddr";
 576         }
 577         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 578             $raddr = "localhost";
 579             $rport = int($1);
 580             $ruri = "tcp:$raddr:$rport";
 581         }
 582         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 583             $spice_port = int($1);
 584         }
 585         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 586             my $volid = $4;
 587             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 588             my $targetdrive = $3;
 589             $targetdrive =~ s/drive-//g;
 590
 591             $self->{target_drive}->{$targetdrive}->{volid} = $volid;
 592             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 593
 594         }
 595     }, errfunc => sub {
 596         my $line = shift;
 597         $self->log('info', $line);
 598     });
 599
 600     die "unable to detect remote migration address\n" if !$raddr;
 601
 602     $self->log('info', "start remote tunnel");
 603
 604     if ($migration_type eq 'secure') {
 605
 606         if ($ruri =~ /^unix:/) {
 607             unlink $raddr;
 608             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 609             $self->{tunnel}->{sock_addr} = $raddr;
 610
 611             my $unix_socket_try = 0; # wait for the socket to become ready
 612             while (! -S $raddr) {
 613                 $unix_socket_try++;
 614                 if ($unix_socket_try > 100) {
 615                     $self->{errors} = 1;
 616                     $self->finish_tunnel($self->{tunnel});
 617                     die "Timeout, migration socket $ruri did not get ready";
 618                 }
 619
 620                 usleep(50000);
 621             }
 622
 623         } elsif ($ruri =~ /^tcp:/) {
 624             my $tunnel_addr;
 625             if ($raddr eq "localhost") {
 626                 # for backwards compatibility with older qemu-server versions
 627                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 628                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 629                 $tunnel_addr = "$lport:localhost:$rport";
 630             }
 631
 632             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 633
 634         } else {
 635             die "unsupported protocol in migration URI: $ruri\n";
 636         }
 637     } else {
 638         #fork tunnel for insecure migration, to send faster commands like resume
 639         $self->{tunnel} = $self->fork_tunnel();
 640     }
 641
 642     my $start = time();
 643
 644     if ($self->{opts}->{targetstorage} && defined($self->{online_local_volumes})) {
 645         $self->{storage_migration} = 1;
 646         $self->{storage_migration_jobs} = {};
 647         $self->log('info', "starting storage migration");
 648
 649         die "The number of local disks does not match between the source and the destination.\n"
 650             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 651         foreach my $drive (keys %{$self->{target_drive}}){
 652             my $nbd_uri = $self->{target_drive}->{$drive}->{nbd_uri};
 653             $self->log('info', "$drive: start migration to to $nbd_uri");
 654             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 1);
 655         }
 656     }
 657
 658     $self->log('info', "starting online/live migration on $ruri");
 659     $self->{livemigration} = 1;
 660
 661     # load_defaults
 662     my $defaults = PVE::QemuServer::load_defaults();
 663
 664     # always set migrate speed (overwrite kvm default of 32m)
 665     # we set a very hight default of 8192m which is basically unlimited
 666     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 667     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 668     $migrate_speed = $migrate_speed * 1048576;
 669     $self->log('info', "migrate_set_speed: $migrate_speed");
 670     eval {
 671         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 672     };
 673     $self->log('info', "migrate_set_speed error: $@") if $@;
 674
 675     my $migrate_downtime = $defaults->{migrate_downtime};
 676     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 677     if (defined($migrate_downtime)) {
 678         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 679         eval {
 680             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 681         };
 682         $self->log('info', "migrate_set_downtime error: $@") if $@;
 683     }
 684
 685     $self->log('info', "set migration_caps");
 686     eval {
 687         PVE::QemuServer::set_migration_caps($vmid);
 688     };
 689     warn $@ if $@;
 690
 691     # set cachesize to 10% of the total memory
 692     my $memory =  $conf->{memory} || $defaults->{memory};
 693     my $cachesize = int($memory * 1048576 / 10);
 694     $self->log('info', "set cachesize: $cachesize");
 695     eval {
 696         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 697     };
 698     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 699
 700     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 701         my $rpcenv = PVE::RPCEnvironment::get();
 702         my $authuser = $rpcenv->get_user();
 703
 704         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 705
 706         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 707         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 708
 709         $self->log('info', "spice client_migrate_info");
 710
 711         eval {
 712             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 713                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 714                                                 'cert-subject' => $subject);
 715         };
 716         $self->log('info', "client_migrate_info error: $@") if $@;
 717
 718     }
 719
 720     $self->log('info', "start migrate command to $ruri");
 721     eval {
 722         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 723     };
 724     my $merr = $@;
 725     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 726
 727     my $lstat = 0;
 728     my $usleep = 1000000;
 729     my $i = 0;
 730     my $err_count = 0;
 731     my $lastrem = undef;
 732     my $downtimecounter = 0;
 733     while (1) {
 734         $i++;
 735         my $avglstat = $lstat/$i if $lstat;
 736
 737         usleep($usleep);
 738         my $stat;
 739         eval {
 740             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 741         };
 742         if (my $err = $@) {
 743             $err_count++;
 744             warn "query migrate failed: $err\n";
 745             $self->log('info', "query migrate failed: $err");
 746             if ($err_count <= 5) {
 747                 usleep(1000000);
 748                 next;
 749             }
 750             die "too many query migrate failures - aborting\n";
 751         }
 752
 753         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 754             sleep(1);
 755             next;
 756         }
 757
 758         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 759             $merr = undef;
 760             $err_count = 0;
 761             if ($stat->{status} eq 'completed') {
 762                 my $delay = time() - $start;
 763                 if ($delay > 0) {
 764                     my $mbps = sprintf "%.2f", $memory / $delay;
 765                     my $downtime = $stat->{downtime} || 0;
 766                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 767                 }
 768             }
 769
 770             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 771                 $self->log('info', "migration status error: $stat->{status}");
 772                 die "aborting\n"
 773             }
 774
 775             if ($stat->{status} ne 'active') {
 776                 $self->log('info', "migration status: $stat->{status}");
 777                 last;
 778             }
 779
 780             if ($stat->{ram}->{transferred} ne $lstat) {
 781                 my $trans = $stat->{ram}->{transferred} || 0;
 782                 my $rem = $stat->{ram}->{remaining} || 0;
 783                 my $total = $stat->{ram}->{total} || 0;
 784                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 785                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 786                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 787                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 788                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 789                 # reduce sleep if remainig memory is lower than the average transfer speed
 790                 $usleep = 100000 if $avglstat && $rem < $avglstat;
 791
 792                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 793                            "remaining ${rem}), total ${total})");
 794
 795                 if (${xbzrlecachesize}) {
 796                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 797                 }
 798
 799                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 800                     $downtimecounter++;
 801                 }
 802                 $lastrem = $rem;
 803
 804                 if ($downtimecounter > 5) {
 805                     $downtimecounter = 0;
 806                     $migrate_downtime *= 2;
 807                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 808                     eval {
 809                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 810                     };
 811                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 812                 }
 813
 814             }
 815
 816
 817             $lstat = $stat->{ram}->{transferred};
 818
 819         } else {
 820             die $merr if $merr;
 821             die "unable to parse migration status '$stat->{status}' - aborting\n";
 822         }
 823     }
 824 }
 825
 826 sub phase2_cleanup {
 827     my ($self, $vmid, $err) = @_;
 828
 829     return if !$self->{errors};
 830     $self->{phase2errors} = 1;
 831
 832     $self->log('info', "aborting phase 2 - cleanup resources");
 833
 834     $self->log('info', "migrate_cancel");
 835     eval {
 836         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 837     };
 838     $self->log('info', "migrate_cancel error: $@") if $@;
 839
 840     my $conf = $self->{vmconf};
 841     delete $conf->{lock};
 842     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 843     if (my $err = $@) {
 844         $self->log('err', $err);
 845     }
 846
 847     # cleanup ressources on target host
 848     if ($self->{storage_migration}) {
 849
 850         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 851         if (my $err = $@) {
 852             $self->log('err', $err);
 853         }
 854
 855         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 856         if (my $err = $@) {
 857             $self->log('err', $err);
 858         }
 859     }
 860
 861     my $nodename = PVE::INotify::nodename();
 862
 863     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 864     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 865     if (my $err = $@) {
 866         $self->log('err', $err);
 867         $self->{errors} = 1;
 868     }
 869
 870     if ($self->{tunnel}) {
 871         eval { finish_tunnel($self, $self->{tunnel});  };
 872         if (my $err = $@) {
 873             $self->log('err', $err);
 874             $self->{errors} = 1;
 875         }
 876     }
 877 }
 878
 879 sub phase3 {
 880     my ($self, $vmid) = @_;
 881
 882     my $volids = $self->{volumes};
 883     return if $self->{phase2errors};
 884
 885     # destroy local copies
 886     foreach my $volid (@$volids) {
 887         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 888         if (my $err = $@) {
 889             $self->log('err', "removing local copy of '$volid' failed - $err");
 890             $self->{errors} = 1;
 891             last if $err =~ /^interrupted by signal$/;
 892         }
 893     }
 894 }
 895
 896 sub phase3_cleanup {
 897     my ($self, $vmid, $err) = @_;
 898
 899     my $conf = $self->{vmconf};
 900     return if $self->{phase2errors};
 901
 902     my $tunnel = $self->{tunnel};
 903
 904     if ($self->{storage_migration}) {
 905         # finish block-job
 906         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}); };
 907
 908         if (my $err = $@) {
 909             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 910             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 911             die "Failed to completed storage migration\n";
 912         } else {
 913             foreach my $target_drive (keys %{$self->{target_drive}}) {
 914                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 915                 $conf->{$target_drive} = PVE::QemuServer::print_drive($vmid, $drive);
 916                 PVE::QemuConfig->write_config($vmid, $conf);
 917             }
 918         }
 919     }
 920
 921     # transfer replication state before move config
 922     $self->transfer_replication_state() if $self->{replicated_volumes};
 923
 924     # move config to remote node
 925     my $conffile = PVE::QemuConfig->config_file($vmid);
 926     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 927
 928     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 929         if !rename($conffile, $newconffile);
 930
 931     $self->switch_replication_job_target() if $self->{replicated_volumes};
 932
 933     if ($self->{livemigration}) {
 934         if ($self->{storage_migration}) {
 935             # stop nbd server on remote vm - requirement for resume since 2.9
 936             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
 937
 938             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 939             if (my $err = $@) {
 940                 $self->log('err', $err);
 941                 $self->{errors} = 1;
 942             }
 943         }
 944
 945         # config moved and nbd server stopped - now we can resume vm on target
 946         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
 947             eval {
 948                 $self->write_tunnel($tunnel, 30, "resume $vmid");
 949             };
 950             if (my $err = $@) {
 951                 $self->log('err', $err);
 952                 $self->{errors} = 1;
 953             }
 954         } else {
 955             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 956             my $logf = sub {
 957                 my $line = shift;
 958                 $self->log('err', $line);
 959             };
 960             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
 961             if (my $err = $@) {
 962                 $self->log('err', $err);
 963                 $self->{errors} = 1;
 964             }
 965         }
 966     }
 967
 968     # close tunnel on successful migration, on error phase2_cleanup closed it
 969     if ($tunnel) {
 970         eval { finish_tunnel($self, $tunnel);  };
 971         if (my $err = $@) {
 972             $self->log('err', $err);
 973             $self->{errors} = 1;
 974         }
 975     }
 976
 977     eval {
 978         my $timer = 0;
 979         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
 980             $self->log('info', "Waiting for spice server migration");
 981             while (1) {
 982                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
 983                 last if int($res->{'migrated'}) == 1;
 984                 last if $timer > 50;
 985                 $timer ++;
 986                 usleep(200000);
 987             }
 988         }
 989     };
 990
 991     # always stop local VM
 992     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 993     if (my $err = $@) {
 994         $self->log('err', "stopping vm failed - $err");
 995         $self->{errors} = 1;
 996     }
 997
 998     # always deactivate volumes - avoid lvm LVs to be active on several nodes
 999     eval {
1000         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1001         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1002     };
1003     if (my $err = $@) {
1004         $self->log('err', $err);
1005         $self->{errors} = 1;
1006     }
1007
1008     if($self->{storage_migration}) {
1009         # destroy local copies
1010         my $volids = $self->{online_local_volumes};
1011
1012         foreach my $volid (@$volids) {
1013             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1014             if (my $err = $@) {
1015                 $self->log('err', "removing local copy of '$volid' failed - $err");
1016                 $self->{errors} = 1;
1017                 last if $err =~ /^interrupted by signal$/;
1018             }
1019         }
1020
1021     }
1022
1023     # clear migrate lock
1024     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1025     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1026 }
1027
1028 sub final_cleanup {
1029     my ($self, $vmid) = @_;
1030
1031     # nothing to do
1032 }
1033
1034 1;