PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::GuestHelpers qw(safe_string_ne);
  13 use PVE::INotify;
  14 use PVE::RPCEnvironment;
  15 use PVE::Replication;
  16 use PVE::ReplicationConfig;
  17 use PVE::ReplicationState;
  18 use PVE::Storage;
  19 use PVE::Tools;
  20
  21 use PVE::QemuConfig;
  22 use PVE::QemuServer::CPUConfig;
  23 use PVE::QemuServer::Drive;
  24 use PVE::QemuServer::Helpers qw(min_version);
  25 use PVE::QemuServer::Machine;
  26 use PVE::QemuServer::Monitor qw(mon_cmd);
  27 use PVE::QemuServer;
  28
  29 use PVE::AbstractMigrate;
  30 use base qw(PVE::AbstractMigrate);
  31
  32 sub fork_command_pipe {
  33     my ($self, $cmd) = @_;
  34
  35     my $reader = IO::File->new();
  36     my $writer = IO::File->new();
  37
  38     my $orig_pid = $$;
  39
  40     my $cpid;
  41
  42     eval { $cpid = open2($reader, $writer, @$cmd); };
  43
  44     my $err = $@;
  45
  46     # catch exec errors
  47     if ($orig_pid != $$) {
  48         $self->log('err', "can't fork command pipe\n");
  49         POSIX::_exit(1);
  50         kill('KILL', $$);
  51     }
  52
  53     die $err if $err;
  54
  55     return { writer => $writer, reader => $reader, pid => $cpid };
  56 }
  57
  58 sub finish_command_pipe {
  59     my ($self, $cmdpipe, $timeout) = @_;
  60
  61     my $cpid = $cmdpipe->{pid};
  62     return if !defined($cpid);
  63
  64     my $writer = $cmdpipe->{writer};
  65     my $reader = $cmdpipe->{reader};
  66
  67     $writer->close();
  68     $reader->close();
  69
  70     my $collect_child_process = sub {
  71         my $res = waitpid($cpid, WNOHANG);
  72         if (defined($res) && ($res == $cpid)) {
  73             delete $cmdpipe->{cpid};
  74             return 1;
  75         } else {
  76             return 0;
  77         }
  78      };
  79
  80     if ($timeout) {
  81         for (my $i = 0; $i < $timeout; $i++) {
  82             return if &$collect_child_process();
  83             sleep(1);
  84         }
  85     }
  86
  87     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  88     kill(15, $cpid);
  89
  90     # wait again
  91     for (my $i = 0; $i < 10; $i++) {
  92         return if &$collect_child_process();
  93         sleep(1);
  94     }
  95
  96     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  97     kill 9, $cpid;
  98     sleep 1;
  99
 100     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
 101         if !&$collect_child_process();
 102 }
 103
 104 sub read_tunnel {
 105     my ($self, $tunnel, $timeout) = @_;
 106
 107     $timeout = 60 if !defined($timeout);
 108
 109     my $reader = $tunnel->{reader};
 110
 111     my $output;
 112     eval {
 113         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 114     };
 115     die "reading from tunnel failed: $@\n" if $@;
 116
 117     chomp $output;
 118
 119     return $output;
 120 }
 121
 122 sub write_tunnel {
 123     my ($self, $tunnel, $timeout, $command) = @_;
 124
 125     $timeout = 60 if !defined($timeout);
 126
 127     my $writer = $tunnel->{writer};
 128
 129     eval {
 130         PVE::Tools::run_with_timeout($timeout, sub {
 131             print $writer "$command\n";
 132             $writer->flush();
 133         });
 134     };
 135     die "writing to tunnel failed: $@\n" if $@;
 136
 137     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 138         my $res = eval { $self->read_tunnel($tunnel, 10); };
 139         die "no reply to command '$command': $@\n" if $@;
 140
 141         if ($res eq 'OK') {
 142             return;
 143         } else {
 144             die "tunnel replied '$res' to command '$command'\n";
 145         }
 146     }
 147 }
 148
 149 sub fork_tunnel {
 150     my ($self, $ssh_forward_info) = @_;
 151
 152     my @localtunnelinfo = ();
 153     foreach my $addr (@$ssh_forward_info) {
 154         push @localtunnelinfo, '-L', $addr;
 155     }
 156
 157     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 158
 159     my $tunnel = $self->fork_command_pipe($cmd);
 160
 161     eval {
 162         my $helo = $self->read_tunnel($tunnel, 60);
 163         die "no reply\n" if !$helo;
 164         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 165         die "got strange reply from mtunnel ('$helo')\n"
 166             if $helo !~ m/^tunnel online$/;
 167     };
 168     my $err = $@;
 169
 170     eval {
 171         my $ver = $self->read_tunnel($tunnel, 10);
 172         if ($ver =~ /^ver (\d+)$/) {
 173             $tunnel->{version} = $1;
 174             $self->log('info', "ssh tunnel $ver\n");
 175         } else {
 176             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 177         }
 178     };
 179
 180     if ($err) {
 181         $self->finish_command_pipe($tunnel);
 182         die "can't open migration tunnel - $err";
 183     }
 184     return $tunnel;
 185 }
 186
 187 sub finish_tunnel {
 188     my ($self, $tunnel) = @_;
 189
 190     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 191     my $err = $@;
 192
 193     $self->finish_command_pipe($tunnel, 30);
 194
 195     if (my $unix_sockets = $tunnel->{unix_sockets}) {
 196         # ssh does not clean up on local host
 197         my $cmd = ['rm', '-f', @$unix_sockets];
 198         PVE::Tools::run_command($cmd);
 199
 200         # .. and just to be sure check on remote side
 201         unshift @{$cmd}, @{$self->{rem_ssh}};
 202         PVE::Tools::run_command($cmd);
 203     }
 204
 205     die $err if $err;
 206 }
 207
 208 sub start_remote_tunnel {
 209     my ($self, $raddr, $rport, $ruri, $unix_socket_info) = @_;
 210
 211     my $nodename = PVE::INotify::nodename();
 212     my $migration_type = $self->{opts}->{migration_type};
 213
 214     if ($migration_type eq 'secure') {
 215
 216         if ($ruri =~ /^unix:/) {
 217             my $ssh_forward_info = ["$raddr:$raddr"];
 218             $unix_socket_info->{$raddr} = 1;
 219
 220             my $unix_sockets = [ keys %$unix_socket_info ];
 221             for my $sock (@$unix_sockets) {
 222                 push @$ssh_forward_info, "$sock:$sock";
 223                 unlink $sock;
 224             }
 225
 226             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 227
 228             my $unix_socket_try = 0; # wait for the socket to become ready
 229             while ($unix_socket_try <= 100) {
 230                 $unix_socket_try++;
 231                 my $available = 0;
 232                 foreach my $sock (@$unix_sockets) {
 233                     if (-S $sock) {
 234                         $available++;
 235                     }
 236                 }
 237
 238                 if ($available == @$unix_sockets) {
 239                     last;
 240                 }
 241
 242                 usleep(50000);
 243             }
 244             if ($unix_socket_try > 100) {
 245                 $self->{errors} = 1;
 246                 $self->finish_tunnel($self->{tunnel});
 247                 die "Timeout, migration socket $ruri did not get ready";
 248             }
 249             $self->{tunnel}->{unix_sockets} = $unix_sockets if (@$unix_sockets);
 250
 251         } elsif ($ruri =~ /^tcp:/) {
 252             my $ssh_forward_info = [];
 253             if ($raddr eq "localhost") {
 254                 # for backwards compatibility with older qemu-server versions
 255                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 256                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 257                 push @$ssh_forward_info, "$lport:localhost:$rport";
 258             }
 259
 260             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 261
 262         } else {
 263             die "unsupported protocol in migration URI: $ruri\n";
 264         }
 265     } else {
 266         #fork tunnel for insecure migration, to send faster commands like resume
 267         $self->{tunnel} = $self->fork_tunnel();
 268     }
 269 }
 270
 271 sub lock_vm {
 272     my ($self, $vmid, $code, @param) = @_;
 273
 274     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 275 }
 276
 277 sub prepare {
 278     my ($self, $vmid) = @_;
 279
 280     my $online = $self->{opts}->{online};
 281
 282     $self->{storecfg} = PVE::Storage::config();
 283
 284     # test if VM exists
 285     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 286
 287     my $repl_conf = PVE::ReplicationConfig->new();
 288     $self->{replication_jobcfg} = $repl_conf->find_local_replication_job($vmid, $self->{node});
 289     $self->{is_replicated} = $repl_conf->check_for_existing_jobs($vmid, 1);
 290
 291     if ($self->{replication_jobcfg} && defined($self->{replication_jobcfg}->{remove_job})) {
 292         die "refusing to migrate replicated VM whose replication job is marked for removal\n";
 293     }
 294
 295     PVE::QemuConfig->check_lock($conf);
 296
 297     my $running = 0;
 298     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 299         die "can't migrate running VM without --online\n" if !$online;
 300         $running = $pid;
 301
 302         if ($self->{is_replicated} && !$self->{replication_jobcfg}) {
 303             if ($self->{opts}->{force}) {
 304                 $self->log('warn', "WARNING: Node '$self->{node}' is not a replication target. Existing " .
 305                                    "replication jobs will fail after migration!\n");
 306             } else {
 307                 die "Cannot live-migrate replicated VM to node '$self->{node}' - not a replication " .
 308                     "target. Use 'force' to override.\n";
 309             }
 310         }
 311
 312         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 313
 314         # To support custom CPU types, we keep QEMU's "-cpu" parameter intact.
 315         # Since the parameter itself contains no reference to a custom model,
 316         # this makes migration independent of changes to "cpu-models.conf".
 317         if ($conf->{cpu}) {
 318             my $cpuconf = PVE::JSONSchema::parse_property_string('pve-cpu-conf', $conf->{cpu});
 319             if ($cpuconf && PVE::QemuServer::CPUConfig::is_custom_model($cpuconf->{cputype})) {
 320                 $self->{forcecpu} = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 321             }
 322         }
 323     }
 324
 325     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 326     if (scalar @$loc_res) {
 327         if ($self->{running} || !$self->{opts}->{force}) {
 328             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 329         } else {
 330             $self->log('info', "migrating VM which uses local devices");
 331         }
 332     }
 333
 334     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 335
 336     foreach my $volid (@$vollist) {
 337         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 338
 339         # check if storage is available on both nodes
 340         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 341
 342         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 343         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 344
 345         if ($scfg->{shared}) {
 346             # PVE::Storage::activate_storage checks this for non-shared storages
 347             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 348             warn "Used shared storage '$sid' is not online on source node!\n"
 349                 if !$plugin->check_connection($sid, $scfg);
 350         }
 351     }
 352
 353     # test ssh connection
 354     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 355     eval { $self->cmd_quiet($cmd); };
 356     die "Can't connect to destination address using public key\n" if $@;
 357
 358     return $running;
 359 }
 360
 361 sub scan_local_volumes {
 362     my ($self, $vmid) = @_;
 363
 364     my $conf = $self->{vmconf};
 365
 366     # local volumes which have been copied
 367     # and their old_id => new_id pairs
 368     $self->{volumes} = [];
 369     $self->{volume_map} = {};
 370     $self->{local_volumes} = {};
 371
 372     my $storecfg = $self->{storecfg};
 373     eval {
 374
 375         # found local volumes and their origin
 376         my $local_volumes = $self->{local_volumes};
 377         my $local_volumes_errors = {};
 378         my $other_errors = [];
 379         my $abort = 0;
 380
 381         my $log_error = sub {
 382             my ($msg, $volid) = @_;
 383
 384             if (defined($volid)) {
 385                 $local_volumes_errors->{$volid} = $msg;
 386             } else {
 387                 push @$other_errors, $msg;
 388             }
 389             $abort = 1;
 390         };
 391
 392         my @sids = PVE::Storage::storage_ids($storecfg);
 393         foreach my $storeid (@sids) {
 394             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 395             next if $scfg->{shared};
 396             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 397
 398             # get list from PVE::Storage (for unused volumes)
 399             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 400
 401             next if @{$dl->{$storeid}} == 0;
 402
 403             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $storeid);
 404             # check if storage is available on target node
 405             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 406
 407             # grandfather in existing mismatches
 408             if ($targetsid ne $storeid) {
 409                 my $target_scfg = PVE::Storage::storage_config($storecfg, $targetsid);
 410                 die "content type 'images' is not available on storage '$targetsid'\n"
 411                     if !$target_scfg->{content}->{images};
 412             }
 413
 414             PVE::Storage::foreach_volid($dl, sub {
 415                 my ($volid, $sid, $volinfo) = @_;
 416
 417                 $local_volumes->{$volid}->{ref} = 'storage';
 418                 $local_volumes->{$volid}->{size} = $volinfo->{size};
 419
 420                 # If with_snapshots is not set for storage migrate, it tries to use
 421                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 422                 # back to qcow2 is currently not possible.
 423                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 424                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 425             });
 426         }
 427
 428         my $replicatable_volumes = !$self->{replication_jobcfg} ? {}
 429             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 430
 431         my $test_volid = sub {
 432             my ($volid, $attr) = @_;
 433
 434             if ($volid =~ m|^/|) {
 435                 return if $attr->{shared};
 436                 $local_volumes->{$volid}->{ref} = 'config';
 437                 die "local file/device\n";
 438             }
 439
 440             my $snaprefs = $attr->{referenced_in_snapshot};
 441
 442             if ($attr->{cdrom}) {
 443                 if ($volid eq 'cdrom') {
 444                     my $msg = "can't migrate local cdrom drive";
 445                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 446                         my $snapnames = join(', ', sort keys %$snaprefs);
 447                         $msg .= " (referenced in snapshot - $snapnames)";
 448                     }
 449                     &$log_error("$msg\n");
 450                     return;
 451                 }
 452                 return if $volid eq 'none';
 453             }
 454
 455             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 456
 457             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 458             # check if storage is available on both nodes
 459             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 460             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 461
 462             return if $scfg->{shared};
 463
 464             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 465             $local_volumes->{$volid}->{ref} = 'storage' if $attr->{is_unused};
 466
 467             $local_volumes->{$volid}->{is_vmstate} = $attr->{is_vmstate} ? 1 : 0;
 468
 469             if ($attr->{cdrom}) {
 470                 if ($volid =~ /vm-\d+-cloudinit/) {
 471                     $local_volumes->{$volid}->{ref} = 'generated';
 472                     return;
 473                 }
 474                 die "local cdrom image\n";
 475             }
 476
 477             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 478
 479             die "owned by other VM (owner = VM $owner)\n"
 480                 if !$owner || ($owner != $vmid);
 481
 482             return if $attr->{is_vmstate};
 483
 484             if (defined($snaprefs)) {
 485                 $local_volumes->{$volid}->{snapshots} = 1;
 486
 487                 # we cannot migrate shapshots on local storage
 488                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 489
 490                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 491                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 492                     die "non-migratable snapshot exists\n";
 493                 }
 494             }
 495
 496             die "referenced by linked clone(s)\n"
 497                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 498         };
 499
 500         PVE::QemuServer::foreach_volid($conf, sub {
 501             my ($volid, $attr) = @_;
 502             eval { $test_volid->($volid, $attr); };
 503             if (my $err = $@) {
 504                 &$log_error($err, $volid);
 505             }
 506         });
 507
 508         foreach my $vol (sort keys %$local_volumes) {
 509             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 510             my $ref = $local_volumes->{$vol}->{ref};
 511             if ($ref eq 'storage') {
 512                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 513             } elsif ($ref eq 'config') {
 514                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 515                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 516                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 517             } elsif ($ref eq 'snapshot') {
 518                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 519             } elsif ($ref eq 'generated') {
 520                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 521             } else {
 522                 $self->log('info', "found $type disk '$vol'\n");
 523             }
 524         }
 525
 526         foreach my $vol (sort keys %$local_volumes_errors) {
 527             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 528         }
 529         foreach my $err (@$other_errors) {
 530             $self->log('warn', "$err");
 531         }
 532
 533         if ($abort) {
 534             die "can't migrate VM - check log\n";
 535         }
 536
 537         # additional checks for local storage
 538         foreach my $volid (keys %$local_volumes) {
 539             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 540             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 541
 542             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 543
 544             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 545                 if !$migratable;
 546
 547             # image is a linked clone on local storage, se we can't migrate.
 548             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 549                 die "can't migrate '$volid' as it's a clone of '$basename'";
 550             }
 551         }
 552
 553         if ($self->{replication_jobcfg}) {
 554             if ($self->{running}) {
 555
 556                 my $version = PVE::QemuServer::kvm_user_version();
 557                 if (!min_version($version, 4, 2)) {
 558                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 559                 }
 560
 561                 my $live_replicatable_volumes = {};
 562                 PVE::QemuConfig->foreach_volume($conf, sub {
 563                     my ($ds, $drive) = @_;
 564
 565                     my $volid = $drive->{file};
 566                     $live_replicatable_volumes->{$ds} = $volid
 567                         if defined($replicatable_volumes->{$volid});
 568                 });
 569                 foreach my $drive (keys %$live_replicatable_volumes) {
 570                     my $volid = $live_replicatable_volumes->{$drive};
 571
 572                     my $bitmap = "repl_$drive";
 573
 574                     # start tracking before replication to get full delta + a few duplicates
 575                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 576                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 577
 578                     # other info comes from target node in phase 2
 579                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 580                 }
 581             }
 582             $self->log('info', "replicating disk images");
 583
 584             my $start_time = time();
 585             my $logfunc = sub { $self->log('info', shift) };
 586             $self->{replicated_volumes} = PVE::Replication::run_replication(
 587                'PVE::QemuConfig', $self->{replication_jobcfg}, $start_time, $start_time, $logfunc);
 588         }
 589
 590         # sizes in config have to be accurate for remote node to correctly
 591         # allocate disks
 592         PVE::QemuConfig->foreach_volume($conf, sub {
 593             my ($key, $drive) = @_;
 594             return if $key eq 'efidisk0'; # skip efidisk, will be handled later
 595
 596             my $volid = $drive->{file};
 597             return if !defined($local_volumes->{$volid}); # only update sizes for local volumes
 598
 599             my ($updated, $msg) = PVE::QemuServer::Drive::update_disksize($drive, $local_volumes->{$volid}->{size});
 600             if (defined($updated)) {
 601                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 602                 $self->log('info', "drive '$key': $msg");
 603             }
 604         });
 605
 606         # we want to set the efidisk size in the config to the size of the
 607         # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 608         if (defined($conf->{efidisk0})) {
 609             PVE::QemuServer::update_efidisk_size($conf);
 610         }
 611
 612         foreach my $volid (sort keys %$local_volumes) {
 613             my $ref = $local_volumes->{$volid}->{ref};
 614             if ($self->{running} && $ref eq 'config') {
 615                 push @{$self->{online_local_volumes}}, $volid;
 616             } elsif ($ref eq 'generated') {
 617                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 618                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 619                 push @{$self->{volumes}}, $volid;
 620                 next;
 621             } else {
 622                 next if $self->{replicated_volumes}->{$volid};
 623                 push @{$self->{volumes}}, $volid;
 624                 $local_volumes->{$volid}->{migration_mode} = 'offline';
 625             }
 626         }
 627     };
 628     die "Problem found while scanning volumes - $@" if $@;
 629 }
 630
 631 sub filter_local_volumes {
 632     my ($self, $migration_mode) = @_;
 633
 634     my $volumes = $self->{local_volumes};
 635     my @filtered_volids;
 636
 637     foreach my $volid (sort keys %{$volumes}) {
 638         next if defined($migration_mode) && safe_string_ne($volumes->{$volid}->{migration_mode}, $migration_mode);
 639         push @filtered_volids, $volid;
 640     }
 641
 642     return @filtered_volids;
 643 }
 644
 645 sub sync_offline_local_volumes {
 646     my ($self) = @_;
 647
 648     my $local_volumes = $self->{local_volumes};
 649     my @volids = $self->filter_local_volumes('offline');
 650
 651     my $storecfg = $self->{storecfg};
 652     my $opts = $self->{opts};
 653
 654     $self->log('info', "copying local disk images") if scalar(@volids);
 655
 656     foreach my $volid (@volids) {
 657         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 658         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 659         # use 'migration' limit for transfer to other node
 660         my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 661         # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 662         $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 663
 664         my $storage_migrate_opts = {
 665             'ratelimit_bps' => $bwlimit,
 666             'insecure' => $opts->{migration_type} eq 'insecure',
 667             'with_snapshots' => $local_volumes->{$volid}->{snapshots},
 668             'allow_rename' => !$local_volumes->{$volid}->{is_vmstate},
 669         };
 670
 671         my $logfunc = sub { $self->log('info', $_[0]); };
 672         my $new_volid = eval {
 673             PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info},
 674                                           $targetsid, $storage_migrate_opts, $logfunc);
 675         };
 676         if (my $err = $@) {
 677             die "storage migration for '$volid' to storage '$targetsid' failed - $err\n";
 678         }
 679
 680         $self->{volume_map}->{$volid} = $new_volid;
 681         $self->log('info', "volume '$volid' is '$new_volid' on the target\n");
 682
 683         eval { PVE::Storage::deactivate_volumes($storecfg, [$volid]); };
 684         if (my $err = $@) {
 685             $self->log('warn', $err);
 686         }
 687     }
 688 }
 689
 690 sub cleanup_remotedisks {
 691     my ($self) = @_;
 692
 693     foreach my $target_drive (keys %{$self->{target_drive}}) {
 694         my $drivestr = $self->{target_drive}->{$target_drive}->{drivestr};
 695         next if !defined($drivestr);
 696
 697         my $drive = PVE::QemuServer::parse_drive($target_drive, $drivestr);
 698
 699         # don't clean up replicated disks!
 700         next if defined($self->{replicated_volumes}->{$drive->{file}});
 701
 702         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 703
 704         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 705
 706         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 707         if (my $err = $@) {
 708             $self->log('err', $err);
 709             $self->{errors} = 1;
 710         }
 711     }
 712 }
 713
 714 sub cleanup_bitmaps {
 715     my ($self) = @_;
 716     foreach my $drive (keys %{$self->{target_drive}}) {
 717         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 718         next if !$bitmap;
 719         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 720         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 721     }
 722 }
 723
 724 sub phase1 {
 725     my ($self, $vmid) = @_;
 726
 727     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 728
 729     my $conf = $self->{vmconf};
 730
 731     # set migrate lock in config file
 732     $conf->{lock} = 'migrate';
 733     PVE::QemuConfig->write_config($vmid, $conf);
 734
 735     # scan_local_volumes fixes disk sizes to match their actual size, write changes so
 736     # target allocates correct volumes
 737     $self->scan_local_volumes($vmid);
 738     PVE::QemuConfig->write_config($vmid, $conf);
 739
 740     $self->sync_offline_local_volumes();
 741 };
 742
 743 sub phase1_cleanup {
 744     my ($self, $vmid, $err) = @_;
 745
 746     $self->log('info', "aborting phase 1 - cleanup resources");
 747
 748     my $conf = $self->{vmconf};
 749     delete $conf->{lock};
 750     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 751     if (my $err = $@) {
 752         $self->log('err', $err);
 753     }
 754
 755     if ($self->{volumes}) {
 756         foreach my $volid (@{$self->{volumes}}) {
 757             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 758             # fixme: try to remove ?
 759         }
 760     }
 761
 762     eval { $self->cleanup_bitmaps() };
 763     if (my $err =$@) {
 764         $self->log('err', $err);
 765     }
 766
 767 }
 768
 769 sub phase2 {
 770     my ($self, $vmid) = @_;
 771
 772     my $conf = $self->{vmconf};
 773
 774     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 775
 776     my $raddr;
 777     my $rport;
 778     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 779     my $nodename = PVE::INotify::nodename();
 780
 781     ## start on remote node
 782     my $cmd = [@{$self->{rem_ssh}}];
 783
 784     my $spice_ticket;
 785     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 786         my $res = mon_cmd($vmid, 'query-spice');
 787         $spice_ticket = $res->{ticket};
 788     }
 789
 790     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 791
 792     my $migration_type = $self->{opts}->{migration_type};
 793
 794     push @$cmd, '--migration_type', $migration_type;
 795
 796     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 797       if $self->{opts}->{migration_network};
 798
 799     if ($migration_type eq 'insecure') {
 800         push @$cmd, '--stateuri', 'tcp';
 801     } else {
 802         push @$cmd, '--stateuri', 'unix';
 803     }
 804
 805     if ($self->{forcemachine}) {
 806         push @$cmd, '--machine', $self->{forcemachine};
 807     }
 808
 809     if ($self->{forcecpu}) {
 810         push @$cmd, '--force-cpu', $self->{forcecpu};
 811     }
 812
 813     if ($self->{online_local_volumes}) {
 814         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 815     }
 816
 817     my $spice_port;
 818     my $unix_socket_info = {};
 819     # version > 0 for unix socket support
 820     my $nbd_protocol_version = 1;
 821     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 822     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 823     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 824
 825     my $number_of_online_replicated_volumes = 0;
 826
 827     # prevent auto-vivification
 828     if ($self->{online_local_volumes}) {
 829         foreach my $volid (@{$self->{online_local_volumes}}) {
 830             next if !$self->{replicated_volumes}->{$volid};
 831             $number_of_online_replicated_volumes++;
 832             $input .= "replicated_volume: $volid\n";
 833         }
 834     }
 835
 836     my $target_replicated_volumes = {};
 837
 838     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 839     # instead we pipe it through STDIN
 840     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 841         my $line = shift;
 842
 843         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 844             $raddr = $1;
 845             $rport = int($2);
 846             $ruri = "tcp:$raddr:$rport";
 847         }
 848         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 849             $raddr = $1;
 850             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 851             $ruri = "unix:$raddr";
 852         }
 853         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 854             $raddr = "localhost";
 855             $rport = int($1);
 856             $ruri = "tcp:$raddr:$rport";
 857         }
 858         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 859             $spice_port = int($1);
 860         }
 861         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 862             my $drivestr = $4;
 863             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 864             my $targetdrive = $3;
 865             $targetdrive =~ s/drive-//g;
 866
 867             $self->{stopnbd} = 1;
 868             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 869             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 870         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 871             my $drivestr = $4;
 872             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 873             my $nbd_unix_addr = $1;
 874             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 875             my $targetdrive = $3;
 876             $targetdrive =~ s/drive-//g;
 877
 878             $self->{stopnbd} = 1;
 879             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 880             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 881             $unix_socket_info->{$nbd_unix_addr} = 1;
 882         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 883             my $drive = $1;
 884             my $volid = $2;
 885             $target_replicated_volumes->{$volid} = $drive;
 886         } elsif ($line =~ m/^QEMU: (.*)$/) {
 887             $self->log('info', "[$self->{node}] $1\n");
 888         }
 889     }, errfunc => sub {
 890         my $line = shift;
 891         $self->log('info', "[$self->{node}] $line");
 892     }, noerr => 1);
 893
 894     die "remote command failed with exit code $exitcode\n" if $exitcode;
 895
 896     die "unable to detect remote migration address\n" if !$raddr;
 897
 898     if (scalar(keys %$target_replicated_volumes) != $number_of_online_replicated_volumes) {
 899         die "number of replicated disks on source and target node do not match - target node too old?\n"
 900     }
 901
 902     $self->log('info', "start remote tunnel");
 903     $self->start_remote_tunnel($raddr, $rport, $ruri, $unix_socket_info);
 904
 905     my $start = time();
 906
 907     my $opt_bwlimit = $self->{opts}->{bwlimit};
 908
 909     if (defined($self->{online_local_volumes})) {
 910         $self->{storage_migration} = 1;
 911         $self->{storage_migration_jobs} = {};
 912         $self->log('info', "starting storage migration");
 913
 914         die "The number of local disks does not match between the source and the destination.\n"
 915             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 916         foreach my $drive (keys %{$self->{target_drive}}){
 917             my $target = $self->{target_drive}->{$drive};
 918             my $nbd_uri = $target->{nbd_uri};
 919
 920             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 921             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 922
 923             my $source_volid = $source_drive->{file};
 924             my $target_volid = $target_drive->{file};
 925
 926             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_volid);
 927             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_volid);
 928
 929             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 930             my $bitmap = $target->{bitmap};
 931
 932             $self->log('info', "$drive: start migration to $nbd_uri");
 933             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 934
 935             $self->{volume_map}->{$source_volid} = $target_volid;
 936             $self->log('info', "volume '$source_volid' is '$target_volid' on the target\n");
 937         }
 938     }
 939
 940     $self->log('info', "starting online/live migration on $ruri");
 941     $self->{livemigration} = 1;
 942
 943     # load_defaults
 944     my $defaults = PVE::QemuServer::load_defaults();
 945
 946     $self->log('info', "set migration_caps");
 947     eval {
 948         PVE::QemuServer::set_migration_caps($vmid);
 949     };
 950     warn $@ if $@;
 951
 952     my $qemu_migrate_params = {};
 953
 954     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 955     # migrate_speed parameter in qm.conf - take the lower of the two.
 956     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 957     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 958     # migrate_speed is in MB/s, bwlimit in KB/s
 959     $migrate_speed *= 1024;
 960
 961     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 962
 963     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 964     # default of 8192m which is basically unlimited
 965     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 966
 967     # qmp takes migrate_speed in B/s.
 968     $migrate_speed *= 1024;
 969     $self->log('info', "migration speed limit: $migrate_speed B/s");
 970     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 971
 972     my $migrate_downtime = $defaults->{migrate_downtime};
 973     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 974     # migrate-set-parameters expects limit in ms
 975     $migrate_downtime *= 1000;
 976     $self->log('info', "migration downtime limit: $migrate_downtime ms");
 977     $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 978
 979     # set cachesize to 10% of the total memory
 980     my $memory =  $conf->{memory} || $defaults->{memory};
 981     my $cachesize = int($memory * 1048576 / 10);
 982     $cachesize = round_powerof2($cachesize);
 983
 984     $self->log('info', "migration cachesize: $cachesize B");
 985     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 986
 987     $self->log('info', "set migration parameters");
 988     eval {
 989         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 990     };
 991     $self->log('info', "migrate-set-parameters error: $@") if $@;
 992
 993     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 994         my $rpcenv = PVE::RPCEnvironment::get();
 995         my $authuser = $rpcenv->get_user();
 996
 997         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 998
 999         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
1000         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
1001
1002         $self->log('info', "spice client_migrate_info");
1003
1004         eval {
1005             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
1006                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
1007                                                 'cert-subject' => $subject);
1008         };
1009         $self->log('info', "client_migrate_info error: $@") if $@;
1010
1011     }
1012
1013     $self->log('info', "start migrate command to $ruri");
1014     eval {
1015         mon_cmd($vmid, "migrate", uri => $ruri);
1016     };
1017     my $merr = $@;
1018     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
1019
1020     my $lstat = 0;
1021     my $usleep = 1000000;
1022     my $i = 0;
1023     my $err_count = 0;
1024     my $lastrem = undef;
1025     my $downtimecounter = 0;
1026     while (1) {
1027         $i++;
1028         my $avglstat = $lstat ? $lstat / $i : 0;
1029
1030         usleep($usleep);
1031         my $stat;
1032         eval {
1033             $stat = mon_cmd($vmid, "query-migrate");
1034         };
1035         if (my $err = $@) {
1036             $err_count++;
1037             warn "query migrate failed: $err\n";
1038             $self->log('info', "query migrate failed: $err");
1039             if ($err_count <= 5) {
1040                 usleep(1000000);
1041                 next;
1042             }
1043             die "too many query migrate failures - aborting\n";
1044         }
1045
1046         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
1047             sleep(1);
1048             next;
1049         }
1050
1051         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
1052             $merr = undef;
1053             $err_count = 0;
1054             if ($stat->{status} eq 'completed') {
1055                 my $delay = time() - $start;
1056                 if ($delay > 0) {
1057                     my $mbps = sprintf "%.2f", $memory / $delay;
1058                     my $downtime = $stat->{downtime} || 0;
1059                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
1060                 }
1061             }
1062
1063             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
1064                 $self->log('info', "migration status error: $stat->{status}");
1065                 die "aborting\n"
1066             }
1067
1068             if ($stat->{status} ne 'active') {
1069                 $self->log('info', "migration status: $stat->{status}");
1070                 last;
1071             }
1072
1073             if ($stat->{ram}->{transferred} ne $lstat) {
1074                 my $trans = $stat->{ram}->{transferred} || 0;
1075                 my $rem = $stat->{ram}->{remaining} || 0;
1076                 my $total = $stat->{ram}->{total} || 0;
1077                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
1078                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
1079                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
1080                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
1081                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
1082                 # reduce sleep if remainig memory is lower than the average transfer speed
1083                 $usleep = 100000 if $avglstat && $rem < $avglstat;
1084
1085                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
1086                            "remaining ${rem}), total ${total})");
1087
1088                 if (${xbzrlecachesize}) {
1089                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
1090                 }
1091
1092                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
1093                     $downtimecounter++;
1094                 }
1095                 $lastrem = $rem;
1096
1097                 if ($downtimecounter > 5) {
1098                     $downtimecounter = 0;
1099                     $migrate_downtime *= 2;
1100                     $self->log('info', "auto-increased downtime to continue migration: $migrate_downtime ms");
1101                     eval {
1102                         # migrate-set-parameters does not touch values not
1103                         # specified, so this only changes downtime-limit
1104                         mon_cmd($vmid, "migrate-set-parameters", 'downtime-limit' => int($migrate_downtime));
1105                     };
1106                     $self->log('info', "migrate-set-parameters error: $@") if $@;
1107                 }
1108
1109             }
1110
1111
1112             $lstat = $stat->{ram}->{transferred};
1113
1114         } else {
1115             die $merr if $merr;
1116             die "unable to parse migration status '$stat->{status}' - aborting\n";
1117         }
1118     }
1119 }
1120
1121 sub phase2_cleanup {
1122     my ($self, $vmid, $err) = @_;
1123
1124     return if !$self->{errors};
1125     $self->{phase2errors} = 1;
1126
1127     $self->log('info', "aborting phase 2 - cleanup resources");
1128
1129     $self->log('info', "migrate_cancel");
1130     eval {
1131         mon_cmd($vmid, "migrate_cancel");
1132     };
1133     $self->log('info', "migrate_cancel error: $@") if $@;
1134
1135     my $conf = $self->{vmconf};
1136     delete $conf->{lock};
1137     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1138     if (my $err = $@) {
1139         $self->log('err', $err);
1140     }
1141
1142     # cleanup ressources on target host
1143     if ($self->{storage_migration}) {
1144         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1145         if (my $err = $@) {
1146             $self->log('err', $err);
1147         }
1148     }
1149
1150     eval { $self->cleanup_bitmaps() };
1151     if (my $err =$@) {
1152         $self->log('err', $err);
1153     }
1154
1155     my $nodename = PVE::INotify::nodename();
1156
1157     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1158     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1159     if (my $err = $@) {
1160         $self->log('err', $err);
1161         $self->{errors} = 1;
1162     }
1163
1164     # cleanup after stopping, otherwise disks might be in-use by target VM!
1165     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1166     if (my $err = $@) {
1167         $self->log('err', $err);
1168     }
1169
1170
1171     if ($self->{tunnel}) {
1172         eval { finish_tunnel($self, $self->{tunnel});  };
1173         if (my $err = $@) {
1174             $self->log('err', $err);
1175             $self->{errors} = 1;
1176         }
1177     }
1178 }
1179
1180 sub phase3 {
1181     my ($self, $vmid) = @_;
1182
1183     my $volids = $self->{volumes};
1184     return if $self->{phase2errors};
1185
1186     # destroy local copies
1187     foreach my $volid (@$volids) {
1188         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1189         if (my $err = $@) {
1190             $self->log('err', "removing local copy of '$volid' failed - $err");
1191             $self->{errors} = 1;
1192             last if $err =~ /^interrupted by signal$/;
1193         }
1194     }
1195 }
1196
1197 sub phase3_cleanup {
1198     my ($self, $vmid, $err) = @_;
1199
1200     my $conf = $self->{vmconf};
1201     return if $self->{phase2errors};
1202
1203     my $tunnel = $self->{tunnel};
1204
1205     if ($self->{storage_migration}) {
1206         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1207         # to avoid it trying to re-establish it. We are in blockjob ready state,
1208         # thus, this command changes to it to blockjob complete (see qapi docs)
1209         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1210
1211         if (my $err = $@) {
1212             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1213             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1214             die "Failed to complete storage migration: $err\n";
1215         }
1216     }
1217
1218     if ($self->{volume_map}) {
1219         my $target_drives = $self->{target_drive};
1220
1221         # FIXME: for NBD storage migration we now only update the volid, and
1222         # not the full drivestr from the target node. Workaround that until we
1223         # got some real rescan, to avoid things like wrong format in the drive
1224         delete $conf->{$_} for keys %$target_drives;
1225         PVE::QemuConfig->update_volume_ids($conf, $self->{volume_map});
1226
1227         for my $drive (keys %$target_drives) {
1228             $conf->{$drive} = $target_drives->{$drive}->{drivestr};
1229         }
1230         PVE::QemuConfig->write_config($vmid, $conf);
1231     }
1232
1233     # transfer replication state before move config
1234     $self->transfer_replication_state() if $self->{is_replicated};
1235     PVE::QemuConfig->move_config_to_node($vmid, $self->{node});
1236     $self->switch_replication_job_target() if $self->{is_replicated};
1237
1238     if ($self->{livemigration}) {
1239         if ($self->{stopnbd}) {
1240             $self->log('info', "stopping NBD storage migration server on target.");
1241             # stop nbd server on remote vm - requirement for resume since 2.9
1242             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1243
1244             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1245             if (my $err = $@) {
1246                 $self->log('err', $err);
1247                 $self->{errors} = 1;
1248             }
1249         }
1250
1251         # config moved and nbd server stopped - now we can resume vm on target
1252         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1253             eval {
1254                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1255             };
1256             if (my $err = $@) {
1257                 $self->log('err', $err);
1258                 $self->{errors} = 1;
1259             }
1260         } else {
1261             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1262             my $logf = sub {
1263                 my $line = shift;
1264                 $self->log('err', $line);
1265             };
1266             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1267             if (my $err = $@) {
1268                 $self->log('err', $err);
1269                 $self->{errors} = 1;
1270             }
1271         }
1272
1273         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1274             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1275             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1276         }
1277     }
1278
1279     # close tunnel on successful migration, on error phase2_cleanup closed it
1280     if ($tunnel) {
1281         eval { finish_tunnel($self, $tunnel);  };
1282         if (my $err = $@) {
1283             $self->log('err', $err);
1284             $self->{errors} = 1;
1285         }
1286     }
1287
1288     eval {
1289         my $timer = 0;
1290         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1291             $self->log('info', "Waiting for spice server migration");
1292             while (1) {
1293                 my $res = mon_cmd($vmid, 'query-spice');
1294                 last if int($res->{'migrated'}) == 1;
1295                 last if $timer > 50;
1296                 $timer ++;
1297                 usleep(200000);
1298             }
1299         }
1300     };
1301
1302     # always stop local VM
1303     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1304     if (my $err = $@) {
1305         $self->log('err', "stopping vm failed - $err");
1306         $self->{errors} = 1;
1307     }
1308
1309     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1310     eval {
1311         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1312         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1313     };
1314     if (my $err = $@) {
1315         $self->log('err', $err);
1316         $self->{errors} = 1;
1317     }
1318
1319     if($self->{storage_migration}) {
1320         # destroy local copies
1321         my $volids = $self->{online_local_volumes};
1322
1323         foreach my $volid (@$volids) {
1324             # keep replicated volumes!
1325             next if $self->{replicated_volumes}->{$volid};
1326
1327             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1328             if (my $err = $@) {
1329                 $self->log('err', "removing local copy of '$volid' failed - $err");
1330                 $self->{errors} = 1;
1331                 last if $err =~ /^interrupted by signal$/;
1332             }
1333         }
1334
1335     }
1336
1337     # clear migrate lock
1338     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1339     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1340 }
1341
1342 sub final_cleanup {
1343     my ($self, $vmid) = @_;
1344
1345     # nothing to do
1346 }
1347
1348 sub round_powerof2 {
1349     return 1 if $_[0] < 2;
1350     return 2 << int(log($_[0]-1)/log(2));
1351 }
1352
1353 1;