PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::INotify;
  13 use PVE::RPCEnvironment;
  14 use PVE::Replication;
  15 use PVE::ReplicationConfig;
  16 use PVE::ReplicationState;
  17 use PVE::Storage;
  18 use PVE::Tools;
  19
  20 use PVE::QemuServer::Drive;
  21 use PVE::QemuServer::Helpers qw(min_version);
  22 use PVE::QemuServer::Machine;
  23 use PVE::QemuServer::Monitor qw(mon_cmd);
  24 use PVE::QemuServer;
  25
  26 use PVE::AbstractMigrate;
  27 use base qw(PVE::AbstractMigrate);
  28
  29 sub fork_command_pipe {
  30     my ($self, $cmd) = @_;
  31
  32     my $reader = IO::File->new();
  33     my $writer = IO::File->new();
  34
  35     my $orig_pid = $$;
  36
  37     my $cpid;
  38
  39     eval { $cpid = open2($reader, $writer, @$cmd); };
  40
  41     my $err = $@;
  42
  43     # catch exec errors
  44     if ($orig_pid != $$) {
  45         $self->log('err', "can't fork command pipe\n");
  46         POSIX::_exit(1);
  47         kill('KILL', $$);
  48     }
  49
  50     die $err if $err;
  51
  52     return { writer => $writer, reader => $reader, pid => $cpid };
  53 }
  54
  55 sub finish_command_pipe {
  56     my ($self, $cmdpipe, $timeout) = @_;
  57
  58     my $cpid = $cmdpipe->{pid};
  59     return if !defined($cpid);
  60
  61     my $writer = $cmdpipe->{writer};
  62     my $reader = $cmdpipe->{reader};
  63
  64     $writer->close();
  65     $reader->close();
  66
  67     my $collect_child_process = sub {
  68         my $res = waitpid($cpid, WNOHANG);
  69         if (defined($res) && ($res == $cpid)) {
  70             delete $cmdpipe->{cpid};
  71             return 1;
  72         } else {
  73             return 0;
  74         }
  75      };
  76
  77     if ($timeout) {
  78         for (my $i = 0; $i < $timeout; $i++) {
  79             return if &$collect_child_process();
  80             sleep(1);
  81         }
  82     }
  83
  84     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  85     kill(15, $cpid);
  86
  87     # wait again
  88     for (my $i = 0; $i < 10; $i++) {
  89         return if &$collect_child_process();
  90         sleep(1);
  91     }
  92
  93     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  94     kill 9, $cpid;
  95     sleep 1;
  96
  97     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  98         if !&$collect_child_process();
  99 }
 100
 101 sub read_tunnel {
 102     my ($self, $tunnel, $timeout) = @_;
 103
 104     $timeout = 60 if !defined($timeout);
 105
 106     my $reader = $tunnel->{reader};
 107
 108     my $output;
 109     eval {
 110         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 111     };
 112     die "reading from tunnel failed: $@\n" if $@;
 113
 114     chomp $output;
 115
 116     return $output;
 117 }
 118
 119 sub write_tunnel {
 120     my ($self, $tunnel, $timeout, $command) = @_;
 121
 122     $timeout = 60 if !defined($timeout);
 123
 124     my $writer = $tunnel->{writer};
 125
 126     eval {
 127         PVE::Tools::run_with_timeout($timeout, sub {
 128             print $writer "$command\n";
 129             $writer->flush();
 130         });
 131     };
 132     die "writing to tunnel failed: $@\n" if $@;
 133
 134     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 135         my $res = eval { $self->read_tunnel($tunnel, 10); };
 136         die "no reply to command '$command': $@\n" if $@;
 137
 138         if ($res eq 'OK') {
 139             return;
 140         } else {
 141             die "tunnel replied '$res' to command '$command'\n";
 142         }
 143     }
 144 }
 145
 146 sub fork_tunnel {
 147     my ($self, $tunnel_addr) = @_;
 148
 149     my @localtunnelinfo = ();
 150     foreach my $addr (@$tunnel_addr) {
 151         push @localtunnelinfo, '-L', $addr;
 152     }
 153
 154     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 155
 156     my $tunnel = $self->fork_command_pipe($cmd);
 157
 158     eval {
 159         my $helo = $self->read_tunnel($tunnel, 60);
 160         die "no reply\n" if !$helo;
 161         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 162         die "got strange reply from mtunnel ('$helo')\n"
 163             if $helo !~ m/^tunnel online$/;
 164     };
 165     my $err = $@;
 166
 167     eval {
 168         my $ver = $self->read_tunnel($tunnel, 10);
 169         if ($ver =~ /^ver (\d+)$/) {
 170             $tunnel->{version} = $1;
 171             $self->log('info', "ssh tunnel $ver\n");
 172         } else {
 173             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 174         }
 175     };
 176
 177     if ($err) {
 178         $self->finish_command_pipe($tunnel);
 179         die "can't open migration tunnel - $err";
 180     }
 181     return $tunnel;
 182 }
 183
 184 sub finish_tunnel {
 185     my ($self, $tunnel) = @_;
 186
 187     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 188     my $err = $@;
 189
 190     $self->finish_command_pipe($tunnel, 30);
 191
 192     if ($tunnel->{sock_addr}) {
 193         # ssh does not clean up on local host
 194         my $cmd = ['rm', '-f', @{$tunnel->{sock_addr}}]; #
 195         PVE::Tools::run_command($cmd);
 196
 197         # .. and just to be sure check on remote side
 198         unshift @{$cmd}, @{$self->{rem_ssh}};
 199         PVE::Tools::run_command($cmd);
 200     }
 201
 202     die $err if $err;
 203 }
 204
 205 sub lock_vm {
 206     my ($self, $vmid, $code, @param) = @_;
 207
 208     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 209 }
 210
 211 sub prepare {
 212     my ($self, $vmid) = @_;
 213
 214     my $online = $self->{opts}->{online};
 215
 216     $self->{storecfg} = PVE::Storage::config();
 217
 218     # test if VM exists
 219     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 220
 221     PVE::QemuConfig->check_lock($conf);
 222
 223     my $running = 0;
 224     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 225         die "can't migrate running VM without --online\n" if !$online;
 226         $running = $pid;
 227
 228         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 229
 230     }
 231     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 232     if (scalar @$loc_res) {
 233         if ($self->{running} || !$self->{opts}->{force}) {
 234             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 235         } else {
 236             $self->log('info', "migrating VM which uses local devices");
 237         }
 238     }
 239
 240     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 241
 242     my $need_activate = [];
 243     foreach my $volid (@$vollist) {
 244         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 245
 246         # check if storage is available on both nodes
 247         my $targetsid = $self->{opts}->{targetstorage} // $sid;
 248
 249         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 250         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 251
 252         if ($scfg->{shared}) {
 253             # PVE::Storage::activate_storage checks this for non-shared storages
 254             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 255             warn "Used shared storage '$sid' is not online on source node!\n"
 256                 if !$plugin->check_connection($sid, $scfg);
 257         } else {
 258             # only activate if not shared
 259             next if ($volid =~ m/vm-\d+-cloudinit/);
 260             push @$need_activate, $volid;
 261         }
 262     }
 263
 264     # activate volumes
 265     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 266
 267     # test ssh connection
 268     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 269     eval { $self->cmd_quiet($cmd); };
 270     die "Can't connect to destination address using public key\n" if $@;
 271
 272     return $running;
 273 }
 274
 275 sub sync_disks {
 276     my ($self, $vmid) = @_;
 277
 278     my $conf = $self->{vmconf};
 279
 280     # local volumes which have been copied
 281     $self->{volumes} = [];
 282
 283     my $storecfg = $self->{storecfg};
 284     my $override_targetsid = $self->{opts}->{targetstorage};
 285
 286     if (defined($override_targetsid)) {
 287         my $scfg = PVE::Storage::storage_config($storecfg, $override_targetsid);
 288         die "content type 'images' is not available on storage '$override_targetsid'\n"
 289             if !$scfg->{content}->{images};
 290     }
 291
 292     eval {
 293
 294         # found local volumes and their origin
 295         my $local_volumes = {};
 296         my $local_volumes_errors = {};
 297         my $other_errors = [];
 298         my $abort = 0;
 299
 300         my $log_error = sub {
 301             my ($msg, $volid) = @_;
 302
 303             if (defined($volid)) {
 304                 $local_volumes_errors->{$volid} = $msg;
 305             } else {
 306                 push @$other_errors, $msg;
 307             }
 308             $abort = 1;
 309         };
 310
 311         my @sids = PVE::Storage::storage_ids($storecfg);
 312         foreach my $storeid (@sids) {
 313             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 314             next if $scfg->{shared};
 315             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 316
 317             # get list from PVE::Storage (for unused volumes)
 318             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 319
 320             next if @{$dl->{$storeid}} == 0;
 321
 322             my $targetsid = $override_targetsid // $storeid;
 323
 324             # check if storage is available on target node
 325             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 326
 327             PVE::Storage::foreach_volid($dl, sub {
 328                 my ($volid, $sid, $volinfo) = @_;
 329
 330                 $local_volumes->{$volid}->{ref} = 'storage';
 331
 332                 # If with_snapshots is not set for storage migrate, it tries to use
 333                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 334                 # back to qcow2 is currently not possible.
 335                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 336                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 337             });
 338         }
 339
 340         my $rep_cfg = PVE::ReplicationConfig->new();
 341         my $replication_jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node});
 342         my $replicatable_volumes = !$replication_jobcfg ? {}
 343             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 344
 345         my $test_volid = sub {
 346             my ($volid, $attr) = @_;
 347
 348             if ($volid =~ m|^/|) {
 349                 return if $attr->{shared};
 350                 $local_volumes->{$volid}->{ref} = 'config';
 351                 die "local file/device\n";
 352             }
 353
 354             my $snaprefs = $attr->{referenced_in_snapshot};
 355
 356             if ($attr->{cdrom}) {
 357                 if ($volid eq 'cdrom') {
 358                     my $msg = "can't migrate local cdrom drive";
 359                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 360                         my $snapnames = join(', ', sort keys %$snaprefs);
 361                         $msg .= " (referenced in snapshot - $snapnames)";
 362                     }
 363                     &$log_error("$msg\n");
 364                     return;
 365                 }
 366                 return if $volid eq 'none';
 367             }
 368
 369             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 370
 371             my $targetsid = $override_targetsid // $sid;
 372             # check if storage is available on both nodes
 373             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 374             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 375
 376             return if $scfg->{shared};
 377
 378             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 379
 380             if ($attr->{cdrom}) {
 381                 if ($volid =~ /vm-\d+-cloudinit/) {
 382                     $local_volumes->{$volid}->{ref} = 'generated';
 383                     return;
 384                 }
 385                 die "local cdrom image\n";
 386             }
 387
 388             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 389
 390             die "owned by other VM (owner = VM $owner)\n"
 391                 if !$owner || ($owner != $vmid);
 392
 393             if (defined($snaprefs)) {
 394                 $local_volumes->{$volid}->{snapshots} = 1;
 395
 396                 # we cannot migrate shapshots on local storage
 397                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 398
 399                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 400                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 401                     die "non-migratable snapshot exists\n";
 402                 }
 403             }
 404
 405             die "referenced by linked clone(s)\n"
 406                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 407         };
 408
 409         PVE::QemuServer::foreach_volid($conf, sub {
 410             my ($volid, $attr) = @_;
 411             eval { $test_volid->($volid, $attr); };
 412             if (my $err = $@) {
 413                 &$log_error($err, $volid);
 414             }
 415         });
 416
 417         foreach my $vol (sort keys %$local_volumes) {
 418             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 419             my $ref = $local_volumes->{$vol}->{ref};
 420             if ($ref eq 'storage') {
 421                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 422             } elsif ($ref eq 'config') {
 423                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 424                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 425                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 426             } elsif ($ref eq 'snapshot') {
 427                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 428             } elsif ($ref eq 'generated') {
 429                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 430             } else {
 431                 $self->log('info', "found $type disk '$vol'\n");
 432             }
 433         }
 434
 435         foreach my $vol (sort keys %$local_volumes_errors) {
 436             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 437         }
 438         foreach my $err (@$other_errors) {
 439             $self->log('warn', "$err");
 440         }
 441
 442         if ($abort) {
 443             die "can't migrate VM - check log\n";
 444         }
 445
 446         # additional checks for local storage
 447         foreach my $volid (keys %$local_volumes) {
 448             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 449             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 450
 451             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 452
 453             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 454                 if !$migratable;
 455
 456             # image is a linked clone on local storage, se we can't migrate.
 457             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 458                 die "can't migrate '$volid' as it's a clone of '$basename'";
 459             }
 460         }
 461
 462         if ($replication_jobcfg) {
 463             if ($self->{running}) {
 464
 465                 my $version = PVE::QemuServer::kvm_user_version();
 466                 if (!min_version($version, 4, 2)) {
 467                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 468                 }
 469
 470                 my $live_replicatable_volumes = {};
 471                 PVE::QemuServer::foreach_drive($conf, sub {
 472                     my ($ds, $drive) = @_;
 473
 474                     my $volid = $drive->{file};
 475                     $live_replicatable_volumes->{$ds} = $volid
 476                         if defined($replicatable_volumes->{$volid});
 477                 });
 478                 foreach my $drive (keys %$live_replicatable_volumes) {
 479                     my $volid = $live_replicatable_volumes->{$drive};
 480
 481                     my $bitmap = "repl_$drive";
 482
 483                     # start tracking before replication to get full delta + a few duplicates
 484                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 485                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 486
 487                     # other info comes from target node in phase 2
 488                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 489                 }
 490             }
 491             $self->log('info', "replicating disk images");
 492
 493             my $start_time = time();
 494             my $logfunc = sub { $self->log('info', shift) };
 495             $self->{replicated_volumes} = PVE::Replication::run_replication(
 496                'PVE::QemuConfig', $replication_jobcfg, $start_time, $start_time, $logfunc);
 497         }
 498
 499         # sizes in config have to be accurate for remote node to correctly
 500         # allocate disks, rescan to be sure
 501         my $volid_hash = PVE::QemuServer::scan_volids($storecfg, $vmid);
 502         PVE::QemuServer::foreach_drive($conf, sub {
 503             my ($key, $drive) = @_;
 504             my ($updated, $old_size, $new_size) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash);
 505             if (defined($updated)) {
 506                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 507                 $self->log('info', "size of disk '$updated->{file}' ($key) updated from $old_size to $new_size\n");
 508             }
 509         });
 510
 511         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 512
 513         foreach my $volid (keys %$local_volumes) {
 514             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 515             my $targetsid = $override_targetsid // $sid;
 516             my $ref = $local_volumes->{$volid}->{ref};
 517             if ($self->{running} && $ref eq 'config') {
 518                 push @{$self->{online_local_volumes}}, $volid;
 519             } elsif ($ref eq 'generated') {
 520                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 521                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 522                 push @{$self->{volumes}}, $volid;
 523                 next;
 524             } else {
 525                 next if $self->{replicated_volumes}->{$volid};
 526                 push @{$self->{volumes}}, $volid;
 527                 my $opts = $self->{opts};
 528                 my $insecure = $opts->{migration_type} eq 'insecure';
 529                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 530                 # use 'migrate' limit for transfer to other node
 531                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 532                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 533                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 534
 535                 PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info}, $targetsid,
 536                                               undef, undef, undef, $bwlimit, $insecure, $with_snapshots);
 537             }
 538         }
 539     };
 540     die "Failed to sync data - $@" if $@;
 541 }
 542
 543 sub cleanup_remotedisks {
 544     my ($self) = @_;
 545
 546     foreach my $target_drive (keys %{$self->{target_drive}}) {
 547         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{drivestr});
 548
 549         # don't clean up replicated disks!
 550         next if defined($self->{replicated_volumes}->{$drive->{file}});
 551
 552         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 553
 554         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 555
 556         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 557         if (my $err = $@) {
 558             $self->log('err', $err);
 559             $self->{errors} = 1;
 560         }
 561     }
 562 }
 563
 564 sub cleanup_bitmaps {
 565     my ($self) = @_;
 566     foreach my $drive (keys %{$self->{target_drive}}) {
 567         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 568         next if !$bitmap;
 569         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 570         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 571     }
 572 }
 573
 574 sub phase1 {
 575     my ($self, $vmid) = @_;
 576
 577     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 578
 579     my $conf = $self->{vmconf};
 580
 581     # set migrate lock in config file
 582     $conf->{lock} = 'migrate';
 583     PVE::QemuConfig->write_config($vmid, $conf);
 584
 585     sync_disks($self, $vmid);
 586
 587     # sync_disks fixes disk sizes to match their actual size, write changes so
 588     # target allocates correct volumes
 589     PVE::QemuConfig->write_config($vmid, $conf);
 590 };
 591
 592 sub phase1_cleanup {
 593     my ($self, $vmid, $err) = @_;
 594
 595     $self->log('info', "aborting phase 1 - cleanup resources");
 596
 597     my $conf = $self->{vmconf};
 598     delete $conf->{lock};
 599     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 600     if (my $err = $@) {
 601         $self->log('err', $err);
 602     }
 603
 604     if ($self->{volumes}) {
 605         foreach my $volid (@{$self->{volumes}}) {
 606             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 607             # fixme: try to remove ?
 608         }
 609     }
 610
 611     eval { $self->cleanup_bitmaps() };
 612     if (my $err =$@) {
 613         $self->log('err', $err);
 614     }
 615
 616 }
 617
 618 sub phase2 {
 619     my ($self, $vmid) = @_;
 620
 621     my $conf = $self->{vmconf};
 622
 623     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 624
 625     my $raddr;
 626     my $rport;
 627     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 628     my $nodename = PVE::INotify::nodename();
 629
 630     ## start on remote node
 631     my $cmd = [@{$self->{rem_ssh}}];
 632
 633     my $spice_ticket;
 634     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 635         my $res = mon_cmd($vmid, 'query-spice');
 636         $spice_ticket = $res->{ticket};
 637     }
 638
 639     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 640
 641     my $migration_type = $self->{opts}->{migration_type};
 642
 643     push @$cmd, '--migration_type', $migration_type;
 644
 645     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 646       if $self->{opts}->{migration_network};
 647
 648     if ($migration_type eq 'insecure') {
 649         push @$cmd, '--stateuri', 'tcp';
 650     } else {
 651         push @$cmd, '--stateuri', 'unix';
 652     }
 653
 654     if ($self->{forcemachine}) {
 655         push @$cmd, '--machine', $self->{forcemachine};
 656     }
 657
 658     if ($self->{online_local_volumes}) {
 659         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 660     }
 661
 662     my $spice_port;
 663     my $tunnel_addr = [];
 664     my $sock_addr = [];
 665     # version > 0 for unix socket support
 666     my $nbd_protocol_version = 1;
 667     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 668     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 669     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 670     foreach my $volid (keys %{$self->{replicated_volumes}}) {
 671         $input .= "replicated_volume: $volid\n";
 672     }
 673
 674     my $target_replicated_volumes = {};
 675
 676     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 677     # instead we pipe it through STDIN
 678     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 679         my $line = shift;
 680
 681         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 682             $raddr = $1;
 683             $rport = int($2);
 684             $ruri = "tcp:$raddr:$rport";
 685         }
 686         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 687             $raddr = $1;
 688             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 689             $ruri = "unix:$raddr";
 690         }
 691         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 692             $raddr = "localhost";
 693             $rport = int($1);
 694             $ruri = "tcp:$raddr:$rport";
 695         }
 696         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 697             $spice_port = int($1);
 698         }
 699         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 700             my $drivestr = $4;
 701             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 702             my $targetdrive = $3;
 703             $targetdrive =~ s/drive-//g;
 704
 705             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 706             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 707         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 708             my $drivestr = $4;
 709             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 710             my $nbd_unix_addr = $1;
 711             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 712             my $targetdrive = $3;
 713             $targetdrive =~ s/drive-//g;
 714
 715             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 716             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 717             push @$tunnel_addr, "$nbd_unix_addr:$nbd_unix_addr";
 718             push @$sock_addr, $nbd_unix_addr;
 719         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 720             my $drive = $1;
 721             my $volid = $2;
 722             $target_replicated_volumes->{$volid} = $drive;
 723         } elsif ($line =~ m/^QEMU: (.*)$/) {
 724             $self->log('info', "[$self->{node}] $1\n");
 725         }
 726     }, errfunc => sub {
 727         my $line = shift;
 728         $self->log('info', "[$self->{node}] $line");
 729     }, noerr => 1);
 730
 731     die "remote command failed with exit code $exitcode\n" if $exitcode;
 732
 733     die "unable to detect remote migration address\n" if !$raddr;
 734
 735     if (scalar(keys %$target_replicated_volumes) != scalar(keys %{$self->{replicated_volumes}})) {
 736         die "number of replicated disks on source and target node do not match - target node too old?\n"
 737     }
 738
 739     $self->log('info', "start remote tunnel");
 740
 741     if ($migration_type eq 'secure') {
 742
 743         if ($ruri =~ /^unix:/) {
 744             unlink $raddr;
 745             push @$tunnel_addr, "$raddr:$raddr";
 746             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 747             push @$sock_addr, $raddr;
 748
 749             my $unix_socket_try = 0; # wait for the socket to become ready
 750             while ($unix_socket_try <= 100) {
 751                 $unix_socket_try++;
 752                 my $available = 0;
 753                 foreach my $sock (@$sock_addr) {
 754                     if (-S $sock) {
 755                         $available++;
 756                     }
 757                 }
 758
 759                 if ($available == @$sock_addr) {
 760                     last;
 761                 }
 762
 763                 usleep(50000);
 764             }
 765             if ($unix_socket_try > 100) {
 766                 $self->{errors} = 1;
 767                 $self->finish_tunnel($self->{tunnel});
 768                 die "Timeout, migration socket $ruri did not get ready";
 769             }
 770
 771         } elsif ($ruri =~ /^tcp:/) {
 772             my $tunnel_addr;
 773             if ($raddr eq "localhost") {
 774                 # for backwards compatibility with older qemu-server versions
 775                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 776                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 777                 $tunnel_addr = "$lport:localhost:$rport";
 778             }
 779
 780             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 781
 782         } else {
 783             die "unsupported protocol in migration URI: $ruri\n";
 784         }
 785     } else {
 786         #fork tunnel for insecure migration, to send faster commands like resume
 787         $self->{tunnel} = $self->fork_tunnel();
 788     }
 789     $self->{tunnel}->{sock_addr} = $sock_addr if (@$sock_addr);
 790
 791     my $start = time();
 792
 793     my $opt_bwlimit = $self->{opts}->{bwlimit};
 794
 795     if (defined($self->{online_local_volumes})) {
 796         $self->{storage_migration} = 1;
 797         $self->{storage_migration_jobs} = {};
 798         $self->log('info', "starting storage migration");
 799
 800         die "The number of local disks does not match between the source and the destination.\n"
 801             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 802         foreach my $drive (keys %{$self->{target_drive}}){
 803             my $target = $self->{target_drive}->{$drive};
 804             my $nbd_uri = $target->{nbd_uri};
 805
 806             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 807             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 808
 809             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_drive->{file});
 810             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_drive->{file});
 811
 812             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 813             my $bitmap = $target->{bitmap};
 814
 815             $self->log('info', "$drive: start migration to $nbd_uri");
 816             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 817         }
 818     }
 819
 820     $self->log('info', "starting online/live migration on $ruri");
 821     $self->{livemigration} = 1;
 822
 823     # load_defaults
 824     my $defaults = PVE::QemuServer::load_defaults();
 825
 826     $self->log('info', "set migration_caps");
 827     eval {
 828         PVE::QemuServer::set_migration_caps($vmid);
 829     };
 830     warn $@ if $@;
 831
 832     my $qemu_migrate_params = {};
 833
 834     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 835     # migrate_speed parameter in qm.conf - take the lower of the two.
 836     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 837     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 838     # migrate_speed is in MB/s, bwlimit in KB/s
 839     $migrate_speed *= 1024;
 840
 841     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 842
 843     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 844     # default of 8192m which is basically unlimited
 845     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 846
 847     # qmp takes migrate_speed in B/s.
 848     $migrate_speed *= 1024;
 849     $self->log('info', "migration speed limit: $migrate_speed B/s");
 850     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 851
 852     my $migrate_downtime = $defaults->{migrate_downtime};
 853     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 854     if (defined($migrate_downtime)) {
 855         # migrate-set-parameters expects limit in ms
 856         $migrate_downtime *= 1000;
 857         $self->log('info', "migration downtime limit: $migrate_downtime ms");
 858         $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 859     }
 860
 861     # set cachesize to 10% of the total memory
 862     my $memory =  $conf->{memory} || $defaults->{memory};
 863     my $cachesize = int($memory * 1048576 / 10);
 864     $cachesize = round_powerof2($cachesize);
 865
 866     $self->log('info', "migration cachesize: $cachesize B");
 867     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 868
 869     $self->log('info', "set migration parameters");
 870     eval {
 871         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 872     };
 873     $self->log('info', "migrate-set-parameters error: $@") if $@;
 874
 875     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 876         my $rpcenv = PVE::RPCEnvironment::get();
 877         my $authuser = $rpcenv->get_user();
 878
 879         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 880
 881         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 882         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 883
 884         $self->log('info', "spice client_migrate_info");
 885
 886         eval {
 887             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 888                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 889                                                 'cert-subject' => $subject);
 890         };
 891         $self->log('info', "client_migrate_info error: $@") if $@;
 892
 893     }
 894
 895     $self->log('info', "start migrate command to $ruri");
 896     eval {
 897         mon_cmd($vmid, "migrate", uri => $ruri);
 898     };
 899     my $merr = $@;
 900     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 901
 902     my $lstat = 0;
 903     my $usleep = 1000000;
 904     my $i = 0;
 905     my $err_count = 0;
 906     my $lastrem = undef;
 907     my $downtimecounter = 0;
 908     while (1) {
 909         $i++;
 910         my $avglstat = $lstat/$i if $lstat;
 911
 912         usleep($usleep);
 913         my $stat;
 914         eval {
 915             $stat = mon_cmd($vmid, "query-migrate");
 916         };
 917         if (my $err = $@) {
 918             $err_count++;
 919             warn "query migrate failed: $err\n";
 920             $self->log('info', "query migrate failed: $err");
 921             if ($err_count <= 5) {
 922                 usleep(1000000);
 923                 next;
 924             }
 925             die "too many query migrate failures - aborting\n";
 926         }
 927
 928         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 929             sleep(1);
 930             next;
 931         }
 932
 933         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 934             $merr = undef;
 935             $err_count = 0;
 936             if ($stat->{status} eq 'completed') {
 937                 my $delay = time() - $start;
 938                 if ($delay > 0) {
 939                     my $mbps = sprintf "%.2f", $memory / $delay;
 940                     my $downtime = $stat->{downtime} || 0;
 941                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 942                 }
 943             }
 944
 945             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 946                 $self->log('info', "migration status error: $stat->{status}");
 947                 die "aborting\n"
 948             }
 949
 950             if ($stat->{status} ne 'active') {
 951                 $self->log('info', "migration status: $stat->{status}");
 952                 last;
 953             }
 954
 955             if ($stat->{ram}->{transferred} ne $lstat) {
 956                 my $trans = $stat->{ram}->{transferred} || 0;
 957                 my $rem = $stat->{ram}->{remaining} || 0;
 958                 my $total = $stat->{ram}->{total} || 0;
 959                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 960                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 961                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 962                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 963                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 964                 # reduce sleep if remainig memory is lower than the average transfer speed
 965                 $usleep = 100000 if $avglstat && $rem < $avglstat;
 966
 967                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 968                            "remaining ${rem}), total ${total})");
 969
 970                 if (${xbzrlecachesize}) {
 971                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 972                 }
 973
 974                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 975                     $downtimecounter++;
 976                 }
 977                 $lastrem = $rem;
 978
 979                 if ($downtimecounter > 5) {
 980                     $downtimecounter = 0;
 981                     $migrate_downtime *= 2;
 982                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 983                     eval {
 984                         mon_cmd($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 985                     };
 986                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 987                 }
 988
 989             }
 990
 991
 992             $lstat = $stat->{ram}->{transferred};
 993
 994         } else {
 995             die $merr if $merr;
 996             die "unable to parse migration status '$stat->{status}' - aborting\n";
 997         }
 998     }
 999 }
1000
1001 sub phase2_cleanup {
1002     my ($self, $vmid, $err) = @_;
1003
1004     return if !$self->{errors};
1005     $self->{phase2errors} = 1;
1006
1007     $self->log('info', "aborting phase 2 - cleanup resources");
1008
1009     $self->log('info', "migrate_cancel");
1010     eval {
1011         mon_cmd($vmid, "migrate_cancel");
1012     };
1013     $self->log('info', "migrate_cancel error: $@") if $@;
1014
1015     my $conf = $self->{vmconf};
1016     delete $conf->{lock};
1017     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1018     if (my $err = $@) {
1019         $self->log('err', $err);
1020     }
1021
1022     # cleanup ressources on target host
1023     if ($self->{storage_migration}) {
1024         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1025         if (my $err = $@) {
1026             $self->log('err', $err);
1027         }
1028     }
1029
1030     eval { $self->cleanup_bitmaps() };
1031     if (my $err =$@) {
1032         $self->log('err', $err);
1033     }
1034
1035     my $nodename = PVE::INotify::nodename();
1036
1037     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1038     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1039     if (my $err = $@) {
1040         $self->log('err', $err);
1041         $self->{errors} = 1;
1042     }
1043
1044     # cleanup after stopping, otherwise disks might be in-use by target VM!
1045     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1046     if (my $err = $@) {
1047         $self->log('err', $err);
1048     }
1049
1050
1051     if ($self->{tunnel}) {
1052         eval { finish_tunnel($self, $self->{tunnel});  };
1053         if (my $err = $@) {
1054             $self->log('err', $err);
1055             $self->{errors} = 1;
1056         }
1057     }
1058 }
1059
1060 sub phase3 {
1061     my ($self, $vmid) = @_;
1062
1063     my $volids = $self->{volumes};
1064     return if $self->{phase2errors};
1065
1066     # destroy local copies
1067     foreach my $volid (@$volids) {
1068         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1069         if (my $err = $@) {
1070             $self->log('err', "removing local copy of '$volid' failed - $err");
1071             $self->{errors} = 1;
1072             last if $err =~ /^interrupted by signal$/;
1073         }
1074     }
1075 }
1076
1077 sub phase3_cleanup {
1078     my ($self, $vmid, $err) = @_;
1079
1080     my $conf = $self->{vmconf};
1081     return if $self->{phase2errors};
1082
1083     my $tunnel = $self->{tunnel};
1084
1085     if ($self->{storage_migration}) {
1086         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1087         # to avoid it trying to re-establish it. We are in blockjob ready state,
1088         # thus, this command changes to it to blockjob complete (see qapi docs)
1089         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1090
1091         if (my $err = $@) {
1092             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1093             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1094             die "Failed to complete storage migration: $err\n";
1095         } else {
1096             foreach my $target_drive (keys %{$self->{target_drive}}) {
1097                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{drivestr});
1098                 $conf->{$target_drive} = PVE::QemuServer::print_drive($drive);
1099                 PVE::QemuConfig->write_config($vmid, $conf);
1100             }
1101         }
1102     }
1103
1104     # transfer replication state before move config
1105     $self->transfer_replication_state() if $self->{replicated_volumes};
1106
1107     # move config to remote node
1108     my $conffile = PVE::QemuConfig->config_file($vmid);
1109     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1110
1111     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1112         if !rename($conffile, $newconffile);
1113
1114     $self->switch_replication_job_target() if $self->{replicated_volumes};
1115
1116     if ($self->{livemigration}) {
1117         if ($self->{storage_migration}) {
1118             # stop nbd server on remote vm - requirement for resume since 2.9
1119             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1120
1121             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1122             if (my $err = $@) {
1123                 $self->log('err', $err);
1124                 $self->{errors} = 1;
1125             }
1126         }
1127
1128         # config moved and nbd server stopped - now we can resume vm on target
1129         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1130             eval {
1131                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1132             };
1133             if (my $err = $@) {
1134                 $self->log('err', $err);
1135                 $self->{errors} = 1;
1136             }
1137         } else {
1138             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1139             my $logf = sub {
1140                 my $line = shift;
1141                 $self->log('err', $line);
1142             };
1143             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1144             if (my $err = $@) {
1145                 $self->log('err', $err);
1146                 $self->{errors} = 1;
1147             }
1148         }
1149
1150         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1151             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1152             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1153         }
1154     }
1155
1156     # close tunnel on successful migration, on error phase2_cleanup closed it
1157     if ($tunnel) {
1158         eval { finish_tunnel($self, $tunnel);  };
1159         if (my $err = $@) {
1160             $self->log('err', $err);
1161             $self->{errors} = 1;
1162         }
1163     }
1164
1165     eval {
1166         my $timer = 0;
1167         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1168             $self->log('info', "Waiting for spice server migration");
1169             while (1) {
1170                 my $res = mon_cmd($vmid, 'query-spice');
1171                 last if int($res->{'migrated'}) == 1;
1172                 last if $timer > 50;
1173                 $timer ++;
1174                 usleep(200000);
1175             }
1176         }
1177     };
1178
1179     # always stop local VM
1180     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1181     if (my $err = $@) {
1182         $self->log('err', "stopping vm failed - $err");
1183         $self->{errors} = 1;
1184     }
1185
1186     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1187     eval {
1188         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1189         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1190     };
1191     if (my $err = $@) {
1192         $self->log('err', $err);
1193         $self->{errors} = 1;
1194     }
1195
1196     if($self->{storage_migration}) {
1197         # destroy local copies
1198         my $volids = $self->{online_local_volumes};
1199
1200         foreach my $volid (@$volids) {
1201             # keep replicated volumes!
1202             next if $self->{replicated_volumes}->{$volid};
1203
1204             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1205             if (my $err = $@) {
1206                 $self->log('err', "removing local copy of '$volid' failed - $err");
1207                 $self->{errors} = 1;
1208                 last if $err =~ /^interrupted by signal$/;
1209             }
1210         }
1211
1212     }
1213
1214     # clear migrate lock
1215     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1216     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1217 }
1218
1219 sub final_cleanup {
1220     my ($self, $vmid) = @_;
1221
1222     # nothing to do
1223 }
1224
1225 sub round_powerof2 {
1226     return 1 if $_[0] < 2;
1227     return 2 << int(log($_[0]-1)/log(2));
1228 }
1229
1230 1;