PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use PVE::INotify;
   9 use PVE::Cluster;
  10 use PVE::Storage;
  11 use PVE::QemuServer;
  12
  13 use base qw(PVE::AbstractMigrate);
  14
  15 sub fork_command_pipe {
  16     my ($self, $cmd) = @_;
  17
  18     my $reader = IO::File->new();
  19     my $writer = IO::File->new();
  20
  21     my $orig_pid = $$;
  22
  23     my $cpid;
  24
  25     eval { $cpid = open2($reader, $writer, @$cmd); };
  26
  27     my $err = $@;
  28
  29     # catch exec errors
  30     if ($orig_pid != $$) {
  31         $self->log('err', "can't fork command pipe\n");
  32         POSIX::_exit(1);
  33         kill('KILL', $$);
  34     }
  35
  36     die $err if $err;
  37
  38     return { writer => $writer, reader => $reader, pid => $cpid };
  39 }
  40
  41 sub finish_command_pipe {
  42     my ($self, $cmdpipe, $timeout) = @_;
  43
  44     my $writer = $cmdpipe->{writer};
  45     my $reader = $cmdpipe->{reader};
  46
  47     $writer->close();
  48     $reader->close();
  49
  50     my $cpid = $cmdpipe->{pid};
  51
  52     if ($timeout) {
  53         for (my $i = 0; $i < $timeout; $i++) {
  54             return if !PVE::ProcFSTools::check_process_running($cpid);
  55             sleep(1);
  56         }
  57     }
  58
  59     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  60     kill(15, $cpid);
  61
  62     # wait again
  63     for (my $i = 0; $i < 10; $i++) {
  64         return if !PVE::ProcFSTools::check_process_running($cpid);
  65         sleep(1);
  66     }
  67
  68     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  69     kill 9, $cpid;
  70     sleep 1;
  71 }
  72
  73 sub fork_tunnel {
  74     my ($self, $nodeip, $lport, $rport) = @_;
  75
  76     my $cmd = [@{$self->{rem_ssh}}, '-L', "$lport:localhost:$rport",
  77                'qm', 'mtunnel' ];
  78
  79     my $tunnel = $self->fork_command_pipe($cmd);
  80
  81     my $reader = $tunnel->{reader};
  82
  83     my $helo;
  84     eval {
  85         PVE::Tools::run_with_timeout(60, sub { $helo = <$reader>; });
  86         die "no reply\n" if !$helo;
  87         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
  88         die "got strange reply from mtunnel ('$helo')\n"
  89             if $helo !~ m/^tunnel online$/;
  90     };
  91     my $err = $@;
  92
  93     if ($err) {
  94         $self->finish_command_pipe($tunnel);
  95         die "can't open migration tunnel - $err";
  96     }
  97     return $tunnel;
  98 }
  99
 100 sub finish_tunnel {
 101     my ($self, $tunnel) = @_;
 102
 103     my $writer = $tunnel->{writer};
 104
 105     eval {
 106         PVE::Tools::run_with_timeout(30, sub {
 107             print $writer "quit\n";
 108             $writer->flush();
 109         });
 110     };
 111     my $err = $@;
 112
 113     $self->finish_command_pipe($tunnel, 30);
 114
 115     die $err if $err;
 116 }
 117
 118 sub lock_vm {
 119     my ($self, $vmid, $code, @param) = @_;
 120
 121     return PVE::QemuServer::lock_config($vmid, $code, @param);
 122 }
 123
 124 sub prepare {
 125     my ($self, $vmid) = @_;
 126
 127     my $online = $self->{opts}->{online};
 128
 129     $self->{storecfg} = PVE::Storage::config();
 130
 131     # test is VM exist
 132     my $conf = $self->{vmconf} = PVE::QemuServer::load_config($vmid);
 133
 134     PVE::QemuServer::check_lock($conf);
 135
 136     my $running = 0;
 137     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 138         die "cant migrate running VM without --online\n" if !$online;
 139         $running = $pid;
 140     }
 141
 142     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 143         if ($self->{running} || !$self->{opts}->{force}) {
 144             die "can't migrate VM which uses local devices\n";
 145         } else {
 146             $self->log('info', "migrating VM which uses local devices");
 147         }
 148     }
 149
 150     # activate volumes
 151     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 152     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 153
 154     # fixme: check if storage is available on both nodes
 155
 156     # test ssh connection
 157     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 158     eval { $self->cmd_quiet($cmd); };
 159     die "Can't connect to destination address using public key\n" if $@;
 160
 161     return $running;
 162 }
 163
 164 sub sync_disks {
 165     my ($self, $vmid) = @_;
 166
 167     $self->log('info', "copying disk images");
 168
 169     my $conf = $self->{vmconf};
 170
 171     $self->{volumes} = [];
 172
 173     my $res = [];
 174
 175     eval {
 176
 177         my $volhash = {};
 178         my $cdromhash = {};
 179
 180         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 181         foreach my $storeid (@sids) {
 182             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 183             next if $scfg->{shared};
 184             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 185
 186             # get list from PVE::Storage (for unused volumes)
 187             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 188             PVE::Storage::foreach_volid($dl, sub {
 189                 my ($volid, $sid, $volname) = @_;
 190
 191                 # check if storage is available on target node
 192                 PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 193
 194                 $volhash->{$volid} = 1;
 195             });
 196         }
 197
 198         # and add used,owned/non-shared disks (just to be sure we have all)
 199
 200         my $sharedvm = 1;
 201         PVE::QemuServer::foreach_drive($conf, sub {
 202             my ($ds, $drive) = @_;
 203
 204             my $volid = $drive->{file};
 205             return if !$volid;
 206
 207             die "cant migrate local file/device '$volid'\n" if $volid =~ m|^/|;
 208
 209             if (PVE::QemuServer::drive_is_cdrom($drive)) {
 210                 die "cant migrate local cdrom drive\n" if $volid eq 'cdrom';
 211                 return if $volid eq 'none';
 212                 $cdromhash->{$volid} = 1;
 213             }
 214
 215             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 216
 217             # check if storage is available on both nodes
 218             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 219             PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 220
 221             return if $scfg->{shared};
 222
 223             die "can't migrate local cdrom '$volid'\n" if $cdromhash->{$volid};
 224
 225             $sharedvm = 0;
 226
 227             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 228
 229             die "can't migrate volume '$volid' - owned by other VM (owner = VM $owner)\n"
 230                 if !$owner || ($owner != $self->{vmid});
 231
 232             $volhash->{$volid} = 1;
 233         });
 234
 235         if ($self->{running} && !$sharedvm) {
 236             die "can't do online migration - VM uses local disks\n";
 237         }
 238
 239         # do some checks first
 240         foreach my $volid (keys %$volhash) {
 241             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 242             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 243
 244             die "can't migrate '$volid' - storagy type '$scfg->{type}' not supported\n"
 245                 if $scfg->{type} ne 'dir';
 246         }
 247
 248         foreach my $volid (keys %$volhash) {
 249             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 250             push @{$self->{volumes}}, $volid;
 251             PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{nodeip}, $sid);
 252         }
 253     };
 254     die "Failed to sync data - $@" if $@;
 255 }
 256
 257 sub phase1 {
 258     my ($self, $vmid) = @_;
 259
 260     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 261
 262     my $conf = $self->{vmconf};
 263
 264     # set migrate lock in config file
 265     $conf->{lock} = 'migrate';
 266     PVE::QemuServer::update_config_nolock($vmid, $conf, 1);
 267
 268     sync_disks($self, $vmid);
 269
 270 };
 271
 272 sub phase1_cleanup {
 273     my ($self, $vmid, $err) = @_;
 274
 275     $self->log('info', "aborting phase 1 - cleanup resources");
 276
 277     my $conf = $self->{vmconf};
 278     delete $conf->{lock};
 279     eval { PVE::QemuServer::update_config_nolock($vmid, $conf, 1) };
 280     if (my $err = $@) {
 281         $self->log('err', $err);
 282     }
 283
 284     if ($self->{volumes}) {
 285         foreach my $volid (@{$self->{volumes}}) {
 286             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 287             # fixme: try to remove ?
 288         }
 289     }
 290 }
 291
 292 sub phase2 {
 293     my ($self, $vmid) = @_;
 294
 295     my $conf = $self->{vmconf};
 296
 297     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 298
 299     my $rport;
 300
 301     ## start on remote node
 302     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'start',
 303                $vmid, '--stateuri', 'tcp', '--skiplock'];
 304
 305     PVE::Tools::run_command($cmd, outfunc => sub {
 306         my $line = shift;
 307
 308         if ($line =~ m/^migration listens on port (\d+)$/) {
 309             $rport = $1;
 310         }
 311     }, errfunc => sub {});
 312
 313     die "unable to detect remote migration port\n" if !$rport;
 314
 315     $self->log('info', "starting migration tunnel");
 316
 317     ## create tunnel to remote port
 318     my $lport = PVE::QemuServer::next_migrate_port();
 319     $self->{tunnel} = $self->fork_tunnel($self->{nodeip}, $lport, $rport);
 320
 321     $self->log('info', "starting online/live migration on port $lport");
 322     # start migration
 323
 324     my $start = time();
 325     eval {
 326         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => "tcp:localhost:$lport");
 327     };
 328     my $merr = $@;
 329
 330     my $lstat = 0;
 331     while (1) {
 332         sleep (2);
 333         my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 334         if ($stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 335             $merr = undef;
 336
 337             if ($stat->{status} eq 'completed') {
 338                 my $delay = time() - $start;
 339                 if ($delay > 0) {
 340                     my $mbps = sprintf "%.2f", $conf->{memory}/$delay;
 341                     $self->log('info', "migration speed: $mbps MB/s");
 342                 }
 343             }
 344
 345             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 346                 die "aborting\n"
 347             }
 348
 349             if ($stat->{status} ne 'active') {
 350                 $self->log('info', "migration status: $stat->{status}");
 351                 last;
 352             }
 353
 354             if ($stat->{ram}->{transferred} ne $lstat) {
 355                 my $trans = $stat->{ram}->{transferred} || 0;
 356                 my $rem = $stat->{ram}->{remaining} || 0;
 357                 my $total = $stat->{ram}->{total} || 0;
 358
 359                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 360                            "remaining ${rem}), total ${total})");
 361             }
 362
 363             $lstat = $stat->{ram}->{transferred};
 364
 365         } else {
 366             die $merr if $merr;
 367             die "unable to parse migration status '$stat->{status}' - aborting\n";
 368         }
 369     }
 370 }
 371
 372 sub phase2_cleanup {
 373     my ($self, $vmid, $err) = @_;
 374
 375     $self->log('info', "aborting phase 2 - cleanup resources");
 376
 377     my $conf = $self->{vmconf};
 378     delete $conf->{lock};
 379     eval { PVE::QemuServer::update_config_nolock($vmid, $conf, 1) };
 380     if (my $err = $@) {
 381         $self->log('err', $err);
 382     }
 383
 384     ## fixme : vm_stop_cleanup on target vm
 385
 386
 387 }
 388
 389 sub phase3 {
 390     my ($self, $vmid) = @_;
 391
 392     my $volids = $self->{volumes};
 393
 394     # destroy local copies
 395     foreach my $volid (@$volids) {
 396         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 397         if (my $err = $@) {
 398             $self->log('err', "removing local copy of '$volid' failed - $err");
 399             $self->{errors} = 1;
 400             last if $err =~ /^interrupted by signal$/;
 401         }
 402     }
 403 }
 404
 405 sub phase3_cleanup {
 406     my ($self, $vmid, $err) = @_;
 407
 408     my $conf = $self->{vmconf};
 409
 410     # move config to remote node
 411     my $conffile = PVE::QemuServer::config_file($vmid);
 412     my $newconffile = PVE::QemuServer::config_file($vmid, $self->{node});
 413
 414     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 415         if !rename($conffile, $newconffile);
 416
 417     # always stop local VM
 418     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 419     if (my $err = $@) {
 420         $self->log('err', "stopping vm failed - $err");
 421         $self->{errors} = 1;
 422     }
 423
 424     if ($self->{tunnel}) {
 425         eval { finish_tunnel($self, $self->{tunnel});  };
 426         if (my $err = $@) {
 427             $self->log('err', $err);
 428             $self->{errors} = 1;
 429         }
 430     }
 431
 432     # always deactivate volumes - avoid lvm LVs to be active on several nodes
 433     eval {
 434         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 435         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
 436     };
 437     if (my $err = $@) {
 438         $self->log('err', $err);
 439         $self->{errors} = 1;
 440     }
 441
 442     # clear migrate lock
 443     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
 444     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
 445 }
 446
 447 sub final_cleanup {
 448     my ($self, $vmid) = @_;
 449
 450     # nothing to do
 451 }
 452
 453 1;