PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::INotify;
  13 use PVE::RPCEnvironment;
  14 use PVE::Replication;
  15 use PVE::ReplicationConfig;
  16 use PVE::ReplicationState;
  17 use PVE::Storage;
  18 use PVE::Tools;
  19
  20 use PVE::QemuConfig;
  21 use PVE::QemuServer::CPUConfig;
  22 use PVE::QemuServer::Drive;
  23 use PVE::QemuServer::Helpers qw(min_version);
  24 use PVE::QemuServer::Machine;
  25 use PVE::QemuServer::Monitor qw(mon_cmd);
  26 use PVE::QemuServer;
  27
  28 use PVE::AbstractMigrate;
  29 use base qw(PVE::AbstractMigrate);
  30
  31 sub fork_command_pipe {
  32     my ($self, $cmd) = @_;
  33
  34     my $reader = IO::File->new();
  35     my $writer = IO::File->new();
  36
  37     my $orig_pid = $$;
  38
  39     my $cpid;
  40
  41     eval { $cpid = open2($reader, $writer, @$cmd); };
  42
  43     my $err = $@;
  44
  45     # catch exec errors
  46     if ($orig_pid != $$) {
  47         $self->log('err', "can't fork command pipe\n");
  48         POSIX::_exit(1);
  49         kill('KILL', $$);
  50     }
  51
  52     die $err if $err;
  53
  54     return { writer => $writer, reader => $reader, pid => $cpid };
  55 }
  56
  57 sub finish_command_pipe {
  58     my ($self, $cmdpipe, $timeout) = @_;
  59
  60     my $cpid = $cmdpipe->{pid};
  61     return if !defined($cpid);
  62
  63     my $writer = $cmdpipe->{writer};
  64     my $reader = $cmdpipe->{reader};
  65
  66     $writer->close();
  67     $reader->close();
  68
  69     my $collect_child_process = sub {
  70         my $res = waitpid($cpid, WNOHANG);
  71         if (defined($res) && ($res == $cpid)) {
  72             delete $cmdpipe->{cpid};
  73             return 1;
  74         } else {
  75             return 0;
  76         }
  77      };
  78
  79     if ($timeout) {
  80         for (my $i = 0; $i < $timeout; $i++) {
  81             return if &$collect_child_process();
  82             sleep(1);
  83         }
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  87     kill(15, $cpid);
  88
  89     # wait again
  90     for (my $i = 0; $i < 10; $i++) {
  91         return if &$collect_child_process();
  92         sleep(1);
  93     }
  94
  95     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  96     kill 9, $cpid;
  97     sleep 1;
  98
  99     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
 100         if !&$collect_child_process();
 101 }
 102
 103 sub read_tunnel {
 104     my ($self, $tunnel, $timeout) = @_;
 105
 106     $timeout = 60 if !defined($timeout);
 107
 108     my $reader = $tunnel->{reader};
 109
 110     my $output;
 111     eval {
 112         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 113     };
 114     die "reading from tunnel failed: $@\n" if $@;
 115
 116     chomp $output;
 117
 118     return $output;
 119 }
 120
 121 sub write_tunnel {
 122     my ($self, $tunnel, $timeout, $command) = @_;
 123
 124     $timeout = 60 if !defined($timeout);
 125
 126     my $writer = $tunnel->{writer};
 127
 128     eval {
 129         PVE::Tools::run_with_timeout($timeout, sub {
 130             print $writer "$command\n";
 131             $writer->flush();
 132         });
 133     };
 134     die "writing to tunnel failed: $@\n" if $@;
 135
 136     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 137         my $res = eval { $self->read_tunnel($tunnel, 10); };
 138         die "no reply to command '$command': $@\n" if $@;
 139
 140         if ($res eq 'OK') {
 141             return;
 142         } else {
 143             die "tunnel replied '$res' to command '$command'\n";
 144         }
 145     }
 146 }
 147
 148 sub fork_tunnel {
 149     my ($self, $tunnel_addr) = @_;
 150
 151     my @localtunnelinfo = ();
 152     foreach my $addr (@$tunnel_addr) {
 153         push @localtunnelinfo, '-L', $addr;
 154     }
 155
 156     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 157
 158     my $tunnel = $self->fork_command_pipe($cmd);
 159
 160     eval {
 161         my $helo = $self->read_tunnel($tunnel, 60);
 162         die "no reply\n" if !$helo;
 163         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 164         die "got strange reply from mtunnel ('$helo')\n"
 165             if $helo !~ m/^tunnel online$/;
 166     };
 167     my $err = $@;
 168
 169     eval {
 170         my $ver = $self->read_tunnel($tunnel, 10);
 171         if ($ver =~ /^ver (\d+)$/) {
 172             $tunnel->{version} = $1;
 173             $self->log('info', "ssh tunnel $ver\n");
 174         } else {
 175             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 176         }
 177     };
 178
 179     if ($err) {
 180         $self->finish_command_pipe($tunnel);
 181         die "can't open migration tunnel - $err";
 182     }
 183     return $tunnel;
 184 }
 185
 186 sub finish_tunnel {
 187     my ($self, $tunnel) = @_;
 188
 189     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 190     my $err = $@;
 191
 192     $self->finish_command_pipe($tunnel, 30);
 193
 194     if ($tunnel->{sock_addr}) {
 195         # ssh does not clean up on local host
 196         my $cmd = ['rm', '-f', @{$tunnel->{sock_addr}}]; #
 197         PVE::Tools::run_command($cmd);
 198
 199         # .. and just to be sure check on remote side
 200         unshift @{$cmd}, @{$self->{rem_ssh}};
 201         PVE::Tools::run_command($cmd);
 202     }
 203
 204     die $err if $err;
 205 }
 206
 207 sub lock_vm {
 208     my ($self, $vmid, $code, @param) = @_;
 209
 210     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 211 }
 212
 213 sub prepare {
 214     my ($self, $vmid) = @_;
 215
 216     my $online = $self->{opts}->{online};
 217
 218     $self->{storecfg} = PVE::Storage::config();
 219
 220     # test if VM exists
 221     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 222
 223     PVE::QemuConfig->check_lock($conf);
 224
 225     my $running = 0;
 226     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 227         die "can't migrate running VM without --online\n" if !$online;
 228         $running = $pid;
 229
 230         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 231
 232         # To support custom CPU types, we keep QEMU's "-cpu" parameter intact.
 233         # Since the parameter itself contains no reference to a custom model,
 234         # this makes migration independent of changes to "cpu-models.conf".
 235         if ($conf->{cpu}) {
 236             my $cpuconf = PVE::QemuServer::CPUConfig::parse_cpu_conf_basic($conf->{cpu});
 237             if ($cpuconf && PVE::QemuServer::CPUConfig::is_custom_model($cpuconf->{cputype})) {
 238                 $self->{forcecpu} = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 239             }
 240         }
 241     }
 242
 243     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 244     if (scalar @$loc_res) {
 245         if ($self->{running} || !$self->{opts}->{force}) {
 246             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 247         } else {
 248             $self->log('info', "migrating VM which uses local devices");
 249         }
 250     }
 251
 252     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 253
 254     my $need_activate = [];
 255     foreach my $volid (@$vollist) {
 256         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 257
 258         # check if storage is available on both nodes
 259         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 260
 261         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 262         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 263
 264         if ($scfg->{shared}) {
 265             # PVE::Storage::activate_storage checks this for non-shared storages
 266             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 267             warn "Used shared storage '$sid' is not online on source node!\n"
 268                 if !$plugin->check_connection($sid, $scfg);
 269         } else {
 270             # only activate if not shared
 271             next if ($volid =~ m/vm-\d+-cloudinit/);
 272             push @$need_activate, $volid;
 273         }
 274     }
 275
 276     # activate volumes
 277     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 278
 279     # test ssh connection
 280     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 281     eval { $self->cmd_quiet($cmd); };
 282     die "Can't connect to destination address using public key\n" if $@;
 283
 284     return $running;
 285 }
 286
 287 sub sync_disks {
 288     my ($self, $vmid) = @_;
 289
 290     my $conf = $self->{vmconf};
 291
 292     # local volumes which have been copied
 293     # and their old_id => new_id pairs
 294     $self->{volumes} = [];
 295     $self->{volume_map} = {};
 296
 297     my $storecfg = $self->{storecfg};
 298     eval {
 299
 300         # found local volumes and their origin
 301         my $local_volumes = {};
 302         my $local_volumes_errors = {};
 303         my $other_errors = [];
 304         my $abort = 0;
 305
 306         my $log_error = sub {
 307             my ($msg, $volid) = @_;
 308
 309             if (defined($volid)) {
 310                 $local_volumes_errors->{$volid} = $msg;
 311             } else {
 312                 push @$other_errors, $msg;
 313             }
 314             $abort = 1;
 315         };
 316
 317         my @sids = PVE::Storage::storage_ids($storecfg);
 318         foreach my $storeid (@sids) {
 319             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 320             next if $scfg->{shared};
 321             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 322
 323             # get list from PVE::Storage (for unused volumes)
 324             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 325
 326             next if @{$dl->{$storeid}} == 0;
 327
 328             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $storeid);
 329             # check if storage is available on target node
 330             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 331
 332             # grandfather in existing mismatches
 333             if ($targetsid ne $storeid) {
 334                 my $target_scfg = PVE::Storage::storage_config($storecfg, $targetsid);
 335                 die "content type 'images' is not available on storage '$targetsid'\n"
 336                     if !$target_scfg->{content}->{images};
 337             }
 338
 339             PVE::Storage::foreach_volid($dl, sub {
 340                 my ($volid, $sid, $volinfo) = @_;
 341
 342                 $local_volumes->{$volid}->{ref} = 'storage';
 343
 344                 # If with_snapshots is not set for storage migrate, it tries to use
 345                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 346                 # back to qcow2 is currently not possible.
 347                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 348                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 349             });
 350         }
 351
 352         my $rep_cfg = PVE::ReplicationConfig->new();
 353         my $replication_jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node});
 354         my $replicatable_volumes = !$replication_jobcfg ? {}
 355             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 356
 357         my $test_volid = sub {
 358             my ($volid, $attr) = @_;
 359
 360             if ($volid =~ m|^/|) {
 361                 return if $attr->{shared};
 362                 $local_volumes->{$volid}->{ref} = 'config';
 363                 die "local file/device\n";
 364             }
 365
 366             my $snaprefs = $attr->{referenced_in_snapshot};
 367
 368             if ($attr->{cdrom}) {
 369                 if ($volid eq 'cdrom') {
 370                     my $msg = "can't migrate local cdrom drive";
 371                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 372                         my $snapnames = join(', ', sort keys %$snaprefs);
 373                         $msg .= " (referenced in snapshot - $snapnames)";
 374                     }
 375                     &$log_error("$msg\n");
 376                     return;
 377                 }
 378                 return if $volid eq 'none';
 379             }
 380
 381             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 382
 383             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 384             # check if storage is available on both nodes
 385             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 386             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 387
 388             return if $scfg->{shared};
 389
 390             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 391
 392             $local_volumes->{$volid}->{is_vmstate} = $attr->{is_vmstate} ? 1 : 0;
 393
 394             if ($attr->{cdrom}) {
 395                 if ($volid =~ /vm-\d+-cloudinit/) {
 396                     $local_volumes->{$volid}->{ref} = 'generated';
 397                     return;
 398                 }
 399                 die "local cdrom image\n";
 400             }
 401
 402             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 403
 404             die "owned by other VM (owner = VM $owner)\n"
 405                 if !$owner || ($owner != $vmid);
 406
 407             return if $attr->{is_vmstate};
 408
 409             if (defined($snaprefs)) {
 410                 $local_volumes->{$volid}->{snapshots} = 1;
 411
 412                 # we cannot migrate shapshots on local storage
 413                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 414
 415                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 416                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 417                     die "non-migratable snapshot exists\n";
 418                 }
 419             }
 420
 421             die "referenced by linked clone(s)\n"
 422                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 423         };
 424
 425         PVE::QemuServer::foreach_volid($conf, sub {
 426             my ($volid, $attr) = @_;
 427             eval { $test_volid->($volid, $attr); };
 428             if (my $err = $@) {
 429                 &$log_error($err, $volid);
 430             }
 431         });
 432
 433         foreach my $vol (sort keys %$local_volumes) {
 434             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 435             my $ref = $local_volumes->{$vol}->{ref};
 436             if ($ref eq 'storage') {
 437                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 438             } elsif ($ref eq 'config') {
 439                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 440                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 441                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 442             } elsif ($ref eq 'snapshot') {
 443                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 444             } elsif ($ref eq 'generated') {
 445                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 446             } else {
 447                 $self->log('info', "found $type disk '$vol'\n");
 448             }
 449         }
 450
 451         foreach my $vol (sort keys %$local_volumes_errors) {
 452             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 453         }
 454         foreach my $err (@$other_errors) {
 455             $self->log('warn', "$err");
 456         }
 457
 458         if ($abort) {
 459             die "can't migrate VM - check log\n";
 460         }
 461
 462         # additional checks for local storage
 463         foreach my $volid (keys %$local_volumes) {
 464             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 465             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 466
 467             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 468
 469             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 470                 if !$migratable;
 471
 472             # image is a linked clone on local storage, se we can't migrate.
 473             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 474                 die "can't migrate '$volid' as it's a clone of '$basename'";
 475             }
 476         }
 477
 478         if ($replication_jobcfg) {
 479             if ($self->{running}) {
 480
 481                 my $version = PVE::QemuServer::kvm_user_version();
 482                 if (!min_version($version, 4, 2)) {
 483                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 484                 }
 485
 486                 my $live_replicatable_volumes = {};
 487                 PVE::QemuConfig->foreach_volume($conf, sub {
 488                     my ($ds, $drive) = @_;
 489
 490                     my $volid = $drive->{file};
 491                     $live_replicatable_volumes->{$ds} = $volid
 492                         if defined($replicatable_volumes->{$volid});
 493                 });
 494                 foreach my $drive (keys %$live_replicatable_volumes) {
 495                     my $volid = $live_replicatable_volumes->{$drive};
 496
 497                     my $bitmap = "repl_$drive";
 498
 499                     # start tracking before replication to get full delta + a few duplicates
 500                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 501                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 502
 503                     # other info comes from target node in phase 2
 504                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 505                 }
 506             }
 507             $self->log('info', "replicating disk images");
 508
 509             my $start_time = time();
 510             my $logfunc = sub { $self->log('info', shift) };
 511             $self->{replicated_volumes} = PVE::Replication::run_replication(
 512                'PVE::QemuConfig', $replication_jobcfg, $start_time, $start_time, $logfunc);
 513         }
 514
 515         # sizes in config have to be accurate for remote node to correctly
 516         # allocate disks, rescan to be sure
 517         my $volid_hash = PVE::QemuServer::scan_volids($storecfg, $vmid);
 518         PVE::QemuConfig->foreach_volume($conf, sub {
 519             my ($key, $drive) = @_;
 520             my ($updated, $old_size, $new_size) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash);
 521             if (defined($updated)) {
 522                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 523                 $self->log('info', "size of disk '$updated->{file}' ($key) updated from $old_size to $new_size\n");
 524             }
 525         });
 526
 527         # we want to set the efidisk size in the config to the size of the
 528         # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 529         if (defined($conf->{efidisk0})) {
 530             PVE::QemuServer::update_efidisk_size($conf);
 531         }
 532
 533         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 534
 535         foreach my $volid (keys %$local_volumes) {
 536             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 537             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 538             my $ref = $local_volumes->{$volid}->{ref};
 539             if ($self->{running} && $ref eq 'config') {
 540                 push @{$self->{online_local_volumes}}, $volid;
 541             } elsif ($ref eq 'generated') {
 542                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 543                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 544                 push @{$self->{volumes}}, $volid;
 545                 next;
 546             } else {
 547                 next if $self->{replicated_volumes}->{$volid};
 548                 push @{$self->{volumes}}, $volid;
 549                 my $opts = $self->{opts};
 550                 # use 'migrate' limit for transfer to other node
 551                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 552                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 553                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 554
 555                 my $storage_migrate_opts = {
 556                     'bwlimit' => $bwlimit,
 557                     'insecure' => $opts->{migration_type} eq 'insecure',
 558                     'with_snapshots' => $local_volumes->{$volid}->{snapshots},
 559                     'allow_rename' => !$local_volumes->{$volid}->{is_vmstate},
 560                 };
 561
 562                 my $logfunc = sub { $self->log('info', $_[0]); };
 563                 my $new_volid = eval {
 564                     PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info},
 565                                                   $targetsid, $storage_migrate_opts, $logfunc);
 566                 };
 567                 if (my $err = $@) {
 568                     die "storage migration for '$volid' to storage '$targetsid' failed - $err\n";
 569                 }
 570
 571                 $self->{volume_map}->{$volid} = $new_volid;
 572                 $self->log('info', "volume '$volid' is '$new_volid' on the target\n");
 573             }
 574         }
 575     };
 576     die "Failed to sync data - $@" if $@;
 577 }
 578
 579 sub cleanup_remotedisks {
 580     my ($self) = @_;
 581
 582     foreach my $target_drive (keys %{$self->{target_drive}}) {
 583         my $drivestr = $self->{target_drive}->{$target_drive}->{drivestr};
 584         next if !defined($drivestr);
 585
 586         my $drive = PVE::QemuServer::parse_drive($target_drive, $drivestr);
 587
 588         # don't clean up replicated disks!
 589         next if defined($self->{replicated_volumes}->{$drive->{file}});
 590
 591         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 592
 593         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 594
 595         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 596         if (my $err = $@) {
 597             $self->log('err', $err);
 598             $self->{errors} = 1;
 599         }
 600     }
 601 }
 602
 603 sub cleanup_bitmaps {
 604     my ($self) = @_;
 605     foreach my $drive (keys %{$self->{target_drive}}) {
 606         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 607         next if !$bitmap;
 608         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 609         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 610     }
 611 }
 612
 613 sub phase1 {
 614     my ($self, $vmid) = @_;
 615
 616     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 617
 618     my $conf = $self->{vmconf};
 619
 620     # set migrate lock in config file
 621     $conf->{lock} = 'migrate';
 622     PVE::QemuConfig->write_config($vmid, $conf);
 623
 624     sync_disks($self, $vmid);
 625
 626     # sync_disks fixes disk sizes to match their actual size, write changes so
 627     # target allocates correct volumes
 628     PVE::QemuConfig->write_config($vmid, $conf);
 629 };
 630
 631 sub phase1_cleanup {
 632     my ($self, $vmid, $err) = @_;
 633
 634     $self->log('info', "aborting phase 1 - cleanup resources");
 635
 636     my $conf = $self->{vmconf};
 637     delete $conf->{lock};
 638     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 639     if (my $err = $@) {
 640         $self->log('err', $err);
 641     }
 642
 643     if ($self->{volumes}) {
 644         foreach my $volid (@{$self->{volumes}}) {
 645             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 646             # fixme: try to remove ?
 647         }
 648     }
 649
 650     eval { $self->cleanup_bitmaps() };
 651     if (my $err =$@) {
 652         $self->log('err', $err);
 653     }
 654
 655 }
 656
 657 sub phase2 {
 658     my ($self, $vmid) = @_;
 659
 660     my $conf = $self->{vmconf};
 661
 662     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 663
 664     my $raddr;
 665     my $rport;
 666     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 667     my $nodename = PVE::INotify::nodename();
 668
 669     ## start on remote node
 670     my $cmd = [@{$self->{rem_ssh}}];
 671
 672     my $spice_ticket;
 673     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 674         my $res = mon_cmd($vmid, 'query-spice');
 675         $spice_ticket = $res->{ticket};
 676     }
 677
 678     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 679
 680     my $migration_type = $self->{opts}->{migration_type};
 681
 682     push @$cmd, '--migration_type', $migration_type;
 683
 684     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 685       if $self->{opts}->{migration_network};
 686
 687     if ($migration_type eq 'insecure') {
 688         push @$cmd, '--stateuri', 'tcp';
 689     } else {
 690         push @$cmd, '--stateuri', 'unix';
 691     }
 692
 693     if ($self->{forcemachine}) {
 694         push @$cmd, '--machine', $self->{forcemachine};
 695     }
 696
 697     if ($self->{forcecpu}) {
 698         push @$cmd, '--force-cpu', $self->{forcecpu};
 699     }
 700
 701     if ($self->{online_local_volumes}) {
 702         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 703     }
 704
 705     my $spice_port;
 706     my $tunnel_addr = [];
 707     my $sock_addr = [];
 708     # version > 0 for unix socket support
 709     my $nbd_protocol_version = 1;
 710     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 711     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 712     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 713
 714     my $number_of_online_replicated_volumes = 0;
 715     foreach my $volid (@{$self->{online_local_volumes}}) {
 716         next if !$self->{replicated_volumes}->{$volid};
 717         $number_of_online_replicated_volumes++;
 718         $input .= "replicated_volume: $volid\n";
 719     }
 720
 721     my $target_replicated_volumes = {};
 722
 723     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 724     # instead we pipe it through STDIN
 725     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 726         my $line = shift;
 727
 728         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 729             $raddr = $1;
 730             $rport = int($2);
 731             $ruri = "tcp:$raddr:$rport";
 732         }
 733         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 734             $raddr = $1;
 735             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 736             $ruri = "unix:$raddr";
 737         }
 738         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 739             $raddr = "localhost";
 740             $rport = int($1);
 741             $ruri = "tcp:$raddr:$rport";
 742         }
 743         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 744             $spice_port = int($1);
 745         }
 746         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 747             my $drivestr = $4;
 748             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 749             my $targetdrive = $3;
 750             $targetdrive =~ s/drive-//g;
 751
 752             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 753             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 754         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 755             my $drivestr = $4;
 756             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 757             my $nbd_unix_addr = $1;
 758             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 759             my $targetdrive = $3;
 760             $targetdrive =~ s/drive-//g;
 761
 762             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 763             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 764             push @$tunnel_addr, "$nbd_unix_addr:$nbd_unix_addr";
 765             push @$sock_addr, $nbd_unix_addr;
 766         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 767             my $drive = $1;
 768             my $volid = $2;
 769             $target_replicated_volumes->{$volid} = $drive;
 770         } elsif ($line =~ m/^QEMU: (.*)$/) {
 771             $self->log('info', "[$self->{node}] $1\n");
 772         }
 773     }, errfunc => sub {
 774         my $line = shift;
 775         $self->log('info', "[$self->{node}] $line");
 776     }, noerr => 1);
 777
 778     die "remote command failed with exit code $exitcode\n" if $exitcode;
 779
 780     die "unable to detect remote migration address\n" if !$raddr;
 781
 782     if (scalar(keys %$target_replicated_volumes) != $number_of_online_replicated_volumes) {
 783         die "number of replicated disks on source and target node do not match - target node too old?\n"
 784     }
 785
 786     $self->log('info', "start remote tunnel");
 787
 788     if ($migration_type eq 'secure') {
 789
 790         if ($ruri =~ /^unix:/) {
 791             unlink $raddr;
 792             push @$tunnel_addr, "$raddr:$raddr";
 793             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 794             push @$sock_addr, $raddr;
 795
 796             my $unix_socket_try = 0; # wait for the socket to become ready
 797             while ($unix_socket_try <= 100) {
 798                 $unix_socket_try++;
 799                 my $available = 0;
 800                 foreach my $sock (@$sock_addr) {
 801                     if (-S $sock) {
 802                         $available++;
 803                     }
 804                 }
 805
 806                 if ($available == @$sock_addr) {
 807                     last;
 808                 }
 809
 810                 usleep(50000);
 811             }
 812             if ($unix_socket_try > 100) {
 813                 $self->{errors} = 1;
 814                 $self->finish_tunnel($self->{tunnel});
 815                 die "Timeout, migration socket $ruri did not get ready";
 816             }
 817
 818         } elsif ($ruri =~ /^tcp:/) {
 819             my $tunnel_addr;
 820             if ($raddr eq "localhost") {
 821                 # for backwards compatibility with older qemu-server versions
 822                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 823                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 824                 $tunnel_addr = "$lport:localhost:$rport";
 825             }
 826
 827             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 828
 829         } else {
 830             die "unsupported protocol in migration URI: $ruri\n";
 831         }
 832     } else {
 833         #fork tunnel for insecure migration, to send faster commands like resume
 834         $self->{tunnel} = $self->fork_tunnel();
 835     }
 836     $self->{tunnel}->{sock_addr} = $sock_addr if (@$sock_addr);
 837
 838     my $start = time();
 839
 840     my $opt_bwlimit = $self->{opts}->{bwlimit};
 841
 842     if (defined($self->{online_local_volumes})) {
 843         $self->{storage_migration} = 1;
 844         $self->{storage_migration_jobs} = {};
 845         $self->log('info', "starting storage migration");
 846
 847         die "The number of local disks does not match between the source and the destination.\n"
 848             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 849         foreach my $drive (keys %{$self->{target_drive}}){
 850             my $target = $self->{target_drive}->{$drive};
 851             my $nbd_uri = $target->{nbd_uri};
 852
 853             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 854             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 855
 856             my $source_volid = $source_drive->{file};
 857             my $target_volid = $target_drive->{file};
 858
 859             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_volid);
 860             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_volid);
 861
 862             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 863             my $bitmap = $target->{bitmap};
 864
 865             $self->log('info', "$drive: start migration to $nbd_uri");
 866             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 867
 868             $self->{volume_map}->{$source_volid} = $target_volid;
 869             $self->log('info', "volume '$source_volid' is '$target_volid' on the target\n");
 870         }
 871     }
 872
 873     $self->log('info', "starting online/live migration on $ruri");
 874     $self->{livemigration} = 1;
 875
 876     # load_defaults
 877     my $defaults = PVE::QemuServer::load_defaults();
 878
 879     $self->log('info', "set migration_caps");
 880     eval {
 881         PVE::QemuServer::set_migration_caps($vmid);
 882     };
 883     warn $@ if $@;
 884
 885     my $qemu_migrate_params = {};
 886
 887     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 888     # migrate_speed parameter in qm.conf - take the lower of the two.
 889     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 890     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 891     # migrate_speed is in MB/s, bwlimit in KB/s
 892     $migrate_speed *= 1024;
 893
 894     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 895
 896     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 897     # default of 8192m which is basically unlimited
 898     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 899
 900     # qmp takes migrate_speed in B/s.
 901     $migrate_speed *= 1024;
 902     $self->log('info', "migration speed limit: $migrate_speed B/s");
 903     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 904
 905     my $migrate_downtime = $defaults->{migrate_downtime};
 906     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 907     # migrate-set-parameters expects limit in ms
 908     $migrate_downtime *= 1000;
 909     $self->log('info', "migration downtime limit: $migrate_downtime ms");
 910     $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 911
 912     # set cachesize to 10% of the total memory
 913     my $memory =  $conf->{memory} || $defaults->{memory};
 914     my $cachesize = int($memory * 1048576 / 10);
 915     $cachesize = round_powerof2($cachesize);
 916
 917     $self->log('info', "migration cachesize: $cachesize B");
 918     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 919
 920     $self->log('info', "set migration parameters");
 921     eval {
 922         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 923     };
 924     $self->log('info', "migrate-set-parameters error: $@") if $@;
 925
 926     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 927         my $rpcenv = PVE::RPCEnvironment::get();
 928         my $authuser = $rpcenv->get_user();
 929
 930         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 931
 932         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 933         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 934
 935         $self->log('info', "spice client_migrate_info");
 936
 937         eval {
 938             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 939                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 940                                                 'cert-subject' => $subject);
 941         };
 942         $self->log('info', "client_migrate_info error: $@") if $@;
 943
 944     }
 945
 946     $self->log('info', "start migrate command to $ruri");
 947     eval {
 948         mon_cmd($vmid, "migrate", uri => $ruri);
 949     };
 950     my $merr = $@;
 951     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 952
 953     my $lstat = 0;
 954     my $usleep = 1000000;
 955     my $i = 0;
 956     my $err_count = 0;
 957     my $lastrem = undef;
 958     my $downtimecounter = 0;
 959     while (1) {
 960         $i++;
 961         my $avglstat = $lstat/$i if $lstat;
 962
 963         usleep($usleep);
 964         my $stat;
 965         eval {
 966             $stat = mon_cmd($vmid, "query-migrate");
 967         };
 968         if (my $err = $@) {
 969             $err_count++;
 970             warn "query migrate failed: $err\n";
 971             $self->log('info', "query migrate failed: $err");
 972             if ($err_count <= 5) {
 973                 usleep(1000000);
 974                 next;
 975             }
 976             die "too many query migrate failures - aborting\n";
 977         }
 978
 979         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 980             sleep(1);
 981             next;
 982         }
 983
 984         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 985             $merr = undef;
 986             $err_count = 0;
 987             if ($stat->{status} eq 'completed') {
 988                 my $delay = time() - $start;
 989                 if ($delay > 0) {
 990                     my $mbps = sprintf "%.2f", $memory / $delay;
 991                     my $downtime = $stat->{downtime} || 0;
 992                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 993                 }
 994             }
 995
 996             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 997                 $self->log('info', "migration status error: $stat->{status}");
 998                 die "aborting\n"
 999             }
1000
1001             if ($stat->{status} ne 'active') {
1002                 $self->log('info', "migration status: $stat->{status}");
1003                 last;
1004             }
1005
1006             if ($stat->{ram}->{transferred} ne $lstat) {
1007                 my $trans = $stat->{ram}->{transferred} || 0;
1008                 my $rem = $stat->{ram}->{remaining} || 0;
1009                 my $total = $stat->{ram}->{total} || 0;
1010                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
1011                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
1012                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
1013                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
1014                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
1015                 # reduce sleep if remainig memory is lower than the average transfer speed
1016                 $usleep = 100000 if $avglstat && $rem < $avglstat;
1017
1018                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
1019                            "remaining ${rem}), total ${total})");
1020
1021                 if (${xbzrlecachesize}) {
1022                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
1023                 }
1024
1025                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
1026                     $downtimecounter++;
1027                 }
1028                 $lastrem = $rem;
1029
1030                 if ($downtimecounter > 5) {
1031                     $downtimecounter = 0;
1032                     $migrate_downtime *= 2;
1033                     $self->log('info', "auto-increased downtime to continue migration: $migrate_downtime ms");
1034                     eval {
1035                         # migrate-set-parameters does not touch values not
1036                         # specified, so this only changes downtime-limit
1037                         mon_cmd($vmid, "migrate-set-parameters", 'downtime-limit' => int($migrate_downtime));
1038                     };
1039                     $self->log('info', "migrate-set-parameters error: $@") if $@;
1040                 }
1041
1042             }
1043
1044
1045             $lstat = $stat->{ram}->{transferred};
1046
1047         } else {
1048             die $merr if $merr;
1049             die "unable to parse migration status '$stat->{status}' - aborting\n";
1050         }
1051     }
1052 }
1053
1054 sub phase2_cleanup {
1055     my ($self, $vmid, $err) = @_;
1056
1057     return if !$self->{errors};
1058     $self->{phase2errors} = 1;
1059
1060     $self->log('info', "aborting phase 2 - cleanup resources");
1061
1062     $self->log('info', "migrate_cancel");
1063     eval {
1064         mon_cmd($vmid, "migrate_cancel");
1065     };
1066     $self->log('info', "migrate_cancel error: $@") if $@;
1067
1068     my $conf = $self->{vmconf};
1069     delete $conf->{lock};
1070     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1071     if (my $err = $@) {
1072         $self->log('err', $err);
1073     }
1074
1075     # cleanup ressources on target host
1076     if ($self->{storage_migration}) {
1077         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1078         if (my $err = $@) {
1079             $self->log('err', $err);
1080         }
1081     }
1082
1083     eval { $self->cleanup_bitmaps() };
1084     if (my $err =$@) {
1085         $self->log('err', $err);
1086     }
1087
1088     my $nodename = PVE::INotify::nodename();
1089
1090     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1091     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1092     if (my $err = $@) {
1093         $self->log('err', $err);
1094         $self->{errors} = 1;
1095     }
1096
1097     # cleanup after stopping, otherwise disks might be in-use by target VM!
1098     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1099     if (my $err = $@) {
1100         $self->log('err', $err);
1101     }
1102
1103
1104     if ($self->{tunnel}) {
1105         eval { finish_tunnel($self, $self->{tunnel});  };
1106         if (my $err = $@) {
1107             $self->log('err', $err);
1108             $self->{errors} = 1;
1109         }
1110     }
1111 }
1112
1113 sub phase3 {
1114     my ($self, $vmid) = @_;
1115
1116     my $volids = $self->{volumes};
1117     return if $self->{phase2errors};
1118
1119     # destroy local copies
1120     foreach my $volid (@$volids) {
1121         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1122         if (my $err = $@) {
1123             $self->log('err', "removing local copy of '$volid' failed - $err");
1124             $self->{errors} = 1;
1125             last if $err =~ /^interrupted by signal$/;
1126         }
1127     }
1128 }
1129
1130 sub phase3_cleanup {
1131     my ($self, $vmid, $err) = @_;
1132
1133     my $conf = $self->{vmconf};
1134     return if $self->{phase2errors};
1135
1136     my $tunnel = $self->{tunnel};
1137
1138     if ($self->{storage_migration}) {
1139         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1140         # to avoid it trying to re-establish it. We are in blockjob ready state,
1141         # thus, this command changes to it to blockjob complete (see qapi docs)
1142         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1143
1144         if (my $err = $@) {
1145             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1146             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1147             die "Failed to complete storage migration: $err\n";
1148         }
1149     }
1150
1151     if ($self->{volume_map}) {
1152         my $target_drives = $self->{target_drive};
1153
1154         # FIXME: for NBD storage migration we now only update the volid, and
1155         # not the full drivestr from the target node. Workaround that until we
1156         # got some real rescan, to avoid things like wrong format in the drive
1157         delete $conf->{$_} for keys %$target_drives;
1158         PVE::QemuConfig->update_volume_ids($conf, $self->{volume_map});
1159
1160         for my $drive (keys %$target_drives) {
1161             $conf->{$drive} = $target_drives->{$drive}->{drivestr};
1162         }
1163         PVE::QemuConfig->write_config($vmid, $conf);
1164     }
1165
1166     # transfer replication state before move config
1167     $self->transfer_replication_state() if $self->{replicated_volumes};
1168
1169     # move config to remote node
1170     my $conffile = PVE::QemuConfig->config_file($vmid);
1171     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1172
1173     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1174         if !rename($conffile, $newconffile);
1175
1176     $self->switch_replication_job_target() if $self->{replicated_volumes};
1177
1178     if ($self->{livemigration}) {
1179         if ($self->{storage_migration}) {
1180             # stop nbd server on remote vm - requirement for resume since 2.9
1181             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1182
1183             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1184             if (my $err = $@) {
1185                 $self->log('err', $err);
1186                 $self->{errors} = 1;
1187             }
1188         }
1189
1190         # config moved and nbd server stopped - now we can resume vm on target
1191         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1192             eval {
1193                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1194             };
1195             if (my $err = $@) {
1196                 $self->log('err', $err);
1197                 $self->{errors} = 1;
1198             }
1199         } else {
1200             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1201             my $logf = sub {
1202                 my $line = shift;
1203                 $self->log('err', $line);
1204             };
1205             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1206             if (my $err = $@) {
1207                 $self->log('err', $err);
1208                 $self->{errors} = 1;
1209             }
1210         }
1211
1212         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1213             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1214             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1215         }
1216     }
1217
1218     # close tunnel on successful migration, on error phase2_cleanup closed it
1219     if ($tunnel) {
1220         eval { finish_tunnel($self, $tunnel);  };
1221         if (my $err = $@) {
1222             $self->log('err', $err);
1223             $self->{errors} = 1;
1224         }
1225     }
1226
1227     eval {
1228         my $timer = 0;
1229         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1230             $self->log('info', "Waiting for spice server migration");
1231             while (1) {
1232                 my $res = mon_cmd($vmid, 'query-spice');
1233                 last if int($res->{'migrated'}) == 1;
1234                 last if $timer > 50;
1235                 $timer ++;
1236                 usleep(200000);
1237             }
1238         }
1239     };
1240
1241     # always stop local VM
1242     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1243     if (my $err = $@) {
1244         $self->log('err', "stopping vm failed - $err");
1245         $self->{errors} = 1;
1246     }
1247
1248     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1249     eval {
1250         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1251         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1252     };
1253     if (my $err = $@) {
1254         $self->log('err', $err);
1255         $self->{errors} = 1;
1256     }
1257
1258     if($self->{storage_migration}) {
1259         # destroy local copies
1260         my $volids = $self->{online_local_volumes};
1261
1262         foreach my $volid (@$volids) {
1263             # keep replicated volumes!
1264             next if $self->{replicated_volumes}->{$volid};
1265
1266             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1267             if (my $err = $@) {
1268                 $self->log('err', "removing local copy of '$volid' failed - $err");
1269                 $self->{errors} = 1;
1270                 last if $err =~ /^interrupted by signal$/;
1271             }
1272         }
1273
1274     }
1275
1276     # clear migrate lock
1277     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1278     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1279 }
1280
1281 sub final_cleanup {
1282     my ($self, $vmid) = @_;
1283
1284     # nothing to do
1285 }
1286
1287 sub round_powerof2 {
1288     return 1 if $_[0] < 2;
1289     return 2 << int(log($_[0]-1)/log(2));
1290 }
1291
1292 1;