PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16
  17 use base qw(PVE::AbstractMigrate);
  18
  19 sub fork_command_pipe {
  20     my ($self, $cmd) = @_;
  21
  22     my $reader = IO::File->new();
  23     my $writer = IO::File->new();
  24
  25     my $orig_pid = $$;
  26
  27     my $cpid;
  28
  29     eval { $cpid = open2($reader, $writer, @$cmd); };
  30
  31     my $err = $@;
  32
  33     # catch exec errors
  34     if ($orig_pid != $$) {
  35         $self->log('err', "can't fork command pipe\n");
  36         POSIX::_exit(1);
  37         kill('KILL', $$);
  38     }
  39
  40     die $err if $err;
  41
  42     return { writer => $writer, reader => $reader, pid => $cpid };
  43 }
  44
  45 sub finish_command_pipe {
  46     my ($self, $cmdpipe, $timeout) = @_;
  47
  48     my $cpid = $cmdpipe->{pid};
  49     return if !defined($cpid);
  50
  51     my $writer = $cmdpipe->{writer};
  52     my $reader = $cmdpipe->{reader};
  53
  54     $writer->close();
  55     $reader->close();
  56
  57     my $collect_child_process = sub {
  58         my $res = waitpid($cpid, WNOHANG);
  59         if (defined($res) && ($res == $cpid)) {
  60             delete $cmdpipe->{cpid};
  61             return 1;
  62         } else {
  63             return 0;
  64         }
  65      };
  66
  67     if ($timeout) {
  68         for (my $i = 0; $i < $timeout; $i++) {
  69             return if &$collect_child_process();
  70             sleep(1);
  71         }
  72     }
  73
  74     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  75     kill(15, $cpid);
  76
  77     # wait again
  78     for (my $i = 0; $i < 10; $i++) {
  79         return if &$collect_child_process();
  80         sleep(1);
  81     }
  82
  83     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  84     kill 9, $cpid;
  85     sleep 1;
  86
  87     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  88         if !&$collect_child_process();
  89 }
  90
  91 sub fork_tunnel {
  92     my ($self, $tunnel_addr) = @_;
  93
  94     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
  95
  96     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, 'qm', 'mtunnel' ];
  97
  98     my $tunnel = $self->fork_command_pipe($cmd);
  99
 100     my $reader = $tunnel->{reader};
 101
 102     my $helo;
 103     eval {
 104         PVE::Tools::run_with_timeout(60, sub { $helo = <$reader>; });
 105         die "no reply\n" if !$helo;
 106         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 107         die "got strange reply from mtunnel ('$helo')\n"
 108             if $helo !~ m/^tunnel online$/;
 109     };
 110     my $err = $@;
 111
 112     if ($err) {
 113         $self->finish_command_pipe($tunnel);
 114         die "can't open migration tunnel - $err";
 115     }
 116     return $tunnel;
 117 }
 118
 119 sub finish_tunnel {
 120     my ($self, $tunnel) = @_;
 121
 122     my $writer = $tunnel->{writer};
 123
 124     eval {
 125         PVE::Tools::run_with_timeout(30, sub {
 126             print $writer "quit\n";
 127             $writer->flush();
 128         });
 129     };
 130     my $err = $@;
 131
 132     $self->finish_command_pipe($tunnel, 30);
 133
 134     if ($tunnel->{sock_addr}) {
 135         # ssh does not clean up on local host
 136         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 137         PVE::Tools::run_command($cmd);
 138
 139         # .. and just to be sure check on remote side
 140         unshift @{$cmd}, @{$self->{rem_ssh}};
 141         PVE::Tools::run_command($cmd);
 142     }
 143
 144     die $err if $err;
 145 }
 146
 147 sub lock_vm {
 148     my ($self, $vmid, $code, @param) = @_;
 149
 150     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 151 }
 152
 153 sub prepare {
 154     my ($self, $vmid) = @_;
 155
 156     my $online = $self->{opts}->{online};
 157
 158     $self->{storecfg} = PVE::Storage::config();
 159
 160     # test if VM exists
 161     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 162
 163     PVE::QemuConfig->check_lock($conf);
 164
 165     my $running = 0;
 166     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 167         die "can't migrate running VM without --online\n" if !$online;
 168         $running = $pid;
 169
 170         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 171
 172     }
 173
 174     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 175         if ($self->{running} || !$self->{opts}->{force}) {
 176             die "can't migrate VM which uses local devices\n";
 177         } else {
 178             $self->log('info', "migrating VM which uses local devices");
 179         }
 180     }
 181
 182     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 183
 184     my $need_activate = [];
 185     foreach my $volid (@$vollist) {
 186         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 187
 188         # check if storage is available on both nodes
 189         my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 190
 191         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 192         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 193
 194         if ($scfg->{shared}) {
 195             # PVE::Storage::activate_storage checks this for non-shared storages
 196             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 197             warn "Used shared storage '$sid' is not online on source node!\n"
 198                 if !$plugin->check_connection($sid, $scfg);
 199         } else {
 200             # only activate if not shared
 201             push @$need_activate, $volid;
 202         }
 203     }
 204
 205     # activate volumes
 206     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 207
 208     # test ssh connection
 209     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 210     eval { $self->cmd_quiet($cmd); };
 211     die "Can't connect to destination address using public key\n" if $@;
 212
 213     return $running;
 214 }
 215
 216 sub sync_disks {
 217     my ($self, $vmid) = @_;
 218
 219     my $conf = $self->{vmconf};
 220
 221     # local volumes which have been copied
 222     $self->{volumes} = [];
 223
 224     my $res = [];
 225
 226     eval {
 227
 228         # found local volumes and their origin
 229         my $local_volumes = {};
 230         my $local_volumes_errors = {};
 231         my $other_errors = [];
 232         my $abort = 0;
 233
 234         my $sharedvm = 1;
 235
 236         my $log_error = sub {
 237             my ($msg, $volid) = @_;
 238
 239             if (defined($volid)) {
 240                 $local_volumes_errors->{$volid} = $msg;
 241             } else {
 242                 push @$other_errors, $msg;
 243             }
 244             $abort = 1;
 245         };
 246
 247         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 248         foreach my $storeid (@sids) {
 249             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 250             next if $scfg->{shared};
 251             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 252
 253             # get list from PVE::Storage (for unused volumes)
 254             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 255
 256             next if @{$dl->{$storeid}} == 0;
 257
 258             # check if storage is available on target node
 259             PVE::Storage::storage_check_node($self->{storecfg}, $storeid, $self->{node});
 260             $sharedvm = 0; # there is a non-shared disk
 261
 262             PVE::Storage::foreach_volid($dl, sub {
 263                 my ($volid, $sid, $volname) = @_;
 264
 265                 $local_volumes->{$volid} = 'storage';
 266             });
 267         }
 268
 269         my $test_volid = sub {
 270             my ($volid, $is_cdrom, $snapname) = @_;
 271
 272             return if !$volid;
 273
 274             if ($volid =~ m|^/|) {
 275                 $local_volumes->{$volid} = 'config';
 276                 die "local file/device\n";
 277             }
 278
 279             if ($is_cdrom) {
 280                 if ($volid eq 'cdrom') {
 281                     my $msg = "can't migrate local cdrom drive";
 282                     $msg .= " (referenced in snapshot '$snapname')"
 283                         if defined($snapname);
 284
 285                     &$log_error("$msg\n");
 286                     return;
 287                 }
 288                 return if $volid eq 'none';
 289             }
 290
 291             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 292
 293             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 294             # check if storage is available on both nodes
 295             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 296             PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 297
 298             return if $scfg->{shared};
 299
 300             $sharedvm = 0;
 301
 302             $local_volumes->{$volid} = defined($snapname) ? 'snapshot' : 'config';
 303
 304             die "local cdrom image\n" if $is_cdrom;
 305
 306             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 307
 308             die "owned by other VM (owner = VM $owner)\n"
 309                 if !$owner || ($owner != $self->{vmid});
 310
 311             if (defined($snapname)) {
 312                 # we cannot migrate shapshots on local storage
 313                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 314
 315                 my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 316                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 317                 if (!($scfg->{type} eq 'zfspool' || $format eq 'qcow2')) {
 318                     die "non-migratable snapshot exists\n";
 319                 }
 320             }
 321
 322             die "referenced by linked clone(s)\n"
 323                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 324         };
 325
 326         my $test_drive = sub {
 327             my ($ds, $drive, $snapname) = @_;
 328
 329             eval {
 330                 &$test_volid($drive->{file}, PVE::QemuServer::drive_is_cdrom($drive), $snapname);
 331             };
 332
 333             &$log_error($@, $drive->{file}) if $@;
 334         };
 335
 336         foreach my $snapname (keys %{$conf->{snapshots}}) {
 337             eval {
 338                 &$test_volid($conf->{snapshots}->{$snapname}->{'vmstate'}, 0, undef)
 339                     if defined($conf->{snapshots}->{$snapname}->{'vmstate'});
 340             };
 341             &$log_error($@, $conf->{snapshots}->{$snapname}->{'vmstate'}) if $@;
 342
 343             PVE::QemuServer::foreach_drive($conf->{snapshots}->{$snapname}, $test_drive, $snapname);
 344         }
 345         PVE::QemuServer::foreach_drive($conf, $test_drive);
 346
 347         foreach my $vol (sort keys %$local_volumes) {
 348             if ($local_volumes->{$vol} eq 'storage') {
 349                 $self->log('info', "found local disk '$vol' (via storage)\n");
 350             } elsif ($local_volumes->{$vol} eq 'config') {
 351                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 352             } elsif ($local_volumes->{$vol} eq 'snapshot') {
 353                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 354             } else {
 355                 $self->log('info', "found local disk '$vol'\n");
 356             }
 357         }
 358
 359         foreach my $vol (sort keys %$local_volumes_errors) {
 360             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 361         }
 362         foreach my $err (@$other_errors) {
 363             $self->log('warn', "$err");
 364         }
 365
 366         if ($self->{running} && !$sharedvm && !$self->{opts}->{targetstorage}) {
 367             $self->{opts}->{targetstorage} = 1; #use same sid for remote local
 368         }
 369
 370         if ($abort) {
 371             die "can't migrate VM - check log\n";
 372         }
 373
 374         # additional checks for local storage
 375         foreach my $volid (keys %$local_volumes) {
 376             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 377             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 378
 379             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 380                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 381
 382             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 383                 if !$migratable;
 384
 385             # image is a linked clone on local storage, se we can't migrate.
 386             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 387                 die "can't migrate '$volid' as it's a clone of '$basename'";
 388             }
 389         }
 390
 391         $self->log('info', "copying disk images");
 392
 393         foreach my $volid (keys %$local_volumes) {
 394             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 395             if ($self->{running} && $self->{opts}->{targetstorage} && $local_volumes->{$volid} eq 'config') {
 396                 push @{$self->{online_local_volumes}}, $volid;
 397             } else {
 398                 push @{$self->{volumes}}, $volid;
 399                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{nodeip}, $sid);
 400             }
 401         }
 402     };
 403     die "Failed to sync data - $@" if $@;
 404 }
 405
 406 sub cleanup_remotedisks {
 407     my ($self) = @_;
 408
 409     foreach my $target_drive (keys %{$self->{target_drive}}) {
 410
 411         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 412         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 413
 414         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 415
 416         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 417         if (my $err = $@) {
 418             $self->log('err', $err);
 419             $self->{errors} = 1;
 420         }
 421     }
 422 }
 423
 424 sub phase1 {
 425     my ($self, $vmid) = @_;
 426
 427     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 428
 429     my $conf = $self->{vmconf};
 430
 431     # set migrate lock in config file
 432     $conf->{lock} = 'migrate';
 433     PVE::QemuConfig->write_config($vmid, $conf);
 434
 435     sync_disks($self, $vmid);
 436
 437 };
 438
 439 sub phase1_cleanup {
 440     my ($self, $vmid, $err) = @_;
 441
 442     $self->log('info', "aborting phase 1 - cleanup resources");
 443
 444     my $conf = $self->{vmconf};
 445     delete $conf->{lock};
 446     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 447     if (my $err = $@) {
 448         $self->log('err', $err);
 449     }
 450
 451     if ($self->{volumes}) {
 452         foreach my $volid (@{$self->{volumes}}) {
 453             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 454             # fixme: try to remove ?
 455         }
 456     }
 457 }
 458
 459 sub phase2 {
 460     my ($self, $vmid) = @_;
 461
 462     my $conf = $self->{vmconf};
 463
 464     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 465
 466     my $raddr;
 467     my $rport;
 468     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 469     my $nodename = PVE::INotify::nodename();
 470
 471     ## start on remote node
 472     my $cmd = [@{$self->{rem_ssh}}];
 473
 474     my $spice_ticket;
 475     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 476         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 477         $spice_ticket = $res->{ticket};
 478     }
 479
 480     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 481
 482     # we use TCP only for unsecure migrations as TCP ssh forward tunnels often
 483     # did appeared to late (they are hard, if not impossible, to check for)
 484     # secure migration use UNIX sockets now, this *breaks* compatibilty when trying
 485     # to migrate from new to old but *not* from old to new.
 486     my $datacenterconf = PVE::Cluster::cfs_read_file('datacenter.cfg');
 487
 488     my $migration_type = 'secure';
 489     if (defined($self->{opts}->{migration_type})) {
 490         $migration_type = $self->{opts}->{migration_type};
 491     } elsif (defined($datacenterconf->{migration}->{type})) {
 492         $migration_type = $datacenterconf->{migration}->{type};
 493     }
 494
 495     push @$cmd, '--migration_type', $migration_type;
 496
 497     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 498       if $self->{opts}->{migration_network};
 499
 500     if ($migration_type eq 'insecure') {
 501         push @$cmd, '--stateuri', 'tcp';
 502     } else {
 503         push @$cmd, '--stateuri', 'unix';
 504     }
 505
 506     if ($self->{forcemachine}) {
 507         push @$cmd, '--machine', $self->{forcemachine};
 508     }
 509
 510     if ($self->{opts}->{targetstorage}) {
 511         push @$cmd, '--targetstorage', $self->{opts}->{targetstorage};
 512     }
 513
 514     my $spice_port;
 515
 516     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 517     # instead we pipe it through STDIN
 518     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 519         my $line = shift;
 520
 521         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 522             $raddr = $1;
 523             $rport = int($2);
 524             $ruri = "tcp:$raddr:$rport";
 525         }
 526         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 527             $raddr = $1;
 528             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 529             $ruri = "unix:$raddr";
 530         }
 531         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 532             $raddr = "localhost";
 533             $rport = int($1);
 534             $ruri = "tcp:$raddr:$rport";
 535         }
 536         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 537             $spice_port = int($1);
 538         }
 539         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 540             my $volid = $4;
 541             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 542             my $targetdrive = $3;
 543             $targetdrive =~ s/drive-//g;
 544
 545             $self->{target_drive}->{$targetdrive}->{volid} = $volid;
 546             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 547
 548         }
 549     }, errfunc => sub {
 550         my $line = shift;
 551         $self->log('info', $line);
 552     });
 553
 554     die "unable to detect remote migration address\n" if !$raddr;
 555
 556     if ($migration_type eq 'secure') {
 557         $self->log('info', "start remote tunnel");
 558
 559         if ($ruri =~ /^unix:/) {
 560             unlink $raddr;
 561             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 562             $self->{tunnel}->{sock_addr} = $raddr;
 563
 564             my $unix_socket_try = 0; # wait for the socket to become ready
 565             while (! -S $raddr) {
 566                 $unix_socket_try++;
 567                 if ($unix_socket_try > 100) {
 568                     $self->{errors} = 1;
 569                     $self->finish_tunnel($self->{tunnel});
 570                     die "Timeout, migration socket $ruri did not get ready";
 571                 }
 572
 573                 usleep(50000);
 574             }
 575
 576         } elsif ($ruri =~ /^tcp:/) {
 577             my $tunnel_addr;
 578             if ($raddr eq "localhost") {
 579                 # for backwards compatibility with older qemu-server versions
 580                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 581                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 582                 $tunnel_addr = "$lport:localhost:$rport";
 583             }
 584
 585             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 586
 587         } else {
 588             die "unsupported protocol in migration URI: $ruri\n";
 589         }
 590     }
 591
 592     my $start = time();
 593
 594     if ($self->{opts}->{targetstorage}) {
 595         $self->{storage_migration} = 1;
 596         $self->{storage_migration_jobs} = {};
 597         $self->log('info', "starting storage migration");
 598
 599         die "The number of local disks does not match between the source and the destination.\n"
 600             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 601         foreach my $drive (keys %{$self->{target_drive}}){
 602             my $nbd_uri = $self->{target_drive}->{$drive}->{nbd_uri};
 603             $self->log('info', "$drive: start migration to to $nbd_uri");
 604             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 1);
 605         }
 606     }
 607
 608     $self->log('info', "starting online/live migration on $ruri");
 609     $self->{livemigration} = 1;
 610
 611     # load_defaults
 612     my $defaults = PVE::QemuServer::load_defaults();
 613
 614     # always set migrate speed (overwrite kvm default of 32m)
 615     # we set a very hight default of 8192m which is basically unlimited
 616     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 617     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 618     $migrate_speed = $migrate_speed * 1048576;
 619     $self->log('info', "migrate_set_speed: $migrate_speed");
 620     eval {
 621         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 622     };
 623     $self->log('info', "migrate_set_speed error: $@") if $@;
 624
 625     my $migrate_downtime = $defaults->{migrate_downtime};
 626     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 627     if (defined($migrate_downtime)) {
 628         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 629         eval {
 630             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 631         };
 632         $self->log('info', "migrate_set_downtime error: $@") if $@;
 633     }
 634
 635     $self->log('info', "set migration_caps");
 636     eval {
 637         PVE::QemuServer::set_migration_caps($vmid);
 638     };
 639     warn $@ if $@;
 640
 641     #set cachesize 10% of the total memory
 642     my $cachesize = int($conf->{memory}*1048576/10);
 643     $self->log('info', "set cachesize: $cachesize");
 644     eval {
 645         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 646     };
 647     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 648
 649     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 650         my $rpcenv = PVE::RPCEnvironment::get();
 651         my $authuser = $rpcenv->get_user();
 652
 653         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 654
 655         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 656         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 657
 658         $self->log('info', "spice client_migrate_info");
 659
 660         eval {
 661             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 662                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 663                                                 'cert-subject' => $subject);
 664         };
 665         $self->log('info', "client_migrate_info error: $@") if $@;
 666
 667     }
 668
 669     $self->log('info', "start migrate command to $ruri");
 670     eval {
 671         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 672     };
 673     my $merr = $@;
 674     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 675
 676     my $lstat = 0;
 677     my $usleep = 2000000;
 678     my $i = 0;
 679     my $err_count = 0;
 680     my $lastrem = undef;
 681     my $downtimecounter = 0;
 682     while (1) {
 683         $i++;
 684         my $avglstat = $lstat/$i if $lstat;
 685
 686         usleep($usleep);
 687         my $stat;
 688         eval {
 689             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 690         };
 691         if (my $err = $@) {
 692             $err_count++;
 693             warn "query migrate failed: $err\n";
 694             $self->log('info', "query migrate failed: $err");
 695             if ($err_count <= 5) {
 696                 usleep(1000000);
 697                 next;
 698             }
 699             die "too many query migrate failures - aborting\n";
 700         }
 701
 702         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 703             sleep(1);
 704             next;
 705         }
 706
 707         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 708             $merr = undef;
 709             $err_count = 0;
 710             if ($stat->{status} eq 'completed') {
 711                 my $delay = time() - $start;
 712                 if ($delay > 0) {
 713                     my $mbps = sprintf "%.2f", $conf->{memory}/$delay;
 714                     my $downtime = $stat->{downtime} || 0;
 715                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 716                 }
 717             }
 718
 719             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 720                 $self->log('info', "migration status error: $stat->{status}");
 721                 die "aborting\n"
 722             }
 723
 724             if ($stat->{status} ne 'active') {
 725                 $self->log('info', "migration status: $stat->{status}");
 726                 last;
 727             }
 728
 729             if ($stat->{ram}->{transferred} ne $lstat) {
 730                 my $trans = $stat->{ram}->{transferred} || 0;
 731                 my $rem = $stat->{ram}->{remaining} || 0;
 732                 my $total = $stat->{ram}->{total} || 0;
 733                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 734                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 735                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 736                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 737                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 738                 #reduce sleep if remainig memory if lower than the everage transfert
 739                 $usleep = 300000 if $avglstat && $rem < $avglstat;
 740
 741                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 742                            "remaining ${rem}), total ${total})");
 743
 744                 if (${xbzrlecachesize}) {
 745                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 746                 }
 747
 748                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 749                     $downtimecounter++;
 750                 }
 751                 $lastrem = $rem;
 752
 753                 if ($downtimecounter > 5) {
 754                     $downtimecounter = 0;
 755                     $migrate_downtime *= 2;
 756                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 757                     eval {
 758                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 759                     };
 760                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 761                 }
 762
 763             }
 764
 765
 766             $lstat = $stat->{ram}->{transferred};
 767
 768         } else {
 769             die $merr if $merr;
 770             die "unable to parse migration status '$stat->{status}' - aborting\n";
 771         }
 772     }
 773
 774     # just to be sure that the tunnel gets closed on successful migration, on error
 775     # phase2_cleanup closes it *after* stopping the remote waiting VM
 776     if (!$self->{errors} && $self->{tunnel}) {
 777         eval { finish_tunnel($self, $self->{tunnel});  };
 778         if (my $err = $@) {
 779             $self->log('err', $err);
 780             $self->{errors} = 1;
 781         }
 782     }
 783 }
 784
 785 sub phase2_cleanup {
 786     my ($self, $vmid, $err) = @_;
 787
 788     return if !$self->{errors};
 789     $self->{phase2errors} = 1;
 790
 791     $self->log('info', "aborting phase 2 - cleanup resources");
 792
 793     $self->log('info', "migrate_cancel");
 794     eval {
 795         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 796     };
 797     $self->log('info', "migrate_cancel error: $@") if $@;
 798
 799     my $conf = $self->{vmconf};
 800     delete $conf->{lock};
 801     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 802     if (my $err = $@) {
 803         $self->log('err', $err);
 804     }
 805
 806     # cleanup ressources on target host
 807     if ($self->{storage_migration}) {
 808
 809         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 810         if (my $err = $@) {
 811             $self->log('err', $err);
 812         }
 813
 814         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 815         if (my $err = $@) {
 816             $self->log('err', $err);
 817         }
 818     }
 819
 820     my $nodename = PVE::INotify::nodename();
 821
 822     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 823     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 824     if (my $err = $@) {
 825         $self->log('err', $err);
 826         $self->{errors} = 1;
 827     }
 828
 829     if ($self->{tunnel}) {
 830         eval { finish_tunnel($self, $self->{tunnel});  };
 831         if (my $err = $@) {
 832             $self->log('err', $err);
 833             $self->{errors} = 1;
 834         }
 835     }
 836 }
 837
 838 sub phase3 {
 839     my ($self, $vmid) = @_;
 840
 841     my $volids = $self->{volumes};
 842     return if $self->{phase2errors};
 843
 844     # destroy local copies
 845     foreach my $volid (@$volids) {
 846         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 847         if (my $err = $@) {
 848             $self->log('err', "removing local copy of '$volid' failed - $err");
 849             $self->{errors} = 1;
 850             last if $err =~ /^interrupted by signal$/;
 851         }
 852     }
 853 }
 854
 855 sub phase3_cleanup {
 856     my ($self, $vmid, $err) = @_;
 857
 858     my $conf = $self->{vmconf};
 859     return if $self->{phase2errors};
 860
 861     if ($self->{storage_migration}) {
 862         # finish block-job
 863         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}); };
 864
 865         if (my $err = $@) {
 866             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 867             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 868             die "Failed to completed storage migration\n";
 869         } else {
 870             foreach my $target_drive (keys %{$self->{target_drive}}) {
 871                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 872                 $conf->{$target_drive} = PVE::QemuServer::print_drive($vmid, $drive);
 873                 PVE::QemuConfig->write_config($vmid, $conf);
 874             }
 875         }
 876     }
 877
 878     # move config to remote node
 879     my $conffile = PVE::QemuConfig->config_file($vmid);
 880     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 881
 882     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 883         if !rename($conffile, $newconffile);
 884
 885     if ($self->{livemigration}) {
 886         # now that config file is move, we can resume vm on target if livemigrate
 887         my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 888         eval{ PVE::Tools::run_command($cmd, outfunc => sub {},
 889                 errfunc => sub {
 890                     my $line = shift;
 891                     $self->log('err', $line);
 892                 });
 893         };
 894         if (my $err = $@) {
 895             $self->log('err', $err);
 896             $self->{errors} = 1;
 897         }
 898     }
 899
 900     eval {
 901         my $timer = 0;
 902         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
 903             $self->log('info', "Waiting for spice server migration");
 904             while (1) {
 905                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
 906                 last if int($res->{'migrated'}) == 1;
 907                 last if $timer > 50;
 908                 $timer ++;
 909                 usleep(200000);
 910             }
 911         }
 912     };
 913
 914     # always stop local VM
 915     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 916     if (my $err = $@) {
 917         $self->log('err', "stopping vm failed - $err");
 918         $self->{errors} = 1;
 919     }
 920
 921     # always deactivate volumes - avoid lvm LVs to be active on several nodes
 922     eval {
 923         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 924         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
 925     };
 926     if (my $err = $@) {
 927         $self->log('err', $err);
 928         $self->{errors} = 1;
 929     }
 930
 931     if($self->{storage_migration}) {
 932         # destroy local copies
 933         my $volids = $self->{online_local_volumes};
 934
 935         foreach my $volid (@$volids) {
 936             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 937             if (my $err = $@) {
 938                 $self->log('err', "removing local copy of '$volid' failed - $err");
 939                 $self->{errors} = 1;
 940                 last if $err =~ /^interrupted by signal$/;
 941             }
 942         }
 943
 944         #stop nbd server to remote vm
 945         my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
 946
 947         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 948         if (my $err = $@) {
 949             $self->log('err', $err);
 950             $self->{errors} = 1;
 951         }
 952     }
 953
 954     # clear migrate lock
 955     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
 956     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
 957 }
 958
 959 sub final_cleanup {
 960     my ($self, $vmid) = @_;
 961
 962     # nothing to do
 963 }
 964
 965 1;