PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16
  17 use base qw(PVE::AbstractMigrate);
  18
  19 sub fork_command_pipe {
  20     my ($self, $cmd) = @_;
  21
  22     my $reader = IO::File->new();
  23     my $writer = IO::File->new();
  24
  25     my $orig_pid = $$;
  26
  27     my $cpid;
  28
  29     eval { $cpid = open2($reader, $writer, @$cmd); };
  30
  31     my $err = $@;
  32
  33     # catch exec errors
  34     if ($orig_pid != $$) {
  35         $self->log('err', "can't fork command pipe\n");
  36         POSIX::_exit(1);
  37         kill('KILL', $$);
  38     }
  39
  40     die $err if $err;
  41
  42     return { writer => $writer, reader => $reader, pid => $cpid };
  43 }
  44
  45 sub finish_command_pipe {
  46     my ($self, $cmdpipe, $timeout) = @_;
  47
  48     my $cpid = $cmdpipe->{pid};
  49     return if !defined($cpid);
  50
  51     my $writer = $cmdpipe->{writer};
  52     my $reader = $cmdpipe->{reader};
  53
  54     $writer->close();
  55     $reader->close();
  56
  57     my $collect_child_process = sub {
  58         my $res = waitpid($cpid, WNOHANG);
  59         if (defined($res) && ($res == $cpid)) {
  60             delete $cmdpipe->{cpid};
  61             return 1;
  62         } else {
  63             return 0;
  64         }
  65      };
  66
  67     if ($timeout) {
  68         for (my $i = 0; $i < $timeout; $i++) {
  69             return if &$collect_child_process();
  70             sleep(1);
  71         }
  72     }
  73
  74     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  75     kill(15, $cpid);
  76
  77     # wait again
  78     for (my $i = 0; $i < 10; $i++) {
  79         return if &$collect_child_process();
  80         sleep(1);
  81     }
  82
  83     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  84     kill 9, $cpid;
  85     sleep 1;
  86
  87     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  88         if !&$collect_child_process();
  89 }
  90
  91 sub fork_tunnel {
  92     my ($self, $tunnel_addr) = @_;
  93
  94     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
  95
  96     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, 'qm', 'mtunnel' ];
  97
  98     my $tunnel = $self->fork_command_pipe($cmd);
  99
 100     my $reader = $tunnel->{reader};
 101
 102     my $helo;
 103     eval {
 104         PVE::Tools::run_with_timeout(60, sub { $helo = <$reader>; });
 105         die "no reply\n" if !$helo;
 106         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 107         die "got strange reply from mtunnel ('$helo')\n"
 108             if $helo !~ m/^tunnel online$/;
 109     };
 110     my $err = $@;
 111
 112     if ($err) {
 113         $self->finish_command_pipe($tunnel);
 114         die "can't open migration tunnel - $err";
 115     }
 116     return $tunnel;
 117 }
 118
 119 sub finish_tunnel {
 120     my ($self, $tunnel) = @_;
 121
 122     my $writer = $tunnel->{writer};
 123
 124     eval {
 125         PVE::Tools::run_with_timeout(30, sub {
 126             print $writer "quit\n";
 127             $writer->flush();
 128         });
 129     };
 130     my $err = $@;
 131
 132     $self->finish_command_pipe($tunnel, 30);
 133
 134     if ($tunnel->{sock_addr}) {
 135         # ssh does not clean up on local host
 136         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 137         PVE::Tools::run_command($cmd);
 138
 139         # .. and just to be sure check on remote side
 140         unshift @{$cmd}, @{$self->{rem_ssh}};
 141         PVE::Tools::run_command($cmd);
 142     }
 143
 144     die $err if $err;
 145 }
 146
 147 sub lock_vm {
 148     my ($self, $vmid, $code, @param) = @_;
 149
 150     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 151 }
 152
 153 sub prepare {
 154     my ($self, $vmid) = @_;
 155
 156     my $online = $self->{opts}->{online};
 157
 158     $self->{storecfg} = PVE::Storage::config();
 159
 160     # test if VM exists
 161     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 162
 163     PVE::QemuConfig->check_lock($conf);
 164
 165     my $running = 0;
 166     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 167         die "can't migrate running VM without --online\n" if !$online;
 168         $running = $pid;
 169
 170         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 171
 172     }
 173
 174     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 175         if ($self->{running} || !$self->{opts}->{force}) {
 176             die "can't migrate VM which uses local devices\n";
 177         } else {
 178             $self->log('info', "migrating VM which uses local devices");
 179         }
 180     }
 181
 182     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 183
 184     my $need_activate = [];
 185     foreach my $volid (@$vollist) {
 186         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 187
 188         # check if storage is available on both nodes
 189         my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 190
 191         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 192         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 193
 194         if ($scfg->{shared}) {
 195             # PVE::Storage::activate_storage checks this for non-shared storages
 196             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 197             warn "Used shared storage '$sid' is not online on source node!\n"
 198                 if !$plugin->check_connection($sid, $scfg);
 199         } else {
 200             # only activate if not shared
 201             push @$need_activate, $volid;
 202         }
 203     }
 204
 205     # activate volumes
 206     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 207
 208     # test ssh connection
 209     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 210     eval { $self->cmd_quiet($cmd); };
 211     die "Can't connect to destination address using public key\n" if $@;
 212
 213     return $running;
 214 }
 215
 216 sub sync_disks {
 217     my ($self, $vmid) = @_;
 218
 219     my $conf = $self->{vmconf};
 220
 221     # local volumes which have been copied
 222     $self->{volumes} = [];
 223
 224     my $res = [];
 225
 226     eval {
 227
 228         # found local volumes and their origin
 229         my $local_volumes = {};
 230         my $local_volumes_errors = {};
 231         my $other_errors = [];
 232         my $abort = 0;
 233
 234         my $sharedvm = 1;
 235
 236         my $log_error = sub {
 237             my ($msg, $volid) = @_;
 238
 239             if (defined($volid)) {
 240                 $local_volumes_errors->{$volid} = $msg;
 241             } else {
 242                 push @$other_errors, $msg;
 243             }
 244             $abort = 1;
 245         };
 246
 247         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 248         foreach my $storeid (@sids) {
 249             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 250             next if $scfg->{shared};
 251             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 252
 253             # get list from PVE::Storage (for unused volumes)
 254             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 255
 256             next if @{$dl->{$storeid}} == 0;
 257
 258             # check if storage is available on target node
 259             PVE::Storage::storage_check_node($self->{storecfg}, $storeid, $self->{node});
 260             $sharedvm = 0; # there is a non-shared disk
 261
 262             PVE::Storage::foreach_volid($dl, sub {
 263                 my ($volid, $sid, $volname) = @_;
 264
 265                 $local_volumes->{$volid} = 'storage';
 266             });
 267         }
 268
 269         my $test_volid = sub {
 270             my ($volid, $is_cdrom, $snapname) = @_;
 271
 272             return if !$volid;
 273
 274             if ($volid =~ m|^/|) {
 275                 $local_volumes->{$volid} = 'config';
 276                 die "local file/device\n";
 277             }
 278
 279             if ($is_cdrom) {
 280                 if ($volid eq 'cdrom') {
 281                     my $msg = "can't migrate local cdrom drive";
 282                     $msg .= " (referenced in snapshot '$snapname')"
 283                         if defined($snapname);
 284
 285                     &$log_error("$msg\n");
 286                     return;
 287                 }
 288                 return if $volid eq 'none';
 289             }
 290
 291             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 292
 293             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 294             # check if storage is available on both nodes
 295             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 296             PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 297
 298             return if $scfg->{shared};
 299
 300             $sharedvm = 0;
 301
 302             $local_volumes->{$volid} = defined($snapname) ? 'snapshot' : 'config';
 303
 304             die "local cdrom image\n" if $is_cdrom;
 305
 306             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 307
 308             die "owned by other VM (owner = VM $owner)\n"
 309                 if !$owner || ($owner != $self->{vmid});
 310
 311             if (defined($snapname)) {
 312                 # we cannot migrate shapshots on local storage
 313                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 314
 315                 my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 316                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 317                 if (!($scfg->{type} eq 'zfspool' || $format eq 'qcow2')) {
 318                     die "non-migratable snapshot exists\n";
 319                 }
 320             }
 321
 322             die "referenced by linked clone(s)\n"
 323                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 324         };
 325
 326         my $test_drive = sub {
 327             my ($ds, $drive, $snapname) = @_;
 328
 329             eval {
 330                 &$test_volid($drive->{file}, PVE::QemuServer::drive_is_cdrom($drive), $snapname);
 331             };
 332
 333             &$log_error($@, $drive->{file}) if $@;
 334         };
 335
 336         foreach my $snapname (keys %{$conf->{snapshots}}) {
 337             eval {
 338                 &$test_volid($conf->{snapshots}->{$snapname}->{'vmstate'}, 0, undef)
 339                     if defined($conf->{snapshots}->{$snapname}->{'vmstate'});
 340             };
 341             &$log_error($@, $conf->{snapshots}->{$snapname}->{'vmstate'}) if $@;
 342
 343             PVE::QemuServer::foreach_drive($conf->{snapshots}->{$snapname}, $test_drive, $snapname);
 344         }
 345         PVE::QemuServer::foreach_drive($conf, $test_drive);
 346
 347         foreach my $vol (sort keys %$local_volumes) {
 348             if ($local_volumes->{$vol} eq 'storage') {
 349                 $self->log('info', "found local disk '$vol' (via storage)\n");
 350             } elsif ($local_volumes->{$vol} eq 'config') {
 351                 die "can't live migrate attached local disks without with-local-disks option\n" if $self->{running} && !$self->{opts}->{"with-local-disks"};
 352                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 353             } elsif ($local_volumes->{$vol} eq 'snapshot') {
 354                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 355             } else {
 356                 $self->log('info', "found local disk '$vol'\n");
 357             }
 358         }
 359
 360         foreach my $vol (sort keys %$local_volumes_errors) {
 361             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 362         }
 363         foreach my $err (@$other_errors) {
 364             $self->log('warn', "$err");
 365         }
 366
 367         if ($self->{running} && !$sharedvm && !$self->{opts}->{targetstorage}) {
 368             $self->{opts}->{targetstorage} = 1; #use same sid for remote local
 369         }
 370
 371         if ($abort) {
 372             die "can't migrate VM - check log\n";
 373         }
 374
 375         # additional checks for local storage
 376         foreach my $volid (keys %$local_volumes) {
 377             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 378             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 379
 380             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 381                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 382
 383             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 384                 if !$migratable;
 385
 386             # image is a linked clone on local storage, se we can't migrate.
 387             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 388                 die "can't migrate '$volid' as it's a clone of '$basename'";
 389             }
 390         }
 391
 392         $self->log('info', "copying disk images");
 393
 394         foreach my $volid (keys %$local_volumes) {
 395             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 396             if ($self->{running} && $self->{opts}->{targetstorage} && $local_volumes->{$volid} eq 'config') {
 397                 push @{$self->{online_local_volumes}}, $volid;
 398             } else {
 399                 push @{$self->{volumes}}, $volid;
 400                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{nodeip}, $sid);
 401             }
 402         }
 403     };
 404     die "Failed to sync data - $@" if $@;
 405 }
 406
 407 sub cleanup_remotedisks {
 408     my ($self) = @_;
 409
 410     foreach my $target_drive (keys %{$self->{target_drive}}) {
 411
 412         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 413         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 414
 415         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 416
 417         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 418         if (my $err = $@) {
 419             $self->log('err', $err);
 420             $self->{errors} = 1;
 421         }
 422     }
 423 }
 424
 425 sub phase1 {
 426     my ($self, $vmid) = @_;
 427
 428     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 429
 430     my $conf = $self->{vmconf};
 431
 432     # set migrate lock in config file
 433     $conf->{lock} = 'migrate';
 434     PVE::QemuConfig->write_config($vmid, $conf);
 435
 436     sync_disks($self, $vmid);
 437
 438 };
 439
 440 sub phase1_cleanup {
 441     my ($self, $vmid, $err) = @_;
 442
 443     $self->log('info', "aborting phase 1 - cleanup resources");
 444
 445     my $conf = $self->{vmconf};
 446     delete $conf->{lock};
 447     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 448     if (my $err = $@) {
 449         $self->log('err', $err);
 450     }
 451
 452     if ($self->{volumes}) {
 453         foreach my $volid (@{$self->{volumes}}) {
 454             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 455             # fixme: try to remove ?
 456         }
 457     }
 458 }
 459
 460 sub phase2 {
 461     my ($self, $vmid) = @_;
 462
 463     my $conf = $self->{vmconf};
 464
 465     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 466
 467     my $raddr;
 468     my $rport;
 469     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 470     my $nodename = PVE::INotify::nodename();
 471
 472     ## start on remote node
 473     my $cmd = [@{$self->{rem_ssh}}];
 474
 475     my $spice_ticket;
 476     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 477         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 478         $spice_ticket = $res->{ticket};
 479     }
 480
 481     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 482
 483     # we use TCP only for unsecure migrations as TCP ssh forward tunnels often
 484     # did appeared to late (they are hard, if not impossible, to check for)
 485     # secure migration use UNIX sockets now, this *breaks* compatibilty when trying
 486     # to migrate from new to old but *not* from old to new.
 487     my $datacenterconf = PVE::Cluster::cfs_read_file('datacenter.cfg');
 488
 489     my $migration_type = 'secure';
 490     if (defined($self->{opts}->{migration_type})) {
 491         $migration_type = $self->{opts}->{migration_type};
 492     } elsif (defined($datacenterconf->{migration}->{type})) {
 493         $migration_type = $datacenterconf->{migration}->{type};
 494     }
 495
 496     push @$cmd, '--migration_type', $migration_type;
 497
 498     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 499       if $self->{opts}->{migration_network};
 500
 501     if ($migration_type eq 'insecure') {
 502         push @$cmd, '--stateuri', 'tcp';
 503     } else {
 504         push @$cmd, '--stateuri', 'unix';
 505     }
 506
 507     if ($self->{forcemachine}) {
 508         push @$cmd, '--machine', $self->{forcemachine};
 509     }
 510
 511     if ($self->{opts}->{targetstorage}) {
 512         push @$cmd, '--targetstorage', $self->{opts}->{targetstorage};
 513     }
 514
 515     my $spice_port;
 516
 517     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 518     # instead we pipe it through STDIN
 519     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 520         my $line = shift;
 521
 522         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 523             $raddr = $1;
 524             $rport = int($2);
 525             $ruri = "tcp:$raddr:$rport";
 526         }
 527         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 528             $raddr = $1;
 529             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 530             $ruri = "unix:$raddr";
 531         }
 532         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 533             $raddr = "localhost";
 534             $rport = int($1);
 535             $ruri = "tcp:$raddr:$rport";
 536         }
 537         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 538             $spice_port = int($1);
 539         }
 540         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 541             my $volid = $4;
 542             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 543             my $targetdrive = $3;
 544             $targetdrive =~ s/drive-//g;
 545
 546             $self->{target_drive}->{$targetdrive}->{volid} = $volid;
 547             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 548
 549         }
 550     }, errfunc => sub {
 551         my $line = shift;
 552         $self->log('info', $line);
 553     });
 554
 555     die "unable to detect remote migration address\n" if !$raddr;
 556
 557     if ($migration_type eq 'secure') {
 558         $self->log('info', "start remote tunnel");
 559
 560         if ($ruri =~ /^unix:/) {
 561             unlink $raddr;
 562             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 563             $self->{tunnel}->{sock_addr} = $raddr;
 564
 565             my $unix_socket_try = 0; # wait for the socket to become ready
 566             while (! -S $raddr) {
 567                 $unix_socket_try++;
 568                 if ($unix_socket_try > 100) {
 569                     $self->{errors} = 1;
 570                     $self->finish_tunnel($self->{tunnel});
 571                     die "Timeout, migration socket $ruri did not get ready";
 572                 }
 573
 574                 usleep(50000);
 575             }
 576
 577         } elsif ($ruri =~ /^tcp:/) {
 578             my $tunnel_addr;
 579             if ($raddr eq "localhost") {
 580                 # for backwards compatibility with older qemu-server versions
 581                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 582                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 583                 $tunnel_addr = "$lport:localhost:$rport";
 584             }
 585
 586             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 587
 588         } else {
 589             die "unsupported protocol in migration URI: $ruri\n";
 590         }
 591     }
 592
 593     my $start = time();
 594
 595     if ($self->{opts}->{targetstorage}) {
 596         $self->{storage_migration} = 1;
 597         $self->{storage_migration_jobs} = {};
 598         $self->log('info', "starting storage migration");
 599
 600         die "The number of local disks does not match between the source and the destination.\n"
 601             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 602         foreach my $drive (keys %{$self->{target_drive}}){
 603             my $nbd_uri = $self->{target_drive}->{$drive}->{nbd_uri};
 604             $self->log('info', "$drive: start migration to to $nbd_uri");
 605             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 1);
 606         }
 607     }
 608
 609     $self->log('info', "starting online/live migration on $ruri");
 610     $self->{livemigration} = 1;
 611
 612     # load_defaults
 613     my $defaults = PVE::QemuServer::load_defaults();
 614
 615     # always set migrate speed (overwrite kvm default of 32m)
 616     # we set a very hight default of 8192m which is basically unlimited
 617     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 618     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 619     $migrate_speed = $migrate_speed * 1048576;
 620     $self->log('info', "migrate_set_speed: $migrate_speed");
 621     eval {
 622         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 623     };
 624     $self->log('info', "migrate_set_speed error: $@") if $@;
 625
 626     my $migrate_downtime = $defaults->{migrate_downtime};
 627     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 628     if (defined($migrate_downtime)) {
 629         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 630         eval {
 631             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 632         };
 633         $self->log('info', "migrate_set_downtime error: $@") if $@;
 634     }
 635
 636     $self->log('info', "set migration_caps");
 637     eval {
 638         PVE::QemuServer::set_migration_caps($vmid);
 639     };
 640     warn $@ if $@;
 641
 642     #set cachesize 10% of the total memory
 643     my $cachesize = int($conf->{memory}*1048576/10);
 644     $self->log('info', "set cachesize: $cachesize");
 645     eval {
 646         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 647     };
 648     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 649
 650     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 651         my $rpcenv = PVE::RPCEnvironment::get();
 652         my $authuser = $rpcenv->get_user();
 653
 654         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 655
 656         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 657         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 658
 659         $self->log('info', "spice client_migrate_info");
 660
 661         eval {
 662             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 663                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 664                                                 'cert-subject' => $subject);
 665         };
 666         $self->log('info', "client_migrate_info error: $@") if $@;
 667
 668     }
 669
 670     $self->log('info', "start migrate command to $ruri");
 671     eval {
 672         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 673     };
 674     my $merr = $@;
 675     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 676
 677     my $lstat = 0;
 678     my $usleep = 2000000;
 679     my $i = 0;
 680     my $err_count = 0;
 681     my $lastrem = undef;
 682     my $downtimecounter = 0;
 683     while (1) {
 684         $i++;
 685         my $avglstat = $lstat/$i if $lstat;
 686
 687         usleep($usleep);
 688         my $stat;
 689         eval {
 690             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 691         };
 692         if (my $err = $@) {
 693             $err_count++;
 694             warn "query migrate failed: $err\n";
 695             $self->log('info', "query migrate failed: $err");
 696             if ($err_count <= 5) {
 697                 usleep(1000000);
 698                 next;
 699             }
 700             die "too many query migrate failures - aborting\n";
 701         }
 702
 703         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 704             sleep(1);
 705             next;
 706         }
 707
 708         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 709             $merr = undef;
 710             $err_count = 0;
 711             if ($stat->{status} eq 'completed') {
 712                 my $delay = time() - $start;
 713                 if ($delay > 0) {
 714                     my $mbps = sprintf "%.2f", $conf->{memory}/$delay;
 715                     my $downtime = $stat->{downtime} || 0;
 716                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 717                 }
 718             }
 719
 720             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 721                 $self->log('info', "migration status error: $stat->{status}");
 722                 die "aborting\n"
 723             }
 724
 725             if ($stat->{status} ne 'active') {
 726                 $self->log('info', "migration status: $stat->{status}");
 727                 last;
 728             }
 729
 730             if ($stat->{ram}->{transferred} ne $lstat) {
 731                 my $trans = $stat->{ram}->{transferred} || 0;
 732                 my $rem = $stat->{ram}->{remaining} || 0;
 733                 my $total = $stat->{ram}->{total} || 0;
 734                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 735                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 736                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 737                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 738                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 739                 #reduce sleep if remainig memory if lower than the everage transfert
 740                 $usleep = 300000 if $avglstat && $rem < $avglstat;
 741
 742                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 743                            "remaining ${rem}), total ${total})");
 744
 745                 if (${xbzrlecachesize}) {
 746                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 747                 }
 748
 749                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 750                     $downtimecounter++;
 751                 }
 752                 $lastrem = $rem;
 753
 754                 if ($downtimecounter > 5) {
 755                     $downtimecounter = 0;
 756                     $migrate_downtime *= 2;
 757                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 758                     eval {
 759                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 760                     };
 761                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 762                 }
 763
 764             }
 765
 766
 767             $lstat = $stat->{ram}->{transferred};
 768
 769         } else {
 770             die $merr if $merr;
 771             die "unable to parse migration status '$stat->{status}' - aborting\n";
 772         }
 773     }
 774
 775     # just to be sure that the tunnel gets closed on successful migration, on error
 776     # phase2_cleanup closes it *after* stopping the remote waiting VM
 777     if (!$self->{errors} && $self->{tunnel}) {
 778         eval { finish_tunnel($self, $self->{tunnel});  };
 779         if (my $err = $@) {
 780             $self->log('err', $err);
 781             $self->{errors} = 1;
 782         }
 783     }
 784 }
 785
 786 sub phase2_cleanup {
 787     my ($self, $vmid, $err) = @_;
 788
 789     return if !$self->{errors};
 790     $self->{phase2errors} = 1;
 791
 792     $self->log('info', "aborting phase 2 - cleanup resources");
 793
 794     $self->log('info', "migrate_cancel");
 795     eval {
 796         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 797     };
 798     $self->log('info', "migrate_cancel error: $@") if $@;
 799
 800     my $conf = $self->{vmconf};
 801     delete $conf->{lock};
 802     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 803     if (my $err = $@) {
 804         $self->log('err', $err);
 805     }
 806
 807     # cleanup ressources on target host
 808     if ($self->{storage_migration}) {
 809
 810         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 811         if (my $err = $@) {
 812             $self->log('err', $err);
 813         }
 814
 815         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 816         if (my $err = $@) {
 817             $self->log('err', $err);
 818         }
 819     }
 820
 821     my $nodename = PVE::INotify::nodename();
 822
 823     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 824     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 825     if (my $err = $@) {
 826         $self->log('err', $err);
 827         $self->{errors} = 1;
 828     }
 829
 830     if ($self->{tunnel}) {
 831         eval { finish_tunnel($self, $self->{tunnel});  };
 832         if (my $err = $@) {
 833             $self->log('err', $err);
 834             $self->{errors} = 1;
 835         }
 836     }
 837 }
 838
 839 sub phase3 {
 840     my ($self, $vmid) = @_;
 841
 842     my $volids = $self->{volumes};
 843     return if $self->{phase2errors};
 844
 845     # destroy local copies
 846     foreach my $volid (@$volids) {
 847         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 848         if (my $err = $@) {
 849             $self->log('err', "removing local copy of '$volid' failed - $err");
 850             $self->{errors} = 1;
 851             last if $err =~ /^interrupted by signal$/;
 852         }
 853     }
 854 }
 855
 856 sub phase3_cleanup {
 857     my ($self, $vmid, $err) = @_;
 858
 859     my $conf = $self->{vmconf};
 860     return if $self->{phase2errors};
 861
 862     if ($self->{storage_migration}) {
 863         # finish block-job
 864         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}); };
 865
 866         if (my $err = $@) {
 867             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 868             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 869             die "Failed to completed storage migration\n";
 870         } else {
 871             foreach my $target_drive (keys %{$self->{target_drive}}) {
 872                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 873                 $conf->{$target_drive} = PVE::QemuServer::print_drive($vmid, $drive);
 874                 PVE::QemuConfig->write_config($vmid, $conf);
 875             }
 876         }
 877     }
 878
 879     # move config to remote node
 880     my $conffile = PVE::QemuConfig->config_file($vmid);
 881     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 882
 883     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 884         if !rename($conffile, $newconffile);
 885
 886     if ($self->{livemigration}) {
 887         # now that config file is move, we can resume vm on target if livemigrate
 888         my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 889         eval{ PVE::Tools::run_command($cmd, outfunc => sub {},
 890                 errfunc => sub {
 891                     my $line = shift;
 892                     $self->log('err', $line);
 893                 });
 894         };
 895         if (my $err = $@) {
 896             $self->log('err', $err);
 897             $self->{errors} = 1;
 898         }
 899     }
 900
 901     eval {
 902         my $timer = 0;
 903         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
 904             $self->log('info', "Waiting for spice server migration");
 905             while (1) {
 906                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
 907                 last if int($res->{'migrated'}) == 1;
 908                 last if $timer > 50;
 909                 $timer ++;
 910                 usleep(200000);
 911             }
 912         }
 913     };
 914
 915     # always stop local VM
 916     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 917     if (my $err = $@) {
 918         $self->log('err', "stopping vm failed - $err");
 919         $self->{errors} = 1;
 920     }
 921
 922     # always deactivate volumes - avoid lvm LVs to be active on several nodes
 923     eval {
 924         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 925         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
 926     };
 927     if (my $err = $@) {
 928         $self->log('err', $err);
 929         $self->{errors} = 1;
 930     }
 931
 932     if($self->{storage_migration}) {
 933         # destroy local copies
 934         my $volids = $self->{online_local_volumes};
 935
 936         foreach my $volid (@$volids) {
 937             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 938             if (my $err = $@) {
 939                 $self->log('err', "removing local copy of '$volid' failed - $err");
 940                 $self->{errors} = 1;
 941                 last if $err =~ /^interrupted by signal$/;
 942             }
 943         }
 944
 945         #stop nbd server to remote vm
 946         my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
 947
 948         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 949         if (my $err = $@) {
 950             $self->log('err', $err);
 951             $self->{errors} = 1;
 952         }
 953     }
 954
 955     # clear migrate lock
 956     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
 957     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
 958 }
 959
 960 sub final_cleanup {
 961     my ($self, $vmid) = @_;
 962
 963     # nothing to do
 964 }
 965
 966 1;