PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Format qw(render_bytes);
  12 use PVE::Cluster;
  13 use PVE::GuestHelpers qw(safe_boolean_ne safe_string_ne);
  14 use PVE::INotify;
  15 use PVE::RPCEnvironment;
  16 use PVE::Replication;
  17 use PVE::ReplicationConfig;
  18 use PVE::ReplicationState;
  19 use PVE::Storage;
  20 use PVE::Tools;
  21
  22 use PVE::QemuConfig;
  23 use PVE::QemuServer::CPUConfig;
  24 use PVE::QemuServer::Drive;
  25 use PVE::QemuServer::Helpers qw(min_version);
  26 use PVE::QemuServer::Machine;
  27 use PVE::QemuServer::Monitor qw(mon_cmd);
  28 use PVE::QemuServer;
  29
  30 use PVE::AbstractMigrate;
  31 use base qw(PVE::AbstractMigrate);
  32
  33 sub fork_command_pipe {
  34     my ($self, $cmd) = @_;
  35
  36     my $reader = IO::File->new();
  37     my $writer = IO::File->new();
  38
  39     my $orig_pid = $$;
  40
  41     my $cpid;
  42
  43     eval { $cpid = open2($reader, $writer, @$cmd); };
  44
  45     my $err = $@;
  46
  47     # catch exec errors
  48     if ($orig_pid != $$) {
  49         $self->log('err', "can't fork command pipe\n");
  50         POSIX::_exit(1);
  51         kill('KILL', $$);
  52     }
  53
  54     die $err if $err;
  55
  56     return { writer => $writer, reader => $reader, pid => $cpid };
  57 }
  58
  59 sub finish_command_pipe {
  60     my ($self, $cmdpipe, $timeout) = @_;
  61
  62     my $cpid = $cmdpipe->{pid};
  63     return if !defined($cpid);
  64
  65     my $writer = $cmdpipe->{writer};
  66     my $reader = $cmdpipe->{reader};
  67
  68     $writer->close();
  69     $reader->close();
  70
  71     my $collect_child_process = sub {
  72         my $res = waitpid($cpid, WNOHANG);
  73         if (defined($res) && ($res == $cpid)) {
  74             delete $cmdpipe->{cpid};
  75             return 1;
  76         } else {
  77             return 0;
  78         }
  79      };
  80
  81     if ($timeout) {
  82         for (my $i = 0; $i < $timeout; $i++) {
  83             return if &$collect_child_process();
  84             sleep(1);
  85         }
  86     }
  87
  88     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  89     kill(15, $cpid);
  90
  91     # wait again
  92     for (my $i = 0; $i < 10; $i++) {
  93         return if &$collect_child_process();
  94         sleep(1);
  95     }
  96
  97     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  98     kill 9, $cpid;
  99     sleep 1;
 100
 101     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
 102         if !&$collect_child_process();
 103 }
 104
 105 sub read_tunnel {
 106     my ($self, $tunnel, $timeout) = @_;
 107
 108     $timeout = 60 if !defined($timeout);
 109
 110     my $reader = $tunnel->{reader};
 111
 112     my $output;
 113     eval {
 114         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 115     };
 116     die "reading from tunnel failed: $@\n" if $@;
 117
 118     chomp $output;
 119
 120     return $output;
 121 }
 122
 123 sub write_tunnel {
 124     my ($self, $tunnel, $timeout, $command) = @_;
 125
 126     $timeout = 60 if !defined($timeout);
 127
 128     my $writer = $tunnel->{writer};
 129
 130     eval {
 131         PVE::Tools::run_with_timeout($timeout, sub {
 132             print $writer "$command\n";
 133             $writer->flush();
 134         });
 135     };
 136     die "writing to tunnel failed: $@\n" if $@;
 137
 138     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 139         my $res = eval { $self->read_tunnel($tunnel, 10); };
 140         die "no reply to command '$command': $@\n" if $@;
 141
 142         if ($res eq 'OK') {
 143             return;
 144         } else {
 145             die "tunnel replied '$res' to command '$command'\n";
 146         }
 147     }
 148 }
 149
 150 sub fork_tunnel {
 151     my ($self, $ssh_forward_info) = @_;
 152
 153     my @localtunnelinfo = ();
 154     foreach my $addr (@$ssh_forward_info) {
 155         push @localtunnelinfo, '-L', $addr;
 156     }
 157
 158     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 159
 160     my $tunnel = $self->fork_command_pipe($cmd);
 161
 162     eval {
 163         my $helo = $self->read_tunnel($tunnel, 60);
 164         die "no reply\n" if !$helo;
 165         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 166         die "got strange reply from mtunnel ('$helo')\n"
 167             if $helo !~ m/^tunnel online$/;
 168     };
 169     my $err = $@;
 170
 171     eval {
 172         my $ver = $self->read_tunnel($tunnel, 10);
 173         if ($ver =~ /^ver (\d+)$/) {
 174             $tunnel->{version} = $1;
 175             $self->log('info', "ssh tunnel $ver\n");
 176         } else {
 177             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 178         }
 179     };
 180
 181     if ($err) {
 182         $self->finish_command_pipe($tunnel);
 183         die "can't open migration tunnel - $err";
 184     }
 185     return $tunnel;
 186 }
 187
 188 sub finish_tunnel {
 189     my ($self, $tunnel) = @_;
 190
 191     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 192     my $err = $@;
 193
 194     $self->finish_command_pipe($tunnel, 30);
 195
 196     if (my $unix_sockets = $tunnel->{unix_sockets}) {
 197         # ssh does not clean up on local host
 198         my $cmd = ['rm', '-f', @$unix_sockets];
 199         PVE::Tools::run_command($cmd);
 200
 201         # .. and just to be sure check on remote side
 202         unshift @{$cmd}, @{$self->{rem_ssh}};
 203         PVE::Tools::run_command($cmd);
 204     }
 205
 206     die $err if $err;
 207 }
 208
 209 sub start_remote_tunnel {
 210     my ($self, $raddr, $rport, $ruri, $unix_socket_info) = @_;
 211
 212     my $nodename = PVE::INotify::nodename();
 213     my $migration_type = $self->{opts}->{migration_type};
 214
 215     if ($migration_type eq 'secure') {
 216
 217         if ($ruri =~ /^unix:/) {
 218             my $ssh_forward_info = ["$raddr:$raddr"];
 219             $unix_socket_info->{$raddr} = 1;
 220
 221             my $unix_sockets = [ keys %$unix_socket_info ];
 222             for my $sock (@$unix_sockets) {
 223                 push @$ssh_forward_info, "$sock:$sock";
 224                 unlink $sock;
 225             }
 226
 227             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 228
 229             my $unix_socket_try = 0; # wait for the socket to become ready
 230             while ($unix_socket_try <= 100) {
 231                 $unix_socket_try++;
 232                 my $available = 0;
 233                 foreach my $sock (@$unix_sockets) {
 234                     if (-S $sock) {
 235                         $available++;
 236                     }
 237                 }
 238
 239                 if ($available == @$unix_sockets) {
 240                     last;
 241                 }
 242
 243                 usleep(50000);
 244             }
 245             if ($unix_socket_try > 100) {
 246                 $self->{errors} = 1;
 247                 $self->finish_tunnel($self->{tunnel});
 248                 die "Timeout, migration socket $ruri did not get ready";
 249             }
 250             $self->{tunnel}->{unix_sockets} = $unix_sockets if (@$unix_sockets);
 251
 252         } elsif ($ruri =~ /^tcp:/) {
 253             my $ssh_forward_info = [];
 254             if ($raddr eq "localhost") {
 255                 # for backwards compatibility with older qemu-server versions
 256                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 257                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 258                 push @$ssh_forward_info, "$lport:localhost:$rport";
 259             }
 260
 261             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 262
 263         } else {
 264             die "unsupported protocol in migration URI: $ruri\n";
 265         }
 266     } else {
 267         #fork tunnel for insecure migration, to send faster commands like resume
 268         $self->{tunnel} = $self->fork_tunnel();
 269     }
 270 }
 271
 272 sub lock_vm {
 273     my ($self, $vmid, $code, @param) = @_;
 274
 275     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 276 }
 277
 278 sub prepare {
 279     my ($self, $vmid) = @_;
 280
 281     my $online = $self->{opts}->{online};
 282
 283     $self->{storecfg} = PVE::Storage::config();
 284
 285     # test if VM exists
 286     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 287
 288     my $repl_conf = PVE::ReplicationConfig->new();
 289     $self->{replication_jobcfg} = $repl_conf->find_local_replication_job($vmid, $self->{node});
 290     $self->{is_replicated} = $repl_conf->check_for_existing_jobs($vmid, 1);
 291
 292     if ($self->{replication_jobcfg} && defined($self->{replication_jobcfg}->{remove_job})) {
 293         die "refusing to migrate replicated VM whose replication job is marked for removal\n";
 294     }
 295
 296     PVE::QemuConfig->check_lock($conf);
 297
 298     my $running = 0;
 299     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 300         die "can't migrate running VM without --online\n" if !$online;
 301         $running = $pid;
 302
 303         if ($self->{is_replicated} && !$self->{replication_jobcfg}) {
 304             if ($self->{opts}->{force}) {
 305                 $self->log('warn', "WARNING: Node '$self->{node}' is not a replication target. Existing " .
 306                                    "replication jobs will fail after migration!\n");
 307             } else {
 308                 die "Cannot live-migrate replicated VM to node '$self->{node}' - not a replication " .
 309                     "target. Use 'force' to override.\n";
 310             }
 311         }
 312
 313         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 314
 315         # To support custom CPU types, we keep QEMU's "-cpu" parameter intact.
 316         # Since the parameter itself contains no reference to a custom model,
 317         # this makes migration independent of changes to "cpu-models.conf".
 318         if ($conf->{cpu}) {
 319             my $cpuconf = PVE::JSONSchema::parse_property_string('pve-cpu-conf', $conf->{cpu});
 320             if ($cpuconf && PVE::QemuServer::CPUConfig::is_custom_model($cpuconf->{cputype})) {
 321                 $self->{forcecpu} = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 322             }
 323         }
 324     }
 325
 326     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 327     if (scalar @$loc_res) {
 328         if ($self->{running} || !$self->{opts}->{force}) {
 329             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 330         } else {
 331             $self->log('info', "migrating VM which uses local devices");
 332         }
 333     }
 334
 335     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 336
 337     foreach my $volid (@$vollist) {
 338         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 339
 340         # check if storage is available on both nodes
 341         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 342
 343         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 344         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 345
 346         if ($scfg->{shared}) {
 347             # PVE::Storage::activate_storage checks this for non-shared storages
 348             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 349             warn "Used shared storage '$sid' is not online on source node!\n"
 350                 if !$plugin->check_connection($sid, $scfg);
 351         }
 352     }
 353
 354     # test ssh connection
 355     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 356     eval { $self->cmd_quiet($cmd); };
 357     die "Can't connect to destination address using public key\n" if $@;
 358
 359     return $running;
 360 }
 361
 362 sub scan_local_volumes {
 363     my ($self, $vmid) = @_;
 364
 365     my $conf = $self->{vmconf};
 366
 367     # local volumes which have been copied
 368     # and their old_id => new_id pairs
 369     $self->{volume_map} = {};
 370     $self->{local_volumes} = {};
 371
 372     my $storecfg = $self->{storecfg};
 373     eval {
 374
 375         # found local volumes and their origin
 376         my $local_volumes = $self->{local_volumes};
 377         my $local_volumes_errors = {};
 378         my $other_errors = [];
 379         my $abort = 0;
 380
 381         my $log_error = sub {
 382             my ($msg, $volid) = @_;
 383
 384             if (defined($volid)) {
 385                 $local_volumes_errors->{$volid} = $msg;
 386             } else {
 387                 push @$other_errors, $msg;
 388             }
 389             $abort = 1;
 390         };
 391
 392         my @sids = PVE::Storage::storage_ids($storecfg);
 393         foreach my $storeid (@sids) {
 394             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 395             next if $scfg->{shared};
 396             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 397
 398             # get list from PVE::Storage (for unused volumes)
 399             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 400
 401             next if @{$dl->{$storeid}} == 0;
 402
 403             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $storeid);
 404             # check if storage is available on target node
 405             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 406
 407             # grandfather in existing mismatches
 408             if ($targetsid ne $storeid) {
 409                 my $target_scfg = PVE::Storage::storage_config($storecfg, $targetsid);
 410                 die "content type 'images' is not available on storage '$targetsid'\n"
 411                     if !$target_scfg->{content}->{images};
 412             }
 413
 414             my $bwlimit = PVE::Storage::get_bandwidth_limit(
 415                 'migration',
 416                 [$targetsid, $storeid],
 417                 $self->{opts}->{bwlimit},
 418             );
 419
 420             PVE::Storage::foreach_volid($dl, sub {
 421                 my ($volid, $sid, $volinfo) = @_;
 422
 423                 $local_volumes->{$volid}->{ref} = 'storage';
 424                 $local_volumes->{$volid}->{size} = $volinfo->{size};
 425                 $local_volumes->{$volid}->{targetsid} = $targetsid;
 426                 $local_volumes->{$volid}->{bwlimit} = $bwlimit;
 427
 428                 # If with_snapshots is not set for storage migrate, it tries to use
 429                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 430                 # back to qcow2 is currently not possible.
 431                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 432                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 433             });
 434         }
 435
 436         my $replicatable_volumes = !$self->{replication_jobcfg} ? {}
 437             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 438         foreach my $volid (keys %{$replicatable_volumes}) {
 439             $local_volumes->{$volid}->{replicated} = 1;
 440         }
 441
 442         my $test_volid = sub {
 443             my ($volid, $attr) = @_;
 444
 445             if ($volid =~ m|^/|) {
 446                 return if $attr->{shared};
 447                 $local_volumes->{$volid}->{ref} = 'config';
 448                 die "local file/device\n";
 449             }
 450
 451             my $snaprefs = $attr->{referenced_in_snapshot};
 452
 453             if ($attr->{cdrom}) {
 454                 if ($volid eq 'cdrom') {
 455                     my $msg = "can't migrate local cdrom drive";
 456                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 457                         my $snapnames = join(', ', sort keys %$snaprefs);
 458                         $msg .= " (referenced in snapshot - $snapnames)";
 459                     }
 460                     &$log_error("$msg\n");
 461                     return;
 462                 }
 463                 return if $volid eq 'none';
 464             }
 465
 466             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 467
 468             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 469             # check if storage is available on both nodes
 470             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 471             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 472
 473             return if $scfg->{shared};
 474
 475             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 476             $local_volumes->{$volid}->{ref} = 'storage' if $attr->{is_unused};
 477
 478             $local_volumes->{$volid}->{is_vmstate} = $attr->{is_vmstate} ? 1 : 0;
 479
 480             $local_volumes->{$volid}->{drivename} = $attr->{drivename}
 481                 if $attr->{drivename};
 482
 483             if ($attr->{cdrom}) {
 484                 if ($volid =~ /vm-\d+-cloudinit/) {
 485                     $local_volumes->{$volid}->{ref} = 'generated';
 486                     return;
 487                 }
 488                 die "local cdrom image\n";
 489             }
 490
 491             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 492
 493             die "owned by other VM (owner = VM $owner)\n"
 494                 if !$owner || ($owner != $vmid);
 495
 496             return if $attr->{is_vmstate};
 497
 498             if (defined($snaprefs)) {
 499                 $local_volumes->{$volid}->{snapshots} = 1;
 500
 501                 # we cannot migrate shapshots on local storage
 502                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 503
 504                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 505                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 506                     die "non-migratable snapshot exists\n";
 507                 }
 508             }
 509
 510             die "referenced by linked clone(s)\n"
 511                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 512         };
 513
 514         PVE::QemuServer::foreach_volid($conf, sub {
 515             my ($volid, $attr) = @_;
 516             eval { $test_volid->($volid, $attr); };
 517             if (my $err = $@) {
 518                 &$log_error($err, $volid);
 519             }
 520         });
 521
 522         foreach my $vol (sort keys %$local_volumes) {
 523             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 524             my $ref = $local_volumes->{$vol}->{ref};
 525             if ($ref eq 'storage') {
 526                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 527             } elsif ($ref eq 'config') {
 528                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 529                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 530                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 531             } elsif ($ref eq 'snapshot') {
 532                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 533             } elsif ($ref eq 'generated') {
 534                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 535             } else {
 536                 $self->log('info', "found $type disk '$vol'\n");
 537             }
 538         }
 539
 540         foreach my $vol (sort keys %$local_volumes_errors) {
 541             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 542         }
 543         foreach my $err (@$other_errors) {
 544             $self->log('warn', "$err");
 545         }
 546
 547         if ($abort) {
 548             die "can't migrate VM - check log\n";
 549         }
 550
 551         # additional checks for local storage
 552         foreach my $volid (keys %$local_volumes) {
 553             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 554             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 555
 556             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 557
 558             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 559                 if !$migratable;
 560
 561             # image is a linked clone on local storage, se we can't migrate.
 562             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 563                 die "can't migrate '$volid' as it's a clone of '$basename'";
 564             }
 565         }
 566
 567         foreach my $volid (sort keys %$local_volumes) {
 568             my $ref = $local_volumes->{$volid}->{ref};
 569             if ($self->{running} && $ref eq 'config') {
 570                 $local_volumes->{$volid}->{migration_mode} = 'online';
 571             } elsif ($self->{running} && $ref eq 'generated') {
 572                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n";
 573             } else {
 574                 $local_volumes->{$volid}->{migration_mode} = 'offline';
 575             }
 576         }
 577     };
 578     die "Problem found while scanning volumes - $@" if $@;
 579 }
 580
 581 sub handle_replication {
 582     my ($self, $vmid) = @_;
 583
 584     my $conf = $self->{vmconf};
 585     my $local_volumes = $self->{local_volumes};
 586
 587     return if !$self->{replication_jobcfg};
 588     if ($self->{running}) {
 589
 590         my $version = PVE::QemuServer::kvm_user_version();
 591         if (!min_version($version, 4, 2)) {
 592             die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 593         }
 594
 595         my @live_replicatable_volumes = $self->filter_local_volumes('online', 1);
 596         foreach my $volid (@live_replicatable_volumes) {
 597             my $drive = $local_volumes->{$volid}->{drivename};
 598             die "internal error - no drive for '$volid'\n" if !defined($drive);
 599
 600             my $bitmap = "repl_$drive";
 601
 602             # start tracking before replication to get full delta + a few duplicates
 603             $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 604             mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 605
 606             # other info comes from target node in phase 2
 607             $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 608         }
 609     }
 610     $self->log('info', "replicating disk images");
 611
 612     my $start_time = time();
 613     my $logfunc = sub { $self->log('info', shift) };
 614     my $actual_replicated_volumes = PVE::Replication::run_replication(
 615        'PVE::QemuConfig', $self->{replication_jobcfg}, $start_time, $start_time, $logfunc);
 616
 617     # extra safety check
 618     my @replicated_volumes = $self->filter_local_volumes(undef, 1);
 619     foreach my $volid (@replicated_volumes) {
 620         die "expected volume '$volid' to get replicated, but it wasn't\n"
 621             if !$actual_replicated_volumes->{$volid};
 622     }
 623 }
 624
 625 sub config_update_local_disksizes {
 626     my ($self) = @_;
 627
 628     my $conf = $self->{vmconf};
 629     my $local_volumes = $self->{local_volumes};
 630
 631     PVE::QemuConfig->foreach_volume($conf, sub {
 632         my ($key, $drive) = @_;
 633         return if $key eq 'efidisk0'; # skip efidisk, will be handled later
 634
 635         my $volid = $drive->{file};
 636         return if !defined($local_volumes->{$volid}); # only update sizes for local volumes
 637
 638         my ($updated, $msg) = PVE::QemuServer::Drive::update_disksize($drive, $local_volumes->{$volid}->{size});
 639         if (defined($updated)) {
 640             $conf->{$key} = PVE::QemuServer::print_drive($updated);
 641             $self->log('info', "drive '$key': $msg");
 642         }
 643     });
 644
 645     # we want to set the efidisk size in the config to the size of the
 646     # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 647     if (defined($conf->{efidisk0})) {
 648         PVE::QemuServer::update_efidisk_size($conf);
 649     }
 650 }
 651
 652 sub filter_local_volumes {
 653     my ($self, $migration_mode, $replicated) = @_;
 654
 655     my $volumes = $self->{local_volumes};
 656     my @filtered_volids;
 657
 658     foreach my $volid (sort keys %{$volumes}) {
 659         next if defined($migration_mode) && safe_string_ne($volumes->{$volid}->{migration_mode}, $migration_mode);
 660         next if defined($replicated) && safe_boolean_ne($volumes->{$volid}->{replicated}, $replicated);
 661         push @filtered_volids, $volid;
 662     }
 663
 664     return @filtered_volids;
 665 }
 666
 667 sub sync_offline_local_volumes {
 668     my ($self) = @_;
 669
 670     my $local_volumes = $self->{local_volumes};
 671     my @volids = $self->filter_local_volumes('offline', 0);
 672
 673     my $storecfg = $self->{storecfg};
 674     my $opts = $self->{opts};
 675
 676     $self->log('info', "copying local disk images") if scalar(@volids);
 677
 678     foreach my $volid (@volids) {
 679         my $targetsid = $local_volumes->{$volid}->{targetsid};
 680         my $bwlimit = $local_volumes->{$volid}->{bwlimit};
 681         $bwlimit = $bwlimit * 1024 if defined($bwlimit); # storage_migrate uses bps
 682
 683         my $storage_migrate_opts = {
 684             'ratelimit_bps' => $bwlimit,
 685             'insecure' => $opts->{migration_type} eq 'insecure',
 686             'with_snapshots' => $local_volumes->{$volid}->{snapshots},
 687             'allow_rename' => !$local_volumes->{$volid}->{is_vmstate},
 688         };
 689
 690         my $logfunc = sub { $self->log('info', $_[0]); };
 691         my $new_volid = eval {
 692             PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info},
 693                                           $targetsid, $storage_migrate_opts, $logfunc);
 694         };
 695         if (my $err = $@) {
 696             die "storage migration for '$volid' to storage '$targetsid' failed - $err\n";
 697         }
 698
 699         $self->{volume_map}->{$volid} = $new_volid;
 700         $self->log('info', "volume '$volid' is '$new_volid' on the target\n");
 701
 702         eval { PVE::Storage::deactivate_volumes($storecfg, [$volid]); };
 703         if (my $err = $@) {
 704             $self->log('warn', $err);
 705         }
 706     }
 707 }
 708
 709 sub cleanup_remotedisks {
 710     my ($self) = @_;
 711
 712     my $local_volumes = $self->{local_volumes};
 713
 714     foreach my $volid (values %{$self->{volume_map}}) {
 715         # don't clean up replicated disks!
 716         next if $local_volumes->{$volid}->{replicated};
 717
 718         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid);
 719
 720         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 721
 722         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 723         if (my $err = $@) {
 724             $self->log('err', $err);
 725             $self->{errors} = 1;
 726         }
 727     }
 728 }
 729
 730 sub cleanup_bitmaps {
 731     my ($self) = @_;
 732     foreach my $drive (keys %{$self->{target_drive}}) {
 733         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 734         next if !$bitmap;
 735         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 736         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 737     }
 738 }
 739
 740 sub phase1 {
 741     my ($self, $vmid) = @_;
 742
 743     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 744
 745     my $conf = $self->{vmconf};
 746
 747     # set migrate lock in config file
 748     $conf->{lock} = 'migrate';
 749     PVE::QemuConfig->write_config($vmid, $conf);
 750
 751     $self->scan_local_volumes($vmid);
 752
 753     # fix disk sizes to match their actual size and write changes,
 754     # so that the target allocates the correct volumes
 755     $self->config_update_local_disksizes();
 756     PVE::QemuConfig->write_config($vmid, $conf);
 757
 758     $self->handle_replication($vmid);
 759
 760     $self->sync_offline_local_volumes();
 761 };
 762
 763 sub phase1_cleanup {
 764     my ($self, $vmid, $err) = @_;
 765
 766     $self->log('info', "aborting phase 1 - cleanup resources");
 767
 768     my $conf = $self->{vmconf};
 769     delete $conf->{lock};
 770     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 771     if (my $err = $@) {
 772         $self->log('err', $err);
 773     }
 774
 775     eval { $self->cleanup_remotedisks() };
 776     if (my $err = $@) {
 777         $self->log('err', $err);
 778     }
 779
 780     eval { $self->cleanup_bitmaps() };
 781     if (my $err =$@) {
 782         $self->log('err', $err);
 783     }
 784 }
 785
 786 sub phase2 {
 787     my ($self, $vmid) = @_;
 788
 789     my $conf = $self->{vmconf};
 790     my $local_volumes = $self->{local_volumes};
 791     my @online_local_volumes = $self->filter_local_volumes('online');
 792
 793     $self->{storage_migration} = 1 if scalar(@online_local_volumes);
 794
 795     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 796
 797     my $raddr;
 798     my $rport;
 799     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 800     my $nodename = PVE::INotify::nodename();
 801
 802     ## start on remote node
 803     my $cmd = [@{$self->{rem_ssh}}];
 804
 805     my $spice_ticket;
 806     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 807         my $res = mon_cmd($vmid, 'query-spice');
 808         $spice_ticket = $res->{ticket};
 809     }
 810
 811     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 812
 813     my $migration_type = $self->{opts}->{migration_type};
 814
 815     push @$cmd, '--migration_type', $migration_type;
 816
 817     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 818       if $self->{opts}->{migration_network};
 819
 820     if ($migration_type eq 'insecure') {
 821         push @$cmd, '--stateuri', 'tcp';
 822     } else {
 823         push @$cmd, '--stateuri', 'unix';
 824     }
 825
 826     if ($self->{forcemachine}) {
 827         push @$cmd, '--machine', $self->{forcemachine};
 828     }
 829
 830     if ($self->{forcecpu}) {
 831         push @$cmd, '--force-cpu', $self->{forcecpu};
 832     }
 833
 834     if ($self->{storage_migration}) {
 835         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 836     }
 837
 838     my $spice_port;
 839     my $unix_socket_info = {};
 840     # version > 0 for unix socket support
 841     my $nbd_protocol_version = 1;
 842     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 843     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 844     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 845
 846     my @online_replicated_volumes = $self->filter_local_volumes('online', 1);
 847     foreach my $volid (@online_replicated_volumes) {
 848         $input .= "replicated_volume: $volid\n";
 849     }
 850
 851     my $handle_storage_migration_listens = sub {
 852         my ($drive_key, $drivestr, $nbd_uri) = @_;
 853
 854         $self->{stopnbd} = 1;
 855         $self->{target_drive}->{$drive_key}->{drivestr} = $drivestr;
 856         $self->{target_drive}->{$drive_key}->{nbd_uri} = $nbd_uri;
 857
 858         my $source_drive = PVE::QemuServer::parse_drive($drive_key, $conf->{$drive_key});
 859         my $target_drive = PVE::QemuServer::parse_drive($drive_key, $drivestr);
 860         my $source_volid = $source_drive->{file};
 861         my $target_volid = $target_drive->{file};
 862
 863         $self->{volume_map}->{$source_volid} = $target_volid;
 864         $self->log('info', "volume '$source_volid' is '$target_volid' on the target\n");
 865     };
 866
 867     my $target_replicated_volumes = {};
 868
 869     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 870     # instead we pipe it through STDIN
 871     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 872         my $line = shift;
 873
 874         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 875             $raddr = $1;
 876             $rport = int($2);
 877             $ruri = "tcp:$raddr:$rport";
 878         }
 879         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 880             $raddr = $1;
 881             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 882             $ruri = "unix:$raddr";
 883         }
 884         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 885             $raddr = "localhost";
 886             $rport = int($1);
 887             $ruri = "tcp:$raddr:$rport";
 888         }
 889         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 890             $spice_port = int($1);
 891         }
 892         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 893             my $drivestr = $4;
 894             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 895             my $targetdrive = $3;
 896             $targetdrive =~ s/drive-//g;
 897
 898             $handle_storage_migration_listens->($targetdrive, $drivestr, $nbd_uri);
 899         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 900             my $drivestr = $4;
 901             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 902             my $nbd_unix_addr = $1;
 903             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 904             my $targetdrive = $3;
 905             $targetdrive =~ s/drive-//g;
 906
 907             $handle_storage_migration_listens->($targetdrive, $drivestr, $nbd_uri);
 908             $unix_socket_info->{$nbd_unix_addr} = 1;
 909         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 910             my $drive = $1;
 911             my $volid = $2;
 912             $target_replicated_volumes->{$volid} = $drive;
 913         } elsif ($line =~ m/^QEMU: (.*)$/) {
 914             $self->log('info', "[$self->{node}] $1\n");
 915         }
 916     }, errfunc => sub {
 917         my $line = shift;
 918         $self->log('info', "[$self->{node}] $line");
 919     }, noerr => 1);
 920
 921     die "remote command failed with exit code $exitcode\n" if $exitcode;
 922
 923     die "unable to detect remote migration address\n" if !$raddr;
 924
 925     if (scalar(keys %$target_replicated_volumes) != scalar(@online_replicated_volumes)) {
 926         die "number of replicated disks on source and target node do not match - target node too old?\n"
 927     }
 928
 929     $self->log('info', "start remote tunnel");
 930     $self->start_remote_tunnel($raddr, $rport, $ruri, $unix_socket_info);
 931
 932     my $start = time();
 933
 934     if ($self->{storage_migration}) {
 935         $self->{storage_migration_jobs} = {};
 936         $self->log('info', "starting storage migration");
 937
 938         die "The number of local disks does not match between the source and the destination.\n"
 939             if (scalar(keys %{$self->{target_drive}}) != scalar(@online_local_volumes));
 940         foreach my $drive (keys %{$self->{target_drive}}){
 941             my $target = $self->{target_drive}->{$drive};
 942             my $nbd_uri = $target->{nbd_uri};
 943
 944             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 945             my $source_volid = $source_drive->{file};
 946
 947             my $bwlimit = $local_volumes->{$source_volid}->{bwlimit};
 948             my $bitmap = $target->{bitmap};
 949
 950             $self->log('info', "$drive: start migration to $nbd_uri");
 951             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 952         }
 953     }
 954
 955     $self->log('info', "starting online/live migration on $ruri");
 956     $self->{livemigration} = 1;
 957
 958     # load_defaults
 959     my $defaults = PVE::QemuServer::load_defaults();
 960
 961     $self->log('info', "set migration capabilities");
 962     eval { PVE::QemuServer::set_migration_caps($vmid) };
 963     warn $@ if $@;
 964
 965     my $qemu_migrate_params = {};
 966
 967     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 968     # migrate_speed parameter in qm.conf - take the lower of the two.
 969     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $self->{opts}->{bwlimit}) // 0;
 970     my $migrate_speed = $conf->{migrate_speed} // 0;
 971     # migrate_speed is in MB/s, bwlimit in KB/s
 972     $migrate_speed *= 1024;
 973
 974     if ($bwlimit && $migrate_speed) {
 975         $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 976     } else {
 977         $migrate_speed ||= $bwlimit;
 978     }
 979     $migrate_speed ||= ($defaults->{migrate_speed} || 0) * 1024;
 980
 981     if ($migrate_speed) {
 982         $migrate_speed *= 1024; # qmp takes migrate_speed in B/s.
 983         $self->log('info', "migration speed limit: ". render_bytes($migrate_speed, 1) ."/s");
 984         $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 985     }
 986
 987     my $migrate_downtime = $defaults->{migrate_downtime};
 988     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 989     # migrate-set-parameters expects limit in ms
 990     $migrate_downtime *= 1000;
 991     $self->log('info', "migration downtime limit: $migrate_downtime ms");
 992     $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 993
 994     # set cachesize to 10% of the total memory
 995     my $memory =  $conf->{memory} || $defaults->{memory};
 996     my $cachesize = int($memory * 1048576 / 10);
 997     $cachesize = round_powerof2($cachesize);
 998
 999     $self->log('info', "migration cachesize: " . render_bytes($cachesize, 1));
1000     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
1001
1002     $self->log('info', "set migration parameters");
1003     eval {
1004         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
1005     };
1006     $self->log('info', "migrate-set-parameters error: $@") if $@;
1007
1008     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
1009         my $rpcenv = PVE::RPCEnvironment::get();
1010         my $authuser = $rpcenv->get_user();
1011
1012         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
1013
1014         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
1015         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
1016
1017         $self->log('info', "spice client_migrate_info");
1018
1019         eval {
1020             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
1021                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
1022                                                 'cert-subject' => $subject);
1023         };
1024         $self->log('info', "client_migrate_info error: $@") if $@;
1025
1026     }
1027
1028     $self->log('info', "start migrate command to $ruri");
1029     eval {
1030         mon_cmd($vmid, "migrate", uri => $ruri);
1031     };
1032     my $merr = $@;
1033     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
1034
1035     my $last_mem_transferred = 0;
1036     my $usleep = 1000000;
1037     my $i = 0;
1038     my $err_count = 0;
1039     my $lastrem = undef;
1040     my $downtimecounter = 0;
1041     while (1) {
1042         $i++;
1043         my $avglstat = $last_mem_transferred ? $last_mem_transferred / $i : 0;
1044
1045         usleep($usleep);
1046
1047         my $stat = eval { mon_cmd($vmid, "query-migrate") };
1048         if (my $err = $@) {
1049             $err_count++;
1050             warn "query migrate failed: $err\n";
1051             $self->log('info', "query migrate failed: $err");
1052             if ($err_count <= 5) {
1053                 usleep(1_000_000);
1054                 next;
1055             }
1056             die "too many query migrate failures - aborting\n";
1057         }
1058
1059         my $status = $stat->{status};
1060         if (defined($status) && $status =~ m/^(setup)$/im) {
1061             sleep(1);
1062             next;
1063         }
1064
1065         if (!defined($status) || $status !~ m/^(active|completed|failed|cancelled)$/im) {
1066             die $merr if $merr;
1067             die "unable to parse migration status '$status' - aborting\n";
1068         }
1069         $merr = undef;
1070         $err_count = 0;
1071
1072         my $memstat = $stat->{ram};
1073
1074         if ($status eq 'completed') {
1075             my $delay = time() - $start;
1076             if ($delay > 0) {
1077                 my $total = $memstat->{total} || 0;
1078                 my $avg_speed = render_bytes($total / $delay, 1);
1079                 my $downtime = $stat->{downtime} || 0;
1080                 $self->log('info', "average migration speed: $avg_speed/s - downtime $downtime ms");
1081             }
1082         }
1083
1084         if ($status eq 'failed' || $status eq 'cancelled') {
1085             $self->log('info', "migration status error: $status");
1086             die "aborting\n"
1087         }
1088
1089         if ($status ne 'active') {
1090             $self->log('info', "migration status: $status");
1091             last;
1092         }
1093
1094         if ($memstat->{transferred} ne $last_mem_transferred) {
1095             my $trans = $memstat->{transferred} || 0;
1096             my $rem = $memstat->{remaining} || 0;
1097             my $total = $memstat->{total} || 0;
1098             my $speed = ($memstat->{'pages-per-second'} // 0) * ($memstat->{'page-size'} // 0);
1099             my $dirty_rate = ($memstat->{'dirty-pages-rate'} // 0) * ($memstat->{'page-size'} // 0);
1100
1101             # reduce sleep if remainig memory is lower than the average transfer speed
1102             $usleep = 100_000 if $avglstat && $rem < $avglstat;
1103
1104             # also reduce loggin if we poll more frequent
1105             my $should_log = $usleep > 100_000 ? 1 : ($i % 10) == 0;
1106
1107             my $total_h = render_bytes($total, 1);
1108             my $transferred_h = render_bytes($trans, 1);
1109             my $speed_h = render_bytes($speed, 1);
1110
1111             my $progress = "transferred $transferred_h of $total_h VM-state, ${speed_h}/s";
1112
1113             if ($dirty_rate > $speed) {
1114                 my $dirty_rate_h = render_bytes($dirty_rate, 1);
1115                 $progress .= ", VM dirties lots of memory: $dirty_rate_h/s";
1116             }
1117
1118             $self->log('info', "migration $status, $progress") if $should_log;
1119
1120             my $xbzrle = $stat->{"xbzrle-cache"} || {};
1121             my ($xbzrlebytes, $xbzrlepages) = $xbzrle->@{'bytes', 'pages'};
1122             if ($xbzrlebytes || $xbzrlepages) {
1123                 my $bytes_h = render_bytes($xbzrlebytes, 1);
1124
1125                 my $msg = "send updates to $xbzrlepages pages in $bytes_h encoded memory";
1126
1127                 $msg .= sprintf(", cache-miss %.2f%%", $xbzrle->{'cache-miss-rate'} * 100)
1128                     if $xbzrle->{'cache-miss-rate'};
1129
1130                 $msg .= ", overflow $xbzrle->{overflow}" if $xbzrle->{overflow};
1131
1132                 $self->log('info', "xbzrle: $msg") if $should_log;
1133             }
1134
1135             if (($lastrem && $rem > $lastrem) || ($rem == 0)) {
1136                 $downtimecounter++;
1137             }
1138             $lastrem = $rem;
1139
1140             if ($downtimecounter > 5) {
1141                 $downtimecounter = 0;
1142                 $migrate_downtime *= 2;
1143                 $self->log('info', "auto-increased downtime to continue migration: $migrate_downtime ms");
1144                 eval {
1145                     # migrate-set-parameters does not touch values not
1146                     # specified, so this only changes downtime-limit
1147                     mon_cmd($vmid, "migrate-set-parameters", 'downtime-limit' => int($migrate_downtime));
1148                 };
1149                 $self->log('info', "migrate-set-parameters error: $@") if $@;
1150             }
1151         }
1152
1153         $last_mem_transferred = $memstat->{transferred};
1154     }
1155
1156     if ($self->{storage_migration}) {
1157         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1158         # to avoid it trying to re-establish it. We are in blockjob ready state,
1159         # thus, this command changes to it to blockjob complete (see qapi docs)
1160         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1161         if (my $err = $@) {
1162             die "Failed to complete storage migration: $err\n";
1163         }
1164     }
1165 }
1166
1167 sub phase2_cleanup {
1168     my ($self, $vmid, $err) = @_;
1169
1170     return if !$self->{errors};
1171     $self->{phase2errors} = 1;
1172
1173     $self->log('info', "aborting phase 2 - cleanup resources");
1174
1175     $self->log('info', "migrate_cancel");
1176     eval {
1177         mon_cmd($vmid, "migrate_cancel");
1178     };
1179     $self->log('info', "migrate_cancel error: $@") if $@;
1180
1181     my $conf = $self->{vmconf};
1182     delete $conf->{lock};
1183     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1184     if (my $err = $@) {
1185         $self->log('err', $err);
1186     }
1187
1188     # cleanup ressources on target host
1189     if ($self->{storage_migration}) {
1190         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1191         if (my $err = $@) {
1192             $self->log('err', $err);
1193         }
1194     }
1195
1196     eval { $self->cleanup_bitmaps() };
1197     if (my $err =$@) {
1198         $self->log('err', $err);
1199     }
1200
1201     my $nodename = PVE::INotify::nodename();
1202
1203     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1204     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1205     if (my $err = $@) {
1206         $self->log('err', $err);
1207         $self->{errors} = 1;
1208     }
1209
1210     # cleanup after stopping, otherwise disks might be in-use by target VM!
1211     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1212     if (my $err = $@) {
1213         $self->log('err', $err);
1214     }
1215
1216
1217     if ($self->{tunnel}) {
1218         eval { finish_tunnel($self, $self->{tunnel});  };
1219         if (my $err = $@) {
1220             $self->log('err', $err);
1221             $self->{errors} = 1;
1222         }
1223     }
1224 }
1225
1226 sub phase3 {
1227     my ($self, $vmid) = @_;
1228
1229     return;
1230 }
1231
1232 sub phase3_cleanup {
1233     my ($self, $vmid, $err) = @_;
1234
1235     my $conf = $self->{vmconf};
1236     return if $self->{phase2errors};
1237
1238     my $tunnel = $self->{tunnel};
1239
1240     if ($self->{volume_map}) {
1241         my $target_drives = $self->{target_drive};
1242
1243         # FIXME: for NBD storage migration we now only update the volid, and
1244         # not the full drivestr from the target node. Workaround that until we
1245         # got some real rescan, to avoid things like wrong format in the drive
1246         delete $conf->{$_} for keys %$target_drives;
1247         PVE::QemuConfig->update_volume_ids($conf, $self->{volume_map});
1248
1249         for my $drive (keys %$target_drives) {
1250             $conf->{$drive} = $target_drives->{$drive}->{drivestr};
1251         }
1252         PVE::QemuConfig->write_config($vmid, $conf);
1253     }
1254
1255     # transfer replication state before move config
1256     $self->transfer_replication_state() if $self->{is_replicated};
1257     PVE::QemuConfig->move_config_to_node($vmid, $self->{node});
1258     $self->switch_replication_job_target() if $self->{is_replicated};
1259
1260     if ($self->{livemigration}) {
1261         if ($self->{stopnbd}) {
1262             $self->log('info', "stopping NBD storage migration server on target.");
1263             # stop nbd server on remote vm - requirement for resume since 2.9
1264             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1265
1266             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1267             if (my $err = $@) {
1268                 $self->log('err', $err);
1269                 $self->{errors} = 1;
1270             }
1271         }
1272
1273         # config moved and nbd server stopped - now we can resume vm on target
1274         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1275             eval {
1276                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1277             };
1278             if (my $err = $@) {
1279                 $self->log('err', $err);
1280                 $self->{errors} = 1;
1281             }
1282         } else {
1283             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1284             my $logf = sub {
1285                 my $line = shift;
1286                 $self->log('err', $line);
1287             };
1288             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1289             if (my $err = $@) {
1290                 $self->log('err', $err);
1291                 $self->{errors} = 1;
1292             }
1293         }
1294
1295         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1296             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1297             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1298         }
1299     }
1300
1301     # close tunnel on successful migration, on error phase2_cleanup closed it
1302     if ($tunnel) {
1303         eval { finish_tunnel($self, $tunnel);  };
1304         if (my $err = $@) {
1305             $self->log('err', $err);
1306             $self->{errors} = 1;
1307         }
1308     }
1309
1310     eval {
1311         my $timer = 0;
1312         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1313             $self->log('info', "Waiting for spice server migration");
1314             while (1) {
1315                 my $res = mon_cmd($vmid, 'query-spice');
1316                 last if int($res->{'migrated'}) == 1;
1317                 last if $timer > 50;
1318                 $timer ++;
1319                 usleep(200000);
1320             }
1321         }
1322     };
1323
1324     # always stop local VM
1325     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1326     if (my $err = $@) {
1327         $self->log('err', "stopping vm failed - $err");
1328         $self->{errors} = 1;
1329     }
1330
1331     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1332     eval {
1333         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1334         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1335     };
1336     if (my $err = $@) {
1337         $self->log('err', $err);
1338         $self->{errors} = 1;
1339     }
1340
1341     my @not_replicated_volumes = $self->filter_local_volumes(undef, 0);
1342
1343     # destroy local copies
1344     foreach my $volid (@not_replicated_volumes) {
1345         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1346         if (my $err = $@) {
1347             $self->log('err', "removing local copy of '$volid' failed - $err");
1348             $self->{errors} = 1;
1349             last if $err =~ /^interrupted by signal$/;
1350         }
1351     }
1352
1353     # clear migrate lock
1354     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1355     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1356 }
1357
1358 sub final_cleanup {
1359     my ($self, $vmid) = @_;
1360
1361     # nothing to do
1362 }
1363
1364 sub round_powerof2 {
1365     return 1 if $_[0] < 2;
1366     return 2 << int(log($_[0]-1)/log(2));
1367 }
1368
1369 1;