PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16 use PVE::ReplicationConfig;
  17 use PVE::ReplicationState;
  18 use PVE::Replication;
  19
  20 use base qw(PVE::AbstractMigrate);
  21
  22 sub fork_command_pipe {
  23     my ($self, $cmd) = @_;
  24
  25     my $reader = IO::File->new();
  26     my $writer = IO::File->new();
  27
  28     my $orig_pid = $$;
  29
  30     my $cpid;
  31
  32     eval { $cpid = open2($reader, $writer, @$cmd); };
  33
  34     my $err = $@;
  35
  36     # catch exec errors
  37     if ($orig_pid != $$) {
  38         $self->log('err', "can't fork command pipe\n");
  39         POSIX::_exit(1);
  40         kill('KILL', $$);
  41     }
  42
  43     die $err if $err;
  44
  45     return { writer => $writer, reader => $reader, pid => $cpid };
  46 }
  47
  48 sub finish_command_pipe {
  49     my ($self, $cmdpipe, $timeout) = @_;
  50
  51     my $cpid = $cmdpipe->{pid};
  52     return if !defined($cpid);
  53
  54     my $writer = $cmdpipe->{writer};
  55     my $reader = $cmdpipe->{reader};
  56
  57     $writer->close();
  58     $reader->close();
  59
  60     my $collect_child_process = sub {
  61         my $res = waitpid($cpid, WNOHANG);
  62         if (defined($res) && ($res == $cpid)) {
  63             delete $cmdpipe->{cpid};
  64             return 1;
  65         } else {
  66             return 0;
  67         }
  68      };
  69
  70     if ($timeout) {
  71         for (my $i = 0; $i < $timeout; $i++) {
  72             return if &$collect_child_process();
  73             sleep(1);
  74         }
  75     }
  76
  77     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  78     kill(15, $cpid);
  79
  80     # wait again
  81     for (my $i = 0; $i < 10; $i++) {
  82         return if &$collect_child_process();
  83         sleep(1);
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  87     kill 9, $cpid;
  88     sleep 1;
  89
  90     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  91         if !&$collect_child_process();
  92 }
  93
  94 sub read_tunnel {
  95     my ($self, $tunnel, $timeout) = @_;
  96
  97     $timeout = 60 if !defined($timeout);
  98
  99     my $reader = $tunnel->{reader};
 100
 101     my $output;
 102     eval {
 103         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 104     };
 105     die "reading from tunnel failed: $@\n" if $@;
 106
 107     chomp $output;
 108
 109     return $output;
 110 }
 111
 112 sub write_tunnel {
 113     my ($self, $tunnel, $timeout, $command) = @_;
 114
 115     $timeout = 60 if !defined($timeout);
 116
 117     my $writer = $tunnel->{writer};
 118
 119     eval {
 120         PVE::Tools::run_with_timeout($timeout, sub {
 121             print $writer "$command\n";
 122             $writer->flush();
 123         });
 124     };
 125     die "writing to tunnel failed: $@\n" if $@;
 126
 127     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 128         my $res = eval { $self->read_tunnel($tunnel, 10); };
 129         die "no reply to command '$command': $@\n" if $@;
 130
 131         if ($res eq 'OK') {
 132             return;
 133         } else {
 134             die "tunnel replied '$res' to command '$command'\n";
 135         }
 136     }
 137 }
 138
 139 sub fork_tunnel {
 140     my ($self, $tunnel_addr) = @_;
 141
 142     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
 143
 144     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 145
 146     my $tunnel = $self->fork_command_pipe($cmd);
 147
 148     eval {
 149         my $helo = $self->read_tunnel($tunnel, 60);
 150         die "no reply\n" if !$helo;
 151         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 152         die "got strange reply from mtunnel ('$helo')\n"
 153             if $helo !~ m/^tunnel online$/;
 154     };
 155     my $err = $@;
 156
 157     eval {
 158         my $ver = $self->read_tunnel($tunnel, 10);
 159         if ($ver =~ /^ver (\d+)$/) {
 160             $tunnel->{version} = $1;
 161             $self->log('info', "ssh tunnel $ver\n");
 162         } else {
 163             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 164         }
 165     };
 166
 167     if ($err) {
 168         $self->finish_command_pipe($tunnel);
 169         die "can't open migration tunnel - $err";
 170     }
 171     return $tunnel;
 172 }
 173
 174 sub finish_tunnel {
 175     my ($self, $tunnel) = @_;
 176
 177     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 178     my $err = $@;
 179
 180     $self->finish_command_pipe($tunnel, 30);
 181
 182     if ($tunnel->{sock_addr}) {
 183         # ssh does not clean up on local host
 184         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 185         PVE::Tools::run_command($cmd);
 186
 187         # .. and just to be sure check on remote side
 188         unshift @{$cmd}, @{$self->{rem_ssh}};
 189         PVE::Tools::run_command($cmd);
 190     }
 191
 192     die $err if $err;
 193 }
 194
 195 sub lock_vm {
 196     my ($self, $vmid, $code, @param) = @_;
 197
 198     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 199 }
 200
 201 sub prepare {
 202     my ($self, $vmid) = @_;
 203
 204     my $online = $self->{opts}->{online};
 205
 206     $self->{storecfg} = PVE::Storage::config();
 207
 208     # test if VM exists
 209     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 210
 211     PVE::QemuConfig->check_lock($conf);
 212
 213     my $running = 0;
 214     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 215         die "can't migrate running VM without --online\n" if !$online;
 216         $running = $pid;
 217
 218         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 219
 220     }
 221
 222     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 223         if ($self->{running} || !$self->{opts}->{force}) {
 224             die "can't migrate VM which uses local devices\n";
 225         } else {
 226             $self->log('info', "migrating VM which uses local devices");
 227         }
 228     }
 229
 230     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 231
 232     my $need_activate = [];
 233     foreach my $volid (@$vollist) {
 234         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 235
 236         # check if storage is available on both nodes
 237         my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 238
 239         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 240         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 241
 242         if ($scfg->{shared}) {
 243             # PVE::Storage::activate_storage checks this for non-shared storages
 244             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 245             warn "Used shared storage '$sid' is not online on source node!\n"
 246                 if !$plugin->check_connection($sid, $scfg);
 247         } else {
 248             # only activate if not shared
 249             push @$need_activate, $volid;
 250         }
 251     }
 252
 253     # activate volumes
 254     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 255
 256     # test ssh connection
 257     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 258     eval { $self->cmd_quiet($cmd); };
 259     die "Can't connect to destination address using public key\n" if $@;
 260
 261     return $running;
 262 }
 263
 264 sub sync_disks {
 265     my ($self, $vmid) = @_;
 266
 267     my $conf = $self->{vmconf};
 268
 269     # local volumes which have been copied
 270     $self->{volumes} = [];
 271
 272     eval {
 273
 274         # found local volumes and their origin
 275         my $local_volumes = {};
 276         my $local_volumes_errors = {};
 277         my $other_errors = [];
 278         my $abort = 0;
 279
 280         my $sharedvm = 1;
 281
 282         my $log_error = sub {
 283             my ($msg, $volid) = @_;
 284
 285             if (defined($volid)) {
 286                 $local_volumes_errors->{$volid} = $msg;
 287             } else {
 288                 push @$other_errors, $msg;
 289             }
 290             $abort = 1;
 291         };
 292
 293         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 294         foreach my $storeid (@sids) {
 295             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 296             next if $scfg->{shared};
 297             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 298
 299             # get list from PVE::Storage (for unused volumes)
 300             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 301
 302             next if @{$dl->{$storeid}} == 0;
 303
 304             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $storeid;
 305
 306             # check if storage is available on target node
 307             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 308             $sharedvm = 0; # there is a non-shared disk
 309
 310             PVE::Storage::foreach_volid($dl, sub {
 311                 my ($volid, $sid, $volname) = @_;
 312
 313                 $local_volumes->{$volid}->{ref} = 'storage';
 314             });
 315         }
 316
 317         my $test_volid = sub {
 318             my ($volid, $attr) = @_;
 319
 320             if ($volid =~ m|^/|) {
 321                 return if $attr->{shared};
 322                 $local_volumes->{$volid}->{ref} = 'config';
 323                 die "local file/device\n";
 324             }
 325
 326             my $snaprefs = $attr->{referenced_in_snapshot};
 327
 328             if ($attr->{cdrom}) {
 329                 if ($volid eq 'cdrom') {
 330                     my $msg = "can't migrate local cdrom drive";
 331                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 332                         my $snapnames = join(', ', sort keys %$snaprefs);
 333                         $msg .= " (referenced in snapshot - $snapnames)";
 334                     }
 335                     &$log_error("$msg\n");
 336                     return;
 337                 }
 338                 return if $volid eq 'none';
 339             }
 340
 341             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 342
 343             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 344             # check if storage is available on both nodes
 345             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 346             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 347
 348             return if $scfg->{shared};
 349
 350             $sharedvm = 0;
 351
 352             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 353
 354             die "local cdrom image\n" if $attr->{cdrom};
 355
 356             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 357
 358             die "owned by other VM (owner = VM $owner)\n"
 359                 if !$owner || ($owner != $self->{vmid});
 360
 361             my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 362             $local_volumes->{$volid}->{snapshots} = defined($snaprefs) || ($format =~ /^(?:qcow2|vmdk)$/);
 363             if (defined($snaprefs)) {
 364                 # we cannot migrate shapshots on local storage
 365                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 366
 367                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 368                 if (!($scfg->{type} eq 'zfspool' || $format eq 'qcow2')) {
 369                     die "non-migratable snapshot exists\n";
 370                 }
 371             }
 372
 373             die "referenced by linked clone(s)\n"
 374                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 375         };
 376
 377         PVE::QemuServer::foreach_volid($conf, sub {
 378             my ($volid, $attr) = @_;
 379             eval { $test_volid->($volid, $attr); };
 380             if (my $err = $@) {
 381                 &$log_error($err, $volid);
 382             }
 383         });
 384
 385         foreach my $vol (sort keys %$local_volumes) {
 386             my $ref = $local_volumes->{$vol}->{ref};
 387             if ($ref eq 'storage') {
 388                 $self->log('info', "found local disk '$vol' (via storage)\n");
 389             } elsif ($ref eq 'config') {
 390                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 391                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 392                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 393             } elsif ($ref eq 'snapshot') {
 394                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 395             } else {
 396                 $self->log('info', "found local disk '$vol'\n");
 397             }
 398         }
 399
 400         foreach my $vol (sort keys %$local_volumes_errors) {
 401             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 402         }
 403         foreach my $err (@$other_errors) {
 404             $self->log('warn', "$err");
 405         }
 406
 407         if ($self->{running} && !$sharedvm && !$self->{opts}->{targetstorage}) {
 408             $self->{opts}->{targetstorage} = 1; #use same sid for remote local
 409         }
 410
 411         if ($abort) {
 412             die "can't migrate VM - check log\n";
 413         }
 414
 415         # additional checks for local storage
 416         foreach my $volid (keys %$local_volumes) {
 417             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 418             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 419
 420             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 421                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 422
 423             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 424                 if !$migratable;
 425
 426             # image is a linked clone on local storage, se we can't migrate.
 427             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 428                 die "can't migrate '$volid' as it's a clone of '$basename'";
 429             }
 430         }
 431
 432         my $rep_volumes;
 433
 434         $self->log('info', "copying disk images");
 435
 436         my $rep_cfg = PVE::ReplicationConfig->new();
 437
 438         if (my $jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node})) {
 439             die "can't live migrate VM with replicated volumes\n" if $self->{running};
 440             my $start_time = time();
 441             my $logfunc = sub { my ($msg) = @_;  $self->log('info', $msg); };
 442             $rep_volumes = PVE::Replication::run_replication(
 443                'PVE::QemuConfig', $jobcfg, $start_time, $start_time, $logfunc);
 444             $self->{replicated_volumes} = $rep_volumes;
 445         }
 446
 447         foreach my $volid (keys %$local_volumes) {
 448             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 449             if ($self->{running} && $self->{opts}->{targetstorage} && $local_volumes->{$volid}->{ref} eq 'config') {
 450                 push @{$self->{online_local_volumes}}, $volid;
 451             } else {
 452                 next if $rep_volumes->{$volid};
 453                 push @{$self->{volumes}}, $volid;
 454                 my $insecure = $self->{opts}->{migration_type} eq 'insecure';
 455                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 456                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{ssh_info}, $sid,
 457                                               undef, undef, undef, undef, $insecure, $with_snapshots);
 458             }
 459         }
 460     };
 461     die "Failed to sync data - $@" if $@;
 462 }
 463
 464 sub cleanup_remotedisks {
 465     my ($self) = @_;
 466
 467     foreach my $target_drive (keys %{$self->{target_drive}}) {
 468
 469         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 470         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 471
 472         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 473
 474         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 475         if (my $err = $@) {
 476             $self->log('err', $err);
 477             $self->{errors} = 1;
 478         }
 479     }
 480 }
 481
 482 sub phase1 {
 483     my ($self, $vmid) = @_;
 484
 485     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 486
 487     my $conf = $self->{vmconf};
 488
 489     # set migrate lock in config file
 490     $conf->{lock} = 'migrate';
 491     PVE::QemuConfig->write_config($vmid, $conf);
 492
 493     sync_disks($self, $vmid);
 494
 495 };
 496
 497 sub phase1_cleanup {
 498     my ($self, $vmid, $err) = @_;
 499
 500     $self->log('info', "aborting phase 1 - cleanup resources");
 501
 502     my $conf = $self->{vmconf};
 503     delete $conf->{lock};
 504     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 505     if (my $err = $@) {
 506         $self->log('err', $err);
 507     }
 508
 509     if ($self->{volumes}) {
 510         foreach my $volid (@{$self->{volumes}}) {
 511             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 512             # fixme: try to remove ?
 513         }
 514     }
 515 }
 516
 517 sub phase2 {
 518     my ($self, $vmid) = @_;
 519
 520     my $conf = $self->{vmconf};
 521
 522     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 523
 524     my $raddr;
 525     my $rport;
 526     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 527     my $nodename = PVE::INotify::nodename();
 528
 529     ## start on remote node
 530     my $cmd = [@{$self->{rem_ssh}}];
 531
 532     my $spice_ticket;
 533     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 534         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 535         $spice_ticket = $res->{ticket};
 536     }
 537
 538     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 539
 540     my $migration_type = $self->{opts}->{migration_type};
 541
 542     push @$cmd, '--migration_type', $migration_type;
 543
 544     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 545       if $self->{opts}->{migration_network};
 546
 547     if ($migration_type eq 'insecure') {
 548         push @$cmd, '--stateuri', 'tcp';
 549     } else {
 550         push @$cmd, '--stateuri', 'unix';
 551     }
 552
 553     if ($self->{forcemachine}) {
 554         push @$cmd, '--machine', $self->{forcemachine};
 555     }
 556
 557     if ($self->{opts}->{targetstorage}) {
 558         push @$cmd, '--targetstorage', $self->{opts}->{targetstorage};
 559     }
 560
 561     my $spice_port;
 562
 563     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 564     # instead we pipe it through STDIN
 565     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 566         my $line = shift;
 567
 568         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 569             $raddr = $1;
 570             $rport = int($2);
 571             $ruri = "tcp:$raddr:$rport";
 572         }
 573         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 574             $raddr = $1;
 575             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 576             $ruri = "unix:$raddr";
 577         }
 578         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 579             $raddr = "localhost";
 580             $rport = int($1);
 581             $ruri = "tcp:$raddr:$rport";
 582         }
 583         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 584             $spice_port = int($1);
 585         }
 586         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 587             my $volid = $4;
 588             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 589             my $targetdrive = $3;
 590             $targetdrive =~ s/drive-//g;
 591
 592             $self->{target_drive}->{$targetdrive}->{volid} = $volid;
 593             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 594
 595         }
 596     }, errfunc => sub {
 597         my $line = shift;
 598         $self->log('info', $line);
 599     });
 600
 601     die "unable to detect remote migration address\n" if !$raddr;
 602
 603     $self->log('info', "start remote tunnel");
 604
 605     if ($migration_type eq 'secure') {
 606
 607         if ($ruri =~ /^unix:/) {
 608             unlink $raddr;
 609             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 610             $self->{tunnel}->{sock_addr} = $raddr;
 611
 612             my $unix_socket_try = 0; # wait for the socket to become ready
 613             while (! -S $raddr) {
 614                 $unix_socket_try++;
 615                 if ($unix_socket_try > 100) {
 616                     $self->{errors} = 1;
 617                     $self->finish_tunnel($self->{tunnel});
 618                     die "Timeout, migration socket $ruri did not get ready";
 619                 }
 620
 621                 usleep(50000);
 622             }
 623
 624         } elsif ($ruri =~ /^tcp:/) {
 625             my $tunnel_addr;
 626             if ($raddr eq "localhost") {
 627                 # for backwards compatibility with older qemu-server versions
 628                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 629                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 630                 $tunnel_addr = "$lport:localhost:$rport";
 631             }
 632
 633             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 634
 635         } else {
 636             die "unsupported protocol in migration URI: $ruri\n";
 637         }
 638     } else {
 639         #fork tunnel for insecure migration, to send faster commands like resume
 640         $self->{tunnel} = $self->fork_tunnel();
 641     }
 642
 643     my $start = time();
 644
 645     if ($self->{opts}->{targetstorage} && defined($self->{online_local_volumes})) {
 646         $self->{storage_migration} = 1;
 647         $self->{storage_migration_jobs} = {};
 648         $self->log('info', "starting storage migration");
 649
 650         die "The number of local disks does not match between the source and the destination.\n"
 651             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 652         foreach my $drive (keys %{$self->{target_drive}}){
 653             my $nbd_uri = $self->{target_drive}->{$drive}->{nbd_uri};
 654             $self->log('info', "$drive: start migration to $nbd_uri");
 655             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 1);
 656         }
 657     }
 658
 659     $self->log('info', "starting online/live migration on $ruri");
 660     $self->{livemigration} = 1;
 661
 662     # load_defaults
 663     my $defaults = PVE::QemuServer::load_defaults();
 664
 665     # always set migrate speed (overwrite kvm default of 32m)
 666     # we set a very hight default of 8192m which is basically unlimited
 667     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 668     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 669     $migrate_speed = $migrate_speed * 1048576;
 670     $self->log('info', "migrate_set_speed: $migrate_speed");
 671     eval {
 672         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 673     };
 674     $self->log('info', "migrate_set_speed error: $@") if $@;
 675
 676     my $migrate_downtime = $defaults->{migrate_downtime};
 677     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 678     if (defined($migrate_downtime)) {
 679         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 680         eval {
 681             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 682         };
 683         $self->log('info', "migrate_set_downtime error: $@") if $@;
 684     }
 685
 686     $self->log('info', "set migration_caps");
 687     eval {
 688         PVE::QemuServer::set_migration_caps($vmid);
 689     };
 690     warn $@ if $@;
 691
 692     # set cachesize to 10% of the total memory
 693     my $memory =  $conf->{memory} || $defaults->{memory};
 694     my $cachesize = int($memory * 1048576 / 10);
 695     $cachesize = round_powerof2($cachesize);
 696
 697     $self->log('info', "set cachesize: $cachesize");
 698     eval {
 699         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 700     };
 701     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 702
 703     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 704         my $rpcenv = PVE::RPCEnvironment::get();
 705         my $authuser = $rpcenv->get_user();
 706
 707         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 708
 709         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 710         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 711
 712         $self->log('info', "spice client_migrate_info");
 713
 714         eval {
 715             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 716                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 717                                                 'cert-subject' => $subject);
 718         };
 719         $self->log('info', "client_migrate_info error: $@") if $@;
 720
 721     }
 722
 723     $self->log('info', "start migrate command to $ruri");
 724     eval {
 725         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 726     };
 727     my $merr = $@;
 728     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 729
 730     my $lstat = 0;
 731     my $usleep = 1000000;
 732     my $i = 0;
 733     my $err_count = 0;
 734     my $lastrem = undef;
 735     my $downtimecounter = 0;
 736     while (1) {
 737         $i++;
 738         my $avglstat = $lstat/$i if $lstat;
 739
 740         usleep($usleep);
 741         my $stat;
 742         eval {
 743             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 744         };
 745         if (my $err = $@) {
 746             $err_count++;
 747             warn "query migrate failed: $err\n";
 748             $self->log('info', "query migrate failed: $err");
 749             if ($err_count <= 5) {
 750                 usleep(1000000);
 751                 next;
 752             }
 753             die "too many query migrate failures - aborting\n";
 754         }
 755
 756         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 757             sleep(1);
 758             next;
 759         }
 760
 761         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 762             $merr = undef;
 763             $err_count = 0;
 764             if ($stat->{status} eq 'completed') {
 765                 my $delay = time() - $start;
 766                 if ($delay > 0) {
 767                     my $mbps = sprintf "%.2f", $memory / $delay;
 768                     my $downtime = $stat->{downtime} || 0;
 769                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 770                 }
 771             }
 772
 773             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 774                 $self->log('info', "migration status error: $stat->{status}");
 775                 die "aborting\n"
 776             }
 777
 778             if ($stat->{status} ne 'active') {
 779                 $self->log('info', "migration status: $stat->{status}");
 780                 last;
 781             }
 782
 783             if ($stat->{ram}->{transferred} ne $lstat) {
 784                 my $trans = $stat->{ram}->{transferred} || 0;
 785                 my $rem = $stat->{ram}->{remaining} || 0;
 786                 my $total = $stat->{ram}->{total} || 0;
 787                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 788                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 789                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 790                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 791                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 792                 # reduce sleep if remainig memory is lower than the average transfer speed
 793                 $usleep = 100000 if $avglstat && $rem < $avglstat;
 794
 795                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 796                            "remaining ${rem}), total ${total})");
 797
 798                 if (${xbzrlecachesize}) {
 799                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 800                 }
 801
 802                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 803                     $downtimecounter++;
 804                 }
 805                 $lastrem = $rem;
 806
 807                 if ($downtimecounter > 5) {
 808                     $downtimecounter = 0;
 809                     $migrate_downtime *= 2;
 810                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 811                     eval {
 812                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 813                     };
 814                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 815                 }
 816
 817             }
 818
 819
 820             $lstat = $stat->{ram}->{transferred};
 821
 822         } else {
 823             die $merr if $merr;
 824             die "unable to parse migration status '$stat->{status}' - aborting\n";
 825         }
 826     }
 827 }
 828
 829 sub phase2_cleanup {
 830     my ($self, $vmid, $err) = @_;
 831
 832     return if !$self->{errors};
 833     $self->{phase2errors} = 1;
 834
 835     $self->log('info', "aborting phase 2 - cleanup resources");
 836
 837     $self->log('info', "migrate_cancel");
 838     eval {
 839         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 840     };
 841     $self->log('info', "migrate_cancel error: $@") if $@;
 842
 843     my $conf = $self->{vmconf};
 844     delete $conf->{lock};
 845     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 846     if (my $err = $@) {
 847         $self->log('err', $err);
 848     }
 849
 850     # cleanup ressources on target host
 851     if ($self->{storage_migration}) {
 852
 853         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 854         if (my $err = $@) {
 855             $self->log('err', $err);
 856         }
 857
 858         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 859         if (my $err = $@) {
 860             $self->log('err', $err);
 861         }
 862     }
 863
 864     my $nodename = PVE::INotify::nodename();
 865
 866     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 867     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 868     if (my $err = $@) {
 869         $self->log('err', $err);
 870         $self->{errors} = 1;
 871     }
 872
 873     if ($self->{tunnel}) {
 874         eval { finish_tunnel($self, $self->{tunnel});  };
 875         if (my $err = $@) {
 876             $self->log('err', $err);
 877             $self->{errors} = 1;
 878         }
 879     }
 880 }
 881
 882 sub phase3 {
 883     my ($self, $vmid) = @_;
 884
 885     my $volids = $self->{volumes};
 886     return if $self->{phase2errors};
 887
 888     # destroy local copies
 889     foreach my $volid (@$volids) {
 890         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 891         if (my $err = $@) {
 892             $self->log('err', "removing local copy of '$volid' failed - $err");
 893             $self->{errors} = 1;
 894             last if $err =~ /^interrupted by signal$/;
 895         }
 896     }
 897 }
 898
 899 sub phase3_cleanup {
 900     my ($self, $vmid, $err) = @_;
 901
 902     my $conf = $self->{vmconf};
 903     return if $self->{phase2errors};
 904
 905     my $tunnel = $self->{tunnel};
 906
 907     if ($self->{storage_migration}) {
 908         # finish block-job
 909         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}); };
 910
 911         if (my $err = $@) {
 912             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 913             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 914             die "Failed to completed storage migration\n";
 915         } else {
 916             foreach my $target_drive (keys %{$self->{target_drive}}) {
 917                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 918                 $conf->{$target_drive} = PVE::QemuServer::print_drive($vmid, $drive);
 919                 PVE::QemuConfig->write_config($vmid, $conf);
 920             }
 921         }
 922     }
 923
 924     # transfer replication state before move config
 925     $self->transfer_replication_state() if $self->{replicated_volumes};
 926
 927     # move config to remote node
 928     my $conffile = PVE::QemuConfig->config_file($vmid);
 929     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 930
 931     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 932         if !rename($conffile, $newconffile);
 933
 934     $self->switch_replication_job_target() if $self->{replicated_volumes};
 935
 936     if ($self->{livemigration}) {
 937         if ($self->{storage_migration}) {
 938             # stop nbd server on remote vm - requirement for resume since 2.9
 939             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
 940
 941             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 942             if (my $err = $@) {
 943                 $self->log('err', $err);
 944                 $self->{errors} = 1;
 945             }
 946         }
 947
 948         # config moved and nbd server stopped - now we can resume vm on target
 949         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
 950             eval {
 951                 $self->write_tunnel($tunnel, 30, "resume $vmid");
 952             };
 953             if (my $err = $@) {
 954                 $self->log('err', $err);
 955                 $self->{errors} = 1;
 956             }
 957         } else {
 958             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 959             my $logf = sub {
 960                 my $line = shift;
 961                 $self->log('err', $line);
 962             };
 963             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
 964             if (my $err = $@) {
 965                 $self->log('err', $err);
 966                 $self->{errors} = 1;
 967             }
 968         }
 969
 970         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
 971             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
 972             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 973         }
 974     }
 975
 976     # close tunnel on successful migration, on error phase2_cleanup closed it
 977     if ($tunnel) {
 978         eval { finish_tunnel($self, $tunnel);  };
 979         if (my $err = $@) {
 980             $self->log('err', $err);
 981             $self->{errors} = 1;
 982         }
 983     }
 984
 985     eval {
 986         my $timer = 0;
 987         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
 988             $self->log('info', "Waiting for spice server migration");
 989             while (1) {
 990                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
 991                 last if int($res->{'migrated'}) == 1;
 992                 last if $timer > 50;
 993                 $timer ++;
 994                 usleep(200000);
 995             }
 996         }
 997     };
 998
 999     # always stop local VM
1000     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1001     if (my $err = $@) {
1002         $self->log('err', "stopping vm failed - $err");
1003         $self->{errors} = 1;
1004     }
1005
1006     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1007     eval {
1008         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1009         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1010     };
1011     if (my $err = $@) {
1012         $self->log('err', $err);
1013         $self->{errors} = 1;
1014     }
1015
1016     if($self->{storage_migration}) {
1017         # destroy local copies
1018         my $volids = $self->{online_local_volumes};
1019
1020         foreach my $volid (@$volids) {
1021             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1022             if (my $err = $@) {
1023                 $self->log('err', "removing local copy of '$volid' failed - $err");
1024                 $self->{errors} = 1;
1025                 last if $err =~ /^interrupted by signal$/;
1026             }
1027         }
1028
1029     }
1030
1031     # clear migrate lock
1032     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1033     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1034 }
1035
1036 sub final_cleanup {
1037     my ($self, $vmid) = @_;
1038
1039     # nothing to do
1040 }
1041
1042 sub round_powerof2 {
1043     return 1 if $_[0] < 2;
1044     return 2 << int(log($_[0]-1)/log(2));
1045 }
1046
1047 1;