PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16 use PVE::ReplicationConfig;
  17 use PVE::ReplicationState;
  18 use PVE::Replication;
  19
  20 use base qw(PVE::AbstractMigrate);
  21
  22 sub fork_command_pipe {
  23     my ($self, $cmd) = @_;
  24
  25     my $reader = IO::File->new();
  26     my $writer = IO::File->new();
  27
  28     my $orig_pid = $$;
  29
  30     my $cpid;
  31
  32     eval { $cpid = open2($reader, $writer, @$cmd); };
  33
  34     my $err = $@;
  35
  36     # catch exec errors
  37     if ($orig_pid != $$) {
  38         $self->log('err', "can't fork command pipe\n");
  39         POSIX::_exit(1);
  40         kill('KILL', $$);
  41     }
  42
  43     die $err if $err;
  44
  45     return { writer => $writer, reader => $reader, pid => $cpid };
  46 }
  47
  48 sub finish_command_pipe {
  49     my ($self, $cmdpipe, $timeout) = @_;
  50
  51     my $cpid = $cmdpipe->{pid};
  52     return if !defined($cpid);
  53
  54     my $writer = $cmdpipe->{writer};
  55     my $reader = $cmdpipe->{reader};
  56
  57     $writer->close();
  58     $reader->close();
  59
  60     my $collect_child_process = sub {
  61         my $res = waitpid($cpid, WNOHANG);
  62         if (defined($res) && ($res == $cpid)) {
  63             delete $cmdpipe->{cpid};
  64             return 1;
  65         } else {
  66             return 0;
  67         }
  68      };
  69
  70     if ($timeout) {
  71         for (my $i = 0; $i < $timeout; $i++) {
  72             return if &$collect_child_process();
  73             sleep(1);
  74         }
  75     }
  76
  77     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  78     kill(15, $cpid);
  79
  80     # wait again
  81     for (my $i = 0; $i < 10; $i++) {
  82         return if &$collect_child_process();
  83         sleep(1);
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  87     kill 9, $cpid;
  88     sleep 1;
  89
  90     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  91         if !&$collect_child_process();
  92 }
  93
  94 sub read_tunnel {
  95     my ($self, $tunnel, $timeout) = @_;
  96
  97     $timeout = 60 if !defined($timeout);
  98
  99     my $reader = $tunnel->{reader};
 100
 101     my $output;
 102     eval {
 103         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 104     };
 105     die "reading from tunnel failed: $@\n" if $@;
 106
 107     chomp $output;
 108
 109     return $output;
 110 }
 111
 112 sub write_tunnel {
 113     my ($self, $tunnel, $timeout, $command) = @_;
 114
 115     $timeout = 60 if !defined($timeout);
 116
 117     my $writer = $tunnel->{writer};
 118
 119     eval {
 120         PVE::Tools::run_with_timeout($timeout, sub {
 121             print $writer "$command\n";
 122             $writer->flush();
 123         });
 124     };
 125     die "writing to tunnel failed: $@\n" if $@;
 126
 127     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 128         my $res = eval { $self->read_tunnel($tunnel, 10); };
 129         die "no reply to command '$command': $@\n" if $@;
 130
 131         if ($res eq 'OK') {
 132             return;
 133         } else {
 134             die "tunnel replied '$res' to command '$command'\n";
 135         }
 136     }
 137 }
 138
 139 sub fork_tunnel {
 140     my ($self, $tunnel_addr) = @_;
 141
 142     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
 143
 144     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 145
 146     my $tunnel = $self->fork_command_pipe($cmd);
 147
 148     eval {
 149         my $helo = $self->read_tunnel($tunnel, 60);
 150         die "no reply\n" if !$helo;
 151         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 152         die "got strange reply from mtunnel ('$helo')\n"
 153             if $helo !~ m/^tunnel online$/;
 154     };
 155     my $err = $@;
 156
 157     eval {
 158         my $ver = $self->read_tunnel($tunnel, 10);
 159         if ($ver =~ /^ver (\d+)$/) {
 160             $tunnel->{version} = $1;
 161             $self->log('info', "ssh tunnel $ver\n");
 162         } else {
 163             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 164         }
 165     };
 166
 167     if ($err) {
 168         $self->finish_command_pipe($tunnel);
 169         die "can't open migration tunnel - $err";
 170     }
 171     return $tunnel;
 172 }
 173
 174 sub finish_tunnel {
 175     my ($self, $tunnel) = @_;
 176
 177     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 178     my $err = $@;
 179
 180     $self->finish_command_pipe($tunnel, 30);
 181
 182     if ($tunnel->{sock_addr}) {
 183         # ssh does not clean up on local host
 184         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 185         PVE::Tools::run_command($cmd);
 186
 187         # .. and just to be sure check on remote side
 188         unshift @{$cmd}, @{$self->{rem_ssh}};
 189         PVE::Tools::run_command($cmd);
 190     }
 191
 192     die $err if $err;
 193 }
 194
 195 sub lock_vm {
 196     my ($self, $vmid, $code, @param) = @_;
 197
 198     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 199 }
 200
 201 sub prepare {
 202     my ($self, $vmid) = @_;
 203
 204     my $online = $self->{opts}->{online};
 205
 206     $self->{storecfg} = PVE::Storage::config();
 207
 208     # test if VM exists
 209     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 210
 211     PVE::QemuConfig->check_lock($conf);
 212
 213     my $running = 0;
 214     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 215         die "can't migrate running VM without --online\n" if !$online;
 216         $running = $pid;
 217
 218         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 219
 220     }
 221
 222     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 223         if ($self->{running} || !$self->{opts}->{force}) {
 224             die "can't migrate VM which uses local devices\n";
 225         } else {
 226             $self->log('info', "migrating VM which uses local devices");
 227         }
 228     }
 229
 230     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 231
 232     my $need_activate = [];
 233     foreach my $volid (@$vollist) {
 234         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 235
 236         # check if storage is available on both nodes
 237         my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 238
 239         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 240         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 241
 242         if ($scfg->{shared}) {
 243             # PVE::Storage::activate_storage checks this for non-shared storages
 244             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 245             warn "Used shared storage '$sid' is not online on source node!\n"
 246                 if !$plugin->check_connection($sid, $scfg);
 247         } else {
 248             # only activate if not shared
 249             push @$need_activate, $volid;
 250         }
 251     }
 252
 253     # activate volumes
 254     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 255
 256     # test ssh connection
 257     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 258     eval { $self->cmd_quiet($cmd); };
 259     die "Can't connect to destination address using public key\n" if $@;
 260
 261     return $running;
 262 }
 263
 264 sub sync_disks {
 265     my ($self, $vmid) = @_;
 266
 267     my $conf = $self->{vmconf};
 268
 269     # local volumes which have been copied
 270     $self->{volumes} = [];
 271
 272     my $res = [];
 273
 274     eval {
 275
 276         # found local volumes and their origin
 277         my $local_volumes = {};
 278         my $local_volumes_errors = {};
 279         my $other_errors = [];
 280         my $abort = 0;
 281
 282         my $sharedvm = 1;
 283
 284         my $log_error = sub {
 285             my ($msg, $volid) = @_;
 286
 287             if (defined($volid)) {
 288                 $local_volumes_errors->{$volid} = $msg;
 289             } else {
 290                 push @$other_errors, $msg;
 291             }
 292             $abort = 1;
 293         };
 294
 295         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 296         foreach my $storeid (@sids) {
 297             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 298             next if $scfg->{shared};
 299             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 300
 301             # get list from PVE::Storage (for unused volumes)
 302             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 303
 304             next if @{$dl->{$storeid}} == 0;
 305
 306             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $storeid;
 307
 308             # check if storage is available on target node
 309             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 310             $sharedvm = 0; # there is a non-shared disk
 311
 312             PVE::Storage::foreach_volid($dl, sub {
 313                 my ($volid, $sid, $volname) = @_;
 314
 315                 $local_volumes->{$volid}->{ref} = 'storage';
 316             });
 317         }
 318
 319         my $test_volid = sub {
 320             my ($volid, $attr) = @_;
 321
 322             if ($volid =~ m|^/|) {
 323                 $local_volumes->{$volid}->{ref} = 'config';
 324                 die "local file/device\n";
 325             }
 326
 327             my $snaprefs = $attr->{referenced_in_snapshot};
 328
 329             if ($attr->{cdrom}) {
 330                 if ($volid eq 'cdrom') {
 331                     my $msg = "can't migrate local cdrom drive";
 332                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 333                         my $snapnames = join(', ', sort keys %$snaprefs);
 334                         $msg .= " (referenced in snapshot - $snapnames)";
 335                     }
 336                     &$log_error("$msg\n");
 337                     return;
 338                 }
 339                 return if $volid eq 'none';
 340             }
 341
 342             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 343
 344             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 345             # check if storage is available on both nodes
 346             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 347             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 348
 349             return if $scfg->{shared};
 350
 351             $sharedvm = 0;
 352
 353             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 354
 355             die "local cdrom image\n" if $attr->{cdrom};
 356
 357             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 358
 359             die "owned by other VM (owner = VM $owner)\n"
 360                 if !$owner || ($owner != $self->{vmid});
 361
 362             my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 363             $local_volumes->{$volid}->{snapshots} = defined($snaprefs) || ($format =~ /^(?:qcow2|vmdk)$/);
 364             if (defined($snaprefs)) {
 365                 # we cannot migrate shapshots on local storage
 366                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 367
 368                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 369                 if (!($scfg->{type} eq 'zfspool' || $format eq 'qcow2')) {
 370                     die "non-migratable snapshot exists\n";
 371                 }
 372             }
 373
 374             die "referenced by linked clone(s)\n"
 375                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 376         };
 377
 378         PVE::QemuServer::foreach_volid($conf, sub {
 379             my ($volid, $attr) = @_;
 380             eval { $test_volid->($volid, $attr); };
 381             if (my $err = $@) {
 382                 &$log_error($err, $volid);
 383             }
 384         });
 385
 386         foreach my $vol (sort keys %$local_volumes) {
 387             my $ref = $local_volumes->{$vol}->{ref};
 388             if ($ref eq 'storage') {
 389                 $self->log('info', "found local disk '$vol' (via storage)\n");
 390             } elsif ($ref eq 'config') {
 391                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 392                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 393                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 394             } elsif ($ref eq 'snapshot') {
 395                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 396             } else {
 397                 $self->log('info', "found local disk '$vol'\n");
 398             }
 399         }
 400
 401         foreach my $vol (sort keys %$local_volumes_errors) {
 402             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 403         }
 404         foreach my $err (@$other_errors) {
 405             $self->log('warn', "$err");
 406         }
 407
 408         if ($self->{running} && !$sharedvm && !$self->{opts}->{targetstorage}) {
 409             $self->{opts}->{targetstorage} = 1; #use same sid for remote local
 410         }
 411
 412         if ($abort) {
 413             die "can't migrate VM - check log\n";
 414         }
 415
 416         # additional checks for local storage
 417         foreach my $volid (keys %$local_volumes) {
 418             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 419             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 420
 421             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 422                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 423
 424             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 425                 if !$migratable;
 426
 427             # image is a linked clone on local storage, se we can't migrate.
 428             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 429                 die "can't migrate '$volid' as it's a clone of '$basename'";
 430             }
 431         }
 432
 433         my $rep_volumes;
 434
 435         $self->log('info', "copying disk images");
 436
 437         my $rep_cfg = PVE::ReplicationConfig->new();
 438
 439         if (my $jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node})) {
 440             die "can't live migrate VM with replicated volumes\n" if $self->{running};
 441             my $start_time = time();
 442             my $logfunc = sub { my ($msg) = @_;  $self->log('info', $msg); };
 443             $rep_volumes = PVE::Replication::run_replication(
 444                'PVE::QemuConfig', $jobcfg, $start_time, $start_time, $logfunc);
 445         }
 446
 447         foreach my $volid (keys %$local_volumes) {
 448             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 449             if ($self->{running} && $self->{opts}->{targetstorage} && $local_volumes->{$volid}->{ref} eq 'config') {
 450                 push @{$self->{online_local_volumes}}, $volid;
 451             } else {
 452                 next if $rep_volumes->{$volid};
 453                 push @{$self->{volumes}}, $volid;
 454                 my $insecure = $self->{opts}->{migration_type} eq 'insecure';
 455                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 456                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{ssh_info}, $sid,
 457                                               undef, undef, undef, undef, $insecure, $with_snapshots);
 458             }
 459         }
 460     };
 461     die "Failed to sync data - $@" if $@;
 462 }
 463
 464 sub cleanup_remotedisks {
 465     my ($self) = @_;
 466
 467     foreach my $target_drive (keys %{$self->{target_drive}}) {
 468
 469         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 470         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 471
 472         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 473
 474         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 475         if (my $err = $@) {
 476             $self->log('err', $err);
 477             $self->{errors} = 1;
 478         }
 479     }
 480 }
 481
 482 sub phase1 {
 483     my ($self, $vmid) = @_;
 484
 485     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 486
 487     my $conf = $self->{vmconf};
 488
 489     # set migrate lock in config file
 490     $conf->{lock} = 'migrate';
 491     PVE::QemuConfig->write_config($vmid, $conf);
 492
 493     sync_disks($self, $vmid);
 494
 495 };
 496
 497 sub phase1_cleanup {
 498     my ($self, $vmid, $err) = @_;
 499
 500     $self->log('info', "aborting phase 1 - cleanup resources");
 501
 502     my $conf = $self->{vmconf};
 503     delete $conf->{lock};
 504     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 505     if (my $err = $@) {
 506         $self->log('err', $err);
 507     }
 508
 509     if ($self->{volumes}) {
 510         foreach my $volid (@{$self->{volumes}}) {
 511             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 512             # fixme: try to remove ?
 513         }
 514     }
 515 }
 516
 517 sub phase2 {
 518     my ($self, $vmid) = @_;
 519
 520     my $conf = $self->{vmconf};
 521
 522     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 523
 524     my $raddr;
 525     my $rport;
 526     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 527     my $nodename = PVE::INotify::nodename();
 528
 529     ## start on remote node
 530     my $cmd = [@{$self->{rem_ssh}}];
 531
 532     my $spice_ticket;
 533     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 534         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 535         $spice_ticket = $res->{ticket};
 536     }
 537
 538     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 539
 540     my $migration_type = $self->{opts}->{migration_type};
 541
 542     push @$cmd, '--migration_type', $migration_type;
 543
 544     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 545       if $self->{opts}->{migration_network};
 546
 547     if ($migration_type eq 'insecure') {
 548         push @$cmd, '--stateuri', 'tcp';
 549     } else {
 550         push @$cmd, '--stateuri', 'unix';
 551     }
 552
 553     if ($self->{forcemachine}) {
 554         push @$cmd, '--machine', $self->{forcemachine};
 555     }
 556
 557     if ($self->{opts}->{targetstorage}) {
 558         push @$cmd, '--targetstorage', $self->{opts}->{targetstorage};
 559     }
 560
 561     my $spice_port;
 562
 563     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 564     # instead we pipe it through STDIN
 565     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 566         my $line = shift;
 567
 568         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 569             $raddr = $1;
 570             $rport = int($2);
 571             $ruri = "tcp:$raddr:$rport";
 572         }
 573         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 574             $raddr = $1;
 575             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 576             $ruri = "unix:$raddr";
 577         }
 578         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 579             $raddr = "localhost";
 580             $rport = int($1);
 581             $ruri = "tcp:$raddr:$rport";
 582         }
 583         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 584             $spice_port = int($1);
 585         }
 586         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 587             my $volid = $4;
 588             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 589             my $targetdrive = $3;
 590             $targetdrive =~ s/drive-//g;
 591
 592             $self->{target_drive}->{$targetdrive}->{volid} = $volid;
 593             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 594
 595         }
 596     }, errfunc => sub {
 597         my $line = shift;
 598         $self->log('info', $line);
 599     });
 600
 601     die "unable to detect remote migration address\n" if !$raddr;
 602
 603     if ($migration_type eq 'secure') {
 604         $self->log('info', "start remote tunnel");
 605
 606         if ($ruri =~ /^unix:/) {
 607             unlink $raddr;
 608             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 609             $self->{tunnel}->{sock_addr} = $raddr;
 610
 611             my $unix_socket_try = 0; # wait for the socket to become ready
 612             while (! -S $raddr) {
 613                 $unix_socket_try++;
 614                 if ($unix_socket_try > 100) {
 615                     $self->{errors} = 1;
 616                     $self->finish_tunnel($self->{tunnel});
 617                     die "Timeout, migration socket $ruri did not get ready";
 618                 }
 619
 620                 usleep(50000);
 621             }
 622
 623         } elsif ($ruri =~ /^tcp:/) {
 624             my $tunnel_addr;
 625             if ($raddr eq "localhost") {
 626                 # for backwards compatibility with older qemu-server versions
 627                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 628                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 629                 $tunnel_addr = "$lport:localhost:$rport";
 630             }
 631
 632             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 633
 634         } else {
 635             die "unsupported protocol in migration URI: $ruri\n";
 636         }
 637     }
 638
 639     my $start = time();
 640
 641     if ($self->{opts}->{targetstorage} && defined($self->{online_local_volumes})) {
 642         $self->{storage_migration} = 1;
 643         $self->{storage_migration_jobs} = {};
 644         $self->log('info', "starting storage migration");
 645
 646         die "The number of local disks does not match between the source and the destination.\n"
 647             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 648         foreach my $drive (keys %{$self->{target_drive}}){
 649             my $nbd_uri = $self->{target_drive}->{$drive}->{nbd_uri};
 650             $self->log('info', "$drive: start migration to to $nbd_uri");
 651             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 1);
 652         }
 653     }
 654
 655     $self->log('info', "starting online/live migration on $ruri");
 656     $self->{livemigration} = 1;
 657
 658     # load_defaults
 659     my $defaults = PVE::QemuServer::load_defaults();
 660
 661     # always set migrate speed (overwrite kvm default of 32m)
 662     # we set a very hight default of 8192m which is basically unlimited
 663     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 664     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 665     $migrate_speed = $migrate_speed * 1048576;
 666     $self->log('info', "migrate_set_speed: $migrate_speed");
 667     eval {
 668         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 669     };
 670     $self->log('info', "migrate_set_speed error: $@") if $@;
 671
 672     my $migrate_downtime = $defaults->{migrate_downtime};
 673     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 674     if (defined($migrate_downtime)) {
 675         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 676         eval {
 677             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 678         };
 679         $self->log('info', "migrate_set_downtime error: $@") if $@;
 680     }
 681
 682     $self->log('info', "set migration_caps");
 683     eval {
 684         PVE::QemuServer::set_migration_caps($vmid);
 685     };
 686     warn $@ if $@;
 687
 688     # set cachesize to 10% of the total memory
 689     my $memory =  $conf->{memory} || $defaults->{memory};
 690     my $cachesize = int($memory * 1048576 / 10);
 691     $self->log('info', "set cachesize: $cachesize");
 692     eval {
 693         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 694     };
 695     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 696
 697     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 698         my $rpcenv = PVE::RPCEnvironment::get();
 699         my $authuser = $rpcenv->get_user();
 700
 701         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 702
 703         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 704         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 705
 706         $self->log('info', "spice client_migrate_info");
 707
 708         eval {
 709             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 710                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 711                                                 'cert-subject' => $subject);
 712         };
 713         $self->log('info', "client_migrate_info error: $@") if $@;
 714
 715     }
 716
 717     $self->log('info', "start migrate command to $ruri");
 718     eval {
 719         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 720     };
 721     my $merr = $@;
 722     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 723
 724     my $lstat = 0;
 725     my $usleep = 2000000;
 726     my $i = 0;
 727     my $err_count = 0;
 728     my $lastrem = undef;
 729     my $downtimecounter = 0;
 730     while (1) {
 731         $i++;
 732         my $avglstat = $lstat/$i if $lstat;
 733
 734         usleep($usleep);
 735         my $stat;
 736         eval {
 737             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 738         };
 739         if (my $err = $@) {
 740             $err_count++;
 741             warn "query migrate failed: $err\n";
 742             $self->log('info', "query migrate failed: $err");
 743             if ($err_count <= 5) {
 744                 usleep(1000000);
 745                 next;
 746             }
 747             die "too many query migrate failures - aborting\n";
 748         }
 749
 750         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 751             sleep(1);
 752             next;
 753         }
 754
 755         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 756             $merr = undef;
 757             $err_count = 0;
 758             if ($stat->{status} eq 'completed') {
 759                 my $delay = time() - $start;
 760                 if ($delay > 0) {
 761                     my $mbps = sprintf "%.2f", $memory / $delay;
 762                     my $downtime = $stat->{downtime} || 0;
 763                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 764                 }
 765             }
 766
 767             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 768                 $self->log('info', "migration status error: $stat->{status}");
 769                 die "aborting\n"
 770             }
 771
 772             if ($stat->{status} ne 'active') {
 773                 $self->log('info', "migration status: $stat->{status}");
 774                 last;
 775             }
 776
 777             if ($stat->{ram}->{transferred} ne $lstat) {
 778                 my $trans = $stat->{ram}->{transferred} || 0;
 779                 my $rem = $stat->{ram}->{remaining} || 0;
 780                 my $total = $stat->{ram}->{total} || 0;
 781                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 782                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 783                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 784                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 785                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 786                 #reduce sleep if remainig memory if lower than the everage transfert
 787                 $usleep = 300000 if $avglstat && $rem < $avglstat;
 788
 789                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 790                            "remaining ${rem}), total ${total})");
 791
 792                 if (${xbzrlecachesize}) {
 793                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 794                 }
 795
 796                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 797                     $downtimecounter++;
 798                 }
 799                 $lastrem = $rem;
 800
 801                 if ($downtimecounter > 5) {
 802                     $downtimecounter = 0;
 803                     $migrate_downtime *= 2;
 804                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 805                     eval {
 806                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 807                     };
 808                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 809                 }
 810
 811             }
 812
 813
 814             $lstat = $stat->{ram}->{transferred};
 815
 816         } else {
 817             die $merr if $merr;
 818             die "unable to parse migration status '$stat->{status}' - aborting\n";
 819         }
 820     }
 821
 822     # just to be sure that the tunnel gets closed on successful migration, on error
 823     # phase2_cleanup closes it *after* stopping the remote waiting VM
 824     if (!$self->{errors} && $self->{tunnel}) {
 825         eval { finish_tunnel($self, $self->{tunnel});  };
 826         if (my $err = $@) {
 827             $self->log('err', $err);
 828             $self->{errors} = 1;
 829         }
 830     }
 831 }
 832
 833 sub phase2_cleanup {
 834     my ($self, $vmid, $err) = @_;
 835
 836     return if !$self->{errors};
 837     $self->{phase2errors} = 1;
 838
 839     $self->log('info', "aborting phase 2 - cleanup resources");
 840
 841     $self->log('info', "migrate_cancel");
 842     eval {
 843         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 844     };
 845     $self->log('info', "migrate_cancel error: $@") if $@;
 846
 847     my $conf = $self->{vmconf};
 848     delete $conf->{lock};
 849     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 850     if (my $err = $@) {
 851         $self->log('err', $err);
 852     }
 853
 854     # cleanup ressources on target host
 855     if ($self->{storage_migration}) {
 856
 857         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 858         if (my $err = $@) {
 859             $self->log('err', $err);
 860         }
 861
 862         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 863         if (my $err = $@) {
 864             $self->log('err', $err);
 865         }
 866     }
 867
 868     my $nodename = PVE::INotify::nodename();
 869
 870     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 871     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 872     if (my $err = $@) {
 873         $self->log('err', $err);
 874         $self->{errors} = 1;
 875     }
 876
 877     if ($self->{tunnel}) {
 878         eval { finish_tunnel($self, $self->{tunnel});  };
 879         if (my $err = $@) {
 880             $self->log('err', $err);
 881             $self->{errors} = 1;
 882         }
 883     }
 884 }
 885
 886 sub phase3 {
 887     my ($self, $vmid) = @_;
 888
 889     my $volids = $self->{volumes};
 890     return if $self->{phase2errors};
 891
 892     # destroy local copies
 893     foreach my $volid (@$volids) {
 894         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 895         if (my $err = $@) {
 896             $self->log('err', "removing local copy of '$volid' failed - $err");
 897             $self->{errors} = 1;
 898             last if $err =~ /^interrupted by signal$/;
 899         }
 900     }
 901 }
 902
 903 sub phase3_cleanup {
 904     my ($self, $vmid, $err) = @_;
 905
 906     my $conf = $self->{vmconf};
 907     return if $self->{phase2errors};
 908
 909     my $tunnel = $self->{tunnel};
 910
 911     if ($self->{storage_migration}) {
 912         # finish block-job
 913         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}); };
 914
 915         if (my $err = $@) {
 916             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 917             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 918             die "Failed to completed storage migration\n";
 919         } else {
 920             foreach my $target_drive (keys %{$self->{target_drive}}) {
 921                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 922                 $conf->{$target_drive} = PVE::QemuServer::print_drive($vmid, $drive);
 923                 PVE::QemuConfig->write_config($vmid, $conf);
 924             }
 925         }
 926     }
 927
 928     # transfer replication state before move config
 929     $self->transfer_replication_state();
 930
 931     # move config to remote node
 932     my $conffile = PVE::QemuConfig->config_file($vmid);
 933     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 934
 935     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 936         if !rename($conffile, $newconffile);
 937
 938     $self->switch_replication_job_target();
 939
 940     if ($self->{livemigration}) {
 941         if ($self->{storage_migration}) {
 942             # remove drives referencing the nbd server from source
 943             # otherwise vm_stop might hang later on
 944             foreach my $drive (keys %{$self->{target_drive}}){
 945                 PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "device_del", id => $drive);
 946             }
 947             # stop nbd server on remote vm - requirement for resume since 2.9
 948             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
 949
 950             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 951             if (my $err = $@) {
 952                 $self->log('err', $err);
 953                 $self->{errors} = 1;
 954             }
 955         }
 956
 957         # config moved and nbd server stopped - now we can resume vm on target
 958         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
 959             eval {
 960                 $self->write_tunnel($tunnel, 30, "resume $vmid");
 961             };
 962             if (my $err = $@) {
 963                 $self->log('err', $err);
 964                 $self->{errors} = 1;
 965             }
 966         } else {
 967             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 968             my $logf = sub {
 969                 my $line = shift;
 970                 $self->log('err', $line);
 971             };
 972             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
 973             if (my $err = $@) {
 974                 $self->log('err', $err);
 975                 $self->{errors} = 1;
 976             }
 977         }
 978     }
 979
 980     eval {
 981         my $timer = 0;
 982         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
 983             $self->log('info', "Waiting for spice server migration");
 984             while (1) {
 985                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
 986                 last if int($res->{'migrated'}) == 1;
 987                 last if $timer > 50;
 988                 $timer ++;
 989                 usleep(200000);
 990             }
 991         }
 992     };
 993
 994     # always stop local VM
 995     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 996     if (my $err = $@) {
 997         $self->log('err', "stopping vm failed - $err");
 998         $self->{errors} = 1;
 999     }
1000
1001     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1002     eval {
1003         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1004         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1005     };
1006     if (my $err = $@) {
1007         $self->log('err', $err);
1008         $self->{errors} = 1;
1009     }
1010
1011     if($self->{storage_migration}) {
1012         # destroy local copies
1013         my $volids = $self->{online_local_volumes};
1014
1015         foreach my $volid (@$volids) {
1016             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1017             if (my $err = $@) {
1018                 $self->log('err', "removing local copy of '$volid' failed - $err");
1019                 $self->{errors} = 1;
1020                 last if $err =~ /^interrupted by signal$/;
1021             }
1022         }
1023
1024     }
1025
1026     # clear migrate lock
1027     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1028     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1029 }
1030
1031 sub final_cleanup {
1032     my ($self, $vmid) = @_;
1033
1034     # nothing to do
1035 }
1036
1037 1;