PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16 use PVE::ReplicationConfig;
  17 use PVE::ReplicationState;
  18 use PVE::Replication;
  19
  20 use base qw(PVE::AbstractMigrate);
  21
  22 sub fork_command_pipe {
  23     my ($self, $cmd) = @_;
  24
  25     my $reader = IO::File->new();
  26     my $writer = IO::File->new();
  27
  28     my $orig_pid = $$;
  29
  30     my $cpid;
  31
  32     eval { $cpid = open2($reader, $writer, @$cmd); };
  33
  34     my $err = $@;
  35
  36     # catch exec errors
  37     if ($orig_pid != $$) {
  38         $self->log('err', "can't fork command pipe\n");
  39         POSIX::_exit(1);
  40         kill('KILL', $$);
  41     }
  42
  43     die $err if $err;
  44
  45     return { writer => $writer, reader => $reader, pid => $cpid };
  46 }
  47
  48 sub finish_command_pipe {
  49     my ($self, $cmdpipe, $timeout) = @_;
  50
  51     my $cpid = $cmdpipe->{pid};
  52     return if !defined($cpid);
  53
  54     my $writer = $cmdpipe->{writer};
  55     my $reader = $cmdpipe->{reader};
  56
  57     $writer->close();
  58     $reader->close();
  59
  60     my $collect_child_process = sub {
  61         my $res = waitpid($cpid, WNOHANG);
  62         if (defined($res) && ($res == $cpid)) {
  63             delete $cmdpipe->{cpid};
  64             return 1;
  65         } else {
  66             return 0;
  67         }
  68      };
  69
  70     if ($timeout) {
  71         for (my $i = 0; $i < $timeout; $i++) {
  72             return if &$collect_child_process();
  73             sleep(1);
  74         }
  75     }
  76
  77     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  78     kill(15, $cpid);
  79
  80     # wait again
  81     for (my $i = 0; $i < 10; $i++) {
  82         return if &$collect_child_process();
  83         sleep(1);
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  87     kill 9, $cpid;
  88     sleep 1;
  89
  90     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  91         if !&$collect_child_process();
  92 }
  93
  94 sub fork_tunnel {
  95     my ($self, $tunnel_addr) = @_;
  96
  97     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
  98
  99     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 100
 101     my $tunnel = $self->fork_command_pipe($cmd);
 102
 103     my $reader = $tunnel->{reader};
 104
 105     my $helo;
 106     eval {
 107         PVE::Tools::run_with_timeout(60, sub { $helo = <$reader>; });
 108         die "no reply\n" if !$helo;
 109         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 110         die "got strange reply from mtunnel ('$helo')\n"
 111             if $helo !~ m/^tunnel online$/;
 112     };
 113     my $err = $@;
 114
 115     if ($err) {
 116         $self->finish_command_pipe($tunnel);
 117         die "can't open migration tunnel - $err";
 118     }
 119     return $tunnel;
 120 }
 121
 122 sub finish_tunnel {
 123     my ($self, $tunnel) = @_;
 124
 125     my $writer = $tunnel->{writer};
 126
 127     eval {
 128         PVE::Tools::run_with_timeout(30, sub {
 129             print $writer "quit\n";
 130             $writer->flush();
 131         });
 132     };
 133     my $err = $@;
 134
 135     $self->finish_command_pipe($tunnel, 30);
 136
 137     if ($tunnel->{sock_addr}) {
 138         # ssh does not clean up on local host
 139         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 140         PVE::Tools::run_command($cmd);
 141
 142         # .. and just to be sure check on remote side
 143         unshift @{$cmd}, @{$self->{rem_ssh}};
 144         PVE::Tools::run_command($cmd);
 145     }
 146
 147     die $err if $err;
 148 }
 149
 150 sub lock_vm {
 151     my ($self, $vmid, $code, @param) = @_;
 152
 153     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 154 }
 155
 156 sub prepare {
 157     my ($self, $vmid) = @_;
 158
 159     my $online = $self->{opts}->{online};
 160
 161     $self->{storecfg} = PVE::Storage::config();
 162
 163     # test if VM exists
 164     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 165
 166     PVE::QemuConfig->check_lock($conf);
 167
 168     my $running = 0;
 169     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 170         die "can't migrate running VM without --online\n" if !$online;
 171         $running = $pid;
 172
 173         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 174
 175     }
 176
 177     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 178         if ($self->{running} || !$self->{opts}->{force}) {
 179             die "can't migrate VM which uses local devices\n";
 180         } else {
 181             $self->log('info', "migrating VM which uses local devices");
 182         }
 183     }
 184
 185     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 186
 187     my $need_activate = [];
 188     foreach my $volid (@$vollist) {
 189         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 190
 191         # check if storage is available on both nodes
 192         my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 193
 194         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 195         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 196
 197         if ($scfg->{shared}) {
 198             # PVE::Storage::activate_storage checks this for non-shared storages
 199             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 200             warn "Used shared storage '$sid' is not online on source node!\n"
 201                 if !$plugin->check_connection($sid, $scfg);
 202         } else {
 203             # only activate if not shared
 204             push @$need_activate, $volid;
 205         }
 206     }
 207
 208     # activate volumes
 209     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 210
 211     # test ssh connection
 212     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 213     eval { $self->cmd_quiet($cmd); };
 214     die "Can't connect to destination address using public key\n" if $@;
 215
 216     return $running;
 217 }
 218
 219 sub sync_disks {
 220     my ($self, $vmid) = @_;
 221
 222     my $conf = $self->{vmconf};
 223
 224     # local volumes which have been copied
 225     $self->{volumes} = [];
 226
 227     my $res = [];
 228
 229     eval {
 230
 231         # found local volumes and their origin
 232         my $local_volumes = {};
 233         my $local_volumes_errors = {};
 234         my $other_errors = [];
 235         my $abort = 0;
 236
 237         my $sharedvm = 1;
 238
 239         my $log_error = sub {
 240             my ($msg, $volid) = @_;
 241
 242             if (defined($volid)) {
 243                 $local_volumes_errors->{$volid} = $msg;
 244             } else {
 245                 push @$other_errors, $msg;
 246             }
 247             $abort = 1;
 248         };
 249
 250         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 251         foreach my $storeid (@sids) {
 252             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 253             next if $scfg->{shared};
 254             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 255
 256             # get list from PVE::Storage (for unused volumes)
 257             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 258
 259             next if @{$dl->{$storeid}} == 0;
 260
 261             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $storeid;
 262
 263             # check if storage is available on target node
 264             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 265             $sharedvm = 0; # there is a non-shared disk
 266
 267             PVE::Storage::foreach_volid($dl, sub {
 268                 my ($volid, $sid, $volname) = @_;
 269
 270                 $local_volumes->{$volid}->{ref} = 'storage';
 271             });
 272         }
 273
 274         my $test_volid = sub {
 275             my ($volid, $attr) = @_;
 276
 277             if ($volid =~ m|^/|) {
 278                 $local_volumes->{$volid}->{ref} = 'config';
 279                 die "local file/device\n";
 280             }
 281
 282             my $snaprefs = $attr->{referenced_in_snapshot};
 283
 284             if ($attr->{cdrom}) {
 285                 if ($volid eq 'cdrom') {
 286                     my $msg = "can't migrate local cdrom drive";
 287                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 288                         my $snapnames = join(', ', sort keys %$snaprefs);
 289                         $msg .= " (referenced in snapshot - $snapnames)";
 290                     }
 291                     &$log_error("$msg\n");
 292                     return;
 293                 }
 294                 return if $volid eq 'none';
 295             }
 296
 297             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 298
 299             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 300             # check if storage is available on both nodes
 301             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 302             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 303
 304             return if $scfg->{shared};
 305
 306             $sharedvm = 0;
 307
 308             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 309
 310             die "local cdrom image\n" if $attr->{cdrom};
 311
 312             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 313
 314             die "owned by other VM (owner = VM $owner)\n"
 315                 if !$owner || ($owner != $self->{vmid});
 316
 317             my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 318             $local_volumes->{$volid}->{snapshots} = defined($snaprefs) || ($format =~ /^(?:qcow2|vmdk)$/);
 319             if (defined($snaprefs)) {
 320                 # we cannot migrate shapshots on local storage
 321                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 322
 323                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 324                 if (!($scfg->{type} eq 'zfspool' || $format eq 'qcow2')) {
 325                     die "non-migratable snapshot exists\n";
 326                 }
 327             }
 328
 329             die "referenced by linked clone(s)\n"
 330                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 331         };
 332
 333         PVE::QemuServer::foreach_volid($conf, sub {
 334             my ($volid, $attr) = @_;
 335             eval { $test_volid->($volid, $attr); };
 336             if (my $err = $@) {
 337                 &$log_error($err, $volid);
 338             }
 339         });
 340
 341         foreach my $vol (sort keys %$local_volumes) {
 342             my $ref = $local_volumes->{$vol}->{ref};
 343             if ($ref eq 'storage') {
 344                 $self->log('info', "found local disk '$vol' (via storage)\n");
 345             } elsif ($ref eq 'config') {
 346                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 347                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 348                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 349             } elsif ($ref eq 'snapshot') {
 350                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 351             } else {
 352                 $self->log('info', "found local disk '$vol'\n");
 353             }
 354         }
 355
 356         foreach my $vol (sort keys %$local_volumes_errors) {
 357             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 358         }
 359         foreach my $err (@$other_errors) {
 360             $self->log('warn', "$err");
 361         }
 362
 363         if ($self->{running} && !$sharedvm && !$self->{opts}->{targetstorage}) {
 364             $self->{opts}->{targetstorage} = 1; #use same sid for remote local
 365         }
 366
 367         if ($abort) {
 368             die "can't migrate VM - check log\n";
 369         }
 370
 371         # additional checks for local storage
 372         foreach my $volid (keys %$local_volumes) {
 373             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 374             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 375
 376             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 377                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 378
 379             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 380                 if !$migratable;
 381
 382             # image is a linked clone on local storage, se we can't migrate.
 383             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 384                 die "can't migrate '$volid' as it's a clone of '$basename'";
 385             }
 386         }
 387
 388         my $rep_volumes;
 389
 390         $self->log('info', "copying disk images");
 391
 392         my $rep_cfg = PVE::ReplicationConfig->new();
 393
 394         if (my $jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node})) {
 395             die "can't live migrate VM with replicated volumes\n" if $self->{running};
 396             my $start_time = time();
 397             my $logfunc = sub { my ($msg) = @_;  $self->log('info', $msg); };
 398             $rep_volumes = PVE::Replication::run_replication(
 399                'PVE::QemuConfig', $jobcfg, $start_time, $start_time, $logfunc);
 400         }
 401
 402         foreach my $volid (keys %$local_volumes) {
 403             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 404             if ($self->{running} && $self->{opts}->{targetstorage} && $local_volumes->{$volid}->{ref} eq 'config') {
 405                 push @{$self->{online_local_volumes}}, $volid;
 406             } else {
 407                 next if $rep_volumes->{$volid};
 408                 push @{$self->{volumes}}, $volid;
 409                 my $insecure = $self->{opts}->{migration_type} eq 'insecure';
 410                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 411                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{ssh_info}, $sid,
 412                                               undef, undef, undef, undef, $insecure, $with_snapshots);
 413             }
 414         }
 415     };
 416     die "Failed to sync data - $@" if $@;
 417 }
 418
 419 sub cleanup_remotedisks {
 420     my ($self) = @_;
 421
 422     foreach my $target_drive (keys %{$self->{target_drive}}) {
 423
 424         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 425         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 426
 427         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 428
 429         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 430         if (my $err = $@) {
 431             $self->log('err', $err);
 432             $self->{errors} = 1;
 433         }
 434     }
 435 }
 436
 437 sub phase1 {
 438     my ($self, $vmid) = @_;
 439
 440     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 441
 442     my $conf = $self->{vmconf};
 443
 444     # set migrate lock in config file
 445     $conf->{lock} = 'migrate';
 446     PVE::QemuConfig->write_config($vmid, $conf);
 447
 448     sync_disks($self, $vmid);
 449
 450 };
 451
 452 sub phase1_cleanup {
 453     my ($self, $vmid, $err) = @_;
 454
 455     $self->log('info', "aborting phase 1 - cleanup resources");
 456
 457     my $conf = $self->{vmconf};
 458     delete $conf->{lock};
 459     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 460     if (my $err = $@) {
 461         $self->log('err', $err);
 462     }
 463
 464     if ($self->{volumes}) {
 465         foreach my $volid (@{$self->{volumes}}) {
 466             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 467             # fixme: try to remove ?
 468         }
 469     }
 470 }
 471
 472 sub phase2 {
 473     my ($self, $vmid) = @_;
 474
 475     my $conf = $self->{vmconf};
 476
 477     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 478
 479     my $raddr;
 480     my $rport;
 481     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 482     my $nodename = PVE::INotify::nodename();
 483
 484     ## start on remote node
 485     my $cmd = [@{$self->{rem_ssh}}];
 486
 487     my $spice_ticket;
 488     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 489         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 490         $spice_ticket = $res->{ticket};
 491     }
 492
 493     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 494
 495     my $migration_type = $self->{opts}->{migration_type};
 496
 497     push @$cmd, '--migration_type', $migration_type;
 498
 499     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 500       if $self->{opts}->{migration_network};
 501
 502     if ($migration_type eq 'insecure') {
 503         push @$cmd, '--stateuri', 'tcp';
 504     } else {
 505         push @$cmd, '--stateuri', 'unix';
 506     }
 507
 508     if ($self->{forcemachine}) {
 509         push @$cmd, '--machine', $self->{forcemachine};
 510     }
 511
 512     if ($self->{opts}->{targetstorage}) {
 513         push @$cmd, '--targetstorage', $self->{opts}->{targetstorage};
 514     }
 515
 516     my $spice_port;
 517
 518     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 519     # instead we pipe it through STDIN
 520     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 521         my $line = shift;
 522
 523         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 524             $raddr = $1;
 525             $rport = int($2);
 526             $ruri = "tcp:$raddr:$rport";
 527         }
 528         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 529             $raddr = $1;
 530             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 531             $ruri = "unix:$raddr";
 532         }
 533         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 534             $raddr = "localhost";
 535             $rport = int($1);
 536             $ruri = "tcp:$raddr:$rport";
 537         }
 538         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 539             $spice_port = int($1);
 540         }
 541         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 542             my $volid = $4;
 543             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 544             my $targetdrive = $3;
 545             $targetdrive =~ s/drive-//g;
 546
 547             $self->{target_drive}->{$targetdrive}->{volid} = $volid;
 548             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 549
 550         }
 551     }, errfunc => sub {
 552         my $line = shift;
 553         $self->log('info', $line);
 554     });
 555
 556     die "unable to detect remote migration address\n" if !$raddr;
 557
 558     if ($migration_type eq 'secure') {
 559         $self->log('info', "start remote tunnel");
 560
 561         if ($ruri =~ /^unix:/) {
 562             unlink $raddr;
 563             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 564             $self->{tunnel}->{sock_addr} = $raddr;
 565
 566             my $unix_socket_try = 0; # wait for the socket to become ready
 567             while (! -S $raddr) {
 568                 $unix_socket_try++;
 569                 if ($unix_socket_try > 100) {
 570                     $self->{errors} = 1;
 571                     $self->finish_tunnel($self->{tunnel});
 572                     die "Timeout, migration socket $ruri did not get ready";
 573                 }
 574
 575                 usleep(50000);
 576             }
 577
 578         } elsif ($ruri =~ /^tcp:/) {
 579             my $tunnel_addr;
 580             if ($raddr eq "localhost") {
 581                 # for backwards compatibility with older qemu-server versions
 582                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 583                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 584                 $tunnel_addr = "$lport:localhost:$rport";
 585             }
 586
 587             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 588
 589         } else {
 590             die "unsupported protocol in migration URI: $ruri\n";
 591         }
 592     }
 593
 594     my $start = time();
 595
 596     if ($self->{opts}->{targetstorage} && defined($self->{online_local_volumes})) {
 597         $self->{storage_migration} = 1;
 598         $self->{storage_migration_jobs} = {};
 599         $self->log('info', "starting storage migration");
 600
 601         die "The number of local disks does not match between the source and the destination.\n"
 602             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 603         foreach my $drive (keys %{$self->{target_drive}}){
 604             my $nbd_uri = $self->{target_drive}->{$drive}->{nbd_uri};
 605             $self->log('info', "$drive: start migration to to $nbd_uri");
 606             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 1);
 607         }
 608     }
 609
 610     $self->log('info', "starting online/live migration on $ruri");
 611     $self->{livemigration} = 1;
 612
 613     # load_defaults
 614     my $defaults = PVE::QemuServer::load_defaults();
 615
 616     # always set migrate speed (overwrite kvm default of 32m)
 617     # we set a very hight default of 8192m which is basically unlimited
 618     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 619     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 620     $migrate_speed = $migrate_speed * 1048576;
 621     $self->log('info', "migrate_set_speed: $migrate_speed");
 622     eval {
 623         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 624     };
 625     $self->log('info', "migrate_set_speed error: $@") if $@;
 626
 627     my $migrate_downtime = $defaults->{migrate_downtime};
 628     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 629     if (defined($migrate_downtime)) {
 630         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 631         eval {
 632             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 633         };
 634         $self->log('info', "migrate_set_downtime error: $@") if $@;
 635     }
 636
 637     $self->log('info', "set migration_caps");
 638     eval {
 639         PVE::QemuServer::set_migration_caps($vmid);
 640     };
 641     warn $@ if $@;
 642
 643     # set cachesize to 10% of the total memory
 644     my $memory =  $conf->{memory} || $defaults->{memory};
 645     my $cachesize = int($memory * 1048576 / 10);
 646     $self->log('info', "set cachesize: $cachesize");
 647     eval {
 648         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 649     };
 650     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 651
 652     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 653         my $rpcenv = PVE::RPCEnvironment::get();
 654         my $authuser = $rpcenv->get_user();
 655
 656         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 657
 658         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 659         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 660
 661         $self->log('info', "spice client_migrate_info");
 662
 663         eval {
 664             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 665                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 666                                                 'cert-subject' => $subject);
 667         };
 668         $self->log('info', "client_migrate_info error: $@") if $@;
 669
 670     }
 671
 672     $self->log('info', "start migrate command to $ruri");
 673     eval {
 674         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 675     };
 676     my $merr = $@;
 677     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 678
 679     my $lstat = 0;
 680     my $usleep = 2000000;
 681     my $i = 0;
 682     my $err_count = 0;
 683     my $lastrem = undef;
 684     my $downtimecounter = 0;
 685     while (1) {
 686         $i++;
 687         my $avglstat = $lstat/$i if $lstat;
 688
 689         usleep($usleep);
 690         my $stat;
 691         eval {
 692             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 693         };
 694         if (my $err = $@) {
 695             $err_count++;
 696             warn "query migrate failed: $err\n";
 697             $self->log('info', "query migrate failed: $err");
 698             if ($err_count <= 5) {
 699                 usleep(1000000);
 700                 next;
 701             }
 702             die "too many query migrate failures - aborting\n";
 703         }
 704
 705         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 706             sleep(1);
 707             next;
 708         }
 709
 710         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 711             $merr = undef;
 712             $err_count = 0;
 713             if ($stat->{status} eq 'completed') {
 714                 my $delay = time() - $start;
 715                 if ($delay > 0) {
 716                     my $mbps = sprintf "%.2f", $memory / $delay;
 717                     my $downtime = $stat->{downtime} || 0;
 718                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 719                 }
 720             }
 721
 722             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 723                 $self->log('info', "migration status error: $stat->{status}");
 724                 die "aborting\n"
 725             }
 726
 727             if ($stat->{status} ne 'active') {
 728                 $self->log('info', "migration status: $stat->{status}");
 729                 last;
 730             }
 731
 732             if ($stat->{ram}->{transferred} ne $lstat) {
 733                 my $trans = $stat->{ram}->{transferred} || 0;
 734                 my $rem = $stat->{ram}->{remaining} || 0;
 735                 my $total = $stat->{ram}->{total} || 0;
 736                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 737                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 738                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 739                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 740                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 741                 #reduce sleep if remainig memory if lower than the everage transfert
 742                 $usleep = 300000 if $avglstat && $rem < $avglstat;
 743
 744                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 745                            "remaining ${rem}), total ${total})");
 746
 747                 if (${xbzrlecachesize}) {
 748                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 749                 }
 750
 751                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 752                     $downtimecounter++;
 753                 }
 754                 $lastrem = $rem;
 755
 756                 if ($downtimecounter > 5) {
 757                     $downtimecounter = 0;
 758                     $migrate_downtime *= 2;
 759                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 760                     eval {
 761                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 762                     };
 763                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 764                 }
 765
 766             }
 767
 768
 769             $lstat = $stat->{ram}->{transferred};
 770
 771         } else {
 772             die $merr if $merr;
 773             die "unable to parse migration status '$stat->{status}' - aborting\n";
 774         }
 775     }
 776
 777     # just to be sure that the tunnel gets closed on successful migration, on error
 778     # phase2_cleanup closes it *after* stopping the remote waiting VM
 779     if (!$self->{errors} && $self->{tunnel}) {
 780         eval { finish_tunnel($self, $self->{tunnel});  };
 781         if (my $err = $@) {
 782             $self->log('err', $err);
 783             $self->{errors} = 1;
 784         }
 785     }
 786 }
 787
 788 sub phase2_cleanup {
 789     my ($self, $vmid, $err) = @_;
 790
 791     return if !$self->{errors};
 792     $self->{phase2errors} = 1;
 793
 794     $self->log('info', "aborting phase 2 - cleanup resources");
 795
 796     $self->log('info', "migrate_cancel");
 797     eval {
 798         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 799     };
 800     $self->log('info', "migrate_cancel error: $@") if $@;
 801
 802     my $conf = $self->{vmconf};
 803     delete $conf->{lock};
 804     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 805     if (my $err = $@) {
 806         $self->log('err', $err);
 807     }
 808
 809     # cleanup ressources on target host
 810     if ($self->{storage_migration}) {
 811
 812         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 813         if (my $err = $@) {
 814             $self->log('err', $err);
 815         }
 816
 817         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 818         if (my $err = $@) {
 819             $self->log('err', $err);
 820         }
 821     }
 822
 823     my $nodename = PVE::INotify::nodename();
 824
 825     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 826     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 827     if (my $err = $@) {
 828         $self->log('err', $err);
 829         $self->{errors} = 1;
 830     }
 831
 832     if ($self->{tunnel}) {
 833         eval { finish_tunnel($self, $self->{tunnel});  };
 834         if (my $err = $@) {
 835             $self->log('err', $err);
 836             $self->{errors} = 1;
 837         }
 838     }
 839 }
 840
 841 sub phase3 {
 842     my ($self, $vmid) = @_;
 843
 844     my $volids = $self->{volumes};
 845     return if $self->{phase2errors};
 846
 847     # destroy local copies
 848     foreach my $volid (@$volids) {
 849         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 850         if (my $err = $@) {
 851             $self->log('err', "removing local copy of '$volid' failed - $err");
 852             $self->{errors} = 1;
 853             last if $err =~ /^interrupted by signal$/;
 854         }
 855     }
 856 }
 857
 858 sub phase3_cleanup {
 859     my ($self, $vmid, $err) = @_;
 860
 861     my $conf = $self->{vmconf};
 862     return if $self->{phase2errors};
 863
 864     if ($self->{storage_migration}) {
 865         # finish block-job
 866         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}); };
 867
 868         if (my $err = $@) {
 869             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 870             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 871             die "Failed to completed storage migration\n";
 872         } else {
 873             foreach my $target_drive (keys %{$self->{target_drive}}) {
 874                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 875                 $conf->{$target_drive} = PVE::QemuServer::print_drive($vmid, $drive);
 876                 PVE::QemuConfig->write_config($vmid, $conf);
 877             }
 878         }
 879     }
 880
 881     # transfer replication state before move config
 882     $self->transfer_replication_state();
 883
 884     # move config to remote node
 885     my $conffile = PVE::QemuConfig->config_file($vmid);
 886     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 887
 888     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 889         if !rename($conffile, $newconffile);
 890
 891     $self->switch_replication_job_target();
 892
 893     if ($self->{livemigration}) {
 894         if ($self->{storage_migration}) {
 895             # remove drives referencing the nbd server from source
 896             # otherwise vm_stop might hang later on
 897             foreach my $drive (keys %{$self->{target_drive}}){
 898                 PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "device_del", id => $drive);
 899             }
 900             # stop nbd server on remote vm - requirement for resume since 2.9
 901             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
 902
 903             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 904             if (my $err = $@) {
 905                 $self->log('err', $err);
 906                 $self->{errors} = 1;
 907             }
 908         }
 909         # config moved and nbd server stopped - now we can resume vm on target
 910         my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 911         eval{ PVE::Tools::run_command($cmd, outfunc => sub {},
 912                 errfunc => sub {
 913                     my $line = shift;
 914                     $self->log('err', $line);
 915                 });
 916         };
 917         if (my $err = $@) {
 918             $self->log('err', $err);
 919             $self->{errors} = 1;
 920         }
 921     }
 922
 923     eval {
 924         my $timer = 0;
 925         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
 926             $self->log('info', "Waiting for spice server migration");
 927             while (1) {
 928                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
 929                 last if int($res->{'migrated'}) == 1;
 930                 last if $timer > 50;
 931                 $timer ++;
 932                 usleep(200000);
 933             }
 934         }
 935     };
 936
 937     # always stop local VM
 938     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 939     if (my $err = $@) {
 940         $self->log('err', "stopping vm failed - $err");
 941         $self->{errors} = 1;
 942     }
 943
 944     # always deactivate volumes - avoid lvm LVs to be active on several nodes
 945     eval {
 946         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 947         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
 948     };
 949     if (my $err = $@) {
 950         $self->log('err', $err);
 951         $self->{errors} = 1;
 952     }
 953
 954     if($self->{storage_migration}) {
 955         # destroy local copies
 956         my $volids = $self->{online_local_volumes};
 957
 958         foreach my $volid (@$volids) {
 959             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 960             if (my $err = $@) {
 961                 $self->log('err', "removing local copy of '$volid' failed - $err");
 962                 $self->{errors} = 1;
 963                 last if $err =~ /^interrupted by signal$/;
 964             }
 965         }
 966
 967     }
 968
 969     # clear migrate lock
 970     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
 971     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
 972 }
 973
 974 sub final_cleanup {
 975     my ($self, $vmid) = @_;
 976
 977     # nothing to do
 978 }
 979
 980 1;